sysdeps/sparc/sparc64/submul_1.S

   1 /* SPARC v9 __mpn_submul_1 -- Multiply a limb vector with a single limb and
   2    subtract the product from a second limb vector.
   3
   4    Copyright (C) 1996-2019 Free Software Foundation, Inc.
   5
   6    This file is part of the GNU MP Library.
   7
   8    The GNU MP Library is free software; you can redistribute it and/or modify
   9    it under the terms of the GNU Lesser General Public License as published by
  10    the Free Software Foundation; either version 2.1 of the License, or (at your
  11    option) any later version.
  12
  13    The GNU MP Library is distributed in the hope that it will be useful, but
  14    WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  15    or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General Public
  16    License for more details.
  17
  18    You should have received a copy of the GNU Lesser General Public License
  19    along with the GNU MP Library; see the file COPYING.LIB.  If not,
  20    see <http://www.gnu.org/licenses/>.  */
  21
  22 #include <sysdep.h>
  23
  24
  25 /* INPUT PARAMETERS
  26    res_ptr      o0
  27    s1_ptr       o1
  28    size         o2
  29    s2_limb      o3  */
  30
  31 ENTRY(__mpn_submul_1)
  32         save    %sp,-192,%sp
  33
  34         sub     %g0,%i2,%o7
  35         mov     0,%o0                   ! zero cy_limb
  36         sllx    %o7,3,%o7
  37         sethi   %hi(0x80000000),%o2
  38         srl     %i3,0,%o1               ! extract low 32 bits of s2_limb
  39         sub     %i1,%o7,%o3
  40         srlx    %i3,32,%i3              ! extract high 32 bits of s2_limb
  41         sub     %i0,%o7,%o4
  42         add     %o2,%o2,%o2             ! o2 = 0x100000000
  43
  44         !   hi   !
  45              !  mid-1 !
  46              !  mid-2 !
  47                  !   lo   !
  48 1:
  49         ldx     [%o3+%o7],%g5
  50         srl     %g5,0,%i0               ! zero hi bits
  51         ldx     [%o4+%o7],%l1
  52         srlx    %g5,32,%g5
  53         mulx    %o1,%i0,%i4             ! lo product
  54         mulx    %i3,%i0,%i1             ! mid-1 product
  55         mulx    %o1,%g5,%l2             ! mid-2 product
  56         mulx    %i3,%g5,%i5             ! hi product
  57         srlx    %i4,32,%i0              ! extract high 32 bits of lo product...
  58         add     %i1,%i0,%i1             ! ...and add it to the mid-1 product
  59         addcc   %i1,%l2,%i1             ! add mid products
  60         mov     0,%l0                   ! we need the carry from that add...
  61         movcs   %xcc,%o2,%l0            ! ...compute it and...
  62         sllx    %i1,32,%i0              !  align low bits of mid product
  63         add     %i5,%l0,%i5             ! ...add to bit 32 of the hi product
  64         srl     %i4,0,%g5               ! zero high 32 bits of lo product
  65         add     %i0,%g5,%i0             ! combine into low 64 bits of result
  66         srlx    %i1,32,%i1              ! extract high bits of mid product...
  67         addcc   %i0,%o0,%i0             !  add cy_limb to low 64 bits of result
  68         add     %i5,%i1,%i1             ! ...and add them to the high result
  69         mov     0,%g5
  70         movcs   %xcc,1,%g5
  71         subcc   %l1,%i0,%i0
  72         stx     %i0,[%o4+%o7]
  73         add     %g5,1,%l1
  74         movcs   %xcc,%l1,%g5
  75         addcc   %o7,8,%o7
  76         bne,pt  %xcc,1b
  77          add    %i1,%g5,%o0             ! compute new cy_limb
  78
  79         jmpl    %i7+8, %g0
  80          restore %o0,%g0,%o0
  81
  82 END(__mpn_submul_1)