Configure

   1 #! /usr/bin/env perl
   2 # -*- mode: perl; -*-
   3 # Copyright 2016-2018 The OpenSSL Project Authors. All Rights Reserved.
   4 #
   5 # Licensed under the Apache License 2.0 (the "License").  You may not use
   6 # this file except in compliance with the License.  You can obtain a copy
   7 # in the file LICENSE in the source distribution or at
   8 # https://www.openssl.org/source/license.html
   9
  10 ##  Configure -- OpenSSL source tree configuration script
  11
  12 use 5.10.0;
  13 use strict;
  14 use Config;
  15 use FindBin;
  16 use lib "$FindBin::Bin/util/perl";
  17 use File::Basename;
  18 use File::Spec::Functions qw/:DEFAULT abs2rel rel2abs splitdir/;
  19 use File::Path qw/mkpath/;
  20 use OpenSSL::fallback "$FindBin::Bin/external/perl/MODULES.txt";
  21 use OpenSSL::Glob;
  22 use OpenSSL::Template;
  23
  24 # see INSTALL for instructions.
  25
  26 my $orig_death_handler = $SIG{__DIE__};
  27 $SIG{__DIE__} = \&death_handler;
  28
  29 my $usage="Usage: Configure [no-<cipher> ...] [enable-<cipher> ...] [-Dxxx] [-lxxx] [-Lxxx] [-fxxx] [-Kxxx] [no-hw-xxx|no-hw] [[no-]threads] [[no-]shared] [[no-]zlib|zlib-dynamic] [no-asm] [no-egd] [sctp] [386] [--prefix=DIR] [--openssldir=OPENSSLDIR] [--with-xxx[=vvv]] [--config=FILE] os/compiler[:flags]\n";
  30
  31 # Options:
  32 #
  33 # --config      add the given configuration file, which will be read after
  34 #               any "Configurations*" files that are found in the same
  35 #               directory as this script.
  36 # --prefix      prefix for the OpenSSL installation, which includes the
  37 #               directories bin, lib, include, share/man, share/doc/openssl
  38 #               This becomes the value of INSTALLTOP in Makefile
  39 #               (Default: /usr/local)
  40 # --openssldir  OpenSSL data area, such as openssl.cnf, certificates and keys.
  41 #               If it's a relative directory, it will be added on the directory
  42 #               given with --prefix.
  43 #               This becomes the value of OPENSSLDIR in Makefile and in C.
  44 #               (Default: PREFIX/ssl)
  45 #
  46 # --cross-compile-prefix Add specified prefix to binutils components.
  47 #
  48 # --api         One of 0.9.8, 1.0.0, 1.0.1, 1.0.2, 1.1.0, 1.1.1, or 3.0
  49 #               Define the public APIs as they were for that version
  50 #               including patch releases.  If 'no-deprecated' is also
  51 #               given, do not compile support for interfaces deprecated
  52 #               up to and including the specified OpenSSL version.
  53 #
  54 # no-hw-xxx     do not compile support for specific crypto hardware.
  55 #               Generic OpenSSL-style methods relating to this support
  56 #               are always compiled but return NULL if the hardware
  57 #               support isn't compiled.
  58 # no-hw         do not compile support for any crypto hardware.
  59 # [no-]threads  [don't] try to create a library that is suitable for
  60 #               multithreaded applications (default is "threads" if we
  61 #               know how to do it)
  62 # [no-]shared   [don't] try to create shared libraries when supported.
  63 # [no-]pic      [don't] try to build position independent code when supported.
  64 #               If disabled, it also disables shared and dynamic-engine.
  65 # no-asm        do not use assembler
  66 # no-egd        do not compile support for the entropy-gathering daemon APIs
  67 # [no-]zlib     [don't] compile support for zlib compression.
  68 # zlib-dynamic  Like "zlib", but the zlib library is expected to be a shared
  69 #               library and will be loaded in run-time by the OpenSSL library.
  70 # sctp          include SCTP support
  71 # no-uplink     Don't build support for UPLINK interface.
  72 # enable-weak-ssl-ciphers
  73 #               Enable weak ciphers that are disabled by default.
  74 # 386           generate 80386 code in assembly modules
  75 # no-sse2       disables IA-32 SSE2 code in assembly modules, the above
  76 #               mentioned '386' option implies this one
  77 # no-<cipher>   build without specified algorithm (rsa, idea, rc5, ...)
  78 # -<xxx> +<xxx> All options which are unknown to the 'Configure' script are
  79 # /<xxx>        passed through to the compiler. Unix-style options beginning
  80 #               with a '-' or '+' are recognized, as well as Windows-style
  81 #               options beginning with a '/'. If the option contains arguments
  82 #               separated by spaces, then the URL-style notation %20 can be
  83 #               used for the space character in order to avoid having to quote
  84 #               the option. For example, -opt%20arg gets expanded to -opt arg.
  85 #               In fact, any ASCII character can be encoded as %xx using its
  86 #               hexadecimal encoding.
  87 # -static       while -static is also a pass-through compiler option (and
  88 #               as such is limited to environments where it's actually
  89 #               meaningful), it triggers a number configuration options,
  90 #               namely no-pic, no-shared and no-threads. It is
  91 #               argued that the only reason to produce statically linked
  92 #               binaries (and in context it means executables linked with
  93 #               -static flag, and not just executables linked with static
  94 #               libcrypto.a) is to eliminate dependency on specific run-time,
  95 #               a.k.a. libc version. The mentioned config options are meant
  96 #               to achieve just that. Unfortunately on Linux it's impossible
  97 #               to eliminate the dependency completely for openssl executable
  98 #               because of getaddrinfo and gethostbyname calls, which can
  99 #               invoke dynamically loadable library facility anyway to meet
 100 #               the lookup requests. For this reason on Linux statically
 101 #               linked openssl executable has rather debugging value than
 102 #               production quality.
 103 #
 104 # BN_LLONG      use the type 'long long' in crypto/bn/bn.h
 105 # RC4_CHAR      use 'char' instead of 'int' for RC4_INT in crypto/rc4/rc4.h
 106 # Following are set automatically by this script
 107 #
 108 # MD5_ASM       use some extra md5 assembler,
 109 # SHA1_ASM      use some extra sha1 assembler, must define L_ENDIAN for x86
 110 # RMD160_ASM    use some extra ripemd160 assembler,
 111 # SHA256_ASM    sha256_block is implemented in assembler
 112 # SHA512_ASM    sha512_block is implemented in assembler
 113 # AES_ASM       AES_[en|de]crypt is implemented in assembler
 114
 115 # Minimum warning options... any contributions to OpenSSL should at least
 116 # get past these.  Note that we only use these with C compilers, not with
 117 # C++ compilers.
 118
 119 # DEBUG_UNUSED enables __owur (warn unused result) checks.
 120 # -DPEDANTIC complements -pedantic and is meant to mask code that
 121 # is not strictly standard-compliant and/or implementation-specific,
 122 # e.g. inline assembly, disregards to alignment requirements, such
 123 # that -pedantic would complain about. Incidentally -DPEDANTIC has
 124 # to be used even in sanitized builds, because sanitizer too is
 125 # supposed to and does take notice of non-standard behaviour. Then
 126 # -pedantic with pre-C9x compiler would also complain about 'long
 127 # long' not being supported. As 64-bit algorithms are common now,
 128 # it grew impossible to resolve this without sizeable additional
 129 # code, so we just tell compiler to be pedantic about everything
 130 # but 'long long' type.
 131
 132 my @gcc_devteam_warn = qw(
 133     -DDEBUG_UNUSED
 134     -DPEDANTIC -pedantic -Wno-long-long
 135     -Wall
 136     -Wextra
 137     -Wno-unused-parameter
 138     -Wno-missing-field-initializers
 139     -Wswitch
 140     -Wsign-compare
 141     -Wshadow
 142     -Wformat
 143     -Wtype-limits
 144     -Wundef
 145     -Werror
 146     -Wmissing-prototypes
 147     -Wstrict-prototypes
 148 );
 149
 150 # These are used in addition to $gcc_devteam_warn when the compiler is clang.
 151 # TODO(openssl-team): fix problems and investigate if (at least) the
 152 # following warnings can also be enabled:
 153 #       -Wcast-align
 154 #       -Wunreachable-code -- no, too ugly/compiler-specific
 155 #       -Wlanguage-extension-token -- no, we use asm()
 156 #       -Wunused-macros -- no, too tricky for BN and _XOPEN_SOURCE etc
 157 #       -Wextended-offsetof -- no, needed in CMS ASN1 code
 158 my @clang_devteam_warn = qw(
 159     -Wno-unknown-warning-option
 160     -Wswitch-default
 161     -Wno-parentheses-equality
 162     -Wno-language-extension-token
 163     -Wno-extended-offsetof
 164     -Wconditional-uninitialized
 165     -Wincompatible-pointer-types-discards-qualifiers
 166     -Wmissing-variable-declarations
 167 );
 168
 169 my @cl_devteam_warn = qw(
 170     /WX
 171 );
 172
 173 my $strict_warnings = 0;
 174
 175 # As for $BSDthreads. Idea is to maintain "collective" set of flags,
 176 # which would cover all BSD flavors. -pthread applies to them all,
 177 # but is treated differently. OpenBSD expands is as -D_POSIX_THREAD
 178 # -lc_r, which is sufficient. FreeBSD 4.x expands it as -lc_r,
 179 # which has to be accompanied by explicit -D_THREAD_SAFE and
 180 # sometimes -D_REENTRANT. FreeBSD 5.x expands it as -lc_r, which
 181 # seems to be sufficient?
 182 our $BSDthreads="-pthread -D_THREAD_SAFE -D_REENTRANT";
 183
 184 #
 185 # API compatibility name to version number mapping.
 186 #
 187 my $apitable = {
 188     # This table expresses when API additions or changes can occur.
 189     # The numbering used changes from 3.0 and on because we updated
 190     # (solidified) our version numbering scheme at that point.
 191
 192     # From 3.0 and on, we internalise the given version number in dedcimal
 193     # as MAJOR * 10000 + MINOR * 100 + 0
 194     "3.0.0" => 30000,
 195     "3.0"   => 30000,
 196
 197     # Note that before 3.0, we didn't have the same version number scheme.
 198     # Still, the numbering we use here covers what we need.
 199     "1.1.1" => 10101,
 200     "1.1.0" => 10100,
 201     "1.0.2" => 10002,
 202     "1.0.1" => 10001,
 203     "1.0.0" => 10000,
 204     "0.9.8" =>   908,
 205 };
 206
 207 our %table = ();
 208 our %config = ();
 209 our %withargs = ();
 210 our $now_printing;      # set to current entry's name in print_table_entry
 211                         # (todo: right thing would be to encapsulate name
 212                         # into %target [class] and make print_table_entry
 213                         # a method)
 214
 215 # Forward declarations ###############################################
 216
 217 # read_config(filename)
 218 #
 219 # Reads a configuration file and populates %table with the contents
 220 # (which the configuration file places in %targets).
 221 sub read_config;
 222
 223 # resolve_config(target)
 224 #
 225 # Resolves all the late evaluations, inheritances and so on for the
 226 # chosen target and any target it inherits from.
 227 sub resolve_config;
 228
 229
 230 # Information collection #############################################
 231
 232 # Unified build supports separate build dir
 233 my $srcdir = catdir(absolutedir(dirname($0))); # catdir ensures local syntax
 234 my $blddir = catdir(absolutedir("."));         # catdir ensures local syntax
 235 my $dofile = abs2rel(catfile($srcdir, "util/dofile.pl"));
 236
 237 my $local_config_envname = 'OPENSSL_LOCAL_CONFIG_DIR';
 238
 239 $config{sourcedir} = abs2rel($srcdir);
 240 $config{builddir} = abs2rel($blddir);
 241
 242 # Collect reconfiguration information if needed
 243 my @argvcopy=@ARGV;
 244
 245 if (grep /^reconf(igure)?$/, @argvcopy) {
 246     die "reconfiguring with other arguments present isn't supported"
 247         if scalar @argvcopy > 1;
 248     if (-f "./configdata.pm") {
 249         my $file = "./configdata.pm";
 250         unless (my $return = do $file) {
 251             die "couldn't parse $file: $@" if $@;
 252             die "couldn't do $file: $!"    unless defined $return;
 253             die "couldn't run $file"       unless $return;
 254         }
 255
 256         @argvcopy = defined($configdata::config{perlargv}) ?
 257             @{$configdata::config{perlargv}} : ();
 258         die "Incorrect data to reconfigure, please do a normal configuration\n"
 259             if (grep(/^reconf/,@argvcopy));
 260         $config{perlenv} = $configdata::config{perlenv} // {};
 261     } else {
 262         die "Insufficient data to reconfigure, please do a normal configuration\n";
 263     }
 264 }
 265
 266 $config{perlargv} = [ @argvcopy ];
 267
 268 # Historical: if known directories in crypto/ have been removed, it means
 269 # that those sub-systems are disabled.
 270 # (the other option would be to removed them from the SUBDIRS statement in
 271 # crypto/build.info)
 272 # We reverse the input list for cosmetic purely reasons, to compensate that
 273 # 'unshift' adds at the front of the list (i.e. in reverse input order).
 274 foreach ( reverse sort( 'aes', 'aria', 'bf', 'camellia', 'cast', 'des', 'dh',
 275                         'dsa', 'ec', 'hmac', 'idea', 'md2', 'md5', 'mdc2',
 276                         'rc2', 'rc4', 'rc5', 'ripemd', 'rsa', 'seed', 'sha',
 277                         'sm2', 'sm3', 'sm4') ) {
 278     unshift @argvcopy, "no-$_" if ! -d catdir($srcdir, 'crypto', $_);
 279 }
 280
 281 # Collect version numbers
 282 my %version = ();
 283
 284 collect_information(
 285     collect_from_file(catfile($srcdir,'VERSION')),
 286     qr/\s*(\w+)\s*=\s*(.*?)\s*$/ =>
 287         sub {
 288             # Only define it if there is a value at all
 289             $version{uc $1} = $2 if $2 ne '';
 290         },
 291     "OTHERWISE" =>
 292         sub { die "Something wrong with this line:\n$_\nin $srcdir/VERSION" },
 293     );
 294
 295 $config{major} = $version{MAJOR} // 'unknown';
 296 $config{minor} = $version{MINOR} // 'unknown';
 297 $config{patch} = $version{PATCH} // 'unknown';
 298 $config{prerelease} =
 299     defined $version{PRE_RELEASE_TAG} ? "-$version{PRE_RELEASE_TAG}" : '';
 300 $config{build_metadata} =
 301     defined $version{BUILD_METADATA} ? "+$version{BUILD_METADATA}" : '';
 302 $config{shlib_version} = $version{SHLIB_VERSION} // 'unknown';
 303 $config{release_date} = $version{RELEASE_DATE} // 'xx XXX xxxx';
 304
 305 $config{version} = "$config{major}.$config{minor}.$config{patch}";
 306 $config{full_version} = "$config{version}$config{prerelease}$config{build_metadata}";
 307
 308 die "erroneous version information in VERSION: ",
 309     "$config{version}, $config{shlib_version}\n"
 310     unless (defined $version{MAJOR}
 311             && defined $version{MINOR}
 312             && defined $version{PATCH}
 313             && defined $version{SHLIB_VERSION});
 314
 315 # Collect target configurations
 316
 317 my $pattern = catfile(dirname($0), "Configurations", "*.conf");
 318 foreach (sort glob($pattern)) {
 319     &read_config($_);
 320 }
 321
 322 if (defined env($local_config_envname)) {
 323     if ($^O eq 'VMS') {
 324         # VMS environment variables are logical names,
 325         # which can be used as is
 326         $pattern = $local_config_envname . ':' . '*.conf';
 327     } else {
 328         $pattern = catfile(env($local_config_envname), '*.conf');
 329     }
 330
 331     foreach (sort glob($pattern)) {
 332         &read_config($_);
 333     }
 334 }
 335
 336 # Save away perl command information
 337 $config{perl_cmd} = $^X;
 338 $config{perl_version} = $Config{version};
 339 $config{perl_archname} = $Config{archname};
 340
 341 $config{prefix}="";
 342 $config{openssldir}="";
 343 $config{processor}="";
 344 $config{libdir}="";
 345 my $auto_threads=1;    # enable threads automatically? true by default
 346 my $default_ranlib;
 347
 348 # Known TLS and DTLS protocols
 349 my @tls = qw(ssl3 tls1 tls1_1 tls1_2 tls1_3);
 350 my @dtls = qw(dtls1 dtls1_2);
 351
 352 # Explicitly known options that are possible to disable.  They can
 353 # be regexps, and will be used like this: /^no-${option}$/
 354 # For developers: keep it sorted alphabetically
 355
 356 my @disablables = (
 357     "afalgeng",
 358     "aria",
 359     "asan",
 360     "asm",
 361     "async",
 362     "autoalginit",
 363     "autoerrinit",
 364     "autoload-config",
 365     "bf",
 366     "blake2",
 367     "buildtest-c++",
 368     "camellia",
 369     "capieng",
 370     "cast",
 371     "chacha",
 372     "cmac",
 373     "cmp",
 374     "cms",
 375     "comp",
 376     "crypto-mdebug",
 377     "ct",
 378     "deprecated",
 379     "des",
 380     "devcryptoeng",
 381     "dgram",
 382     "dh",
 383     "dsa",
 384     "dso",
 385     "dtls",
 386     "dynamic-engine",
 387     "ec",
 388     "ec2m",
 389     "ecdh",
 390     "ecdsa",
 391     "ec_nistp_64_gcc_128",
 392     "egd",
 393     "engine",
 394     "err",
 395     "external-tests",
 396     "filenames",
 397     "fips",
 398     "fuzz-libfuzzer",
 399     "fuzz-afl",
 400     "gost",
 401     "idea",
 402     "ktls",
 403     "legacy",
 404     "makedepend",
 405     "md2",
 406     "md4",
 407     "mdc2",
 408     "module",
 409     "msan",
 410     "multiblock",
 411     "nextprotoneg",
 412     "pinshared",
 413     "ocb",
 414     "ocsp",
 415     "padlockeng",
 416     "pic",
 417     "poly1305",
 418     "posix-io",
 419     "psk",
 420     "rc2",
 421     "rc4",
 422     "rc5",
 423     "rdrand",
 424     "rfc3779",
 425     "rmd160",
 426     "scrypt",
 427     "sctp",
 428     "secure-memory",
 429     "seed",
 430     "shared",
 431     "siphash",
 432     "siv",
 433     "sm2",
 434     "sm3",
 435     "sm4",
 436     "sock",
 437     "srp",
 438     "srtp",
 439     "sse2",
 440     "ssl",
 441     "ssl-trace",
 442     "static-engine",
 443     "stdio",
 444     "tests",
 445     "threads",
 446     "tls",
 447     "trace",
 448     "ts",
 449     "ubsan",
 450     "ui-console",
 451     "unit-test",
 452     "uplink",
 453     "whirlpool",
 454     "weak-ssl-ciphers",
 455     "zlib",
 456     "zlib-dynamic",
 457     );
 458 foreach my $proto ((@tls, @dtls))
 459         {
 460         push(@disablables, $proto);
 461         push(@disablables, "$proto-method") unless $proto eq "tls1_3";
 462         }
 463
 464 # Internal disablables, for aliasing purposes.  They serve no special
 465 # purpose here, but allow scripts to get to know them through configdata.pm,
 466 # where these are merged with @disablables.
 467 # The actual aliasing mechanism is done via %disable_cascades
 468 my @disablables_int = qw(
 469     crmf
 470     );
 471
 472 my %deprecated_disablables = (
 473     "ssl2" => undef,
 474     "buf-freelists" => undef,
 475     "crypto-mdebug-backtrace" => undef,
 476     "hw" => "hw",               # causes cascade, but no macro
 477     "hw-padlock" => "padlockeng",
 478     "ripemd" => "rmd160",
 479     "ui" => "ui-console",
 480     "heartbeats" => undef,
 481     );
 482
 483 # All of the following are disabled by default:
 484
 485 our %disabled = ( # "what"         => "comment"
 486                   "asan"                => "default",
 487                   "buildtest-c++"       => "default",
 488                   "crypto-mdebug"       => "default",
 489                   "crypto-mdebug-backtrace" => "default",
 490                   "devcryptoeng"        => "default",
 491                   "ec_nistp_64_gcc_128" => "default",
 492                   "egd"                 => "default",
 493                   "external-tests"      => "default",
 494                   "fuzz-libfuzzer"      => "default",
 495                   "fuzz-afl"            => "default",
 496                   "md2"                 => "default",
 497                   "msan"                => "default",
 498                   "rc5"                 => "default",
 499                   "sctp"                => "default",
 500                   "ssl-trace"           => "default",
 501                   "ssl3"                => "default",
 502                   "ssl3-method"         => "default",
 503                   "trace"               => "default",
 504                   "ubsan"               => "default",
 505                   "unit-test"           => "default",
 506                   "weak-ssl-ciphers"    => "default",
 507                   "zlib"                => "default",
 508                   "zlib-dynamic"        => "default",
 509                   "ktls"                => "default",
 510                 );
 511
 512 # Note: => pair form used for aesthetics, not to truly make a hash table
 513 my @disable_cascades = (
 514     # "what"            => [ "cascade", ... ]
 515     sub { $config{processor} eq "386" }
 516                         => [ "sse2" ],
 517     "ssl"               => [ "ssl3" ],
 518     "ssl3-method"       => [ "ssl3" ],
 519     "zlib"              => [ "zlib-dynamic" ],
 520     "des"               => [ "mdc2" ],
 521     "ec"                => [ "ecdsa", "ecdh", "sm2" ],
 522     sub { $disabled{"ec"} && $disabled{"dh"} }
 523                         => [ "tls1_3" ],
 524     "dgram"             => [ "dtls", "sctp" ],
 525     "sock"              => [ "dgram" ],
 526     "dtls"              => [ @dtls ],
 527     sub { 0 == scalar grep { !$disabled{$_} } @dtls }
 528                         => [ "dtls" ],
 529
 530     "tls"               => [ @tls ],
 531     sub { 0 == scalar grep { !$disabled{$_} } @tls }
 532                         => [ "tls" ],
 533
 534     "crypto-mdebug"     => [ "crypto-mdebug-backtrace" ],
 535
 536     # If no modules, then no dynamic engines either
 537     "module"            => [ "dynamic-engine" ],
 538
 539     # Without shared libraries, dynamic engines aren't possible.
 540     # This is due to them having to link with libcrypto and register features
 541     # using the ENGINE functionality, and since that relies on global tables,
 542     # those *have* to be exacty the same as the ones accessed from the app,
 543     # which cannot be guaranteed if shared libraries aren't present.
 544     # (note that even with shared libraries, both the app and dynamic engines
 545     # must be linked with the same library)
 546     "shared"            => [ "dynamic-engine", "uplink" ],
 547     "dso"               => [ "dynamic-engine", "module" ],
 548     # Other modules don't necessarily have to link with libcrypto, so shared
 549     # libraries do not have to be a condition to produce those.
 550
 551     # Without position independent code, there can be no shared libraries
 552     # or modules.
 553     "pic"               => [ "shared", "module" ],
 554
 555     "module"            => [ "fips" ],
 556
 557     "engine"            => [ grep /eng$/, @disablables ],
 558     "hw"                => [ "padlockeng" ],
 559
 560     # no-autoalginit is only useful when building non-shared
 561     "autoalginit"       => [ "shared", "apps" ],
 562
 563     "stdio"             => [ "apps", "capieng", "egd" ],
 564     "apps"              => [ "tests" ],
 565     "tests"             => [ "external-tests" ],
 566     "comp"              => [ "zlib" ],
 567     "sm3"               => [ "sm2" ],
 568     sub { !$disabled{"unit-test"} } => [ "heartbeats" ],
 569
 570     sub { !$disabled{"msan"} } => [ "asm" ],
 571
 572     sub { $disabled{cmac}; } => [ "siv" ],
 573     "legacy"                 => [ "md2" ],
 574
 575     "cmp"               => [ "crmf" ],
 576
 577     # Padlock engine uses low-level AES APIs which are deprecated
 578     sub { $disabled{"deprecated-3.0"} }
 579           => [ "padlockeng" ]
 580     );
 581
 582 # Avoid protocol support holes.  Also disable all versions below N, if version
 583 # N is disabled while N+1 is enabled.
 584 #
 585 my @list = (reverse @tls);
 586 while ((my $first, my $second) = (shift @list, shift @list)) {
 587     last unless @list;
 588     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 589                               => [ @list ] );
 590     unshift @list, $second;
 591 }
 592 my @list = (reverse @dtls);
 593 while ((my $first, my $second) = (shift @list, shift @list)) {
 594     last unless @list;
 595     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 596                               => [ @list ] );
 597     unshift @list, $second;
 598 }
 599
 600 # Explicit "no-..." options will be collected in %disabled along with the defaults.
 601 # To remove something from %disabled, use "enable-foo".
 602 # For symmetry, "disable-foo" is a synonym for "no-foo".
 603
 604 &usage if ($#ARGV < 0);
 605
 606 # For the "make variables" CPPINCLUDES and CPPDEFINES, we support lists with
 607 # platform specific list separators.  Users from those platforms should
 608 # recognise those separators from how you set up the PATH to find executables.
 609 # The default is the Unix like separator, :, but as an exception, we also
 610 # support the space as separator.
 611 my $list_separator_re =
 612     { VMS           => qr/(?<!\^),/,
 613       MSWin32       => qr/(?<!\\);/ } -> {$^O} // qr/(?<!\\)[:\s]/;
 614 # All the "make variables" we support
 615 # Some get pre-populated for the sake of backward compatibility
 616 # (we supported those before the change to "make variable" support.
 617 my %user = (
 618     AR          => env('AR'),
 619     ARFLAGS     => [],
 620     AS          => undef,
 621     ASFLAGS     => [],
 622     CC          => env('CC'),
 623     CFLAGS      => [ env('CFLAGS') || () ],
 624     CXX         => env('CXX'),
 625     CXXFLAGS    => [ env('CXXFLAGS') || () ],
 626     CPP         => undef,
 627     CPPFLAGS    => [ env('CPPFLAGS') || () ],  # -D, -I, -Wp,
 628     CPPDEFINES  => [],  # Alternative for -D
 629     CPPINCLUDES => [],  # Alternative for -I
 630     CROSS_COMPILE => env('CROSS_COMPILE'),
 631     HASHBANGPERL=> env('HASHBANGPERL') || env('PERL'),
 632     LD          => undef,
 633     LDFLAGS     => [ env('LDFLAGS') || () ],  # -L, -Wl,
 634     LDLIBS      => [ env('LDLIBS') || () ],  # -l
 635     MT          => undef,
 636     MTFLAGS     => [],
 637     PERL        => env('PERL') || ($^O ne "VMS" ? $^X : "perl"),
 638     RANLIB      => env('RANLIB'),
 639     RC          => env('RC') || env('WINDRES'),
 640     RCFLAGS     => [ env('RCFLAGS') || () ],
 641     RM          => undef,
 642    );
 643 # Info about what "make variables" may be prefixed with the cross compiler
 644 # prefix.  This should NEVER mention any such variable with a list for value.
 645 my @user_crossable = qw ( AR AS CC CXX CPP LD MT RANLIB RC );
 646 # The same but for flags given as Configure options.  These are *additional*
 647 # input, as opposed to the VAR=string option that override the corresponding
 648 # config target attributes
 649 my %useradd = (
 650     CPPDEFINES  => [],
 651     CPPINCLUDES => [],
 652     CPPFLAGS    => [],
 653     CFLAGS      => [],
 654     CXXFLAGS    => [],
 655     LDFLAGS     => [],
 656     LDLIBS      => [],
 657     RCFLAGS     => [],
 658    );
 659
 660 my %user_synonyms = (
 661     HASHBANGPERL=> 'PERL',
 662     RC          => 'WINDRES',
 663    );
 664
 665 # Some target attributes have been renamed, this is the translation table
 666 my %target_attr_translate =(
 667     ar          => 'AR',
 668     as          => 'AS',
 669     cc          => 'CC',
 670     cxx         => 'CXX',
 671     cpp         => 'CPP',
 672     hashbangperl => 'HASHBANGPERL',
 673     ld          => 'LD',
 674     mt          => 'MT',
 675     ranlib      => 'RANLIB',
 676     rc          => 'RC',
 677     rm          => 'RM',
 678    );
 679
 680 # Initialisers coming from 'config' scripts
 681 $config{defines} = [ split(/$list_separator_re/, env('__CNF_CPPDEFINES')) ];
 682 $config{includes} = [ split(/$list_separator_re/, env('__CNF_CPPINCLUDES')) ];
 683 $config{cppflags} = [ env('__CNF_CPPFLAGS') || () ];
 684 $config{cflags} = [ env('__CNF_CFLAGS') || () ];
 685 $config{cxxflags} = [ env('__CNF_CXXFLAGS') || () ];
 686 $config{lflags} = [ env('__CNF_LDFLAGS') || () ];
 687 $config{ex_libs} = [ env('__CNF_LDLIBS') || () ];
 688
 689 $config{openssl_api_defines}=[];
 690 $config{openssl_sys_defines}=[];
 691 $config{openssl_feature_defines}=[];
 692 $config{options}="";
 693 $config{build_type} = "release";
 694 my $target="";
 695
 696 my %cmdvars = ();               # Stores FOO='blah' type arguments
 697 my %unsupported_options = ();
 698 my %deprecated_options = ();
 699 # If you change this, update apps/version.c
 700 my @known_seed_sources = qw(getrandom devrandom os egd none rdcpu librandom);
 701 my @seed_sources = ();
 702 while (@argvcopy)
 703         {
 704         $_ = shift @argvcopy;
 705
 706         # Support env variable assignments among the options
 707         if (m|^(\w+)=(.+)?$|)
 708                 {
 709                 $cmdvars{$1} = $2;
 710                 # Every time a variable is given as a configuration argument,
 711                 # it acts as a reset if the variable.
 712                 if (exists $user{$1})
 713                         {
 714                         $user{$1} = ref $user{$1} eq "ARRAY" ? [] : undef;
 715                         }
 716                 #if (exists $useradd{$1})
 717                 #       {
 718                 #       $useradd{$1} = [];
 719                 #       }
 720                 next;
 721                 }
 722
 723         # VMS is a case insensitive environment, and depending on settings
 724         # out of our control, we may receive options uppercased.  Let's
 725         # downcase at least the part before any equal sign.
 726         if ($^O eq "VMS")
 727                 {
 728                 s/^([^=]*)/lc($1)/e;
 729                 }
 730
 731         # some people just can't read the instructions, clang people have to...
 732         s/^-no-(?!integrated-as)/no-/;
 733
 734         # rewrite some options in "enable-..." form
 735         s /^-?-?shared$/enable-shared/;
 736         s /^sctp$/enable-sctp/;
 737         s /^threads$/enable-threads/;
 738         s /^zlib$/enable-zlib/;
 739         s /^zlib-dynamic$/enable-zlib-dynamic/;
 740
 741         if (/^(no|disable|enable)-(.+)$/)
 742                 {
 743                 my $word = $2;
 744                 if ($word !~ m|hw(?:-.+)| # special treatment for hw regexp opt
 745                         && !exists $deprecated_disablables{$word}
 746                         && !grep { $word eq $_ } @disablables)
 747                         {
 748                         $unsupported_options{$_} = 1;
 749                         next;
 750                         }
 751                 }
 752         if (/^no-(.+)$/ || /^disable-(.+)$/)
 753                 {
 754                 foreach my $proto ((@tls, @dtls))
 755                         {
 756                         if ($1 eq "$proto-method")
 757                                 {
 758                                 $disabled{"$proto"} = "option($proto-method)";
 759                                 last;
 760                                 }
 761                         }
 762                 if ($1 eq "dtls")
 763                         {
 764                         foreach my $proto (@dtls)
 765                                 {
 766                                 $disabled{$proto} = "option(dtls)";
 767                                 }
 768                         $disabled{"dtls"} = "option(dtls)";
 769                         }
 770                 elsif ($1 eq "ssl")
 771                         {
 772                         # Last one of its kind
 773                         $disabled{"ssl3"} = "option(ssl)";
 774                         }
 775                 elsif ($1 eq "tls")
 776                         {
 777                         # XXX: Tests will fail if all SSL/TLS
 778                         # protocols are disabled.
 779                         foreach my $proto (@tls)
 780                                 {
 781                                 $disabled{$proto} = "option(tls)";
 782                                 }
 783                         }
 784                 elsif ($1 eq "static-engine")
 785                         {
 786                         delete $disabled{"dynamic-engine"};
 787                         }
 788                 elsif ($1 eq "dynamic-engine")
 789                         {
 790                         $disabled{"dynamic-engine"} = "option";
 791                         }
 792                 elsif (exists $deprecated_disablables{$1})
 793                         {
 794                         $deprecated_options{$_} = 1;
 795                         if (defined $deprecated_disablables{$1})
 796                                 {
 797                                 $disabled{$deprecated_disablables{$1}} = "option";
 798                                 }
 799                         }
 800                 elsif ($1 =~ m|hw(?:-.+)|) # deprecate hw options in regexp form
 801                         {
 802                         $deprecated_options{$_} = 1;
 803                         }
 804                 else
 805                         {
 806                         $disabled{$1} = "option";
 807                         }
 808                 # No longer an automatic choice
 809                 $auto_threads = 0 if ($1 eq "threads");
 810                 }
 811         elsif (/^enable-(.+)$/)
 812                 {
 813                 if ($1 eq "static-engine")
 814                         {
 815                         $disabled{"dynamic-engine"} = "option";
 816                         }
 817                 elsif ($1 eq "dynamic-engine")
 818                         {
 819                         delete $disabled{"dynamic-engine"};
 820                         }
 821                 elsif ($1 eq "zlib-dynamic")
 822                         {
 823                         delete $disabled{"zlib"};
 824                         }
 825                 my $algo = $1;
 826                 delete $disabled{$algo};
 827
 828                 # No longer an automatic choice
 829                 $auto_threads = 0 if ($1 eq "threads");
 830                 }
 831         elsif (/^--strict-warnings$/)
 832                 {
 833                 # Pretend that our strict flags is a C flag, and replace it
 834                 # with the proper flags later on
 835                 push @{$useradd{CFLAGS}}, '--ossl-strict-warnings';
 836                 $strict_warnings=1;
 837                 }
 838         elsif (/^--debug$/)
 839                 {
 840                 $config{build_type} = "debug";
 841                 }
 842         elsif (/^--release$/)
 843                 {
 844                 $config{build_type} = "release";
 845                 }
 846         elsif (/^386$/)
 847                 { $config{processor}=386; }
 848         elsif (/^fips$/)
 849                 {
 850                 die "FIPS mode not supported\n";
 851                 }
 852         elsif (/^rsaref$/)
 853                 {
 854                 # No RSAref support any more since it's not needed.
 855                 # The check for the option is there so scripts aren't
 856                 # broken
 857                 }
 858         elsif (/^nofipscanistercheck$/)
 859                 {
 860                 die "FIPS mode not supported\n";
 861                 }
 862         elsif (m|^[-+/]|)
 863                 {
 864                 if (/^--prefix=(.*)$/)
 865                         {
 866                         $config{prefix}=$1;
 867                         die "Directory given with --prefix MUST be absolute\n"
 868                                 unless file_name_is_absolute($config{prefix});
 869                         }
 870                 elsif (/^--api=(.*)$/)
 871                         {
 872                         my $api = $1;
 873                         die "Unknown API compatibility level $api"
 874                                 unless defined $apitable->{$api};
 875                         $config{api}=$apitable->{$api};
 876                         }
 877                 elsif (/^--libdir=(.*)$/)
 878                         {
 879                         $config{libdir}=$1;
 880                         }
 881                 elsif (/^--openssldir=(.*)$/)
 882                         {
 883                         $config{openssldir}=$1;
 884                         }
 885                 elsif (/^--with-zlib-lib=(.*)$/)
 886                         {
 887                         $withargs{zlib_lib}=$1;
 888                         }
 889                 elsif (/^--with-zlib-include=(.*)$/)
 890                         {
 891                         $withargs{zlib_include}=$1;
 892                         }
 893                 elsif (/^--with-fuzzer-lib=(.*)$/)
 894                         {
 895                         $withargs{fuzzer_lib}=$1;
 896                         }
 897                 elsif (/^--with-fuzzer-include=(.*)$/)
 898                         {
 899                         $withargs{fuzzer_include}=$1;
 900                         }
 901                 elsif (/^--with-rand-seed=(.*)$/)
 902                         {
 903                         foreach my $x (split(m|,|, $1))
 904                             {
 905                             die "Unknown --with-rand-seed choice $x\n"
 906                                 if ! grep { $x eq $_ } @known_seed_sources;
 907                             push @seed_sources, $x;
 908                             }
 909                         }
 910                 elsif (/^--cross-compile-prefix=(.*)$/)
 911                         {
 912                         $user{CROSS_COMPILE}=$1;
 913                         }
 914                 elsif (/^--config=(.*)$/)
 915                         {
 916                         read_config $1;
 917                         }
 918                 elsif (/^-l(.*)$/)
 919                         {
 920                         push @{$useradd{LDLIBS}}, $_;
 921                         }
 922                 elsif (/^-framework$/)
 923                         {
 924                         push @{$useradd{LDLIBS}}, $_, shift(@argvcopy);
 925                         }
 926                 elsif (/^-L(.*)$/ or /^-Wl,/)
 927                         {
 928                         push @{$useradd{LDFLAGS}}, $_;
 929                         }
 930                 elsif (/^-rpath$/ or /^-R$/)
 931                         # -rpath is the OSF1 rpath flag
 932                         # -R is the old Solaris rpath flag
 933                         {
 934                         my $rpath = shift(@argvcopy) || "";
 935                         $rpath .= " " if $rpath ne "";
 936                         push @{$useradd{LDFLAGS}}, $_, $rpath;
 937                         }
 938                 elsif (/^-static$/)
 939                         {
 940                         push @{$useradd{LDFLAGS}}, $_;
 941                         }
 942                 elsif (m|^[-/]D(.*)$|)
 943                         {
 944                         push @{$useradd{CPPDEFINES}}, $1;
 945                         }
 946                 elsif (m|^[-/]I(.*)$|)
 947                         {
 948                         push @{$useradd{CPPINCLUDES}}, $1;
 949                         }
 950                 elsif (/^-Wp,$/)
 951                         {
 952                         push @{$useradd{CPPFLAGS}}, $1;
 953                         }
 954                 else    # common if (/^[-+]/), just pass down...
 955                         {
 956                         # Treat %xx as an ASCII code (e.g. replace %20 by a space character).
 957                         # This provides a simple way to pass options with arguments separated
 958                         # by spaces without quoting (e.g. -opt%20arg translates to -opt arg).
 959                         $_ =~ s/%([0-9a-f]{1,2})/chr(hex($1))/gei;
 960                         push @{$useradd{CFLAGS}}, $_;
 961                         push @{$useradd{CXXFLAGS}}, $_;
 962                         }
 963                 }
 964         elsif (m|^/|)
 965                 {
 966                 # Treat %xx as an ASCII code (e.g. replace %20 by a space character).
 967                 # This provides a simple way to pass options with arguments separated
 968                 # by spaces without quoting (e.g. /opt%20arg translates to /opt arg).
 969                 $_ =~ s/%([0-9a-f]{1,2})/chr(hex($1))/gei;
 970                 push @{$useradd{CFLAGS}}, $_;
 971                 push @{$useradd{CXXFLAGS}}, $_;
 972                 }
 973         else
 974                 {
 975                 die "target already defined - $target (offending arg: $_)\n" if ($target ne "");
 976                 $target=$_;
 977                 }
 978         unless ($_ eq $target || /^no-/ || /^disable-/)
 979                 {
 980                 # "no-..." follows later after implied deactivations
 981                 # have been derived.  (Don't take this too seriously,
 982                 # we really only write OPTIONS to the Makefile out of
 983                 # nostalgia.)
 984
 985                 if ($config{options} eq "")
 986                         { $config{options} = $_; }
 987                 else
 988                         { $config{options} .= " ".$_; }
 989                 }
 990         }
 991
 992 if (keys %deprecated_options)
 993         {
 994         warn "***** Deprecated options: ",
 995                 join(", ", keys %deprecated_options), "\n";
 996         }
 997 if (keys %unsupported_options)
 998         {
 999         die "***** Unsupported options: ",
1000                 join(", ", keys %unsupported_options), "\n";
1001         }
1002
1003 # If any %useradd entry has been set, we must check that the "make
1004 # variables" haven't been set.  We start by checking of any %useradd entry
1005 # is set.
1006 if (grep { scalar @$_ > 0 } values %useradd) {
1007     # Hash of env / make variables names.  The possible values are:
1008     # 1 - "make vars"
1009     # 2 - %useradd entry set
1010     # 3 - both set
1011     my %detected_vars =
1012         map { my $v = 0;
1013               $v += 1 if $cmdvars{$_};
1014               $v += 2 if @{$useradd{$_}};
1015               $_ => $v }
1016         keys %useradd;
1017
1018     # If any of the corresponding "make variables" is set, we error
1019     if (grep { $_ & 1 } values %detected_vars) {
1020         my $names = join(', ', grep { $detected_vars{$_} > 0 }
1021                                sort keys %detected_vars);
1022         die <<"_____";
1023 ***** Mixing make variables and additional compiler/linker flags as
1024 ***** configure command line option is not permitted.
1025 ***** Affected make variables: $names
1026 _____
1027     }
1028 }
1029
1030 # Check through all supported command line variables to see if any of them
1031 # were set, and canonicalise the values we got.  If no compiler or linker
1032 # flag or anything else that affects %useradd was set, we also check the
1033 # environment for values.
1034 my $anyuseradd =
1035     grep { defined $_ && (ref $_ ne 'ARRAY' || @$_) } values %useradd;
1036 foreach (keys %user) {
1037     my $value = $cmdvars{$_};
1038     $value //= env($_) unless $anyuseradd;
1039     $value //=
1040         defined $user_synonyms{$_} ? $cmdvars{$user_synonyms{$_}} : undef;
1041     $value //= defined $user_synonyms{$_} ? env($user_synonyms{$_}) : undef
1042         unless $anyuseradd;
1043
1044     if (defined $value) {
1045         if (ref $user{$_} eq 'ARRAY') {
1046             if ($_ eq 'CPPDEFINES' || $_ eq 'CPPINCLUDES') {
1047                 $user{$_} = [ split /$list_separator_re/, $value ];
1048             } else {
1049                 $user{$_} = [ $value ];
1050             }
1051         } elsif (!defined $user{$_}) {
1052             $user{$_} = $value;
1053         }
1054     }
1055 }
1056
1057 if (grep { /-rpath\b/ } ($user{LDFLAGS} ? @{$user{LDFLAGS}} : ())
1058     && !$disabled{shared}
1059     && !($disabled{asan} && $disabled{msan} && $disabled{ubsan})) {
1060     die "***** Cannot simultaneously use -rpath, shared libraries, and\n",
1061         "***** any of asan, msan or ubsan\n";
1062 }
1063
1064 sub disable {
1065     my $disable_type = shift;
1066
1067     for (@_) {
1068         $disabled{$_} = $disable_type;
1069     }
1070
1071     my @tocheckfor = (@_ ? @_ : keys %disabled);
1072     while (@tocheckfor) {
1073         my %new_tocheckfor = ();
1074         my @cascade_copy = (@disable_cascades);
1075         while (@cascade_copy) {
1076             my ($test, $descendents) =
1077                 (shift @cascade_copy, shift @cascade_copy);
1078             if (ref($test) eq "CODE" ? $test->() : defined($disabled{$test})) {
1079                 foreach (grep { !defined($disabled{$_}) } @$descendents) {
1080                     $new_tocheckfor{$_} = 1; $disabled{$_} = "cascade";
1081                 }
1082             }
1083         }
1084         @tocheckfor = (keys %new_tocheckfor);
1085     }
1086 }
1087 disable();                     # First cascade run
1088
1089 our $die = sub { die @_; };
1090 if ($target eq "TABLE") {
1091     local $die = sub { warn @_; };
1092     foreach (sort keys %table) {
1093         print_table_entry($_, "TABLE");
1094     }
1095     exit 0;
1096 }
1097
1098 if ($target eq "LIST") {
1099     foreach (sort keys %table) {
1100         print $_,"\n" unless $table{$_}->{template};
1101     }
1102     exit 0;
1103 }
1104
1105 if ($target eq "HASH") {
1106     local $die = sub { warn @_; };
1107     print "%table = (\n";
1108     foreach (sort keys %table) {
1109         print_table_entry($_, "HASH");
1110     }
1111     exit 0;
1112 }
1113
1114 print "Configuring OpenSSL version $config{full_version} ";
1115 print "for target $target\n";
1116
1117 if (scalar(@seed_sources) == 0) {
1118     print "Using os-specific seed configuration\n";
1119     push @seed_sources, 'os';
1120 }
1121 if (scalar(grep { $_ eq 'none' } @seed_sources) > 0) {
1122     die "Cannot seed with none and anything else" if scalar(@seed_sources) > 1;
1123     warn <<_____ if scalar(@seed_sources) == 1;
1124
1125 ============================== WARNING ===============================
1126 You have selected the --with-rand-seed=none option, which effectively
1127 disables automatic reseeding of the OpenSSL random generator.
1128 All operations depending on the random generator such as creating keys
1129 will not work unless the random generator is seeded manually by the
1130 application.
1131
1132 Please read the 'Note on random number generation' section in the
1133 INSTALL instructions and the RAND_DRBG(7) manual page for more details.
1134 ============================== WARNING ===============================
1135
1136 _____
1137 }
1138 push @{$config{openssl_feature_defines}},
1139      map { (my $x = $_) =~ tr|[\-a-z]|[_A-Z]|; "OPENSSL_RAND_SEED_$x" }
1140         @seed_sources;
1141
1142 # Backward compatibility?
1143 if ($target =~ m/^CygWin32(-.*)$/) {
1144     $target = "Cygwin".$1;
1145 }
1146
1147 # Support for legacy targets having a name starting with 'debug-'
1148 my ($d, $t) = $target =~ m/^(debug-)?(.*)$/;
1149 if ($d) {
1150     $config{build_type} = "debug";
1151
1152     # If we do not find debug-foo in the table, the target is set to foo.
1153     if (!$table{$target}) {
1154         $target = $t;
1155     }
1156 }
1157
1158 &usage if !$table{$target} || $table{$target}->{template};
1159
1160 $config{target} = $target;
1161 my %target = resolve_config($target);
1162
1163 foreach (keys %target_attr_translate) {
1164     $target{$target_attr_translate{$_}} = $target{$_}
1165         if $target{$_};
1166     delete $target{$_};
1167 }
1168
1169 %target = ( %{$table{DEFAULTS}}, %target );
1170
1171 my %conf_files = map { $_ => 1 } (@{$target{_conf_fname_int}});
1172 $config{conf_files} = [ sort keys %conf_files ];
1173
1174 # Using sub disable within these loops may prove fragile, so we run
1175 # a cascade afterwards
1176 foreach my $feature (@{$target{disable}}) {
1177     if (exists $deprecated_disablables{$feature}) {
1178         warn "***** config $target disables deprecated feature $feature\n";
1179     } elsif (!grep { $feature eq $_ } @disablables) {
1180         die "***** config $target disables unknown feature $feature\n";
1181     }
1182     $disabled{$feature} = 'config';
1183 }
1184 foreach my $feature (@{$target{enable}}) {
1185     if ("default" eq ($disabled{$feature} // "")) {
1186         if (exists $deprecated_disablables{$feature}) {
1187             warn "***** config $target enables deprecated feature $feature\n";
1188         } elsif (!grep { $feature eq $_ } @disablables) {
1189             die "***** config $target enables unknown feature $feature\n";
1190         }
1191         delete $disabled{$feature};
1192     }
1193 }
1194
1195 # If uplink_arch isn't defined, disable uplink
1196 $disabled{uplink} = 'no uplink_arch' unless (defined $target{uplink_arch});
1197 # If asm_arch isn't defined, disable asm
1198 $disabled{asm} = 'no asm_arch' unless (defined $target{asm_arch});
1199
1200 disable();                      # Run a cascade now
1201
1202 $target{CXXFLAGS}//=$target{CFLAGS} if $target{CXX};
1203 $target{cxxflags}//=$target{cflags} if $target{CXX};
1204 $target{exe_extension}=".exe" if ($config{target} eq "DJGPP");
1205 $target{exe_extension}=".pm"  if ($config{target} =~ /vos/);
1206
1207 # Fill %config with values from %user, and in case those are undefined or
1208 # empty, use values from %target (acting as a default).
1209 foreach (keys %user) {
1210     my $ref_type = ref $user{$_};
1211
1212     # Temporary function.  Takes an intended ref type (empty string or "ARRAY")
1213     # and a value that's to be coerced into that type.
1214     my $mkvalue = sub {
1215         my $type = shift;
1216         my $value = shift;
1217         my $undef_p = shift;
1218
1219         die "Too many arguments for \$mkvalue" if @_;
1220
1221         while (ref $value eq 'CODE') {
1222             $value = $value->();
1223         }
1224
1225         if ($type eq 'ARRAY') {
1226             return undef unless defined $value;
1227             return undef if ref $value ne 'ARRAY' && !$value;
1228             return undef if ref $value eq 'ARRAY' && !@$value;
1229             return [ $value ] unless ref $value eq 'ARRAY';
1230         }
1231         return undef unless $value;
1232         return $value;
1233     };
1234
1235     $config{$_} =
1236         $mkvalue->($ref_type, $user{$_})
1237         || $mkvalue->($ref_type, $target{$_});
1238     delete $config{$_} unless defined $config{$_};
1239 }
1240
1241 # Finish up %config by appending things the user gave us on the command line
1242 # apart from "make variables"
1243 foreach (keys %useradd) {
1244     # The must all be lists, so we assert that here
1245     die "internal error: \$useradd{$_} isn't an ARRAY\n"
1246         unless ref $useradd{$_} eq 'ARRAY';
1247
1248     if (defined $config{$_}) {
1249         push @{$config{$_}}, @{$useradd{$_}};
1250     } else {
1251         $config{$_} = [ @{$useradd{$_}} ];
1252     }
1253 }
1254 # At this point, we can forget everything about %user and %useradd,
1255 # because it's now all been merged into the corresponding $config entry
1256
1257 # Allow overriding the build file name
1258 $config{build_file} = env('BUILDFILE') || $target{build_file} || "Makefile";
1259
1260 # Make sure build_scheme is consistent.
1261 $target{build_scheme} = [ $target{build_scheme} ]
1262     if ref($target{build_scheme}) ne "ARRAY";
1263
1264 my ($builder, $builder_platform, @builder_opts) =
1265     @{$target{build_scheme}};
1266
1267 foreach my $checker (($builder_platform."-".$target{build_file}."-checker.pm",
1268                       $builder_platform."-checker.pm")) {
1269     my $checker_path = catfile($srcdir, "Configurations", $checker);
1270     if (-f $checker_path) {
1271         my $fn = $ENV{CONFIGURE_CHECKER_WARN}
1272             ? sub { warn $@; } : sub { die $@; };
1273         if (! do $checker_path) {
1274             if ($@) {
1275                 $fn->($@);
1276             } elsif ($!) {
1277                 $fn->($!);
1278             } else {
1279                 $fn->("The detected tools didn't match the platform\n");
1280             }
1281         }
1282         last;
1283     }
1284 }
1285
1286 push @{$config{defines}}, "NDEBUG"    if $config{build_type} eq "release";
1287
1288 if ($target =~ /^mingw/ && `$config{CC} --target-help 2>&1` =~ m/-mno-cygwin/m)
1289         {
1290         push @{$config{cflags}}, "-mno-cygwin";
1291         push @{$config{cxxflags}}, "-mno-cygwin" if $config{CXX};
1292         push @{$config{shared_ldflag}}, "-mno-cygwin";
1293         }
1294
1295 if ($target =~ /linux.*-mips/ && !$disabled{asm}
1296         && !grep { $_ !~ /-m(ips|arch=)/ } (@{$config{CFLAGS}})) {
1297         # minimally required architecture flags for assembly modules
1298         my $value;
1299         $value = '-mips2' if ($target =~ /mips32/);
1300         $value = '-mips3' if ($target =~ /mips64/);
1301         unshift @{$config{cflags}}, $value;
1302         unshift @{$config{cxxflags}}, $value if $config{CXX};
1303 }
1304
1305 # If threads aren't disabled, check how possible they are
1306 unless ($disabled{threads}) {
1307     if ($auto_threads) {
1308         # Enabled by default, disable it forcibly if unavailable
1309         if ($target{thread_scheme} eq "(unknown)") {
1310             disable("unavailable", 'threads');
1311         }
1312     } else {
1313         # The user chose to enable threads explicitly, let's see
1314         # if there's a chance that's possible
1315         if ($target{thread_scheme} eq "(unknown)") {
1316             # If the user asked for "threads" and we don't have internal
1317             # knowledge how to do it, [s]he is expected to provide any
1318             # system-dependent compiler options that are necessary.  We
1319             # can't truly check that the given options are correct, but
1320             # we expect the user to know what [s]He is doing.
1321             if (!@{$config{CFLAGS}} && !@{$config{CPPDEFINES}}) {
1322                 die "You asked for multi-threading support, but didn't\n"
1323                     ,"provide any system-specific compiler options\n";
1324             }
1325         }
1326     }
1327 }
1328
1329 # Find out if clang's sanitizers have been enabled with -fsanitize
1330 # flags and ensure that the corresponding %disabled elements area
1331 # removed to reflect that the sanitizers are indeed enabled.
1332 my %detected_sanitizers = ();
1333 foreach (grep /^-fsanitize=/, @{$config{CFLAGS} || []}) {
1334     (my $checks = $_) =~ s/^-fsanitize=//;
1335     foreach (split /,/, $checks) {
1336         my $d = { address       => 'asan',
1337                   undefined     => 'ubsan',
1338                   memory        => 'msan' } -> {$_};
1339         next unless defined $d;
1340
1341         $detected_sanitizers{$d} = 1;
1342         if (defined $disabled{$d}) {
1343             die "***** Conflict between disabling $d and enabling $_ sanitizer"
1344                 if $disabled{$d} ne "default";
1345             delete $disabled{$d};
1346         }
1347     }
1348 }
1349
1350 # If threads still aren't disabled, add a C macro to ensure the source
1351 # code knows about it.  Any other flag is taken care of by the configs.
1352 unless($disabled{threads}) {
1353     push @{$config{openssl_feature_defines}}, "OPENSSL_THREADS";
1354 }
1355
1356 my $no_shared_warn=0;
1357 if ($target{shared_target} eq "")
1358         {
1359         $no_shared_warn = 1
1360             if (!$disabled{shared} || !$disabled{"dynamic-engine"});
1361         disable('no-shared-target', 'pic');
1362         }
1363
1364 if ($disabled{"dynamic-engine"}) {
1365         $config{dynamic_engines} = 0;
1366 } else {
1367         $config{dynamic_engines} = 1;
1368 }
1369
1370 unless ($disabled{asan} || defined $detected_sanitizers{asan}) {
1371     push @{$config{cflags}}, "-fsanitize=address";
1372 }
1373
1374 unless ($disabled{ubsan} || defined $detected_sanitizers{ubsan}) {
1375     # -DPEDANTIC or -fnosanitize=alignment may also be required on some
1376     # platforms.
1377     push @{$config{cflags}}, "-fsanitize=undefined", "-fno-sanitize-recover=all";
1378 }
1379
1380 unless ($disabled{msan} || defined $detected_sanitizers{msan}) {
1381   push @{$config{cflags}}, "-fsanitize=memory";
1382 }
1383
1384 unless ($disabled{"fuzz-libfuzzer"} && $disabled{"fuzz-afl"}
1385         && $disabled{asan} && $disabled{ubsan} && $disabled{msan}) {
1386     push @{$config{cflags}}, "-fno-omit-frame-pointer", "-g";
1387     push @{$config{cxxflags}}, "-fno-omit-frame-pointer", "-g" if $config{CXX};
1388 }
1389 #
1390 # Platform fix-ups
1391 #
1392
1393 # This saves the build files from having to check
1394 if ($disabled{pic})
1395         {
1396         foreach (qw(shared_cflag shared_cxxflag shared_cppflag
1397                     shared_defines shared_includes shared_ldflag
1398                     module_cflags module_cxxflags module_cppflags
1399                     module_defines module_includes module_lflags))
1400                 {
1401                 delete $config{$_};
1402                 $target{$_} = "";
1403                 }
1404         }
1405 else
1406         {
1407         push @{$config{lib_defines}}, "OPENSSL_PIC";
1408         }
1409
1410 if ($target{sys_id} ne "")
1411         {
1412         push @{$config{openssl_sys_defines}}, "OPENSSL_SYS_$target{sys_id}";
1413         }
1414
1415 my %predefined_C = compiler_predefined($config{CROSS_COMPILE}.$config{CC});
1416 my %predefined_CXX = $config{CXX}
1417     ? compiler_predefined($config{CROSS_COMPILE}.$config{CXX})
1418     : ();
1419
1420 unless ($disabled{asm}) {
1421     # big endian systems can use ELFv2 ABI
1422     if ($target eq "linux-ppc64") {
1423         $target{perlasm_scheme} = "linux64v2" if ($predefined_C{_CALL_ELF} == 2);
1424     }
1425 }
1426
1427 # Check for makedepend capabilities.
1428 if (!$disabled{makedepend}) {
1429     if ($config{target} =~ /^(VC|vms)-/) {
1430         # For VC- and vms- targets, there's nothing more to do here.  The
1431         # functionality is hard coded in the corresponding build files for
1432         # cl (Windows) and CC/DECC (VMS).
1433     } elsif (($predefined_C{__GNUC__} // -1) >= 3
1434              && !($predefined_C{__APPLE_CC__} && !$predefined_C{__clang__})) {
1435         # We know that GNU C version 3 and up as well as all clang
1436         # versions support dependency generation, but Xcode did not
1437         # handle $cc -M before clang support (but claims __GNUC__ = 3)
1438         $config{makedepprog} = "\$(CROSS_COMPILE)$config{CC}";
1439     } else {
1440         # In all other cases, we look for 'makedepend', and disable the
1441         # capability if not found.
1442         $config{makedepprog} = which('makedepend');
1443         disable('unavailable', 'makedepend') unless $config{makedepprog};
1444     }
1445 }
1446
1447 if (!$disabled{asm} && !$predefined_C{__MACH__} && $^O ne 'VMS') {
1448     # probe for -Wa,--noexecstack option...
1449     if ($predefined_C{__clang__}) {
1450         # clang has builtin assembler, which doesn't recognize --help,
1451         # but it apparently recognizes the option in question on all
1452         # supported platforms even when it's meaningless. In other words
1453         # probe would fail, but probed option always accepted...
1454         push @{$config{cflags}}, "-Wa,--noexecstack", "-Qunused-arguments";
1455     } else {
1456         my $cc = $config{CROSS_COMPILE}.$config{CC};
1457         open(PIPE, "$cc -Wa,--help -c -o null.$$.o -x assembler /dev/null 2>&1 |");
1458         while(<PIPE>) {
1459             if (m/--noexecstack/) {
1460                 push @{$config{cflags}}, "-Wa,--noexecstack";
1461                 last;
1462             }
1463         }
1464         close(PIPE);
1465         unlink("null.$$.o");
1466     }
1467 }
1468
1469 # Deal with bn_ops ###################################################
1470
1471 $config{bn_ll}                  =0;
1472 my $def_int="unsigned int";
1473 $config{rc4_int}                =$def_int;
1474 ($config{b64l},$config{b64},$config{b32})=(0,0,1);
1475
1476 my $count = 0;
1477 foreach (sort split(/\s+/,$target{bn_ops})) {
1478     $count++ if /SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT/;
1479     $config{bn_ll}=1                            if $_ eq 'BN_LLONG';
1480     $config{rc4_int}="unsigned char"            if $_ eq 'RC4_CHAR';
1481     ($config{b64l},$config{b64},$config{b32})
1482         =(0,1,0)                                if $_ eq 'SIXTY_FOUR_BIT';
1483     ($config{b64l},$config{b64},$config{b32})
1484         =(1,0,0)                                if $_ eq 'SIXTY_FOUR_BIT_LONG';
1485     ($config{b64l},$config{b64},$config{b32})
1486         =(0,0,1)                                if $_ eq 'THIRTY_TWO_BIT';
1487 }
1488 die "Exactly one of SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT can be set in bn_ops\n"
1489     if $count > 1;
1490
1491 $config{api} = $config{major} * 10000 + $config{minor} * 100
1492     unless $config{api};
1493 foreach (keys %$apitable) {
1494     $disabled{"deprecated-$_"} = "deprecation"
1495         if $disabled{deprecated} && $config{api} >= $apitable->{$_};
1496 }
1497
1498 disable();                      # Run a cascade now
1499
1500 # Hack cflags for better warnings (dev option) #######################
1501
1502 # "Stringify" the C and C++ flags string.  This permits it to be made part of
1503 # a string and works as well on command lines.
1504 $config{cflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1505                         @{$config{cflags}} ];
1506 $config{cxxflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1507                           @{$config{cxxflags}} ] if $config{CXX};
1508
1509 $config{openssl_api_defines} = [
1510     "OPENSSL_CONFIGURED_API=".$config{api},
1511 ];
1512
1513 my @strict_warnings_collection=();
1514 if ($strict_warnings)
1515         {
1516         my $wopt;
1517         my $gccver = $predefined_C{__GNUC__} // -1;
1518
1519         if ($gccver >= 4)
1520                 {
1521                 push @strict_warnings_collection, @gcc_devteam_warn;
1522                 push @strict_warnings_collection, @clang_devteam_warn
1523                     if (defined($predefined_C{__clang__}));
1524                 }
1525         elsif ($config{target} =~ /^VC-/)
1526                 {
1527                 push @strict_warnings_collection, @cl_devteam_warn;
1528                 }
1529         else
1530                 {
1531                 warn "WARNING --strict-warnings requires gcc[>=4] or gcc-alike, or MSVC"
1532                 }
1533         }
1534
1535 if (grep { $_ =~ /(?:^|\s)-static(?:\s|$)/ } @{$config{LDFLAGS}}) {
1536     disable('static', 'pic', 'threads');
1537 }
1538
1539 $config{CFLAGS} = [ map { $_ eq '--ossl-strict-warnings'
1540                               ? @strict_warnings_collection
1541                               : ( $_ ) }
1542                     @{$config{CFLAGS}} ];
1543
1544 unless ($disabled{afalgeng}) {
1545     $config{afalgeng}="";
1546     if (grep { $_ eq 'afalgeng' } @{$target{enable}}) {
1547         my $minver = 4*10000 + 1*100 + 0;
1548         if ($config{CROSS_COMPILE} eq "") {
1549             my $verstr = `uname -r`;
1550             my ($ma, $mi1, $mi2) = split("\\.", $verstr);
1551             ($mi2) = $mi2 =~ /(\d+)/;
1552             my $ver = $ma*10000 + $mi1*100 + $mi2;
1553             if ($ver < $minver) {
1554                 disable('too-old-kernel', 'afalgeng');
1555             } else {
1556                 push @{$config{engdirs}}, "afalg";
1557             }
1558         } else {
1559             disable('cross-compiling', 'afalgeng');
1560         }
1561     } else {
1562         disable('not-linux', 'afalgeng');
1563     }
1564 }
1565
1566 unless ($disabled{devcryptoeng}) {
1567     if ($target =~ m/^BSD/) {
1568         my $maxver = 5*100 + 7;
1569         my $sysstr = `uname -s`;
1570         my $verstr = `uname -r`;
1571         $sysstr =~ s|\R$||;
1572         $verstr =~ s|\R$||;
1573         my ($ma, $mi, @rest) = split m|\.|, $verstr;
1574         my $ver = $ma*100 + $mi;
1575         if ($sysstr eq 'OpenBSD' && $ver >= $maxver) {
1576             disable('too-new-kernel', 'devcryptoeng');
1577         }
1578     }
1579 }
1580
1581 unless ($disabled{ktls}) {
1582     $config{ktls}="";
1583     if ($target =~ m/^linux/) {
1584         my $usr = "/usr/$config{cross_compile_prefix}";
1585         chop($usr);
1586         if ($config{cross_compile_prefix} eq "") {
1587             $usr = "/usr";
1588         }
1589         my $minver = (4 << 16) + (13 << 8) + 0;
1590         my @verstr = split(" ",`cat $usr/include/linux/version.h | grep LINUX_VERSION_CODE`);
1591
1592         if ($verstr[2] < $minver) {
1593             disable('too-old-kernel', 'ktls');
1594         }
1595     } elsif ($target =~ m/^BSD/) {
1596         my $cc = $config{CROSS_COMPILE}.$config{CC};
1597         system("printf '#include <sys/types.h>\n#include <sys/ktls.h>' | $cc -E - >/dev/null 2>&1");
1598         if ($? != 0) {
1599             disable('too-old-freebsd', 'ktls');
1600         }
1601     } else {
1602         disable('not-linux-or-freebsd', 'ktls');
1603     }
1604 }
1605
1606 push @{$config{openssl_other_defines}}, "OPENSSL_NO_KTLS" if ($disabled{ktls});
1607
1608 # Get the extra flags used when building shared libraries and modules.  We
1609 # do this late because some of them depend on %disabled.
1610
1611 # Make the flags to build DSOs the same as for shared libraries unless they
1612 # are already defined
1613 $target{module_cflags} = $target{shared_cflag} unless defined $target{module_cflags};
1614 $target{module_cxxflags} = $target{shared_cxxflag} unless defined $target{module_cxxflags};
1615 $target{module_ldflags} = $target{shared_ldflag} unless defined $target{module_ldflags};
1616 {
1617     my $shared_info_pl =
1618         catfile(dirname($0), "Configurations", "shared-info.pl");
1619     my %shared_info = read_eval_file($shared_info_pl);
1620     push @{$target{_conf_fname_int}}, $shared_info_pl;
1621     my $si = $target{shared_target};
1622     while (ref $si ne "HASH") {
1623         last if ! defined $si;
1624         if (ref $si eq "CODE") {
1625             $si = $si->();
1626         } else {
1627             $si = $shared_info{$si};
1628         }
1629     }
1630
1631     # Some of the 'shared_target' values don't have any entries in
1632     # %shared_info.  That's perfectly fine, AS LONG AS the build file
1633     # template knows how to handle this.  That is currently the case for
1634     # Windows and VMS.
1635     if (defined $si) {
1636         # Just as above, copy certain shared_* attributes to the corresponding
1637         # module_ attribute unless the latter is already defined
1638         $si->{module_cflags} = $si->{shared_cflag} unless defined $si->{module_cflags};
1639         $si->{module_cxxflags} = $si->{shared_cxxflag} unless defined $si->{module_cxxflags};
1640         $si->{module_ldflags} = $si->{shared_ldflag} unless defined $si->{module_ldflags};
1641         foreach (sort keys %$si) {
1642             $target{$_} = defined $target{$_}
1643                 ? add($si->{$_})->($target{$_})
1644                 : $si->{$_};
1645         }
1646     }
1647 }
1648
1649 # ALL MODIFICATIONS TO %disabled, %config and %target MUST BE DONE FROM HERE ON
1650
1651 ######################################################################
1652 # Build up information for skipping certain directories depending on disabled
1653 # features, as well as setting up macros for disabled features.
1654
1655 # This is a tentative database of directories to skip.  Some entries may not
1656 # correspond to anything real, but that's ok, they will simply be ignored.
1657 # The actual processing of these entries is done in the build.info lookup
1658 # loop further down.
1659 #
1660 # The key is a Unix formatted path in the source tree, the value is an index
1661 # into %disabled_info, so any existing path gets added to a corresponding
1662 # 'skipped' entry in there with the list of skipped directories.
1663 my %skipdir = ();
1664 my %disabled_info = ();         # For configdata.pm
1665 foreach my $what (sort keys %disabled) {
1666     # There are deprecated disablables that translate to themselves.
1667     # They cause disabling cascades, but should otherwise not regiter.
1668     next if $deprecated_disablables{$what};
1669     # The generated $disabled{"deprecated-x.y"} entries are special
1670     # and treated properly elsewhere
1671     next if $what =~ m|^deprecated-|;
1672
1673     $config{options} .= " no-$what";
1674
1675     if (!grep { $what eq $_ } ( 'buildtest-c++', 'fips', 'threads', 'shared',
1676                                 'module', 'pic', 'dynamic-engine', 'makedepend',
1677                                 'zlib-dynamic', 'zlib', 'sse2', 'legacy' )) {
1678         (my $WHAT = uc $what) =~ s|-|_|g;
1679         my $skipdir = $what;
1680
1681         # fix-up crypto/directory name(s)
1682         $skipdir = "ripemd" if $what eq "rmd160";
1683         $skipdir = "whrlpool" if $what eq "whirlpool";
1684
1685         my $macro = $disabled_info{$what}->{macro} = "OPENSSL_NO_$WHAT";
1686         push @{$config{openssl_feature_defines}}, $macro;
1687
1688         $skipdir{engines} = $what if $what eq 'engine';
1689         $skipdir{"crypto/$skipdir"} = $what
1690             unless $what eq 'async' || $what eq 'err' || $what eq 'dso';
1691     }
1692 }
1693
1694 if ($disabled{"dynamic-engine"}) {
1695     push @{$config{openssl_feature_defines}}, "OPENSSL_NO_DYNAMIC_ENGINE";
1696 } else {
1697     push @{$config{openssl_feature_defines}}, "OPENSSL_NO_STATIC_ENGINE";
1698 }
1699
1700 # If we use the unified build, collect information from build.info files
1701 my %unified_info = ();
1702
1703 my $buildinfo_debug = defined($ENV{CONFIGURE_DEBUG_BUILDINFO});
1704 if ($builder eq "unified") {
1705     use Text::Template 1.46;
1706
1707     sub cleandir {
1708         my $base = shift;
1709         my $dir = shift;
1710         my $relativeto = shift || ".";
1711
1712         $dir = catdir($base,$dir) unless isabsolute($dir);
1713
1714         # Make sure the directories we're building in exists
1715         mkpath($dir);
1716
1717         my $res = abs2rel(absolutedir($dir), rel2abs($relativeto));
1718         #print STDERR "DEBUG[cleandir]: $dir , $base => $res\n";
1719         return $res;
1720     }
1721
1722     sub cleanfile {
1723         my $base = shift;
1724         my $file = shift;
1725         my $relativeto = shift || ".";
1726
1727         $file = catfile($base,$file) unless isabsolute($file);
1728
1729         my $d = dirname($file);
1730         my $f = basename($file);
1731
1732         # Make sure the directories we're building in exists
1733         mkpath($d);
1734
1735         my $res = abs2rel(catfile(absolutedir($d), $f), rel2abs($relativeto));
1736         #print STDERR "DEBUG[cleanfile]: $d , $f => $res\n";
1737         return $res;
1738     }
1739
1740     # Store the name of the template file we will build the build file from
1741     # in %config.  This may be useful for the build file itself.
1742     my @build_file_template_names =
1743         ( $builder_platform."-".$target{build_file}.".tmpl",
1744           $target{build_file}.".tmpl" );
1745     my @build_file_templates = ();
1746
1747     # First, look in the user provided directory, if given
1748     if (defined env($local_config_envname)) {
1749         @build_file_templates =
1750             map {
1751                 if ($^O eq 'VMS') {
1752                     # VMS environment variables are logical names,
1753                     # which can be used as is
1754                     $local_config_envname . ':' . $_;
1755                 } else {
1756                     catfile(env($local_config_envname), $_);
1757                 }
1758             }
1759             @build_file_template_names;
1760     }
1761     # Then, look in our standard directory
1762     push @build_file_templates,
1763         ( map { cleanfile($srcdir, catfile("Configurations", $_), $blddir) }
1764           @build_file_template_names );
1765
1766     my $build_file_template;
1767     for $_ (@build_file_templates) {
1768         $build_file_template = $_;
1769         last if -f $build_file_template;
1770
1771         $build_file_template = undef;
1772     }
1773     if (!defined $build_file_template) {
1774         die "*** Couldn't find any of:\n", join("\n", @build_file_templates), "\n";
1775     }
1776     $config{build_file_templates}
1777       = [ cleanfile($srcdir, catfile("Configurations", "common0.tmpl"),
1778                     $blddir),
1779           $build_file_template,
1780           cleanfile($srcdir, catfile("Configurations", "common.tmpl"),
1781                     $blddir) ];
1782
1783     my @build_dirs = ( [ ] );   # current directory
1784
1785     $config{build_infos} = [ ];
1786
1787     my %ordinals = ();
1788     while (@build_dirs) {
1789         my @curd = @{shift @build_dirs};
1790         my $sourced = catdir($srcdir, @curd);
1791         my $buildd = catdir($blddir, @curd);
1792
1793         my $unixdir = join('/', @curd);
1794         if (exists $skipdir{$unixdir}) {
1795             my $what = $skipdir{$unixdir};
1796             push @{$disabled_info{$what}->{skipped}}, catdir(@curd);
1797             next;
1798         }
1799
1800         mkpath($buildd);
1801
1802         my $f = 'build.info';
1803         # The basic things we're trying to build
1804         my @programs = ();
1805         my @libraries = ();
1806         my @modules = ();
1807         my @scripts = ();
1808
1809         my %sources = ();
1810         my %shared_sources = ();
1811         my %includes = ();
1812         my %defines = ();
1813         my %depends = ();
1814         my %generate = ();
1815         my %htmldocs = ();
1816         my %mandocs = ();
1817
1818         # Support for $variablename in build.info files.
1819         # Embedded perl code is the ultimate master, still.  If its output
1820         # contains a dollar sign, it had better be escaped, or it will be
1821         # taken for a variable name prefix.
1822         my %variables = ();
1823         # Variable name syntax
1824         my $variable_name_re = qr/(?P<VARIABLE>[[:alpha:]][[:alnum:]_]*)/;
1825         # Value modifier syntaxes
1826         my $variable_subst_re = qr/\/(?P<RE>(?:\\\/|.)*?)\/(?P<SUBST>.*?)/;
1827         # Put it all together
1828         my $variable_re = qr/\$
1829                              (?|
1830                                  # Simple case, just the name
1831                                  ${variable_name_re}
1832                              |
1833                                  # Expressive case, with braces and possible
1834                                  # modifier expressions
1835                                  \{
1836                                  ${variable_name_re}
1837                                  (?:
1838                                      # Pile on modifier expressions,
1839                                      # separated by |
1840                                      ${variable_subst_re}
1841                                  )
1842                                  \}
1843                              )/x;
1844         my $expand_variables = sub {
1845             my $value = '';
1846             my $value_rest = shift;
1847
1848             if ($ENV{CONFIGURE_DEBUG_VARIABLE_EXPAND}) {
1849                 print STDERR
1850                     "DEBUG[\$expand_variables] Parsed '$value_rest' ...\n"
1851             }
1852             while ($value_rest =~ /(?<!\\)${variable_re}/) {
1853                 $value_rest = $';
1854                 $value .= $`;
1855
1856                 my $variable_value = $variables{$+{VARIABLE}};
1857
1858                 # Process modifier expressions, if present
1859                 if (defined $+{RE}) {
1860                     # We must save important %+ values, because the s///
1861                     # below clears them
1862                     my $re = $+{RE};
1863                     my $subst = $+{SUBST};
1864
1865                     $variable_value =~ s/\Q$re\E/$subst/g;
1866
1867                     if ($ENV{CONFIGURE_DEBUG_VARIABLE_EXPAND}) {
1868                         print STDERR
1869                             "DEBUG[\$expand_variables] ... and substituted ",
1870                             "'$re' with '$subst'\n";
1871                     }
1872                 }
1873
1874                 $value .= $variable_value;
1875             }
1876             if ($ENV{CONFIGURE_DEBUG_VARIABLE_EXPAND}) {
1877                 print STDERR
1878                     "DEBUG[\$expand_variables] ... into: '$value$value_rest'\n";
1879             }
1880             return $value . $value_rest;
1881         };
1882
1883         # Support for attributes in build.info files
1884         my %attributes = ();
1885         my $handle_attributes = sub {
1886             my $attr_str = shift;
1887             my $ref = shift;
1888             my @goals = @_;
1889
1890             return unless defined $attr_str;
1891
1892             my @a = tokenize($attr_str, qr|\s*,\s*|);
1893             foreach my $a (@a) {
1894                 my $ac = 1;
1895                 my $ak = $a;
1896                 my $av = 1;
1897                 if ($a =~ m|^(!)?(.*?)\s* = \s*(.*?)$|) {
1898                     $ac = ! $1;
1899                     $ak = $1;
1900                     $av = $2;
1901                 }
1902                 foreach my $g (@goals) {
1903                     if ($ac) {
1904                         $$ref->{$g}->{$ak} = $av;
1905                     } else {
1906                         delete $$ref->{$g}->{$ak};
1907                     }
1908                 }
1909             }
1910         };
1911
1912         # Support for pushing values on multiple indexes of a given hash
1913         # array.
1914         my $push_to = sub {
1915             my $valueref = shift;
1916             my $index_str = shift; # May be undef or empty
1917             my $attrref = shift;   # May be undef
1918             my $attr_str = shift;
1919             my @values = @_;
1920
1921             if (defined $index_str) {
1922                 my @indexes = ( '' );
1923                 if ($index_str !~ m|^\s*$|) {
1924                     @indexes = tokenize($index_str);
1925                 }
1926                 foreach (@indexes) {
1927                     push @{$valueref->{$_}}, @values;
1928                     if (defined $attrref) {
1929                         $handle_attributes->($attr_str, \$$attrref->{$_},
1930                                              @values);
1931                     }
1932                 }
1933             } else {
1934                 push @$valueref, @values;
1935                 $handle_attributes->($attr_str, $attrref, @values)
1936                     if defined $attrref;
1937             }
1938         };
1939
1940         # We want to detect configdata.pm in the source tree, so we
1941         # don't use it if the build tree is different.
1942         my $src_configdata = cleanfile($srcdir, "configdata.pm", $blddir);
1943
1944
1945         if ($buildinfo_debug) {
1946             print STDERR "DEBUG: Reading ",catfile($sourced, $f),"\n";
1947         }
1948         push @{$config{build_infos}}, catfile(abs2rel($sourced, $blddir), $f);
1949         my $template =
1950             Text::Template->new(TYPE => 'FILE',
1951                                 SOURCE => catfile($sourced, $f),
1952                                 PREPEND => qq{use lib "$FindBin::Bin/util/perl";});
1953         die "Something went wrong with $sourced/$f: $!\n" unless $template;
1954         my @text =
1955             split /^/m,
1956             $template->fill_in(HASH => { config => \%config,
1957                                          target => \%target,
1958                                          disabled => \%disabled,
1959                                          withargs => \%withargs,
1960                                          builddir => abs2rel($buildd, $blddir),
1961                                          sourcedir => abs2rel($sourced, $blddir),
1962                                          buildtop => abs2rel($blddir, $blddir),
1963                                          sourcetop => abs2rel($srcdir, $blddir) },
1964                                DELIMITERS => [ "{-", "-}" ]);
1965
1966         # The top item of this stack has the following values
1967         # -2 positive already run and we found ELSE (following ELSIF should fail)
1968         # -1 positive already run (skip until ENDIF)
1969         # 0 negatives so far (if we're at a condition, check it)
1970         # 1 last was positive (don't skip lines until next ELSE, ELSIF or ENDIF)
1971         # 2 positive ELSE (following ELSIF should fail)
1972         my @skip = ();
1973
1974         # A few useful generic regexps
1975         my $index_re = qr/\[\s*(?P<INDEX>(?:\\.|.)*?)\s*\]/;
1976         my $cond_re = qr/\[\s*(?P<COND>(?:\\.|.)*?)\s*\]/;
1977         my $attribs_re = qr/(?:\{\s*(?P<ATTRIBS>(?:\\.|.)*?)\s*\})?/;
1978         my $value_re = qr/\s*(?P<VALUE>.*?)\s*/;
1979         collect_information(
1980             collect_from_array([ @text ],
1981                                qr/\\$/ => sub { my $l1 = shift; my $l2 = shift;
1982                                                 $l1 =~ s/\\$//; $l1.$l2 }),
1983             # Info we're looking for
1984             qr/^\s* IF ${cond_re} \s*$/x
1985             => sub {
1986                 if (! @skip || $skip[$#skip] > 0) {
1987                     push @skip, !! $expand_variables->($+{COND});
1988                 } else {
1989                     push @skip, -1;
1990                 }
1991             },
1992             qr/^\s* ELSIF ${cond_re} \s*$/x
1993             => sub { die "ELSIF out of scope" if ! @skip;
1994                      die "ELSIF following ELSE" if abs($skip[$#skip]) == 2;
1995                      $skip[$#skip] = -1 if $skip[$#skip] != 0;
1996                      $skip[$#skip] = !! $expand_variables->($+{COND})
1997                          if $skip[$#skip] == 0; },
1998             qr/^\s* ELSE \s*$/x
1999             => sub { die "ELSE out of scope" if ! @skip;
2000                      $skip[$#skip] = -2 if $skip[$#skip] != 0;
2001                      $skip[$#skip] = 2 if $skip[$#skip] == 0; },
2002             qr/^\s* ENDIF \s*$/x
2003             => sub { die "ENDIF out of scope" if ! @skip;
2004                      pop @skip; },
2005             qr/^\s* ${variable_re} \s* = ${value_re} $/x
2006             => sub {
2007                 if (!@skip || $skip[$#skip] > 0) {
2008                     $variables{$+{VARIABLE}} = $expand_variables->($+{VALUE});
2009                 }
2010             },
2011             qr/^\s* SUBDIRS \s* = ${value_re} $/x
2012             => sub {
2013                 if (!@skip || $skip[$#skip] > 0) {
2014                     foreach (tokenize($expand_variables->($+{VALUE}))) {
2015                         push @build_dirs, [ @curd, splitdir($_, 1) ];
2016                     }
2017                 }
2018             },
2019             qr/^\s* PROGRAMS ${attribs_re} \s* =  ${value_re} $/x
2020             => sub { $push_to->(\@programs, undef,
2021                                 \$attributes{programs}, $+{ATTRIBS},
2022                                 tokenize($expand_variables->($+{VALUE})))
2023                          if !@skip || $skip[$#skip] > 0; },
2024             qr/^\s* LIBS ${attribs_re} \s* =  ${value_re} $/x
2025             => sub { $push_to->(\@libraries, undef,
2026                                 \$attributes{libraries}, $+{ATTRIBS},
2027                                 tokenize($expand_variables->($+{VALUE})))
2028                          if !@skip || $skip[$#skip] > 0; },
2029             qr/^\s* MODULES ${attribs_re} \s* =  ${value_re} $/x
2030             => sub { $push_to->(\@modules, undef,
2031                                 \$attributes{modules}, $+{ATTRIBS},
2032                                 tokenize($expand_variables->($+{VALUE})))
2033                          if !@skip || $skip[$#skip] > 0; },
2034             qr/^\s* SCRIPTS ${attribs_re} \s* =  ${value_re} $/x
2035             => sub { $push_to->(\@scripts, undef,
2036                                 \$attributes{scripts}, $+{ATTRIBS},
2037                                 tokenize($expand_variables->($+{VALUE})))
2038                          if !@skip || $skip[$#skip] > 0; },
2039             qr/^\s* HTMLDOCS ${index_re} = ${value_re} $/x
2040             => sub { $push_to->(\%htmldocs, $expand_variables->($+{INDEX}),
2041                                 undef, undef,
2042                                 tokenize($expand_variables->($+{VALUE})))
2043                          if !@skip || $skip[$#skip] > 0; },
2044             qr/^\s* MANDOCS ${index_re} = ${value_re} $/x
2045             => sub { $push_to->(\%mandocs, $expand_variables->($+{INDEX}),
2046                                 undef, undef,
2047                                 tokenize($expand_variables->($+{VALUE})))
2048                          if !@skip || $skip[$#skip] > 0; },
2049             qr/^\s* SOURCE ${index_re} = ${value_re} $/x
2050             => sub { $push_to->(\%sources, $expand_variables->($+{INDEX}),
2051                                 undef, undef,
2052                                 tokenize($expand_variables->($+{VALUE})))
2053                          if !@skip || $skip[$#skip] > 0; },
2054             qr/^\s* SHARED_SOURCE ${index_re} = ${value_re} $/x
2055             => sub { $push_to->(\%shared_sources, $expand_variables->($+{INDEX}),
2056                                 undef, undef,
2057                                 tokenize($expand_variables->($+{VALUE})))
2058                          if !@skip || $skip[$#skip] > 0; },
2059             qr/^\s* INCLUDE ${index_re} = ${value_re} $/x
2060             => sub { $push_to->(\%includes, $expand_variables->($+{INDEX}),
2061                                 undef, undef,
2062                                 tokenize($expand_variables->($+{VALUE})))
2063                          if !@skip || $skip[$#skip] > 0; },
2064             qr/^\s* DEFINE ${index_re} = ${value_re} $/x
2065             => sub { $push_to->(\%defines, $expand_variables->($+{INDEX}),
2066                                 undef, undef,
2067                                 tokenize($expand_variables->($+{VALUE})))
2068                          if !@skip || $skip[$#skip] > 0; },
2069             qr/^\s* DEPEND ${index_re} ${attribs_re} = ${value_re} $/x
2070             => sub { $push_to->(\%depends, $expand_variables->($+{INDEX}),
2071                                 \$attributes{depends}, $+{ATTRIBS},
2072                                 tokenize($expand_variables->($+{VALUE})))
2073                          if !@skip || $skip[$#skip] > 0; },
2074             qr/^\s* GENERATE ${index_re} = ${value_re} $/x
2075             => sub { $push_to->(\%generate, $expand_variables->($+{INDEX}),
2076                                 undef, undef, $+{VALUE})
2077                          if !@skip || $skip[$#skip] > 0; },
2078             qr/^\s* (?:\#.*)? $/x => sub { },
2079             "OTHERWISE" => sub { die "Something wrong with this line:\n$_\nat $sourced/$f" },
2080             "BEFORE" => sub {
2081                 if ($buildinfo_debug) {
2082                     print STDERR "DEBUG: Parsing ",join(" ", @_),"\n";
2083                     print STDERR "DEBUG: ... before parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
2084                 }
2085             },
2086             "AFTER" => sub {
2087                 if ($buildinfo_debug) {
2088                     print STDERR "DEBUG: .... after parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
2089                 }
2090             },
2091             );
2092         die "runaway IF?" if (@skip);
2093
2094         if (grep { defined $attributes{modules}->{$_}->{engine} } keys %attributes
2095                 and !$config{dynamic_engines}) {
2096             die <<"EOF"
2097 ENGINES can only be used if configured with 'dynamic-engine'.
2098 This is usually a fault in a build.info file.
2099 EOF
2100         }
2101
2102         {
2103             my %infos = ( programs  => [ @programs  ],
2104                           libraries => [ @libraries ],
2105                           modules   => [ @modules   ],
2106                           scripts   => [ @scripts   ] );
2107             foreach my $k (keys %infos) {
2108                 foreach (@{$infos{$k}}) {
2109                     my $item = cleanfile($buildd, $_, $blddir);
2110                     $unified_info{$k}->{$item} = 1;
2111
2112                     # Fix up associated attributes
2113                     $unified_info{attributes}->{$k}->{$item} =
2114                         $attributes{$k}->{$_}
2115                         if defined $attributes{$k}->{$_};
2116                 }
2117             }
2118         }
2119
2120         # Check that we haven't defined any library as both shared and
2121         # explicitly static.  That is forbidden.
2122         my @doubles = ();
2123         foreach (grep /\.a$/, keys %{$unified_info{libraries}}) {
2124             (my $l = $_) =~ s/\.a$//;
2125             push @doubles, $l if defined $unified_info{libraries}->{$l};
2126         }
2127         die "these libraries are both explicitly static and shared:\n  ",
2128             join(" ", @doubles), "\n"
2129             if @doubles;
2130
2131         foreach (keys %sources) {
2132             my $dest = $_;
2133             my $ddest = cleanfile($buildd, $_, $blddir);
2134             foreach (@{$sources{$dest}}) {
2135                 my $s = cleanfile($sourced, $_, $blddir);
2136
2137                 # If it's generated or we simply don't find it in the source
2138                 # tree, we assume it's in the build tree.
2139                 if ($s eq $src_configdata || $generate{$_} || ! -f $s) {
2140                     $s = cleanfile($buildd, $_, $blddir);
2141                 }
2142                 # We recognise C++, C and asm files
2143                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
2144                     my $o = $_;
2145                     $o =~ s/\.[csS]$/.o/; # C and assembler
2146                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
2147                     $o = cleanfile($buildd, $o, $blddir);
2148                     $unified_info{sources}->{$ddest}->{$o} = -1;
2149                     $unified_info{sources}->{$o}->{$s} = -1;
2150                 } elsif ($s =~ /\.rc$/) {
2151                     # We also recognise resource files
2152                     my $o = $_;
2153                     $o =~ s/\.rc$/.res/; # Resource configuration
2154                     my $o = cleanfile($buildd, $o, $blddir);
2155                     $unified_info{sources}->{$ddest}->{$o} = -1;
2156                     $unified_info{sources}->{$o}->{$s} = -1;
2157                 } else {
2158                     $unified_info{sources}->{$ddest}->{$s} = 1;
2159                 }
2160             }
2161         }
2162
2163         foreach (keys %shared_sources) {
2164             my $dest = $_;
2165             my $ddest = cleanfile($buildd, $_, $blddir);
2166             foreach (@{$shared_sources{$dest}}) {
2167                 my $s = cleanfile($sourced, $_, $blddir);
2168
2169                 # If it's generated or we simply don't find it in the source
2170                 # tree, we assume it's in the build tree.
2171                 if ($s eq $src_configdata || $generate{$_} || ! -f $s) {
2172                     $s = cleanfile($buildd, $_, $blddir);
2173                 }
2174
2175                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
2176                     # We recognise C++, C and asm files
2177                     my $o = $_;
2178                     $o =~ s/\.[csS]$/.o/; # C and assembler
2179                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
2180                     $o = cleanfile($buildd, $o, $blddir);
2181                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2182                     $unified_info{sources}->{$o}->{$s} = -1;
2183                 } elsif ($s =~ /\.rc$/) {
2184                     # We also recognise resource files
2185                     my $o = $_;
2186                     $o =~ s/\.rc$/.res/; # Resource configuration
2187                     my $o = cleanfile($buildd, $o, $blddir);
2188                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2189                     $unified_info{sources}->{$o}->{$s} = -1;
2190                 } elsif ($s =~ /\.ld$/) {
2191                     # We also recognise linker scripts (or corresponding)
2192                     # We know they are generated files
2193                     my $ld = cleanfile($buildd, $_, $blddir);
2194                     $unified_info{shared_sources}->{$ddest}->{$ld} = 1;
2195                 } else {
2196                     die "unrecognised source file type for shared library: $s\n";
2197                 }
2198             }
2199         }
2200
2201         foreach (keys %generate) {
2202             my $dest = $_;
2203             my $ddest = cleanfile($buildd, $_, $blddir);
2204             die "more than one generator for $dest: "
2205                 ,join(" ", @{$generate{$_}}),"\n"
2206                 if scalar @{$generate{$_}} > 1;
2207             my @generator = split /\s+/, $generate{$dest}->[0];
2208             my $gen = $generator[0];
2209             $generator[0] = cleanfile($sourced, $gen, $blddir);
2210
2211             # If the generator is itself generated, it's in the build tree
2212             if ($generate{$gen}) {
2213                 $generator[0] = cleanfile($buildd, $gen, $blddir);
2214             }
2215
2216             $unified_info{generate}->{$ddest} = [ @generator ];
2217         }
2218
2219         foreach (keys %depends) {
2220             my $dest = $_;
2221             my $ddest = $dest eq "" ? "" : cleanfile($sourced, $_, $blddir);
2222
2223             # If the destination doesn't exist in source, it can only be
2224             # a generated file in the build tree.
2225             if ($ddest ne "" && ($ddest eq $src_configdata || ! -f $ddest)) {
2226                 $ddest = cleanfile($buildd, $_, $blddir);
2227             }
2228             foreach (@{$depends{$dest}}) {
2229                 my $d = cleanfile($sourced, $_, $blddir);
2230
2231                 # If we know it's generated, or assume it is because we can't
2232                 # find it in the source tree, we set file we depend on to be
2233                 # in the build tree rather than the source tree.
2234                 if ($d eq $src_configdata
2235                     || (grep { $d eq $_ }
2236                         map { cleanfile($srcdir, $_, $blddir) }
2237                         grep { /\.h$/ } keys %{$unified_info{generate}})
2238                     || ! -f $d) {
2239                     $d = cleanfile($buildd, $_, $blddir);
2240                 }
2241                 $unified_info{depends}->{$ddest}->{$d} = 1;
2242
2243                 # Fix up associated attributes
2244                 $unified_info{attributes}->{depends}->{$ddest}->{$d} =
2245                     $attributes{depends}->{$dest}->{$_}
2246                     if defined $attributes{depends}->{$dest}->{$_};
2247             }
2248         }
2249
2250         foreach (keys %includes) {
2251             my $dest = $_;
2252             my $ddest = cleanfile($sourced, $_, $blddir);
2253
2254             # If the destination doesn't exist in source, it can only be
2255             # a generated file in the build tree.
2256             if ($ddest eq $src_configdata || ! -f $ddest) {
2257                 $ddest = cleanfile($buildd, $_, $blddir);
2258             }
2259             foreach (@{$includes{$dest}}) {
2260                 my $is = cleandir($sourced, $_, $blddir);
2261                 my $ib = cleandir($buildd, $_, $blddir);
2262                 push @{$unified_info{includes}->{$ddest}->{source}}, $is
2263                     unless grep { $_ eq $is } @{$unified_info{includes}->{$ddest}->{source}};
2264                 push @{$unified_info{includes}->{$ddest}->{build}}, $ib
2265                     unless grep { $_ eq $ib } @{$unified_info{includes}->{$ddest}->{build}};
2266             }
2267         }
2268
2269         foreach my $dest (keys %defines) {
2270             my $ddest;
2271
2272             if ($dest ne "") {
2273                 $ddest = cleanfile($sourced, $dest, $blddir);
2274
2275                 # If the destination doesn't exist in source, it can only
2276                 # be a generated file in the build tree.
2277                 if (! -f $ddest) {
2278                     $ddest = cleanfile($buildd, $dest, $blddir);
2279                 }
2280             }
2281             foreach my $v (@{$defines{$dest}}) {
2282                 $v =~ m|^([^=]*)(=.*)?$|;
2283                 die "0 length macro name not permitted\n" if $1 eq "";
2284                 if ($dest ne "") {
2285                     die "$1 defined more than once\n"
2286                         if defined $unified_info{defines}->{$ddest}->{$1};
2287                     $unified_info{defines}->{$ddest}->{$1} = $2;
2288                 } else {
2289                     die "$1 defined more than once\n"
2290                         if grep { $v eq $_ } @{$config{defines}};
2291                     push @{$config{defines}}, $v;
2292                 }
2293             }
2294         }
2295
2296         foreach my $section (keys %htmldocs) {
2297             foreach (@{$htmldocs{$section}}) {
2298                 my $htmldocs = cleanfile($buildd, $_, $blddir);
2299                 $unified_info{htmldocs}->{$section}->{$htmldocs} = 1;
2300             }
2301         }
2302
2303         foreach my $section (keys %mandocs) {
2304             foreach (@{$mandocs{$section}}) {
2305                 my $mandocs = cleanfile($buildd, $_, $blddir);
2306                 $unified_info{mandocs}->{$section}->{$mandocs} = 1;
2307             }
2308         }
2309     }
2310
2311     my $ordinals_text = join(', ', sort keys %ordinals);
2312     warn <<"EOF" if $ordinals_text;
2313
2314 WARNING: ORDINALS were specified for $ordinals_text
2315 They are ignored and should be replaced with a combination of GENERATE,
2316 DEPEND and SHARED_SOURCE.
2317 EOF
2318
2319
2320     # Go through the sources of all libraries and check that the same basename
2321     # doesn't appear more than once.  Some static library archivers depend on
2322     # them being unique.
2323     {
2324         my $err = 0;
2325         foreach my $prod (keys %{$unified_info{libraries}}) {
2326             my @prod_sources =
2327                 map { keys %{$unified_info{sources}->{$_}} }
2328                 keys %{$unified_info{sources}->{$prod}};
2329             my %srccnt = ();
2330
2331             # Count how many times a given each source basename
2332             # appears for each product.
2333             foreach my $src (@prod_sources) {
2334                 $srccnt{basename $src}++;
2335             }
2336
2337             foreach my $src (keys %srccnt) {
2338                 if ((my $cnt = $srccnt{$src}) > 1) {
2339                     print STDERR "$src appears $cnt times for the product $prod\n";
2340                     $err++
2341                 }
2342             }
2343         }
2344         die if $err > 0;
2345     }
2346
2347     # Massage the result
2348
2349     # If we depend on a header file or a perl module, add an inclusion of
2350     # its directory to allow smoothe inclusion
2351     foreach my $dest (keys %{$unified_info{depends}}) {
2352         next if $dest eq "";
2353         foreach my $d (keys %{$unified_info{depends}->{$dest}}) {
2354             next unless $d =~ /\.(h|pm)$/;
2355             my $i = dirname($d);
2356             my $spot =
2357                 $d eq "configdata.pm" || defined($unified_info{generate}->{$d})
2358                 ? 'build' : 'source';
2359             push @{$unified_info{includes}->{$dest}->{$spot}}, $i
2360                 unless grep { $_ eq $i } @{$unified_info{includes}->{$dest}->{$spot}};
2361         }
2362     }
2363
2364     # Go through all intermediary files and change their names to something that
2365     # reflects what they will be built for.  Note that for some source files,
2366     # this leads to duplicate object files because they are used multiple times.
2367     # the goal is to rename all object files according to this scheme:
2368     #    {productname}-{midfix}-{origobjname}.[o|res]
2369     # the {midfix} is a keyword indicating the type of product, which is mostly
2370     # valuable for libraries since they come in two forms.
2371     #
2372     # This also reorganises the {sources} and {shared_sources} so that the
2373     # former only contains ALL object files that are supposed to end up in
2374     # static libraries and programs, while the latter contains ALL object files
2375     # that are supposed to end up in shared libraries and DSOs.
2376     # The main reason for having two different source structures is to allow
2377     # the same name to be used for the static and the shared variants of a
2378     # library.
2379     {
2380         # Take copies so we don't get interference from added stuff
2381         my %unified_copy = ();
2382         foreach (('sources', 'shared_sources')) {
2383             $unified_copy{$_} = { %{$unified_info{$_}} }
2384                 if defined($unified_info{$_});
2385             delete $unified_info{$_};
2386         }
2387         foreach my $prodtype (('programs', 'libraries', 'modules', 'scripts')) {
2388             # $intent serves multi purposes:
2389             # - give a prefix for the new object files names
2390             # - in the case of libraries, rearrange the object files so static
2391             #   libraries use the 'sources' structure exclusively, while shared
2392             #   libraries use the 'shared_sources' structure exclusively.
2393             my $intent = {
2394                 programs  => { bin    => { src => [ 'sources' ],
2395                                            dst => 'sources' } },
2396                 libraries => { lib    => { src => [ 'sources' ],
2397                                            dst => 'sources' },
2398                                shlib  => { prodselect =>
2399                                                sub { grep !/\.a$/, @_ },
2400                                            src => [ 'sources',
2401                                                     'shared_sources' ],
2402                                            dst => 'shared_sources' } },
2403                 modules   => { dso    => { src => [ 'sources' ],
2404                                            dst => 'sources' } },
2405                 scripts   => { script => { src => [ 'sources' ],
2406                                            dst => 'sources' } }
2407                } -> {$prodtype};
2408             foreach my $kind (keys %$intent) {
2409                 next if ($intent->{$kind}->{dst} eq 'shared_sources'
2410                              && $disabled{shared});
2411
2412                 my @src = @{$intent->{$kind}->{src}};
2413                 my $dst = $intent->{$kind}->{dst};
2414                 my $prodselect = $intent->{$kind}->{prodselect} // sub { @_ };
2415                 foreach my $prod ($prodselect->(keys %{$unified_info{$prodtype}})) {
2416                     # %prod_sources has all applicable objects as keys, and
2417                     # their corresponding sources as values
2418                     my %prod_sources =
2419                         map { $_ => [ keys %{$unified_copy{sources}->{$_}} ] }
2420                         map { keys %{$unified_copy{$_}->{$prod}} }
2421                         @src;
2422                     foreach (keys %prod_sources) {
2423                         # Only affect object files and resource files,
2424                         # the others simply get a new value
2425                         # (+1 instead of -1)
2426                         if ($_ =~ /\.(o|res)$/) {
2427                             (my $prodname = $prod) =~ s|\.a$||;
2428                             my $newobj =
2429                                 catfile(dirname($_),
2430                                         basename($prodname)
2431                                             . '-' . $kind
2432                                             . '-' . basename($_));
2433                             $unified_info{$dst}->{$prod}->{$newobj} = 1;
2434                             foreach my $src (@{$prod_sources{$_}}) {
2435                                 $unified_info{sources}->{$newobj}->{$src} = 1;
2436                             }
2437                             # Adjust dependencies
2438                             foreach my $deps (keys %{$unified_info{depends}->{$_}}) {
2439                                 $unified_info{depends}->{$_}->{$deps} = -1;
2440                                 $unified_info{depends}->{$newobj}->{$deps} = 1;
2441                             }
2442                             # Adjust includes
2443                             foreach my $k (('source', 'build')) {
2444                                 next unless
2445                                     defined($unified_info{includes}->{$_}->{$k});
2446                                 my @incs = @{$unified_info{includes}->{$_}->{$k}};
2447                                 $unified_info{includes}->{$newobj}->{$k} = [ @incs ];
2448                             }
2449                         } else {
2450                             $unified_info{$dst}->{$prod}->{$_} = 1;
2451                         }
2452                     }
2453                 }
2454             }
2455         }
2456     }
2457
2458     # At this point, we have a number of sources with the value -1.  They
2459     # aren't part of the local build and are probably meant for a different
2460     # platform, and can therefore be cleaned away.  That happens when making
2461     # %unified_info more efficient below.
2462
2463     ### Make unified_info a bit more efficient
2464     # One level structures
2465     foreach (("programs", "libraries", "modules", "scripts")) {
2466         $unified_info{$_} = [ sort keys %{$unified_info{$_}} ];
2467     }
2468     # Two level structures
2469     foreach my $l1 (("sources", "shared_sources", "ldadd", "depends",
2470                      "htmldocs", "mandocs")) {
2471         foreach my $l2 (sort keys %{$unified_info{$l1}}) {
2472             my @items =
2473                 sort
2474                 grep { $unified_info{$l1}->{$l2}->{$_} > 0 }
2475                 keys %{$unified_info{$l1}->{$l2}};
2476             if (@items) {
2477                 $unified_info{$l1}->{$l2} = [ @items ];
2478             } else {
2479                 delete $unified_info{$l1}->{$l2};
2480             }
2481         }
2482     }
2483     # Defines
2484     foreach my $dest (sort keys %{$unified_info{defines}}) {
2485         $unified_info{defines}->{$dest}
2486             = [ map { $_.$unified_info{defines}->{$dest}->{$_} }
2487                 sort keys %{$unified_info{defines}->{$dest}} ];
2488     }
2489     # Includes
2490     foreach my $dest (sort keys %{$unified_info{includes}}) {
2491         if (defined($unified_info{includes}->{$dest}->{build})) {
2492             my @source_includes = ();
2493             @source_includes = ( @{$unified_info{includes}->{$dest}->{source}} )
2494                 if defined($unified_info{includes}->{$dest}->{source});
2495             $unified_info{includes}->{$dest} =
2496                 [ @{$unified_info{includes}->{$dest}->{build}} ];
2497             foreach my $inc (@source_includes) {
2498                 push @{$unified_info{includes}->{$dest}}, $inc
2499                     unless grep { $_ eq $inc } @{$unified_info{includes}->{$dest}};
2500             }
2501         } elsif (defined($unified_info{includes}->{$dest}->{source})) {
2502             $unified_info{includes}->{$dest} =
2503                 [ @{$unified_info{includes}->{$dest}->{source}} ];
2504         } else {
2505             delete $unified_info{includes}->{$dest};
2506         }
2507     }
2508
2509     # For convenience collect information regarding directories where
2510     # files are generated, those generated files and the end product
2511     # they end up in where applicable.  Then, add build rules for those
2512     # directories
2513     my %loopinfo = ( "lib" => [ @{$unified_info{libraries}} ],
2514                      "dso" => [ @{$unified_info{modules}} ],
2515                      "bin" => [ @{$unified_info{programs}} ],
2516                      "script" => [ @{$unified_info{scripts}} ],
2517                      "docs" => [ (map { @{$unified_info{htmldocs}->{$_} // []} }
2518                                   keys %{$unified_info{htmldocs} // {}}),
2519                                  (map { @{$unified_info{mandocs}->{$_} // []} }
2520                                   keys %{$unified_info{mandocs} // {}}) ] );
2521     foreach my $type (keys %loopinfo) {
2522         foreach my $product (@{$loopinfo{$type}}) {
2523             my %dirs = ();
2524             my $pd = dirname($product);
2525
2526             foreach (@{$unified_info{sources}->{$product} // []},
2527                      @{$unified_info{shared_sources}->{$product} // []}) {
2528                 my $d = dirname($_);
2529
2530                 # We don't want to create targets for source directories
2531                 # when building out of source
2532                 next if ($config{sourcedir} ne $config{builddir}
2533                              && $d =~ m|^\Q$config{sourcedir}\E|);
2534                 # We already have a "test" target, and the current directory
2535                 # is just silly to make a target for
2536                 next if $d eq "test" || $d eq ".";
2537
2538                 $dirs{$d} = 1;
2539                 push @{$unified_info{dirinfo}->{$d}->{deps}}, $_
2540                     if $d ne $pd;
2541             }
2542             foreach (keys %dirs) {
2543                 push @{$unified_info{dirinfo}->{$_}->{products}->{$type}},
2544                     $product;
2545             }
2546         }
2547     }
2548 }
2549
2550 # For the schemes that need it, we provide the old *_obj configs
2551 # from the *_asm_obj ones
2552 foreach (grep /_(asm|aux)_src$/, keys %target) {
2553     my $src = $_;
2554     (my $obj = $_) =~ s/_(asm|aux)_src$/_obj/;
2555     $target{$obj} = $target{$src};
2556     $target{$obj} =~ s/\.[csS]\b/.o/g; # C and assembler
2557     $target{$obj} =~ s/\.(cc|cpp)\b/_cc.o/g; # C++
2558 }
2559
2560 # Write down our configuration where it fits #########################
2561
2562 my %template_vars = (
2563     config => \%config,
2564     target => \%target,
2565     disablables => \@disablables,
2566     disablables_int => \@disablables_int,
2567     disabled => \%disabled,
2568     withargs => \%withargs,
2569     unified_info => \%unified_info,
2570     tls => \@tls,
2571     dtls => \@dtls,
2572     makevars => [ sort keys %user ],
2573     disabled_info => \%disabled_info,
2574     user_crossable => \@user_crossable,
2575 );
2576 my $configdata_outname = 'configdata.pm';
2577 print "Creating $configdata_outname\n";
2578 open CONFIGDATA, ">$configdata_outname.new"
2579             or die "Trying to create $configdata_outname.new: $!";
2580 my $configdata_tmplname = cleanfile($srcdir, "configdata.pm.in", $blddir);
2581 my $configdata_tmpl =
2582     OpenSSL::Template->new(TYPE => 'FILE', SOURCE => $configdata_tmplname);
2583 $configdata_tmpl->fill_in(
2584     FILENAME => $configdata_tmplname,
2585     OUTPUT => \*CONFIGDATA,
2586     HASH => { %template_vars,
2587               autowarntext => [
2588                   'WARNING: do not edit!',
2589                   "Generated by Configure from $configdata_tmplname",
2590               ] }
2591 ) or die $Text::Template::ERROR;
2592 close CONFIGDATA;
2593 rename "$configdata_outname.new", $configdata_outname;
2594 if ($builder_platform eq 'unix') {
2595     my $mode = (0755 & ~umask);
2596     chmod $mode, 'configdata.pm'
2597         or warn sprintf("WARNING: Couldn't change mode for 'configdata.pm' to 0%03o: %s\n",$mode,$!);
2598 }
2599
2600 print "Running $configdata_outname\n";
2601 my $perlcmd = (quotify("maybeshell", $config{PERL}))[0];
2602 my $cmd = "$perlcmd $configdata_outname";
2603 #print STDERR "DEBUG[run_dofile]: \$cmd = $cmd\n";
2604 system($cmd);
2605 exit 1 if $? != 0;
2606
2607 $SIG{__DIE__} = $orig_death_handler;
2608
2609 print <<"EOF" if ($disabled{threads} eq "unavailable");
2610
2611 The library could not be configured for supporting multi-threaded
2612 applications as the compiler options required on this system are not known.
2613 See file INSTALL for details if you need multi-threading.
2614 EOF
2615
2616 print <<"EOF" if ($no_shared_warn);
2617
2618 The options 'shared', 'pic' and 'dynamic-engine' aren't supported on this
2619 platform, so we will pretend you gave the option 'no-pic', which also disables
2620 'shared' and 'dynamic-engine'.  If you know how to implement shared libraries
2621 or position independent code, please let us know (but please first make sure
2622 you have tried with a current version of OpenSSL).
2623 EOF
2624
2625 print <<"EOF";
2626
2627 **********************************************************************
2628 ***                                                                ***
2629 ***   OpenSSL has been successfully configured                     ***
2630 ***                                                                ***
2631 ***   If you encounter a problem while building, please open an    ***
2632 ***   issue on GitHub <https://github.com/openssl/openssl/issues>  ***
2633 ***   and include the output from the following command:           ***
2634 ***                                                                ***
2635 ***       perl configdata.pm --dump                                ***
2636 ***                                                                ***
2637 ***   (If you are new to OpenSSL, you might want to consult the    ***
2638 ***   'Troubleshooting' section in the INSTALL file first)         ***
2639 ***                                                                ***
2640 **********************************************************************
2641 EOF
2642
2643 exit(0);
2644
2645 ######################################################################
2646 #
2647 # Helpers and utility functions
2648 #
2649
2650 # Death handler, to print a helpful message in case of failure #######
2651 #
2652 sub death_handler {
2653     die @_ if $^S;              # To prevent the added message in eval blocks
2654     my $build_file = $target{build_file} // "build file";
2655     my @message = ( <<"_____", @_ );
2656
2657 Failure!  $build_file wasn't produced.
2658 Please read INSTALL and associated NOTES files.  You may also have to look over
2659 your available compiler tool chain or change your configuration.
2660
2661 _____
2662
2663     # Dying is terminal, so it's ok to reset the signal handler here.
2664     $SIG{__DIE__} = $orig_death_handler;
2665     die @message;
2666 }
2667
2668 # Configuration file reading #########################################
2669
2670 # Note: All of the helper functions are for lazy evaluation.  They all
2671 # return a CODE ref, which will return the intended value when evaluated.
2672 # Thus, whenever there's mention of a returned value, it's about that
2673 # intended value.
2674
2675 # Helper function to implement conditional value variants, with a default
2676 # plus additional values based on the value of $config{build_type}.
2677 # Arguments are given in hash table form:
2678 #
2679 #       picker(default => "Basic string: ",
2680 #              debug   => "debug",
2681 #              release => "release")
2682 #
2683 # When configuring with --debug, the resulting string will be
2684 # "Basic string: debug", and when not, it will be "Basic string: release"
2685 #
2686 # This can be used to create variants of sets of flags according to the
2687 # build type:
2688 #
2689 #       cflags => picker(default => "-Wall",
2690 #                        debug   => "-g -O0",
2691 #                        release => "-O3")
2692 #
2693 sub picker {
2694     my %opts = @_;
2695     return sub { add($opts{default} || (),
2696                      $opts{$config{build_type}} || ())->(); }
2697 }
2698
2699 # Helper function to combine several values of different types into one.
2700 # This is useful if you want to combine a string with the result of a
2701 # lazy function, such as:
2702 #
2703 #       cflags => combine("-Wall", sub { $disabled{zlib} ? () : "-DZLIB" })
2704 #
2705 sub combine {
2706     my @stuff = @_;
2707     return sub { add(@stuff)->(); }
2708 }
2709
2710 # Helper function to implement conditional values depending on the value
2711 # of $disabled{threads}.  Can be used as follows:
2712 #
2713 #       cflags => combine("-Wall", threads("-pthread"))
2714 #
2715 sub threads {
2716     my @flags = @_;
2717     return sub { add($disabled{threads} ? () : @flags)->(); }
2718 }
2719
2720 sub shared {
2721     my @flags = @_;
2722     return sub { add($disabled{shared} ? () : @flags)->(); }
2723 }
2724
2725 our $add_called = 0;
2726 # Helper function to implement adding values to already existing configuration
2727 # values.  It handles elements that are ARRAYs, CODEs and scalars
2728 sub _add {
2729     my $separator = shift;
2730
2731     # If there's any ARRAY in the collection of values OR the separator
2732     # is undef, we will return an ARRAY of combined values, otherwise a
2733     # string of joined values with $separator as the separator.
2734     my $found_array = !defined($separator);
2735
2736     my @values =
2737         map {
2738             my $res = $_;
2739             while (ref($res) eq "CODE") {
2740                 $res = $res->();
2741             }
2742             if (defined($res)) {
2743                 if (ref($res) eq "ARRAY") {
2744                     $found_array = 1;
2745                     @$res;
2746                 } else {
2747                     $res;
2748                 }
2749             } else {
2750                 ();
2751             }
2752     } (@_);
2753
2754     $add_called = 1;
2755
2756     if ($found_array) {
2757         [ @values ];
2758     } else {
2759         join($separator, grep { defined($_) && $_ ne "" } @values);
2760     }
2761 }
2762 sub add_before {
2763     my $separator = " ";
2764     if (ref($_[$#_]) eq "HASH") {
2765         my $opts = pop;
2766         $separator = $opts->{separator};
2767     }
2768     my @x = @_;
2769     sub { _add($separator, @x, @_) };
2770 }
2771 sub add {
2772     my $separator = " ";
2773     if (ref($_[$#_]) eq "HASH") {
2774         my $opts = pop;
2775         $separator = $opts->{separator};
2776     }
2777     my @x = @_;
2778     sub { _add($separator, @_, @x) };
2779 }
2780
2781 sub read_eval_file {
2782     my $fname = shift;
2783     my $content;
2784     my @result;
2785
2786     open F, "< $fname" or die "Can't open '$fname': $!\n";
2787     {
2788         undef local $/;
2789         $content = <F>;
2790     }
2791     close F;
2792     {
2793         local $@;
2794
2795         @result = ( eval $content );
2796         warn $@ if $@;
2797     }
2798     return wantarray ? @result : $result[0];
2799 }
2800
2801 # configuration reader, evaluates the input file as a perl script and expects
2802 # it to fill %targets with target configurations.  Those are then added to
2803 # %table.
2804 sub read_config {
2805     my $fname = shift;
2806     my %targets;
2807
2808     {
2809         # Protect certain tables from tampering
2810         local %table = ();
2811
2812         %targets = read_eval_file($fname);
2813     }
2814     my %preexisting = ();
2815     foreach (sort keys %targets) {
2816         $preexisting{$_} = 1 if $table{$_};
2817     }
2818     die <<"EOF",
2819 The following config targets from $fname
2820 shadow pre-existing config targets with the same name:
2821 EOF
2822         map { "  $_\n" } sort keys %preexisting
2823         if %preexisting;
2824
2825
2826     # For each target, check that it's configured with a hash table.
2827     foreach (keys %targets) {
2828         if (ref($targets{$_}) ne "HASH") {
2829             if (ref($targets{$_}) eq "") {
2830                 warn "Deprecated target configuration for $_, ignoring...\n";
2831             } else {
2832                 warn "Misconfigured target configuration for $_ (should be a hash table), ignoring...\n";
2833             }
2834             delete $targets{$_};
2835         } else {
2836             $targets{$_}->{_conf_fname_int} = add([ $fname ]);
2837         }
2838     }
2839
2840     %table = (%table, %targets);
2841
2842 }
2843
2844 # configuration resolver.  Will only resolve all the lazy evaluation
2845 # codeblocks for the chosen target and all those it inherits from,
2846 # recursively
2847 sub resolve_config {
2848     my $target = shift;
2849     my @breadcrumbs = @_;
2850
2851 #    my $extra_checks = defined($ENV{CONFIGURE_EXTRA_CHECKS});
2852
2853     if (grep { $_ eq $target } @breadcrumbs) {
2854         die "inherit_from loop!  target backtrace:\n  "
2855             ,$target,"\n  ",join("\n  ", @breadcrumbs),"\n";
2856     }
2857
2858     if (!defined($table{$target})) {
2859         warn "Warning! target $target doesn't exist!\n";
2860         return ();
2861     }
2862     # Recurse through all inheritances.  They will be resolved on the
2863     # fly, so when this operation is done, they will all just be a
2864     # bunch of attributes with string values.
2865     # What we get here, though, are keys with references to lists of
2866     # the combined values of them all.  We will deal with lists after
2867     # this stage is done.
2868     my %combined_inheritance = ();
2869     if ($table{$target}->{inherit_from}) {
2870         my @inherit_from =
2871             map { ref($_) eq "CODE" ? $_->() : $_ } @{$table{$target}->{inherit_from}};
2872         foreach (@inherit_from) {
2873             my %inherited_config = resolve_config($_, $target, @breadcrumbs);
2874
2875             # 'template' is a marker that's considered private to
2876             # the config that had it.
2877             delete $inherited_config{template};
2878
2879             foreach (keys %inherited_config) {
2880                 if (!$combined_inheritance{$_}) {
2881                     $combined_inheritance{$_} = [];
2882                 }
2883                 push @{$combined_inheritance{$_}}, $inherited_config{$_};
2884             }
2885         }
2886     }
2887
2888     # We won't need inherit_from in this target any more, since we've
2889     # resolved all the inheritances that lead to this
2890     delete $table{$target}->{inherit_from};
2891
2892     # Now is the time to deal with those lists.  Here's the place to
2893     # decide what shall be done with those lists, all based on the
2894     # values of the target we're currently dealing with.
2895     # - If a value is a coderef, it will be executed with the list of
2896     #   inherited values as arguments.
2897     # - If the corresponding key doesn't have a value at all or is the
2898     #   empty string, the inherited value list will be run through the
2899     #   default combiner (below), and the result becomes this target's
2900     #   value.
2901     # - Otherwise, this target's value is assumed to be a string that
2902     #   will simply override the inherited list of values.
2903     my $default_combiner = add();
2904
2905     my %all_keys =
2906         map { $_ => 1 } (keys %combined_inheritance,
2907                          keys %{$table{$target}});
2908
2909     sub process_values {
2910         my $object    = shift;
2911         my $inherited = shift;  # Always a [ list ]
2912         my $target    = shift;
2913         my $entry     = shift;
2914
2915         $add_called = 0;
2916
2917         while(ref($object) eq "CODE") {
2918             $object = $object->(@$inherited);
2919         }
2920         if (!defined($object)) {
2921             return ();
2922         }
2923         elsif (ref($object) eq "ARRAY") {
2924             local $add_called;  # To make sure recursive calls don't affect it
2925             return [ map { process_values($_, $inherited, $target, $entry) }
2926                      @$object ];
2927         } elsif (ref($object) eq "") {
2928             return $object;
2929         } else {
2930             die "cannot handle reference type ",ref($object)
2931                 ," found in target ",$target," -> ",$entry,"\n";
2932         }
2933     }
2934
2935     foreach (sort keys %all_keys) {
2936         my $previous = $combined_inheritance{$_};
2937
2938         # Current target doesn't have a value for the current key?
2939         # Assign it the default combiner, the rest of this loop body
2940         # will handle it just like any other coderef.
2941         if (!exists $table{$target}->{$_}) {
2942             $table{$target}->{$_} = $default_combiner;
2943         }
2944
2945         $table{$target}->{$_} = process_values($table{$target}->{$_},
2946                                                $combined_inheritance{$_},
2947                                                $target, $_);
2948         unless(defined($table{$target}->{$_})) {
2949             delete $table{$target}->{$_};
2950         }
2951 #        if ($extra_checks &&
2952 #            $previous && !($add_called ||  $previous ~~ $table{$target}->{$_})) {
2953 #            warn "$_ got replaced in $target\n";
2954 #        }
2955     }
2956
2957     # Finally done, return the result.
2958     return %{$table{$target}};
2959 }
2960
2961 sub usage
2962         {
2963         print STDERR $usage;
2964         print STDERR "\npick os/compiler from:\n";
2965         my $j=0;
2966         my $i;
2967         my $k=0;
2968         foreach $i (sort keys %table)
2969                 {
2970                 next if $table{$i}->{template};
2971                 next if $i =~ /^debug/;
2972                 $k += length($i) + 1;
2973                 if ($k > 78)
2974                         {
2975                         print STDERR "\n";
2976                         $k=length($i);
2977                         }
2978                 print STDERR $i . " ";
2979                 }
2980         foreach $i (sort keys %table)
2981                 {
2982                 next if $table{$i}->{template};
2983                 next if $i !~ /^debug/;
2984                 $k += length($i) + 1;
2985                 if ($k > 78)
2986                         {
2987                         print STDERR "\n";
2988                         $k=length($i);
2989                         }
2990                 print STDERR $i . " ";
2991                 }
2992         print STDERR "\n\nNOTE: If in doubt, on Unix-ish systems use './config'.\n";
2993         exit(1);
2994         }
2995
2996 sub compiler_predefined {
2997     state %predefined;
2998     my $cc = shift;
2999
3000     return () if $^O eq 'VMS';
3001
3002     die 'compiler_predefined called without a compiler command'
3003         unless $cc;
3004
3005     if (! $predefined{$cc}) {
3006
3007         $predefined{$cc} = {};
3008
3009         # collect compiler pre-defines from gcc or gcc-alike...
3010         open(PIPE, "$cc -dM -E -x c /dev/null 2>&1 |");
3011         while (my $l = <PIPE>) {
3012             $l =~ m/^#define\s+(\w+(?:\(\w+\))?)(?:\s+(.+))?/ or last;
3013             $predefined{$cc}->{$1} = $2 // '';
3014         }
3015         close(PIPE);
3016     }
3017
3018     return %{$predefined{$cc}};
3019 }
3020
3021 sub which
3022 {
3023     my ($name)=@_;
3024
3025     if (eval { require IPC::Cmd; 1; }) {
3026         IPC::Cmd->import();
3027         return scalar IPC::Cmd::can_run($name);
3028     } else {
3029         # if there is $directories component in splitpath,
3030         # then it's not something to test with $PATH...
3031         return $name if (File::Spec->splitpath($name))[1];
3032
3033         foreach (File::Spec->path()) {
3034             my $fullpath = catfile($_, "$name$target{exe_extension}");
3035             if (-f $fullpath and -x $fullpath) {
3036                 return $fullpath;
3037             }
3038         }
3039     }
3040 }
3041
3042 sub env
3043 {
3044     my $name = shift;
3045     my %opts = @_;
3046
3047     unless ($opts{cacheonly}) {
3048         # Note that if $ENV{$name} doesn't exist or is undefined,
3049         # $config{perlenv}->{$name} will be created with the value
3050         # undef.  This is intentional.
3051
3052         $config{perlenv}->{$name} = $ENV{$name}
3053             if ! exists $config{perlenv}->{$name};
3054     }
3055     return $config{perlenv}->{$name};
3056 }
3057
3058 # Configuration printer ##############################################
3059
3060 sub print_table_entry
3061 {
3062     local $now_printing = shift;
3063     my %target = resolve_config($now_printing);
3064     my $type = shift;
3065
3066     # Don't print the templates
3067     return if $target{template};
3068
3069     my @sequence = (
3070         "sys_id",
3071         "cpp",
3072         "cppflags",
3073         "defines",
3074         "includes",
3075         "cc",
3076         "cflags",
3077         "ld",
3078         "lflags",
3079         "loutflag",
3080         "ex_libs",
3081         "bn_ops",
3082         "poly1035_asm_src",
3083         "thread_scheme",
3084         "perlasm_scheme",
3085         "dso_scheme",
3086         "shared_target",
3087         "shared_cflag",
3088         "shared_defines",
3089         "shared_ldflag",
3090         "shared_rcflag",
3091         "shared_extension",
3092         "dso_extension",
3093         "obj_extension",
3094         "exe_extension",
3095         "ranlib",
3096         "ar",
3097         "arflags",
3098         "aroutflag",
3099         "rc",
3100         "rcflags",
3101         "rcoutflag",
3102         "mt",
3103         "mtflags",
3104         "mtinflag",
3105         "mtoutflag",
3106         "multilib",
3107         "build_scheme",
3108         );
3109
3110     if ($type eq "TABLE") {
3111         print "\n";
3112         print "*** $now_printing\n";
3113         foreach (@sequence) {
3114             if (ref($target{$_}) eq "ARRAY") {
3115                 printf "\$%-12s = %s\n", $_, join(" ", @{$target{$_}});
3116             } else {
3117                 printf "\$%-12s = %s\n", $_, $target{$_};
3118             }
3119         }
3120     } elsif ($type eq "HASH") {
3121         my $largest =
3122             length((sort { length($a) <=> length($b) } @sequence)[-1]);
3123         print "    '$now_printing' => {\n";
3124         foreach (@sequence) {
3125             if ($target{$_}) {
3126                 if (ref($target{$_}) eq "ARRAY") {
3127                     print "      '",$_,"'"," " x ($largest - length($_))," => [ ",join(", ", map { "'$_'" } @{$target{$_}})," ],\n";
3128                 } else {
3129                     print "      '",$_,"'"," " x ($largest - length($_))," => '",$target{$_},"',\n";
3130                 }
3131             }
3132         }
3133         print "    },\n";
3134     }
3135 }
3136
3137 # Utility routines ###################################################
3138
3139 # On VMS, if the given file is a logical name, File::Spec::Functions
3140 # will consider it an absolute path.  There are cases when we want a
3141 # purely syntactic check without checking the environment.
3142 sub isabsolute {
3143     my $file = shift;
3144
3145     # On non-platforms, we just use file_name_is_absolute().
3146     return file_name_is_absolute($file) unless $^O eq "VMS";
3147
3148     # If the file spec includes a device or a directory spec,
3149     # file_name_is_absolute() is perfectly safe.
3150     return file_name_is_absolute($file) if $file =~ m|[:\[]|;
3151
3152     # Here, we know the given file spec isn't absolute
3153     return 0;
3154 }
3155
3156 # Makes a directory absolute and cleans out /../ in paths like foo/../bar
3157 # On some platforms, this uses rel2abs(), while on others, realpath() is used.
3158 # realpath() requires that at least all path components except the last is an
3159 # existing directory.  On VMS, the last component of the directory spec must
3160 # exist.
3161 sub absolutedir {
3162     my $dir = shift;
3163
3164     # realpath() is quite buggy on VMS.  It uses LIB$FID_TO_NAME, which
3165     # will return the volume name for the device, no matter what.  Also,
3166     # it will return an incorrect directory spec if the argument is a
3167     # directory that doesn't exist.
3168     if ($^O eq "VMS") {
3169         return rel2abs($dir);
3170     }
3171
3172     # We use realpath() on Unix, since no other will properly clean out
3173     # a directory spec.
3174     use Cwd qw/realpath/;
3175
3176     return realpath($dir);
3177 }
3178
3179 sub quotify {
3180     my %processors = (
3181         perl    => sub { my $x = shift;
3182                          $x =~ s/([\\\$\@"])/\\$1/g;
3183                          return '"'.$x.'"'; },
3184         maybeshell => sub { my $x = shift;
3185                             (my $y = $x) =~ s/([\\\"])/\\$1/g;
3186                             if ($x ne $y || $x =~ m|\s|) {
3187                                 return '"'.$y.'"';
3188                             } else {
3189                                 return $x;
3190                             }
3191                         },
3192         );
3193     my $for = shift;
3194     my $processor =
3195         defined($processors{$for}) ? $processors{$for} : sub { shift; };
3196
3197     return map { $processor->($_); } @_;
3198 }
3199
3200 # collect_from_file($filename, $line_concat_cond_re, $line_concat)
3201 # $filename is a file name to read from
3202 # $line_concat_cond_re is a regexp detecting a line continuation ending
3203 # $line_concat is a CODEref that takes care of concatenating two lines
3204 sub collect_from_file {
3205     my $filename = shift;
3206     my $line_concat_cond_re = shift;
3207     my $line_concat = shift;
3208
3209     open my $fh, $filename || die "unable to read $filename: $!\n";
3210     return sub {
3211         my $saved_line = "";
3212         $_ = "";
3213         while (<$fh>) {
3214             s|\R$||;
3215             if (defined $line_concat) {
3216                 $_ = $line_concat->($saved_line, $_);
3217                 $saved_line = "";
3218             }
3219             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3220                 $saved_line = $_;
3221                 next;
3222             }
3223             return $_;
3224         }
3225         die "$filename ending with continuation line\n" if $_;
3226         close $fh;
3227         return undef;
3228     }
3229 }
3230
3231 # collect_from_array($array, $line_concat_cond_re, $line_concat)
3232 # $array is an ARRAYref of lines
3233 # $line_concat_cond_re is a regexp detecting a line continuation ending
3234 # $line_concat is a CODEref that takes care of concatenating two lines
3235 sub collect_from_array {
3236     my $array = shift;
3237     my $line_concat_cond_re = shift;
3238     my $line_concat = shift;
3239     my @array = (@$array);
3240
3241     return sub {
3242         my $saved_line = "";
3243         $_ = "";
3244         while (defined($_ = shift @array)) {
3245             s|\R$||;
3246             if (defined $line_concat) {
3247                 $_ = $line_concat->($saved_line, $_);
3248                 $saved_line = "";
3249             }
3250             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3251                 $saved_line = $_;
3252                 next;
3253             }
3254             return $_;
3255         }
3256         die "input text ending with continuation line\n" if $_;
3257         return undef;
3258     }
3259 }
3260
3261 # collect_information($lineiterator, $line_continue, $regexp => $CODEref, ...)
3262 # $lineiterator is a CODEref that delivers one line at a time.
3263 # All following arguments are regex/CODEref pairs, where the regexp detects a
3264 # line and the CODEref does something with the result of the regexp.
3265 sub collect_information {
3266     my $lineiterator = shift;
3267     my %collectors = @_;
3268
3269     while(defined($_ = $lineiterator->())) {
3270         s|\R$||;
3271         my $found = 0;
3272         if ($collectors{"BEFORE"}) {
3273             $collectors{"BEFORE"}->($_);
3274         }
3275         foreach my $re (keys %collectors) {
3276             if ($re !~ /^OTHERWISE|BEFORE|AFTER$/ && /$re/) {
3277                 $collectors{$re}->($lineiterator);
3278                 $found = 1;
3279             };
3280         }
3281         if ($collectors{"OTHERWISE"}) {
3282             $collectors{"OTHERWISE"}->($lineiterator, $_)
3283                 unless $found || !defined $collectors{"OTHERWISE"};
3284         }
3285         if ($collectors{"AFTER"}) {
3286             $collectors{"AFTER"}->($_);
3287         }
3288     }
3289 }
3290
3291 # tokenize($line)
3292 # tokenize($line,$separator)
3293 # $line is a line of text to split up into tokens
3294 # $separator [optional] is a regular expression that separates the tokens,
3295 # the default being spaces.  Do not use quotes of any kind as separators,
3296 # that will give undefined results.
3297 # Returns a list of tokens.
3298 #
3299 # Tokens are divided by separator (spaces by default).  If the tokens include
3300 # the separators, they have to be quoted with single or double quotes.
3301 # Double quotes inside a double quoted token must be escaped.  Escaping is done
3302 # with backslash.
3303 # Basically, the same quoting rules apply for " and ' as in any
3304 # Unix shell.
3305 sub tokenize {
3306     my $line = my $debug_line = shift;
3307     my $separator = shift // qr|\s+|;
3308     my @result = ();
3309
3310     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
3311         print STDERR "DEBUG[tokenize]: \$separator = $separator\n";
3312     }
3313
3314     while ($line =~ s|^${separator}||, $line ne "") {
3315         my $token = "";
3316     again:
3317         $line =~ m/^(.*?)(${separator}|"|'|$)/;
3318         $token .= $1;
3319         $line = $2.$';
3320
3321         if ($line =~ m/^"((?:[^"\\]+|\\.)*)"/) {
3322             $token .= $1;
3323             $line = $';
3324             goto again;
3325         } elsif ($line =~ m/^'([^']*)'/) {
3326             $token .= $1;
3327             $line = $';
3328             goto again;
3329         }
3330         push @result, $token;
3331     }
3332
3333     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
3334         print STDERR "DEBUG[tokenize]: Parsed '$debug_line' into:\n";
3335         print STDERR "DEBUG[tokenize]: ('", join("', '", @result), "')\n";
3336     }
3337     return @result;
3338 }