sysdeps/unix/sysv/linux/s390/s390-64/swapcontext.S

   1 /* Copyright (C) 2002-2014 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3    Contributed by Martin Schwidefsky (schwidefsky@de.ibm.com).
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 #include <sysdep.h>
  20 #include <features.h>
  21
  22 #include "ucontext_i.h"
  23
  24 /*  __swapcontext (ucontext_t *oucp, const ucontext_t *ucp)
  25
  26   Saves the machine context in oucp such that when it is activated,
  27   it appears as if __swapcontextt() returned again, restores the
  28   machine context in ucp and thereby resumes execution in that
  29   context.
  30
  31   This implementation is intended to be used for *synchronous* context
  32   switches only.  Therefore, it does not have to save anything
  33   other than the PRESERVED state.  */
  34
  35 ENTRY(__swapcontext)
  36         lgr     %r1,%r2
  37         lgr     %r0,%r3
  38
  39         /* sigprocmask (SIG_BLOCK, NULL, &sc->sc_mask).  */
  40         la      %r2,SIG_BLOCK
  41         slgr    %r3,%r3
  42         la      %r4,SC_MASK(%r1)
  43         lghi    %r5,_NSIG8
  44         svc     SYS_ify(rt_sigprocmask)
  45
  46         /* Store fpu context.  */
  47         stfpc   SC_FPC(%r1)
  48         std     %f0,SC_FPRS(%r1)
  49         std     %f1,SC_FPRS+8(%r1)
  50         std     %f2,SC_FPRS+16(%r1)
  51         std     %f3,SC_FPRS+24(%r1)
  52         std     %f4,SC_FPRS+32(%r1)
  53         std     %f5,SC_FPRS+40(%r1)
  54         std     %f6,SC_FPRS+48(%r1)
  55         std     %f7,SC_FPRS+56(%r1)
  56         std     %f8,SC_FPRS+64(%r1)
  57         std     %f9,SC_FPRS+72(%r1)
  58         std     %f10,SC_FPRS+80(%r1)
  59         std     %f11,SC_FPRS+88(%r1)
  60         std     %f12,SC_FPRS+96(%r1)
  61         std     %f13,SC_FPRS+104(%r1)
  62         std     %f14,SC_FPRS+112(%r1)
  63         std     %f15,SC_FPRS+120(%r1)
  64
  65         /* Set __swapcontext return value to 0.  */
  66         slgr     %r2,%r2
  67
  68         /* Store access registers.  */
  69         stam    %a0,%a15,SC_ACRS(%r1)
  70
  71         /* Store general purpose registers.  */
  72         stmg    %r0,%r15,SC_GPRS(%r1)
  73
  74         /* sigprocmask (SIG_SETMASK, &sc->sc_mask, NULL).  */
  75         la      %r2,SIG_BLOCK
  76         lgr     %r5,%r0
  77         la      %r3,SC_MASK(%r5)
  78         lghi    %r5,_NSIG8
  79         slgr    %r4,%r4
  80         svc     SYS_ify(rt_sigprocmask)
  81
  82         /* Load fpu context.  */
  83         lgr     %r5,%r0
  84         lfpc    SC_FPC(%r5)
  85         ld      %f0,SC_FPRS(%r5)
  86         ld      %f1,SC_FPRS+8(%r5)
  87         ld      %f2,SC_FPRS+16(%r5)
  88         ld      %f3,SC_FPRS+24(%r5)
  89         ld      %f4,SC_FPRS+32(%r5)
  90         ld      %f5,SC_FPRS+40(%r5)
  91         ld      %f6,SC_FPRS+48(%r5)
  92         ld      %f7,SC_FPRS+56(%r5)
  93         ld      %f8,SC_FPRS+64(%r5)
  94         ld      %f9,SC_FPRS+72(%r5)
  95         ld      %f10,SC_FPRS+80(%r5)
  96         ld      %f11,SC_FPRS+88(%r5)
  97         ld      %f12,SC_FPRS+96(%r5)
  98         ld      %f13,SC_FPRS+104(%r5)
  99         ld      %f14,SC_FPRS+112(%r5)
 100         ld      %f15,SC_FPRS+120(%r5)
 101
 102         /* Don't touch %a0 and %a1, used for thread purposes.  */
 103         lam     %a2,%a15,SC_ACRS+8(%r5)
 104
 105         /* Load general purpose registers.  */
 106         lmg     %r0,%r15,SC_GPRS(%r5)
 107
 108         /* Return.  */
 109         br      %r14
 110 END(__swapcontext)
 111 weak_alias (__swapcontext, swapcontext)