sysdeps/powerpc/powerpc64/fpu/s_round.S

   1 /* round function.  PowerPC64 version.
   2    Copyright (C) 2004-2016 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 #include <sysdep.h>
  20 #include <math_ldbl_opt.h>
  21
  22         .section        ".toc","aw"
  23 .LC0:   /* 2**52 */
  24         .tc FD_43300000_0[TC],0x4330000000000000
  25 .LC1:   /* 0.5 */
  26         .tc FD_3fe00000_0[TC],0x3fe0000000000000
  27         .section        ".text"
  28
  29 /* double [fp1] round (double x [fp1])
  30    IEEE 1003.1 round function.  IEEE specifies "round to the nearest
  31    integer value, rounding halfway cases away from zero, regardless of
  32    the current rounding mode."  However PowerPC Architecture defines
  33    "Round to Nearest" as "Choose the best approximation. In case of a
  34    tie, choose the one that is even (least significant bit o).".
  35    So we can't use the PowerPC "Round to Nearest" mode. Instead we set
  36    "Round toward Zero" mode and round by adding +-0.5 before rounding
  37    to the integer value.  */
  38
  39 EALIGN (__round, 4, 0)
  40         CALL_MCOUNT 0
  41         lfd     fp13,.LC0@toc(2)
  42         fabs    fp0,fp1
  43         fsub    fp12,fp13,fp13  /* generate 0.0  */
  44         fcmpu   cr7,fp0,fp13    /* if (fabs(x) > TWO52)  */
  45         mffs    fp11            /* Save current FPU rounding mode and
  46                                    "inexact" state.  */
  47         fcmpu   cr6,fp1,fp12    /* if (x > 0.0)  */
  48         bnllr-  cr7
  49         mtfsfi  7,1             /* Set rounding mode toward 0.  */
  50         lfd     fp10,.LC1@toc(2)
  51         ble-    cr6,.L4
  52         fadd    fp1,fp1,fp10    /* x+= 0.5;  */
  53         fadd    fp1,fp1,fp13    /* x+= TWO52;  */
  54         fsub    fp1,fp1,fp13    /* x-= TWO52;  */
  55         fabs    fp1,fp1         /* if (x == 0.0)  */
  56                                 /* x = 0.0; */
  57         mtfsf   0xff,fp11       /* Restore previous rounding mode and
  58                                    "inexact" state.  */
  59         blr
  60 .L4:
  61         fsub    fp9,fp1,fp10    /* x+= 0.5;  */
  62         bge-    cr6,.L9         /* if (x < 0.0)  */
  63         fsub    fp1,fp9,fp13    /* x-= TWO52;  */
  64         fadd    fp1,fp1,fp13    /* x+= TWO52;  */
  65         fnabs   fp1,fp1         /* if (x == 0.0)  */
  66                                 /* x = -0.0; */
  67 .L9:
  68         mtfsf   0xff,fp11       /* Restore previous rounding mode and
  69                                    "inexact" state.  */
  70         blr
  71         END (__round)
  72
  73 weak_alias (__round, round)
  74
  75 #ifdef NO_LONG_DOUBLE
  76 weak_alias (__round, roundl)
  77 strong_alias (__round, __roundl)
  78 #endif
  79 #if LONG_DOUBLE_COMPAT(libm, GLIBC_2_1)
  80 compat_symbol (libm, __round, roundl, GLIBC_2_1)
  81 #endif