sysdeps/powerpc/powerpc64/fpu/s_nearbyintf.S

   1 /* Round to int floating-point values.  PowerPC64 version.
   2    Copyright (C) 2011-2014 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4    Contributed by Adhemerval Zanella <azanella@br.ibm.com>, 2011
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library; if not, see
  18    <http://www.gnu.org/licenses/>.  */
  19
  20 /* This has been coded in assembler because GCC makes such a mess of it
  21    when it's coded in C.  */
  22
  23 #include <sysdep.h>
  24
  25
  26 /* float [fp1] nearbyintf(float [fp1]) */
  27
  28         .section        ".toc","aw"
  29         .p2align 3
  30 .LC0:   /* 2**23 */
  31         .long 0x4b000000
  32         .long 0x0
  33         .section        ".text"
  34
  35 EALIGN (__nearbyintf, 4, 0)
  36         CALL_MCOUNT 0
  37         fabs    fp0,fp1
  38         lfs     fp13,.LC0@toc(2)
  39         fcmpu   cr7,fp0,fp13    /* if (fabs(x) > TWO52)  */
  40         bgelr   cr7
  41         fsubs   fp12,fp13,fp13  /* generate 0.0 */
  42         fcmpu   cr7,fp1,fp12    /* if (x > 0.0)  */
  43         ble     cr7, L(lessthanzero)
  44         mtfsb0  4*cr7+lt        /* Disable FE_INEXACT exception */
  45         fadds   fp1,fp1,fp13    /* x += TWO23 */
  46         fsubs   fp1,fp1,fp13    /* x -= TWO23 */
  47         fabs    fp1,fp1         /* if (x == 0.0) */
  48         mtfsb0  4*cr1+eq        /* Clear pending FE_INEXACT exception */
  49         blr                     /* x = 0.0; */
  50 L(lessthanzero):
  51         bgelr   cr7             /* if (x < 0.0) */
  52         mtfsb0  4*cr7+lt        /* Disable FE_INEXACT exception */
  53         fsubs   fp1,fp1,fp13    /* x -= TWO23 */
  54         fadds   fp1,fp1,fp13    /* x += TWO23 */
  55         fnabs   fp1,fp1         /* if (x == 0.0) */
  56         mtfsb0  4*cr1+eq        /* Clear pending FE_INEXACT exception */
  57         blr                     /* x = -0.0; */
  58 END (__nearbyintf)
  59
  60 weak_alias (__nearbyintf, nearbyintf)