sysdeps/s390/multiarch/strchr-vx.S

   1 /* Vector optimized 32/64 bit S/390 version of strchr.
   2    Copyright (C) 2015-2018 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 #if defined HAVE_S390_VX_ASM_SUPPORT && IS_IN (libc)
  20
  21 # include "sysdep.h"
  22 # include "asm-syntax.h"
  23
  24         .text
  25
  26 /* char *strchr (const char *s, int c)
  27    Locate character in string.
  28
  29    Register usage:
  30    -r1=tmp
  31    -r2=s
  32    -r3=c
  33    -r4=tmp
  34    -r5=current_len
  35    -v16=part of s
  36    -v17=index of unequal
  37    -v18=replicated c
  38 */
  39 ENTRY(__strchr_vx)
  40         .machine "z13"
  41         .machinemode "zarch_nohighgprs"
  42
  43         vlbb    %v16,0(%r2),6   /* Load s until next 4k-byte boundary.  */
  44         lcbb    %r1,0(%r2),6    /* Get bytes to 4k-byte boundary or 16.  */
  45
  46         lghi    %r5,0           /* current_len = 0.  */
  47
  48         vlvgb   %v18,%r3,0      /* Generate vector which elements are all c.
  49                                    If c > 255, c will be truncated.  */
  50         vrepb   %v18,%v18,0
  51
  52         vfeezbs %v16,%v16,%v18  /* Find element equal with zero search.  */
  53         vlgvb   %r4,%v16,7      /* Load byte index of character or zero.  */
  54         clrjl   %r4,%r1,.Lfound /* Return if c/zero is in loaded bytes.  */
  55
  56         /* Align s to 16 byte.  */
  57         risbgn  %r4,%r2,60,128+63,0 /* %r3 = bits 60-63 of %r2 'and' 15.  */
  58         lghi    %r5,16          /* current_len = 16.  */
  59         slr     %r5,%r4         /* Compute bytes to 16bytes boundary.  */
  60
  61         /* Find c/zero in 16 byte aligned loop */
  62 .Lloop:
  63         vl      %v16,0(%r5,%r2) /* Load s.  */
  64         vfeezbs %v16,%v16,%v18  /* Find element equal with zero search.  */
  65         jno     .Lfound         /* Found c/zero (cc=0|1|2).  */
  66         vl      %v16,16(%r5,%r2)
  67         vfeezbs %v16,%v16,%v18
  68         jno     .Lfound16
  69         vl      %v16,32(%r5,%r2)
  70         vfeezbs %v16,%v16,%v18
  71         jno     .Lfound32
  72         vl      %v16,48(%r5,%r2)
  73         vfeezbs %v16,%v16,%v18
  74         jno     .Lfound48
  75
  76         aghi    %r5,64
  77         j       .Lloop          /* No character and no zero -> loop.  */
  78
  79 .Lfound48:
  80         la      %r5,16(%r5)     /* Use la since aghi would clobber cc.  */
  81 .Lfound32:
  82         la      %r5,16(%r5)
  83 .Lfound16:
  84         la      %r5,16(%r5)
  85 .Lfound:
  86         je      .Lzero          /* Found zero, but no c before that zero.  */
  87
  88 .Lcharacter:
  89         vlgvb   %r4,%v16,7      /* Load byte index of character.  */
  90         algr    %r5,%r4
  91         la      %r2,0(%r5,%r2)  /* Return pointer to character.  */
  92         br      %r14
  93
  94 .Lzero:
  95         llgcr   %r3,%r3         /* char c_char = (char) c.  */
  96         clije   %r3,0,.Lcharacter /* Found zero and c is zero.  */
  97         lghi    %r2,0           /* Return null if character not found.  */
  98         br      %r14
  99 END(__strchr_vx)
 100 #endif /* HAVE_S390_VX_ASM_SUPPORT && IS_IN (libc) */