sysdeps/unix/sysv/linux/m68k/clone.S

   1 /* Copyright (C) 1996-2019 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3    Contributed by Andreas Schwab (schwab@issan.informatik.uni-dortmund.de)
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library.  If not, see
  17    <https://www.gnu.org/licenses/>.  */
  18
  19 /* clone() is even more special than fork() as it mucks with stacks
  20    and invokes a function in the right context after its all over.  */
  21
  22 #include <sysdep.h>
  23 #define _ERRNO_H        1
  24 #include <bits/errno.h>
  25 #include <tls.h>
  26
  27 /* int clone(int (*fn)(void *arg), void *child_stack, int flags, void *arg,
  28              void *parent_tidptr, void *tls, void *child_tidptr) */
  29
  30         .text
  31 ENTRY (__clone)
  32
  33         /* Sanity check arguments.  */
  34         movel   #-EINVAL, %d0
  35         movel   4(%sp), %a0             /* no NULL function pointers */
  36         tstl    %a0
  37         jeq     SYSCALL_ERROR_LABEL
  38         movel   8(%sp), %a1             /* no NULL stack pointers */
  39         tstl    %a1
  40         jeq     SYSCALL_ERROR_LABEL
  41
  42         /* Allocate space and copy the argument onto the new stack.  */
  43         movel   16(%sp), -(%a1)
  44
  45         /* Do the system call */
  46         movel   12+0(%sp), %d1          /* get flags */
  47         movel   %d3, -(%a1)             /* save %d3 and get parent_tidptr */
  48         movel   %d3, -(%sp)
  49         cfi_adjust_cfa_offset (4)
  50         cfi_rel_offset (%d3, 0)
  51         movel   20+4(%sp), %d3
  52         movel   %d4, -(%a1)             /* save %d4 and get child_tidptr */
  53         movel   %d4, -(%sp)
  54         cfi_adjust_cfa_offset (4)
  55         cfi_rel_offset (%d4, 0)
  56         movel   28+8(%sp), %d4
  57         movel   %d5, -(%a1)             /* save %d5 and get tls */
  58         movel   %d5, -(%sp)
  59         cfi_adjust_cfa_offset (4)
  60         cfi_rel_offset (%d5, 0)
  61         movel   24+12(%sp), %d5
  62         /* save %d2 and get stack pointer */
  63 #ifdef __mcoldfire__
  64         movel   %d2, -(%a1)
  65         movel   %d2, -(%sp)
  66         cfi_adjust_cfa_offset (4)
  67         cfi_rel_offset (%d2, 0)
  68         movel   %a1, %d2
  69 #else
  70         exg     %d2, %a1                /* save %d2 and get stack pointer */
  71         cfi_register (%d2, %a1)
  72 #endif
  73         movel   #SYS_ify (clone), %d0
  74
  75         /* End FDE now, because in the child the unwind info will be
  76            wrong.  */
  77         cfi_endproc
  78
  79         trap    #0
  80 #ifdef __mcoldfire__
  81         movel   (%sp)+, %d2
  82 #else
  83         exg     %d2, %a1                /* restore %d2 */
  84 #endif
  85         movel   (%sp)+, %d5             /* restore %d5, %d4 and %d3 */
  86         movel   (%sp)+, %d4
  87         movel   (%sp)+, %d3
  88
  89         tstl    %d0
  90         jmi     SYSCALL_ERROR_LABEL
  91         jeq     1f
  92
  93         rts
  94
  95 1:
  96         cfi_startproc
  97         cfi_undefined (pc)      /* Mark end of stack */
  98         subl    %fp, %fp        /* terminate the stack frame */
  99         jsr     (%a0)
 100         movel   %d0, %d1
 101         movel   #SYS_ify (exit), %d0
 102         trap    #0
 103         cfi_endproc
 104
 105         cfi_startproc
 106 PSEUDO_END (__clone)
 107
 108 libc_hidden_def (__clone)
 109 weak_alias (__clone, clone)