configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 #######################
   5 ### Base configuration
   6
   7 # Configure autoconf
   8 AC_PREREQ([2.64])
   9
  10 AC_INIT([lldpd],
  11         [m4_esyscmd_s([./get-version])],
  12         [https://github.com/vincentbernat/lldpd/issues],
  13         [lldpd],
  14         [http://vincentbernat.github.io/lldpd/])
  15
  16 AC_CONFIG_SRCDIR([src/log.c])
  17 AC_CONFIG_HEADER([config.h])
  18 AC_CONFIG_FILES([Makefile
  19                  src/Makefile
  20                  src/compat/Makefile
  21                  src/daemon/Makefile
  22                  src/lib/Makefile
  23                  src/client/Makefile
  24                  tests/Makefile
  25                  osx/Makefile])
  26 AC_CONFIG_MACRO_DIR([m4])
  27 AC_SUBST([CONFIGURE_ARGS], [$ac_configure_args])
  28
  29 # Configure automake
  30 AM_INIT_AUTOMAKE([foreign subdir-objects -Wall -Werror])
  31 AM_MAINTAINER_MODE
  32 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES(yes)])
  33
  34 # Automake 1.12...
  35 m4_pattern_allow([AM_PROG_AR])
  36 AM_PROG_AR
  37
  38 # Configure libtool
  39 LT_INIT
  40
  41 #######################
  42 ### Checks
  43
  44 # Checks for programs.
  45 AC_PROG_CC
  46 AC_PROG_CC_C99
  47 if test x"$ac_cv_prog_cc_c99" = x"no"; then
  48   AC_MSG_FAILURE([*** C99 support is mandatory])
  49 fi
  50 AC_PROG_CXX
  51 AM_PROG_CC_C_O
  52 AC_PROG_LIBTOOL
  53 AC_PROG_LN_S
  54 AC_PROG_EGREP
  55 AC_PROG_AWK
  56
  57 # Doxygen
  58 DX_HTML_FEATURE(ON)
  59 DX_DOT_FEATURE(OFF)
  60 DX_CHM_FEATURE(OFF)
  61 DX_CHI_FEATURE(OFF)
  62 DX_MAN_FEATURE(OFF)
  63 DX_RTF_FEATURE(OFF)
  64 DX_XML_FEATURE(OFF)
  65 DX_PDF_FEATURE(ON)
  66 DX_PS_FEATURE(OFF)
  67 DX_INIT_DOXYGEN([lldpd], [doxygen.cfg], [doxygen])
  68
  69 # Check some compiler flags
  70 AX_CFLAGS_GCC_OPTION([-Wunknown-warning-option], [LLDP_CFLAGS])
  71 AX_CFLAGS_GCC_OPTION([-fdiagnostics-show-option], [LLDP_CFLAGS])
  72 AX_CFLAGS_GCC_OPTION([-fdiagnostics-color=auto], [LLDP_CFLAGS])
  73 AX_CFLAGS_GCC_OPTION([-pipe], [LLDP_CFLAGS])
  74 AX_CFLAGS_GCC_OPTION([-Wall], [LLDP_CFLAGS])
  75 AX_CFLAGS_GCC_OPTION([-W], [LLDP_CFLAGS])
  76 AX_CFLAGS_GCC_OPTION([-Wextra], [LLDP_CFLAGS])
  77 AX_CFLAGS_GCC_OPTION([-Wformat], [LLDP_CFLAGS])
  78 AX_CFLAGS_GCC_OPTION([-Wformat-security], [LLDP_CFLAGS])
  79 AX_CFLAGS_GCC_OPTION([-Wfatal-errors], [LLDP_CFLAGS])
  80 AX_CFLAGS_GCC_OPTION([-Wcast-align], [LLDP_CFLAGS])
  81 AX_CFLAGS_GCC_OPTION([-Wheader-guard], [LLDP_CFLAGS])
  82 AX_CFLAGS_GCC_OPTION([-Wdocumentation], [LLDP_CFLAGS])
  83 AX_CFLAGS_GCC_OPTION([-Winline], [LLDP_CFLAGS])
  84 AX_CFLAGS_GCC_OPTION([-fno-omit-frame-pointer], [LLDP_CFLAGS])
  85 AX_CFLAGS_GCC_OPTION([-Wno-unused-parameter], [LLDP_CFLAGS])
  86 AX_CFLAGS_GCC_OPTION([-Wno-missing-field-initializers], [LLDP_CFLAGS])
  87 AX_CFLAGS_GCC_OPTION([-Wno-sign-compare], [LLDP_CFLAGS]) dnl Should be fixed later
  88 AX_LDFLAGS_OPTION([-Wl,-z,relro], [LLDP_LDFLAGS])
  89 AX_LDFLAGS_OPTION([-Wl,-z,now], [LLDP_LDFLAGS])
  90
  91 # Hardening
  92 AC_ARG_ENABLE([hardening],
  93   [AS_HELP_STRING([--enable-hardening],
  94     [Enable compiler and linker options to frustrate memory corruption exploits @<:@yes@:>@])],
  95   [hardening="$enableval"],
  96   [hardening="yes"])
  97
  98 if test x"$hardening" != x"no"; then
  99   AX_CFLAGS_GCC_OPTION([-fstack-protector], [LLDP_CFLAGS])
 100   AX_CFLAGS_GCC_OPTION([-fstack-protector-all], [LLDP_CFLAGS])
 101   AX_CFLAGS_GCC_OPTION([-fstack-protector-strong], [LLDP_CFLAGS])
 102   AX_CFLAGS_GCC_OPTION([-D_FORTIFY_SOURCE=2], [LLDP_CPPFLAGS])
 103   AX_CFLAGS_GCC_OPTION([-fPIE], [LLDP_CFLAGS])
 104   AX_LDFLAGS_OPTION([-fPIE -pie], [LLDP_BIN_LDFLAGS],
 105     [AX_LDFLAGS_OPTION([-fPIE -Wl,-pie], [LLDP_BIN_LDFLAGS])])
 106 fi
 107
 108 # OS
 109 lldp_CHECK_OS
 110 lldp_CFLAGS_OS
 111
 112 AC_CACHE_SAVE
 113
 114 # Checks for header files.
 115 AC_HEADER_RESOLV
 116 AC_CHECK_HEADERS([valgrind/valgrind.h])
 117 lldp_CHECK_STDINT
 118
 119 AC_CACHE_SAVE
 120
 121 # Checks for typedefs, structures, and compiler characteristics.
 122 lldp_CHECK___PROGNAME
 123 lldp_CHECK_ALIGNOF
 124
 125 # Checks for library functions.
 126 AC_CONFIG_LIBOBJ_DIR([src/compat])
 127 AC_FUNC_MALLOC
 128 AC_FUNC_REALLOC
 129 AC_FUNC_FORK
 130 # setproctitle (maybe through libbsd)
 131 AC_SEARCH_LIBS([setproctitle], [util bsd])
 132 AC_REPLACE_FUNCS([setproctitle])
 133 AC_CHECK_FUNCS([setproctitle_init])
 134 # Other functions
 135 AC_REPLACE_FUNCS([strlcpy
 136                   strnlen
 137                   strndup
 138                   fgetln
 139                   asprintf
 140                   vsyslog
 141                   daemon])
 142 # Optional functions
 143 AC_CHECK_FUNCS([setresuid setresgid])
 144
 145 case " $LIBS " in
 146      *\ -lbsd\ *)
 147         AC_DEFINE(HAVE_LIBBSD, 1, [Define if libbsd is used])
 148         ;;
 149 esac
 150
 151 # Check for res_init. On OSX, res_init is a symbol in libsystem_info
 152 # and a macro in resolv.h. We need to ensure we test with resolv.h.
 153 m4_pushdef([AC_LANG_CALL(C)], [
 154   AC_LANG_PROGRAM([$1
 155 @%:@include <resolv.h>], [return $2 ();])])
 156 AC_SEARCH_LIBS([res_init], resolv bind,
 157                AC_DEFINE([HAVE_RES_INIT], 1,
 158                [Define to indicate that res_init() exists]))
 159 m4_popdef([AC_LANG_CALL(C)])
 160
 161 AC_CACHE_SAVE
 162
 163 ## Unit tests wich check
 164 PKG_CHECK_MODULES([CHECK], [check >= 0.9.4], [have_check=yes], [have_check=no])
 165
 166 # Libevent
 167 lldp_CHECK_LIBEVENT
 168
 169 # Compatibility with pkg.m4 < 0.27
 170 m4_ifdef([PKG_INSTALLDIR], [PKG_INSTALLDIR],
 171          [AC_ARG_WITH([pkgconfigdir],
 172                       [AS_HELP_STRING([--with-pkgconfigdir],
 173                       [install directory for *.pc pkg-config file])],
 174                       [],[with_pkgconfigdir='$(libdir)/pkgconfig'])
 175           AC_SUBST([pkgconfigdir], [${with_pkgconfigdir}])])
 176
 177 #######################
 178 ### Options
 179
 180 # Readline
 181 AC_ARG_WITH([readline],
 182   AS_HELP_STRING(
 183     [--with-readline],
 184     [Enable the use of readline-like library @<:@default=auto@:>@]),
 185   [],
 186   [with_readline=auto])
 187 if test x"$with_readline" != x"no"; then
 188    AX_LIB_READLINE
 189    if test x"$with_readline" != x"check" -a x"$with_readline" != x"auto"; then
 190      if test x"$ax_cv_lib_readline" = x"no"; then
 191        AC_MSG_FAILURE([*** no readline support found])
 192      fi
 193    fi
 194 else
 195    ax_cv_lib_readline="no"
 196 fi
 197
 198 # SNMP
 199 AC_ARG_WITH([snmp],
 200   AS_HELP_STRING(
 201     [--with-snmp],
 202     [Enable the use of SNMP @<:@default=no@:>@]),
 203   [],
 204   [with_snmp=no])
 205 lldp_CHECK_SNMP
 206
 207 # XML
 208 AC_ARG_WITH([xml],
 209   AS_HELP_STRING(
 210     [--with-xml],
 211     [Enable XML output via libxml2 @<:@default=auto@:>@]),
 212   [],
 213   [with_xml=auto])
 214 lldp_CHECK_XML2
 215
 216 # JSON
 217 AC_ARG_WITH([json],
 218   AS_HELP_STRING(
 219     [--with-json],
 220     [Enable JSON output via janson or json-c @<:@default=auto@:>@]),
 221   [],
 222   [with_json=auto])
 223 if test x"$with_json" = x"yes" -o x"$with_json" = x"auto"; then
 224    _with_json="$with_json"
 225    with_json=auto
 226    lldp_CHECK_JANSSON
 227    if test x"$with_json" = x"no"; then
 228      with_json=auto
 229      lldp_CHECK_JSONC
 230    fi
 231    if test x"$with_json" = x"no" -a x"$_with_json" = x"yes"; then
 232      AC_MSG_FAILURE([*** no JSON support found])
 233    fi
 234 else
 235    lldp_CHECK_JANSSON
 236    lldp_CHECK_JSONC
 237 fi
 238
 239 # Seccomp
 240 AC_ARG_WITH([seccomp],
 241   AS_HELP_STRING(
 242     [--with-seccomp],
 243     [Enable seccomp support (with libseccomp) @<:@default=no@:>@]),
 244   [],
 245   [with_seccomp=no])
 246 lldp_CHECK_SECCOMP
 247
 248 # OS X launchd support
 249 lldp_ARG_WITH([launchddaemonsdir], [Directory for launchd configuration file (OSX)],
 250                                    [/Library/LaunchDaemons])
 251 AC_SUBST([launchddaemonsdir], [$with_launchddaemonsdir])
 252 AM_CONDITIONAL(HAVE_LAUNCHDDAEMONSDIR,
 253     [test -n "$with_launchddaemonsdir" -a "x$with_launchddaemonsdir" != xno ])
 254
 255 # Systemd
 256 lldp_ARG_WITH([systemdsystemunitdir], [Directory for systemd service files],
 257               [$($PKG_CONFIG --variable=systemdsystemunitdir systemd 2> /dev/null)])
 258 AC_SUBST([systemdsystemunitdir], [$with_systemdsystemunitdir])
 259 AM_CONDITIONAL(HAVE_SYSTEMDSYSTEMUNITDIR,
 260     [test -n "$with_systemdsystemunitdir" -a "x$with_systemdsystemunitdir" != xno ])
 261
 262 # sysusers
 263 lldp_ARG_WITH([sysusersdir], [Directory for sysusers files],
 264               [$($PKG_CONFIG --variable=sysusersdir systemd 2> /dev/null)])
 265 AC_SUBST([sysusersdir], [$with_sysusersdir])
 266 AM_CONDITIONAL(HAVE_SYSUSERSDIR,
 267     [test -n "$with_sysusersdir" -a "x$with_sysusersdir" != xno ])
 268
 269 # Systemtap/DTrace
 270 lldp_SYSTEMTAP
 271
 272 # Privsep settings
 273 lldp_ARG_ENABLE([privsep], [Privilege separation], [yes])
 274 lldp_ARG_WITH([privsep-user], [Which user to use for privilege separation], [_lldpd])
 275 lldp_ARG_WITH([privsep-group], [Which group to use for privilege separation], [_lldpd])
 276
 277 # Directories
 278 dnl On autoconf 2.69 and before, runstatedir is not configurable, let be able to use it anyway
 279 if test "x$runstatedir" = x; then
 280     AC_SUBST([runstatedir], ['${localstatedir}/run'])
 281 fi
 282 lldp_ARG_WITH([privsep-chroot], [Which directory to use to chroot lldpd], [${runstatedir}/lldpd])
 283 lldp_ARG_WITH([lldpd-ctl-socket], [Path to socket for communication with lldpd], [${runstatedir}/lldpd.socket])
 284 lldp_ARG_WITH([lldpd-pid-file], [Path to lldpd PID file], [${runstatedir}/lldpd.pid])
 285
 286 # CDP/FDP/EDP/SONMP
 287 lldp_ARG_ENABLE([cdp], [Cisco Discovery Protocol], [yes])
 288 lldp_ARG_ENABLE([fdp], [Foundry Discovery Protocol], [yes])
 289 lldp_ARG_ENABLE([edp], [Extreme Discovery Protocol], [yes])
 290 lldp_ARG_ENABLE([sonmp], [SynOptics Network Management Protocol], [yes])
 291
 292 # LLDPMED/Dot1/Dot3
 293 lldp_ARG_ENABLE([lldpmed], [LLDP-MED extension], [yes])
 294 lldp_ARG_ENABLE([dot1], [Dot1 extension (VLAN stuff)], [yes])
 295 lldp_ARG_ENABLE([dot3], [Dot3 extension (PHY stuff)], [yes])
 296 lldp_ARG_ENABLE([custom], [Custom TLV support], [yes])
 297
 298 # Oldies
 299 lldp_ARG_ENABLE([oldies], [compatibility with Linux kernel older than 2.6.18], [no])
 300
 301 #######################
 302 # Output results
 303 AC_SUBST([LLDP_CFLAGS])
 304 AC_SUBST([LLDP_CPPFLAGS])
 305 AC_SUBST([LLDP_LDFLAGS])
 306 AC_SUBST([LLDP_BIN_LDFLAGS])
 307 AM_CONDITIONAL([HAVE_CHECK], [test x"$have_check" = x"yes"])
 308 AM_CONDITIONAL([USE_SNMP], [test x"$with_snmp" = x"yes"])
 309 AM_CONDITIONAL([USE_XML], [test x"$with_xml" = x"yes"])
 310 AM_CONDITIONAL([USE_JSON], [test x"$with_json" = x"json-c" || test -x"$with_json" = x"jansson"])
 311 AM_CONDITIONAL([USE_JANSSON], [test x"$with_json" = x"jansson"])
 312 AM_CONDITIONAL([USE_JSONC], [test x"$with_json" = x"json-c"])
 313 AM_CONDITIONAL([USE_SECCOMP], [test x"$with_seccomp" = x"yes"])
 314 AC_OUTPUT
 315
 316 if test x"$LIBEVENT_EMBEDDED" = x; then
 317    libevent=system
 318 else
 319    libevent=embedded
 320 fi
 321
 322 cat <<EOF
 323
 324 ------------------ Summary ------------------
 325  $PACKAGE_NAME version $PACKAGE_VERSION
 326   OS.............: $os
 327   Prefix.........: $prefix
 328   C Compiler.....: $CC $LLDP_CFLAGS $LLDP_CPPFLAGS $CFLAGS $CPPFLAGS
 329   Linker.........: $LD $LLDP_LDFLAGS $LLDP_BIN_LDFLAGS $LDFLAGS $LIBS
 330   Libevent.......: $libevent
 331   Readline.......: ${ax_cv_lib_readline}
 332  Optional features:
 333   SNMP support...: ${with_snmp-no}
 334   CDP............: $enable_cdp
 335   FDP............: $enable_fdp
 336   EDP............: $enable_edp
 337   SONMP..........: $enable_sonmp
 338   LLDPMED........: $enable_lldpmed
 339   DOT1...........: $enable_dot1
 340   DOT3...........: $enable_dot3
 341   CUSTOM.........: $enable_custom
 342   XML output.....: ${with_xml-no}
 343   JSON output....: ${with_json-no}
 344   Oldies support.: $enable_oldies
 345   seccomp........: ${with_seccomp-no}
 346  Privilege separation:
 347   Enabled........: $enable_privsep
 348   User/group.....: ${with_privsep_user}/${with_privsep_group}
 349   Chroot.........: ${with_privsep_chroot}
 350 ---------------------------------------------
 351
 352 Check the above options and compile with:
 353  ${MAKE-make}
 354
 355 EOF