sysdeps/unix/sysv/linux/sh/vfork.S

   1 /* Copyright (C) 1999-2014 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3
   4    The GNU C Library is free software; you can redistribute it and/or
   5    modify it under the terms of the GNU Lesser General Public
   6    License as published by the Free Software Foundation; either
   7    version 2.1 of the License, or (at your option) any later version.
   8
   9    The GNU C Library is distributed in the hope that it will be useful,
  10    but WITHOUT ANY WARRANTY; without even the implied warranty of
  11    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12    Lesser General Public License for more details.
  13
  14    You should have received a copy of the GNU Lesser General Public
  15    License along with the GNU C Library; if not, see
  16    <http://www.gnu.org/licenses/>.  */
  17
  18 #include <sysdep.h>
  19 #define _ERRNO_H        1
  20 #include <bits/errno.h>
  21
  22 /* Clone the calling process, but without copying the whole address space.
  23    The calling process is suspended until the new process exits or is
  24    replaced by a call to `execve'.  Return -1 for errors, 0 to the new process,
  25    and the process ID of the new process to the old process.  */
  26
  27 ENTRY (__vfork)
  28
  29 #ifdef __NR_vfork
  30         mov.w   .L3, r3
  31         trapa   #0x10
  32         mov     r0, r1
  33         mov     #-12, r2
  34         shad    r2, r1
  35         not     r1, r1                  // r1=0 means r0 = -1 to -4095
  36         tst     r1, r1                  // i.e. error in linux
  37         bf      1f
  38         mov.w   .L1, r1
  39         cmp/eq  r1, r0
  40         bt      2f
  41         bra     .Lsyscall_error
  42          nop
  43 .L1:
  44         .word   -ENOSYS
  45 .L3:    .word   __NR_vfork
  46 1:
  47         rts
  48          nop
  49 2:
  50 #endif
  51
  52         /* If we don't have vfork, fork is close enough.  */
  53         mov     #+__NR_fork, r3
  54         trapa   #0x10
  55         mov     r0, r1
  56         mov     #-12, r2
  57         shad    r2, r1
  58         not     r1, r1                  // r1=0 means r0 = -1 to -4095
  59         tst     r1, r1                  // i.e. error in linux
  60         bf      .Lpseudo_end
  61 .Lsyscall_error:
  62         SYSCALL_ERROR_HANDLER
  63 .Lpseudo_end:
  64         rts
  65          nop
  66
  67 PSEUDO_END (__vfork)
  68 libc_hidden_def (__vfork)
  69
  70 weak_alias (__vfork, vfork)