sysdeps/s390/s390-32/add_n.S

   1 /* Add two limb vectors of the same length > 0 and store sum in a third
   2    limb vector.
   3    Copyright (C) 2000-2016 Free Software Foundation, Inc.
   4    Contributed by Martin Schwidefsky (schwidefsky@de.ibm.com).
   5    This file is part of the GNU MP Library.
   6
   7    The GNU MP Library is free software; you can redistribute it and/or modify
   8    it under the terms of the GNU Lesser General Public License as published by
   9    the Free Software Foundation; either version 2.1 of the License, or (at your
  10    option) any later version.
  11
  12    The GNU MP Library is distributed in the hope that it will be useful, but
  13    WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  14    or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General Public
  15    License for more details.
  16
  17    You should have received a copy of the GNU Lesser General Public License
  18    along with the GNU MP Library; see the file COPYING.LIB.  If not,
  19    see <http://www.gnu.org/licenses/>.  */
  20
  21 /*
  22   INPUT PARAMETERS
  23   res_ptr       %r2
  24   s1_ptr        %r3
  25   s2_ptr        %r4
  26   size          %r5
  27 */
  28
  29 #include "sysdep.h"
  30 #include "asm-syntax.h"
  31
  32         .text
  33 ENTRY(__mpn_add_n)
  34         st     %r6,24(%r15)   # save register 6
  35         cfi_offset (%r6, -72)
  36         sr     %r1,%r1
  37         lhi    %r0,1          # cannot use ahi to add carry, use alr
  38 .L0:    l      %r6,0(%r1,%r3) # .L0 -> no carry from last add
  39         al     %r6,0(%r1,%r4)
  40         st     %r6,0(%r1,%r2)
  41         la     %r1,4(0,%r1)
  42         brc    3,.L3
  43 .L1:    brct   %r5,.L0
  44         slr    %r2,%r2        # no last carry to return
  45         j      .Lexit
  46 .L2:    l      %r6,0(%r1,%r3) # .L2 -> carry from last add
  47         al     %r6,0(%r1,%r4)
  48         brc    3,.L4
  49         alr    %r6,%r0        # no carry yet, add carry from last add
  50         st     %r6,0(%r1,%r2)
  51         la     %r1,4(0,%r1)
  52         brc    12,.L1          # new carry ?
  53 .L3:    brct   %r5,.L2
  54         lr     %r2,%r0        # return last carry
  55         j      .Lexit
  56 .L4:    alr    %r6,%r0        # already a carry, add carry from last add
  57         st     %r6,0(%r1,%r2)
  58         la     %r1,4(0,%r1)
  59         brct   %r5,.L2
  60         lr     %r2,%r0        # return last carry
  61 .Lexit: l      %r6,24(%r15)   # restore register 6
  62         br     %r14
  63 END(__mpn_add_n)