sysdeps/sparc/sparc32/sparcv9/fpu/multiarch/s_floorf-vis3.S

   1 /* Float floor function, sparc32 v9 vis3 version.
   2    Copyright (C) 2012-2016 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4    Contributed by David S. Miller <davem@davemloft.net>, 2012.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library; if not, see
  18    <http://www.gnu.org/licenses/>.  */
  19
  20 #include <sysdep.h>
  21
  22         /* 'siam' (Set Interval Arithmetic Mode) is used to quickly override
  23            the rounding mode during this routine.
  24
  25            We add then subtract (or subtract than add if the initial
  26            value was negative) 2**23 to the value, then subtract it
  27            back out.
  28
  29            This will clear out the fractional portion of the value and,
  30            with suitable 'siam' initiated rouding mode settings, round
  31            the final result in the proper direction.
  32
  33            We also use VIS3 moves to avoid using the stack to transfer
  34            values between float and integer registers.  */
  35
  36 #define TWO_TWENTYTHREE 0x4b000000              /* 2**23 */
  37
  38 #define ZERO            %f10                    /* 0.0 */
  39 #define SIGN_BIT        %f12                    /* -0.0 */
  40
  41 ENTRY (__floorf_vis3)
  42         movwtos %o0, %f0
  43         sethi   %hi(TWO_TWENTYTHREE), %o2
  44         fzeros  ZERO
  45         fnegs   ZERO, SIGN_BIT
  46         movwtos %o2, %f16
  47         fabss   %f0, %f14
  48         fcmps   %fcc3, %f14, %f16
  49         fmovsuge %fcc3, ZERO, %f16
  50         fands   %f0, SIGN_BIT, SIGN_BIT
  51         fors    %f16, SIGN_BIT, %f16
  52         siam    (1 << 2) | 3
  53         fadds   %f0, %f16, %f1
  54         siam    (1 << 2) | 0
  55         fsubs   %f1, %f16, %f1
  56         siam    (0 << 2)
  57         retl
  58          fors   %f1, SIGN_BIT, %f0
  59 END (__floorf_vis3)