Configure

   1 #! /usr/bin/env perl
   2 # -*- mode: perl; -*-
   3 # Copyright 2016-2018 The OpenSSL Project Authors. All Rights Reserved.
   4 #
   5 # Licensed under the Apache License 2.0 (the "License").  You may not use
   6 # this file except in compliance with the License.  You can obtain a copy
   7 # in the file LICENSE in the source distribution or at
   8 # https://www.openssl.org/source/license.html
   9
  10 ##  Configure -- OpenSSL source tree configuration script
  11
  12 use 5.10.0;
  13 use strict;
  14 use Config;
  15 use FindBin;
  16 use lib "$FindBin::Bin/util/perl";
  17 use File::Basename;
  18 use File::Spec::Functions qw/:DEFAULT abs2rel rel2abs splitdir/;
  19 use File::Path qw/mkpath/;
  20 use OpenSSL::fallback "$FindBin::Bin/external/perl/MODULES.txt";
  21 use OpenSSL::Glob;
  22 use OpenSSL::Template;
  23
  24 # see INSTALL for instructions.
  25
  26 my $orig_death_handler = $SIG{__DIE__};
  27 $SIG{__DIE__} = \&death_handler;
  28
  29 my $usage="Usage: Configure [no-<cipher> ...] [enable-<cipher> ...] [-Dxxx] [-lxxx] [-Lxxx] [-fxxx] [-Kxxx] [no-hw-xxx|no-hw] [[no-]threads] [[no-]shared] [[no-]zlib|zlib-dynamic] [no-asm] [no-egd] [sctp] [386] [--prefix=DIR] [--openssldir=OPENSSLDIR] [--with-xxx[=vvv]] [--config=FILE] os/compiler[:flags]\n";
  30
  31 # Options:
  32 #
  33 # --config      add the given configuration file, which will be read after
  34 #               any "Configurations*" files that are found in the same
  35 #               directory as this script.
  36 # --prefix      prefix for the OpenSSL installation, which includes the
  37 #               directories bin, lib, include, share/man, share/doc/openssl
  38 #               This becomes the value of INSTALLTOP in Makefile
  39 #               (Default: /usr/local)
  40 # --openssldir  OpenSSL data area, such as openssl.cnf, certificates and keys.
  41 #               If it's a relative directory, it will be added on the directory
  42 #               given with --prefix.
  43 #               This becomes the value of OPENSSLDIR in Makefile and in C.
  44 #               (Default: PREFIX/ssl)
  45 #
  46 # --cross-compile-prefix Add specified prefix to binutils components.
  47 #
  48 # --api         One of 0.9.8, 1.0.0, 1.0.1, 1.0.2, 1.1.0, 1.1.1, or 3.0
  49 #               Define the public APIs as they were for that version
  50 #               including patch releases.  If 'no-deprecated' is also
  51 #               given, do not compile support for interfaces deprecated
  52 #               up to and including the specified OpenSSL version.
  53 #
  54 # no-hw-xxx     do not compile support for specific crypto hardware.
  55 #               Generic OpenSSL-style methods relating to this support
  56 #               are always compiled but return NULL if the hardware
  57 #               support isn't compiled.
  58 # no-hw         do not compile support for any crypto hardware.
  59 # [no-]threads  [don't] try to create a library that is suitable for
  60 #               multithreaded applications (default is "threads" if we
  61 #               know how to do it)
  62 # [no-]shared   [don't] try to create shared libraries when supported.
  63 # [no-]pic      [don't] try to build position independent code when supported.
  64 #               If disabled, it also disables shared and dynamic-engine.
  65 # no-asm        do not use assembler
  66 # no-egd        do not compile support for the entropy-gathering daemon APIs
  67 # [no-]zlib     [don't] compile support for zlib compression.
  68 # zlib-dynamic  Like "zlib", but the zlib library is expected to be a shared
  69 #               library and will be loaded in run-time by the OpenSSL library.
  70 # sctp          include SCTP support
  71 # no-uplink     Don't build support for UPLINK interface.
  72 # enable-weak-ssl-ciphers
  73 #               Enable weak ciphers that are disabled by default.
  74 # 386           generate 80386 code in assembly modules
  75 # no-sse2       disables IA-32 SSE2 code in assembly modules, the above
  76 #               mentioned '386' option implies this one
  77 # no-<cipher>   build without specified algorithm (rsa, idea, rc5, ...)
  78 # -<xxx> +<xxx> All options which are unknown to the 'Configure' script are
  79 # /<xxx>        passed through to the compiler. Unix-style options beginning
  80 #               with a '-' or '+' are recognized, as well as Windows-style
  81 #               options beginning with a '/'. If the option contains arguments
  82 #               separated by spaces, then the URL-style notation %20 can be
  83 #               used for the space character in order to avoid having to quote
  84 #               the option. For example, -opt%20arg gets expanded to -opt arg.
  85 #               In fact, any ASCII character can be encoded as %xx using its
  86 #               hexadecimal encoding.
  87 # -static       while -static is also a pass-through compiler option (and
  88 #               as such is limited to environments where it's actually
  89 #               meaningful), it triggers a number configuration options,
  90 #               namely no-pic, no-shared and no-threads. It is
  91 #               argued that the only reason to produce statically linked
  92 #               binaries (and in context it means executables linked with
  93 #               -static flag, and not just executables linked with static
  94 #               libcrypto.a) is to eliminate dependency on specific run-time,
  95 #               a.k.a. libc version. The mentioned config options are meant
  96 #               to achieve just that. Unfortunately on Linux it's impossible
  97 #               to eliminate the dependency completely for openssl executable
  98 #               because of getaddrinfo and gethostbyname calls, which can
  99 #               invoke dynamically loadable library facility anyway to meet
 100 #               the lookup requests. For this reason on Linux statically
 101 #               linked openssl executable has rather debugging value than
 102 #               production quality.
 103 #
 104 # BN_LLONG      use the type 'long long' in crypto/bn/bn.h
 105 # RC4_CHAR      use 'char' instead of 'int' for RC4_INT in crypto/rc4/rc4.h
 106 # Following are set automatically by this script
 107 #
 108 # MD5_ASM       use some extra md5 assembler,
 109 # SHA1_ASM      use some extra sha1 assembler, must define L_ENDIAN for x86
 110 # RMD160_ASM    use some extra ripemd160 assembler,
 111 # SHA256_ASM    sha256_block is implemented in assembler
 112 # SHA512_ASM    sha512_block is implemented in assembler
 113 # AES_ASM       AES_[en|de]crypt is implemented in assembler
 114
 115 # Minimum warning options... any contributions to OpenSSL should at least
 116 # get past these.  Note that we only use these with C compilers, not with
 117 # C++ compilers.
 118
 119 # DEBUG_UNUSED enables __owur (warn unused result) checks.
 120 # -DPEDANTIC complements -pedantic and is meant to mask code that
 121 # is not strictly standard-compliant and/or implementation-specific,
 122 # e.g. inline assembly, disregards to alignment requirements, such
 123 # that -pedantic would complain about. Incidentally -DPEDANTIC has
 124 # to be used even in sanitized builds, because sanitizer too is
 125 # supposed to and does take notice of non-standard behaviour. Then
 126 # -pedantic with pre-C9x compiler would also complain about 'long
 127 # long' not being supported. As 64-bit algorithms are common now,
 128 # it grew impossible to resolve this without sizeable additional
 129 # code, so we just tell compiler to be pedantic about everything
 130 # but 'long long' type.
 131
 132 my @gcc_devteam_warn = qw(
 133     -DDEBUG_UNUSED
 134     -DPEDANTIC -pedantic -Wno-long-long
 135     -Wall
 136     -Wextra
 137     -Wno-unused-parameter
 138     -Wno-missing-field-initializers
 139     -Wswitch
 140     -Wsign-compare
 141     -Wshadow
 142     -Wformat
 143     -Wtype-limits
 144     -Wundef
 145     -Werror
 146     -Wmissing-prototypes
 147     -Wstrict-prototypes
 148 );
 149
 150 # These are used in addition to $gcc_devteam_warn when the compiler is clang.
 151 # TODO(openssl-team): fix problems and investigate if (at least) the
 152 # following warnings can also be enabled:
 153 #       -Wcast-align
 154 #       -Wunreachable-code -- no, too ugly/compiler-specific
 155 #       -Wlanguage-extension-token -- no, we use asm()
 156 #       -Wunused-macros -- no, too tricky for BN and _XOPEN_SOURCE etc
 157 #       -Wextended-offsetof -- no, needed in CMS ASN1 code
 158 my @clang_devteam_warn = qw(
 159     -Wno-unknown-warning-option
 160     -Wswitch-default
 161     -Wno-parentheses-equality
 162     -Wno-language-extension-token
 163     -Wno-extended-offsetof
 164     -Wconditional-uninitialized
 165     -Wincompatible-pointer-types-discards-qualifiers
 166     -Wmissing-variable-declarations
 167 );
 168
 169 my @cl_devteam_warn = qw(
 170     /WX
 171 );
 172
 173 my $strict_warnings = 0;
 174
 175 # As for $BSDthreads. Idea is to maintain "collective" set of flags,
 176 # which would cover all BSD flavors. -pthread applies to them all,
 177 # but is treated differently. OpenBSD expands is as -D_POSIX_THREAD
 178 # -lc_r, which is sufficient. FreeBSD 4.x expands it as -lc_r,
 179 # which has to be accompanied by explicit -D_THREAD_SAFE and
 180 # sometimes -D_REENTRANT. FreeBSD 5.x expands it as -lc_r, which
 181 # seems to be sufficient?
 182 our $BSDthreads="-pthread -D_THREAD_SAFE -D_REENTRANT";
 183
 184 #
 185 # API compatibility name to version number mapping.
 186 #
 187 my $apitable = {
 188     # This table expresses when API additions or changes can occur.
 189     # The numbering used changes from 3.0 and on because we updated
 190     # (solidified) our version numbering scheme at that point.
 191
 192     # From 3.0 and on, we internalise the given version number in dedcimal
 193     # as MAJOR * 10000 + MINOR * 100 + 0
 194     "3.0.0" => 30000,
 195     "3.0"   => 30000,
 196
 197     # Note that before 3.0, we didn't have the same version number scheme.
 198     # Still, the numbering we use here covers what we need.
 199     "1.1.1" => 10101,
 200     "1.1.0" => 10100,
 201     "1.0.2" => 10002,
 202     "1.0.1" => 10001,
 203     "1.0.0" => 10000,
 204     "0.9.8" =>   908,
 205 };
 206
 207 our %table = ();
 208 our %config = ();
 209 our %withargs = ();
 210 our $now_printing;      # set to current entry's name in print_table_entry
 211                         # (todo: right thing would be to encapsulate name
 212                         # into %target [class] and make print_table_entry
 213                         # a method)
 214
 215 # Forward declarations ###############################################
 216
 217 # read_config(filename)
 218 #
 219 # Reads a configuration file and populates %table with the contents
 220 # (which the configuration file places in %targets).
 221 sub read_config;
 222
 223 # resolve_config(target)
 224 #
 225 # Resolves all the late evaluations, inheritances and so on for the
 226 # chosen target and any target it inherits from.
 227 sub resolve_config;
 228
 229
 230 # Information collection #############################################
 231
 232 # Unified build supports separate build dir
 233 my $srcdir = catdir(absolutedir(dirname($0))); # catdir ensures local syntax
 234 my $blddir = catdir(absolutedir("."));         # catdir ensures local syntax
 235 my $dofile = abs2rel(catfile($srcdir, "util/dofile.pl"));
 236
 237 my $local_config_envname = 'OPENSSL_LOCAL_CONFIG_DIR';
 238
 239 $config{sourcedir} = abs2rel($srcdir);
 240 $config{builddir} = abs2rel($blddir);
 241
 242 # Collect reconfiguration information if needed
 243 my @argvcopy=@ARGV;
 244
 245 if (grep /^reconf(igure)?$/, @argvcopy) {
 246     die "reconfiguring with other arguments present isn't supported"
 247         if scalar @argvcopy > 1;
 248     if (-f "./configdata.pm") {
 249         my $file = "./configdata.pm";
 250         unless (my $return = do $file) {
 251             die "couldn't parse $file: $@" if $@;
 252             die "couldn't do $file: $!"    unless defined $return;
 253             die "couldn't run $file"       unless $return;
 254         }
 255
 256         @argvcopy = defined($configdata::config{perlargv}) ?
 257             @{$configdata::config{perlargv}} : ();
 258         die "Incorrect data to reconfigure, please do a normal configuration\n"
 259             if (grep(/^reconf/,@argvcopy));
 260         $config{perlenv} = $configdata::config{perlenv} // {};
 261     } else {
 262         die "Insufficient data to reconfigure, please do a normal configuration\n";
 263     }
 264 }
 265
 266 $config{perlargv} = [ @argvcopy ];
 267
 268 # Collect version numbers
 269 my %version = ();
 270
 271 collect_information(
 272     collect_from_file(catfile($srcdir,'VERSION')),
 273     qr/\s*(\w+)\s*=\s*(.*?)\s*$/ =>
 274         sub {
 275             # Only define it if there is a value at all
 276             $version{uc $1} = $2 if $2 ne '';
 277         },
 278     "OTHERWISE" =>
 279         sub { die "Something wrong with this line:\n$_\nin $srcdir/VERSION" },
 280     );
 281
 282 $config{major} = $version{MAJOR} // 'unknown';
 283 $config{minor} = $version{MINOR} // 'unknown';
 284 $config{patch} = $version{PATCH} // 'unknown';
 285 $config{prerelease} =
 286     defined $version{PRE_RELEASE_TAG} ? "-$version{PRE_RELEASE_TAG}" : '';
 287 $config{build_metadata} =
 288     defined $version{BUILD_METADATA} ? "+$version{BUILD_METADATA}" : '';
 289 $config{shlib_version} = $version{SHLIB_VERSION} // 'unknown';
 290 $config{release_date} = $version{RELEASE_DATE} // 'xx XXX xxxx';
 291
 292 $config{version} = "$config{major}.$config{minor}.$config{patch}";
 293 $config{full_version} = "$config{version}$config{prerelease}$config{build_metadata}";
 294
 295 die "erroneous version information in VERSION: ",
 296     "$config{version}, $config{shlib_version}\n"
 297     unless (defined $version{MAJOR}
 298             && defined $version{MINOR}
 299             && defined $version{PATCH}
 300             && defined $version{SHLIB_VERSION});
 301
 302 # Collect target configurations
 303
 304 my $pattern = catfile(dirname($0), "Configurations", "*.conf");
 305 foreach (sort glob($pattern)) {
 306     &read_config($_);
 307 }
 308
 309 if (defined env($local_config_envname)) {
 310     if ($^O eq 'VMS') {
 311         # VMS environment variables are logical names,
 312         # which can be used as is
 313         $pattern = $local_config_envname . ':' . '*.conf';
 314     } else {
 315         $pattern = catfile(env($local_config_envname), '*.conf');
 316     }
 317
 318     foreach (sort glob($pattern)) {
 319         &read_config($_);
 320     }
 321 }
 322
 323 # Save away perl command information
 324 $config{perl_cmd} = $^X;
 325 $config{perl_version} = $Config{version};
 326 $config{perl_archname} = $Config{archname};
 327
 328 $config{prefix}="";
 329 $config{openssldir}="";
 330 $config{processor}="";
 331 $config{libdir}="";
 332 my $auto_threads=1;    # enable threads automatically? true by default
 333 my $default_ranlib;
 334
 335 # Known TLS and DTLS protocols
 336 my @tls = qw(ssl3 tls1 tls1_1 tls1_2 tls1_3);
 337 my @dtls = qw(dtls1 dtls1_2);
 338
 339 # Explicitly known options that are possible to disable.  They can
 340 # be regexps, and will be used like this: /^no-${option}$/
 341 # For developers: keep it sorted alphabetically
 342
 343 my @disablables = (
 344     "afalgeng",
 345     "aria",
 346     "asan",
 347     "asm",
 348     "async",
 349     "autoalginit",
 350     "autoerrinit",
 351     "autoload-config",
 352     "bf",
 353     "blake2",
 354     "buildtest-c++",
 355     "camellia",
 356     "capieng",
 357     "cast",
 358     "chacha",
 359     "cmac",
 360     "cmp",
 361     "cms",
 362     "comp",
 363     "crypto-mdebug",
 364     "ct",
 365     "deprecated",
 366     "des",
 367     "devcryptoeng",
 368     "dgram",
 369     "dh",
 370     "dsa",
 371     "dso",
 372     "dtls",
 373     "dynamic-engine",
 374     "ec",
 375     "ec2m",
 376     "ecdh",
 377     "ecdsa",
 378     "ec_nistp_64_gcc_128",
 379     "egd",
 380     "engine",
 381     "err",
 382     "external-tests",
 383     "filenames",
 384     "fips",
 385     "fuzz-libfuzzer",
 386     "fuzz-afl",
 387     "gost",
 388     "idea",
 389     "ktls",
 390     "legacy",
 391     "makedepend",
 392     "md2",
 393     "md4",
 394     "mdc2",
 395     "module",
 396     "msan",
 397     "multiblock",
 398     "nextprotoneg",
 399     "pinshared",
 400     "ocb",
 401     "ocsp",
 402     "padlockeng",
 403     "pic",
 404     "poly1305",
 405     "posix-io",
 406     "psk",
 407     "rc2",
 408     "rc4",
 409     "rc5",
 410     "rdrand",
 411     "rfc3779",
 412     "rmd160",
 413     "scrypt",
 414     "sctp",
 415     "seed",
 416     "shared",
 417     "siphash",
 418     "siv",
 419     "sm2",
 420     "sm3",
 421     "sm4",
 422     "sock",
 423     "srp",
 424     "srtp",
 425     "sse2",
 426     "ssl",
 427     "ssl-trace",
 428     "static-engine",
 429     "stdio",
 430     "tests",
 431     "threads",
 432     "tls",
 433     "trace",
 434     "ts",
 435     "ubsan",
 436     "ui-console",
 437     "unit-test",
 438     "uplink",
 439     "whirlpool",
 440     "weak-ssl-ciphers",
 441     "zlib",
 442     "zlib-dynamic",
 443     );
 444 foreach my $proto ((@tls, @dtls))
 445         {
 446         push(@disablables, $proto);
 447         push(@disablables, "$proto-method") unless $proto eq "tls1_3";
 448         }
 449
 450 # Internal disablables, for aliasing purposes.  They serve no special
 451 # purpose here, but allow scripts to get to know them through configdata.pm,
 452 # where these are merged with @disablables.
 453 # The actual aliasing mechanism is done via %disable_cascades
 454 my @disablables_int = qw(
 455     crmf
 456     );
 457
 458 my %deprecated_disablables = (
 459     "ssl2" => undef,
 460     "buf-freelists" => undef,
 461     "crypto-mdebug-backtrace" => undef,
 462     "hw" => "hw",               # causes cascade, but no macro
 463     "hw-padlock" => "padlockeng",
 464     "ripemd" => "rmd160",
 465     "ui" => "ui-console",
 466     "heartbeats" => undef,
 467     );
 468
 469 # All of the following are disabled by default:
 470
 471 our %disabled = ( # "what"         => "comment"
 472                   "asan"                => "default",
 473                   "buildtest-c++"       => "default",
 474                   "crypto-mdebug"       => "default",
 475                   "crypto-mdebug-backtrace" => "default",
 476                   "devcryptoeng"        => "default",
 477                   "ec_nistp_64_gcc_128" => "default",
 478                   "egd"                 => "default",
 479                   "external-tests"      => "default",
 480                   "fuzz-libfuzzer"      => "default",
 481                   "fuzz-afl"            => "default",
 482                   "md2"                 => "default",
 483                   "msan"                => "default",
 484                   "rc5"                 => "default",
 485                   "sctp"                => "default",
 486                   "ssl-trace"           => "default",
 487                   "ssl3"                => "default",
 488                   "ssl3-method"         => "default",
 489                   "trace"               => "default",
 490                   "ubsan"               => "default",
 491                   "unit-test"           => "default",
 492                   "weak-ssl-ciphers"    => "default",
 493                   "zlib"                => "default",
 494                   "zlib-dynamic"        => "default",
 495                   "ktls"                => "default",
 496                 );
 497
 498 # Note: => pair form used for aesthetics, not to truly make a hash table
 499 my @disable_cascades = (
 500     # "what"            => [ "cascade", ... ]
 501     sub { $config{processor} eq "386" }
 502                         => [ "sse2" ],
 503     "ssl"               => [ "ssl3" ],
 504     "ssl3-method"       => [ "ssl3" ],
 505     "zlib"              => [ "zlib-dynamic" ],
 506     "des"               => [ "mdc2" ],
 507     "ec"                => [ "ecdsa", "ecdh", "sm2" ],
 508     sub { $disabled{"ec"} && $disabled{"dh"} }
 509                         => [ "tls1_3" ],
 510     "dgram"             => [ "dtls", "sctp" ],
 511     "sock"              => [ "dgram" ],
 512     "dtls"              => [ @dtls ],
 513     sub { 0 == scalar grep { !$disabled{$_} } @dtls }
 514                         => [ "dtls" ],
 515
 516     "tls"               => [ @tls ],
 517     sub { 0 == scalar grep { !$disabled{$_} } @tls }
 518                         => [ "tls" ],
 519
 520     "crypto-mdebug"     => [ "crypto-mdebug-backtrace" ],
 521
 522     # If no modules, then no dynamic engines either
 523     "module"            => [ "dynamic-engine" ],
 524
 525     # Without shared libraries, dynamic engines aren't possible.
 526     # This is due to them having to link with libcrypto and register features
 527     # using the ENGINE functionality, and since that relies on global tables,
 528     # those *have* to be exacty the same as the ones accessed from the app,
 529     # which cannot be guaranteed if shared libraries aren't present.
 530     # (note that even with shared libraries, both the app and dynamic engines
 531     # must be linked with the same library)
 532     "shared"            => [ "dynamic-engine", "uplink" ],
 533     "dso"               => [ "dynamic-engine", "module" ],
 534     # Other modules don't necessarily have to link with libcrypto, so shared
 535     # libraries do not have to be a condition to produce those.
 536
 537     # Without position independent code, there can be no shared libraries
 538     # or modules.
 539     "pic"               => [ "shared", "module" ],
 540
 541     "module"            => [ "fips" ],
 542
 543     "engine"            => [ grep /eng$/, @disablables ],
 544     "hw"                => [ "padlockeng" ],
 545
 546     # no-autoalginit is only useful when building non-shared
 547     "autoalginit"       => [ "shared", "apps" ],
 548
 549     "stdio"             => [ "apps", "capieng", "egd" ],
 550     "apps"              => [ "tests" ],
 551     "tests"             => [ "external-tests" ],
 552     "comp"              => [ "zlib" ],
 553     "sm3"               => [ "sm2" ],
 554     sub { !$disabled{"unit-test"} } => [ "heartbeats" ],
 555
 556     sub { !$disabled{"msan"} } => [ "asm" ],
 557
 558     sub { $disabled{cmac}; } => [ "siv" ],
 559     "legacy"                 => [ "md2" ],
 560
 561     "cmp"               => [ "crmf" ],
 562
 563     # Padlock engine uses low-level AES APIs which are deprecated
 564     sub { $disabled{"deprecated-3.0"} }
 565           => [ "padlockeng" ]
 566     );
 567
 568 # Avoid protocol support holes.  Also disable all versions below N, if version
 569 # N is disabled while N+1 is enabled.
 570 #
 571 my @list = (reverse @tls);
 572 while ((my $first, my $second) = (shift @list, shift @list)) {
 573     last unless @list;
 574     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 575                               => [ @list ] );
 576     unshift @list, $second;
 577 }
 578 my @list = (reverse @dtls);
 579 while ((my $first, my $second) = (shift @list, shift @list)) {
 580     last unless @list;
 581     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 582                               => [ @list ] );
 583     unshift @list, $second;
 584 }
 585
 586 # Explicit "no-..." options will be collected in %disabled along with the defaults.
 587 # To remove something from %disabled, use "enable-foo".
 588 # For symmetry, "disable-foo" is a synonym for "no-foo".
 589
 590 &usage if ($#ARGV < 0);
 591
 592 # For the "make variables" CPPINCLUDES and CPPDEFINES, we support lists with
 593 # platform specific list separators.  Users from those platforms should
 594 # recognise those separators from how you set up the PATH to find executables.
 595 # The default is the Unix like separator, :, but as an exception, we also
 596 # support the space as separator.
 597 my $list_separator_re =
 598     { VMS           => qr/(?<!\^),/,
 599       MSWin32       => qr/(?<!\\);/ } -> {$^O} // qr/(?<!\\)[:\s]/;
 600 # All the "make variables" we support
 601 # Some get pre-populated for the sake of backward compatibility
 602 # (we supported those before the change to "make variable" support.
 603 my %user = (
 604     AR          => env('AR'),
 605     ARFLAGS     => [],
 606     AS          => undef,
 607     ASFLAGS     => [],
 608     CC          => env('CC'),
 609     CFLAGS      => [ env('CFLAGS') || () ],
 610     CXX         => env('CXX'),
 611     CXXFLAGS    => [ env('CXXFLAGS') || () ],
 612     CPP         => undef,
 613     CPPFLAGS    => [ env('CPPFLAGS') || () ],  # -D, -I, -Wp,
 614     CPPDEFINES  => [],  # Alternative for -D
 615     CPPINCLUDES => [],  # Alternative for -I
 616     CROSS_COMPILE => env('CROSS_COMPILE'),
 617     HASHBANGPERL=> env('HASHBANGPERL') || env('PERL'),
 618     LD          => undef,
 619     LDFLAGS     => [ env('LDFLAGS') || () ],  # -L, -Wl,
 620     LDLIBS      => [ env('LDLIBS') || () ],  # -l
 621     MT          => undef,
 622     MTFLAGS     => [],
 623     PERL        => env('PERL') || ($^O ne "VMS" ? $^X : "perl"),
 624     RANLIB      => env('RANLIB'),
 625     RC          => env('RC') || env('WINDRES'),
 626     RCFLAGS     => [ env('RCFLAGS') || () ],
 627     RM          => undef,
 628    );
 629 # Info about what "make variables" may be prefixed with the cross compiler
 630 # prefix.  This should NEVER mention any such variable with a list for value.
 631 my @user_crossable = qw ( AR AS CC CXX CPP LD MT RANLIB RC );
 632 # The same but for flags given as Configure options.  These are *additional*
 633 # input, as opposed to the VAR=string option that override the corresponding
 634 # config target attributes
 635 my %useradd = (
 636     CPPDEFINES  => [],
 637     CPPINCLUDES => [],
 638     CPPFLAGS    => [],
 639     CFLAGS      => [],
 640     CXXFLAGS    => [],
 641     LDFLAGS     => [],
 642     LDLIBS      => [],
 643     RCFLAGS     => [],
 644    );
 645
 646 my %user_synonyms = (
 647     HASHBANGPERL=> 'PERL',
 648     RC          => 'WINDRES',
 649    );
 650
 651 # Some target attributes have been renamed, this is the translation table
 652 my %target_attr_translate =(
 653     ar          => 'AR',
 654     as          => 'AS',
 655     cc          => 'CC',
 656     cxx         => 'CXX',
 657     cpp         => 'CPP',
 658     hashbangperl => 'HASHBANGPERL',
 659     ld          => 'LD',
 660     mt          => 'MT',
 661     ranlib      => 'RANLIB',
 662     rc          => 'RC',
 663     rm          => 'RM',
 664    );
 665
 666 # Initialisers coming from 'config' scripts
 667 $config{defines} = [ split(/$list_separator_re/, env('__CNF_CPPDEFINES')) ];
 668 $config{includes} = [ split(/$list_separator_re/, env('__CNF_CPPINCLUDES')) ];
 669 $config{cppflags} = [ env('__CNF_CPPFLAGS') || () ];
 670 $config{cflags} = [ env('__CNF_CFLAGS') || () ];
 671 $config{cxxflags} = [ env('__CNF_CXXFLAGS') || () ];
 672 $config{lflags} = [ env('__CNF_LDFLAGS') || () ];
 673 $config{ex_libs} = [ env('__CNF_LDLIBS') || () ];
 674
 675 $config{openssl_api_defines}=[];
 676 $config{openssl_sys_defines}=[];
 677 $config{openssl_feature_defines}=[];
 678 $config{options}="";
 679 $config{build_type} = "release";
 680 my $target="";
 681
 682 my %cmdvars = ();               # Stores FOO='blah' type arguments
 683 my %unsupported_options = ();
 684 my %deprecated_options = ();
 685 # If you change this, update apps/version.c
 686 my @known_seed_sources = qw(getrandom devrandom os egd none rdcpu librandom);
 687 my @seed_sources = ();
 688 while (@argvcopy)
 689         {
 690         $_ = shift @argvcopy;
 691
 692         # Support env variable assignments among the options
 693         if (m|^(\w+)=(.+)?$|)
 694                 {
 695                 $cmdvars{$1} = $2;
 696                 # Every time a variable is given as a configuration argument,
 697                 # it acts as a reset if the variable.
 698                 if (exists $user{$1})
 699                         {
 700                         $user{$1} = ref $user{$1} eq "ARRAY" ? [] : undef;
 701                         }
 702                 #if (exists $useradd{$1})
 703                 #       {
 704                 #       $useradd{$1} = [];
 705                 #       }
 706                 next;
 707                 }
 708
 709         # VMS is a case insensitive environment, and depending on settings
 710         # out of our control, we may receive options uppercased.  Let's
 711         # downcase at least the part before any equal sign.
 712         if ($^O eq "VMS")
 713                 {
 714                 s/^([^=]*)/lc($1)/e;
 715                 }
 716
 717         # some people just can't read the instructions, clang people have to...
 718         s/^-no-(?!integrated-as)/no-/;
 719
 720         # rewrite some options in "enable-..." form
 721         s /^-?-?shared$/enable-shared/;
 722         s /^sctp$/enable-sctp/;
 723         s /^threads$/enable-threads/;
 724         s /^zlib$/enable-zlib/;
 725         s /^zlib-dynamic$/enable-zlib-dynamic/;
 726
 727         if (/^(no|disable|enable)-(.+)$/)
 728                 {
 729                 my $word = $2;
 730                 if ($word !~ m|hw(?:-.+)| # special treatment for hw regexp opt
 731                         && !exists $deprecated_disablables{$word}
 732                         && !grep { $word eq $_ } @disablables)
 733                         {
 734                         $unsupported_options{$_} = 1;
 735                         next;
 736                         }
 737                 }
 738         if (/^no-(.+)$/ || /^disable-(.+)$/)
 739                 {
 740                 foreach my $proto ((@tls, @dtls))
 741                         {
 742                         if ($1 eq "$proto-method")
 743                                 {
 744                                 $disabled{"$proto"} = "option($proto-method)";
 745                                 last;
 746                                 }
 747                         }
 748                 if ($1 eq "dtls")
 749                         {
 750                         foreach my $proto (@dtls)
 751                                 {
 752                                 $disabled{$proto} = "option(dtls)";
 753                                 }
 754                         $disabled{"dtls"} = "option(dtls)";
 755                         }
 756                 elsif ($1 eq "ssl")
 757                         {
 758                         # Last one of its kind
 759                         $disabled{"ssl3"} = "option(ssl)";
 760                         }
 761                 elsif ($1 eq "tls")
 762                         {
 763                         # XXX: Tests will fail if all SSL/TLS
 764                         # protocols are disabled.
 765                         foreach my $proto (@tls)
 766                                 {
 767                                 $disabled{$proto} = "option(tls)";
 768                                 }
 769                         }
 770                 elsif ($1 eq "static-engine")
 771                         {
 772                         delete $disabled{"dynamic-engine"};
 773                         }
 774                 elsif ($1 eq "dynamic-engine")
 775                         {
 776                         $disabled{"dynamic-engine"} = "option";
 777                         }
 778                 elsif (exists $deprecated_disablables{$1})
 779                         {
 780                         $deprecated_options{$_} = 1;
 781                         if (defined $deprecated_disablables{$1})
 782                                 {
 783                                 $disabled{$deprecated_disablables{$1}} = "option";
 784                                 }
 785                         }
 786                 elsif ($1 =~ m|hw(?:-.+)|) # deprecate hw options in regexp form
 787                         {
 788                         $deprecated_options{$_} = 1;
 789                         }
 790                 else
 791                         {
 792                         $disabled{$1} = "option";
 793                         }
 794                 # No longer an automatic choice
 795                 $auto_threads = 0 if ($1 eq "threads");
 796                 }
 797         elsif (/^enable-(.+)$/)
 798                 {
 799                 if ($1 eq "static-engine")
 800                         {
 801                         $disabled{"dynamic-engine"} = "option";
 802                         }
 803                 elsif ($1 eq "dynamic-engine")
 804                         {
 805                         delete $disabled{"dynamic-engine"};
 806                         }
 807                 elsif ($1 eq "zlib-dynamic")
 808                         {
 809                         delete $disabled{"zlib"};
 810                         }
 811                 my $algo = $1;
 812                 delete $disabled{$algo};
 813
 814                 # No longer an automatic choice
 815                 $auto_threads = 0 if ($1 eq "threads");
 816                 }
 817         elsif (/^--strict-warnings$/)
 818                 {
 819                 # Pretend that our strict flags is a C flag, and replace it
 820                 # with the proper flags later on
 821                 push @{$useradd{CFLAGS}}, '--ossl-strict-warnings';
 822                 $strict_warnings=1;
 823                 }
 824         elsif (/^--debug$/)
 825                 {
 826                 $config{build_type} = "debug";
 827                 }
 828         elsif (/^--release$/)
 829                 {
 830                 $config{build_type} = "release";
 831                 }
 832         elsif (/^386$/)
 833                 { $config{processor}=386; }
 834         elsif (/^fips$/)
 835                 {
 836                 die "FIPS mode not supported\n";
 837                 }
 838         elsif (/^rsaref$/)
 839                 {
 840                 # No RSAref support any more since it's not needed.
 841                 # The check for the option is there so scripts aren't
 842                 # broken
 843                 }
 844         elsif (/^nofipscanistercheck$/)
 845                 {
 846                 die "FIPS mode not supported\n";
 847                 }
 848         elsif (m|^[-+/]|)
 849                 {
 850                 if (/^--prefix=(.*)$/)
 851                         {
 852                         $config{prefix}=$1;
 853                         die "Directory given with --prefix MUST be absolute\n"
 854                                 unless file_name_is_absolute($config{prefix});
 855                         }
 856                 elsif (/^--api=(.*)$/)
 857                         {
 858                         my $api = $1;
 859                         die "Unknown API compatibility level $api"
 860                                 unless defined $apitable->{$api};
 861                         $config{api}=$apitable->{$api};
 862                         }
 863                 elsif (/^--libdir=(.*)$/)
 864                         {
 865                         $config{libdir}=$1;
 866                         }
 867                 elsif (/^--openssldir=(.*)$/)
 868                         {
 869                         $config{openssldir}=$1;
 870                         }
 871                 elsif (/^--with-zlib-lib=(.*)$/)
 872                         {
 873                         $withargs{zlib_lib}=$1;
 874                         }
 875                 elsif (/^--with-zlib-include=(.*)$/)
 876                         {
 877                         $withargs{zlib_include}=$1;
 878                         }
 879                 elsif (/^--with-fuzzer-lib=(.*)$/)
 880                         {
 881                         $withargs{fuzzer_lib}=$1;
 882                         }
 883                 elsif (/^--with-fuzzer-include=(.*)$/)
 884                         {
 885                         $withargs{fuzzer_include}=$1;
 886                         }
 887                 elsif (/^--with-rand-seed=(.*)$/)
 888                         {
 889                         foreach my $x (split(m|,|, $1))
 890                             {
 891                             die "Unknown --with-rand-seed choice $x\n"
 892                                 if ! grep { $x eq $_ } @known_seed_sources;
 893                             push @seed_sources, $x;
 894                             }
 895                         }
 896                 elsif (/^--cross-compile-prefix=(.*)$/)
 897                         {
 898                         $user{CROSS_COMPILE}=$1;
 899                         }
 900                 elsif (/^--config=(.*)$/)
 901                         {
 902                         read_config $1;
 903                         }
 904                 elsif (/^-l(.*)$/)
 905                         {
 906                         push @{$useradd{LDLIBS}}, $_;
 907                         }
 908                 elsif (/^-framework$/)
 909                         {
 910                         push @{$useradd{LDLIBS}}, $_, shift(@argvcopy);
 911                         }
 912                 elsif (/^-L(.*)$/ or /^-Wl,/)
 913                         {
 914                         push @{$useradd{LDFLAGS}}, $_;
 915                         }
 916                 elsif (/^-rpath$/ or /^-R$/)
 917                         # -rpath is the OSF1 rpath flag
 918                         # -R is the old Solaris rpath flag
 919                         {
 920                         my $rpath = shift(@argvcopy) || "";
 921                         $rpath .= " " if $rpath ne "";
 922                         push @{$useradd{LDFLAGS}}, $_, $rpath;
 923                         }
 924                 elsif (/^-static$/)
 925                         {
 926                         push @{$useradd{LDFLAGS}}, $_;
 927                         }
 928                 elsif (m|^[-/]D(.*)$|)
 929                         {
 930                         push @{$useradd{CPPDEFINES}}, $1;
 931                         }
 932                 elsif (m|^[-/]I(.*)$|)
 933                         {
 934                         push @{$useradd{CPPINCLUDES}}, $1;
 935                         }
 936                 elsif (/^-Wp,$/)
 937                         {
 938                         push @{$useradd{CPPFLAGS}}, $1;
 939                         }
 940                 else    # common if (/^[-+]/), just pass down...
 941                         {
 942                         # Treat %xx as an ASCII code (e.g. replace %20 by a space character).
 943                         # This provides a simple way to pass options with arguments separated
 944                         # by spaces without quoting (e.g. -opt%20arg translates to -opt arg).
 945                         $_ =~ s/%([0-9a-f]{1,2})/chr(hex($1))/gei;
 946                         push @{$useradd{CFLAGS}}, $_;
 947                         push @{$useradd{CXXFLAGS}}, $_;
 948                         }
 949                 }
 950         elsif (m|^/|)
 951                 {
 952                 # Treat %xx as an ASCII code (e.g. replace %20 by a space character).
 953                 # This provides a simple way to pass options with arguments separated
 954                 # by spaces without quoting (e.g. /opt%20arg translates to /opt arg).
 955                 $_ =~ s/%([0-9a-f]{1,2})/chr(hex($1))/gei;
 956                 push @{$useradd{CFLAGS}}, $_;
 957                 push @{$useradd{CXXFLAGS}}, $_;
 958                 }
 959         else
 960                 {
 961                 die "target already defined - $target (offending arg: $_)\n" if ($target ne "");
 962                 $target=$_;
 963                 }
 964         unless ($_ eq $target || /^no-/ || /^disable-/)
 965                 {
 966                 # "no-..." follows later after implied deactivations
 967                 # have been derived.  (Don't take this too seriously,
 968                 # we really only write OPTIONS to the Makefile out of
 969                 # nostalgia.)
 970
 971                 if ($config{options} eq "")
 972                         { $config{options} = $_; }
 973                 else
 974                         { $config{options} .= " ".$_; }
 975                 }
 976         }
 977
 978 if (keys %deprecated_options)
 979         {
 980         warn "***** Deprecated options: ",
 981                 join(", ", keys %deprecated_options), "\n";
 982         }
 983 if (keys %unsupported_options)
 984         {
 985         die "***** Unsupported options: ",
 986                 join(", ", keys %unsupported_options), "\n";
 987         }
 988
 989 # If any %useradd entry has been set, we must check that the "make
 990 # variables" haven't been set.  We start by checking of any %useradd entry
 991 # is set.
 992 if (grep { scalar @$_ > 0 } values %useradd) {
 993     # Hash of env / make variables names.  The possible values are:
 994     # 1 - "make vars"
 995     # 2 - %useradd entry set
 996     # 3 - both set
 997     my %detected_vars =
 998         map { my $v = 0;
 999               $v += 1 if $cmdvars{$_};
1000               $v += 2 if @{$useradd{$_}};
1001               $_ => $v }
1002         keys %useradd;
1003
1004     # If any of the corresponding "make variables" is set, we error
1005     if (grep { $_ & 1 } values %detected_vars) {
1006         my $names = join(', ', grep { $detected_vars{$_} > 0 }
1007                                sort keys %detected_vars);
1008         die <<"_____";
1009 ***** Mixing make variables and additional compiler/linker flags as
1010 ***** configure command line option is not permitted.
1011 ***** Affected make variables: $names
1012 _____
1013     }
1014 }
1015
1016 # Check through all supported command line variables to see if any of them
1017 # were set, and canonicalise the values we got.  If no compiler or linker
1018 # flag or anything else that affects %useradd was set, we also check the
1019 # environment for values.
1020 my $anyuseradd =
1021     grep { defined $_ && (ref $_ ne 'ARRAY' || @$_) } values %useradd;
1022 foreach (keys %user) {
1023     my $value = $cmdvars{$_};
1024     $value //= env($_) unless $anyuseradd;
1025     $value //=
1026         defined $user_synonyms{$_} ? $cmdvars{$user_synonyms{$_}} : undef;
1027     $value //= defined $user_synonyms{$_} ? env($user_synonyms{$_}) : undef
1028         unless $anyuseradd;
1029
1030     if (defined $value) {
1031         if (ref $user{$_} eq 'ARRAY') {
1032             if ($_ eq 'CPPDEFINES' || $_ eq 'CPPINCLUDES') {
1033                 $user{$_} = [ split /$list_separator_re/, $value ];
1034             } else {
1035                 $user{$_} = [ $value ];
1036             }
1037         } elsif (!defined $user{$_}) {
1038             $user{$_} = $value;
1039         }
1040     }
1041 }
1042
1043 if (grep { /-rpath\b/ } ($user{LDFLAGS} ? @{$user{LDFLAGS}} : ())
1044     && !$disabled{shared}
1045     && !($disabled{asan} && $disabled{msan} && $disabled{ubsan})) {
1046     die "***** Cannot simultaneously use -rpath, shared libraries, and\n",
1047         "***** any of asan, msan or ubsan\n";
1048 }
1049
1050 sub disable {
1051     my $disable_type = shift;
1052
1053     for (@_) {
1054         $disabled{$_} = $disable_type;
1055     }
1056
1057     my @tocheckfor = (@_ ? @_ : keys %disabled);
1058     while (@tocheckfor) {
1059         my %new_tocheckfor = ();
1060         my @cascade_copy = (@disable_cascades);
1061         while (@cascade_copy) {
1062             my ($test, $descendents) =
1063                 (shift @cascade_copy, shift @cascade_copy);
1064             if (ref($test) eq "CODE" ? $test->() : defined($disabled{$test})) {
1065                 foreach (grep { !defined($disabled{$_}) } @$descendents) {
1066                     $new_tocheckfor{$_} = 1; $disabled{$_} = "cascade";
1067                 }
1068             }
1069         }
1070         @tocheckfor = (keys %new_tocheckfor);
1071     }
1072 }
1073 disable();                     # First cascade run
1074
1075 our $die = sub { die @_; };
1076 if ($target eq "TABLE") {
1077     local $die = sub { warn @_; };
1078     foreach (sort keys %table) {
1079         print_table_entry($_, "TABLE");
1080     }
1081     exit 0;
1082 }
1083
1084 if ($target eq "LIST") {
1085     foreach (sort keys %table) {
1086         print $_,"\n" unless $table{$_}->{template};
1087     }
1088     exit 0;
1089 }
1090
1091 if ($target eq "HASH") {
1092     local $die = sub { warn @_; };
1093     print "%table = (\n";
1094     foreach (sort keys %table) {
1095         print_table_entry($_, "HASH");
1096     }
1097     exit 0;
1098 }
1099
1100 print "Configuring OpenSSL version $config{full_version} ";
1101 print "for target $target\n";
1102
1103 if (scalar(@seed_sources) == 0) {
1104     print "Using os-specific seed configuration\n";
1105     push @seed_sources, 'os';
1106 }
1107 if (scalar(grep { $_ eq 'none' } @seed_sources) > 0) {
1108     die "Cannot seed with none and anything else" if scalar(@seed_sources) > 1;
1109     warn <<_____ if scalar(@seed_sources) == 1;
1110
1111 ============================== WARNING ===============================
1112 You have selected the --with-rand-seed=none option, which effectively
1113 disables automatic reseeding of the OpenSSL random generator.
1114 All operations depending on the random generator such as creating keys
1115 will not work unless the random generator is seeded manually by the
1116 application.
1117
1118 Please read the 'Note on random number generation' section in the
1119 INSTALL instructions and the RAND_DRBG(7) manual page for more details.
1120 ============================== WARNING ===============================
1121
1122 _____
1123 }
1124 push @{$config{openssl_feature_defines}},
1125      map { (my $x = $_) =~ tr|[\-a-z]|[_A-Z]|; "OPENSSL_RAND_SEED_$x" }
1126         @seed_sources;
1127
1128 # Backward compatibility?
1129 if ($target =~ m/^CygWin32(-.*)$/) {
1130     $target = "Cygwin".$1;
1131 }
1132
1133 # Support for legacy targets having a name starting with 'debug-'
1134 my ($d, $t) = $target =~ m/^(debug-)?(.*)$/;
1135 if ($d) {
1136     $config{build_type} = "debug";
1137
1138     # If we do not find debug-foo in the table, the target is set to foo.
1139     if (!$table{$target}) {
1140         $target = $t;
1141     }
1142 }
1143
1144 &usage if !$table{$target} || $table{$target}->{template};
1145
1146 $config{target} = $target;
1147 my %target = resolve_config($target);
1148
1149 foreach (keys %target_attr_translate) {
1150     $target{$target_attr_translate{$_}} = $target{$_}
1151         if $target{$_};
1152     delete $target{$_};
1153 }
1154
1155 %target = ( %{$table{DEFAULTS}}, %target );
1156
1157 my %conf_files = map { $_ => 1 } (@{$target{_conf_fname_int}});
1158 $config{conf_files} = [ sort keys %conf_files ];
1159
1160 # Using sub disable within these loops may prove fragile, so we run
1161 # a cascade afterwards
1162 foreach my $feature (@{$target{disable}}) {
1163     if (exists $deprecated_disablables{$feature}) {
1164         warn "***** config $target disables deprecated feature $feature\n";
1165     } elsif (!grep { $feature eq $_ } @disablables) {
1166         die "***** config $target disables unknown feature $feature\n";
1167     }
1168     $disabled{$feature} = 'config';
1169 }
1170 foreach my $feature (@{$target{enable}}) {
1171     if ("default" eq ($disabled{$feature} // "")) {
1172         if (exists $deprecated_disablables{$feature}) {
1173             warn "***** config $target enables deprecated feature $feature\n";
1174         } elsif (!grep { $feature eq $_ } @disablables) {
1175             die "***** config $target enables unknown feature $feature\n";
1176         }
1177         delete $disabled{$feature};
1178     }
1179 }
1180
1181 # If uplink_arch isn't defined, disable uplink
1182 $disabled{uplink} = 'no uplink_arch' unless (defined $target{uplink_arch});
1183 # If asm_arch isn't defined, disable asm
1184 $disabled{asm} = 'no asm_arch' unless (defined $target{asm_arch});
1185
1186 disable();                      # Run a cascade now
1187
1188 $target{CXXFLAGS}//=$target{CFLAGS} if $target{CXX};
1189 $target{cxxflags}//=$target{cflags} if $target{CXX};
1190 $target{exe_extension}=".exe" if ($config{target} eq "DJGPP");
1191 $target{exe_extension}=".pm"  if ($config{target} =~ /vos/);
1192
1193 # Fill %config with values from %user, and in case those are undefined or
1194 # empty, use values from %target (acting as a default).
1195 foreach (keys %user) {
1196     my $ref_type = ref $user{$_};
1197
1198     # Temporary function.  Takes an intended ref type (empty string or "ARRAY")
1199     # and a value that's to be coerced into that type.
1200     my $mkvalue = sub {
1201         my $type = shift;
1202         my $value = shift;
1203         my $undef_p = shift;
1204
1205         die "Too many arguments for \$mkvalue" if @_;
1206
1207         while (ref $value eq 'CODE') {
1208             $value = $value->();
1209         }
1210
1211         if ($type eq 'ARRAY') {
1212             return undef unless defined $value;
1213             return undef if ref $value ne 'ARRAY' && !$value;
1214             return undef if ref $value eq 'ARRAY' && !@$value;
1215             return [ $value ] unless ref $value eq 'ARRAY';
1216         }
1217         return undef unless $value;
1218         return $value;
1219     };
1220
1221     $config{$_} =
1222         $mkvalue->($ref_type, $user{$_})
1223         || $mkvalue->($ref_type, $target{$_});
1224     delete $config{$_} unless defined $config{$_};
1225 }
1226
1227 # Finish up %config by appending things the user gave us on the command line
1228 # apart from "make variables"
1229 foreach (keys %useradd) {
1230     # The must all be lists, so we assert that here
1231     die "internal error: \$useradd{$_} isn't an ARRAY\n"
1232         unless ref $useradd{$_} eq 'ARRAY';
1233
1234     if (defined $config{$_}) {
1235         push @{$config{$_}}, @{$useradd{$_}};
1236     } else {
1237         $config{$_} = [ @{$useradd{$_}} ];
1238     }
1239 }
1240 # At this point, we can forget everything about %user and %useradd,
1241 # because it's now all been merged into the corresponding $config entry
1242
1243 # Allow overriding the build file name
1244 $config{build_file} = env('BUILDFILE') || $target{build_file} || "Makefile";
1245
1246 # Make sure build_scheme is consistent.
1247 $target{build_scheme} = [ $target{build_scheme} ]
1248     if ref($target{build_scheme}) ne "ARRAY";
1249
1250 my ($builder, $builder_platform, @builder_opts) =
1251     @{$target{build_scheme}};
1252
1253 foreach my $checker (($builder_platform."-".$target{build_file}."-checker.pm",
1254                       $builder_platform."-checker.pm")) {
1255     my $checker_path = catfile($srcdir, "Configurations", $checker);
1256     if (-f $checker_path) {
1257         my $fn = $ENV{CONFIGURE_CHECKER_WARN}
1258             ? sub { warn $@; } : sub { die $@; };
1259         if (! do $checker_path) {
1260             if ($@) {
1261                 $fn->($@);
1262             } elsif ($!) {
1263                 $fn->($!);
1264             } else {
1265                 $fn->("The detected tools didn't match the platform\n");
1266             }
1267         }
1268         last;
1269     }
1270 }
1271
1272 push @{$config{defines}}, "NDEBUG"    if $config{build_type} eq "release";
1273
1274 if ($target =~ /^mingw/ && `$config{CC} --target-help 2>&1` =~ m/-mno-cygwin/m)
1275         {
1276         push @{$config{cflags}}, "-mno-cygwin";
1277         push @{$config{cxxflags}}, "-mno-cygwin" if $config{CXX};
1278         push @{$config{shared_ldflag}}, "-mno-cygwin";
1279         }
1280
1281 if ($target =~ /linux.*-mips/ && !$disabled{asm}
1282         && !grep { $_ !~ /-m(ips|arch=)/ } (@{$config{CFLAGS}})) {
1283         # minimally required architecture flags for assembly modules
1284         my $value;
1285         $value = '-mips2' if ($target =~ /mips32/);
1286         $value = '-mips3' if ($target =~ /mips64/);
1287         unshift @{$config{cflags}}, $value;
1288         unshift @{$config{cxxflags}}, $value if $config{CXX};
1289 }
1290
1291 # If threads aren't disabled, check how possible they are
1292 unless ($disabled{threads}) {
1293     if ($auto_threads) {
1294         # Enabled by default, disable it forcibly if unavailable
1295         if ($target{thread_scheme} eq "(unknown)") {
1296             disable("unavailable", 'threads');
1297         }
1298     } else {
1299         # The user chose to enable threads explicitly, let's see
1300         # if there's a chance that's possible
1301         if ($target{thread_scheme} eq "(unknown)") {
1302             # If the user asked for "threads" and we don't have internal
1303             # knowledge how to do it, [s]he is expected to provide any
1304             # system-dependent compiler options that are necessary.  We
1305             # can't truly check that the given options are correct, but
1306             # we expect the user to know what [s]He is doing.
1307             if (!@{$config{CFLAGS}} && !@{$config{CPPDEFINES}}) {
1308                 die "You asked for multi-threading support, but didn't\n"
1309                     ,"provide any system-specific compiler options\n";
1310             }
1311         }
1312     }
1313 }
1314
1315 # Find out if clang's sanitizers have been enabled with -fsanitize
1316 # flags and ensure that the corresponding %disabled elements area
1317 # removed to reflect that the sanitizers are indeed enabled.
1318 my %detected_sanitizers = ();
1319 foreach (grep /^-fsanitize=/, @{$config{CFLAGS} || []}) {
1320     (my $checks = $_) =~ s/^-fsanitize=//;
1321     foreach (split /,/, $checks) {
1322         my $d = { address       => 'asan',
1323                   undefined     => 'ubsan',
1324                   memory        => 'msan' } -> {$_};
1325         next unless defined $d;
1326
1327         $detected_sanitizers{$d} = 1;
1328         if (defined $disabled{$d}) {
1329             die "***** Conflict between disabling $d and enabling $_ sanitizer"
1330                 if $disabled{$d} ne "default";
1331             delete $disabled{$d};
1332         }
1333     }
1334 }
1335
1336 # If threads still aren't disabled, add a C macro to ensure the source
1337 # code knows about it.  Any other flag is taken care of by the configs.
1338 unless($disabled{threads}) {
1339     push @{$config{openssl_feature_defines}}, "OPENSSL_THREADS";
1340 }
1341
1342 my $no_shared_warn=0;
1343 if ($target{shared_target} eq "")
1344         {
1345         $no_shared_warn = 1
1346             if (!$disabled{shared} || !$disabled{"dynamic-engine"});
1347         disable('no-shared-target', 'pic');
1348         }
1349
1350 if ($disabled{"dynamic-engine"}) {
1351         $config{dynamic_engines} = 0;
1352 } else {
1353         $config{dynamic_engines} = 1;
1354 }
1355
1356 unless ($disabled{asan} || defined $detected_sanitizers{asan}) {
1357     push @{$config{cflags}}, "-fsanitize=address";
1358 }
1359
1360 unless ($disabled{ubsan} || defined $detected_sanitizers{ubsan}) {
1361     # -DPEDANTIC or -fnosanitize=alignment may also be required on some
1362     # platforms.
1363     push @{$config{cflags}}, "-fsanitize=undefined", "-fno-sanitize-recover=all";
1364 }
1365
1366 unless ($disabled{msan} || defined $detected_sanitizers{msan}) {
1367   push @{$config{cflags}}, "-fsanitize=memory";
1368 }
1369
1370 unless ($disabled{"fuzz-libfuzzer"} && $disabled{"fuzz-afl"}
1371         && $disabled{asan} && $disabled{ubsan} && $disabled{msan}) {
1372     push @{$config{cflags}}, "-fno-omit-frame-pointer", "-g";
1373     push @{$config{cxxflags}}, "-fno-omit-frame-pointer", "-g" if $config{CXX};
1374 }
1375 #
1376 # Platform fix-ups
1377 #
1378
1379 # This saves the build files from having to check
1380 if ($disabled{pic})
1381         {
1382         foreach (qw(shared_cflag shared_cxxflag shared_cppflag
1383                     shared_defines shared_includes shared_ldflag
1384                     module_cflags module_cxxflags module_cppflags
1385                     module_defines module_includes module_lflags))
1386                 {
1387                 delete $config{$_};
1388                 $target{$_} = "";
1389                 }
1390         }
1391 else
1392         {
1393         push @{$config{lib_defines}}, "OPENSSL_PIC";
1394         }
1395
1396 if ($target{sys_id} ne "")
1397         {
1398         push @{$config{openssl_sys_defines}}, "OPENSSL_SYS_$target{sys_id}";
1399         }
1400
1401 my %predefined_C = compiler_predefined($config{CROSS_COMPILE}.$config{CC});
1402 my %predefined_CXX = $config{CXX}
1403     ? compiler_predefined($config{CROSS_COMPILE}.$config{CXX})
1404     : ();
1405
1406 unless ($disabled{asm}) {
1407     # big endian systems can use ELFv2 ABI
1408     if ($target eq "linux-ppc64") {
1409         $target{perlasm_scheme} = "linux64v2" if ($predefined_C{_CALL_ELF} == 2);
1410     }
1411 }
1412
1413 # Check for makedepend capabilities.
1414 if (!$disabled{makedepend}) {
1415     if ($config{target} =~ /^(VC|vms)-/) {
1416         # For VC- and vms- targets, there's nothing more to do here.  The
1417         # functionality is hard coded in the corresponding build files for
1418         # cl (Windows) and CC/DECC (VMS).
1419     } elsif (($predefined_C{__GNUC__} // -1) >= 3
1420              && !($predefined_C{__APPLE_CC__} && !$predefined_C{__clang__})) {
1421         # We know that GNU C version 3 and up as well as all clang
1422         # versions support dependency generation, but Xcode did not
1423         # handle $cc -M before clang support (but claims __GNUC__ = 3)
1424         $config{makedepprog} = "\$(CROSS_COMPILE)$config{CC}";
1425     } else {
1426         # In all other cases, we look for 'makedepend', and disable the
1427         # capability if not found.
1428         $config{makedepprog} = which('makedepend');
1429         disable('unavailable', 'makedepend') unless $config{makedepprog};
1430     }
1431 }
1432
1433 if (!$disabled{asm} && !$predefined_C{__MACH__} && $^O ne 'VMS') {
1434     # probe for -Wa,--noexecstack option...
1435     if ($predefined_C{__clang__}) {
1436         # clang has builtin assembler, which doesn't recognize --help,
1437         # but it apparently recognizes the option in question on all
1438         # supported platforms even when it's meaningless. In other words
1439         # probe would fail, but probed option always accepted...
1440         push @{$config{cflags}}, "-Wa,--noexecstack", "-Qunused-arguments";
1441     } else {
1442         my $cc = $config{CROSS_COMPILE}.$config{CC};
1443         open(PIPE, "$cc -Wa,--help -c -o null.$$.o -x assembler /dev/null 2>&1 |");
1444         while(<PIPE>) {
1445             if (m/--noexecstack/) {
1446                 push @{$config{cflags}}, "-Wa,--noexecstack";
1447                 last;
1448             }
1449         }
1450         close(PIPE);
1451         unlink("null.$$.o");
1452     }
1453 }
1454
1455 # Deal with bn_ops ###################################################
1456
1457 $config{bn_ll}                  =0;
1458 my $def_int="unsigned int";
1459 $config{rc4_int}                =$def_int;
1460 ($config{b64l},$config{b64},$config{b32})=(0,0,1);
1461
1462 my $count = 0;
1463 foreach (sort split(/\s+/,$target{bn_ops})) {
1464     $count++ if /SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT/;
1465     $config{bn_ll}=1                            if $_ eq 'BN_LLONG';
1466     $config{rc4_int}="unsigned char"            if $_ eq 'RC4_CHAR';
1467     ($config{b64l},$config{b64},$config{b32})
1468         =(0,1,0)                                if $_ eq 'SIXTY_FOUR_BIT';
1469     ($config{b64l},$config{b64},$config{b32})
1470         =(1,0,0)                                if $_ eq 'SIXTY_FOUR_BIT_LONG';
1471     ($config{b64l},$config{b64},$config{b32})
1472         =(0,0,1)                                if $_ eq 'THIRTY_TWO_BIT';
1473 }
1474 die "Exactly one of SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT can be set in bn_ops\n"
1475     if $count > 1;
1476
1477 $config{api} = $config{major} * 10000 + $config{minor} * 100
1478     unless $config{api};
1479 foreach (keys %$apitable) {
1480     $disabled{"deprecated-$_"} = "deprecation"
1481         if $disabled{deprecated} && $config{api} >= $apitable->{$_};
1482 }
1483
1484 disable();                      # Run a cascade now
1485
1486 # Hack cflags for better warnings (dev option) #######################
1487
1488 # "Stringify" the C and C++ flags string.  This permits it to be made part of
1489 # a string and works as well on command lines.
1490 $config{cflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1491                         @{$config{cflags}} ];
1492 $config{cxxflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1493                           @{$config{cxxflags}} ] if $config{CXX};
1494
1495 $config{openssl_api_defines} = [
1496     "OPENSSL_CONFIGURED_API=".$config{api},
1497 ];
1498
1499 my @strict_warnings_collection=();
1500 if ($strict_warnings)
1501         {
1502         my $wopt;
1503         my $gccver = $predefined_C{__GNUC__} // -1;
1504
1505         if ($gccver >= 4)
1506                 {
1507                 push @strict_warnings_collection, @gcc_devteam_warn;
1508                 push @strict_warnings_collection, @clang_devteam_warn
1509                     if (defined($predefined_C{__clang__}));
1510                 }
1511         elsif ($config{target} =~ /^VC-/)
1512                 {
1513                 push @strict_warnings_collection, @cl_devteam_warn;
1514                 }
1515         else
1516                 {
1517                 warn "WARNING --strict-warnings requires gcc[>=4] or gcc-alike, or MSVC"
1518                 }
1519         }
1520
1521 if (grep { $_ =~ /(?:^|\s)-static(?:\s|$)/ } @{$config{LDFLAGS}}) {
1522     disable('static', 'pic', 'threads');
1523 }
1524
1525 $config{CFLAGS} = [ map { $_ eq '--ossl-strict-warnings'
1526                               ? @strict_warnings_collection
1527                               : ( $_ ) }
1528                     @{$config{CFLAGS}} ];
1529
1530 unless ($disabled{afalgeng}) {
1531     $config{afalgeng}="";
1532     if (grep { $_ eq 'afalgeng' } @{$target{enable}}) {
1533         my $minver = 4*10000 + 1*100 + 0;
1534         if ($config{CROSS_COMPILE} eq "") {
1535             my $verstr = `uname -r`;
1536             my ($ma, $mi1, $mi2) = split("\\.", $verstr);
1537             ($mi2) = $mi2 =~ /(\d+)/;
1538             my $ver = $ma*10000 + $mi1*100 + $mi2;
1539             if ($ver < $minver) {
1540                 disable('too-old-kernel', 'afalgeng');
1541             } else {
1542                 push @{$config{engdirs}}, "afalg";
1543             }
1544         } else {
1545             disable('cross-compiling', 'afalgeng');
1546         }
1547     } else {
1548         disable('not-linux', 'afalgeng');
1549     }
1550 }
1551
1552 unless ($disabled{devcryptoeng}) {
1553     if ($target =~ m/^BSD/) {
1554         my $maxver = 5*100 + 7;
1555         my $sysstr = `uname -s`;
1556         my $verstr = `uname -r`;
1557         $sysstr =~ s|\R$||;
1558         $verstr =~ s|\R$||;
1559         my ($ma, $mi, @rest) = split m|\.|, $verstr;
1560         my $ver = $ma*100 + $mi;
1561         if ($sysstr eq 'OpenBSD' && $ver >= $maxver) {
1562             disable('too-new-kernel', 'devcryptoeng');
1563         }
1564     }
1565 }
1566
1567 unless ($disabled{ktls}) {
1568     $config{ktls}="";
1569     if ($target =~ m/^linux/) {
1570         my $usr = "/usr/$config{cross_compile_prefix}";
1571         chop($usr);
1572         if ($config{cross_compile_prefix} eq "") {
1573             $usr = "/usr";
1574         }
1575         my $minver = (4 << 16) + (13 << 8) + 0;
1576         my @verstr = split(" ",`cat $usr/include/linux/version.h | grep LINUX_VERSION_CODE`);
1577
1578         if ($verstr[2] < $minver) {
1579             disable('too-old-kernel', 'ktls');
1580         }
1581     } elsif ($target =~ m/^BSD/) {
1582         my $cc = $config{CROSS_COMPILE}.$config{CC};
1583         system("printf '#include <sys/types.h>\n#include <sys/ktls.h>' | $cc -E - >/dev/null 2>&1");
1584         if ($? != 0) {
1585             disable('too-old-freebsd', 'ktls');
1586         }
1587     } else {
1588         disable('not-linux-or-freebsd', 'ktls');
1589     }
1590 }
1591
1592 push @{$config{openssl_other_defines}}, "OPENSSL_NO_KTLS" if ($disabled{ktls});
1593
1594 # Get the extra flags used when building shared libraries and modules.  We
1595 # do this late because some of them depend on %disabled.
1596
1597 # Make the flags to build DSOs the same as for shared libraries unless they
1598 # are already defined
1599 $target{module_cflags} = $target{shared_cflag} unless defined $target{module_cflags};
1600 $target{module_cxxflags} = $target{shared_cxxflag} unless defined $target{module_cxxflags};
1601 $target{module_ldflags} = $target{shared_ldflag} unless defined $target{module_ldflags};
1602 {
1603     my $shared_info_pl =
1604         catfile(dirname($0), "Configurations", "shared-info.pl");
1605     my %shared_info = read_eval_file($shared_info_pl);
1606     push @{$target{_conf_fname_int}}, $shared_info_pl;
1607     my $si = $target{shared_target};
1608     while (ref $si ne "HASH") {
1609         last if ! defined $si;
1610         if (ref $si eq "CODE") {
1611             $si = $si->();
1612         } else {
1613             $si = $shared_info{$si};
1614         }
1615     }
1616
1617     # Some of the 'shared_target' values don't have any entries in
1618     # %shared_info.  That's perfectly fine, AS LONG AS the build file
1619     # template knows how to handle this.  That is currently the case for
1620     # Windows and VMS.
1621     if (defined $si) {
1622         # Just as above, copy certain shared_* attributes to the corresponding
1623         # module_ attribute unless the latter is already defined
1624         $si->{module_cflags} = $si->{shared_cflag} unless defined $si->{module_cflags};
1625         $si->{module_cxxflags} = $si->{shared_cxxflag} unless defined $si->{module_cxxflags};
1626         $si->{module_ldflags} = $si->{shared_ldflag} unless defined $si->{module_ldflags};
1627         foreach (sort keys %$si) {
1628             $target{$_} = defined $target{$_}
1629                 ? add($si->{$_})->($target{$_})
1630                 : $si->{$_};
1631         }
1632     }
1633 }
1634
1635 # ALL MODIFICATIONS TO %disabled, %config and %target MUST BE DONE FROM HERE ON
1636
1637 ######################################################################
1638 # Build up information for skipping certain directories depending on disabled
1639 # features, as well as setting up macros for disabled features.
1640
1641 # This is a tentative database of directories to skip.  Some entries may not
1642 # correspond to anything real, but that's ok, they will simply be ignored.
1643 # The actual processing of these entries is done in the build.info lookup
1644 # loop further down.
1645 #
1646 # The key is a Unix formatted path in the source tree, the value is an index
1647 # into %disabled_info, so any existing path gets added to a corresponding
1648 # 'skipped' entry in there with the list of skipped directories.
1649 my %skipdir = ();
1650 my %disabled_info = ();         # For configdata.pm
1651 foreach my $what (sort keys %disabled) {
1652     # There are deprecated disablables that translate to themselves.
1653     # They cause disabling cascades, but should otherwise not regiter.
1654     next if $deprecated_disablables{$what};
1655     # The generated $disabled{"deprecated-x.y"} entries are special
1656     # and treated properly elsewhere
1657     next if $what =~ m|^deprecated-|;
1658
1659     $config{options} .= " no-$what";
1660
1661     if (!grep { $what eq $_ } ( 'buildtest-c++', 'fips', 'threads', 'shared',
1662                                 'module', 'pic', 'dynamic-engine', 'makedepend',
1663                                 'zlib-dynamic', 'zlib', 'sse2', 'legacy' )) {
1664         (my $WHAT = uc $what) =~ s|-|_|g;
1665         my $skipdir = $what;
1666
1667         # fix-up crypto/directory name(s)
1668         $skipdir = "ripemd" if $what eq "rmd160";
1669         $skipdir = "whrlpool" if $what eq "whirlpool";
1670
1671         my $macro = $disabled_info{$what}->{macro} = "OPENSSL_NO_$WHAT";
1672         push @{$config{openssl_feature_defines}}, $macro;
1673
1674         $skipdir{engines} = $what if $what eq 'engine';
1675         $skipdir{"crypto/$skipdir"} = $what
1676             unless $what eq 'async' || $what eq 'err' || $what eq 'dso';
1677     }
1678 }
1679
1680 if ($disabled{"dynamic-engine"}) {
1681     push @{$config{openssl_feature_defines}}, "OPENSSL_NO_DYNAMIC_ENGINE";
1682 } else {
1683     push @{$config{openssl_feature_defines}}, "OPENSSL_NO_STATIC_ENGINE";
1684 }
1685
1686 # If we use the unified build, collect information from build.info files
1687 my %unified_info = ();
1688
1689 my $buildinfo_debug = defined($ENV{CONFIGURE_DEBUG_BUILDINFO});
1690 if ($builder eq "unified") {
1691     use Text::Template 1.46;
1692
1693     sub cleandir {
1694         my $base = shift;
1695         my $dir = shift;
1696         my $relativeto = shift || ".";
1697
1698         $dir = catdir($base,$dir) unless isabsolute($dir);
1699
1700         # Make sure the directories we're building in exists
1701         mkpath($dir);
1702
1703         my $res = abs2rel(absolutedir($dir), rel2abs($relativeto));
1704         #print STDERR "DEBUG[cleandir]: $dir , $base => $res\n";
1705         return $res;
1706     }
1707
1708     sub cleanfile {
1709         my $base = shift;
1710         my $file = shift;
1711         my $relativeto = shift || ".";
1712
1713         $file = catfile($base,$file) unless isabsolute($file);
1714
1715         my $d = dirname($file);
1716         my $f = basename($file);
1717
1718         # Make sure the directories we're building in exists
1719         mkpath($d);
1720
1721         my $res = abs2rel(catfile(absolutedir($d), $f), rel2abs($relativeto));
1722         #print STDERR "DEBUG[cleanfile]: $d , $f => $res\n";
1723         return $res;
1724     }
1725
1726     # Store the name of the template file we will build the build file from
1727     # in %config.  This may be useful for the build file itself.
1728     my @build_file_template_names =
1729         ( $builder_platform."-".$target{build_file}.".tmpl",
1730           $target{build_file}.".tmpl" );
1731     my @build_file_templates = ();
1732
1733     # First, look in the user provided directory, if given
1734     if (defined env($local_config_envname)) {
1735         @build_file_templates =
1736             map {
1737                 if ($^O eq 'VMS') {
1738                     # VMS environment variables are logical names,
1739                     # which can be used as is
1740                     $local_config_envname . ':' . $_;
1741                 } else {
1742                     catfile(env($local_config_envname), $_);
1743                 }
1744             }
1745             @build_file_template_names;
1746     }
1747     # Then, look in our standard directory
1748     push @build_file_templates,
1749         ( map { cleanfile($srcdir, catfile("Configurations", $_), $blddir) }
1750           @build_file_template_names );
1751
1752     my $build_file_template;
1753     for $_ (@build_file_templates) {
1754         $build_file_template = $_;
1755         last if -f $build_file_template;
1756
1757         $build_file_template = undef;
1758     }
1759     if (!defined $build_file_template) {
1760         die "*** Couldn't find any of:\n", join("\n", @build_file_templates), "\n";
1761     }
1762     $config{build_file_templates}
1763       = [ cleanfile($srcdir, catfile("Configurations", "common0.tmpl"),
1764                     $blddir),
1765           $build_file_template,
1766           cleanfile($srcdir, catfile("Configurations", "common.tmpl"),
1767                     $blddir) ];
1768
1769     my @build_dirs = ( [ ] );   # current directory
1770
1771     $config{build_infos} = [ ];
1772
1773     my %ordinals = ();
1774     while (@build_dirs) {
1775         my @curd = @{shift @build_dirs};
1776         my $sourced = catdir($srcdir, @curd);
1777         my $buildd = catdir($blddir, @curd);
1778
1779         my $unixdir = join('/', @curd);
1780         if (exists $skipdir{$unixdir}) {
1781             my $what = $skipdir{$unixdir};
1782             push @{$disabled_info{$what}->{skipped}}, catdir(@curd);
1783             next;
1784         }
1785
1786         mkpath($buildd);
1787
1788         my $f = 'build.info';
1789         # The basic things we're trying to build
1790         my @programs = ();
1791         my @libraries = ();
1792         my @modules = ();
1793         my @scripts = ();
1794
1795         my %sources = ();
1796         my %shared_sources = ();
1797         my %includes = ();
1798         my %defines = ();
1799         my %depends = ();
1800         my %generate = ();
1801         my %htmldocs = ();
1802         my %mandocs = ();
1803
1804         # Support for $variablename in build.info files.
1805         # Embedded perl code is the ultimate master, still.  If its output
1806         # contains a dollar sign, it had better be escaped, or it will be
1807         # taken for a variable name prefix.
1808         my %variables = ();
1809         my $variable_re = qr/\$(?P<VARIABLE>[[:alpha:]][[:alnum:]_]*)/;
1810         my $expand_variables = sub {
1811             my $value = '';
1812             my $value_rest = shift;
1813
1814             if ($ENV{CONFIGURE_DEBUG_VARIABLE_EXPAND}) {
1815                 print STDERR
1816                     "DEBUG[\$expand_variables] Parsed '$value_rest' into:\n"
1817             }
1818             while ($value_rest =~ /(?<!\\)${variable_re}/) {
1819                 $value .= $`;
1820                 $value .= $variables{$+{VARIABLE}};
1821                 $value_rest = $';
1822             }
1823             if ($ENV{CONFIGURE_DEBUG_VARIABLE_EXPAND}) {
1824                 print STDERR
1825                     "DEBUG[\$expand_variables] ... '$value$value_rest'\n";
1826             }
1827             return $value . $value_rest;
1828         };
1829
1830         # Support for attributes in build.info files
1831         my %attributes = ();
1832         my $handle_attributes = sub {
1833             my $attr_str = shift;
1834             my $ref = shift;
1835             my @goals = @_;
1836
1837             return unless defined $attr_str;
1838
1839             my @a = tokenize($attr_str, qr|\s*,\s*|);
1840             foreach my $a (@a) {
1841                 my $ac = 1;
1842                 my $ak = $a;
1843                 my $av = 1;
1844                 if ($a =~ m|^(!)?(.*?)\s* = \s*(.*?)$|) {
1845                     $ac = ! $1;
1846                     $ak = $1;
1847                     $av = $2;
1848                 }
1849                 foreach my $g (@goals) {
1850                     if ($ac) {
1851                         $$ref->{$g}->{$ak} = $av;
1852                     } else {
1853                         delete $$ref->{$g}->{$ak};
1854                     }
1855                 }
1856             }
1857         };
1858
1859         # We want to detect configdata.pm in the source tree, so we
1860         # don't use it if the build tree is different.
1861         my $src_configdata = cleanfile($srcdir, "configdata.pm", $blddir);
1862
1863
1864         if ($buildinfo_debug) {
1865             print STDERR "DEBUG: Reading ",catfile($sourced, $f),"\n";
1866         }
1867         push @{$config{build_infos}}, catfile(abs2rel($sourced, $blddir), $f);
1868         my $template =
1869             Text::Template->new(TYPE => 'FILE',
1870                                 SOURCE => catfile($sourced, $f),
1871                                 PREPEND => qq{use lib "$FindBin::Bin/util/perl";});
1872         die "Something went wrong with $sourced/$f: $!\n" unless $template;
1873         my @text =
1874             split /^/m,
1875             $template->fill_in(HASH => { config => \%config,
1876                                          target => \%target,
1877                                          disabled => \%disabled,
1878                                          withargs => \%withargs,
1879                                          builddir => abs2rel($buildd, $blddir),
1880                                          sourcedir => abs2rel($sourced, $blddir),
1881                                          buildtop => abs2rel($blddir, $blddir),
1882                                          sourcetop => abs2rel($srcdir, $blddir) },
1883                                DELIMITERS => [ "{-", "-}" ]);
1884
1885         # The top item of this stack has the following values
1886         # -2 positive already run and we found ELSE (following ELSIF should fail)
1887         # -1 positive already run (skip until ENDIF)
1888         # 0 negatives so far (if we're at a condition, check it)
1889         # 1 last was positive (don't skip lines until next ELSE, ELSIF or ENDIF)
1890         # 2 positive ELSE (following ELSIF should fail)
1891         my @skip = ();
1892
1893         # A few useful generic regexps
1894         my $index_re = qr/\[\s*(?P<INDEX>(?:\\.|.)*?)\s*\]/;
1895         my $cond_re = qr/\[\s*(?P<COND>(?:\\.|.)*?)\s*\]/;
1896         my $attribs_re = qr/(?:\{\s*(?P<ATTRIBS>(?:\\.|.)*?)\s*\})?/;
1897         my $value_re = qr/\s*(?P<VALUE>.*?)\s*/;
1898         collect_information(
1899             collect_from_array([ @text ],
1900                                qr/\\$/ => sub { my $l1 = shift; my $l2 = shift;
1901                                                 $l1 =~ s/\\$//; $l1.$l2 }),
1902             # Info we're looking for
1903             qr/^\s* IF ${cond_re} \s*$/x
1904             => sub {
1905                 if (! @skip || $skip[$#skip] > 0) {
1906                     push @skip, !! $expand_variables->($+{COND});
1907                 } else {
1908                     push @skip, -1;
1909                 }
1910             },
1911             qr/^\s* ELSIF ${cond_re} \s*$/x
1912             => sub { die "ELSIF out of scope" if ! @skip;
1913                      die "ELSIF following ELSE" if abs($skip[$#skip]) == 2;
1914                      $skip[$#skip] = -1 if $skip[$#skip] != 0;
1915                      $skip[$#skip] = !! $expand_variables->($+{COND})
1916                          if $skip[$#skip] == 0; },
1917             qr/^\s* ELSE \s*$/x
1918             => sub { die "ELSE out of scope" if ! @skip;
1919                      $skip[$#skip] = -2 if $skip[$#skip] != 0;
1920                      $skip[$#skip] = 2 if $skip[$#skip] == 0; },
1921             qr/^\s* ENDIF \s*$/x
1922             => sub { die "ENDIF out of scope" if ! @skip;
1923                      pop @skip; },
1924             qr/^\s* ${variable_re} \s* = ${value_re} $/x
1925             => sub {
1926                 if (!@skip || $skip[$#skip] > 0) {
1927                     $variables{$+{VARIABLE}} = $expand_variables->($+{VALUE});
1928                 }
1929             },
1930             qr/^\s* SUBDIRS \s* = ${value_re} $/x
1931             => sub {
1932                 if (!@skip || $skip[$#skip] > 0) {
1933                     foreach (tokenize($expand_variables->($+{VALUE}))) {
1934                         push @build_dirs, [ @curd, splitdir($_, 1) ];
1935                     }
1936                 }
1937             },
1938             qr/^\s* PROGRAMS ${attribs_re} \s* =  ${value_re} $/x
1939             => sub {
1940                 if (!@skip || $skip[$#skip] > 0) {
1941                     my @p = tokenize($expand_variables->($+{VALUE}));
1942                     push @programs, @p;
1943                     $handle_attributes->($+{ATTRIBS},
1944                                          \$attributes{programs},
1945                                          @p);
1946                 }
1947             },
1948             qr/^\s* LIBS ${attribs_re} \s* =  ${value_re} $/x
1949             => sub {
1950                 if (!@skip || $skip[$#skip] > 0) {
1951                     my @l = tokenize($expand_variables->($+{VALUE}));
1952                     push @libraries, @l;
1953                     $handle_attributes->($+{ATTRIBS},
1954                                          \$attributes{libraries},
1955                                          @l);
1956                 }
1957             },
1958             qr/^\s* MODULES ${attribs_re} \s* =  ${value_re} $/x
1959             => sub {
1960                 if (!@skip || $skip[$#skip] > 0) {
1961                     my @m = tokenize($expand_variables->($+{VALUE}));
1962                     push @modules, @m;
1963                     $handle_attributes->($+{ATTRIBS},
1964                                          \$attributes{modules},
1965                                          @m);
1966                 }
1967             },
1968             qr/^\s* SCRIPTS ${attribs_re} \s* =  ${value_re} $/x
1969             => sub {
1970                 if (!@skip || $skip[$#skip] > 0) {
1971                     my @s = tokenize($expand_variables->($+{VALUE}));
1972                     push @scripts, @s;
1973                     $handle_attributes->($+{ATTRIBS},
1974                                          \$attributes{scripts},
1975                                          @s);
1976                 }
1977             },
1978             qr/^\s* HTMLDOCS ${index_re} = ${value_re} $/x
1979             => sub { push @{$htmldocs{$expand_variables->($+{INDEX})}},
1980                          tokenize($expand_variables->($+{VALUE}))
1981                          if !@skip || $skip[$#skip] > 0 },
1982             qr/^\s* MANDOCS ${index_re} = ${value_re} $/x
1983             => sub { push @{$mandocs{$expand_variables->($+{INDEX})}},
1984                          tokenize($expand_variables->($+{VALUE}))
1985                          if !@skip || $skip[$#skip] > 0 },
1986             qr/^\s* ORDINALS ${index_re} = ${value_re} $/x
1987             => sub { push @{$ordinals{$expand_variables->($+{INDEX})}},
1988                          tokenize($expand_variables->($+{VALUE}))
1989                          if !@skip || $skip[$#skip] > 0 },
1990             qr/^\s* SOURCE ${index_re} = ${value_re} $/x
1991             => sub { push @{$sources{$expand_variables->($+{INDEX})}},
1992                          tokenize($expand_variables->($+{VALUE}))
1993                          if !@skip || $skip[$#skip] > 0 },
1994             qr/^\s* SHARED_SOURCE ${index_re} = ${value_re} $/x
1995             => sub { push @{$shared_sources{$expand_variables->($+{INDEX})}},
1996                          tokenize($expand_variables->($+{VALUE}))
1997                          if !@skip || $skip[$#skip] > 0 },
1998             qr/^\s* INCLUDE ${index_re} = ${value_re} $/x
1999             => sub { push @{$includes{$expand_variables->($+{INDEX})}},
2000                          tokenize($expand_variables->($+{VALUE}))
2001                          if !@skip || $skip[$#skip] > 0 },
2002             qr/^\s* DEFINE ${index_re} = ${value_re} $/x
2003             => sub { push @{$defines{$expand_variables->($+{INDEX})}},
2004                          tokenize($expand_variables->($+{VALUE}))
2005                          if !@skip || $skip[$#skip] > 0 },
2006             qr/^\s* DEPEND ${index_re} ${attribs_re} = ${value_re} $/x
2007             => sub {
2008                 if (!@skip || $skip[$#skip] > 0) {
2009                     my $i = $expand_variables->($+{INDEX});
2010                     my @d = tokenize($expand_variables->($+{VALUE}));
2011                     push @{$depends{$i}}, @d;
2012                     $handle_attributes->($+{ATTRIBS},
2013                                          \$attributes{depends}->{$i},
2014                                          @d);
2015                 }
2016             },
2017             qr/^\s* GENERATE ${index_re} = ${value_re} $/x
2018             => sub { push @{$generate{$expand_variables->($+{INDEX})}},
2019                          $+{VALUE}
2020                          if !@skip || $skip[$#skip] > 0 },
2021             qr/^\s* (?:\#.*)? $/x => sub { },
2022             "OTHERWISE" => sub { die "Something wrong with this line:\n$_\nat $sourced/$f" },
2023             "BEFORE" => sub {
2024                 if ($buildinfo_debug) {
2025                     print STDERR "DEBUG: Parsing ",join(" ", @_),"\n";
2026                     print STDERR "DEBUG: ... before parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
2027                 }
2028             },
2029             "AFTER" => sub {
2030                 if ($buildinfo_debug) {
2031                     print STDERR "DEBUG: .... after parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
2032                 }
2033             },
2034             );
2035         die "runaway IF?" if (@skip);
2036
2037         if (grep { defined $attributes{modules}->{$_}->{engine} } keys %attributes
2038                 and !$config{dynamic_engines}) {
2039             die <<"EOF"
2040 ENGINES can only be used if configured with 'dynamic-engine'.
2041 This is usually a fault in a build.info file.
2042 EOF
2043         }
2044
2045         {
2046             my %infos = ( programs  => [ @programs  ],
2047                           libraries => [ @libraries ],
2048                           modules   => [ @modules   ],
2049                           scripts   => [ @scripts   ] );
2050             foreach my $k (keys %infos) {
2051                 foreach (@{$infos{$k}}) {
2052                     my $item = cleanfile($buildd, $_, $blddir);
2053                     $unified_info{$k}->{$item} = 1;
2054
2055                     # Fix up associated attributes
2056                     $unified_info{attributes}->{$k}->{$item} =
2057                         $attributes{$k}->{$_}
2058                         if defined $attributes{$k}->{$_};
2059                 }
2060             }
2061         }
2062
2063         # Check that we haven't defined any library as both shared and
2064         # explicitly static.  That is forbidden.
2065         my @doubles = ();
2066         foreach (grep /\.a$/, keys %{$unified_info{libraries}}) {
2067             (my $l = $_) =~ s/\.a$//;
2068             push @doubles, $l if defined $unified_info{libraries}->{$l};
2069         }
2070         die "these libraries are both explicitly static and shared:\n  ",
2071             join(" ", @doubles), "\n"
2072             if @doubles;
2073
2074         foreach (keys %sources) {
2075             my $dest = $_;
2076             my $ddest = cleanfile($buildd, $_, $blddir);
2077             foreach (@{$sources{$dest}}) {
2078                 my $s = cleanfile($sourced, $_, $blddir);
2079
2080                 # If it isn't in the source tree, we assume it's generated
2081                 # in the build tree
2082                 if ($s eq $src_configdata || ! -f $s || $generate{$_}) {
2083                     $s = cleanfile($buildd, $_, $blddir);
2084                 }
2085                 # We recognise C++, C and asm files
2086                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
2087                     my $o = $_;
2088                     $o =~ s/\.[csS]$/.o/; # C and assembler
2089                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
2090                     $o = cleanfile($buildd, $o, $blddir);
2091                     $unified_info{sources}->{$ddest}->{$o} = -1;
2092                     $unified_info{sources}->{$o}->{$s} = -1;
2093                 } elsif ($s =~ /\.rc$/) {
2094                     # We also recognise resource files
2095                     my $o = $_;
2096                     $o =~ s/\.rc$/.res/; # Resource configuration
2097                     my $o = cleanfile($buildd, $o, $blddir);
2098                     $unified_info{sources}->{$ddest}->{$o} = -1;
2099                     $unified_info{sources}->{$o}->{$s} = -1;
2100                 } else {
2101                     $unified_info{sources}->{$ddest}->{$s} = 1;
2102                 }
2103             }
2104         }
2105
2106         foreach (keys %shared_sources) {
2107             my $dest = $_;
2108             my $ddest = cleanfile($buildd, $_, $blddir);
2109             foreach (@{$shared_sources{$dest}}) {
2110                 my $s = cleanfile($sourced, $_, $blddir);
2111
2112                 # If it isn't in the source tree, we assume it's generated
2113                 # in the build tree
2114                 if ($s eq $src_configdata || ! -f $s || $generate{$_}) {
2115                     $s = cleanfile($buildd, $_, $blddir);
2116                 }
2117
2118                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
2119                     # We recognise C++, C and asm files
2120                     my $o = $_;
2121                     $o =~ s/\.[csS]$/.o/; # C and assembler
2122                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
2123                     $o = cleanfile($buildd, $o, $blddir);
2124                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2125                     $unified_info{sources}->{$o}->{$s} = -1;
2126                 } elsif ($s =~ /\.rc$/) {
2127                     # We also recognise resource files
2128                     my $o = $_;
2129                     $o =~ s/\.rc$/.res/; # Resource configuration
2130                     my $o = cleanfile($buildd, $o, $blddir);
2131                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2132                     $unified_info{sources}->{$o}->{$s} = -1;
2133                 } elsif ($s =~ /\.ld$/) {
2134                     # We also recognise linker scripts (or corresponding)
2135                     # We know they are generated files
2136                     my $ld = cleanfile($buildd, $_, $blddir);
2137                     $unified_info{shared_sources}->{$ddest}->{$ld} = 1;
2138                 } else {
2139                     die "unrecognised source file type for shared library: $s\n";
2140                 }
2141             }
2142         }
2143
2144         foreach (keys %generate) {
2145             my $dest = $_;
2146             my $ddest = cleanfile($buildd, $_, $blddir);
2147             die "more than one generator for $dest: "
2148                 ,join(" ", @{$generate{$_}}),"\n"
2149                 if scalar @{$generate{$_}} > 1;
2150             my @generator = split /\s+/, $generate{$dest}->[0];
2151             my $gen = $generator[0];
2152             $generator[0] = cleanfile($sourced, $gen, $blddir);
2153
2154             # If the generator isn't in the source tree, we assume it's
2155             # generated in the build tree
2156             if ($generate{$gen}) {
2157                 $generator[0] = cleanfile($buildd, $gen, $blddir);
2158             }
2159
2160             $unified_info{generate}->{$ddest} = [ @generator ];
2161         }
2162
2163         foreach (keys %depends) {
2164             my $dest = $_;
2165             my $ddest = $dest eq "" ? "" : cleanfile($sourced, $_, $blddir);
2166
2167             # If the destination doesn't exist in source, it can only be
2168             # a generated file in the build tree.
2169             if ($ddest ne "" && ($ddest eq $src_configdata || ! -f $ddest)) {
2170                 $ddest = cleanfile($buildd, $_, $blddir);
2171             }
2172             foreach (@{$depends{$dest}}) {
2173                 my $d = cleanfile($sourced, $_, $blddir);
2174
2175                 # If we know it's generated, or assume it is because we can't
2176                 # find it in the source tree, we set file we depend on to be
2177                 # in the build tree rather than the source tree, and assume
2178                 # and that there are lines to build it in a BEGINRAW..ENDRAW
2179                 # section or in the Makefile template.
2180                 if ($d eq $src_configdata
2181                     || ! -f $d
2182                     || (grep { $d eq $_ }
2183                         map { cleanfile($srcdir, $_, $blddir) }
2184                         grep { /\.h$/ } keys %{$unified_info{generate}})) {
2185                     $d = cleanfile($buildd, $_, $blddir);
2186                 }
2187                 # Take note if the file to depend on is being renamed
2188                 # Take extra care with files ending with .a, they should
2189                 # be treated without that extension, and the extension
2190                 # should be added back after treatment.
2191                 $d =~ /(\.a)?$/;
2192                 my $e = $1 // "";
2193                 $d = $`.$e;
2194                 $unified_info{depends}->{$ddest}->{$d} = 1;
2195
2196                 # Fix up associated attributes
2197                 $unified_info{attributes}->{depends}->{$ddest}->{$d} =
2198                     $attributes{depends}->{$dest}->{$_}
2199                     if defined $attributes{depends}->{$dest}->{$_};
2200             }
2201         }
2202
2203         foreach (keys %includes) {
2204             my $dest = $_;
2205             my $ddest = cleanfile($sourced, $_, $blddir);
2206
2207             # If the destination doesn't exist in source, it can only be
2208             # a generated file in the build tree.
2209             if ($ddest eq $src_configdata || ! -f $ddest) {
2210                 $ddest = cleanfile($buildd, $_, $blddir);
2211             }
2212             foreach (@{$includes{$dest}}) {
2213                 my $is = cleandir($sourced, $_, $blddir);
2214                 my $ib = cleandir($buildd, $_, $blddir);
2215                 push @{$unified_info{includes}->{$ddest}->{source}}, $is
2216                     unless grep { $_ eq $is } @{$unified_info{includes}->{$ddest}->{source}};
2217                 push @{$unified_info{includes}->{$ddest}->{build}}, $ib
2218                     unless grep { $_ eq $ib } @{$unified_info{includes}->{$ddest}->{build}};
2219             }
2220         }
2221
2222         foreach my $dest (keys %defines) {
2223             my $ddest;
2224
2225             if ($dest ne "") {
2226                 $ddest = cleanfile($sourced, $dest, $blddir);
2227
2228                 # If the destination doesn't exist in source, it can only
2229                 # be a generated file in the build tree.
2230                 if (! -f $ddest) {
2231                     $ddest = cleanfile($buildd, $dest, $blddir);
2232                     if ($unified_info{rename}->{$ddest}) {
2233                         $ddest = $unified_info{rename}->{$ddest};
2234                     }
2235                 }
2236             }
2237             foreach my $v (@{$defines{$dest}}) {
2238                 $v =~ m|^([^=]*)(=.*)?$|;
2239                 die "0 length macro name not permitted\n" if $1 eq "";
2240                 if ($dest ne "") {
2241                     die "$1 defined more than once\n"
2242                         if defined $unified_info{defines}->{$ddest}->{$1};
2243                     $unified_info{defines}->{$ddest}->{$1} = $2;
2244                 } else {
2245                     die "$1 defined more than once\n"
2246                         if grep { $v eq $_ } @{$config{defines}};
2247                     push @{$config{defines}}, $v;
2248                 }
2249             }
2250         }
2251
2252         foreach my $section (keys %htmldocs) {
2253             foreach (@{$htmldocs{$section}}) {
2254                 my $htmldocs = cleanfile($buildd, $_, $blddir);
2255                 $unified_info{htmldocs}->{$section}->{$htmldocs} = 1;
2256             }
2257         }
2258
2259         foreach my $section (keys %mandocs) {
2260             foreach (@{$mandocs{$section}}) {
2261                 my $mandocs = cleanfile($buildd, $_, $blddir);
2262                 $unified_info{mandocs}->{$section}->{$mandocs} = 1;
2263             }
2264         }
2265     }
2266
2267     my $ordinals_text = join(', ', sort keys %ordinals);
2268     warn <<"EOF" if $ordinals_text;
2269
2270 WARNING: ORDINALS were specified for $ordinals_text
2271 They are ignored and should be replaced with a combination of GENERATE,
2272 DEPEND and SHARED_SOURCE.
2273 EOF
2274
2275
2276     # Go through the sources of all libraries and check that the same basename
2277     # doesn't appear more than once.  Some static library archivers depend on
2278     # them being unique.
2279     {
2280         my $err = 0;
2281         foreach my $prod (keys %{$unified_info{libraries}}) {
2282             my @prod_sources =
2283                 map { keys %{$unified_info{sources}->{$_}} }
2284                 keys %{$unified_info{sources}->{$prod}};
2285             my %srccnt = ();
2286
2287             # Count how many times a given each source basename
2288             # appears for each product.
2289             foreach my $src (@prod_sources) {
2290                 $srccnt{basename $src}++;
2291             }
2292
2293             foreach my $src (keys %srccnt) {
2294                 if ((my $cnt = $srccnt{$src}) > 1) {
2295                     print STDERR "$src appears $cnt times for the product $prod\n";
2296                     $err++
2297                 }
2298             }
2299         }
2300         die if $err > 0;
2301     }
2302
2303     # Massage the result
2304
2305     # If we depend on a header file or a perl module, add an inclusion of
2306     # its directory to allow smoothe inclusion
2307     foreach my $dest (keys %{$unified_info{depends}}) {
2308         next if $dest eq "";
2309         foreach my $d (keys %{$unified_info{depends}->{$dest}}) {
2310             next unless $d =~ /\.(h|pm)$/;
2311             my $i = dirname($d);
2312             my $spot =
2313                 $d eq "configdata.pm" || defined($unified_info{generate}->{$d})
2314                 ? 'build' : 'source';
2315             push @{$unified_info{includes}->{$dest}->{$spot}}, $i
2316                 unless grep { $_ eq $i } @{$unified_info{includes}->{$dest}->{$spot}};
2317         }
2318     }
2319
2320     # Go through all intermediary files and change their names to something that
2321     # reflects what they will be built for.  Note that for some source files,
2322     # this leads to duplicate object files because they are used multiple times.
2323     # the goal is to rename all object files according to this scheme:
2324     #    {productname}-{midfix}-{origobjname}.[o|res]
2325     # the {midfix} is a keyword indicating the type of product, which is mostly
2326     # valuable for libraries since they come in two forms.
2327     #
2328     # This also reorganises the {sources} and {shared_sources} so that the
2329     # former only contains ALL object files that are supposed to end up in
2330     # static libraries and programs, while the latter contains ALL object files
2331     # that are supposed to end up in shared libraries and DSOs.
2332     # The main reason for having two different source structures is to allow
2333     # the same name to be used for the static and the shared variants of a
2334     # library.
2335     {
2336         # Take copies so we don't get interference from added stuff
2337         my %unified_copy = ();
2338         foreach (('sources', 'shared_sources')) {
2339             $unified_copy{$_} = { %{$unified_info{$_}} }
2340                 if defined($unified_info{$_});
2341             delete $unified_info{$_};
2342         }
2343         foreach my $prodtype (('programs', 'libraries', 'modules', 'scripts')) {
2344             # $intent serves multi purposes:
2345             # - give a prefix for the new object files names
2346             # - in the case of libraries, rearrange the object files so static
2347             #   libraries use the 'sources' structure exclusively, while shared
2348             #   libraries use the 'shared_sources' structure exclusively.
2349             my $intent = {
2350                 programs  => { bin    => { src => [ 'sources' ],
2351                                            dst => 'sources' } },
2352                 libraries => { lib    => { src => [ 'sources' ],
2353                                            dst => 'sources' },
2354                                shlib  => { prodselect =>
2355                                                sub { grep !/\.a$/, @_ },
2356                                            src => [ 'sources',
2357                                                     'shared_sources' ],
2358                                            dst => 'shared_sources' } },
2359                 modules   => { dso    => { src => [ 'sources' ],
2360                                            dst => 'sources' } },
2361                 scripts   => { script => { src => [ 'sources' ],
2362                                            dst => 'sources' } }
2363                } -> {$prodtype};
2364             foreach my $kind (keys %$intent) {
2365                 next if ($intent->{$kind}->{dst} eq 'shared_sources'
2366                              && $disabled{shared});
2367
2368                 my @src = @{$intent->{$kind}->{src}};
2369                 my $dst = $intent->{$kind}->{dst};
2370                 my $prodselect = $intent->{$kind}->{prodselect} // sub { @_ };
2371                 foreach my $prod ($prodselect->(keys %{$unified_info{$prodtype}})) {
2372                     # %prod_sources has all applicable objects as keys, and
2373                     # their corresponding sources as values
2374                     my %prod_sources =
2375                         map { $_ => [ keys %{$unified_copy{sources}->{$_}} ] }
2376                         map { keys %{$unified_copy{$_}->{$prod}} }
2377                         @src;
2378                     foreach (keys %prod_sources) {
2379                         # Only affect object files and resource files,
2380                         # the others simply get a new value
2381                         # (+1 instead of -1)
2382                         if ($_ =~ /\.(o|res)$/) {
2383                             (my $prodname = $prod) =~ s|\.a$||;
2384                             my $newobj =
2385                                 catfile(dirname($_),
2386                                         basename($prodname)
2387                                             . '-' . $kind
2388                                             . '-' . basename($_));
2389                             $unified_info{$dst}->{$prod}->{$newobj} = 1;
2390                             foreach my $src (@{$prod_sources{$_}}) {
2391                                 $unified_info{sources}->{$newobj}->{$src} = 1;
2392                             }
2393                             # Adjust dependencies
2394                             foreach my $deps (keys %{$unified_info{depends}->{$_}}) {
2395                                 $unified_info{depends}->{$_}->{$deps} = -1;
2396                                 $unified_info{depends}->{$newobj}->{$deps} = 1;
2397                             }
2398                             # Adjust includes
2399                             foreach my $k (('source', 'build')) {
2400                                 next unless
2401                                     defined($unified_info{includes}->{$_}->{$k});
2402                                 my @incs = @{$unified_info{includes}->{$_}->{$k}};
2403                                 $unified_info{includes}->{$newobj}->{$k} = [ @incs ];
2404                             }
2405                         } else {
2406                             $unified_info{$dst}->{$prod}->{$_} = 1;
2407                         }
2408                     }
2409                 }
2410             }
2411         }
2412     }
2413
2414     # At this point, we have a number of sources with the value -1.  They
2415     # aren't part of the local build and are probably meant for a different
2416     # platform, and can therefore be cleaned away.  That happens when making
2417     # %unified_info more efficient below.
2418
2419     ### Make unified_info a bit more efficient
2420     # One level structures
2421     foreach (("programs", "libraries", "modules", "scripts")) {
2422         $unified_info{$_} = [ sort keys %{$unified_info{$_}} ];
2423     }
2424     # Two level structures
2425     foreach my $l1 (("sources", "shared_sources", "ldadd", "depends",
2426                      "htmldocs", "mandocs")) {
2427         foreach my $l2 (sort keys %{$unified_info{$l1}}) {
2428             my @items =
2429                 sort
2430                 grep { $unified_info{$l1}->{$l2}->{$_} > 0 }
2431                 keys %{$unified_info{$l1}->{$l2}};
2432             if (@items) {
2433                 $unified_info{$l1}->{$l2} = [ @items ];
2434             } else {
2435                 delete $unified_info{$l1}->{$l2};
2436             }
2437         }
2438     }
2439     # Defines
2440     foreach my $dest (sort keys %{$unified_info{defines}}) {
2441         $unified_info{defines}->{$dest}
2442             = [ map { $_.$unified_info{defines}->{$dest}->{$_} }
2443                 sort keys %{$unified_info{defines}->{$dest}} ];
2444     }
2445     # Includes
2446     foreach my $dest (sort keys %{$unified_info{includes}}) {
2447         if (defined($unified_info{includes}->{$dest}->{build})) {
2448             my @source_includes = ();
2449             @source_includes = ( @{$unified_info{includes}->{$dest}->{source}} )
2450                 if defined($unified_info{includes}->{$dest}->{source});
2451             $unified_info{includes}->{$dest} =
2452                 [ @{$unified_info{includes}->{$dest}->{build}} ];
2453             foreach my $inc (@source_includes) {
2454                 push @{$unified_info{includes}->{$dest}}, $inc
2455                     unless grep { $_ eq $inc } @{$unified_info{includes}->{$dest}};
2456             }
2457         } elsif (defined($unified_info{includes}->{$dest}->{source})) {
2458             $unified_info{includes}->{$dest} =
2459                 [ @{$unified_info{includes}->{$dest}->{source}} ];
2460         } else {
2461             delete $unified_info{includes}->{$dest};
2462         }
2463     }
2464
2465     # For convenience collect information regarding directories where
2466     # files are generated, those generated files and the end product
2467     # they end up in where applicable.  Then, add build rules for those
2468     # directories
2469     my %loopinfo = ( "lib" => [ @{$unified_info{libraries}} ],
2470                      "dso" => [ @{$unified_info{modules}} ],
2471                      "bin" => [ @{$unified_info{programs}} ],
2472                      "script" => [ @{$unified_info{scripts}} ],
2473                      "docs" => [ (map { @{$unified_info{htmldocs}->{$_} // []} }
2474                                   keys %{$unified_info{htmldocs} // {}}),
2475                                  (map { @{$unified_info{mandocs}->{$_} // []} }
2476                                   keys %{$unified_info{mandocs} // {}}) ] );
2477     foreach my $type (keys %loopinfo) {
2478         foreach my $product (@{$loopinfo{$type}}) {
2479             my %dirs = ();
2480             my $pd = dirname($product);
2481
2482             foreach (@{$unified_info{sources}->{$product} // []},
2483                      @{$unified_info{shared_sources}->{$product} // []}) {
2484                 my $d = dirname($_);
2485
2486                 # We don't want to create targets for source directories
2487                 # when building out of source
2488                 next if ($config{sourcedir} ne $config{builddir}
2489                              && $d =~ m|^\Q$config{sourcedir}\E|);
2490                 # We already have a "test" target, and the current directory
2491                 # is just silly to make a target for
2492                 next if $d eq "test" || $d eq ".";
2493
2494                 $dirs{$d} = 1;
2495                 push @{$unified_info{dirinfo}->{$d}->{deps}}, $_
2496                     if $d ne $pd;
2497             }
2498             foreach (keys %dirs) {
2499                 push @{$unified_info{dirinfo}->{$_}->{products}->{$type}},
2500                     $product;
2501             }
2502         }
2503     }
2504 }
2505
2506 # For the schemes that need it, we provide the old *_obj configs
2507 # from the *_asm_obj ones
2508 foreach (grep /_(asm|aux)_src$/, keys %target) {
2509     my $src = $_;
2510     (my $obj = $_) =~ s/_(asm|aux)_src$/_obj/;
2511     $target{$obj} = $target{$src};
2512     $target{$obj} =~ s/\.[csS]\b/.o/g; # C and assembler
2513     $target{$obj} =~ s/\.(cc|cpp)\b/_cc.o/g; # C++
2514 }
2515
2516 # Write down our configuration where it fits #########################
2517
2518 my %template_vars = (
2519     config => \%config,
2520     target => \%target,
2521     disablables => \@disablables,
2522     disablables_int => \@disablables_int,
2523     disabled => \%disabled,
2524     withargs => \%withargs,
2525     unified_info => \%unified_info,
2526     tls => \@tls,
2527     dtls => \@dtls,
2528     makevars => [ sort keys %user ],
2529     disabled_info => \%disabled_info,
2530     user_crossable => \@user_crossable,
2531 );
2532 my $configdata_outname = 'configdata.pm';
2533 print "Creating $configdata_outname\n";
2534 open CONFIGDATA, ">$configdata_outname.new"
2535             or die "Trying to create $configdata_outname.new: $!";
2536 my $configdata_tmplname = cleanfile($srcdir, "configdata.pm.in", $blddir);
2537 my $configdata_tmpl =
2538     OpenSSL::Template->new(TYPE => 'FILE', SOURCE => $configdata_tmplname);
2539 $configdata_tmpl->fill_in(
2540     FILENAME => $configdata_tmplname,
2541     OUTPUT => \*CONFIGDATA,
2542     HASH => { %template_vars,
2543               autowarntext => [
2544                   'WARNING: do not edit!',
2545                   "Generated by Configure from $configdata_tmplname",
2546               ] }
2547 ) or die $Text::Template::ERROR;
2548 close CONFIGDATA;
2549 rename "$configdata_outname.new", $configdata_outname;
2550 if ($builder_platform eq 'unix') {
2551     my $mode = (0755 & ~umask);
2552     chmod $mode, 'configdata.pm'
2553         or warn sprintf("WARNING: Couldn't change mode for 'configdata.pm' to 0%03o: %s\n",$mode,$!);
2554 }
2555
2556 print "Running $configdata_outname\n";
2557 my $perlcmd = (quotify("maybeshell", $config{PERL}))[0];
2558 my $cmd = "$perlcmd $configdata_outname";
2559 #print STDERR "DEBUG[run_dofile]: \$cmd = $cmd\n";
2560 system($cmd);
2561 exit 1 if $? != 0;
2562
2563 $SIG{__DIE__} = $orig_death_handler;
2564
2565 print <<"EOF" if ($disabled{threads} eq "unavailable");
2566
2567 The library could not be configured for supporting multi-threaded
2568 applications as the compiler options required on this system are not known.
2569 See file INSTALL for details if you need multi-threading.
2570 EOF
2571
2572 print <<"EOF" if ($no_shared_warn);
2573
2574 The options 'shared', 'pic' and 'dynamic-engine' aren't supported on this
2575 platform, so we will pretend you gave the option 'no-pic', which also disables
2576 'shared' and 'dynamic-engine'.  If you know how to implement shared libraries
2577 or position independent code, please let us know (but please first make sure
2578 you have tried with a current version of OpenSSL).
2579 EOF
2580
2581 print <<"EOF";
2582
2583 **********************************************************************
2584 ***                                                                ***
2585 ***   OpenSSL has been successfully configured                     ***
2586 ***                                                                ***
2587 ***   If you encounter a problem while building, please open an    ***
2588 ***   issue on GitHub <https://github.com/openssl/openssl/issues>  ***
2589 ***   and include the output from the following command:           ***
2590 ***                                                                ***
2591 ***       perl configdata.pm --dump                                ***
2592 ***                                                                ***
2593 ***   (If you are new to OpenSSL, you might want to consult the    ***
2594 ***   'Troubleshooting' section in the INSTALL file first)         ***
2595 ***                                                                ***
2596 **********************************************************************
2597 EOF
2598
2599 exit(0);
2600
2601 ######################################################################
2602 #
2603 # Helpers and utility functions
2604 #
2605
2606 # Death handler, to print a helpful message in case of failure #######
2607 #
2608 sub death_handler {
2609     die @_ if $^S;              # To prevent the added message in eval blocks
2610     my $build_file = $target{build_file} // "build file";
2611     my @message = ( <<"_____", @_ );
2612
2613 Failure!  $build_file wasn't produced.
2614 Please read INSTALL and associated NOTES files.  You may also have to look over
2615 your available compiler tool chain or change your configuration.
2616
2617 _____
2618
2619     # Dying is terminal, so it's ok to reset the signal handler here.
2620     $SIG{__DIE__} = $orig_death_handler;
2621     die @message;
2622 }
2623
2624 # Configuration file reading #########################################
2625
2626 # Note: All of the helper functions are for lazy evaluation.  They all
2627 # return a CODE ref, which will return the intended value when evaluated.
2628 # Thus, whenever there's mention of a returned value, it's about that
2629 # intended value.
2630
2631 # Helper function to implement conditional value variants, with a default
2632 # plus additional values based on the value of $config{build_type}.
2633 # Arguments are given in hash table form:
2634 #
2635 #       picker(default => "Basic string: ",
2636 #              debug   => "debug",
2637 #              release => "release")
2638 #
2639 # When configuring with --debug, the resulting string will be
2640 # "Basic string: debug", and when not, it will be "Basic string: release"
2641 #
2642 # This can be used to create variants of sets of flags according to the
2643 # build type:
2644 #
2645 #       cflags => picker(default => "-Wall",
2646 #                        debug   => "-g -O0",
2647 #                        release => "-O3")
2648 #
2649 sub picker {
2650     my %opts = @_;
2651     return sub { add($opts{default} || (),
2652                      $opts{$config{build_type}} || ())->(); }
2653 }
2654
2655 # Helper function to combine several values of different types into one.
2656 # This is useful if you want to combine a string with the result of a
2657 # lazy function, such as:
2658 #
2659 #       cflags => combine("-Wall", sub { $disabled{zlib} ? () : "-DZLIB" })
2660 #
2661 sub combine {
2662     my @stuff = @_;
2663     return sub { add(@stuff)->(); }
2664 }
2665
2666 # Helper function to implement conditional values depending on the value
2667 # of $disabled{threads}.  Can be used as follows:
2668 #
2669 #       cflags => combine("-Wall", threads("-pthread"))
2670 #
2671 sub threads {
2672     my @flags = @_;
2673     return sub { add($disabled{threads} ? () : @flags)->(); }
2674 }
2675
2676 sub shared {
2677     my @flags = @_;
2678     return sub { add($disabled{shared} ? () : @flags)->(); }
2679 }
2680
2681 our $add_called = 0;
2682 # Helper function to implement adding values to already existing configuration
2683 # values.  It handles elements that are ARRAYs, CODEs and scalars
2684 sub _add {
2685     my $separator = shift;
2686
2687     # If there's any ARRAY in the collection of values OR the separator
2688     # is undef, we will return an ARRAY of combined values, otherwise a
2689     # string of joined values with $separator as the separator.
2690     my $found_array = !defined($separator);
2691
2692     my @values =
2693         map {
2694             my $res = $_;
2695             while (ref($res) eq "CODE") {
2696                 $res = $res->();
2697             }
2698             if (defined($res)) {
2699                 if (ref($res) eq "ARRAY") {
2700                     $found_array = 1;
2701                     @$res;
2702                 } else {
2703                     $res;
2704                 }
2705             } else {
2706                 ();
2707             }
2708     } (@_);
2709
2710     $add_called = 1;
2711
2712     if ($found_array) {
2713         [ @values ];
2714     } else {
2715         join($separator, grep { defined($_) && $_ ne "" } @values);
2716     }
2717 }
2718 sub add_before {
2719     my $separator = " ";
2720     if (ref($_[$#_]) eq "HASH") {
2721         my $opts = pop;
2722         $separator = $opts->{separator};
2723     }
2724     my @x = @_;
2725     sub { _add($separator, @x, @_) };
2726 }
2727 sub add {
2728     my $separator = " ";
2729     if (ref($_[$#_]) eq "HASH") {
2730         my $opts = pop;
2731         $separator = $opts->{separator};
2732     }
2733     my @x = @_;
2734     sub { _add($separator, @_, @x) };
2735 }
2736
2737 sub read_eval_file {
2738     my $fname = shift;
2739     my $content;
2740     my @result;
2741
2742     open F, "< $fname" or die "Can't open '$fname': $!\n";
2743     {
2744         undef local $/;
2745         $content = <F>;
2746     }
2747     close F;
2748     {
2749         local $@;
2750
2751         @result = ( eval $content );
2752         warn $@ if $@;
2753     }
2754     return wantarray ? @result : $result[0];
2755 }
2756
2757 # configuration reader, evaluates the input file as a perl script and expects
2758 # it to fill %targets with target configurations.  Those are then added to
2759 # %table.
2760 sub read_config {
2761     my $fname = shift;
2762     my %targets;
2763
2764     {
2765         # Protect certain tables from tampering
2766         local %table = ();
2767
2768         %targets = read_eval_file($fname);
2769     }
2770     my %preexisting = ();
2771     foreach (sort keys %targets) {
2772         $preexisting{$_} = 1 if $table{$_};
2773     }
2774     die <<"EOF",
2775 The following config targets from $fname
2776 shadow pre-existing config targets with the same name:
2777 EOF
2778         map { "  $_\n" } sort keys %preexisting
2779         if %preexisting;
2780
2781
2782     # For each target, check that it's configured with a hash table.
2783     foreach (keys %targets) {
2784         if (ref($targets{$_}) ne "HASH") {
2785             if (ref($targets{$_}) eq "") {
2786                 warn "Deprecated target configuration for $_, ignoring...\n";
2787             } else {
2788                 warn "Misconfigured target configuration for $_ (should be a hash table), ignoring...\n";
2789             }
2790             delete $targets{$_};
2791         } else {
2792             $targets{$_}->{_conf_fname_int} = add([ $fname ]);
2793         }
2794     }
2795
2796     %table = (%table, %targets);
2797
2798 }
2799
2800 # configuration resolver.  Will only resolve all the lazy evaluation
2801 # codeblocks for the chosen target and all those it inherits from,
2802 # recursively
2803 sub resolve_config {
2804     my $target = shift;
2805     my @breadcrumbs = @_;
2806
2807 #    my $extra_checks = defined($ENV{CONFIGURE_EXTRA_CHECKS});
2808
2809     if (grep { $_ eq $target } @breadcrumbs) {
2810         die "inherit_from loop!  target backtrace:\n  "
2811             ,$target,"\n  ",join("\n  ", @breadcrumbs),"\n";
2812     }
2813
2814     if (!defined($table{$target})) {
2815         warn "Warning! target $target doesn't exist!\n";
2816         return ();
2817     }
2818     # Recurse through all inheritances.  They will be resolved on the
2819     # fly, so when this operation is done, they will all just be a
2820     # bunch of attributes with string values.
2821     # What we get here, though, are keys with references to lists of
2822     # the combined values of them all.  We will deal with lists after
2823     # this stage is done.
2824     my %combined_inheritance = ();
2825     if ($table{$target}->{inherit_from}) {
2826         my @inherit_from =
2827             map { ref($_) eq "CODE" ? $_->() : $_ } @{$table{$target}->{inherit_from}};
2828         foreach (@inherit_from) {
2829             my %inherited_config = resolve_config($_, $target, @breadcrumbs);
2830
2831             # 'template' is a marker that's considered private to
2832             # the config that had it.
2833             delete $inherited_config{template};
2834
2835             foreach (keys %inherited_config) {
2836                 if (!$combined_inheritance{$_}) {
2837                     $combined_inheritance{$_} = [];
2838                 }
2839                 push @{$combined_inheritance{$_}}, $inherited_config{$_};
2840             }
2841         }
2842     }
2843
2844     # We won't need inherit_from in this target any more, since we've
2845     # resolved all the inheritances that lead to this
2846     delete $table{$target}->{inherit_from};
2847
2848     # Now is the time to deal with those lists.  Here's the place to
2849     # decide what shall be done with those lists, all based on the
2850     # values of the target we're currently dealing with.
2851     # - If a value is a coderef, it will be executed with the list of
2852     #   inherited values as arguments.
2853     # - If the corresponding key doesn't have a value at all or is the
2854     #   empty string, the inherited value list will be run through the
2855     #   default combiner (below), and the result becomes this target's
2856     #   value.
2857     # - Otherwise, this target's value is assumed to be a string that
2858     #   will simply override the inherited list of values.
2859     my $default_combiner = add();
2860
2861     my %all_keys =
2862         map { $_ => 1 } (keys %combined_inheritance,
2863                          keys %{$table{$target}});
2864
2865     sub process_values {
2866         my $object    = shift;
2867         my $inherited = shift;  # Always a [ list ]
2868         my $target    = shift;
2869         my $entry     = shift;
2870
2871         $add_called = 0;
2872
2873         while(ref($object) eq "CODE") {
2874             $object = $object->(@$inherited);
2875         }
2876         if (!defined($object)) {
2877             return ();
2878         }
2879         elsif (ref($object) eq "ARRAY") {
2880             local $add_called;  # To make sure recursive calls don't affect it
2881             return [ map { process_values($_, $inherited, $target, $entry) }
2882                      @$object ];
2883         } elsif (ref($object) eq "") {
2884             return $object;
2885         } else {
2886             die "cannot handle reference type ",ref($object)
2887                 ," found in target ",$target," -> ",$entry,"\n";
2888         }
2889     }
2890
2891     foreach (sort keys %all_keys) {
2892         my $previous = $combined_inheritance{$_};
2893
2894         # Current target doesn't have a value for the current key?
2895         # Assign it the default combiner, the rest of this loop body
2896         # will handle it just like any other coderef.
2897         if (!exists $table{$target}->{$_}) {
2898             $table{$target}->{$_} = $default_combiner;
2899         }
2900
2901         $table{$target}->{$_} = process_values($table{$target}->{$_},
2902                                                $combined_inheritance{$_},
2903                                                $target, $_);
2904         unless(defined($table{$target}->{$_})) {
2905             delete $table{$target}->{$_};
2906         }
2907 #        if ($extra_checks &&
2908 #            $previous && !($add_called ||  $previous ~~ $table{$target}->{$_})) {
2909 #            warn "$_ got replaced in $target\n";
2910 #        }
2911     }
2912
2913     # Finally done, return the result.
2914     return %{$table{$target}};
2915 }
2916
2917 sub usage
2918         {
2919         print STDERR $usage;
2920         print STDERR "\npick os/compiler from:\n";
2921         my $j=0;
2922         my $i;
2923         my $k=0;
2924         foreach $i (sort keys %table)
2925                 {
2926                 next if $table{$i}->{template};
2927                 next if $i =~ /^debug/;
2928                 $k += length($i) + 1;
2929                 if ($k > 78)
2930                         {
2931                         print STDERR "\n";
2932                         $k=length($i);
2933                         }
2934                 print STDERR $i . " ";
2935                 }
2936         foreach $i (sort keys %table)
2937                 {
2938                 next if $table{$i}->{template};
2939                 next if $i !~ /^debug/;
2940                 $k += length($i) + 1;
2941                 if ($k > 78)
2942                         {
2943                         print STDERR "\n";
2944                         $k=length($i);
2945                         }
2946                 print STDERR $i . " ";
2947                 }
2948         print STDERR "\n\nNOTE: If in doubt, on Unix-ish systems use './config'.\n";
2949         exit(1);
2950         }
2951
2952 sub compiler_predefined {
2953     state %predefined;
2954     my $cc = shift;
2955
2956     return () if $^O eq 'VMS';
2957
2958     die 'compiler_predefined called without a compiler command'
2959         unless $cc;
2960
2961     if (! $predefined{$cc}) {
2962
2963         $predefined{$cc} = {};
2964
2965         # collect compiler pre-defines from gcc or gcc-alike...
2966         open(PIPE, "$cc -dM -E -x c /dev/null 2>&1 |");
2967         while (my $l = <PIPE>) {
2968             $l =~ m/^#define\s+(\w+(?:\(\w+\))?)(?:\s+(.+))?/ or last;
2969             $predefined{$cc}->{$1} = $2 // '';
2970         }
2971         close(PIPE);
2972     }
2973
2974     return %{$predefined{$cc}};
2975 }
2976
2977 sub which
2978 {
2979     my ($name)=@_;
2980
2981     if (eval { require IPC::Cmd; 1; }) {
2982         IPC::Cmd->import();
2983         return scalar IPC::Cmd::can_run($name);
2984     } else {
2985         # if there is $directories component in splitpath,
2986         # then it's not something to test with $PATH...
2987         return $name if (File::Spec->splitpath($name))[1];
2988
2989         foreach (File::Spec->path()) {
2990             my $fullpath = catfile($_, "$name$target{exe_extension}");
2991             if (-f $fullpath and -x $fullpath) {
2992                 return $fullpath;
2993             }
2994         }
2995     }
2996 }
2997
2998 sub env
2999 {
3000     my $name = shift;
3001     my %opts = @_;
3002
3003     unless ($opts{cacheonly}) {
3004         # Note that if $ENV{$name} doesn't exist or is undefined,
3005         # $config{perlenv}->{$name} will be created with the value
3006         # undef.  This is intentional.
3007
3008         $config{perlenv}->{$name} = $ENV{$name}
3009             if ! exists $config{perlenv}->{$name};
3010     }
3011     return $config{perlenv}->{$name};
3012 }
3013
3014 # Configuration printer ##############################################
3015
3016 sub print_table_entry
3017 {
3018     local $now_printing = shift;
3019     my %target = resolve_config($now_printing);
3020     my $type = shift;
3021
3022     # Don't print the templates
3023     return if $target{template};
3024
3025     my @sequence = (
3026         "sys_id",
3027         "cpp",
3028         "cppflags",
3029         "defines",
3030         "includes",
3031         "cc",
3032         "cflags",
3033         "ld",
3034         "lflags",
3035         "loutflag",
3036         "ex_libs",
3037         "bn_ops",
3038         "poly1035_asm_src",
3039         "thread_scheme",
3040         "perlasm_scheme",
3041         "dso_scheme",
3042         "shared_target",
3043         "shared_cflag",
3044         "shared_defines",
3045         "shared_ldflag",
3046         "shared_rcflag",
3047         "shared_extension",
3048         "dso_extension",
3049         "obj_extension",
3050         "exe_extension",
3051         "ranlib",
3052         "ar",
3053         "arflags",
3054         "aroutflag",
3055         "rc",
3056         "rcflags",
3057         "rcoutflag",
3058         "mt",
3059         "mtflags",
3060         "mtinflag",
3061         "mtoutflag",
3062         "multilib",
3063         "build_scheme",
3064         );
3065
3066     if ($type eq "TABLE") {
3067         print "\n";
3068         print "*** $now_printing\n";
3069         foreach (@sequence) {
3070             if (ref($target{$_}) eq "ARRAY") {
3071                 printf "\$%-12s = %s\n", $_, join(" ", @{$target{$_}});
3072             } else {
3073                 printf "\$%-12s = %s\n", $_, $target{$_};
3074             }
3075         }
3076     } elsif ($type eq "HASH") {
3077         my $largest =
3078             length((sort { length($a) <=> length($b) } @sequence)[-1]);
3079         print "    '$now_printing' => {\n";
3080         foreach (@sequence) {
3081             if ($target{$_}) {
3082                 if (ref($target{$_}) eq "ARRAY") {
3083                     print "      '",$_,"'"," " x ($largest - length($_))," => [ ",join(", ", map { "'$_'" } @{$target{$_}})," ],\n";
3084                 } else {
3085                     print "      '",$_,"'"," " x ($largest - length($_))," => '",$target{$_},"',\n";
3086                 }
3087             }
3088         }
3089         print "    },\n";
3090     }
3091 }
3092
3093 # Utility routines ###################################################
3094
3095 # On VMS, if the given file is a logical name, File::Spec::Functions
3096 # will consider it an absolute path.  There are cases when we want a
3097 # purely syntactic check without checking the environment.
3098 sub isabsolute {
3099     my $file = shift;
3100
3101     # On non-platforms, we just use file_name_is_absolute().
3102     return file_name_is_absolute($file) unless $^O eq "VMS";
3103
3104     # If the file spec includes a device or a directory spec,
3105     # file_name_is_absolute() is perfectly safe.
3106     return file_name_is_absolute($file) if $file =~ m|[:\[]|;
3107
3108     # Here, we know the given file spec isn't absolute
3109     return 0;
3110 }
3111
3112 # Makes a directory absolute and cleans out /../ in paths like foo/../bar
3113 # On some platforms, this uses rel2abs(), while on others, realpath() is used.
3114 # realpath() requires that at least all path components except the last is an
3115 # existing directory.  On VMS, the last component of the directory spec must
3116 # exist.
3117 sub absolutedir {
3118     my $dir = shift;
3119
3120     # realpath() is quite buggy on VMS.  It uses LIB$FID_TO_NAME, which
3121     # will return the volume name for the device, no matter what.  Also,
3122     # it will return an incorrect directory spec if the argument is a
3123     # directory that doesn't exist.
3124     if ($^O eq "VMS") {
3125         return rel2abs($dir);
3126     }
3127
3128     # We use realpath() on Unix, since no other will properly clean out
3129     # a directory spec.
3130     use Cwd qw/realpath/;
3131
3132     return realpath($dir);
3133 }
3134
3135 sub quotify {
3136     my %processors = (
3137         perl    => sub { my $x = shift;
3138                          $x =~ s/([\\\$\@"])/\\$1/g;
3139                          return '"'.$x.'"'; },
3140         maybeshell => sub { my $x = shift;
3141                             (my $y = $x) =~ s/([\\\"])/\\$1/g;
3142                             if ($x ne $y || $x =~ m|\s|) {
3143                                 return '"'.$y.'"';
3144                             } else {
3145                                 return $x;
3146                             }
3147                         },
3148         );
3149     my $for = shift;
3150     my $processor =
3151         defined($processors{$for}) ? $processors{$for} : sub { shift; };
3152
3153     return map { $processor->($_); } @_;
3154 }
3155
3156 # collect_from_file($filename, $line_concat_cond_re, $line_concat)
3157 # $filename is a file name to read from
3158 # $line_concat_cond_re is a regexp detecting a line continuation ending
3159 # $line_concat is a CODEref that takes care of concatenating two lines
3160 sub collect_from_file {
3161     my $filename = shift;
3162     my $line_concat_cond_re = shift;
3163     my $line_concat = shift;
3164
3165     open my $fh, $filename || die "unable to read $filename: $!\n";
3166     return sub {
3167         my $saved_line = "";
3168         $_ = "";
3169         while (<$fh>) {
3170             s|\R$||;
3171             if (defined $line_concat) {
3172                 $_ = $line_concat->($saved_line, $_);
3173                 $saved_line = "";
3174             }
3175             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3176                 $saved_line = $_;
3177                 next;
3178             }
3179             return $_;
3180         }
3181         die "$filename ending with continuation line\n" if $_;
3182         close $fh;
3183         return undef;
3184     }
3185 }
3186
3187 # collect_from_array($array, $line_concat_cond_re, $line_concat)
3188 # $array is an ARRAYref of lines
3189 # $line_concat_cond_re is a regexp detecting a line continuation ending
3190 # $line_concat is a CODEref that takes care of concatenating two lines
3191 sub collect_from_array {
3192     my $array = shift;
3193     my $line_concat_cond_re = shift;
3194     my $line_concat = shift;
3195     my @array = (@$array);
3196
3197     return sub {
3198         my $saved_line = "";
3199         $_ = "";
3200         while (defined($_ = shift @array)) {
3201             s|\R$||;
3202             if (defined $line_concat) {
3203                 $_ = $line_concat->($saved_line, $_);
3204                 $saved_line = "";
3205             }
3206             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3207                 $saved_line = $_;
3208                 next;
3209             }
3210             return $_;
3211         }
3212         die "input text ending with continuation line\n" if $_;
3213         return undef;
3214     }
3215 }
3216
3217 # collect_information($lineiterator, $line_continue, $regexp => $CODEref, ...)
3218 # $lineiterator is a CODEref that delivers one line at a time.
3219 # All following arguments are regex/CODEref pairs, where the regexp detects a
3220 # line and the CODEref does something with the result of the regexp.
3221 sub collect_information {
3222     my $lineiterator = shift;
3223     my %collectors = @_;
3224
3225     while(defined($_ = $lineiterator->())) {
3226         s|\R$||;
3227         my $found = 0;
3228         if ($collectors{"BEFORE"}) {
3229             $collectors{"BEFORE"}->($_);
3230         }
3231         foreach my $re (keys %collectors) {
3232             if ($re !~ /^OTHERWISE|BEFORE|AFTER$/ && /$re/) {
3233                 $collectors{$re}->($lineiterator);
3234                 $found = 1;
3235             };
3236         }
3237         if ($collectors{"OTHERWISE"}) {
3238             $collectors{"OTHERWISE"}->($lineiterator, $_)
3239                 unless $found || !defined $collectors{"OTHERWISE"};
3240         }
3241         if ($collectors{"AFTER"}) {
3242             $collectors{"AFTER"}->($_);
3243         }
3244     }
3245 }
3246
3247 # tokenize($line)
3248 # tokenize($line,$separator)
3249 # $line is a line of text to split up into tokens
3250 # $separator [optional] is a regular expression that separates the tokens,
3251 # the default being spaces.  Do not use quotes of any kind as separators,
3252 # that will give undefined results.
3253 # Returns a list of tokens.
3254 #
3255 # Tokens are divided by separator (spaces by default).  If the tokens include
3256 # the separators, they have to be quoted with single or double quotes.
3257 # Double quotes inside a double quoted token must be escaped.  Escaping is done
3258 # with backslash.
3259 # Basically, the same quoting rules apply for " and ' as in any
3260 # Unix shell.
3261 sub tokenize {
3262     my $line = my $debug_line = shift;
3263     my $separator = shift // qr|\s+|;
3264     my @result = ();
3265
3266     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
3267         print STDERR "DEBUG[tokenize]: \$separator = $separator\n";
3268     }
3269
3270     while ($line =~ s|^${separator}||, $line ne "") {
3271         my $token = "";
3272     again:
3273         $line =~ m/^(.*?)(${separator}|"|'|$)/;
3274         $token .= $1;
3275         $line = $2.$';
3276
3277         if ($line =~ m/^"((?:[^"\\]+|\\.)*)"/) {
3278             $token .= $1;
3279             $line = $';
3280             goto again;
3281         } elsif ($line =~ m/^'([^']*)'/) {
3282             $token .= $1;
3283             $line = $';
3284             goto again;
3285         }
3286         push @result, $token;
3287     }
3288
3289     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
3290         print STDERR "DEBUG[tokenize]: Parsed '$debug_line' into:\n";
3291         print STDERR "DEBUG[tokenize]: ('", join("', '", @result), "')\n";
3292     }
3293     return @result;
3294 }