sysdeps/powerpc/powerpc64/fpu/s_floorf.S

   1 /* float Floor function.  PowerPC64 version.
   2    Copyright (C) 2004-2019 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 #include <sysdep.h>
  20 #include <libm-alias-float.h>
  21
  22         .section        ".toc","aw"
  23         .p2align 3
  24 .LC0:   /* 2**23 */
  25         .long 0x4b000000
  26         .long 0x0
  27         .section        ".text"
  28
  29 ENTRY (__floorf, 4)
  30         CALL_MCOUNT 0
  31         lfs     fp13,.LC0@toc(2)
  32         fabs    fp0,fp1
  33         fsubs   fp12,fp13,fp13  /* generate 0.0  */
  34         fcmpu   cr7,fp0,fp13    /* if (fabs(x) > TWO23)  */
  35         mffs    fp11            /* Save current FPU rounding mode and
  36                                    "inexact" state.  */
  37         fcmpu   cr6,fp1,fp12    /* if (x > 0.0)  */
  38         bnl-    cr7,.L10
  39         mtfsfi  7,3             /* Set rounding mode toward -inf.  */
  40         ble-    cr6,.L4
  41         fadds   fp1,fp1,fp13    /* x+= TWO23;  */
  42         fsubs   fp1,fp1,fp13    /* x-= TWO23;  */
  43         fabs    fp1,fp1         /* if (x == 0.0)  */
  44                                 /* x = 0.0; */
  45         mtfsf   0xff,fp11       /* Restore previous rounding mode and
  46                                    "inexact" state.  */
  47         blr
  48 .L4:
  49         bge-    cr6,.L9         /* if (x < 0.0)  */
  50         fsubs   fp1,fp1,fp13    /* x-= TWO23;  */
  51         fadds   fp1,fp1,fp13    /* x+= TWO23;  */
  52         fnabs   fp1,fp1         /* if (x == 0.0)  */
  53                                 /* x = -0.0; */
  54 .L9:
  55         mtfsf   0xff,fp11       /* Restore previous rounding mode and
  56                                    "inexact" state.  */
  57         blr
  58 .L10:
  59         /* Ensure sNaN input is converted to qNaN.  */
  60         fcmpu   cr7,fp1,fp1
  61         beqlr   cr7
  62         fadds   fp1,fp1,fp1
  63         blr
  64         END (__floorf)
  65
  66 libm_alias_float (__floor, floor)
  67