configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 #######################
   5 ### Base configuration
   6
   7 # Configure autoconf
   8 AC_PREREQ([2.64])
   9
  10 AC_INIT([lldpd],
  11         [m4_esyscmd_s([./get-version])],
  12         [https://github.com/vincentbernat/lldpd/issues],
  13         [lldpd],
  14         [http://vincentbernat.github.io/lldpd/])
  15
  16 AC_CONFIG_SRCDIR([src/log.c])
  17 AC_CONFIG_HEADER([config.h])
  18 AC_CONFIG_FILES([Makefile
  19                  src/Makefile
  20                  src/compat/Makefile
  21                  src/daemon/Makefile
  22                  src/lib/Makefile
  23                  src/client/Makefile
  24                  tests/Makefile
  25                  osx/Makefile])
  26 AC_CONFIG_MACRO_DIR([m4])
  27 AC_SUBST([CONFIGURE_ARGS], [$ac_configure_args])
  28
  29 # Configure automake
  30 AM_INIT_AUTOMAKE([foreign subdir-objects -Wall -Werror tar-ustar])
  31 AM_MAINTAINER_MODE
  32 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES(yes)])
  33
  34 # Automake 1.12...
  35 m4_pattern_allow([AM_PROG_AR])
  36 AM_PROG_AR
  37
  38 # Configure libtool
  39 LT_INIT
  40 gl_LD_VERSION_SCRIPT
  41
  42 #######################
  43 ### Checks
  44
  45 # Checks for programs.
  46 AC_PROG_CC
  47 AC_PROG_CC_C99
  48 if test x"$ac_cv_prog_cc_c99" = x"no"; then
  49   AC_MSG_FAILURE([*** C99 support is mandatory])
  50 fi
  51 AC_PROG_CXX
  52 AM_PROG_CC_C_O
  53 AC_PROG_LIBTOOL
  54 AC_PROG_LN_S
  55 AC_PROG_EGREP
  56 AC_PROG_AWK
  57
  58 # Doxygen
  59 DX_HTML_FEATURE(ON)
  60 DX_DOT_FEATURE(OFF)
  61 DX_CHM_FEATURE(OFF)
  62 DX_CHI_FEATURE(OFF)
  63 DX_MAN_FEATURE(OFF)
  64 DX_RTF_FEATURE(OFF)
  65 DX_XML_FEATURE(OFF)
  66 DX_PDF_FEATURE(ON)
  67 DX_PS_FEATURE(OFF)
  68 DX_INIT_DOXYGEN([lldpd], [doxygen.cfg], [doxygen])
  69
  70 # Check some compiler flags
  71 AX_CFLAGS_GCC_OPTION([-Wunknown-warning-option], [LLDP_CFLAGS])
  72 AX_CFLAGS_GCC_OPTION([-fdiagnostics-show-option], [LLDP_CFLAGS])
  73 AX_CFLAGS_GCC_OPTION([-fdiagnostics-color=auto], [LLDP_CFLAGS])
  74 AX_CFLAGS_GCC_OPTION([-pipe], [LLDP_CFLAGS])
  75 AX_CFLAGS_GCC_OPTION([-Wall], [LLDP_CFLAGS])
  76 AX_CFLAGS_GCC_OPTION([-W], [LLDP_CFLAGS])
  77 AX_CFLAGS_GCC_OPTION([-Wextra], [LLDP_CFLAGS])
  78 AX_CFLAGS_GCC_OPTION([-Wformat], [LLDP_CFLAGS])
  79 AX_CFLAGS_GCC_OPTION([-Wformat-security], [LLDP_CFLAGS])
  80 AX_CFLAGS_GCC_OPTION([-Wfatal-errors], [LLDP_CFLAGS])
  81 AX_CFLAGS_GCC_OPTION([-Wcast-align], [LLDP_CFLAGS])
  82 AX_CFLAGS_GCC_OPTION([-Wheader-guard], [LLDP_CFLAGS])
  83 AX_CFLAGS_GCC_OPTION([-Wdocumentation], [LLDP_CFLAGS])
  84 AX_CFLAGS_GCC_OPTION([-Winline], [LLDP_CFLAGS])
  85 AX_CFLAGS_GCC_OPTION([-Wpointer-arith], [LLDP_CFLAGS])
  86 AX_CFLAGS_GCC_OPTION([-fno-omit-frame-pointer], [LLDP_CFLAGS])
  87 AX_CFLAGS_GCC_OPTION([-Wno-unused-parameter], [LLDP_CFLAGS])
  88 AX_CFLAGS_GCC_OPTION([-Wno-missing-field-initializers], [LLDP_CFLAGS])
  89 AX_CFLAGS_GCC_OPTION([-Wno-sign-compare], [LLDP_CFLAGS]) dnl Should be fixed later
  90 AX_LDFLAGS_OPTION([-Wl,-z,relro], [LLDP_LDFLAGS])
  91 AX_LDFLAGS_OPTION([-Wl,-z,now], [LLDP_LDFLAGS])
  92 lldp_CHECK_CTORS
  93
  94 # Hardening
  95 AC_ARG_ENABLE([hardening],
  96   [AS_HELP_STRING([--enable-hardening],
  97     [Enable compiler and linker options to frustrate memory corruption exploits @<:@default=yes@:>@])],
  98   [hardening="$enableval"],
  99   [hardening="yes"])
 100 AC_ARG_ENABLE([pie],
 101   [AS_HELP_STRING([--enable-pie],
 102     [Enable PIE (position independant executable) @<:@default=no@:>@])],
 103   [pie="$enableval"],
 104   [pie="no"])
 105
 106 if test x"$hardening" != x"no"; then
 107   AX_CFLAGS_GCC_OPTION([-fstack-protector], [LLDP_CFLAGS])
 108   AX_CFLAGS_GCC_OPTION([-fstack-protector-all], [LLDP_CFLAGS])
 109   AX_CFLAGS_GCC_OPTION([-fstack-protector-strong], [LLDP_CFLAGS])
 110   AX_CFLAGS_GCC_OPTION([-D_FORTIFY_SOURCE=2], [LLDP_CPPFLAGS])
 111 fi
 112 if test x"$pie" = x"yes"; then
 113   AX_CFLAGS_GCC_OPTION([-fPIE], [LLDP_CFLAGS])
 114   AX_LDFLAGS_OPTION([-fPIE -pie], [LLDP_BIN_LDFLAGS],
 115     [AX_LDFLAGS_OPTION([-fPIE -Wl,-pie], [LLDP_BIN_LDFLAGS])])
 116 fi
 117
 118 # OS
 119 lldp_CHECK_OS
 120 lldp_CFLAGS_OS
 121
 122 AC_CACHE_SAVE
 123
 124 # Checks for header files.
 125 AC_HEADER_RESOLV
 126 AC_CHECK_HEADERS([valgrind/valgrind.h])
 127 lldp_CHECK_STDINT
 128
 129 AC_CACHE_SAVE
 130
 131 # Checks for typedefs, structures, and compiler characteristics.
 132 lldp_CHECK___PROGNAME
 133 lldp_CHECK_ALIGNOF
 134
 135 # Checks for library functions.
 136 AC_CONFIG_LIBOBJ_DIR([src/compat])
 137 AC_FUNC_MALLOC
 138 AC_FUNC_REALLOC
 139 AC_FUNC_FORK
 140
 141 # Some functions can be in libbsd
 142 PKG_CHECK_MODULES([libbsd], [libbsd-overlay], [
 143   _save_CFLAGS="$CFLAGS"
 144   _save_LIBS="$LIBS"
 145   CFLAGS="$CFLAGS $libbsd_CFLAGS"
 146   LIBS="$LIBS $libbsd_LIBS"
 147   AC_MSG_CHECKING([if libbsd can be linked correctly])
 148   AC_LINK_IFELSE([AC_LANG_SOURCE([[int main() { return 0; }]])],
 149     [
 150       AC_MSG_RESULT(yes)
 151       LLDP_CFLAGS="$LLDP_CFLAGS $libbsd_CFLAGS"
 152       LLDP_LDFLAGS="$LLDP_LDFLAGS $libbsd_LIBS"
 153     ],[
 154       AC_MSG_RESULT(no)
 155       CFLAGS="$_save_CFLAGS"
 156       LIBS="$_save_LIBS"
 157     ])
 158 ], [:])
 159
 160 # setproctitle may have an _init function
 161 AC_REPLACE_FUNCS([setproctitle])
 162 AC_CHECK_FUNCS([setproctitle_init])
 163 # Other functions
 164 AC_REPLACE_FUNCS([strlcpy
 165                   strnlen
 166                   strndup
 167                   getline
 168                   asprintf
 169                   vsyslog
 170                   daemon])
 171 # Optional functions
 172 AC_CHECK_FUNCS([setresuid setresgid])
 173
 174 CFLAGS="$_save_CFLAGS"
 175 LIBS="$_save_LIBS"
 176
 177 # Check for res_init. On OSX, res_init is a symbol in libsystem_info
 178 # and a macro in resolv.h. We need to ensure we test with resolv.h.
 179 m4_pushdef([AC_LANG_CALL(C)], [
 180   AC_LANG_PROGRAM([$1
 181 @%:@include <resolv.h>], [return $2 ();])])
 182 AC_SEARCH_LIBS([res_init], resolv bind,
 183                AC_DEFINE([HAVE_RES_INIT], 1,
 184                [Define to indicate that res_init() exists]))
 185 m4_popdef([AC_LANG_CALL(C)])
 186
 187 AC_CACHE_SAVE
 188
 189 ## Unit tests wich check
 190 PKG_CHECK_MODULES([CHECK], [check >= 0.9.4], [have_check=yes], [have_check=no])
 191
 192 # Third-party libraries
 193 lldp_CHECK_LIBEVENT
 194
 195 # Compatibility with pkg.m4 < 0.27
 196 m4_ifdef([PKG_INSTALLDIR], [PKG_INSTALLDIR],
 197          [AC_ARG_WITH([pkgconfigdir],
 198                       [AS_HELP_STRING([--with-pkgconfigdir],
 199                       [install directory for *.pc pkg-config file])],
 200                       [],[with_pkgconfigdir='$(libdir)/pkgconfig'])
 201           AC_SUBST([pkgconfigdir], [${with_pkgconfigdir}])])
 202
 203 #######################
 204 ### Options
 205
 206 # Readline
 207 AC_ARG_WITH([readline],
 208   AS_HELP_STRING(
 209     [--with-readline],
 210     [Enable the use of readline-like library @<:@default=auto@:>@]),
 211   [],
 212   [with_readline=auto])
 213 if test x"$with_readline" != x"no"; then
 214    AX_LIB_READLINE
 215    if test x"$with_readline" != x"check" -a x"$with_readline" != x"auto"; then
 216      if test x"$ax_cv_lib_readline" = x"no"; then
 217        AC_MSG_FAILURE([*** no readline support found])
 218      fi
 219    fi
 220 else
 221    ax_cv_lib_readline="no"
 222 fi
 223
 224 # SNMP
 225 AC_ARG_WITH([snmp],
 226   AS_HELP_STRING(
 227     [--with-snmp],
 228     [Enable the use of SNMP @<:@default=no@:>@]),
 229   [],
 230   [with_snmp=no])
 231 lldp_CHECK_SNMP
 232
 233 # XML
 234 AC_ARG_WITH([xml],
 235   AS_HELP_STRING(
 236     [--with-xml],
 237     [Enable XML output via libxml2 @<:@default=auto@:>@]),
 238   [],
 239   [with_xml=auto])
 240 lldp_CHECK_XML2
 241
 242 # JSON
 243 AC_ARG_WITH([json],
 244   AS_HELP_STRING(
 245     [--with-json],
 246     [Enable JSON output via janson or json-c @<:@default=auto@:>@]),
 247   [],
 248   [with_json=auto])
 249 if test x"$with_json" = x"yes" -o x"$with_json" = x"auto"; then
 250    _with_json="$with_json"
 251    with_json=auto
 252    lldp_CHECK_JANSSON
 253    if test x"$with_json" = x"no"; then
 254      with_json=auto
 255      lldp_CHECK_JSONC
 256    fi
 257    if test x"$with_json" = x"no" -a x"$_with_json" = x"yes"; then
 258      AC_MSG_FAILURE([*** no JSON support found])
 259    fi
 260 else
 261    lldp_CHECK_JANSSON
 262    lldp_CHECK_JSONC
 263 fi
 264
 265 # Seccomp
 266 AC_ARG_WITH([seccomp],
 267   AS_HELP_STRING(
 268     [--with-seccomp],
 269     [Enable seccomp support (with libseccomp, experimental) @<:@default=no@:>@]),
 270   [],
 271   [with_seccomp=no])
 272 lldp_CHECK_SECCOMP
 273
 274 # OS X launchd support
 275 lldp_ARG_WITH([launchddaemonsdir], [Directory for launchd configuration file (OSX)],
 276                                    [/Library/LaunchDaemons])
 277 AC_SUBST([launchddaemonsdir], [$with_launchddaemonsdir])
 278 AM_CONDITIONAL(HAVE_LAUNCHDDAEMONSDIR,
 279     [test -n "$with_launchddaemonsdir" -a "x$with_launchddaemonsdir" != xno ])
 280
 281 # Systemd
 282 lldp_ARG_WITH([systemdsystemunitdir], [Directory for systemd service files],
 283               [$($PKG_CONFIG --variable=systemdsystemunitdir systemd 2> /dev/null)])
 284 AC_SUBST([systemdsystemunitdir], [$with_systemdsystemunitdir])
 285 AM_CONDITIONAL(HAVE_SYSTEMDSYSTEMUNITDIR,
 286     [test -n "$with_systemdsystemunitdir" -a "x$with_systemdsystemunitdir" != xno ])
 287
 288 # sysusers
 289 lldp_ARG_WITH([sysusersdir], [Directory for sysusers files],
 290               [$($PKG_CONFIG --variable=sysusersdir systemd 2> /dev/null)])
 291 AC_SUBST([sysusersdir], [$with_sysusersdir])
 292 AM_CONDITIONAL(HAVE_SYSUSERSDIR,
 293     [test -n "$with_sysusersdir" -a "x$with_sysusersdir" != xno ])
 294
 295 # AppArmor
 296 lldp_ARG_WITH([apparmordir], [Directory for AppArmor profiles (Linux)],
 297                              [no])
 298 AC_SUBST([apparmordir], [$with_apparmordir])
 299 AM_CONDITIONAL(HAVE_APPARMORDIR,
 300     [test -n "$with_apparmordir" -a "x$with_apprmordir" != xno ])
 301
 302 # Systemtap/DTrace
 303 lldp_SYSTEMTAP
 304
 305 # Privsep settings
 306 lldp_ARG_ENABLE([privsep], [Privilege separation], [yes])
 307 lldp_ARG_WITH([privsep-user], [Which user to use for privilege separation], [_lldpd])
 308 lldp_ARG_WITH([privsep-group], [Which group to use for privilege separation], [_lldpd])
 309
 310 # Directories
 311 dnl On autoconf 2.69 and before, runstatedir is not configurable, let be able to use it anyway
 312 if test "x$runstatedir" = x; then
 313     AC_SUBST([runstatedir], ['${localstatedir}/run'])
 314 fi
 315 lldp_ARG_WITH([privsep-chroot], [Which directory to use to chroot lldpd], [${runstatedir}/lldpd])
 316 lldp_ARG_WITH([lldpd-ctl-socket], [Path to socket for communication with lldpd], [${runstatedir}/lldpd.socket])
 317 lldp_ARG_WITH([lldpd-pid-file], [Path to lldpd PID file], [${runstatedir}/lldpd.pid])
 318
 319 # CDP/FDP/EDP/SONMP
 320 lldp_ARG_ENABLE([cdp], [Cisco Discovery Protocol], [yes])
 321 lldp_ARG_ENABLE([fdp], [Foundry Discovery Protocol], [yes])
 322 lldp_ARG_ENABLE([edp], [Extreme Discovery Protocol], [yes])
 323 lldp_ARG_ENABLE([sonmp], [SynOptics Network Management Protocol], [yes])
 324
 325 # LLDPMED/Dot1/Dot3
 326 lldp_ARG_ENABLE([lldpmed], [LLDP-MED extension], [yes])
 327 lldp_ARG_ENABLE([dot1], [Dot1 extension (VLAN stuff)], [yes])
 328 lldp_ARG_ENABLE([dot3], [Dot3 extension (PHY stuff)], [yes])
 329 lldp_ARG_ENABLE([custom], [Custom TLV support], [yes])
 330
 331 # Oldies
 332 MIN_LINUX_KERNEL_VERSION=2.6.39
 333 lldp_ARG_ENABLE([oldies], [compatibility with Linux kernel older than 2.6.39], [no])
 334 if test x"$os" = x"Linux"; then
 335     if test x"$enable_oldies" = x"no"; then
 336       AC_DEFINE_UNQUOTED(MIN_LINUX_KERNEL_VERSION, "[$MIN_LINUX_KERNEL_VERSION]", [Minimal Linux kernel version required])
 337     else
 338       AC_DEFINE(MIN_LINUX_KERNEL_VERSION, "2.6.11", [Minimal kernel version required])
 339     fi
 340 fi
 341
 342 #######################
 343 # Output results
 344 AC_SUBST([LLDP_CFLAGS])
 345 AC_SUBST([LLDP_CPPFLAGS])
 346 AC_SUBST([LLDP_LDFLAGS])
 347 AC_SUBST([LLDP_BIN_LDFLAGS])
 348 AM_CONDITIONAL([HAVE_CHECK], [test x"$have_check" = x"yes"])
 349 AM_CONDITIONAL([USE_SNMP], [test x"$with_snmp" = x"yes"])
 350 AM_CONDITIONAL([USE_XML], [test x"$with_xml" = x"yes"])
 351 AM_CONDITIONAL([USE_JSON], [test x"$with_json" = x"json-c" || test -x"$with_json" = x"jansson"])
 352 AM_CONDITIONAL([USE_JANSSON], [test x"$with_json" = x"jansson"])
 353 AM_CONDITIONAL([USE_JSONC], [test x"$with_json" = x"json-c"])
 354 AM_CONDITIONAL([USE_SECCOMP], [test x"$with_seccomp" = x"yes"])
 355 AC_OUTPUT
 356
 357 if test x"$LIBEVENT_EMBEDDED" = x; then
 358    libevent=system
 359 else
 360    libevent=embedded
 361 fi
 362
 363 cat <<EOF
 364
 365 ------------------ Summary ------------------
 366  $PACKAGE_NAME version $PACKAGE_VERSION
 367   OS.............: $os
 368   Prefix.........: $prefix
 369   C Compiler.....: $CC $LLDP_CFLAGS $LLDP_CPPFLAGS $CFLAGS $CPPFLAGS
 370   Linker.........: $LD $LLDP_LDFLAGS $LLDP_BIN_LDFLAGS $LDFLAGS $LIBS
 371   Libevent.......: $libevent
 372   Readline.......: ${ax_cv_lib_readline}
 373  Optional features:
 374   SNMP support...: ${with_snmp-no}
 375   CDP............: $enable_cdp
 376   FDP............: $enable_fdp
 377   EDP............: $enable_edp
 378   SONMP..........: $enable_sonmp
 379   LLDPMED........: $enable_lldpmed
 380   DOT1...........: $enable_dot1
 381   DOT3...........: $enable_dot3
 382   CUSTOM.........: $enable_custom
 383   XML output.....: ${with_xml-no}
 384   JSON output....: ${with_json-no}
 385   Oldies support.: $enable_oldies
 386   seccomp........: ${with_seccomp-no}
 387  Privilege separation:
 388   Enabled........: $enable_privsep
 389   User/group.....: ${with_privsep_user}/${with_privsep_group}
 390   Chroot.........: ${with_privsep_chroot}
 391 ---------------------------------------------
 392
 393 Check the above options and compile with:
 394  ${MAKE-make}
 395
 396 EOF