sysdeps/sparc/sparc32/sparcv9/fpu/s_trunc.S

   1 /* Truncate argument to nearest integral value not larger than
   2    the argument, sparc32 v9 version.
   3
   4    Copyright (C) 2013-2014 Free Software Foundation, Inc.
   5    This file is part of the GNU C Library.
   6    Contributed by David S. Miller <davem@davemloft.net>, 2013.
   7
   8    The GNU C Library is free software; you can redistribute it and/or
   9    modify it under the terms of the GNU Lesser General Public
  10    License as published by the Free Software Foundation; either
  11    version 2.1 of the License, or (at your option) any later version.
  12
  13    The GNU C Library is distributed in the hope that it will be useful,
  14    but WITHOUT ANY WARRANTY; without even the implied warranty of
  15    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16    Lesser General Public License for more details.
  17
  18    You should have received a copy of the GNU Lesser General Public
  19    License along with the GNU C Library; if not, see
  20    <http://www.gnu.org/licenses/>.  */
  21
  22 #include <sysdep.h>
  23 #include <math_ldbl_opt.h>
  24
  25         /* We pop constants into the FPU registers using the incoming
  26            argument stack slots, since this avoid having to use any PIC
  27            references.  We also thus avoid having to allocate a register
  28            window.
  29
  30            VIS instructions are used to facilitate the formation of
  31            easier constants, and the propagation of the sign bit.  */
  32
  33 #define TWO_FIFTYTWO    0x43300000              /* 2**52 */
  34
  35 #define ZERO            %f10                    /* 0.0 */
  36 #define SIGN_BIT        %f12                    /* -0.0 */
  37
  38 ENTRY (__trunc)
  39         sethi   %hi(TWO_FIFTYTWO), %o2
  40         sllx    %o0, 32, %o0
  41         or      %o0, %o1, %o0
  42         fzero   ZERO
  43         stx     %o0, [%sp + 72]
  44         sllx    %o2, 32, %o2
  45         fnegd   ZERO, SIGN_BIT
  46         ldd     [%sp + 72], %f0
  47         stx     %o2, [%sp + 72]
  48         fabsd   %f0, %f14
  49         ldd     [%sp + 72], %f16
  50         fcmpd   %fcc3, %f14, %f16
  51         fmovduge %fcc3, ZERO, %f14
  52         fand    %f0, SIGN_BIT, SIGN_BIT
  53         fdtox   %f14, %f14
  54         fxtod   %f14, %f14
  55         faddd   %f0, ZERO, %f18
  56         fmovduge %fcc3, %f18, %f14
  57         retl
  58          for    %f14, SIGN_BIT, %f0
  59 END (__trunc)
  60 weak_alias (__trunc, trunc)
  61
  62 #if LONG_DOUBLE_COMPAT(libm, GLIBC_2_1)
  63 compat_symbol (libm, __trunc, truncl, GLIBC_2_1)
  64 #endif