sysdeps/powerpc/powerpc64/power7/fpu/s_isinf.S

   1 /* isinf().  PowerPC64/POWER7 version.
   2    Copyright (C) 2010-2014 Free Software Foundation, Inc.
   3    Contributed by Luis Machado <luisgpm@br.ibm.com>.
   4    This file is part of the GNU C Library.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library; if not, see
  18    <http://www.gnu.org/licenses/>.  */
  19
  20 #include <sysdep.h>
  21 #include <math_ldbl_opt.h>
  22
  23 /* int __isinf(x)  */
  24         .section    ".toc","aw"
  25 .LC0:   /* 1.0 */
  26         .tc         FD_ONE[TC],0x3ff0000000000000
  27         .section    ".text"
  28         .type       __isinf, @function
  29         .machine    power7
  30 EALIGN (__isinf, 4, 0)
  31         CALL_MCOUNT 0
  32         lfd     fp0,.LC0@toc(r2)
  33         ftdiv   cr7,fp1,fp0
  34         li      r3,0
  35         bflr    29            /* If not INF, return.  */
  36
  37         /* Either we have -INF/+INF or a denormal.  */
  38
  39         stfd    fp1,-16(r1)   /* Transfer FP to GPR's.  */
  40         ori     2,2,0         /* Force a new dispatch group.  */
  41         lhz     r4,-16+HISHORT(r1)  /* Fetch the upper 16 bits of the FP value
  42                                     (biased exponent and sign bit).  */
  43         cmpwi   cr7,r4,0x7ff0 /* r4 == 0x7ff0?  */
  44         li      r3,1
  45         beqlr   cr7           /* EQ means INF, otherwise -INF.  */
  46         li      r3,-1
  47         blr
  48         END (__isinf)
  49
  50 hidden_def (__isinf)
  51 weak_alias (__isinf, isinf)
  52
  53 /* It turns out that the 'double' version will also always work for
  54    single-precision.  */
  55 strong_alias (__isinf, __isinff)
  56 hidden_def (__isinff)
  57 weak_alias (__isinff, isinff)
  58
  59 #ifdef NO_LONG_DOUBLE
  60 strong_alias (__isinf, __isinfl)
  61 weak_alias (__isinf, isinfl)
  62 #endif
  63
  64 #ifndef IS_IN_libm
  65 # if LONG_DOUBLE_COMPAT(libc, GLIBC_2_0)
  66 compat_symbol (libc, __isinf, __isinfl, GLIBC_2_0);
  67 compat_symbol (libc, isinf, isinfl, GLIBC_2_0);
  68 # endif
  69 #endif