sysdeps/sparc/sparc32/sparcv9/fpu/s_rintf.S

   1 /* Round float to int floating-point values, sparc32 v9 version.
   2    Copyright (C) 2012-2019 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4    Contributed by David S. Miller <davem@davemloft.net>, 2012.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library; if not, see
  18    <https://www.gnu.org/licenses/>.  */
  19
  20 #include <sysdep.h>
  21 #include <libm-alias-float.h>
  22
  23         /* We pop constants into the FPU registers using the incoming
  24            argument stack slots, since this avoid having to use any PIC
  25            references.  We also thus avoid having to allocate a register
  26            window.
  27
  28            VIS instructions are used to facilitate the formation of
  29            easier constants, and the propagation of the sign bit.  */
  30
  31 #define TWO_TWENTYTHREE 0x4b000000              /* 2**23 */
  32
  33 #define ZERO            %f10                    /* 0.0 */
  34 #define SIGN_BIT        %f12                    /* -0.0 */
  35
  36 ENTRY (__rintf)
  37         st      %o0, [%sp + 68]
  38         sethi   %hi(TWO_TWENTYTHREE), %o2
  39         fzeros  ZERO
  40
  41         ld      [%sp + 68], %f1
  42         fnegs   ZERO, SIGN_BIT
  43
  44         st      %o2, [%sp + 68]
  45         fabss   %f1, %f14
  46
  47         ld      [%sp + 68], %f16
  48         fcmps   %fcc3, %f14, %f16
  49
  50         fmovsuge %fcc3, ZERO, %f16
  51         fands   %f1, SIGN_BIT, SIGN_BIT
  52
  53         fors    %f16, SIGN_BIT, %f16
  54         fadds   %f1, %f16, %f5
  55         fsubs   %f5, %f16, %f0
  56         fabss   %f0, %f0
  57         retl
  58          fors   %f0, SIGN_BIT, %f0
  59 END (__rintf)
  60 libm_alias_float (__rint, rint)