sysdeps/sparc/sparc64/fpu/s_nearbyintf.S

   1 /* Round float to int floating-point values without generating
   2    an inexact exception, sparc64 version.
   3
   4    Copyright (C) 2013-2019 Free Software Foundation, Inc.
   5    This file is part of the GNU C Library.
   6    Contributed by David S. Miller <davem@davemloft.net>, 2013.
   7
   8    The GNU C Library is free software; you can redistribute it and/or
   9    modify it under the terms of the GNU Lesser General Public
  10    License as published by the Free Software Foundation; either
  11    version 2.1 of the License, or (at your option) any later version.
  12
  13    The GNU C Library is distributed in the hope that it will be useful,
  14    but WITHOUT ANY WARRANTY; without even the implied warranty of
  15    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16    Lesser General Public License for more details.
  17
  18    You should have received a copy of the GNU Lesser General Public
  19    License along with the GNU C Library; if not, see
  20    <http://www.gnu.org/licenses/>.  */
  21
  22 #include <sysdep.h>
  23 #include <libm-alias-float.h>
  24
  25         /* We pop constants into the FPU registers using the incoming
  26            argument stack slots, since this avoid having to use any PIC
  27            references.  We also thus avoid having to allocate a register
  28            window.
  29
  30            VIS instructions are used to facilitate the formation of
  31            easier constants, and the propagation of the sign bit.  */
  32
  33 #define TWO_TWENTYTHREE 0x4b000000              /* 2**23 */
  34
  35 #define ZERO            %f10                    /* 0.0 */
  36 #define SIGN_BIT        %f12                    /* -0.0 */
  37
  38 ENTRY (__nearbyintf)
  39         fcmps   %fcc3, %f1, %f1                 /* Check for sNaN */
  40         stx     %fsr, [%sp + STACK_BIAS + 144]
  41         sethi   %hi(0xf8003e0), %o5
  42         sethi   %hi(TWO_TWENTYTHREE), %o2
  43         ldx     [%sp + STACK_BIAS + 144], %o4
  44         or      %o5, %lo(0xf8003e0), %o5
  45         fzeros  ZERO
  46         andn    %o4, %o5, %o4
  47         fnegs   ZERO, SIGN_BIT
  48         st      %o2, [%sp + STACK_BIAS + 128]
  49         stx     %o4, [%sp + STACK_BIAS + 136]
  50         ldx     [%sp + STACK_BIAS + 136], %fsr
  51         fabss   %f1, %f14
  52         ld      [%sp + STACK_BIAS + 128], %f16
  53         fcmps   %fcc3, %f14, %f16
  54         fmovsuge %fcc3, ZERO, %f16
  55         fands   %f1, SIGN_BIT, SIGN_BIT
  56         fors    %f16, SIGN_BIT, %f16
  57         fadds   %f1, %f16, %f5
  58         fsubs   %f5, %f16, %f0
  59         fabss   %f0, %f0
  60         fors    %f0, SIGN_BIT, %f0
  61         retl
  62          ldx    [%sp + STACK_BIAS + 144], %fsr
  63 END (__nearbyintf)
  64 libm_alias_float (__nearbyint, nearbyint)