configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 #######################
   5 ### Base configuration
   6
   7 # Configure autoconf
   8 AC_PREREQ([2.64])
   9
  10 AC_INIT([lldpd],
  11         [m4_esyscmd_s([./get-version])],
  12         [https://github.com/vincentbernat/lldpd/issues],
  13         [lldpd],
  14         [http://vincentbernat.github.io/lldpd/])
  15
  16 AC_CONFIG_SRCDIR([src/log.c])
  17 AC_CONFIG_HEADER([config.h])
  18 AC_CONFIG_FILES([Makefile
  19                  src/Makefile
  20                  src/compat/Makefile
  21                  src/daemon/Makefile
  22                  src/lib/Makefile
  23                  src/client/Makefile
  24                  tests/Makefile
  25                  osx/Makefile])
  26 AC_CONFIG_MACRO_DIR([m4])
  27 AC_SUBST([CONFIGURE_ARGS], [$ac_configure_args])
  28
  29 # Configure automake
  30 AM_INIT_AUTOMAKE([foreign subdir-objects -Wall -Werror tar-ustar])
  31 AM_MAINTAINER_MODE
  32 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES(yes)])
  33
  34 # Automake 1.12...
  35 m4_pattern_allow([AM_PROG_AR])
  36 AM_PROG_AR
  37
  38 # Configure libtool
  39 LT_INIT
  40 gl_LD_VERSION_SCRIPT
  41
  42 #######################
  43 ### Checks
  44
  45 # Checks for programs.
  46 AC_PROG_CC
  47 AC_PROG_CC_C99
  48 if test x"$ac_cv_prog_cc_c99" = x"no"; then
  49   AC_MSG_FAILURE([*** C99 support is mandatory])
  50 fi
  51 AC_PROG_CXX
  52 AM_PROG_CC_C_O
  53 AC_PROG_LIBTOOL
  54 AC_PROG_LN_S
  55 AC_PROG_EGREP
  56 AC_PROG_AWK
  57
  58 # Doxygen
  59 DX_HTML_FEATURE(ON)
  60 DX_DOT_FEATURE(OFF)
  61 DX_CHM_FEATURE(OFF)
  62 DX_CHI_FEATURE(OFF)
  63 DX_MAN_FEATURE(OFF)
  64 DX_RTF_FEATURE(OFF)
  65 DX_XML_FEATURE(OFF)
  66 DX_PDF_FEATURE(ON)
  67 DX_PS_FEATURE(OFF)
  68 DX_INIT_DOXYGEN([lldpd], [doxygen.cfg], [doxygen])
  69
  70 # Check some compiler flags
  71 AX_CFLAGS_GCC_OPTION([-Wunknown-warning-option], [LLDP_CFLAGS])
  72 AX_CFLAGS_GCC_OPTION([-fdiagnostics-show-option], [LLDP_CFLAGS])
  73 AX_CFLAGS_GCC_OPTION([-fdiagnostics-color=auto], [LLDP_CFLAGS])
  74 AX_CFLAGS_GCC_OPTION([-pipe], [LLDP_CFLAGS])
  75 AX_CFLAGS_GCC_OPTION([-Wall], [LLDP_CFLAGS])
  76 AX_CFLAGS_GCC_OPTION([-W], [LLDP_CFLAGS])
  77 AX_CFLAGS_GCC_OPTION([-Wextra], [LLDP_CFLAGS])
  78 AX_CFLAGS_GCC_OPTION([-Wformat], [LLDP_CFLAGS])
  79 AX_CFLAGS_GCC_OPTION([-Wformat-security], [LLDP_CFLAGS])
  80 AX_CFLAGS_GCC_OPTION([-Wfatal-errors], [LLDP_CFLAGS])
  81 AX_CFLAGS_GCC_OPTION([-Wcast-align], [LLDP_CFLAGS])
  82 AX_CFLAGS_GCC_OPTION([-Wheader-guard], [LLDP_CFLAGS])
  83 AX_CFLAGS_GCC_OPTION([-Wdocumentation], [LLDP_CFLAGS])
  84 AX_CFLAGS_GCC_OPTION([-Winline], [LLDP_CFLAGS])
  85 AX_CFLAGS_GCC_OPTION([-Wpointer-arith], [LLDP_CFLAGS])
  86 AX_CFLAGS_GCC_OPTION([-fno-omit-frame-pointer], [LLDP_CFLAGS])
  87 AX_CFLAGS_GCC_OPTION([-Wno-unused-parameter], [LLDP_CFLAGS])
  88 AX_CFLAGS_GCC_OPTION([-Wno-missing-field-initializers], [LLDP_CFLAGS])
  89 AX_CFLAGS_GCC_OPTION([-Wno-sign-compare], [LLDP_CFLAGS]) dnl Should be fixed later
  90 AX_LDFLAGS_OPTION([-Wl,-z,relro], [LLDP_LDFLAGS])
  91 AX_LDFLAGS_OPTION([-Wl,-z,now], [LLDP_LDFLAGS])
  92
  93 AC_C_TYPEOF
  94
  95 # Hardening
  96 AC_ARG_ENABLE([hardening],
  97   [AS_HELP_STRING([--enable-hardening],
  98     [Enable compiler and linker options to frustrate memory corruption exploits @<:@default=yes@:>@])],
  99   [hardening="$enableval"],
 100   [hardening="yes"])
 101 AC_ARG_ENABLE([pie],
 102   [AS_HELP_STRING([--enable-pie],
 103     [Enable PIE (position independant executable) @<:@default=no@:>@])],
 104   [pie="$enableval"],
 105   [pie="no"])
 106
 107 if test x"$hardening" != x"no"; then
 108   AX_CFLAGS_GCC_OPTION([-fstack-protector], [LLDP_CFLAGS])
 109   AX_CFLAGS_GCC_OPTION([-fstack-protector-all], [LLDP_CFLAGS])
 110   AX_CFLAGS_GCC_OPTION([-fstack-protector-strong], [LLDP_CFLAGS])
 111   AX_CFLAGS_GCC_OPTION([-fstack-protector-strong], [LLDP_CFLAGS])
 112   AX_CFLAGS_GCC_OPTION([-D_FORTIFY_SOURCE=2], [LLDP_CPPFLAGS])
 113   AX_LDFLAGS_OPTION([-fsanitize=safe-stack], [LLDP_BIN_LDFLAGS])
 114   if test x"$ax_cv_ld_check_flag__fsanitize_safe_stack" != x"no"; then
 115     AX_CFLAGS_GCC_OPTION([-fsanitize=safe-stack], [LLDP_CFLAGS])
 116   fi
 117 fi
 118 if test x"$pie" = x"yes"; then
 119   AX_CFLAGS_GCC_OPTION([-fPIE], [LLDP_CFLAGS])
 120   AX_LDFLAGS_OPTION([-fPIE -pie], [LLDP_BIN_LDFLAGS],
 121     [AX_LDFLAGS_OPTION([-fPIE -Wl,-pie], [LLDP_BIN_LDFLAGS])])
 122 fi
 123
 124 # Sanitizers
 125 AC_ARG_ENABLE([sanitizers],
 126   AS_HELP_STRING([--enable-sanitizers],
 127     [Enable code instrumentation with selected sanitizers @<:@default=no@:>@]),
 128   [
 129 case "$enableval" in
 130     no) sanitizers= ;;
 131     yes) sanitizers="-fsanitize=address,undefined" ;;
 132     *) sanitizers="-fsanitize=$enableval" ;;
 133 esac
 134 if test x"$sanitizers" != x; then
 135   LLDP_CFLAGS="$LLDP_CFLAGS $sanitizers"
 136   LLDP_LDFLAGS="$LLDP_LDFLAGS $sanitizers"
 137   AC_DEFINE([HAVE_ADDRESS_SANITIZER], 1, [Define if have both address and leak sanitizer])
 138 fi
 139   ])
 140
 141 # Code coverage
 142 AC_ARG_ENABLE([gcov],
 143   AS_HELP_STRING([--enable-gcov],
 144     [Enable coverage instrumentation @<:@default=no@:>@]),
 145     [gcov="$enableval"],
 146     [gcov="no"])
 147 if test x"$gcov" != x"no"; then
 148   LLDP_CFLAGS="$LLDP_CFLAGS --coverage"
 149   LLDP_LDFLAGS="$LLDP_LDFLAGS --coverage"
 150 fi
 151
 152 # OS
 153 lldp_CHECK_OS
 154 lldp_CFLAGS_OS
 155
 156 AC_CACHE_SAVE
 157
 158 # Checks for header files.
 159 AC_HEADER_RESOLV
 160 AC_CHECK_HEADERS([valgrind/valgrind.h])
 161 lldp_CHECK_STDINT
 162
 163 AC_CACHE_SAVE
 164
 165 # Checks for typedefs, structures, and compiler characteristics.
 166 lldp_CHECK___PROGNAME
 167 lldp_CHECK_ALIGNOF
 168
 169 # Checks for library functions.
 170 AC_CONFIG_LIBOBJ_DIR([src/compat])
 171 AC_FUNC_MALLOC
 172 AC_FUNC_REALLOC
 173 AC_FUNC_FORK
 174
 175 # Some functions can be in libbsd
 176 PKG_CHECK_MODULES([libbsd], [libbsd-overlay], [
 177   _save_CFLAGS="$CFLAGS"
 178   _save_LIBS="$LIBS"
 179   CFLAGS="$CFLAGS $libbsd_CFLAGS"
 180   LIBS="$LIBS $libbsd_LIBS"
 181   AC_MSG_CHECKING([if libbsd can be linked correctly])
 182   AC_TRY_LINK([
 183 @%:@include <sys/time.h>
 184 @%:@include <sys/types.h>
 185 ],[],
 186     [
 187       AC_MSG_RESULT(yes)
 188       LLDP_CFLAGS="$LLDP_CFLAGS $libbsd_CFLAGS"
 189       LLDP_LDFLAGS="$LLDP_LDFLAGS $libbsd_LIBS"
 190     ],[
 191       AC_MSG_RESULT(no)
 192       CFLAGS="$_save_CFLAGS"
 193       LIBS="$_save_LIBS"
 194     ])
 195 ], [:])
 196
 197 # setproctitle may have an _init function
 198 AC_REPLACE_FUNCS([setproctitle])
 199 AC_CHECK_FUNCS([setproctitle_init])
 200 # Other functions
 201 AC_REPLACE_FUNCS([strlcpy
 202                   strnlen
 203                   strndup
 204                   strtonum
 205                   getline
 206                   asprintf
 207                   vsyslog
 208                   daemon])
 209 # Optional functions
 210 AC_CHECK_FUNCS([setresuid setresgid])
 211
 212 # Check for res_init. On OSX, res_init is a symbol in libsystem_info
 213 # and a macro in resolv.h. We need to ensure we test with resolv.h.
 214 m4_pushdef([AC_LANG_CALL(C)], [
 215   AC_LANG_PROGRAM([$1
 216 @%:@include <resolv.h>], [return $2 ();])])
 217 AC_SEARCH_LIBS([res_init], resolv bind,
 218                AC_DEFINE([HAVE_RES_INIT], 1,
 219                [Define to indicate that res_init() exists]))
 220 m4_popdef([AC_LANG_CALL(C)])
 221
 222 AC_CACHE_SAVE
 223
 224 ## Unit tests wich check
 225 PKG_CHECK_MODULES([CHECK], [check >= 0.9.4], [have_check=yes], [have_check=no])
 226
 227 # Third-party libraries
 228 lldp_CHECK_LIBEVENT
 229
 230 # Compatibility with pkg.m4 < 0.27
 231 m4_ifdef([PKG_INSTALLDIR], [PKG_INSTALLDIR],
 232          [AC_ARG_WITH([pkgconfigdir],
 233                       [AS_HELP_STRING([--with-pkgconfigdir],
 234                       [install directory for *.pc pkg-config file])],
 235                       [],[with_pkgconfigdir='$(libdir)/pkgconfig'])
 236           AC_SUBST([pkgconfigdir], [${with_pkgconfigdir}])])
 237
 238 #######################
 239 ### Options
 240
 241 # Readline
 242 AC_ARG_WITH([readline],
 243   AS_HELP_STRING(
 244     [--with-readline],
 245     [Enable the use of readline-like library @<:@default=auto@:>@]),
 246   [],
 247   [with_readline=auto])
 248 if test x"$with_readline" != x"no"; then
 249    AX_LIB_READLINE
 250    if test x"$with_readline" != x"check" -a x"$with_readline" != x"auto"; then
 251      if test x"$ax_cv_lib_readline" = x"no"; then
 252        AC_MSG_FAILURE([*** no readline support found])
 253      fi
 254    fi
 255 else
 256    ax_cv_lib_readline="no"
 257 fi
 258
 259 # SNMP
 260 AC_ARG_WITH([snmp],
 261   AS_HELP_STRING(
 262     [--with-snmp],
 263     [Enable the use of SNMP @<:@default=no@:>@]),
 264   [],
 265   [with_snmp=no])
 266 lldp_CHECK_SNMP
 267
 268 # XML
 269 AC_ARG_WITH([xml],
 270   AS_HELP_STRING(
 271     [--with-xml],
 272     [Enable XML output via libxml2 @<:@default=auto@:>@]),
 273   [],
 274   [with_xml=auto])
 275 lldp_CHECK_XML2
 276
 277 # JSON (built-in)
 278 lldp_ARG_ENABLE([json0], [use of pre-0.9.2 JSON/json-c format], [no])
 279
 280 # Seccomp
 281 AC_ARG_WITH([seccomp],
 282   AS_HELP_STRING(
 283     [--with-seccomp],
 284     [Enable seccomp support (with libseccomp, experimental) @<:@default=no@:>@]),
 285   [],
 286   [with_seccomp=no])
 287 lldp_CHECK_SECCOMP
 288
 289 # OS X launchd support
 290 lldp_ARG_WITH([launchddaemonsdir], [Directory for launchd configuration file (OSX)],
 291                                    [/Library/LaunchDaemons])
 292 AC_SUBST([launchddaemonsdir], [$with_launchddaemonsdir])
 293 AM_CONDITIONAL(HAVE_LAUNCHDDAEMONSDIR,
 294     [test -n "$with_launchddaemonsdir" -a "x$with_launchddaemonsdir" != xno ])
 295
 296 # Systemd
 297 lldp_ARG_WITH([systemdsystemunitdir], [Directory for systemd service files],
 298               [$($PKG_CONFIG --variable=systemdsystemunitdir systemd 2> /dev/null)])
 299 AC_SUBST([systemdsystemunitdir], [$with_systemdsystemunitdir])
 300 AM_CONDITIONAL(HAVE_SYSTEMDSYSTEMUNITDIR,
 301     [test -n "$with_systemdsystemunitdir" -a "x$with_systemdsystemunitdir" != xno ])
 302
 303 # sysusers
 304 lldp_ARG_WITH([sysusersdir], [Directory for sysusers files],
 305               [$($PKG_CONFIG --variable=sysusersdir systemd 2> /dev/null)])
 306 AC_SUBST([sysusersdir], [$with_sysusersdir])
 307 AM_CONDITIONAL(HAVE_SYSUSERSDIR,
 308     [test -n "$with_sysusersdir" -a "x$with_sysusersdir" != xno ])
 309
 310 # AppArmor
 311 lldp_ARG_WITH([apparmordir], [Directory for AppArmor profiles (Linux)],
 312                              [no])
 313 AC_SUBST([apparmordir], [$with_apparmordir])
 314 AM_CONDITIONAL(HAVE_APPARMORDIR,
 315     [test -n "$with_apparmordir" -a "x$with_apparmordir" != xno ])
 316
 317 # Systemtap/DTrace
 318 lldp_SYSTEMTAP
 319
 320 # Privsep settings
 321 lldp_ARG_ENABLE([privsep], [Privilege separation], [yes])
 322 lldp_ARG_WITH([privsep-user], [Which user to use for privilege separation], [_lldpd])
 323 lldp_ARG_WITH([privsep-group], [Which group to use for privilege separation], [_lldpd])
 324
 325 # Directories
 326 dnl On autoconf 2.69 and before, runstatedir is not configurable, let be able to use it anyway
 327 if test "x$runstatedir" = x; then
 328     AC_SUBST([runstatedir], ['${localstatedir}/run'])
 329 fi
 330 lldp_ARG_WITH([privsep-chroot], [Which directory to use to chroot lldpd], [${runstatedir}/lldpd])
 331 lldp_ARG_WITH([lldpd-ctl-socket], [Path to socket for communication with lldpd], [${runstatedir}/lldpd.socket])
 332 lldp_ARG_WITH([lldpd-pid-file], [Path to lldpd PID file], [${runstatedir}/lldpd.pid])
 333
 334 # Netlink
 335 lldp_ARG_WITH_UNQUOTED([netlink-max-receive-bufsize], [Netlink maximum receive buffer size], [1024*1024])
 336 lldp_ARG_WITH_UNQUOTED([netlink-receive-bufsize], [Netlink initial receive buffer size], [0])
 337 lldp_ARG_WITH_UNQUOTED([netlink-send-bufsize], [Netlink send buffer size], [0])
 338
 339 # CDP/FDP/EDP/SONMP
 340 lldp_ARG_ENABLE([cdp], [Cisco Discovery Protocol], [yes])
 341 lldp_ARG_ENABLE([fdp], [Foundry Discovery Protocol], [yes])
 342 lldp_ARG_ENABLE([edp], [Extreme Discovery Protocol], [yes])
 343 lldp_ARG_ENABLE([sonmp], [SynOptics Network Management Protocol], [yes])
 344
 345 # LLDPMED/Dot1/Dot3
 346 lldp_ARG_ENABLE([lldpmed], [LLDP-MED extension], [yes])
 347 lldp_ARG_ENABLE([dot1], [Dot1 extension (VLAN stuff)], [yes])
 348 lldp_ARG_ENABLE([dot3], [Dot3 extension (PHY stuff)], [yes])
 349 lldp_ARG_ENABLE([custom], [Custom TLV support], [yes])
 350
 351 # Oldies
 352 MIN_LINUX_KERNEL_VERSION=2.6.39
 353 lldp_ARG_ENABLE([oldies], [compatibility with Linux kernel older than 2.6.39], [no])
 354 if test x"$os" = x"Linux"; then
 355     if test x"$enable_oldies" = x"no"; then
 356       AC_DEFINE_UNQUOTED(MIN_LINUX_KERNEL_VERSION, "[$MIN_LINUX_KERNEL_VERSION]", [Minimal Linux kernel version required])
 357     else
 358       AC_DEFINE(MIN_LINUX_KERNEL_VERSION, "2.6.11", [Minimal kernel version required])
 359     fi
 360 fi
 361
 362 AX_BUILD_DATE_EPOCH(BUILD_DATE, "%FT%TZ", [BUILD_DATE="(unknown)"])
 363 AC_DEFINE_UNQUOTED(BUILD_DATE, "[$BUILD_DATE]", [Build date and time])
 364 AC_DEFINE_UNQUOTED(LLDP_CC, "[$CC $LLDP_CFLAGS $LLDP_CPPFLAGS $CFLAGS $CPPFLAGS]", [C compiler command])
 365 AC_DEFINE_UNQUOTED(LLDP_LD, "[$LD $LLDP_LDFLAGS $LLDP_BIN_LDFLAGS $LDFLAGS $LIBS]", [Linker compiler command])
 366
 367 #######################
 368 # Output results
 369 AC_SUBST([LLDP_CFLAGS])
 370 AC_SUBST([LLDP_CPPFLAGS])
 371 AC_SUBST([LLDP_LDFLAGS])
 372 AC_SUBST([LLDP_BIN_LDFLAGS])
 373 AM_CONDITIONAL([HAVE_CHECK], [test x"$have_check" = x"yes"])
 374 AM_CONDITIONAL([USE_SNMP], [test x"$with_snmp" = x"yes"])
 375 AM_CONDITIONAL([USE_XML], [test x"$with_xml" = x"yes"])
 376 AM_CONDITIONAL([USE_SECCOMP], [test x"$with_seccomp" = x"yes"])
 377 dnl If old default of AR_FLAGS is otherwise being used (because of older automake),
 378 dnl replace it with one without 'u'
 379 if test "x$AR_FLAGS" = "xcru" ; then
 380   AR_FLAGS="cr"
 381 fi
 382 AC_OUTPUT
 383
 384 if test x"$LIBEVENT_EMBEDDED" = x; then
 385    libevent=system
 386 else
 387    libevent=embedded
 388 fi
 389
 390 cat <<EOF
 391
 392 ------------------ Summary ------------------
 393  $PACKAGE_NAME version $PACKAGE_VERSION
 394   OS.............: $os
 395   Prefix.........: $prefix
 396   C Compiler.....: $CC $LLDP_CFLAGS $LLDP_CPPFLAGS $CFLAGS $CPPFLAGS
 397   Linker.........: $LD $LLDP_LDFLAGS $LLDP_BIN_LDFLAGS $LDFLAGS $LIBS
 398   Libevent.......: $libevent
 399   Readline.......: ${ax_cv_lib_readline}
 400
 401  Optional features:
 402   SNMP support...: ${with_snmp-no}
 403   CDP............: $enable_cdp
 404   FDP............: $enable_fdp
 405   EDP............: $enable_edp
 406   SONMP..........: $enable_sonmp
 407   LLDPMED........: $enable_lldpmed
 408   DOT1...........: $enable_dot1
 409   DOT3...........: $enable_dot3
 410   CUSTOM.........: $enable_custom
 411   XML output.....: ${with_xml-no}
 412   Oldies support.: $enable_oldies
 413   seccomp........: ${with_seccomp-no}
 414
 415  Privilege separation:
 416   Enabled........: $enable_privsep
 417   User/group.....: ${with_privsep_user}/${with_privsep_group}
 418   Chroot.........: ${with_privsep_chroot}
 419
 420  Instrumentation (for devs only):
 421   Sanitizers.....: ${sanitizers:-none}
 422   Coverage.......: ${gcov}
 423 ------------- Compiler version --------------
 424 $($CC --version || true)
 425 -------------- Linker version ---------------
 426 $($LD --version || true)
 427 ---------------------------------------------
 428
 429 Check the above options and compile with:
 430  ${MAKE-make}
 431
 432 EOF