sysdeps/sparc/sparc32/elf/start.S

   1 /* Startup code for elf32-sparc
   2    Copyright (C) 1997, 1998, 2002, 2004, 2007, 2009
   3    Free Software Foundation, Inc.
   4    This file is part of the GNU C Library.
   5    Contributed by Richard Henderson <richard@gnu.ai.mit.edu>, 1997.
   6
   7    The GNU C Library is free software; you can redistribute it and/or
   8    modify it under the terms of the GNU Lesser General Public
   9    License as published by the Free Software Foundation; either
  10    version 2.1 of the License, or (at your option) any later version.
  11
  12    In addition to the permissions in the GNU Lesser General Public
  13    License, the Free Software Foundation gives you unlimited
  14    permission to link the compiled version of this file with other
  15    programs, and to distribute those programs without any restriction
  16    coming from the use of this file. (The GNU Lesser General Public
  17    License restrictions do apply in other respects; for example, they
  18    cover modification of the file, and distribution when not linked
  19    into another program.)
  20
  21    Note that people who make modified versions of this file are not
  22    obligated to grant this special exception for their modified
  23    versions; it is their choice whether to do so. The GNU Lesser
  24    General Public License gives permission to release a modified
  25    version without this exception; this exception also makes it
  26    possible to release a modified version which carries forward this
  27    exception.
  28
  29    The GNU C Library is distributed in the hope that it will be useful,
  30    but WITHOUT ANY WARRANTY; without even the implied warranty of
  31    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  32    Lesser General Public License for more details.
  33
  34    You should have received a copy of the GNU Lesser General Public
  35    License along with the GNU C Library; if not, see
  36    <http://www.gnu.org/licenses/>.  */
  37
  38 #include <sysdep.h>
  39
  40
  41         .section ".text"
  42         .align 4
  43 #ifdef SHARED
  44 .LLGETPC0:
  45         retl
  46          add    %o7, %l7, %l7
  47 #endif
  48         .global _start
  49         .type _start,#function
  50 _start:
  51 #ifdef SHARED
  52         sethi   %hi(_GLOBAL_OFFSET_TABLE_-4), %l7
  53         call    .LLGETPC0
  54          add    %l7, %lo(_GLOBAL_OFFSET_TABLE_+4), %l7
  55 #endif
  56
  57   /* Terminate the stack frame, and reserve space for functions to
  58      drop their arguments.  */
  59         mov     %g0, %fp
  60         sub     %sp, 6*4, %sp
  61
  62   /* Extract the arguments and environment as encoded on the stack.  The
  63      argument info starts after one register window (16 words) past the SP.  */
  64         ld      [%sp+22*4], %o1
  65         add     %sp, 23*4, %o2
  66
  67   /* Load the addresses of the user entry points.  */
  68         sethi   %hi(main), %o0
  69         sethi   %hi(__libc_csu_init), %o3
  70         sethi   %hi(__libc_csu_fini), %o4
  71         or      %o0, %lo(main), %o0
  72         or      %o3, %lo(__libc_csu_init), %o3
  73         or      %o4, %lo(__libc_csu_fini), %o4
  74 #ifdef SHARED
  75         ld      [%l7 + %o0], %o0
  76         ld      [%l7 + %o3], %o3
  77         ld      [%l7 + %o4], %o4
  78 #endif
  79
  80   /* When starting a binary via the dynamic linker, %g1 contains the
  81      address of the shared library termination function, which will be
  82      registered with atexit().  If we are statically linked, this will
  83      be NULL.  */
  84         mov     %g1, %o5
  85
  86   /* Let libc do the rest of the initialization, and call main.  */
  87         call    __libc_start_main
  88          nop
  89
  90   /* Die very horribly if exit returns.  */
  91         unimp
  92
  93         .size _start, .-_start
  94
  95 /* Define a symbol for the first piece of initialized data.  */
  96         .data
  97         .globl  __data_start
  98 __data_start:
  99         .long   0
 100 weak_alias (__data_start, data_start)