configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 #######################
   5 ### Base configuration
   6
   7 # Configure autoconf
   8 AC_PREREQ([2.64])
   9
  10 AC_INIT([lldpd],
  11         [m4_esyscmd_s([./get-version])],
  12         [https://github.com/vincentbernat/lldpd/issues],
  13         [lldpd],
  14         [http://vincentbernat.github.io/lldpd/])
  15
  16 AC_CONFIG_SRCDIR([src/log.c])
  17 AC_CONFIG_HEADER([config.h])
  18 AC_CONFIG_FILES([Makefile
  19                  src/Makefile
  20                  src/compat/Makefile
  21                  src/daemon/Makefile
  22                  src/lib/Makefile
  23                  src/client/Makefile
  24                  tests/Makefile
  25                  osx/Makefile])
  26 AC_CONFIG_MACRO_DIR([m4])
  27 AC_SUBST([CONFIGURE_ARGS], [$ac_configure_args])
  28
  29 # Configure automake
  30 AM_INIT_AUTOMAKE([foreign subdir-objects -Wall -Werror tar-ustar])
  31 AM_MAINTAINER_MODE
  32 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES(yes)])
  33
  34 # Automake 1.12...
  35 m4_pattern_allow([AM_PROG_AR])
  36 AM_PROG_AR
  37
  38 # Configure libtool
  39 LT_INIT
  40 gl_LD_VERSION_SCRIPT
  41
  42 #######################
  43 ### Checks
  44
  45 # Checks for programs.
  46 AC_PROG_CC
  47 AC_PROG_CC_C99
  48 if test x"$ac_cv_prog_cc_c99" = x"no"; then
  49   AC_MSG_FAILURE([*** C99 support is mandatory])
  50 fi
  51 AC_PROG_CXX
  52 AM_PROG_CC_C_O
  53 AC_PROG_LIBTOOL
  54 AC_PROG_LN_S
  55 AC_PROG_EGREP
  56 AC_PROG_AWK
  57
  58 # Doxygen
  59 DX_HTML_FEATURE(ON)
  60 DX_DOT_FEATURE(OFF)
  61 DX_CHM_FEATURE(OFF)
  62 DX_CHI_FEATURE(OFF)
  63 DX_MAN_FEATURE(OFF)
  64 DX_RTF_FEATURE(OFF)
  65 DX_XML_FEATURE(OFF)
  66 DX_PDF_FEATURE(ON)
  67 DX_PS_FEATURE(OFF)
  68 DX_INIT_DOXYGEN([lldpd], [doxygen.cfg], [doxygen])
  69
  70 # Check some compiler flags
  71 AX_CFLAGS_GCC_OPTION([-Wunknown-warning-option], [LLDP_CFLAGS])
  72 AX_CFLAGS_GCC_OPTION([-fdiagnostics-show-option], [LLDP_CFLAGS])
  73 AX_CFLAGS_GCC_OPTION([-fdiagnostics-color=auto], [LLDP_CFLAGS])
  74 AX_CFLAGS_GCC_OPTION([-pipe], [LLDP_CFLAGS])
  75 AX_CFLAGS_GCC_OPTION([-Wall], [LLDP_CFLAGS])
  76 AX_CFLAGS_GCC_OPTION([-W], [LLDP_CFLAGS])
  77 AX_CFLAGS_GCC_OPTION([-Wextra], [LLDP_CFLAGS])
  78 AX_CFLAGS_GCC_OPTION([-Wformat], [LLDP_CFLAGS])
  79 AX_CFLAGS_GCC_OPTION([-Wformat-security], [LLDP_CFLAGS])
  80 AX_CFLAGS_GCC_OPTION([-Wfatal-errors], [LLDP_CFLAGS])
  81 AX_CFLAGS_GCC_OPTION([-Wcast-align], [LLDP_CFLAGS])
  82 AX_CFLAGS_GCC_OPTION([-Wheader-guard], [LLDP_CFLAGS])
  83 AX_CFLAGS_GCC_OPTION([-Wdocumentation], [LLDP_CFLAGS])
  84 AX_CFLAGS_GCC_OPTION([-Winline], [LLDP_CFLAGS])
  85 AX_CFLAGS_GCC_OPTION([-Wpointer-arith], [LLDP_CFLAGS])
  86 AX_CFLAGS_GCC_OPTION([-fno-omit-frame-pointer], [LLDP_CFLAGS])
  87 AX_CFLAGS_GCC_OPTION([-Wno-unused-parameter], [LLDP_CFLAGS])
  88 AX_CFLAGS_GCC_OPTION([-Wno-missing-field-initializers], [LLDP_CFLAGS])
  89 AX_CFLAGS_GCC_OPTION([-Wno-sign-compare], [LLDP_CFLAGS]) dnl Should be fixed later
  90 AX_LDFLAGS_OPTION([-Wl,-z,relro], [LLDP_LDFLAGS])
  91 AX_LDFLAGS_OPTION([-Wl,-z,now], [LLDP_LDFLAGS])
  92 lldp_CHECK_CTORS
  93
  94 # Hardening
  95 AC_ARG_ENABLE([hardening],
  96   [AS_HELP_STRING([--enable-hardening],
  97     [Enable compiler and linker options to frustrate memory corruption exploits @<:@default=yes@:>@])],
  98   [hardening="$enableval"],
  99   [hardening="yes"])
 100 AC_ARG_ENABLE([pie],
 101   [AS_HELP_STRING([--enable-pie],
 102     [Enable PIE (position independant executable) @<:@default=no@:>@])],
 103   [pie="$enableval"],
 104   [pie="no"])
 105
 106 if test x"$hardening" != x"no"; then
 107   AX_CFLAGS_GCC_OPTION([-fstack-protector], [LLDP_CFLAGS])
 108   AX_CFLAGS_GCC_OPTION([-fstack-protector-all], [LLDP_CFLAGS])
 109   AX_CFLAGS_GCC_OPTION([-fstack-protector-strong], [LLDP_CFLAGS])
 110   AX_CFLAGS_GCC_OPTION([-D_FORTIFY_SOURCE=2], [LLDP_CPPFLAGS])
 111 fi
 112 if test x"$pie" = x"yes"; then
 113   AX_CFLAGS_GCC_OPTION([-fPIE], [LLDP_CFLAGS])
 114   AX_LDFLAGS_OPTION([-fPIE -pie], [LLDP_BIN_LDFLAGS],
 115     [AX_LDFLAGS_OPTION([-fPIE -Wl,-pie], [LLDP_BIN_LDFLAGS])])
 116 fi
 117
 118 # Sanitizers
 119 AC_ARG_ENABLE([sanitizers],
 120   AS_HELP_STRING(
 121     [--enable-sanitizers],
 122     [Enable code instrumentation with selected sanitizers @<:@default=no@:>@]),
 123   [
 124 case "$enableval" in
 125     no) sanitizers= ;;
 126     yes) sanitizers="-fsanitize=address" ;;
 127     *) sanitizers="-fsanitize=$enableval" ;;
 128 esac
 129 if test x"$sanitizers" != x; then
 130   LLDP_CFLAGS="$LLDP_CFLAGS $sanitizers"
 131   LLDP_LDFLAGS="$LLDP_LDFLAGS $sanitizers"
 132   AC_DEFINE([HAVE_ADDRESS_SANITIZER], 1, [Define if have both address and leak sanitizer])
 133 fi
 134   ])
 135
 136 # OS
 137 lldp_CHECK_OS
 138 lldp_CFLAGS_OS
 139
 140 AC_CACHE_SAVE
 141
 142 # Checks for header files.
 143 AC_HEADER_RESOLV
 144 AC_CHECK_HEADERS([valgrind/valgrind.h])
 145 lldp_CHECK_STDINT
 146
 147 AC_CACHE_SAVE
 148
 149 # Checks for typedefs, structures, and compiler characteristics.
 150 lldp_CHECK___PROGNAME
 151 lldp_CHECK_ALIGNOF
 152
 153 # Checks for library functions.
 154 AC_CONFIG_LIBOBJ_DIR([src/compat])
 155 AC_FUNC_MALLOC
 156 AC_FUNC_REALLOC
 157 AC_FUNC_FORK
 158
 159 # Some functions can be in libbsd
 160 PKG_CHECK_MODULES([libbsd], [libbsd-overlay], [
 161   _save_CFLAGS="$CFLAGS"
 162   _save_LIBS="$LIBS"
 163   CFLAGS="$CFLAGS $libbsd_CFLAGS"
 164   LIBS="$LIBS $libbsd_LIBS"
 165   AC_MSG_CHECKING([if libbsd can be linked correctly])
 166   AC_LINK_IFELSE([AC_LANG_SOURCE([[int main() { return 0; }]])],
 167     [
 168       AC_MSG_RESULT(yes)
 169       LLDP_CFLAGS="$LLDP_CFLAGS $libbsd_CFLAGS"
 170       LLDP_LDFLAGS="$LLDP_LDFLAGS $libbsd_LIBS"
 171     ],[
 172       AC_MSG_RESULT(no)
 173       CFLAGS="$_save_CFLAGS"
 174       LIBS="$_save_LIBS"
 175     ])
 176 ], [:])
 177
 178 # setproctitle may have an _init function
 179 AC_REPLACE_FUNCS([setproctitle])
 180 AC_CHECK_FUNCS([setproctitle_init])
 181 # Other functions
 182 AC_REPLACE_FUNCS([strlcpy
 183                   strnlen
 184                   strndup
 185                   getline
 186                   asprintf
 187                   vsyslog
 188                   daemon])
 189 # Optional functions
 190 AC_CHECK_FUNCS([setresuid setresgid])
 191
 192 # Check for res_init. On OSX, res_init is a symbol in libsystem_info
 193 # and a macro in resolv.h. We need to ensure we test with resolv.h.
 194 m4_pushdef([AC_LANG_CALL(C)], [
 195   AC_LANG_PROGRAM([$1
 196 @%:@include <resolv.h>], [return $2 ();])])
 197 AC_SEARCH_LIBS([res_init], resolv bind,
 198                AC_DEFINE([HAVE_RES_INIT], 1,
 199                [Define to indicate that res_init() exists]))
 200 m4_popdef([AC_LANG_CALL(C)])
 201
 202 AC_CACHE_SAVE
 203
 204 ## Unit tests wich check
 205 PKG_CHECK_MODULES([CHECK], [check >= 0.9.4], [have_check=yes], [have_check=no])
 206
 207 # Third-party libraries
 208 lldp_CHECK_LIBEVENT
 209
 210 # Compatibility with pkg.m4 < 0.27
 211 m4_ifdef([PKG_INSTALLDIR], [PKG_INSTALLDIR],
 212          [AC_ARG_WITH([pkgconfigdir],
 213                       [AS_HELP_STRING([--with-pkgconfigdir],
 214                       [install directory for *.pc pkg-config file])],
 215                       [],[with_pkgconfigdir='$(libdir)/pkgconfig'])
 216           AC_SUBST([pkgconfigdir], [${with_pkgconfigdir}])])
 217
 218 #######################
 219 ### Options
 220
 221 # Readline
 222 AC_ARG_WITH([readline],
 223   AS_HELP_STRING(
 224     [--with-readline],
 225     [Enable the use of readline-like library @<:@default=auto@:>@]),
 226   [],
 227   [with_readline=auto])
 228 if test x"$with_readline" != x"no"; then
 229    AX_LIB_READLINE
 230    if test x"$with_readline" != x"check" -a x"$with_readline" != x"auto"; then
 231      if test x"$ax_cv_lib_readline" = x"no"; then
 232        AC_MSG_FAILURE([*** no readline support found])
 233      fi
 234    fi
 235 else
 236    ax_cv_lib_readline="no"
 237 fi
 238
 239 # SNMP
 240 AC_ARG_WITH([snmp],
 241   AS_HELP_STRING(
 242     [--with-snmp],
 243     [Enable the use of SNMP @<:@default=no@:>@]),
 244   [],
 245   [with_snmp=no])
 246 lldp_CHECK_SNMP
 247
 248 # XML
 249 AC_ARG_WITH([xml],
 250   AS_HELP_STRING(
 251     [--with-xml],
 252     [Enable XML output via libxml2 @<:@default=auto@:>@]),
 253   [],
 254   [with_xml=auto])
 255 lldp_CHECK_XML2
 256
 257 # JSON
 258 AC_ARG_WITH([json],
 259   AS_HELP_STRING(
 260     [--with-json],
 261     [Enable JSON output via janson or json-c @<:@default=auto@:>@]),
 262   [],
 263   [with_json=auto])
 264 if test x"$with_json" = x"yes" -o x"$with_json" = x"auto"; then
 265    _with_json="$with_json"
 266    with_json=auto
 267    lldp_CHECK_JANSSON
 268    if test x"$with_json" = x"no"; then
 269      with_json=auto
 270      lldp_CHECK_JSONC
 271    fi
 272    if test x"$with_json" = x"no" -a x"$_with_json" = x"yes"; then
 273      AC_MSG_FAILURE([*** no JSON support found])
 274    fi
 275 else
 276    lldp_CHECK_JANSSON
 277    lldp_CHECK_JSONC
 278 fi
 279
 280 # Seccomp
 281 AC_ARG_WITH([seccomp],
 282   AS_HELP_STRING(
 283     [--with-seccomp],
 284     [Enable seccomp support (with libseccomp, experimental) @<:@default=no@:>@]),
 285   [],
 286   [with_seccomp=no])
 287 lldp_CHECK_SECCOMP
 288
 289 # OS X launchd support
 290 lldp_ARG_WITH([launchddaemonsdir], [Directory for launchd configuration file (OSX)],
 291                                    [/Library/LaunchDaemons])
 292 AC_SUBST([launchddaemonsdir], [$with_launchddaemonsdir])
 293 AM_CONDITIONAL(HAVE_LAUNCHDDAEMONSDIR,
 294     [test -n "$with_launchddaemonsdir" -a "x$with_launchddaemonsdir" != xno ])
 295
 296 # Systemd
 297 lldp_ARG_WITH([systemdsystemunitdir], [Directory for systemd service files],
 298               [$($PKG_CONFIG --variable=systemdsystemunitdir systemd 2> /dev/null)])
 299 AC_SUBST([systemdsystemunitdir], [$with_systemdsystemunitdir])
 300 AM_CONDITIONAL(HAVE_SYSTEMDSYSTEMUNITDIR,
 301     [test -n "$with_systemdsystemunitdir" -a "x$with_systemdsystemunitdir" != xno ])
 302
 303 # sysusers
 304 lldp_ARG_WITH([sysusersdir], [Directory for sysusers files],
 305               [$($PKG_CONFIG --variable=sysusersdir systemd 2> /dev/null)])
 306 AC_SUBST([sysusersdir], [$with_sysusersdir])
 307 AM_CONDITIONAL(HAVE_SYSUSERSDIR,
 308     [test -n "$with_sysusersdir" -a "x$with_sysusersdir" != xno ])
 309
 310 # AppArmor
 311 lldp_ARG_WITH([apparmordir], [Directory for AppArmor profiles (Linux)],
 312                              [no])
 313 AC_SUBST([apparmordir], [$with_apparmordir])
 314 AM_CONDITIONAL(HAVE_APPARMORDIR,
 315     [test -n "$with_apparmordir" -a "x$with_apprmordir" != xno ])
 316
 317 # Systemtap/DTrace
 318 lldp_SYSTEMTAP
 319
 320 # Privsep settings
 321 lldp_ARG_ENABLE([privsep], [Privilege separation], [yes])
 322 lldp_ARG_WITH([privsep-user], [Which user to use for privilege separation], [_lldpd])
 323 lldp_ARG_WITH([privsep-group], [Which group to use for privilege separation], [_lldpd])
 324
 325 # Directories
 326 dnl On autoconf 2.69 and before, runstatedir is not configurable, let be able to use it anyway
 327 if test "x$runstatedir" = x; then
 328     AC_SUBST([runstatedir], ['${localstatedir}/run'])
 329 fi
 330 lldp_ARG_WITH([privsep-chroot], [Which directory to use to chroot lldpd], [${runstatedir}/lldpd])
 331 lldp_ARG_WITH([lldpd-ctl-socket], [Path to socket for communication with lldpd], [${runstatedir}/lldpd.socket])
 332 lldp_ARG_WITH([lldpd-pid-file], [Path to lldpd PID file], [${runstatedir}/lldpd.pid])
 333
 334 # CDP/FDP/EDP/SONMP
 335 lldp_ARG_ENABLE([cdp], [Cisco Discovery Protocol], [yes])
 336 lldp_ARG_ENABLE([fdp], [Foundry Discovery Protocol], [yes])
 337 lldp_ARG_ENABLE([edp], [Extreme Discovery Protocol], [yes])
 338 lldp_ARG_ENABLE([sonmp], [SynOptics Network Management Protocol], [yes])
 339
 340 # LLDPMED/Dot1/Dot3
 341 lldp_ARG_ENABLE([lldpmed], [LLDP-MED extension], [yes])
 342 lldp_ARG_ENABLE([dot1], [Dot1 extension (VLAN stuff)], [yes])
 343 lldp_ARG_ENABLE([dot3], [Dot3 extension (PHY stuff)], [yes])
 344 lldp_ARG_ENABLE([custom], [Custom TLV support], [yes])
 345
 346 # Oldies
 347 MIN_LINUX_KERNEL_VERSION=2.6.39
 348 lldp_ARG_ENABLE([oldies], [compatibility with Linux kernel older than 2.6.39], [no])
 349 if test x"$os" = x"Linux"; then
 350     if test x"$enable_oldies" = x"no"; then
 351       AC_DEFINE_UNQUOTED(MIN_LINUX_KERNEL_VERSION, "[$MIN_LINUX_KERNEL_VERSION]", [Minimal Linux kernel version required])
 352     else
 353       AC_DEFINE(MIN_LINUX_KERNEL_VERSION, "2.6.11", [Minimal kernel version required])
 354     fi
 355 fi
 356
 357 # Build date
 358 if test x"$SOURCE_DATE_EPOCH" != x; then
 359    AC_DEFINE_UNQUOTED(BUILD_DATE, "[$SOURCE_DATE_EPOCH]", [Build date and time])
 360 fi
 361 AC_DEFINE_UNQUOTED(LLDP_CC, "[$CC $LLDP_CFLAGS $LLDP_CPPFLAGS $CFLAGS $CPPFLAGS]", [C compiler command])
 362 AC_DEFINE_UNQUOTED(LLDP_LD, "[$LD $LLDP_LDFLAGS $LLDP_BIN_LDFLAGS $LDFLAGS $LIBS]", [Linker compiler command])
 363
 364 #######################
 365 # Output results
 366 AC_SUBST([LLDP_CFLAGS])
 367 AC_SUBST([LLDP_CPPFLAGS])
 368 AC_SUBST([LLDP_LDFLAGS])
 369 AC_SUBST([LLDP_BIN_LDFLAGS])
 370 AM_CONDITIONAL([HAVE_CHECK], [test x"$have_check" = x"yes"])
 371 AM_CONDITIONAL([USE_SNMP], [test x"$with_snmp" = x"yes"])
 372 AM_CONDITIONAL([USE_XML], [test x"$with_xml" = x"yes"])
 373 AM_CONDITIONAL([USE_JSON], [test x"$with_json" = x"json-c" || test -x"$with_json" = x"jansson"])
 374 AM_CONDITIONAL([USE_JANSSON], [test x"$with_json" = x"jansson"])
 375 AM_CONDITIONAL([USE_JSONC], [test x"$with_json" = x"json-c"])
 376 AM_CONDITIONAL([USE_SECCOMP], [test x"$with_seccomp" = x"yes"])
 377 AC_OUTPUT
 378
 379 if test x"$LIBEVENT_EMBEDDED" = x; then
 380    libevent=system
 381 else
 382    libevent=embedded
 383 fi
 384
 385 cat <<EOF
 386
 387 ------------------ Summary ------------------
 388  $PACKAGE_NAME version $PACKAGE_VERSION
 389   OS.............: $os
 390   Prefix.........: $prefix
 391   C Compiler.....: $CC $LLDP_CFLAGS $LLDP_CPPFLAGS $CFLAGS $CPPFLAGS
 392   Linker.........: $LD $LLDP_LDFLAGS $LLDP_BIN_LDFLAGS $LDFLAGS $LIBS
 393   Libevent.......: $libevent
 394   Readline.......: ${ax_cv_lib_readline}
 395
 396  Optional features:
 397   SNMP support...: ${with_snmp-no}
 398   CDP............: $enable_cdp
 399   FDP............: $enable_fdp
 400   EDP............: $enable_edp
 401   SONMP..........: $enable_sonmp
 402   LLDPMED........: $enable_lldpmed
 403   DOT1...........: $enable_dot1
 404   DOT3...........: $enable_dot3
 405   CUSTOM.........: $enable_custom
 406   XML output.....: ${with_xml-no}
 407   JSON output....: ${with_json-no}
 408   Oldies support.: $enable_oldies
 409   seccomp........: ${with_seccomp-no}
 410
 411  Privilege separation:
 412   Enabled........: $enable_privsep
 413   User/group.....: ${with_privsep_user}/${with_privsep_group}
 414   Chroot.........: ${with_privsep_chroot}
 415 ------------- Compiler version --------------
 416 $($CC --version || true)
 417 -------------- Linker version ---------------
 418 $($LD --version || true)
 419 ---------------------------------------------
 420
 421 Check the above options and compile with:
 422  ${MAKE-make}
 423
 424 EOF