sysdeps/unix/sysv/linux/mips/swapcontext.S

   1 /* Save and set current context.
   2    Copyright (C) 2009-2019 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4    Contributed by Maciej W. Rozycki <macro@codesourcery.com>.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library.  If not, see
  18    <https://www.gnu.org/licenses/>.  */
  19
  20 #include <sysdep.h>
  21 #include <sys/asm.h>
  22 #include <sys/fpregdef.h>
  23 #include <sys/regdef.h>
  24
  25 #include "ucontext_i.h"
  26
  27 /* int swapcontext (ucontext_t *oucp, const ucontext_t *ucp) */
  28
  29         .text
  30         .set    nomips16
  31 LOCALSZ = 0
  32 ARGSZ = 0
  33 MASK = 0x00000000
  34 #ifdef __PIC__
  35 LOCALSZ = 1                                             /* save gp */
  36 #endif
  37 #if _MIPS_SIM != _ABIO32
  38 ARGSZ = 1                                               /* save a1 */
  39 # ifdef __PIC__
  40 MASK = 0x10000000
  41 # endif
  42 #endif
  43 FRAMESZ = (((ARGSZ + LOCALSZ) * SZREG) + ALSZ) & ALMASK
  44 GPOFF = FRAMESZ - ((ARGSZ + 1) * SZREG)
  45 #if _MIPS_SIM != _ABIO32
  46 A1OFF = FRAMESZ - (1 * SZREG)                           /* callee-allocated */
  47 #else
  48 A1OFF = FRAMESZ + (1 * SZREG)                           /* caller-allocated */
  49 #endif
  50 MCONTEXT_GREGSZ = 8
  51 #if _MIPS_SIM == _ABIO32 && __BYTE_ORDER__ == __ORDER_BIG_ENDIAN__
  52 MCONTEXT_GREGOFF = 4
  53 #else
  54 MCONTEXT_GREGOFF = 0
  55 #endif
  56
  57 NESTED (__swapcontext, FRAMESZ, ra)
  58         .mask   MASK, -(ARGSZ * SZREG)
  59         .fmask  0x00000000, 0
  60
  61 #ifdef __PIC__
  62         SETUP_GP
  63
  64         move    a2, sp
  65 # define _SP a2
  66
  67 # if _MIPS_SIM != _ABIO32
  68         move    a3, gp
  69 #  define _GP a3
  70 # endif
  71
  72         PTR_ADDIU sp, -FRAMESZ
  73         cfi_adjust_cfa_offset (FRAMESZ)
  74         SETUP_GP64_STACK (GPOFF, __swapcontext)
  75         SAVE_GP (GPOFF)
  76
  77 #else  /* ! __PIC__ */
  78 # define _SP sp
  79 # define _GP gp
  80
  81 #endif /* ! __PIC__ */
  82
  83 #ifdef PROF
  84         .set    noat
  85         move    AT, ra
  86         jal     _mcount
  87         .set    at
  88 #endif
  89
  90         REG_S   s0, (MCONTEXT_GREGOFF + 16 * MCONTEXT_GREGSZ + MCONTEXT_GREGS)(a0)
  91         REG_S   s1, (MCONTEXT_GREGOFF + 17 * MCONTEXT_GREGSZ + MCONTEXT_GREGS)(a0)
  92         REG_S   s2, (MCONTEXT_GREGOFF + 18 * MCONTEXT_GREGSZ + MCONTEXT_GREGS)(a0)
  93         REG_S   s3, (MCONTEXT_GREGOFF + 19 * MCONTEXT_GREGSZ + MCONTEXT_GREGS)(a0)
  94         REG_S   s4, (MCONTEXT_GREGOFF + 20 * MCONTEXT_GREGSZ + MCONTEXT_GREGS)(a0)
  95         REG_S   s5, (MCONTEXT_GREGOFF + 21 * MCONTEXT_GREGSZ + MCONTEXT_GREGS)(a0)
  96         REG_S   s6, (MCONTEXT_GREGOFF + 22 * MCONTEXT_GREGSZ + MCONTEXT_GREGS)(a0)
  97         REG_S   s7, (MCONTEXT_GREGOFF + 23 * MCONTEXT_GREGSZ + MCONTEXT_GREGS)(a0)
  98 #if ! defined (__PIC__) || _MIPS_SIM != _ABIO32
  99         REG_S   _GP, (MCONTEXT_GREGOFF + 28 * MCONTEXT_GREGSZ + MCONTEXT_GREGS)(a0)
 100 #endif
 101         REG_S   _SP, (MCONTEXT_GREGOFF + 29 * MCONTEXT_GREGSZ + MCONTEXT_GREGS)(a0)
 102         REG_S   fp, (MCONTEXT_GREGOFF + 30 * MCONTEXT_GREGSZ + MCONTEXT_GREGS)(a0)
 103         REG_S   ra, (MCONTEXT_GREGOFF + 31 * MCONTEXT_GREGSZ + MCONTEXT_GREGS)(a0)
 104         REG_S   ra, (MCONTEXT_GREGOFF + MCONTEXT_PC)(a0)
 105
 106 #ifdef __mips_hard_float
 107 # if _MIPS_SIM == _ABI64
 108         s.d     fs0, (24 * SZREG + MCONTEXT_FPREGS)(a0)
 109         s.d     fs1, (25 * SZREG + MCONTEXT_FPREGS)(a0)
 110         s.d     fs2, (26 * SZREG + MCONTEXT_FPREGS)(a0)
 111         s.d     fs3, (27 * SZREG + MCONTEXT_FPREGS)(a0)
 112         s.d     fs4, (28 * SZREG + MCONTEXT_FPREGS)(a0)
 113         s.d     fs5, (29 * SZREG + MCONTEXT_FPREGS)(a0)
 114         s.d     fs6, (30 * SZREG + MCONTEXT_FPREGS)(a0)
 115         s.d     fs7, (31 * SZREG + MCONTEXT_FPREGS)(a0)
 116
 117 # else  /* _MIPS_SIM != _ABI64 */
 118         s.d     fs0, (20 * SZREG + MCONTEXT_FPREGS)(a0)
 119         s.d     fs1, (22 * SZREG + MCONTEXT_FPREGS)(a0)
 120         s.d     fs2, (24 * SZREG + MCONTEXT_FPREGS)(a0)
 121         s.d     fs3, (26 * SZREG + MCONTEXT_FPREGS)(a0)
 122         s.d     fs4, (28 * SZREG + MCONTEXT_FPREGS)(a0)
 123         s.d     fs5, (30 * SZREG + MCONTEXT_FPREGS)(a0)
 124
 125 # endif /* _MIPS_SIM != _ABI64 */
 126
 127         cfc1    v1, fcr31
 128         sw      v1, MCONTEXT_FPC_CSR(a0)
 129 #endif /* __mips_hard_float */
 130
 131         REG_S   a1, A1OFF(sp)
 132
 133 /* rt_sigprocmask (SIG_SETMASK, &ucp->uc_sigmask, &oucp->uc_sigmask, _NSIG8) */
 134         li      a3, _NSIG8
 135         PTR_ADDU a2, a0, UCONTEXT_SIGMASK
 136         PTR_ADDU a1, a1, UCONTEXT_SIGMASK
 137         li      a0, SIG_SETMASK
 138
 139         li      v0, SYS_ify (rt_sigprocmask)
 140         syscall
 141         bnez    a3, 99f
 142
 143         REG_L   v0, A1OFF(sp)
 144
 145 #ifdef __mips_hard_float
 146 # if _MIPS_SIM == _ABI64
 147         l.d     fs0, (24 * SZREG + MCONTEXT_FPREGS)(v0)
 148         l.d     fs1, (25 * SZREG + MCONTEXT_FPREGS)(v0)
 149         l.d     fs2, (26 * SZREG + MCONTEXT_FPREGS)(v0)
 150         l.d     fs3, (27 * SZREG + MCONTEXT_FPREGS)(v0)
 151         l.d     fs4, (28 * SZREG + MCONTEXT_FPREGS)(v0)
 152         l.d     fs5, (29 * SZREG + MCONTEXT_FPREGS)(v0)
 153         l.d     fs6, (30 * SZREG + MCONTEXT_FPREGS)(v0)
 154         l.d     fs7, (31 * SZREG + MCONTEXT_FPREGS)(v0)
 155
 156 # else  /* _MIPS_SIM != _ABI64 */
 157         l.d     fs0, (20 * SZREG + MCONTEXT_FPREGS)(v0)
 158         l.d     fs1, (22 * SZREG + MCONTEXT_FPREGS)(v0)
 159         l.d     fs2, (24 * SZREG + MCONTEXT_FPREGS)(v0)
 160         l.d     fs3, (26 * SZREG + MCONTEXT_FPREGS)(v0)
 161         l.d     fs4, (28 * SZREG + MCONTEXT_FPREGS)(v0)
 162         l.d     fs5, (30 * SZREG + MCONTEXT_FPREGS)(v0)
 163
 164 # endif /* _MIPS_SIM != _ABI64 */
 165
 166         lw      v1, MCONTEXT_FPC_CSR(v0)
 167         ctc1    v1, fcr31
 168 #endif /* __mips_hard_float */
 169
 170         /* Note the contents of argument registers will be random
 171            unless makecontext() has been called.  */
 172         REG_L   a0, (MCONTEXT_GREGOFF + 4 * MCONTEXT_GREGSZ + MCONTEXT_GREGS)(v0)
 173         REG_L   a1, (MCONTEXT_GREGOFF + 5 * MCONTEXT_GREGSZ + MCONTEXT_GREGS)(v0)
 174         REG_L   a2, (MCONTEXT_GREGOFF + 6 * MCONTEXT_GREGSZ + MCONTEXT_GREGS)(v0)
 175         REG_L   a3, (MCONTEXT_GREGOFF + 7 * MCONTEXT_GREGSZ + MCONTEXT_GREGS)(v0)
 176 #if _MIPS_SIM != _ABIO32
 177         REG_L   a4, (MCONTEXT_GREGOFF + 8 * MCONTEXT_GREGSZ + MCONTEXT_GREGS)(v0)
 178         REG_L   a5, (MCONTEXT_GREGOFF + 9 * MCONTEXT_GREGSZ + MCONTEXT_GREGS)(v0)
 179         REG_L   a6, (MCONTEXT_GREGOFF + 10 * MCONTEXT_GREGSZ + MCONTEXT_GREGS)(v0)
 180         REG_L   a7, (MCONTEXT_GREGOFF + 11 * MCONTEXT_GREGSZ + MCONTEXT_GREGS)(v0)
 181 #endif
 182
 183         REG_L   s0, (MCONTEXT_GREGOFF + 16 * MCONTEXT_GREGSZ + MCONTEXT_GREGS)(v0)
 184         REG_L   s1, (MCONTEXT_GREGOFF + 17 * MCONTEXT_GREGSZ + MCONTEXT_GREGS)(v0)
 185         REG_L   s2, (MCONTEXT_GREGOFF + 18 * MCONTEXT_GREGSZ + MCONTEXT_GREGS)(v0)
 186         REG_L   s3, (MCONTEXT_GREGOFF + 19 * MCONTEXT_GREGSZ + MCONTEXT_GREGS)(v0)
 187         REG_L   s4, (MCONTEXT_GREGOFF + 20 * MCONTEXT_GREGSZ + MCONTEXT_GREGS)(v0)
 188         REG_L   s5, (MCONTEXT_GREGOFF + 21 * MCONTEXT_GREGSZ + MCONTEXT_GREGS)(v0)
 189         REG_L   s6, (MCONTEXT_GREGOFF + 22 * MCONTEXT_GREGSZ + MCONTEXT_GREGS)(v0)
 190         REG_L   s7, (MCONTEXT_GREGOFF + 23 * MCONTEXT_GREGSZ + MCONTEXT_GREGS)(v0)
 191 #if ! defined (__PIC__) || _MIPS_SIM != _ABIO32
 192         REG_L   gp, (MCONTEXT_GREGOFF + 28 * MCONTEXT_GREGSZ + MCONTEXT_GREGS)(v0)
 193 #endif
 194         REG_L   sp, (MCONTEXT_GREGOFF + 29 * MCONTEXT_GREGSZ + MCONTEXT_GREGS)(v0)
 195         REG_L   fp, (MCONTEXT_GREGOFF + 30 * MCONTEXT_GREGSZ + MCONTEXT_GREGS)(v0)
 196         REG_L   ra, (MCONTEXT_GREGOFF + 31 * MCONTEXT_GREGSZ + MCONTEXT_GREGS)(v0)
 197         REG_L   t9, (MCONTEXT_GREGOFF + MCONTEXT_PC)(v0)
 198
 199         move    v0, zero
 200         jr      t9
 201
 202 99:
 203 #ifdef __PIC__
 204         PTR_LA  t9, JUMPTARGET (__syscall_error)
 205         RESTORE_GP64_STACK
 206         PTR_ADDIU sp, FRAMESZ
 207         cfi_adjust_cfa_offset (-FRAMESZ)
 208         jr      t9
 209
 210 #else  /* ! __PIC__ */
 211
 212         j       JUMPTARGET (__syscall_error)
 213 #endif /* ! __PIC__ */
 214 PSEUDO_END (__swapcontext)
 215
 216 weak_alias (__swapcontext, swapcontext)