sysdeps/powerpc/powerpc32/power7/fpu/s_isnan.S

   1 /* isnan().  PowerPC32/POWER7 version.
   2    Copyright (C) 2010-2014 Free Software Foundation, Inc.
   3    Contributed by Luis Machado <luisgpm@br.ibm.com>.
   4    This file is part of the GNU C Library.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library; if not, see
  18    <http://www.gnu.org/licenses/>.  */
  19
  20 #include <sysdep.h>
  21 #include <math_ldbl_opt.h>
  22
  23 /* int __isnan(x)  */
  24         .section    .rodata.cst8,"aM",@progbits,8
  25         .align 3
  26 .LC0:   /* 1.0 */
  27         .quad       0x3ff0000000000000
  28
  29         .section    ".text"
  30         .type       __isnan, @function
  31         .machine    power7
  32 ENTRY (__isnan)
  33 #ifdef SHARED
  34         mflr    r11
  35         cfi_register(lr,r11)
  36
  37         SETUP_GOT_ACCESS(r9,got_label)
  38         addis   r9,r9,.LC0-got_label@ha
  39         lfd     fp0,.LC0-got_label@l(r9)
  40
  41         mtlr    r11
  42         cfi_same_value (lr)
  43 #else
  44         lis     r9,.LC0@ha
  45         lfd     fp0,.LC0@l(r9)
  46 #endif
  47         ftdiv   cr7,fp1,fp0
  48         li      r3,0
  49         bflr    30            /* If not NaN or Inf, finish. */
  50
  51         /* We have -INF/+INF/NaN or a denormal.  */
  52
  53         stwu    r1,-16(r1)    /* Allocate stack space.  */
  54         stfd    fp1,8(r1)     /* Transfer FP to GPR's.  */
  55         ori     2,2,0         /* Force a new dispatch group.  */
  56         lwz     r4,8+HIWORD(r1) /* Load the upper half of the FP value.  */
  57         lwz     r5,8+LOWORD(r1) /* Load the lower half of the FP value.  */
  58         addi    r1,r1,16      /* Reset the stack pointer.  */
  59         lis     r0,0x7ff0     /* Load the upper portion for an INF/NaN.  */
  60         clrlwi  r4,r4,1       /* r4 = abs(r4).  */
  61         cmpw    cr7,r4,r0     /* if (abs(r4) <= inf).  */
  62         cmpwi   cr6,r5,0      /* r5 == 0x00000000?  */
  63         bltlr   cr7           /* LT means we have a denormal.  */
  64         bgt     cr7,L(NaN)    /* GT means we have a NaN.  */
  65         beqlr   cr6           /* EQ means we have +/-INF.  */
  66 L(NaN):
  67         li      r3,1          /* x == NaN?  */
  68         blr
  69         END (__isnan)
  70
  71 hidden_def (__isnan)
  72 weak_alias (__isnan, isnan)
  73
  74 /* It turns out that the 'double' version will also always work for
  75    single-precision.  */
  76 strong_alias (__isnan, __isnanf)
  77 hidden_def (__isnanf)
  78 weak_alias (__isnanf, isnanf)
  79
  80 #ifdef NO_LONG_DOUBLE
  81 strong_alias (__isnan, __isnanl)
  82 weak_alias (__isnan, isnanl)
  83 #endif
  84
  85 #ifndef IS_IN_libm
  86 # if LONG_DOUBLE_COMPAT(libc, GLIBC_2_0)
  87 compat_symbol (libc, __isnan, __isnanl, GLIBC_2_0);
  88 compat_symbol (libc, isnan, isnanl, GLIBC_2_0);
  89 # endif
  90 #endif