sysdeps/powerpc/powerpc64/fpu/s_roundf.S

   1 /* roundf  function.  PowerPC64 version.
   2    Copyright (C) 2004 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 #include <sysdep.h>
  20
  21         .section        ".toc","aw"
  22 .LC0:   /* 2**23 */
  23         .tc FD_4b000000_0[TC],0x4b00000000000000
  24 .LC1:   /* 0.5 */
  25         .tc FD_3f000000_0[TC],0x3f00000000000000
  26         .section        ".text"
  27
  28 /* float [fp1] roundf  (float x [fp1])
  29    IEEE 1003.1 round function.  IEEE specifies "round to the nearest
  30    integer value, rounding halfway cases away from zero, regardless of
  31    the current rounding mode."  However PowerPC Architecture defines
  32    "Round to Nearest" as "Choose the best approximation. In case of a
  33    tie, choose the one that is even (least significant bit o).".
  34    So we can't use the PowerPC "Round to Nearest" mode. Instead we set
  35    "Round toward Zero" mode and round by adding +-0.5 before rounding
  36    to the integer value.  */
  37
  38 EALIGN (__roundf, 4, 0)
  39         CALL_MCOUNT 0
  40         mffs    fp11            /* Save current FPU rounding mode.  */
  41         lfs     fp13,.LC0@toc(2)
  42         fabs    fp0,fp1
  43         fsubs   fp12,fp13,fp13  /* generate 0.0  */
  44         fcmpu   cr7,fp0,fp13    /* if (fabs(x) > TWO23)  */
  45         fcmpu   cr6,fp1,fp12    /* if (x > 0.0)  */
  46         bnllr-  cr7
  47         mtfsfi  7,1             /* Set rounding mode toward 0.  */
  48         lfs     fp10,.LC1@toc(2)
  49         ble-    cr6,.L4
  50         fadds   fp1,fp1,fp10    /* x+= 0.5;  */
  51         fadds   fp1,fp1,fp13    /* x+= TWO23;  */
  52         fsubs   fp1,fp1,fp13    /* x-= TWO23;  */
  53         fabs    fp1,fp1         /* if (x == 0.0)  */
  54                                 /* x = 0.0; */
  55         mtfsf   0x01,fp11       /* restore previous rounding mode.  */
  56         blr
  57 .L4:
  58         fsubs   fp9,fp1,fp10    /* x+= 0.5;  */
  59         bge-    cr6,.L9         /* if (x < 0.0)  */
  60         fsubs   fp1,fp9,fp13    /* x-= TWO23;  */
  61         fadds   fp1,fp1,fp13    /* x+= TWO23;  */
  62         fnabs   fp1,fp1         /* if (x == 0.0)  */
  63                                 /* x = -0.0; */
  64 .L9:
  65         mtfsf   0x01,fp11       /* restore previous rounding mode.  */
  66         blr
  67         END (__roundf)
  68
  69 weak_alias (__roundf, roundf)
  70