configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 #######################
   5 ### Base configuration
   6
   7 # Configure autoconf
   8 AC_PREREQ([2.64])
   9
  10 AC_INIT([lldpd],
  11         [m4_esyscmd_s([./get-version])],
  12         [https://github.com/vincentbernat/lldpd/issues],
  13         [lldpd],
  14         [http://vincentbernat.github.io/lldpd/])
  15
  16 AC_CONFIG_SRCDIR([src/log.c])
  17 AC_CONFIG_HEADER([config.h])
  18 AC_CONFIG_FILES([Makefile
  19                  src/Makefile
  20                  src/compat/Makefile
  21                  src/daemon/Makefile
  22                  src/lib/Makefile
  23                  src/client/Makefile
  24                  tests/Makefile
  25                  osx/Makefile])
  26 AC_CONFIG_MACRO_DIR([m4])
  27 AC_SUBST([CONFIGURE_ARGS], [$ac_configure_args])
  28
  29 # Configure automake
  30 AM_INIT_AUTOMAKE([foreign subdir-objects -Wall -Werror tar-ustar])
  31 AM_MAINTAINER_MODE
  32 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES(yes)])
  33
  34 # Automake 1.12...
  35 m4_pattern_allow([AM_PROG_AR])
  36 AM_PROG_AR
  37
  38 # Configure libtool
  39 LT_INIT
  40 gl_LD_VERSION_SCRIPT
  41
  42 #######################
  43 ### Checks
  44
  45 # Checks for programs.
  46 AC_PROG_CC
  47 AC_PROG_CC_C99
  48 if test x"$ac_cv_prog_cc_c99" = x"no"; then
  49   AC_MSG_FAILURE([*** C99 support is mandatory])
  50 fi
  51 AC_PROG_CXX
  52 AM_PROG_CC_C_O
  53 AC_PROG_LIBTOOL
  54 AC_PROG_LN_S
  55 AC_PROG_EGREP
  56 AC_PROG_AWK
  57
  58 # Doxygen
  59 DX_HTML_FEATURE(ON)
  60 DX_DOT_FEATURE(OFF)
  61 DX_CHM_FEATURE(OFF)
  62 DX_CHI_FEATURE(OFF)
  63 DX_MAN_FEATURE(OFF)
  64 DX_RTF_FEATURE(OFF)
  65 DX_XML_FEATURE(OFF)
  66 DX_PDF_FEATURE(ON)
  67 DX_PS_FEATURE(OFF)
  68 DX_INIT_DOXYGEN([lldpd], [doxygen.cfg], [doxygen])
  69
  70 # Check some compiler flags
  71 AX_CFLAGS_GCC_OPTION([-Wunknown-warning-option], [LLDP_CFLAGS])
  72 AX_CFLAGS_GCC_OPTION([-fdiagnostics-show-option], [LLDP_CFLAGS])
  73 AX_CFLAGS_GCC_OPTION([-fdiagnostics-color=auto], [LLDP_CFLAGS])
  74 AX_CFLAGS_GCC_OPTION([-pipe], [LLDP_CFLAGS])
  75 AX_CFLAGS_GCC_OPTION([-Wall], [LLDP_CFLAGS])
  76 AX_CFLAGS_GCC_OPTION([-W], [LLDP_CFLAGS])
  77 AX_CFLAGS_GCC_OPTION([-Wextra], [LLDP_CFLAGS])
  78 AX_CFLAGS_GCC_OPTION([-Wformat], [LLDP_CFLAGS])
  79 AX_CFLAGS_GCC_OPTION([-Wformat-security], [LLDP_CFLAGS])
  80 AX_CFLAGS_GCC_OPTION([-Wfatal-errors], [LLDP_CFLAGS])
  81 AX_CFLAGS_GCC_OPTION([-Wcast-align], [LLDP_CFLAGS])
  82 AX_CFLAGS_GCC_OPTION([-Wheader-guard], [LLDP_CFLAGS])
  83 AX_CFLAGS_GCC_OPTION([-Wdocumentation], [LLDP_CFLAGS])
  84 AX_CFLAGS_GCC_OPTION([-Winline], [LLDP_CFLAGS])
  85 AX_CFLAGS_GCC_OPTION([-Wpointer-arith], [LLDP_CFLAGS])
  86 AX_CFLAGS_GCC_OPTION([-fno-omit-frame-pointer], [LLDP_CFLAGS])
  87 AX_CFLAGS_GCC_OPTION([-Wno-unused-parameter], [LLDP_CFLAGS])
  88 AX_CFLAGS_GCC_OPTION([-Wno-missing-field-initializers], [LLDP_CFLAGS])
  89 AX_CFLAGS_GCC_OPTION([-Wno-sign-compare], [LLDP_CFLAGS]) dnl Should be fixed later
  90 AX_LDFLAGS_OPTION([-Wl,-z,relro], [LLDP_LDFLAGS])
  91 AX_LDFLAGS_OPTION([-Wl,-z,now], [LLDP_LDFLAGS])
  92
  93 AC_C_TYPEOF
  94
  95 # Hardening
  96 AC_ARG_ENABLE([hardening],
  97   [AS_HELP_STRING([--enable-hardening],
  98     [Enable compiler and linker options to frustrate memory corruption exploits @<:@default=yes@:>@])],
  99   [hardening="$enableval"],
 100   [hardening="yes"])
 101 AC_ARG_ENABLE([pie],
 102   [AS_HELP_STRING([--enable-pie],
 103     [Enable PIE (position independant executable) @<:@default=no@:>@])],
 104   [pie="$enableval"],
 105   [pie="no"])
 106
 107 if test x"$hardening" != x"no"; then
 108   AX_CFLAGS_GCC_OPTION([-fstack-protector], [LLDP_CFLAGS])
 109   AX_CFLAGS_GCC_OPTION([-fstack-protector-all], [LLDP_CFLAGS])
 110   AX_CFLAGS_GCC_OPTION([-fstack-protector-strong], [LLDP_CFLAGS])
 111   AX_CFLAGS_GCC_OPTION([-D_FORTIFY_SOURCE=2], [LLDP_CPPFLAGS])
 112 fi
 113 if test x"$pie" = x"yes"; then
 114   AX_CFLAGS_GCC_OPTION([-fPIE], [LLDP_CFLAGS])
 115   AX_LDFLAGS_OPTION([-fPIE -pie], [LLDP_BIN_LDFLAGS],
 116     [AX_LDFLAGS_OPTION([-fPIE -Wl,-pie], [LLDP_BIN_LDFLAGS])])
 117 fi
 118
 119 # Sanitizers
 120 AC_ARG_ENABLE([sanitizers],
 121   AS_HELP_STRING([--enable-sanitizers],
 122     [Enable code instrumentation with selected sanitizers @<:@default=no@:>@]),
 123   [
 124 case "$enableval" in
 125     no) sanitizers= ;;
 126     yes) sanitizers="-fsanitize=address,undefined" ;;
 127     *) sanitizers="-fsanitize=$enableval" ;;
 128 esac
 129 if test x"$sanitizers" != x; then
 130   LLDP_CFLAGS="$LLDP_CFLAGS $sanitizers"
 131   LLDP_LDFLAGS="$LLDP_LDFLAGS $sanitizers"
 132   AC_DEFINE([HAVE_ADDRESS_SANITIZER], 1, [Define if have both address and leak sanitizer])
 133 fi
 134   ])
 135
 136 # Code coverage
 137 AC_ARG_ENABLE([gcov],
 138   AS_HELP_STRING([--enable-gcov],
 139     [Enable coverage instrumentation @<:@default=no@:>@]),
 140     [gcov="$enableval"],
 141     [gcov="no"])
 142 if test x"$gcov" != x"no"; then
 143   LLDP_CFLAGS="$LLDP_CFLAGS --coverage"
 144   LLDP_LDFLAGS="$LLDP_LDFLAGS --coverage"
 145 fi
 146
 147 # OS
 148 lldp_CHECK_OS
 149 lldp_CFLAGS_OS
 150
 151 AC_CACHE_SAVE
 152
 153 # Checks for header files.
 154 AC_HEADER_RESOLV
 155 AC_CHECK_HEADERS([valgrind/valgrind.h])
 156 lldp_CHECK_STDINT
 157
 158 AC_CACHE_SAVE
 159
 160 # Checks for typedefs, structures, and compiler characteristics.
 161 lldp_CHECK___PROGNAME
 162 lldp_CHECK_ALIGNOF
 163
 164 # Checks for library functions.
 165 AC_CONFIG_LIBOBJ_DIR([src/compat])
 166 AC_FUNC_MALLOC
 167 AC_FUNC_REALLOC
 168 AC_FUNC_FORK
 169
 170 # Some functions can be in libbsd
 171 PKG_CHECK_MODULES([libbsd], [libbsd-overlay], [
 172   _save_CFLAGS="$CFLAGS"
 173   _save_LIBS="$LIBS"
 174   CFLAGS="$CFLAGS $libbsd_CFLAGS"
 175   LIBS="$LIBS $libbsd_LIBS"
 176   AC_MSG_CHECKING([if libbsd can be linked correctly])
 177   AC_TRY_LINK([
 178 @%:@include <sys/time.h>
 179 @%:@include <sys/types.h>
 180 ],[],
 181     [
 182       AC_MSG_RESULT(yes)
 183       LLDP_CFLAGS="$LLDP_CFLAGS $libbsd_CFLAGS"
 184       LLDP_LDFLAGS="$LLDP_LDFLAGS $libbsd_LIBS"
 185     ],[
 186       AC_MSG_RESULT(no)
 187       CFLAGS="$_save_CFLAGS"
 188       LIBS="$_save_LIBS"
 189     ])
 190 ], [:])
 191
 192 # setproctitle may have an _init function
 193 AC_REPLACE_FUNCS([setproctitle])
 194 AC_CHECK_FUNCS([setproctitle_init])
 195 # Other functions
 196 AC_REPLACE_FUNCS([strlcpy
 197                   strnlen
 198                   strndup
 199                   strtonum
 200                   getline
 201                   asprintf
 202                   vsyslog
 203                   daemon])
 204 # Optional functions
 205 AC_CHECK_FUNCS([setresuid setresgid])
 206
 207 # Check for res_init. On OSX, res_init is a symbol in libsystem_info
 208 # and a macro in resolv.h. We need to ensure we test with resolv.h.
 209 m4_pushdef([AC_LANG_CALL(C)], [
 210   AC_LANG_PROGRAM([$1
 211 @%:@include <resolv.h>], [return $2 ();])])
 212 AC_SEARCH_LIBS([res_init], resolv bind,
 213                AC_DEFINE([HAVE_RES_INIT], 1,
 214                [Define to indicate that res_init() exists]))
 215 m4_popdef([AC_LANG_CALL(C)])
 216
 217 AC_CACHE_SAVE
 218
 219 ## Unit tests wich check
 220 PKG_CHECK_MODULES([CHECK], [check >= 0.9.4], [have_check=yes], [have_check=no])
 221
 222 # Third-party libraries
 223 lldp_CHECK_LIBEVENT
 224
 225 # Compatibility with pkg.m4 < 0.27
 226 m4_ifdef([PKG_INSTALLDIR], [PKG_INSTALLDIR],
 227          [AC_ARG_WITH([pkgconfigdir],
 228                       [AS_HELP_STRING([--with-pkgconfigdir],
 229                       [install directory for *.pc pkg-config file])],
 230                       [],[with_pkgconfigdir='$(libdir)/pkgconfig'])
 231           AC_SUBST([pkgconfigdir], [${with_pkgconfigdir}])])
 232
 233 #######################
 234 ### Options
 235
 236 # Readline
 237 AC_ARG_WITH([readline],
 238   AS_HELP_STRING(
 239     [--with-readline],
 240     [Enable the use of readline-like library @<:@default=auto@:>@]),
 241   [],
 242   [with_readline=auto])
 243 if test x"$with_readline" != x"no"; then
 244    AX_LIB_READLINE
 245    if test x"$with_readline" != x"check" -a x"$with_readline" != x"auto"; then
 246      if test x"$ax_cv_lib_readline" = x"no"; then
 247        AC_MSG_FAILURE([*** no readline support found])
 248      fi
 249    fi
 250 else
 251    ax_cv_lib_readline="no"
 252 fi
 253
 254 # SNMP
 255 AC_ARG_WITH([snmp],
 256   AS_HELP_STRING(
 257     [--with-snmp],
 258     [Enable the use of SNMP @<:@default=no@:>@]),
 259   [],
 260   [with_snmp=no])
 261 lldp_CHECK_SNMP
 262
 263 # XML
 264 AC_ARG_WITH([xml],
 265   AS_HELP_STRING(
 266     [--with-xml],
 267     [Enable XML output via libxml2 @<:@default=auto@:>@]),
 268   [],
 269   [with_xml=auto])
 270 lldp_CHECK_XML2
 271
 272 # JSON
 273 AC_ARG_WITH([json],
 274   AS_HELP_STRING(
 275     [--with-json],
 276     [Enable JSON output via janson or json-c @<:@default=auto@:>@]),
 277   [],
 278   [with_json=auto])
 279 if test x"$with_json" = x"yes" -o x"$with_json" = x"auto"; then
 280    _with_json="$with_json"
 281    with_json=auto
 282    lldp_CHECK_JANSSON
 283    if test x"$with_json" = x"no"; then
 284      with_json=auto
 285      lldp_CHECK_JSONC
 286    fi
 287    if test x"$with_json" = x"no" -a x"$_with_json" = x"yes"; then
 288      AC_MSG_FAILURE([*** no JSON support found])
 289    fi
 290 else
 291    lldp_CHECK_JANSSON
 292    lldp_CHECK_JSONC
 293 fi
 294 lldp_ARG_ENABLE([json0], [use of pre-0.9.2 JSON/json-c format], [no])
 295
 296 # Seccomp
 297 AC_ARG_WITH([seccomp],
 298   AS_HELP_STRING(
 299     [--with-seccomp],
 300     [Enable seccomp support (with libseccomp, experimental) @<:@default=no@:>@]),
 301   [],
 302   [with_seccomp=no])
 303 lldp_CHECK_SECCOMP
 304
 305 # OS X launchd support
 306 lldp_ARG_WITH([launchddaemonsdir], [Directory for launchd configuration file (OSX)],
 307                                    [/Library/LaunchDaemons])
 308 AC_SUBST([launchddaemonsdir], [$with_launchddaemonsdir])
 309 AM_CONDITIONAL(HAVE_LAUNCHDDAEMONSDIR,
 310     [test -n "$with_launchddaemonsdir" -a "x$with_launchddaemonsdir" != xno ])
 311
 312 # Systemd
 313 lldp_ARG_WITH([systemdsystemunitdir], [Directory for systemd service files],
 314               [$($PKG_CONFIG --variable=systemdsystemunitdir systemd 2> /dev/null)])
 315 AC_SUBST([systemdsystemunitdir], [$with_systemdsystemunitdir])
 316 AM_CONDITIONAL(HAVE_SYSTEMDSYSTEMUNITDIR,
 317     [test -n "$with_systemdsystemunitdir" -a "x$with_systemdsystemunitdir" != xno ])
 318
 319 # sysusers
 320 lldp_ARG_WITH([sysusersdir], [Directory for sysusers files],
 321               [$($PKG_CONFIG --variable=sysusersdir systemd 2> /dev/null)])
 322 AC_SUBST([sysusersdir], [$with_sysusersdir])
 323 AM_CONDITIONAL(HAVE_SYSUSERSDIR,
 324     [test -n "$with_sysusersdir" -a "x$with_sysusersdir" != xno ])
 325
 326 # AppArmor
 327 lldp_ARG_WITH([apparmordir], [Directory for AppArmor profiles (Linux)],
 328                              [no])
 329 AC_SUBST([apparmordir], [$with_apparmordir])
 330 AM_CONDITIONAL(HAVE_APPARMORDIR,
 331     [test -n "$with_apparmordir" -a "x$with_apparmordir" != xno ])
 332
 333 # Systemtap/DTrace
 334 lldp_SYSTEMTAP
 335
 336 # Privsep settings
 337 lldp_ARG_ENABLE([privsep], [Privilege separation], [yes])
 338 lldp_ARG_WITH([privsep-user], [Which user to use for privilege separation], [_lldpd])
 339 lldp_ARG_WITH([privsep-group], [Which group to use for privilege separation], [_lldpd])
 340
 341 # Directories
 342 dnl On autoconf 2.69 and before, runstatedir is not configurable, let be able to use it anyway
 343 if test "x$runstatedir" = x; then
 344     AC_SUBST([runstatedir], ['${localstatedir}/run'])
 345 fi
 346 lldp_ARG_WITH([privsep-chroot], [Which directory to use to chroot lldpd], [${runstatedir}/lldpd])
 347 lldp_ARG_WITH([lldpd-ctl-socket], [Path to socket for communication with lldpd], [${runstatedir}/lldpd.socket])
 348 lldp_ARG_WITH([lldpd-pid-file], [Path to lldpd PID file], [${runstatedir}/lldpd.pid])
 349
 350 # Netlink
 351 lldp_ARG_WITH_UNQUOTED([netlink-max-receive-bufsize], [Netlink maximum receive buffer size], [1024*1024])
 352 lldp_ARG_WITH_UNQUOTED([netlink-receive-bufsize], [Netlink initial receive buffer size], [0])
 353 lldp_ARG_WITH_UNQUOTED([netlink-send-bufsize], [Netlink send buffer size], [0])
 354
 355 # CDP/FDP/EDP/SONMP
 356 lldp_ARG_ENABLE([cdp], [Cisco Discovery Protocol], [yes])
 357 lldp_ARG_ENABLE([fdp], [Foundry Discovery Protocol], [yes])
 358 lldp_ARG_ENABLE([edp], [Extreme Discovery Protocol], [yes])
 359 lldp_ARG_ENABLE([sonmp], [SynOptics Network Management Protocol], [yes])
 360
 361 # LLDPMED/Dot1/Dot3
 362 lldp_ARG_ENABLE([lldpmed], [LLDP-MED extension], [yes])
 363 lldp_ARG_ENABLE([dot1], [Dot1 extension (VLAN stuff)], [yes])
 364 lldp_ARG_ENABLE([dot3], [Dot3 extension (PHY stuff)], [yes])
 365 lldp_ARG_ENABLE([custom], [Custom TLV support], [yes])
 366
 367 # Oldies
 368 MIN_LINUX_KERNEL_VERSION=2.6.39
 369 lldp_ARG_ENABLE([oldies], [compatibility with Linux kernel older than 2.6.39], [no])
 370 if test x"$os" = x"Linux"; then
 371     if test x"$enable_oldies" = x"no"; then
 372       AC_DEFINE_UNQUOTED(MIN_LINUX_KERNEL_VERSION, "[$MIN_LINUX_KERNEL_VERSION]", [Minimal Linux kernel version required])
 373     else
 374       AC_DEFINE(MIN_LINUX_KERNEL_VERSION, "2.6.11", [Minimal kernel version required])
 375     fi
 376 fi
 377
 378 AX_BUILD_DATE_EPOCH(BUILD_DATE, "%FT%TZ", [BUILD_DATE="(unknown)"])
 379 AC_DEFINE_UNQUOTED(BUILD_DATE, "[$BUILD_DATE]", [Build date and time])
 380 AC_DEFINE_UNQUOTED(LLDP_CC, "[$CC $LLDP_CFLAGS $LLDP_CPPFLAGS $CFLAGS $CPPFLAGS]", [C compiler command])
 381 AC_DEFINE_UNQUOTED(LLDP_LD, "[$LD $LLDP_LDFLAGS $LLDP_BIN_LDFLAGS $LDFLAGS $LIBS]", [Linker compiler command])
 382
 383 #######################
 384 # Output results
 385 AC_SUBST([LLDP_CFLAGS])
 386 AC_SUBST([LLDP_CPPFLAGS])
 387 AC_SUBST([LLDP_LDFLAGS])
 388 AC_SUBST([LLDP_BIN_LDFLAGS])
 389 AM_CONDITIONAL([HAVE_CHECK], [test x"$have_check" = x"yes"])
 390 AM_CONDITIONAL([USE_SNMP], [test x"$with_snmp" = x"yes"])
 391 AM_CONDITIONAL([USE_XML], [test x"$with_xml" = x"yes"])
 392 AM_CONDITIONAL([USE_JSON], [test x"$with_json" = x"json-c" || test -x"$with_json" = x"jansson"])
 393 AM_CONDITIONAL([USE_JANSSON], [test x"$with_json" = x"jansson"])
 394 AM_CONDITIONAL([USE_JSONC], [test x"$with_json" = x"json-c"])
 395 AM_CONDITIONAL([USE_SECCOMP], [test x"$with_seccomp" = x"yes"])
 396 dnl If old default of AR_FLAGS is otherwise being used (because of older automake),
 397 dnl replace it with one without 'u'
 398 if test "x$AR_FLAGS" = "xcru" ; then
 399   AR_FLAGS="cr"
 400 fi
 401 AC_OUTPUT
 402
 403 if test x"$LIBEVENT_EMBEDDED" = x; then
 404    libevent=system
 405 else
 406    libevent=embedded
 407 fi
 408
 409 cat <<EOF
 410
 411 ------------------ Summary ------------------
 412  $PACKAGE_NAME version $PACKAGE_VERSION
 413   OS.............: $os
 414   Prefix.........: $prefix
 415   C Compiler.....: $CC $LLDP_CFLAGS $LLDP_CPPFLAGS $CFLAGS $CPPFLAGS
 416   Linker.........: $LD $LLDP_LDFLAGS $LLDP_BIN_LDFLAGS $LDFLAGS $LIBS
 417   Libevent.......: $libevent
 418   Readline.......: ${ax_cv_lib_readline}
 419
 420  Optional features:
 421   SNMP support...: ${with_snmp-no}
 422   CDP............: $enable_cdp
 423   FDP............: $enable_fdp
 424   EDP............: $enable_edp
 425   SONMP..........: $enable_sonmp
 426   LLDPMED........: $enable_lldpmed
 427   DOT1...........: $enable_dot1
 428   DOT3...........: $enable_dot3
 429   CUSTOM.........: $enable_custom
 430   XML output.....: ${with_xml-no}
 431   JSON output....: ${with_json-no}
 432   Oldies support.: $enable_oldies
 433   seccomp........: ${with_seccomp-no}
 434
 435  Privilege separation:
 436   Enabled........: $enable_privsep
 437   User/group.....: ${with_privsep_user}/${with_privsep_group}
 438   Chroot.........: ${with_privsep_chroot}
 439
 440  Instrumentation (for devs only):
 441   Sanitizers.....: ${sanitizers:-none}
 442   Coverage.......: ${gcov}
 443 ------------- Compiler version --------------
 444 $($CC --version || true)
 445 -------------- Linker version ---------------
 446 $($LD --version || true)
 447 ---------------------------------------------
 448
 449 Check the above options and compile with:
 450  ${MAKE-make}
 451
 452 EOF