sysdeps/powerpc/powerpc64/fpu/s_llroundf.S

   1 /* llroundf function.  PowerPC64 version.
   2    Copyright (C) 2004-2016 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 #include <sysdep.h>
  20
  21         .section        ".toc","aw"
  22 .LC0:   /* 2^23 */
  23         .tc FD_41600000_0[TC],0x4160000000000000
  24 .LC1:   /* 0.5 */
  25         .tc FD_3fe00000_0[TC],0x3fe0000000000000
  26 .LC2:   /* 2^52 */
  27         .tc FD_43300000_0[TC],0x4330000000000000
  28         .section        ".text"
  29
  30 /* long long [r3] llroundf (float x [fp1])
  31    IEEE 1003.1 llroundf function.  IEEE specifies "roundf to the nearest
  32    integer value, rounding halfway cases away from zero, regardless of
  33    the current rounding mode."  However PowerPC Architecture defines
  34    "roundf to Nearest" as "Choose the best approximation. In case of a
  35    tie, choose the one that is even (least significant bit o).".
  36    So we can't use the PowerPC "round to Nearest" mode. Instead we set
  37    "round toward Zero" mode and round by adding +-0.5 before rounding
  38    to the integer value.
  39
  40    It is necessary to detect when x is (+-)0x1.fffffffffffffp-2
  41    because adding +-0.5 in this case will cause an erroneous shift,
  42    carry and round.  We simply return 0 if 0.5 > x > -0.5.  Likewise
  43    if x is and odd number between +-(2^23 and 2^24-1) a shift and
  44    carry will erroneously round if biased with +-0.5.  Therefore if x
  45    is greater/less than +-2^23 we don't need to bias the number with
  46    +-0.5.  */
  47
  48 ENTRY (__llroundf)
  49         CALL_MCOUNT 0
  50         lfd     fp9,.LC0@toc(2) /* Load 2^23 into fpr9.  */
  51         lfd     fp10,.LC1@toc(2)/* Load 0.5 into fpr10.  */
  52         lfd     fp11,.LC2@toc(2)        /* Load 2^52 into fpr11.  */
  53         fabs    fp2,fp1         /* Get the absolute value of x.  */
  54         fsub    fp12,fp10,fp10  /* Compute 0.0 into fp12.  */
  55         fcmpu   cr6,fp2,fp10    /* if |x| < 0.5  */
  56         fcmpu   cr7,fp2,fp9     /* if |x| >= 2^23  */
  57         fcmpu   cr1,fp1,fp12    /* x is negative? x < 0.0  */
  58         blt-    cr6,.Lretzero   /* 0.5 > x < -0.5 so just return 0.  */
  59         bge-    cr7,.Lnobias    /* 2^23 > x < -2^23 just convert with no bias.  */
  60         /* Test whether an integer to avoid spurious "inexact".  */
  61         fadd    fp3,fp2,fp11
  62         fsub    fp3,fp3,fp11
  63         fcmpu   cr5,fp2,fp3
  64         beq     cr5,.Lnobias
  65         fadd    fp3,fp2,fp10    /* |x|+=0.5 bias to prepare to round.  */
  66         bge     cr1,.Lconvert   /* x is positive so don't negate x.  */
  67         fnabs   fp3,fp3         /* -(|x|+=0.5)  */
  68 .Lconvert:
  69         fctidz  fp4,fp3         /* Convert to Integer double word round toward 0.  */
  70         stfd    fp4,-16(r1)
  71         nop
  72         nop
  73         nop
  74         ld      r3,-16(r1)      /* Load return as integer.  */
  75 .Lout:
  76         blr
  77 .Lretzero:                      /* 0.5 > x > -0.5  */
  78         li      r3,0            /* return 0.  */
  79         b       .Lout
  80 .Lnobias:
  81         fmr     fp3,fp1
  82         b       .Lconvert
  83         END (__llroundf)
  84
  85 strong_alias (__llroundf, __lroundf)
  86 weak_alias (__llroundf, llroundf)
  87 weak_alias (__lroundf, lroundf)
  88