configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 #######################
   5 ### Base configuration
   6
   7 # Configure autoconf
   8 AC_PREREQ([2.64])
   9
  10 AC_INIT([lldpd],
  11         [m4_esyscmd_s([./get-version])],
  12         [https://github.com/vincentbernat/lldpd/issues],
  13         [lldpd],
  14         [http://vincentbernat.github.io/lldpd/])
  15
  16 AC_CONFIG_SRCDIR([src/log.c])
  17 AC_CONFIG_HEADER([config.h])
  18 AC_CONFIG_FILES([Makefile
  19                  src/Makefile
  20                  src/compat/Makefile
  21                  src/daemon/Makefile
  22                  src/lib/Makefile
  23                  src/client/Makefile
  24                  tests/Makefile
  25                  osx/Makefile])
  26 AC_CONFIG_MACRO_DIR([m4])
  27 AC_SUBST([CONFIGURE_ARGS], [$ac_configure_args])
  28
  29 # Configure automake
  30 AM_INIT_AUTOMAKE([foreign subdir-objects -Wall -Werror])
  31 AM_MAINTAINER_MODE
  32 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES(yes)])
  33
  34 # Automake 1.12...
  35 m4_pattern_allow([AM_PROG_AR])
  36 AM_PROG_AR
  37
  38 # Configure libtool
  39 LT_INIT
  40
  41 #######################
  42 ### Checks
  43
  44 # Checks for programs.
  45 AC_PROG_CC
  46 AC_PROG_CC_C99
  47 if test x"$ac_cv_prog_cc_c99" = x"no"; then
  48   AC_MSG_FAILURE([*** C99 support is mandatory])
  49 fi
  50 AC_PROG_CXX
  51 AM_PROG_CC_C_O
  52 AC_PROG_LIBTOOL
  53 AC_PROG_LN_S
  54 AC_PROG_EGREP
  55 AC_PROG_AWK
  56
  57 # Doxygen
  58 DX_HTML_FEATURE(ON)
  59 DX_DOT_FEATURE(OFF)
  60 DX_CHM_FEATURE(OFF)
  61 DX_CHI_FEATURE(OFF)
  62 DX_MAN_FEATURE(OFF)
  63 DX_RTF_FEATURE(OFF)
  64 DX_XML_FEATURE(OFF)
  65 DX_PDF_FEATURE(ON)
  66 DX_PS_FEATURE(OFF)
  67 DX_INIT_DOXYGEN([lldpd], [doxygen.cfg], [doxygen])
  68
  69 # Check some compiler flags
  70 AX_CFLAGS_GCC_OPTION([-fdiagnostics-show-option], [LLDP_CFLAGS])
  71 AX_CFLAGS_GCC_OPTION([-fdiagnostics-color=auto], [LLDP_CFLAGS])
  72 AX_CFLAGS_GCC_OPTION([-pipe], [LLDP_CFLAGS])
  73 AX_CFLAGS_GCC_OPTION([-Wall], [LLDP_CFLAGS])
  74 AX_CFLAGS_GCC_OPTION([-W], [LLDP_CFLAGS])
  75 AX_CFLAGS_GCC_OPTION([-Wextra], [LLDP_CFLAGS])
  76 AX_CFLAGS_GCC_OPTION([-Wformat], [LLDP_CFLAGS])
  77 AX_CFLAGS_GCC_OPTION([-Wformat-security], [LLDP_CFLAGS])
  78 AX_CFLAGS_GCC_OPTION([-Wfatal-errors], [LLDP_CFLAGS])
  79 AX_CFLAGS_GCC_OPTION([-Wcast-align], [LLDP_CFLAGS])
  80 AX_CFLAGS_GCC_OPTION([-Winline], [LLDP_CFLAGS])
  81 AX_CFLAGS_GCC_OPTION([-fno-omit-frame-pointer], [LLDP_CFLAGS])
  82 AX_CFLAGS_GCC_OPTION([-Wno-unused-parameter], [LLDP_CFLAGS])
  83 AX_CFLAGS_GCC_OPTION([-Wno-missing-field-initializers], [LLDP_CFLAGS])
  84 AX_CFLAGS_GCC_OPTION([-Wno-sign-compare], [LLDP_CFLAGS]) dnl Should be fixed later
  85 AX_LDFLAGS_OPTION([-Wl,-z,relro], [LLDP_LDFLAGS])
  86 AX_LDFLAGS_OPTION([-Wl,-z,now], [LLDP_LDFLAGS])
  87
  88 # Hardening
  89 AC_ARG_ENABLE([hardening],
  90   [AS_HELP_STRING([--enable-hardening],
  91     [Enable compiler and linker options to frustrate memory corruption exploits @<:@yes@:>@])],
  92   [hardening="$enableval"],
  93   [hardening="yes"])
  94
  95 if test x"$hardening" != x"no"; then
  96   AX_CFLAGS_GCC_OPTION([-fstack-protector], [LLDP_CFLAGS])
  97   AX_CFLAGS_GCC_OPTION([-fstack-protector-all], [LLDP_CFLAGS])
  98   AX_CFLAGS_GCC_OPTION([-fstack-protector-strong], [LLDP_CFLAGS])
  99   AX_CFLAGS_GCC_OPTION([-D_FORTIFY_SOURCE=2], [LLDP_CPPFLAGS])
 100   AX_CFLAGS_GCC_OPTION([-fPIE], [LLDP_CFLAGS])
 101   AX_LDFLAGS_OPTION([-fPIE -Wl,-pie], [LLDP_LDFLAGS],
 102     [AX_LDFLAGS_OPTION([-fPIE -pie], [LLDP_LDFLAGS])])
 103 fi
 104
 105 # OS
 106 lldp_CHECK_OS
 107 lldp_CFLAGS_OS
 108
 109 AC_CACHE_SAVE
 110
 111 # Checks for header files.
 112 AC_HEADER_RESOLV
 113 AC_CHECK_HEADERS([valgrind/valgrind.h])
 114 lldp_CHECK_STDINT
 115
 116 AC_CACHE_SAVE
 117
 118 # Checks for typedefs, structures, and compiler characteristics.
 119 lldp_CHECK___PROGNAME
 120 lldp_CHECK_ALIGNOF
 121
 122 # Checks for library functions.
 123 AC_CONFIG_LIBOBJ_DIR([src/compat])
 124 AC_FUNC_MALLOC
 125 AC_FUNC_REALLOC
 126 AC_FUNC_FORK
 127 # setproctitle (maybe through libbsd)
 128 AC_SEARCH_LIBS([setproctitle], [util bsd])
 129 AC_REPLACE_FUNCS([setproctitle])
 130 AC_CHECK_FUNCS([setproctitle_init])
 131 # Other functions
 132 AC_REPLACE_FUNCS([strlcpy
 133                   strnlen
 134                   strndup
 135                   fgetln
 136                   asprintf
 137                   vsyslog
 138                   daemon])
 139 # Optional functions
 140 AC_CHECK_FUNCS([setresuid setresgid])
 141
 142 case " $LIBS " in
 143      *\ -lbsd\ *)
 144         AC_DEFINE(HAVE_LIBBSD, 1, [Define if libbsd is used])
 145         ;;
 146 esac
 147
 148 # Check for res_init. On OSX, res_init is a symbol in libsystem_info
 149 # and a macro in resolv.h. We need to ensure we test with resolv.h.
 150 m4_pushdef([AC_LANG_CALL(C)], [
 151   AC_LANG_PROGRAM([$1
 152 @%:@include <resolv.h>], [return $2 ();])])
 153 AC_SEARCH_LIBS([res_init], resolv bind,
 154                AC_DEFINE([HAVE_RES_INIT], 1,
 155                [Define to indicate that res_init() exists]))
 156 m4_popdef([AC_LANG_CALL(C)])
 157
 158 AC_CACHE_SAVE
 159
 160 ## Unit tests wich check
 161 PKG_CHECK_MODULES([CHECK], [check >= 0.9.4], [have_check=yes], [have_check=no])
 162
 163 # Libevent
 164 lldp_CHECK_LIBEVENT
 165
 166 # Compatibility with pkg.m4 < 0.27
 167 m4_ifdef([PKG_INSTALLDIR], [PKG_INSTALLDIR],
 168          [AC_ARG_WITH([pkgconfigdir],
 169                       [AS_HELP_STRING([--with-pkgconfigdir],
 170                       [install directory for *.pc pkg-config file])],
 171                       [],[with_pkgconfigdir='$(libdir)/pkgconfig'])
 172           AC_SUBST([pkgconfigdir], [${with_pkgconfigdir}])])
 173
 174 #######################
 175 ### Options
 176
 177 # Readline
 178 AC_ARG_WITH([readline],
 179   AS_HELP_STRING(
 180     [--with-readline],
 181     [Enable the use of readline-like library @<:@default=auto@:>@]),
 182   [],
 183   [with_readline=auto])
 184 if test x"$with_readline" != x"no"; then
 185    AX_LIB_READLINE
 186    if test x"$with_readline" != x"check" -a x"$with_readline" != x"auto"; then
 187      if test x"$ax_cv_lib_readline" = x"no"; then
 188        AC_MSG_FAILURE([*** no readline support found])
 189      fi
 190    fi
 191 else
 192    ax_cv_lib_readline="no"
 193 fi
 194
 195 # SNMP
 196 AC_ARG_WITH([snmp],
 197   AS_HELP_STRING(
 198     [--with-snmp],
 199     [Enable the use of SNMP @<:@default=no@:>@]),
 200   [],
 201   [with_snmp=no])
 202 lldp_CHECK_SNMP
 203
 204 # XML
 205 AC_ARG_WITH([xml],
 206   AS_HELP_STRING(
 207     [--with-xml],
 208     [Enable XML output via libxml2 @<:@default=auto@:>@]),
 209   [],
 210   [with_xml=auto])
 211 lldp_CHECK_XML2
 212
 213 # JSON
 214 AC_ARG_WITH([json],
 215   AS_HELP_STRING(
 216     [--with-json],
 217     [Enable JSON output via janson or json-c @<:@default=auto@:>@]),
 218   [],
 219   [with_json=auto])
 220 if test x"$with_json" = x"yes" -o x"$with_json" = x"auto"; then
 221    _with_json="$with_json"
 222    with_json=auto
 223    lldp_CHECK_JANSSON
 224    if test x"$with_json" = x"no"; then
 225      with_json=auto
 226      lldp_CHECK_JSONC
 227    fi
 228    if test x"$with_json" = x"no" -a x"$_with_json" = x"yes"; then
 229      AC_MSG_FAILURE([*** no JSON support found])
 230    fi
 231 else
 232    lldp_CHECK_JANSSON
 233    lldp_CHECK_JSONC
 234 fi
 235
 236 # Seccomp
 237 AC_ARG_WITH([seccomp],
 238   AS_HELP_STRING(
 239     [--with-seccomp],
 240     [Enable seccomp support (with libseccomp) @<:@default=no@:>@]),
 241   [],
 242   [with_seccomp=no])
 243 lldp_CHECK_SECCOMP
 244
 245 # OS X launchd support
 246 lldp_ARG_WITH([launchddaemonsdir], [Directory for launchd configuration file (OSX)],
 247                                    [/Library/LaunchDaemons])
 248 AC_SUBST([launchddaemonsdir], [$with_launchddaemonsdir])
 249 AM_CONDITIONAL(HAVE_LAUNCHDDAEMONSDIR,
 250     [test -n "$with_launchddaemonsdir" -a "x$with_launchddaemonsdir" != xno ])
 251
 252 # Systemd
 253 lldp_ARG_WITH([systemdsystemunitdir], [Directory for systemd service files],
 254               [$($PKG_CONFIG --variable=systemdsystemunitdir systemd 2> /dev/null)])
 255 AC_SUBST([systemdsystemunitdir], [$with_systemdsystemunitdir])
 256 AM_CONDITIONAL(HAVE_SYSTEMDSYSTEMUNITDIR,
 257     [test -n "$with_systemdsystemunitdir" -a "x$with_systemdsystemunitdir" != xno ])
 258
 259 # sysusers
 260 lldp_ARG_WITH([sysusersdir], [Directory for sysusers files],
 261               [$($PKG_CONFIG --variable=sysusersdir systemd 2> /dev/null)])
 262 AC_SUBST([sysusersdir], [$with_sysusersdir])
 263 AM_CONDITIONAL(HAVE_SYSUSERSDIR,
 264     [test -n "$with_sysusersdir" -a "x$with_sysusersdir" != xno ])
 265
 266 # Systemtap/DTrace
 267 lldp_SYSTEMTAP
 268
 269 # Privsep settings
 270 lldp_ARG_ENABLE([privsep], [Privilege separation], [yes])
 271 lldp_ARG_WITH([privsep-user], [Which user to use for privilege separation], [_lldpd])
 272 lldp_ARG_WITH([privsep-group], [Which group to use for privilege separation], [_lldpd])
 273
 274 # Directories
 275 dnl On autoconf 2.69 and before, runstatedir is not configurable, let be able to use it anyway
 276 if test "x$runstatedir" = x; then
 277     AC_SUBST([runstatedir], ['${localstatedir}/run'])
 278 fi
 279 lldp_ARG_WITH([privsep-chroot], [Which directory to use to chroot lldpd], [${runstatedir}/lldpd])
 280 lldp_ARG_WITH([lldpd-ctl-socket], [Path to socket for communication with lldpd], [${runstatedir}/lldpd.socket])
 281 lldp_ARG_WITH([lldpd-pid-file], [Path to lldpd PID file], [${runstatedir}/lldpd.pid])
 282
 283 # CDP/FDP/EDP/SONMP
 284 lldp_ARG_ENABLE([cdp], [Cisco Discovery Protocol], [yes])
 285 lldp_ARG_ENABLE([fdp], [Foundry Discovery Protocol], [yes])
 286 lldp_ARG_ENABLE([edp], [Extreme Discovery Protocol], [yes])
 287 lldp_ARG_ENABLE([sonmp], [SynOptics Network Management Protocol], [yes])
 288
 289 # LLDPMED/Dot1/Dot3
 290 lldp_ARG_ENABLE([lldpmed], [LLDP-MED extension], [yes])
 291 lldp_ARG_ENABLE([dot1], [Dot1 extension (VLAN stuff)], [yes])
 292 lldp_ARG_ENABLE([dot3], [Dot3 extension (PHY stuff)], [yes])
 293 lldp_ARG_ENABLE([custom], [Custom TLV support], [yes])
 294
 295 # Oldies
 296 lldp_ARG_ENABLE([oldies], [compatibility with Linux kernel older than 2.6.18], [no])
 297
 298 #######################
 299 # Output results
 300 AC_SUBST([LLDP_CFLAGS])
 301 AC_SUBST([LLDP_CPPFLAGS])
 302 AC_SUBST([LLDP_LDFLAGS])
 303 AM_CONDITIONAL([HAVE_CHECK], [test x"$have_check" = x"yes"])
 304 AM_CONDITIONAL([USE_SNMP], [test x"$with_snmp" = x"yes"])
 305 AM_CONDITIONAL([USE_XML], [test x"$with_xml" = x"yes"])
 306 AM_CONDITIONAL([USE_JSON], [test x"$with_json" = x"json-c" || test -x"$with_json" = x"jansson"])
 307 AM_CONDITIONAL([USE_JANSSON], [test x"$with_json" = x"jansson"])
 308 AM_CONDITIONAL([USE_JSONC], [test x"$with_json" = x"json-c"])
 309 AM_CONDITIONAL([USE_SECCOMP], [test x"$with_seccomp" = x"yes"])
 310 AC_OUTPUT
 311
 312 if test x"$LIBEVENT_EMBEDDED" = x; then
 313    libevent=system
 314 else
 315    libevent=embedded
 316 fi
 317
 318 cat <<EOF
 319
 320 ------------------ Summary ------------------
 321  $PACKAGE_NAME version $PACKAGE_VERSION
 322   OS.............: $os
 323   Prefix.........: $prefix
 324   C Compiler.....: $CC $LLDP_CFLAGS $LLDP_CPPFLAGS $CFLAGS $CPPFLAGS
 325   Linker.........: $LD $LLDP_LDFLAGS $LDFLAGS $LIBS
 326   Libevent.......: $libevent
 327   Readline.......: ${ax_cv_lib_readline}
 328  Optional features:
 329   SNMP support...: ${with_snmp-no}
 330   CDP............: $enable_cdp
 331   FDP............: $enable_fdp
 332   EDP............: $enable_edp
 333   SONMP..........: $enable_sonmp
 334   LLDPMED........: $enable_lldpmed
 335   DOT1...........: $enable_dot1
 336   DOT3...........: $enable_dot3
 337   CUSTOM.........: $enable_custom
 338   XML output.....: ${with_xml-no}
 339   JSON output....: ${with_json-no}
 340   Oldies support.: $enable_oldies
 341   seccomp........: ${with_seccomp-no}
 342  Privilege separation:
 343   Enabled........: $enable_privsep
 344   User/group.....: ${with_privsep_user}/${with_privsep_group}
 345   Chroot.........: ${with_privsep_chroot}
 346 ---------------------------------------------
 347
 348 Check the above options and compile with:
 349  ${MAKE-make}
 350
 351 EOF