sysdeps/s390/s390-32/s390-mcount.S

   1 /* S/390-specific implemetation of profiling support.
   2    Copyright (C) 2000-2015 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4    Contributed by Martin Schwidefsky (schwidefsky@de.ibm.com)
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library; if not, see
  18    <http://www.gnu.org/licenses/>.  */
  19
  20 #include <sysdep.h>
  21
  22 /*
  23  * How profiling works on S/390:
  24  * On the start of each function _mcount is called with the address of a
  25  * data word in %r1 (initialized to 0, used for counting). The compiler
  26  * with the option -p generates code of the form:
  27  *
  28  *         STM    6,15,24(15)
  29  *         BRAS   13,.LTN0_0
  30  * .LT0_0:
  31  * .LC12:  .long  _mcount
  32  * .LC13:  .long  .LP0
  33  *         .data
  34  *         .align 4
  35  * .LP0:   .long  0
  36  *         .text
  37  * # function profiler
  38  *         st     14,4(15)
  39  *         l      14,.LC12-.LT0_0(13)
  40  *         l      1,.LC13-.LT0_0(13)
  41  *         basr   14,14
  42  *         l      14,4(15)
  43  *
  44  * The _mcount implementation now has to call __mcount_internal with the
  45  * address of .LP0 as first parameter and the return address as second
  46  * parameter. &.LP0 was loaded to %r1 and the return address is in %r14.
  47  * _mcount may not modify any register.
  48  */
  49
  50         .globl C_SYMBOL_NAME(_mcount)
  51         .type C_SYMBOL_NAME(_mcount), @function
  52         cfi_startproc
  53         .align ALIGNARG(4)
  54 C_LABEL(_mcount)
  55         /* Save the caller-clobbered registers.  */
  56         ahi   %r15,-128
  57         cfi_adjust_cfa_offset (128)
  58         stm   %r14,%r5,96(%r15)
  59         cfi_offset (r14, 0)
  60         cfi_offset (r15, 4)
  61         l     %r2,132(%r15)       # callers address  = first parameter
  62         la    %r2,0(%r2)          # clear bit 0
  63         la    %r3,0(%r14)         # callees address  = second parameter
  64
  65 #ifdef PIC
  66         bras  %r14,0f
  67         .long _GLOBAL_OFFSET_TABLE_-.
  68 0:      al    %r14,0(%r14)
  69         l     %r14,__mcount_internal@GOT(%r14)
  70 #else
  71         bras  %r14,0f
  72         .long __mcount_internal
  73 0:      l     %r14,0(%r14)
  74 #endif
  75         basr  %r14,%r14
  76
  77         /*
  78          * Pop the saved registers.  Please note that `mcount' has no
  79          * return value.
  80          */
  81         lm    %r14,%r5,96(%r15)
  82         ahi   %r15,128
  83         cfi_adjust_cfa_offset (-128)
  84         br    %r14
  85         cfi_endproc
  86         ASM_SIZE_DIRECTIVE(C_SYMBOL_NAME(_mcount))
  87
  88 #undef mcount
  89 weak_alias (_mcount, mcount)