sysdeps/unix/sysv/linux/s390/s390-64/swapcontext.S

   1 /* Copyright (C) 2002-2019 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3    Contributed by Martin Schwidefsky (schwidefsky@de.ibm.com).
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 #include <sysdep.h>
  20 #include <features.h>
  21
  22 #include "ucontext_i.h"
  23
  24 /*  __swapcontext (ucontext_t *oucp, const ucontext_t *ucp)
  25
  26   Saves the machine context in oucp such that when it is activated,
  27   it appears as if __swapcontext() returned again, restores the
  28   machine context in ucp and thereby resumes execution in that
  29   context.
  30
  31   This implementation is intended to be used for *synchronous* context
  32   switches only.  Therefore, it does not have to save anything
  33   other than the PRESERVED state.  */
  34
  35 ENTRY(__swapcontext)
  36         /* While not part of the ABI a system call never clobbers r0
  37            or r1.  So keeping the values here while calling
  38            rt_sigprocmask is ok.  */
  39         lgr     %r1,%r2
  40         lgr     %r0,%r3
  41
  42         /* Store fpu context.  */
  43         stfpc   SC_FPC(%r1)
  44         std     %f0,SC_FPRS(%r1)
  45         std     %f1,SC_FPRS+8(%r1)
  46         std     %f2,SC_FPRS+16(%r1)
  47         std     %f3,SC_FPRS+24(%r1)
  48         std     %f4,SC_FPRS+32(%r1)
  49         std     %f5,SC_FPRS+40(%r1)
  50         std     %f6,SC_FPRS+48(%r1)
  51         std     %f7,SC_FPRS+56(%r1)
  52         std     %f8,SC_FPRS+64(%r1)
  53         std     %f9,SC_FPRS+72(%r1)
  54         std     %f10,SC_FPRS+80(%r1)
  55         std     %f11,SC_FPRS+88(%r1)
  56         std     %f12,SC_FPRS+96(%r1)
  57         std     %f13,SC_FPRS+104(%r1)
  58         std     %f14,SC_FPRS+112(%r1)
  59         std     %f15,SC_FPRS+120(%r1)
  60
  61         /* Set __swapcontext return value to 0.  */
  62         slgr     %r2,%r2
  63
  64         /* Store access registers.  */
  65         stam    %a0,%a15,SC_ACRS(%r1)
  66
  67         /* Store general purpose registers.  */
  68         stmg    %r0,%r15,SC_GPRS(%r1)
  69
  70         /* rt_sigprocmask (SIG_SETMASK, &ucp->uc_sigmask, &oucp->uc_sigmask,
  71            sigsetsize).  */
  72         la      %r2,SIG_SETMASK
  73         lgr     %r5,%r0
  74         la      %r3,SC_MASK(%r5)
  75         la      %r4,SC_MASK(%r1)
  76         lghi    %r5,_NSIG8
  77         svc     SYS_ify(rt_sigprocmask)
  78
  79         /* Load fpu context.  */
  80         lgr     %r5,%r0
  81         lfpc    SC_FPC(%r5)
  82         ld      %f0,SC_FPRS(%r5)
  83         ld      %f1,SC_FPRS+8(%r5)
  84         ld      %f2,SC_FPRS+16(%r5)
  85         ld      %f3,SC_FPRS+24(%r5)
  86         ld      %f4,SC_FPRS+32(%r5)
  87         ld      %f5,SC_FPRS+40(%r5)
  88         ld      %f6,SC_FPRS+48(%r5)
  89         ld      %f7,SC_FPRS+56(%r5)
  90         ld      %f8,SC_FPRS+64(%r5)
  91         ld      %f9,SC_FPRS+72(%r5)
  92         ld      %f10,SC_FPRS+80(%r5)
  93         ld      %f11,SC_FPRS+88(%r5)
  94         ld      %f12,SC_FPRS+96(%r5)
  95         ld      %f13,SC_FPRS+104(%r5)
  96         ld      %f14,SC_FPRS+112(%r5)
  97         ld      %f15,SC_FPRS+120(%r5)
  98
  99         /* Don't touch %a0 and %a1, used for thread purposes.  */
 100         lam     %a2,%a15,SC_ACRS+8(%r5)
 101
 102         /* Load general purpose registers.  */
 103         lmg     %r0,%r15,SC_GPRS(%r5)
 104
 105         /* Return.  */
 106         br      %r14
 107 END(__swapcontext)
 108 weak_alias (__swapcontext, swapcontext)