configure.ac

   1 AC_PREREQ(2.60)
   2 AC_INIT([kmod],
   3         [12],
   4         [linux-modules@vger.kernel.org],
   5         [kmod],
   6         [http://git.kernel.org/?p=utils/kernel/kmod/kmod.git])
   7
   8 AC_CONFIG_SRCDIR([libkmod/libkmod.c])
   9 AC_CONFIG_AUX_DIR([build-aux])
  10 AM_INIT_AUTOMAKE([check-news foreign 1.11 silent-rules
  11         tar-pax no-dist-gzip dist-xz subdir-objects color-tests])
  12 AC_PROG_CC_STDC
  13 AC_USE_SYSTEM_EXTENSIONS
  14 AC_SYS_LARGEFILE
  15 AC_CONFIG_MACRO_DIR([m4])
  16 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
  17 AM_SILENT_RULES([yes])
  18 LT_INIT([disable-static pic-only])
  19 AC_PREFIX_DEFAULT([/usr])
  20
  21 #####################################################################
  22 # Program checks and configurations
  23 #####################################################################
  24
  25 AC_PROG_CC
  26 AC_PROG_CC_C99
  27 AC_C_TYPEOF
  28 AM_PROG_CC_C_O
  29 AC_PROG_GCC_TRADITIONAL
  30 AC_C_BIGENDIAN
  31
  32 AC_PROG_SED
  33 AC_PROG_MKDIR_P
  34 PKG_PROG_PKG_CONFIG
  35
  36
  37 #####################################################################
  38 # Function and structure checks
  39 #####################################################################
  40
  41 AC_CHECK_FUNCS_ONCE(__xstat)
  42 AC_CHECK_FUNCS_ONCE([__secure_getenv secure_getenv])
  43
  44 # dietlibc doesn't have st.st_mtim struct member
  45 AC_CHECK_MEMBERS([struct stat.st_mtim], [], [], [#include <sys/stat.h>])
  46
  47 # Check kernel headers
  48 AC_CHECK_HEADERS_ONCE([linux/module.h])
  49
  50
  51 #####################################################################
  52 # --with-
  53 #####################################################################
  54
  55 AC_ARG_WITH([rootlibdir],
  56         AS_HELP_STRING([--with-rootlibdir=DIR], [rootfs directory to install shared libraries]),
  57         [], [with_rootlibdir=$libdir])
  58 AC_SUBST([rootlibdir], [$with_rootlibdir])
  59
  60 AC_ARG_WITH([xz],
  61         AS_HELP_STRING([--with-xz], [handle Xz-compressed modules @<:@default=disabled@:>@]),
  62         [], [with_xz=no])
  63 AS_IF([test "x$with_xz" != "xno"], [
  64         PKG_CHECK_MODULES([liblzma], [liblzma >= 4.99])
  65         AC_DEFINE([ENABLE_XZ], [1], [Enable Xz for modules.])
  66 ], [
  67         AC_MSG_NOTICE([Xz support not requested])
  68 ])
  69
  70 AC_ARG_WITH([zlib],
  71         AS_HELP_STRING([--with-zlib], [handle gzipped modules @<:@default=disabled@:>@]),
  72         [], [with_zlib=no])
  73 AS_IF([test "x$with_zlib" != "xno"], [
  74         PKG_CHECK_MODULES([zlib], [zlib])
  75         AC_DEFINE([ENABLE_ZLIB], [1], [Enable zlib for modules.])
  76 ], [
  77         AC_MSG_NOTICE([zlib support not requested])
  78 ])
  79
  80
  81 #####################################################################
  82 # --enable-
  83 #####################################################################
  84
  85 AC_ARG_ENABLE([tools],
  86         AS_HELP_STRING([--disable-tools], [disable building tools that provide same functionality as module-init-tools @<:@default=enabled@:>@]),
  87         [], enable_tools=yes)
  88 AM_CONDITIONAL([BUILD_TOOLS], [test "x$enable_tools" = "xyes"])
  89
  90 AC_ARG_ENABLE([manpages],
  91         AS_HELP_STRING([--disable-manpages], [disable manpages @<:@default=enabled@:>@]),
  92         [], enable_manpages=yes)
  93 AM_CONDITIONAL([BUILD_MANPAGES], [test "x$enable_manpages" = "xyes"])
  94 AC_PATH_PROG([XSLTPROC], [xsltproc], [no])
  95 AS_IF([test "x$XSLTPROC" = "xno" && test "x$enable_manpages" = "xyes"], [
  96         AC_MSG_ERROR([xsltproc command not found, try ./configure --disable-manpages])
  97 ])
  98
  99 AC_ARG_ENABLE([logging],
 100         AS_HELP_STRING([--disable-logging], [disable system logging @<:@default=enabled@:>@]),
 101         [], enable_logging=yes)
 102 AS_IF([test "x$enable_logging" = "xyes"], [
 103         AC_DEFINE(ENABLE_LOGGING, [1], [System logging.])
 104 ])
 105
 106 AC_ARG_ENABLE([debug],
 107         AS_HELP_STRING([--enable-debug], [enable debug messages @<:@default=disabled@:>@]),
 108         [], [enable_debug=no])
 109 AS_IF([test "x$enable_debug" = "xyes"], [
 110         AC_DEFINE(ENABLE_DEBUG, [1], [Debug messages.])
 111 ])
 112
 113 m4_ifdef([GTK_DOC_CHECK], [
 114 GTK_DOC_CHECK([1.14],[--flavour no-tmpl-flat])
 115 ], [
 116 AM_CONDITIONAL([ENABLE_GTK_DOC], false)])
 117
 118
 119 #####################################################################
 120 # Default CFLAGS and LDFLAGS
 121 #####################################################################
 122
 123 CC_CHECK_FLAGS_APPEND(with_cflags, [CFLAGS], [\
 124                        -pipe \
 125                        -DANOTHER_BRICK_IN_THE \
 126                        -Wall \
 127                        -W \
 128                        -Wextra \
 129                        -Wno-inline \
 130                        -Wvla \
 131                        -Wundef \
 132                        -Wformat=2 \
 133                        -Wlogical-op \
 134                        -Wsign-compare \
 135                        -Wformat-security \
 136                        -Wmissing-include-dirs \
 137                        -Wformat-nonliteral \
 138                        -Wold-style-definition \
 139                        -Wpointer-arith \
 140                        -Winit-self \
 141                        -Wdeclaration-after-statement \
 142                        -Wfloat-equal \
 143                        -Wmissing-prototypes \
 144                        -Wstrict-prototypes \
 145                        -Wredundant-decls \
 146                        -Wmissing-declarations \
 147                        -Wmissing-noreturn \
 148                        -Wshadow \
 149                        -Wendif-labels \
 150                        -Wstrict-aliasing=2 \
 151                        -Wwrite-strings \
 152                        -Wno-long-long \
 153                        -Wno-overlength-strings \
 154                        -Wno-unused-parameter \
 155                        -Wno-missing-field-initializers \
 156                        -Wno-unused-result \
 157                        -Wnested-externs \
 158                        -Wchar-subscripts \
 159                        -Wtype-limits \
 160                        -Wuninitialized \
 161                        -fno-common \
 162                        -fdiagnostics-show-option \
 163                        -fvisibility=hidden \
 164                        -ffunction-sections \
 165                        -fdata-sections])
 166 AC_SUBST([WARNINGFLAGS], $with_cflags)
 167
 168
 169 CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [ \
 170                        -Wl,--as-needed \
 171                        -Wl,--gc-sections])
 172 AC_SUBST([GCLDFLAGS], $with_ldflags)
 173
 174 #####################################################################
 175 # Generate files from *.in
 176 #####################################################################
 177
 178 AC_CONFIG_HEADERS(config.h)
 179 AC_CONFIG_FILES([
 180         Makefile
 181         man/Makefile
 182         libkmod/docs/Makefile
 183         libkmod/docs/version.xml
 184 ])
 185
 186
 187 #####################################################################
 188
 189 AC_OUTPUT
 190 AC_MSG_RESULT([
 191         $PACKAGE $VERSION
 192         ======
 193
 194         prefix:                 ${prefix}
 195         sysconfdir:             ${sysconfdir}
 196         libdir:                 ${libdir}
 197         rootlibdir:             ${rootlibdir}
 198         includedir:             ${includedir}
 199         bindir:                 ${bindir}
 200
 201         compiler:               ${CC}
 202         cflags:                 ${with_cflags} ${CFLAGS}
 203         ldflags:                ${with_ldflags} ${LDFLAGS}
 204
 205         tools:                  ${enable_tools}
 206         logging:                ${enable_logging}
 207         compression:            xz=${with_xz}  zlib=${with_zlib}
 208         debug:                  ${enable_debug}
 209         doc:                    ${enable_gtk_doc}
 210         man:                    ${enable_manpages}
 211 ])