sysdeps/powerpc/powerpc64/fpu/s_llround.S

   1 /* llround function.  PowerPC64 version.
   2    Copyright (C) 2004-2015 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 #include <sysdep.h>
  20 #include <math_ldbl_opt.h>
  21
  22         .section        ".toc","aw"
  23 .LC0:   /* 2^52 */
  24         .tc FD_43300000_0[TC],0x4330000000000000
  25 .LC1:   /* 0.5 */
  26         .tc FD_3fe00000_0[TC],0x3fe0000000000000
  27         .section        ".text"
  28
  29 /* long long [r3] llround (double x [fp1])
  30    IEEE 1003.1 llround function.  IEEE specifies "round to the nearest
  31    integer value, rounding halfway cases away from zero, regardless of
  32    the current rounding mode."  However PowerPC Architecture defines
  33    "round to Nearest" as "Choose the best approximation. In case of a
  34    tie, choose the one that is even (least significant bit o).".
  35    So we can't use the PowerPC "round to Nearest" mode. Instead we set
  36    "round toward Zero" mode and round by adding +-0.5 before rounding
  37    to the integer value.
  38
  39    It is necessary to detect when x is (+-)0x1.fffffffffffffp-2
  40    because adding +-0.5 in this case will cause an erroneous shift,
  41    carry and round.  We simply return 0 if 0.5 > x > -0.5.  Likewise
  42    if x is and odd number between +-(2^52 and 2^53-1) a shift and
  43    carry will erroneously round if biased with +-0.5.  Therefore if x
  44    is greater/less than +-2^52 we don't need to bias the number with
  45    +-0.5.  */
  46
  47 ENTRY (__llround)
  48         CALL_MCOUNT 0
  49         lfd     fp9,.LC0@toc(2) /* Load 2^52 into fpr9.  */
  50         lfd     fp10,.LC1@toc(2)/* Load 0.5 into fpr10.  */
  51         fabs    fp2,fp1         /* Get the absolute value of x.  */
  52         fsub    fp12,fp10,fp10  /* Compute 0.0 into fp12.  */
  53         fcmpu   cr6,fp2,fp10    /* if |x| < 0.5  */
  54         fcmpu   cr7,fp2,fp9     /* if |x| >= 2^52  */
  55         fcmpu   cr1,fp1,fp12    /* x is negative? x < 0.0  */
  56         blt-    cr6,.Lretzero   /* 0.5 > x < -0.5 so just return 0.  */
  57         bge-    cr7,.Lnobias    /* 2^52 > x < -2^52 just convert with no bias.  */
  58         fadd    fp3,fp2,fp10    /* |x|+=0.5 bias to prepare to round.  */
  59         bge     cr1,.Lconvert   /* x is positive so don't negate x.  */
  60         fnabs   fp3,fp3         /* -(|x|+=0.5)  */
  61 .Lconvert:
  62         fctidz  fp4,fp3         /* Convert to Integer double word round toward 0.  */
  63         stfd    fp4,-16(r1)
  64         nop
  65         nop
  66         nop
  67         ld      r3,-16(r1)      /* Load return as integer.  */
  68 .Lout:
  69         blr
  70 .Lretzero:                      /* 0.5 > x > -0.5  */
  71         li      r3,0            /* return 0.  */
  72         b       .Lout
  73 .Lnobias:
  74         fmr     fp3,fp1
  75         b       .Lconvert
  76         END (__llround)
  77
  78 strong_alias (__llround, __lround)
  79 weak_alias (__llround, llround)
  80 weak_alias (__lround, lround)
  81
  82 #ifdef NO_LONG_DOUBLE
  83 weak_alias (__llround, llroundl)
  84 strong_alias (__llround, __llroundl)
  85 weak_alias (__lround, lroundl)
  86 strong_alias (__lround, __lroundl)
  87 #endif
  88 #if LONG_DOUBLE_COMPAT(libm, GLIBC_2_1)
  89 compat_symbol (libm, __llround, llroundl, GLIBC_2_1)
  90 compat_symbol (libm, __lround, lroundl, GLIBC_2_1)
  91 #endif