sysdeps/sparc/sparc64/fpu/s_rint.S

   1 /* Round float to int floating-point values, sparc64 version.
   2    Copyright (C) 2012-2019 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4    Contributed by David S. Miller <davem@davemloft.net>, 2012.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library; if not, see
  18    <http://www.gnu.org/licenses/>.  */
  19
  20 #include <sysdep.h>
  21 #include <libm-alias-double.h>
  22
  23         /* We pop constants into the FPU registers using the incoming
  24            argument stack slots, since this avoid having to use any PIC
  25            references.  We also thus avoid having to allocate a register
  26            window.
  27
  28            VIS instructions are used to facilitate the formation of
  29            easier constants, and the propagation of the sign bit.  */
  30
  31 #define TWO_FIFTYTWO    0x43300000              /* 2**52 */
  32
  33 #define ZERO            %f10                    /* 0.0 */
  34 #define SIGN_BIT        %f12                    /* -0.0 */
  35
  36 ENTRY (__rint)
  37         sethi   %hi(TWO_FIFTYTWO), %o2
  38         sllx    %o2, 32, %o2
  39         fzero   ZERO
  40
  41         fnegd   ZERO, SIGN_BIT
  42         stx     %o2, [%sp + STACK_BIAS + 128]
  43         fabsd   %f0, %f14
  44
  45         ldd     [%sp + STACK_BIAS + 128], %f16
  46         fcmpd   %fcc3, %f14, %f16
  47
  48         fmovduge %fcc3, ZERO, %f16
  49         fand    %f0, SIGN_BIT, SIGN_BIT
  50
  51         for     %f16, SIGN_BIT, %f16
  52         faddd   %f0, %f16, %f6
  53         fsubd   %f6, %f16, %f0
  54         fabsd   %f0, %f0
  55         retl
  56          for    %f0, SIGN_BIT, %f0
  57 END (__rint)
  58 libm_alias_double (__rint, rint)