configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 #######################
   5 ### Base configuration
   6
   7 # Configure autoconf
   8 AC_PREREQ([2.64])
   9
  10 AC_INIT([lldpd],
  11         [m4_esyscmd_s([./get-version])],
  12         [https://github.com/vincentbernat/lldpd/issues],
  13         [lldpd],
  14         [http://vincentbernat.github.io/lldpd/])
  15
  16 AC_CONFIG_SRCDIR([src/log.c])
  17 AC_CONFIG_HEADER([config.h])
  18 AC_CONFIG_FILES([Makefile
  19                  src/Makefile
  20                  src/compat/Makefile
  21                  src/daemon/Makefile
  22                  src/lib/Makefile
  23                  src/client/Makefile
  24                  tests/Makefile
  25                  osx/Makefile])
  26 AC_CONFIG_MACRO_DIR([m4])
  27 AC_SUBST([CONFIGURE_ARGS], [$ac_configure_args])
  28
  29 # Configure automake
  30 AM_INIT_AUTOMAKE([foreign subdir-objects -Wall -Werror])
  31 AM_MAINTAINER_MODE
  32 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES(yes)])
  33
  34 # Automake 1.12...
  35 m4_pattern_allow([AM_PROG_AR])
  36 AM_PROG_AR
  37
  38 # Configure libtool
  39 LT_INIT
  40
  41 #######################
  42 ### Checks
  43
  44 # Checks for programs.
  45 AC_PROG_CC
  46 AC_PROG_CC_C99
  47 if test x"$ac_cv_prog_cc_c99" = x"no"; then
  48   AC_MSG_FAILURE([*** C99 support is mandatory])
  49 fi
  50 AC_PROG_CXX
  51 AM_PROG_CC_C_O
  52 AC_PROG_LIBTOOL
  53 AC_PROG_LN_S
  54 AC_PROG_EGREP
  55 AC_PROG_AWK
  56
  57 # Doxygen
  58 DX_HTML_FEATURE(ON)
  59 DX_DOT_FEATURE(OFF)
  60 DX_CHM_FEATURE(OFF)
  61 DX_CHI_FEATURE(OFF)
  62 DX_MAN_FEATURE(OFF)
  63 DX_RTF_FEATURE(OFF)
  64 DX_XML_FEATURE(OFF)
  65 DX_PDF_FEATURE(ON)
  66 DX_PS_FEATURE(OFF)
  67 DX_INIT_DOXYGEN([lldpd], [doxygen.cfg], [doxygen])
  68
  69 # Check some compiler flags
  70 AX_CFLAGS_GCC_OPTION([-fdiagnostics-show-option], [LLDP_CFLAGS])
  71 AX_CFLAGS_GCC_OPTION([-fdiagnostics-color=auto], [LLDP_CFLAGS])
  72 AX_CFLAGS_GCC_OPTION([-pipe], [LLDP_CFLAGS])
  73 AX_CFLAGS_GCC_OPTION([-Wall], [LLDP_CFLAGS])
  74 AX_CFLAGS_GCC_OPTION([-W], [LLDP_CFLAGS])
  75 AX_CFLAGS_GCC_OPTION([-Wextra], [LLDP_CFLAGS])
  76 AX_CFLAGS_GCC_OPTION([-Wformat], [LLDP_CFLAGS])
  77 AX_CFLAGS_GCC_OPTION([-Wformat-security], [LLDP_CFLAGS])
  78 AX_CFLAGS_GCC_OPTION([-Wfatal-errors], [LLDP_CFLAGS])
  79 AX_CFLAGS_GCC_OPTION([-Wcast-align], [LLDP_CFLAGS])
  80 AX_CFLAGS_GCC_OPTION([-Winline], [LLDP_CFLAGS])
  81 AX_CFLAGS_GCC_OPTION([-fstack-protector], [LLDP_CFLAGS])
  82 AX_CFLAGS_GCC_OPTION([-fstack-protector-strong], [LLDP_CFLAGS])
  83 AX_CFLAGS_GCC_OPTION([-fno-omit-frame-pointer], [LLDP_CFLAGS])
  84 AX_CFLAGS_GCC_OPTION([-D_FORTIFY_SOURCE=2], [LLDP_CPPFLAGS])
  85 AX_CFLAGS_GCC_OPTION([-Wno-unused-parameter], [LLDP_CFLAGS])
  86 AX_CFLAGS_GCC_OPTION([-Wno-missing-field-initializers], [LLDP_CFLAGS])
  87 AX_CFLAGS_GCC_OPTION([-Wno-sign-compare], [LLDP_CFLAGS]) dnl Should be fixed later
  88 AX_LDFLAGS_OPTION([-Wl,-z,relro], [LLDP_LDFLAGS])
  89 AX_LDFLAGS_OPTION([-Wl,-z,now], [LLDP_LDFLAGS])
  90
  91 # OS
  92 lldp_CHECK_OS
  93 lldp_CFLAGS_OS
  94
  95 AC_CACHE_SAVE
  96
  97 # Checks for header files.
  98 AC_HEADER_RESOLV
  99 AC_CHECK_HEADERS([valgrind/valgrind.h])
 100 lldp_CHECK_STDINT
 101
 102 AC_CACHE_SAVE
 103
 104 # Checks for typedefs, structures, and compiler characteristics.
 105 lldp_CHECK___PROGNAME
 106 lldp_CHECK_ALIGNOF
 107
 108 # Checks for library functions.
 109 AC_CONFIG_LIBOBJ_DIR([src/compat])
 110 AC_FUNC_MALLOC
 111 AC_FUNC_REALLOC
 112 AC_FUNC_FORK
 113 # setproctitle (maybe through libbsd)
 114 AC_SEARCH_LIBS([setproctitle], [util bsd])
 115 AC_REPLACE_FUNCS([setproctitle])
 116 AC_CHECK_FUNCS([setproctitle_init])
 117 # Other functions
 118 AC_REPLACE_FUNCS([strlcpy
 119                   strnlen
 120                   strndup
 121                   fgetln
 122                   asprintf
 123                   vsyslog
 124                   daemon])
 125 # Optional functions
 126 AC_CHECK_FUNCS([setresuid setresgid])
 127
 128 case " $LIBS " in
 129      *\ -lbsd\ *)
 130         AC_DEFINE(HAVE_LIBBSD, 1, [Define if libbsd is used])
 131         ;;
 132 esac
 133
 134 # Check for res_init. On OSX, res_init is a symbol in libsystem_info
 135 # and a macro in resolv.h. We need to ensure we test with resolv.h.
 136 m4_pushdef([AC_LANG_CALL(C)], [
 137   AC_LANG_PROGRAM([$1
 138 @%:@include <resolv.h>], [return $2 ();])])
 139 AC_SEARCH_LIBS([res_init], resolv bind,
 140                AC_DEFINE([HAVE_RES_INIT], 1,
 141                [Define to indicate that res_init() exists]))
 142 m4_popdef([AC_LANG_CALL(C)])
 143
 144 AC_CACHE_SAVE
 145
 146 ## Unit tests wich check
 147 PKG_CHECK_MODULES([CHECK], [check >= 0.9.4], [have_check=yes], [have_check=no])
 148
 149 # Libevent
 150 lldp_CHECK_LIBEVENT
 151
 152 # Compatibility with pkg.m4 < 0.27
 153 m4_ifdef([PKG_INSTALLDIR], [PKG_INSTALLDIR],
 154          [AC_ARG_WITH([pkgconfigdir],
 155                       [AS_HELP_STRING([--with-pkgconfigdir],
 156                       [install directory for *.pc pkg-config file])],
 157                       [],[with_pkgconfigdir='$(libdir)/pkgconfig'])
 158           AC_SUBST([pkgconfigdir], [${with_pkgconfigdir}])])
 159
 160 #######################
 161 ### Options
 162
 163 # Readline
 164 AC_ARG_WITH([readline],
 165   AS_HELP_STRING(
 166     [--with-readline],
 167     [Enable the use of readline-like library @<:@default=auto@:>@]),
 168   [],
 169   [with_readline=auto])
 170 if test x"$with_readline" != x"no"; then
 171    AX_LIB_READLINE
 172    if test x"$with_readline" != x"check" -a x"$with_readline" != x"auto"; then
 173      if test x"$ax_cv_lib_readline" = x"no"; then
 174        AC_MSG_FAILURE([*** no readline support found])
 175      fi
 176    fi
 177 else
 178    ax_cv_lib_readline="no"
 179 fi
 180
 181 # SNMP
 182 AC_ARG_WITH([snmp],
 183   AS_HELP_STRING(
 184     [--with-snmp],
 185     [Enable the use of SNMP @<:@default=no@:>@]),
 186   [],
 187   [with_snmp=no])
 188 lldp_CHECK_SNMP
 189
 190 # XML
 191 AC_ARG_WITH([xml],
 192   AS_HELP_STRING(
 193     [--with-xml],
 194     [Enable XML output via libxml2 @<:@default=auto@:>@]),
 195   [],
 196   [with_xml=auto])
 197 lldp_CHECK_XML2
 198
 199 # JSON
 200 AC_ARG_WITH([json],
 201   AS_HELP_STRING(
 202     [--with-json],
 203     [Enable JSON output via janson or json-c @<:@default=auto@:>@]),
 204   [],
 205   [with_json=auto])
 206 if test x"$with_json" = x"yes" -o x"$with_json" = x"auto"; then
 207    _with_json="$with_json"
 208    with_json=auto
 209    lldp_CHECK_JANSSON
 210    if test x"$with_json" = x"no"; then
 211      with_json=auto
 212      lldp_CHECK_JSONC
 213    fi
 214    if test x"$with_json" = x"no" -a x"$_with_json" = x"yes"; then
 215      AC_MSG_FAILURE([*** no JSON support found])
 216    fi
 217 else
 218    lldp_CHECK_JANSSON
 219    lldp_CHECK_JSONC
 220 fi
 221
 222 # Seccomp
 223 AC_ARG_WITH([seccomp],
 224   AS_HELP_STRING(
 225     [--with-seccomp],
 226     [Enable seccomp support (with libseccomp) @<:@default=no@:>@]),
 227   [],
 228   [with_seccomp=no])
 229 lldp_CHECK_SECCOMP
 230
 231 # OS X launchd support
 232 lldp_ARG_WITH([launchddaemonsdir], [Directory for launchd configuration file (OSX)],
 233                                    [/Library/LaunchDaemons])
 234 AC_SUBST([launchddaemonsdir], [$with_launchddaemonsdir])
 235 AM_CONDITIONAL(HAVE_LAUNCHDDAEMONSDIR,
 236     [test -n "$with_launchddaemonsdir" -a "x$with_launchddaemonsdir" != xno ])
 237
 238 # Systemd
 239 lldp_ARG_WITH([systemdsystemunitdir], [Directory for systemd service files],
 240               [$($PKG_CONFIG --variable=systemdsystemunitdir systemd 2> /dev/null)])
 241 AC_SUBST([systemdsystemunitdir], [$with_systemdsystemunitdir])
 242 AM_CONDITIONAL(HAVE_SYSTEMDSYSTEMUNITDIR,
 243     [test -n "$with_systemdsystemunitdir" -a "x$with_systemdsystemunitdir" != xno ])
 244
 245 # sysusers
 246 lldp_ARG_WITH([sysusersdir], [Directory for sysusers files],
 247               [$($PKG_CONFIG --variable=sysusersdir systemd 2> /dev/null)])
 248 AC_SUBST([sysusersdir], [$with_sysusersdir])
 249 AM_CONDITIONAL(HAVE_SYSUSERSDIR,
 250     [test -n "$with_sysusersdir" -a "x$with_sysusersdir" != xno ])
 251
 252 # Systemtap/DTrace
 253 lldp_SYSTEMTAP
 254
 255 # Privsep settings
 256 lldp_ARG_ENABLE([privsep], [Privilege separation], [yes])
 257 lldp_ARG_WITH([privsep-user], [Which user to use for privilege separation], [_lldpd])
 258 lldp_ARG_WITH([privsep-group], [Which group to use for privilege separation], [_lldpd])
 259
 260 # Directories
 261 dnl On autoconf 2.69 and before, runstatedir is not configurable, let be able to use it anyway
 262 if test "x$runstatedir" = x; then
 263     AC_SUBST([runstatedir], ['${localstatedir}/run'])
 264 fi
 265 lldp_ARG_WITH([privsep-chroot], [Which directory to use to chroot lldpd], [${runstatedir}/lldpd])
 266 lldp_ARG_WITH([lldpd-ctl-socket], [Path to socket for communication with lldpd], [${runstatedir}/lldpd.socket])
 267 lldp_ARG_WITH([lldpd-pid-file], [Path to lldpd PID file], [${runstatedir}/lldpd.pid])
 268
 269 # CDP/FDP/EDP/SONMP
 270 lldp_ARG_ENABLE([cdp], [Cisco Discovery Protocol], [yes])
 271 lldp_ARG_ENABLE([fdp], [Foundry Discovery Protocol], [yes])
 272 lldp_ARG_ENABLE([edp], [Extreme Discovery Protocol], [yes])
 273 lldp_ARG_ENABLE([sonmp], [SynOptics Network Management Protocol], [yes])
 274
 275 # LLDPMED/Dot1/Dot3
 276 lldp_ARG_ENABLE([lldpmed], [LLDP-MED extension], [yes])
 277 lldp_ARG_ENABLE([dot1], [Dot1 extension (VLAN stuff)], [yes])
 278 lldp_ARG_ENABLE([dot3], [Dot3 extension (PHY stuff)], [yes])
 279
 280 # Oldies
 281 lldp_ARG_ENABLE([oldies], [compatibility with Linux kernel older than 2.6.18], [no])
 282
 283 #######################
 284 # Output results
 285 AC_SUBST([LLDP_CFLAGS])
 286 AC_SUBST([LLDP_CPPFLAGS])
 287 AC_SUBST([LLDP_LDFLAGS])
 288 AM_CONDITIONAL([HAVE_CHECK], [test x"$have_check" = x"yes"])
 289 AM_CONDITIONAL([USE_SNMP], [test x"$with_snmp" = x"yes"])
 290 AM_CONDITIONAL([USE_XML], [test x"$with_xml" = x"yes"])
 291 AM_CONDITIONAL([USE_JSON], [test x"$with_json" = x"json-c" || test -x"$with_json" = x"jansson"])
 292 AM_CONDITIONAL([USE_JANSSON], [test x"$with_json" = x"jansson"])
 293 AM_CONDITIONAL([USE_JSONC], [test x"$with_json" = x"json-c"])
 294 AM_CONDITIONAL([USE_SECCOMP], [test x"$with_seccomp" = x"yes"])
 295 AC_OUTPUT
 296
 297 if test x"$LIBEVENT_EMBEDDED" = x; then
 298    libevent=system
 299 else
 300    libevent=embedded
 301 fi
 302
 303 cat <<EOF
 304
 305 ------------------ Summary ------------------
 306  $PACKAGE_NAME version $PACKAGE_VERSION
 307   OS.............: $os
 308   Prefix.........: $prefix
 309   C Compiler.....: $CC $LLDP_CFLAGS $LLDP_CPPFLAGS $CFLAGS $CPPFLAGS
 310   Linker.........: $LD $LLDP_LDFLAGS $LDFLAGS $LIBS
 311   Libevent.......: $libevent
 312   Readline.......: ${ax_cv_lib_readline}
 313  Optional features:
 314   SNMP support...: ${with_snmp-no}
 315   CDP............: $enable_cdp
 316   FDP............: $enable_fdp
 317   EDP............: $enable_edp
 318   SONMP..........: $enable_sonmp
 319   LLDPMED........: $enable_lldpmed
 320   DOT1...........: $enable_dot1
 321   DOT3...........: $enable_dot3
 322   XML output.....: ${with_xml-no}
 323   JSON output....: ${with_json-no}
 324   Oldies support.: $enable_oldies
 325   seccomp........: ${with_seccomp-no}
 326  Privilege separation:
 327   Enabled........: $enable_privsep
 328   User/group.....: ${with_privsep_user}/${with_privsep_group}
 329   Chroot.........: ${with_privsep_chroot}
 330 ---------------------------------------------
 331
 332 Check the above options and compile with:
 333  ${MAKE-make}
 334
 335 EOF