Configure

   1 #! /usr/bin/env perl
   2 # -*- mode: perl; -*-
   3 # Copyright 2016 The OpenSSL Project Authors. All Rights Reserved.
   4 #
   5 # Licensed under the OpenSSL license (the "License").  You may not use
   6 # this file except in compliance with the License.  You can obtain a copy
   7 # in the file LICENSE in the source distribution or at
   8 # https://www.openssl.org/source/license.html
   9
  10 ##  Configure -- OpenSSL source tree configuration script
  11
  12 require 5.10.0;
  13 use strict;
  14 use Config;
  15 use File::Basename;
  16 use File::Spec::Functions qw/:DEFAULT abs2rel rel2abs/;
  17 use File::Path qw/mkpath/;
  18 use if $^O ne "VMS", 'File::Glob' => qw/glob/;
  19
  20 # see INSTALL for instructions.
  21
  22 my $usage="Usage: Configure [no-<cipher> ...] [enable-<cipher> ...] [-Dxxx] [-lxxx] [-Lxxx] [-fxxx] [-Kxxx] [no-hw-xxx|no-hw] [[no-]threads] [[no-]shared] [[no-]zlib|zlib-dynamic] [no-asm] [no-dso] [no-egd] [sctp] [386] [--prefix=DIR] [--openssldir=OPENSSLDIR] [--with-xxx[=vvv]] [--config=FILE] os/compiler[:flags]\n";
  23
  24 # Options:
  25 #
  26 # --config      add the given configuration file, which will be read after
  27 #               any "Configurations*" files that are found in the same
  28 #               directory as this script.
  29 # --prefix      prefix for the OpenSSL installation, which includes the
  30 #               directories bin, lib, include, share/man, share/doc/openssl
  31 #               This becomes the value of INSTALLTOP in Makefile
  32 #               (Default: /usr/local)
  33 # --openssldir  OpenSSL data area, such as openssl.cnf, certificates and keys.
  34 #               If it's a relative directory, it will be added on the directory
  35 #               given with --prefix.
  36 #               This becomes the value of OPENSSLDIR in Makefile and in C.
  37 #               (Default: PREFIX/ssl)
  38 #
  39 # --cross-compile-prefix Add specified prefix to binutils components.
  40 #
  41 # --api         One of 0.9.8, 1.0.0 or 1.1.0.  Do not compile support for
  42 #               interfaces deprecated as of the specified OpenSSL version.
  43 #
  44 # no-hw-xxx     do not compile support for specific crypto hardware.
  45 #               Generic OpenSSL-style methods relating to this support
  46 #               are always compiled but return NULL if the hardware
  47 #               support isn't compiled.
  48 # no-hw         do not compile support for any crypto hardware.
  49 # [no-]threads  [don't] try to create a library that is suitable for
  50 #               multithreaded applications (default is "threads" if we
  51 #               know how to do it)
  52 # [no-]shared   [don't] try to create shared libraries when supported.
  53 # [no-]pic      [don't] try to build position independent code when supported.
  54 #               If disabled, it also disables shared and dynamic-engine.
  55 # no-asm        do not use assembler
  56 # no-dso        do not compile in any native shared-library methods. This
  57 #               will ensure that all methods just return NULL.
  58 # no-egd        do not compile support for the entropy-gathering daemon APIs
  59 # [no-]zlib     [don't] compile support for zlib compression.
  60 # zlib-dynamic  Like "zlib", but the zlib library is expected to be a shared
  61 #               library and will be loaded in run-time by the OpenSSL library.
  62 # sctp          include SCTP support
  63 # enable-weak-ssl-ciphers
  64 #               Enable weak ciphers that are disabled by default. This currently
  65 #               only includes RC4 based ciphers.
  66 # 386           generate 80386 code in assembly modules
  67 # no-sse2       disables IA-32 SSE2 code in assembly modules, the above
  68 #               mentioned '386' option implies this one
  69 # no-<cipher>   build without specified algorithm (rsa, idea, rc5, ...)
  70 # -<xxx> +<xxx> compiler options are passed through
  71 # -static       while -static is also a pass-through compiler option (and
  72 #               as such is limited to environments where it's actually
  73 #               meaningful), it triggers a number configuration options,
  74 #               namely no-dso, no-pic, no-shared and no-threads. It is
  75 #               argued that the only reason to produce statically linked
  76 #               binaries (and in context it means executables linked with
  77 #               -static flag, and not just executables linked with static
  78 #               libcrypto.a) is to eliminate dependency on specific run-time,
  79 #               a.k.a. libc version. The mentioned config options are meant
  80 #               to achieve just that. Unfortunately on Linux it's impossible
  81 #               to eliminate the dependency completely for openssl executable
  82 #               because of getaddrinfo and gethostbyname calls, which can
  83 #               invoke dynamically loadable library facility anyway to meet
  84 #               the lookup requests. For this reason on Linux statically
  85 #               linked openssl executable has rather debugging value than
  86 #               production quality.
  87 #
  88 # DEBUG_SAFESTACK use type-safe stacks to enforce type-safety on stack items
  89 #               provided to stack calls. Generates unique stack functions for
  90 #               each possible stack type.
  91 # BN_LLONG      use the type 'long long' in crypto/bn/bn.h
  92 # RC4_CHAR      use 'char' instead of 'int' for RC4_INT in crypto/rc4/rc4.h
  93 # Following are set automatically by this script
  94 #
  95 # MD5_ASM       use some extra md5 assembler,
  96 # SHA1_ASM      use some extra sha1 assembler, must define L_ENDIAN for x86
  97 # RMD160_ASM    use some extra ripemd160 assembler,
  98 # SHA256_ASM    sha256_block is implemented in assembler
  99 # SHA512_ASM    sha512_block is implemented in assembler
 100 # AES_ASM       AES_[en|de]crypt is implemented in assembler
 101
 102 # Minimum warning options... any contributions to OpenSSL should at least get
 103 # past these.
 104
 105 # DEBUG_UNUSED enables __owur (warn unused result) checks.
 106 my $gcc_devteam_warn = "-DDEBUG_UNUSED"
 107         # -DPEDANTIC complements -pedantic and is meant to mask code that
 108         # is not strictly standard-compliant and/or implementation-specific,
 109         # e.g. inline assembly, disregards to alignment requirements, such
 110         # that -pedantic would complain about. Incidentally -DPEDANTIC has
 111         # to be used even in sanitized builds, because sanitizer too is
 112         # supposed to and does take notice of non-standard behaviour. Then
 113         # -pedantic with pre-C9x compiler would also complain about 'long
 114         # long' not being supported. As 64-bit algorithms are common now,
 115         # it grew impossible to resolve this without sizeable additional
 116         # code, so we just tell compiler to be pedantic about everything
 117         # but 'long long' type.
 118         . " -Wswitch"
 119         . " -DPEDANTIC -pedantic -Wno-long-long"
 120         . " -Wall"
 121         . " -Wsign-compare"
 122         . " -Wmissing-prototypes"
 123         . " -Wshadow"
 124         . " -Wformat"
 125         . " -Wtype-limits"
 126         . " -Werror"
 127         ;
 128
 129 # These are used in addition to $gcc_devteam_warn when the compiler is clang.
 130 # TODO(openssl-team): fix problems and investigate if (at least) the
 131 # following warnings can also be enabled:
 132 #       -Wcast-align
 133 #       -Wunreachable-code
 134 #       -Wlanguage-extension-token -- no, we use asm()
 135 #       -Wunused-macros -- no, too tricky for BN and _XOPEN_SOURCE etc
 136 #       -Wextended-offsetof -- no, needed in CMS ASN1 code
 137 my $clang_devteam_warn = ""
 138         . " -Qunused-arguments"
 139         . " -Wextra"
 140         . " -Wswitch -Wswitch-default"
 141         . " -Wno-unused-parameter"
 142         . " -Wno-missing-field-initializers"
 143         . " -Wno-language-extension-token"
 144         . " -Wno-extended-offsetof"
 145         . " -Wconditional-uninitialized"
 146         . " -Wincompatible-pointer-types-discards-qualifiers"
 147         . " -Wmissing-variable-declarations"
 148         ;
 149
 150 # This adds backtrace information to the memory leak info.  Is only used
 151 # when crypto-mdebug-backtrace is enabled.
 152 my $memleak_devteam_backtrace = "-rdynamic";
 153
 154 my $strict_warnings = 0;
 155
 156 # As for $BSDthreads. Idea is to maintain "collective" set of flags,
 157 # which would cover all BSD flavors. -pthread applies to them all,
 158 # but is treated differently. OpenBSD expands is as -D_POSIX_THREAD
 159 # -lc_r, which is sufficient. FreeBSD 4.x expands it as -lc_r,
 160 # which has to be accompanied by explicit -D_THREAD_SAFE and
 161 # sometimes -D_REENTRANT. FreeBSD 5.x expands it as -lc_r, which
 162 # seems to be sufficient?
 163 our $BSDthreads="-pthread -D_THREAD_SAFE -D_REENTRANT";
 164
 165 #
 166 # API compatibility name to version number mapping.
 167 #
 168 my $maxapi = "1.1.0";           # API for "no-deprecated" builds
 169 my $apitable = {
 170     "1.1.0" => "0x10100000L",
 171     "1.0.0" => "0x10000000L",
 172     "0.9.8" => "0x00908000L",
 173 };
 174
 175 our %table = ();
 176 our %config = ();
 177 our %withargs = ();
 178
 179 # Forward declarations ###############################################
 180
 181 # read_config(filename)
 182 #
 183 # Reads a configuration file and populates %table with the contents
 184 # (which the configuration file places in %targets).
 185 sub read_config;
 186
 187 # resolve_config(target)
 188 #
 189 # Resolves all the late evaluations, inheritances and so on for the
 190 # chosen target and any target it inherits from.
 191 sub resolve_config;
 192
 193
 194 # Information collection #############################################
 195
 196 # Unified build supports separate build dir
 197 my $srcdir = catdir(absolutedir(dirname($0))); # catdir ensures local syntax
 198 my $blddir = catdir(absolutedir("."));         # catdir ensures local syntax
 199 my $dofile = abs2rel(catfile($srcdir, "util/dofile.pl"));
 200
 201 my $local_config_envname = 'OPENSSL_LOCAL_CONFIG_DIR';
 202
 203 $config{sourcedir} = abs2rel($srcdir);
 204 $config{builddir} = abs2rel($blddir);
 205
 206 # Collect reconfiguration information if needed
 207 my @argvcopy=@ARGV;
 208
 209 if (grep /^reconf(igure)?$/, @argvcopy) {
 210     if (-f "./configdata.pm") {
 211         my $file = "./configdata.pm";
 212         unless (my $return = do $file) {
 213             die "couldn't parse $file: $@" if $@;
 214             die "couldn't do $file: $!"    unless defined $return;
 215             die "couldn't run $file"       unless $return;
 216         }
 217
 218         @argvcopy = defined($configdata::config{perlargv}) ?
 219             @{$configdata::config{perlargv}} : ();
 220         die "Incorrect data to reconfigure, please do a normal configuration\n"
 221             if (grep(/^reconf/,@argvcopy));
 222         $ENV{CROSS_COMPILE} = $configdata::config{cross_compile_prefix}
 223             if defined($configdata::config{cross_compile_prefix});
 224         $ENV{CC} = $configdata::config{cc}
 225             if defined($configdata::config{cc});
 226         $ENV{CXX} = $configdata::config{cxx}
 227             if defined($configdata::config{cxx});
 228         $ENV{BUILDFILE} = $configdata::config{build_file}
 229             if defined($configdata::config{build_file});
 230         $ENV{$local_config_envname} = $configdata::config{local_config_dir}
 231             if defined($configdata::config{local_config_dir});
 232
 233         print "Reconfiguring with: ", join(" ",@argvcopy), "\n";
 234         print "    CROSS_COMPILE = ",$ENV{CROSS_COMPILE},"\n"
 235             if $ENV{CROSS_COMPILE};
 236         print "    CC = ",$ENV{CC},"\n" if $ENV{CC};
 237         print "    CXX = ",$ENV{CXX},"\n" if $ENV{CXX};
 238         print "    BUILDFILE = ",$ENV{BUILDFILE},"\n" if $ENV{BUILDFILE};
 239         print "    $local_config_envname = ",$ENV{$local_config_envname},"\n"
 240             if $ENV{$local_config_envname};
 241     } else {
 242         die "Insufficient data to reconfigure, please do a normal configuration\n";
 243     }
 244 }
 245
 246 $config{perlargv} = [ @argvcopy ];
 247
 248 # Collect version numbers
 249 $config{version} = "unknown";
 250 $config{version_num} = "unknown";
 251 $config{shlib_version_number} = "unknown";
 252 $config{shlib_version_history} = "unknown";
 253
 254 collect_information(
 255     collect_from_file(catfile($srcdir,'include/openssl/opensslv.h')),
 256     qr/OPENSSL.VERSION.TEXT.*OpenSSL (\S+) / => sub { $config{version} = $1; },
 257     qr/OPENSSL.VERSION.NUMBER.*(0x\S+)/      => sub { $config{version_num}=$1 },
 258     qr/SHLIB_VERSION_NUMBER *"([^"]+)"/      => sub { $config{shlib_version_number}=$1 },
 259     qr/SHLIB_VERSION_HISTORY *"([^"]*)"/     => sub { $config{shlib_version_history}=$1 }
 260     );
 261 if ($config{shlib_version_history} ne "") { $config{shlib_version_history} .= ":"; }
 262
 263 ($config{major}, $config{minor})
 264     = ($config{version} =~ /^([0-9]+)\.([0-9\.]+)/);
 265 ($config{shlib_major}, $config{shlib_minor})
 266     = ($config{shlib_version_number} =~ /^([0-9]+)\.([0-9\.]+)/);
 267 die "erroneous version information in opensslv.h: ",
 268     "$config{major}, $config{minor}, $config{shlib_major}, $config{shlib_minor}\n"
 269     if ($config{major} eq "" || $config{minor} eq ""
 270         || $config{shlib_major} eq "" ||  $config{shlib_minor} eq "");
 271
 272 # Collect target configurations
 273
 274 my $pattern = catfile(dirname($0), "Configurations", "*.conf");
 275 foreach (sort glob($pattern)) {
 276     &read_config($_);
 277 }
 278
 279 if (defined $ENV{$local_config_envname}) {
 280     if ($^O eq 'VMS') {
 281         # VMS environment variables are logical names,
 282         # which can be used as is
 283         $pattern = $local_config_envname . ':' . '*.conf';
 284     } else {
 285         $pattern = catfile($ENV{$local_config_envname}, '*.conf');
 286     }
 287
 288     foreach (sort glob($pattern)) {
 289         &read_config($_);
 290     }
 291 }
 292
 293
 294 print "Configuring OpenSSL version $config{version} ($config{version_num})\n";
 295
 296 $config{prefix}="";
 297 $config{openssldir}="";
 298 $config{processor}="";
 299 $config{libdir}="";
 300 $config{cross_compile_prefix}="";
 301 $config{fipslibdir}="/usr/local/ssl/fips-2.0/lib/";
 302 my $nofipscanistercheck=0;
 303 $config{baseaddr}="0xFB00000";
 304 my $auto_threads=1;    # enable threads automatically? true by default
 305 my $default_ranlib;
 306 $config{fips}=0;
 307
 308 # Top level directories to build
 309 $config{dirs} = [ "crypto", "ssl", "engines", "apps", "test", "util", "tools", "fuzz" ];
 310 # crypto/ subdirectories to build
 311 $config{sdirs} = [
 312     "objects",
 313     "md2", "md4", "md5", "sha", "mdc2", "hmac", "ripemd", "whrlpool", "poly1305", "blake2",
 314     "des", "aes", "rc2", "rc4", "rc5", "idea", "bf", "cast", "camellia", "seed", "chacha", "modes",
 315     "bn", "ec", "rsa", "dsa", "dh", "dso", "engine",
 316     "buffer", "bio", "stack", "lhash", "rand", "err",
 317     "evp", "asn1", "pem", "x509", "x509v3", "conf", "txt_db", "pkcs7", "pkcs12", "comp", "ocsp", "ui",
 318     "cms", "ts", "srp", "cmac", "ct", "async", "kdf"
 319     ];
 320 # test/ subdirectories to build
 321 $config{tdirs} = [ "ossl_shim" ];
 322
 323 # Known TLS and DTLS protocols
 324 my @tls = qw(ssl3 tls1 tls1_1 tls1_2 tls1_3);
 325 my @dtls = qw(dtls1 dtls1_2);
 326
 327 # Explicitly known options that are possible to disable.  They can
 328 # be regexps, and will be used like this: /^no-${option}$/
 329 # For developers: keep it sorted alphabetically
 330
 331 my @disablables = (
 332     "afalgeng",
 333     "asan",
 334     "asm",
 335     "async",
 336     "autoalginit",
 337     "autoerrinit",
 338     "bf",
 339     "blake2",
 340     "camellia",
 341     "capieng",
 342     "cast",
 343     "chacha",
 344     "cmac",
 345     "cms",
 346     "comp",
 347     "crypto-mdebug",
 348     "crypto-mdebug-backtrace",
 349     "ct",
 350     "deprecated",
 351     "des",
 352     "dgram",
 353     "dh",
 354     "dsa",
 355     "dso",
 356     "dtls",
 357     "dynamic-engine",
 358     "ec",
 359     "ec2m",
 360     "ecdh",
 361     "ecdsa",
 362     "ec_nistp_64_gcc_128",
 363     "egd",
 364     "engine",
 365     "err",
 366     "external-tests",
 367     "filenames",
 368     "fuzz-libfuzzer",
 369     "fuzz-afl",
 370     "gost",
 371     "heartbeats",
 372     "hw(-.+)?",
 373     "idea",
 374     "makedepend",
 375     "md2",
 376     "md4",
 377     "mdc2",
 378     "msan",
 379     "multiblock",
 380     "nextprotoneg",
 381     "ocb",
 382     "ocsp",
 383     "pic",
 384     "poly1305",
 385     "posix-io",
 386     "psk",
 387     "rc2",
 388     "rc4",
 389     "rc5",
 390     "rdrand",
 391     "rfc3779",
 392     "rmd160",
 393     "scrypt",
 394     "sctp",
 395     "seed",
 396     "shared",
 397     "sock",
 398     "srp",
 399     "srtp",
 400     "sse2",
 401     "ssl",
 402     "ssl-trace",
 403     "static-engine",
 404     "stdio",
 405     "tests",
 406     "threads",
 407     "tls",
 408     "ts",
 409     "ubsan",
 410     "ui",
 411     "unit-test",
 412     "whirlpool",
 413     "weak-ssl-ciphers",
 414     "zlib",
 415     "zlib-dynamic",
 416     );
 417 foreach my $proto ((@tls, @dtls))
 418         {
 419         push(@disablables, $proto);
 420         push(@disablables, "$proto-method");
 421         }
 422
 423 my %deprecated_disablables = (
 424     "ssl2" => undef,
 425     "buf-freelists" => undef,
 426     "ripemd" => "rmd160"
 427     );
 428
 429 # All of the following is disabled by default (RC5 was enabled before 0.9.8):
 430
 431 our %disabled = ( # "what"         => "comment"
 432                   "asan"                => "default",
 433                   "crypto-mdebug"       => "default",
 434                   "crypto-mdebug-backtrace" => "default",
 435                   "ec_nistp_64_gcc_128" => "default",
 436                   "egd"                 => "default",
 437                   "external-tests"      => "default",
 438                   "fuzz-libfuzzer"      => "default",
 439                   "fuzz-afl"            => "default",
 440                   "heartbeats"          => "default",
 441                   "md2"                 => "default",
 442                   "msan"                => "default",
 443                   "rc5"                 => "default",
 444                   "sctp"                => "default",
 445                   "ssl-trace"           => "default",
 446                   "ssl3"                => "default",
 447                   "ssl3-method"         => "default",
 448                   "ubsan"               => "default",
 449           #TODO(TLS1.3): Temporarily disabled while this is a WIP
 450                   "tls1_3"              => "default",
 451                   "unit-test"           => "default",
 452                   "weak-ssl-ciphers"    => "default",
 453                   "zlib"                => "default",
 454                   "zlib-dynamic"        => "default",
 455                 );
 456
 457 # Note: => pair form used for aesthetics, not to truly make a hash table
 458 my @disable_cascades = (
 459     # "what"            => [ "cascade", ... ]
 460     sub { $config{processor} eq "386" }
 461                         => [ "sse2" ],
 462     "ssl"               => [ "ssl3" ],
 463     "ssl3-method"       => [ "ssl3" ],
 464     "zlib"              => [ "zlib-dynamic" ],
 465     "des"               => [ "mdc2" ],
 466     "ec"                => [ "ecdsa", "ecdh" ],
 467
 468     "dgram"             => [ "dtls", "sctp" ],
 469     "sock"              => [ "dgram" ],
 470     "dtls"              => [ @dtls ],
 471
 472     # SSL 3.0, (D)TLS 1.0 and TLS 1.1 require MD5 and SHA
 473     "md5"               => [ "ssl", "tls1", "tls1_1", "dtls1" ],
 474     "sha"               => [ "ssl", "tls1", "tls1_1", "dtls1" ],
 475
 476     # Additionally, SSL 3.0 requires either RSA or DSA+DH
 477     sub { $disabled{rsa}
 478           && ($disabled{dsa} || $disabled{dh}); }
 479                         => [ "ssl" ],
 480
 481     # (D)TLS 1.0 and TLS 1.1 also require either RSA or DSA+DH
 482     # or ECDSA + ECDH.  (D)TLS 1.2 has this requirement as well.
 483     # (XXX: We don't support PSK-only builds).
 484     sub { $disabled{rsa}
 485           && ($disabled{dsa} || $disabled{dh})
 486           && ($disabled{ecdsa} || $disabled{ecdh}); }
 487                         => [ "tls1", "tls1_1", "tls1_2", "tls1_3",
 488                              "dtls1", "dtls1_2" ],
 489
 490     "tls"               => [ @tls ],
 491
 492     # SRP and HEARTBEATS require TLSEXT
 493     "tlsext"            => [ "srp", "heartbeats" ],
 494
 495     "crypto-mdebug"     => [ "crypto-mdebug-backtrace" ],
 496
 497     # Without DSO, we can't load dynamic engines, so don't build them dynamic
 498     "dso"               => [ "dynamic-engine" ],
 499
 500     # Without position independent code, there can be no shared libraries or DSOs
 501     "pic"               => [ "shared" ],
 502     "shared"            => [ "dynamic-engine" ],
 503     "engine"            => [ "afalgeng" ],
 504
 505     # no-autoalginit is only useful when building non-shared
 506     "autoalginit"       => [ "shared", "apps" ],
 507
 508     "stdio"             => [ "apps", "capieng" ],
 509     "apps"              => [ "tests" ],
 510     "comp"              => [ "zlib" ],
 511     "ec"                => [ "tls1_3" ],
 512     sub { !$disabled{"unit-test"} } => [ "heartbeats" ],
 513
 514     sub { !$disabled{"msan"} } => [ "asm" ],
 515     );
 516
 517 # Avoid protocol support holes.  Also disable all versions below N, if version
 518 # N is disabled while N+1 is enabled.
 519 #
 520 my @list = (reverse @tls);
 521 while ((my $first, my $second) = (shift @list, shift @list)) {
 522     last unless @list;
 523     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 524                               => [ @list ] );
 525     unshift @list, $second;
 526 }
 527 my @list = (reverse @dtls);
 528 while ((my $first, my $second) = (shift @list, shift @list)) {
 529     last unless @list;
 530     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 531                               => [ @list ] );
 532     unshift @list, $second;
 533 }
 534
 535 # Explicit "no-..." options will be collected in %disabled along with the defaults.
 536 # To remove something from %disabled, use "enable-foo".
 537 # For symmetry, "disable-foo" is a synonym for "no-foo".
 538
 539 my $no_sse2=0;
 540
 541 &usage if ($#ARGV < 0);
 542
 543 my $user_cflags="";
 544 my @user_defines=();
 545 $config{openssl_api_defines}=[];
 546 $config{openssl_algorithm_defines}=[];
 547 $config{openssl_thread_defines}=[];
 548 $config{openssl_sys_defines}=[];
 549 $config{openssl_other_defines}=[];
 550 my $libs="";
 551 my $target="";
 552 $config{options}="";
 553 $config{build_type} = "release";
 554
 555 my %unsupported_options = ();
 556 my %deprecated_options = ();
 557 while (@argvcopy)
 558         {
 559         $_ = shift @argvcopy;
 560         # VMS is a case insensitive environment, and depending on settings
 561         # out of our control, we may receive options uppercased.  Let's
 562         # downcase at least the part before any equal sign.
 563         if ($^O eq "VMS")
 564                 {
 565                 s/^([^=]*)/lc($1)/e;
 566                 }
 567         s /^-no-/no-/; # some people just can't read the instructions
 568
 569         # rewrite some options in "enable-..." form
 570         s /^-?-?shared$/enable-shared/;
 571         s /^sctp$/enable-sctp/;
 572         s /^threads$/enable-threads/;
 573         s /^zlib$/enable-zlib/;
 574         s /^zlib-dynamic$/enable-zlib-dynamic/;
 575
 576         if (/^(no|disable|enable)-(.+)$/)
 577                 {
 578                 my $word = $2;
 579                 if (!exists $deprecated_disablables{$word}
 580                         && !grep { $word =~ /^${_}$/ } @disablables)
 581                         {
 582                         $unsupported_options{$_} = 1;
 583                         next;
 584                         }
 585                 }
 586         if (/^no-(.+)$/ || /^disable-(.+)$/)
 587                 {
 588                 foreach my $proto ((@tls, @dtls))
 589                         {
 590                         if ($1 eq "$proto-method")
 591                                 {
 592                                 $disabled{"$proto"} = "option($proto-method)";
 593                                 last;
 594                                 }
 595                         }
 596                 if ($1 eq "dtls")
 597                         {
 598                         foreach my $proto (@dtls)
 599                                 {
 600                                 $disabled{$proto} = "option(dtls)";
 601                                 }
 602                         $disabled{"dtls"} = "option(dtls)";
 603                         }
 604                 elsif ($1 eq "ssl")
 605                         {
 606                         # Last one of its kind
 607                         $disabled{"ssl3"} = "option(ssl)";
 608                         }
 609                 elsif ($1 eq "tls")
 610                         {
 611                         # XXX: Tests will fail if all SSL/TLS
 612                         # protocols are disabled.
 613                         foreach my $proto (@tls)
 614                                 {
 615                                 $disabled{$proto} = "option(tls)";
 616                                 }
 617                         }
 618                 elsif ($1 eq "static-engine")
 619                         {
 620                         delete $disabled{"dynamic-engine"};
 621                         }
 622                 elsif ($1 eq "dynamic-engine")
 623                         {
 624                         $disabled{"dynamic-engine"} = "option";
 625                         }
 626                 elsif (exists $deprecated_disablables{$1})
 627                         {
 628                         $deprecated_options{$_} = 1;
 629                         if (defined $deprecated_disablables{$1})
 630                                 {
 631                                 $disabled{$deprecated_disablables{$1}} = "option";
 632                                 }
 633                         }
 634                 else
 635                         {
 636                         $disabled{$1} = "option";
 637                         }
 638                 # No longer an automatic choice
 639                 $auto_threads = 0 if ($1 eq "threads");
 640                 }
 641         elsif (/^enable-(.+)$/)
 642                 {
 643                 if ($1 eq "static-engine")
 644                         {
 645                         $disabled{"dynamic-engine"} = "option";
 646                         }
 647                 elsif ($1 eq "dynamic-engine")
 648                         {
 649                         delete $disabled{"dynamic-engine"};
 650                         }
 651                 elsif ($1 eq "zlib-dynamic")
 652                         {
 653                         delete $disabled{"zlib"};
 654                         }
 655                 my $algo = $1;
 656                 delete $disabled{$algo};
 657
 658                 # No longer an automatic choice
 659                 $auto_threads = 0 if ($1 eq "threads");
 660                 }
 661         elsif (/^--strict-warnings$/)
 662                 {
 663                 $strict_warnings = 1;
 664                 }
 665         elsif (/^--debug$/)
 666                 {
 667                 $config{build_type} = "debug";
 668                 }
 669         elsif (/^--release$/)
 670                 {
 671                 $config{build_type} = "release";
 672                 }
 673         elsif (/^386$/)
 674                 { $config{processor}=386; }
 675         elsif (/^fips$/)
 676                 {
 677                 $config{fips}=1;
 678                 }
 679         elsif (/^rsaref$/)
 680                 {
 681                 # No RSAref support any more since it's not needed.
 682                 # The check for the option is there so scripts aren't
 683                 # broken
 684                 }
 685         elsif (/^nofipscanistercheck$/)
 686                 {
 687                 $config{fips} = 1;
 688                 $nofipscanistercheck = 1;
 689                 }
 690         elsif (/^[-+]/)
 691                 {
 692                 if (/^--prefix=(.*)$/)
 693                         {
 694                         $config{prefix}=$1;
 695                         die "Directory given with --prefix MUST be absolute\n"
 696                                 unless file_name_is_absolute($config{prefix});
 697                         }
 698                 elsif (/^--api=(.*)$/)
 699                         {
 700                         $config{api}=$1;
 701                         }
 702                 elsif (/^--libdir=(.*)$/)
 703                         {
 704                         $config{libdir}=$1;
 705                         }
 706                 elsif (/^--openssldir=(.*)$/)
 707                         {
 708                         $config{openssldir}=$1;
 709                         }
 710                 elsif (/^--with-zlib-lib=(.*)$/)
 711                         {
 712                         $withargs{zlib_lib}=$1;
 713                         }
 714                 elsif (/^--with-zlib-include=(.*)$/)
 715                         {
 716                         $withargs{zlib_include}=$1;
 717                         }
 718                 elsif (/^--with-fuzzer-lib=(.*)$/)
 719                         {
 720                         $withargs{fuzzer_lib}=$1;
 721                         }
 722                 elsif (/^--with-fuzzer-include=(.*)$/)
 723                         {
 724                         $withargs{fuzzer_include}=$1;
 725                         }
 726                 elsif (/^--with-fipslibdir=(.*)$/)
 727                         {
 728                         $config{fipslibdir}="$1/";
 729                         }
 730                 elsif (/^--with-baseaddr=(.*)$/)
 731                         {
 732                         $config{baseaddr}="$1";
 733                         }
 734                 elsif (/^--cross-compile-prefix=(.*)$/)
 735                         {
 736                         $config{cross_compile_prefix}=$1;
 737                         }
 738                 elsif (/^--config=(.*)$/)
 739                         {
 740                         read_config $1;
 741                         }
 742                 elsif (/^-[lL](.*)$/ or /^-Wl,/)
 743                         {
 744                         $libs.=$_." ";
 745                         }
 746                 elsif (/^-rpath$/ or /^-R$/)
 747                         # -rpath is the OSF1 rpath flag
 748                         # -R is the old Solaris rpath flag
 749                         {
 750                         my $rpath = shift(@argvcopy) || "";
 751                         $rpath .= " " if $rpath ne "";
 752                         $libs.=$_." ".$rpath;
 753                         }
 754                 elsif (/^-static$/)
 755                         {
 756                         $libs.=$_." ";
 757                         $disabled{"dso"} = "forced";
 758                         $disabled{"pic"} = "forced";
 759                         $disabled{"shared"} = "forced";
 760                         $disabled{"threads"} = "forced";
 761                         }
 762                 elsif (/^-D(.*)$/)
 763                         {
 764                         push @user_defines, $1;
 765                         }
 766                 else    # common if (/^[-+]/), just pass down...
 767                         {
 768                         $_ =~ s/%([0-9a-f]{1,2})/chr(hex($1))/gei;
 769                         $user_cflags.=" ".$_;
 770                         }
 771                 }
 772         else
 773                 {
 774                 die "target already defined - $target (offending arg: $_)\n" if ($target ne "");
 775                 $target=$_;
 776                 }
 777         unless ($_ eq $target || /^no-/ || /^disable-/)
 778                 {
 779                 # "no-..." follows later after implied disactivations
 780                 # have been derived.  (Don't take this too seriously,
 781                 # we really only write OPTIONS to the Makefile out of
 782                 # nostalgia.)
 783
 784                 if ($config{options} eq "")
 785                         { $config{options} = $_; }
 786                 else
 787                         { $config{options} .= " ".$_; }
 788                 }
 789
 790         if (defined($config{api}) && !exists $apitable->{$config{api}}) {
 791                 die "***** Unsupported api compatibility level: $config{api}\n",
 792         }
 793
 794         if (keys %deprecated_options)
 795                 {
 796                 warn "***** Deprecated options: ",
 797                         join(", ", keys %deprecated_options), "\n";
 798                 }
 799         if (keys %unsupported_options)
 800                 {
 801                 die "***** Unsupported options: ",
 802                         join(", ", keys %unsupported_options), "\n";
 803                 }
 804         }
 805
 806 if ($libs =~ /(^|\s)-Wl,-rpath,/
 807     && !$disabled{shared}
 808     && !($disabled{asan} && $disabled{msan} && $disabled{ubsan})) {
 809     die "***** Cannot simultaneously use -rpath, shared libraries, and\n",
 810         "***** any of asan, msan or ubsan\n";
 811 }
 812
 813 if ($config{fips})
 814         {
 815         delete $disabled{"shared"} if ($disabled{"shared"} =~ /^default/);
 816         }
 817 else
 818         {
 819         @{$config{dirs}} = grep !/^fips$/, @{$config{dirs}};
 820         }
 821
 822 my @tocheckfor = (keys %disabled);
 823 while (@tocheckfor) {
 824     my %new_tocheckfor = ();
 825     my @cascade_copy = (@disable_cascades);
 826     while (@cascade_copy) {
 827         my ($test, $descendents) = (shift @cascade_copy, shift @cascade_copy);
 828         if (ref($test) eq "CODE" ? $test->() : defined($disabled{$test})) {
 829             foreach(grep { !defined($disabled{$_}) } @$descendents) {
 830                 $new_tocheckfor{$_} = 1; $disabled{$_} = "forced";
 831             }
 832         }
 833     }
 834     @tocheckfor = (keys %new_tocheckfor);
 835 }
 836
 837 our $die = sub { die @_; };
 838 if ($target eq "TABLE") {
 839     local $die = sub { warn @_; };
 840     foreach (sort keys %table) {
 841         print_table_entry($_, "TABLE");
 842     }
 843     exit 0;
 844 }
 845
 846 if ($target eq "LIST") {
 847     foreach (sort keys %table) {
 848         print $_,"\n" unless $table{$_}->{template};
 849     }
 850     exit 0;
 851 }
 852
 853 if ($target eq "HASH") {
 854     local $die = sub { warn @_; };
 855     print "%table = (\n";
 856     foreach (sort keys %table) {
 857         print_table_entry($_, "HASH");
 858     }
 859     exit 0;
 860 }
 861
 862 # Backward compatibility?
 863 if ($target =~ m/^CygWin32(-.*)$/) {
 864     $target = "Cygwin".$1;
 865 }
 866
 867 foreach (sort (keys %disabled))
 868         {
 869         $config{options} .= " no-$_";
 870
 871         printf "    no-%-12s %-10s", $_, "[$disabled{$_}]";
 872
 873         if (/^dso$/)
 874                 { }
 875         elsif (/^threads$/)
 876                 { }
 877         elsif (/^shared$/)
 878                 { }
 879         elsif (/^pic$/)
 880                 { }
 881         elsif (/^zlib$/)
 882                 { }
 883         elsif (/^dynamic-engine$/)
 884                 { }
 885         elsif (/^makedepend$/)
 886                 { }
 887         elsif (/^zlib-dynamic$/)
 888                 { }
 889         elsif (/^sse2$/)
 890                 { $no_sse2 = 1; }
 891         elsif (/^engine$/)
 892                 {
 893                 @{$config{dirs}} = grep !/^engines$/, @{$config{dirs}};
 894                 @{$config{sdirs}} = grep !/^engine$/, @{$config{sdirs}};
 895                 push @{$config{openssl_other_defines}}, "OPENSSL_NO_ENGINE";
 896                 print " OPENSSL_NO_ENGINE (skip engines)";
 897                 }
 898         else
 899                 {
 900                 my ($WHAT, $what);
 901
 902                 ($WHAT = $what = $_) =~ tr/[\-a-z]/[_A-Z]/;
 903
 904                 # Fix up C macro end names
 905                 $WHAT = "RMD160" if $what eq "ripemd";
 906
 907                 # fix-up crypto/directory name(s)
 908                 $what = "ripemd" if $what eq "rmd160";
 909                 $what = "whrlpool" if $what eq "whirlpool";
 910
 911                 if ($what ne "async" && $what ne "err"
 912                     && grep { $_ eq $what } @{$config{sdirs}})
 913                         {
 914                         push @{$config{openssl_algorithm_defines}}, "OPENSSL_NO_$WHAT";
 915                         @{$config{sdirs}} = grep { $_ ne $what} @{$config{sdirs}};
 916
 917                         print " OPENSSL_NO_$WHAT (skip dir)";
 918                         }
 919                 else
 920                         {
 921                         push @{$config{openssl_other_defines}}, "OPENSSL_NO_$WHAT";
 922                         print " OPENSSL_NO_$WHAT";
 923
 924                         if (/^err$/)    { push @user_defines, "OPENSSL_NO_ERR"; }
 925                         }
 926                 }
 927
 928         print "\n";
 929         }
 930
 931 print "Configuring for $target\n";
 932 # Support for legacy targets having a name starting with 'debug-'
 933 my ($d, $t) = $target =~ m/^(debug-)?(.*)$/;
 934 if ($d) {
 935     $config{build_type} = "debug";
 936
 937     # If we do not find debug-foo in the table, the target is set to foo.
 938     if (!$table{$target}) {
 939         $target = $t;
 940     }
 941 }
 942 $config{target} = $target;
 943 my %target = resolve_config($target);
 944
 945 &usage if (!%target || $target{template});
 946
 947 my %conf_files = map { $_ => 1 } (@{$target{_conf_fname_int}});
 948 $config{conf_files} = [ sort keys %conf_files ];
 949 %target = ( %{$table{DEFAULTS}}, %target );
 950
 951 $target{cxxflags}=$target{cflags} unless defined $target{cxxflags};
 952 $target{exe_extension}="";
 953 $target{exe_extension}=".exe" if ($config{target} eq "DJGPP"
 954                                   || $config{target} =~ /^(?:Cygwin|mingw)/);
 955 $target{exe_extension}=".pm"  if ($config{target} =~ /vos/);
 956
 957 ($target{shared_extension_simple}=$target{shared_extension})
 958     =~ s|\.\$\(SHLIB_MAJOR\)\.\$\(SHLIB_MINOR\)||;
 959 $target{dso_extension}=$target{shared_extension_simple};
 960 ($target{shared_import_extension}=$target{shared_extension_simple}.".a")
 961     if ($config{target} =~ /^(?:Cygwin|mingw)/);
 962
 963
 964 $config{cross_compile_prefix} = $ENV{'CROSS_COMPILE'}
 965     if $config{cross_compile_prefix} eq "";
 966
 967 # Allow overriding the names of some tools.  USE WITH CARE
 968 # Note: only Unix cares about HASHBANGPERL...  that explains
 969 # the default string.
 970 $config{perl} =    ($^O ne "VMS" ? $^X : "perl");
 971 $config{hashbangperl} =
 972     $ENV{'HASHBANGPERL'}           || $ENV{'PERL'}     || "/usr/bin/env perl";
 973 $target{cc} =      $ENV{'CC'}      || $target{cc}      || "cc";
 974 $target{cxx} =     $ENV{'CXX'}     || $target{cxx}     || "c++";
 975 $target{ranlib} =  $ENV{'RANLIB'}  || $target{ranlib}  ||
 976                    (which("$config{cross_compile_prefix}ranlib") ?
 977                           "\$(CROSS_COMPILE)ranlib" : "true");
 978 $target{ar} =      $ENV{'AR'}      || $target{ar}      || "ar";
 979 $target{nm} =      $ENV{'NM'}      || $target{nm}      || "nm";
 980 $target{rc} =
 981     $ENV{'RC'}  || $ENV{'WINDRES'} || $target{rc}      || "windres";
 982
 983 # Allow overriding the build file name
 984 $target{build_file} = $ENV{BUILDFILE} || $target{build_file} || "Makefile";
 985
 986 # Cache information necessary for reconfiguration
 987 $config{cc} = $target{cc};
 988 $config{cxx} = $target{cxx};
 989 $config{build_file} = $target{build_file};
 990
 991 # For cflags, lflags, plib_lflags, ex_libs and defines, add the debug_
 992 # or release_ attributes.
 993 # Do it in such a way that no spurious space is appended (hence the grep).
 994 $config{defines} = [];
 995 $config{cflags} = "";
 996 $config{cxxflags} = "";
 997 $config{ex_libs} = "";
 998 $config{shared_ldflag} = "";
 999
1000 # Make sure build_scheme is consistent.
1001 $target{build_scheme} = [ $target{build_scheme} ]
1002     if ref($target{build_scheme}) ne "ARRAY";
1003
1004 my ($builder, $builder_platform, @builder_opts) =
1005     @{$target{build_scheme}};
1006
1007 push @{$config{defines}}, "NDEBUG"    if $config{build_type} eq "release";
1008
1009 if ($target =~ /^mingw/ && `$target{cc} --target-help 2>&1` =~ m/-mno-cygwin/m)
1010         {
1011         $config{cflags} .= " -mno-cygwin";
1012         $config{shared_ldflag} .= " -mno-cygwin";
1013         }
1014
1015 if ($target =~ /linux.*-mips/ && !$disabled{asm} && $user_cflags !~ /-m(ips|arch=)/) {
1016         # minimally required architecture flags for assembly modules
1017         $config{cflags}="-mips2 $config{cflags}" if ($target =~ /mips32/);
1018         $config{cflags}="-mips3 $config{cflags}" if ($target =~ /mips64/);
1019 }
1020
1021 my $no_shared_warn=0;
1022 my $no_user_cflags=0;
1023 my $no_user_defines=0;
1024
1025 # The DSO code currently always implements all functions so that no
1026 # applications will have to worry about that from a compilation point
1027 # of view. However, the "method"s may return zero unless that platform
1028 # has support compiled in for them. Currently each method is enabled
1029 # by a define "DSO_<name>" ... we translate the "dso_scheme" config
1030 # string entry into using the following logic;
1031 if (!$disabled{dso} && $target{dso_scheme} ne "")
1032         {
1033         $target{dso_scheme} =~ tr/[a-z]/[A-Z]/;
1034         if ($target{dso_scheme} eq "DLFCN")
1035                 {
1036                 unshift @{$config{defines}}, "DSO_DLFCN", "HAVE_DLFCN_H";
1037                 }
1038         elsif ($target{dso_scheme} eq "DLFCN_NO_H")
1039                 {
1040                 unshift @{$config{defines}}, "DSO_DLFCN";
1041                 }
1042         else
1043                 {
1044                 unshift @{$config{defines}}, "DSO_$target{dso_scheme}";
1045                 }
1046         }
1047
1048 $config{ex_libs}="$libs$config{ex_libs}" if ($libs ne "");
1049
1050 if ($disabled{asm})
1051         {
1052         if ($config{fips})
1053                 {
1054                 @{$config{defines}} = grep !/^[BL]_ENDIAN$/, @{$config{defines}};
1055                 @{$target{defines}} = grep !/^[BL]_ENDIAN$/, @{$target{defines}};
1056                 }
1057         }
1058
1059 # If threads aren't disabled, check how possible they are
1060 unless ($disabled{threads}) {
1061     if ($auto_threads) {
1062         # Enabled by default, disable it forcibly if unavailable
1063         if ($target{thread_scheme} eq "(unknown)") {
1064             $disabled{threads} = "unavailable";
1065         }
1066     } else {
1067         # The user chose to enable threads explicitly, let's see
1068         # if there's a chance that's possible
1069         if ($target{thread_scheme} eq "(unknown)") {
1070             # If the user asked for "threads" and we don't have internal
1071             # knowledge how to do it, [s]he is expected to provide any
1072             # system-dependent compiler options that are necessary.  We
1073             # can't truly check that the given options are correct, but
1074             # we expect the user to know what [s]He is doing.
1075             if ($no_user_cflags && $no_user_defines) {
1076                 die "You asked for multi-threading support, but didn't\n"
1077                     ,"provide any system-specific compiler options\n";
1078             }
1079         }
1080     }
1081 }
1082
1083 # If threads still aren't disabled, add a C macro to ensure the source
1084 # code knows about it.  Any other flag is taken care of by the configs.
1085 unless($disabled{threads}) {
1086     foreach (("defines", "openssl_thread_defines")) {
1087         push @{$config{$_}}, "OPENSSL_THREADS";
1088     }
1089 }
1090
1091 # With "deprecated" disable all deprecated features.
1092 if (defined($disabled{"deprecated"})) {
1093         $config{api} = $maxapi;
1094 }
1095
1096 if ($target{shared_target} eq "")
1097         {
1098         $no_shared_warn = 1
1099             if ((!$disabled{shared} || !$disabled{"dynamic-engine"})
1100                 && !$config{fips});
1101         $disabled{shared} = "no-shared-target";
1102         $disabled{pic} = $disabled{shared} = $disabled{"dynamic-engine"} =
1103             "no-shared-target";
1104         }
1105
1106 if ($disabled{"dynamic-engine"}) {
1107         push @{$config{defines}}, "OPENSSL_NO_DYNAMIC_ENGINE";
1108         $config{dynamic_engines} = 0;
1109 } else {
1110         push @{$config{defines}}, "OPENSSL_NO_STATIC_ENGINE";
1111         $config{dynamic_engines} = 1;
1112 }
1113
1114 unless ($disabled{asan}) {
1115     $config{cflags} .= "-fsanitize=address ";
1116 }
1117
1118 unless ($disabled{ubsan}) {
1119     # -DPEDANTIC or -fnosanitize=alignment may also be required on some
1120     # platforms.
1121     $config{cflags} .= "-fsanitize=undefined -fno-sanitize-recover=all ";
1122 }
1123
1124 unless ($disabled{msan}) {
1125   $config{cflags} .= "-fsanitize=memory ";
1126 }
1127
1128 unless ($disabled{"fuzz-libfuzzer"} && $disabled{"fuzz-afl"}
1129         && $disabled{asan} && $disabled{ubsan} && $disabled{msan}) {
1130     $config{cflags} .= "-fno-omit-frame-pointer -g ";
1131 }
1132 #
1133 # Platform fix-ups
1134 #
1135
1136 # This saves the build files from having to check
1137 if ($disabled{pic})
1138         {
1139         $target{shared_cflag} = $target{shared_ldflag} =
1140                 $target{shared_rcflag} = "";
1141         }
1142 else
1143         {
1144         push @{$config{defines}}, "OPENSSL_PIC";
1145         }
1146
1147 if ($target{sys_id} ne "")
1148         {
1149         push @{$config{openssl_sys_defines}}, "OPENSSL_SYS_$target{sys_id}";
1150         }
1151
1152 unless ($disabled{asm}) {
1153     $target{cpuid_asm_src}=$table{DEFAULTS}->{cpuid_asm_src} if ($config{processor} eq "386");
1154     $target{bn_asm_src} =~ s/\w+-gf2m.c// if (defined($disabled{ec2m}));
1155
1156     # bn-586 is the only one implementing bn_*_part_words
1157     push @{$config{defines}}, "OPENSSL_BN_ASM_PART_WORDS" if ($target{bn_asm_src} =~ /bn-586/);
1158     push @{$config{defines}}, "OPENSSL_IA32_SSE2" if (!$no_sse2 && $target{bn_asm_src} =~ /86/);
1159
1160     push @{$config{defines}}, "OPENSSL_BN_ASM_MONT" if ($target{bn_asm_src} =~ /-mont/);
1161     push @{$config{defines}}, "OPENSSL_BN_ASM_MONT5" if ($target{bn_asm_src} =~ /-mont5/);
1162     push @{$config{defines}}, "OPENSSL_BN_ASM_GF2m" if ($target{bn_asm_src} =~ /-gf2m/);
1163
1164     if ($config{fips}) {
1165         push @{$config{openssl_other_defines}}, "OPENSSL_FIPS";
1166     }
1167
1168     if ($target{sha1_asm_src}) {
1169         push @{$config{defines}}, "SHA1_ASM"   if ($target{sha1_asm_src} =~ /sx86/ || $target{sha1_asm_src} =~ /sha1/);
1170         push @{$config{defines}}, "SHA256_ASM" if ($target{sha1_asm_src} =~ /sha256/);
1171         push @{$config{defines}}, "SHA512_ASM" if ($target{sha1_asm_src} =~ /sha512/);
1172     }
1173     if ($target{rc4_asm_src} ne $table{DEFAULTS}->{rc4_asm_src}) {
1174         push @{$config{defines}}, "RC4_ASM";
1175     }
1176     if ($target{md5_asm_src}) {
1177         push @{$config{defines}}, "MD5_ASM";
1178     }
1179     $target{cast_asm_src}=$table{DEFAULTS}->{cast_asm_src} unless $disabled{pic}; # CAST assembler is not PIC
1180     if ($target{rmd160_asm_src}) {
1181         push @{$config{defines}}, "RMD160_ASM";
1182     }
1183     if ($target{aes_asm_src}) {
1184         push @{$config{defines}}, "AES_ASM" if ($target{aes_asm_src} =~ m/\baes-/);;
1185         # aes-ctr.fake is not a real file, only indication that assembler
1186         # module implements AES_ctr32_encrypt...
1187         push @{$config{defines}}, "AES_CTR_ASM" if ($target{aes_asm_src} =~ s/\s*aes-ctr\.fake//);
1188         # aes-xts.fake indicates presence of AES_xts_[en|de]crypt...
1189         push @{$config{defines}}, "AES_XTS_ASM" if ($target{aes_asm_src} =~ s/\s*aes-xts\.fake//);
1190         $target{aes_asm_src} =~ s/\s*(vpaes|aesni)-x86\.s//g if ($no_sse2);
1191         push @{$config{defines}}, "VPAES_ASM" if ($target{aes_asm_src} =~ m/vpaes/);
1192         push @{$config{defines}}, "BSAES_ASM" if ($target{aes_asm_src} =~ m/bsaes/);
1193     }
1194     if ($target{wp_asm_src} =~ /mmx/) {
1195         if ($config{processor} eq "386") {
1196             $target{wp_asm_src}=$table{DEFAULTS}->{wp_asm_src};
1197         } elsif (!$disabled{"whirlpool"}) {
1198             push @{$config{defines}}, "WHIRLPOOL_ASM";
1199         }
1200     }
1201     if ($target{modes_asm_src} =~ /ghash-/) {
1202         push @{$config{defines}}, "GHASH_ASM";
1203     }
1204     if ($target{ec_asm_src} =~ /ecp_nistz256/) {
1205         push @{$config{defines}}, "ECP_NISTZ256_ASM";
1206     }
1207     if ($target{padlock_asm_src} ne $table{DEFAULTS}->{padlock_asm_src}) {
1208         push @{$config{defines}}, "PADLOCK_ASM";
1209     }
1210     if ($target{poly1305_asm_src} ne "") {
1211         push @{$config{defines}}, "POLY1305_ASM";
1212     }
1213 }
1214
1215 my $ecc = $target{cc};
1216 if ($^O ne "VMS" && !$disabled{makedepend}) {
1217     # Is the compiler gcc or clang?  $ecc is used below to see if
1218     # error-checking can be turned on.
1219     my $ccpcc = "$config{cross_compile_prefix}$target{cc}";
1220     open(PIPE, "$ccpcc --version 2>&1 |");
1221     my $lines = 2;
1222     while ( <PIPE> ) {
1223         # Find the version number and save the major.
1224         m|(?:.*)\b(\d+)\.\d+\.\d+\b(?:.*)|;
1225         my $compiler_major = $1;
1226         # We know that GNU C version 3 and up as well as all clang
1227         # versions support dependency generation
1228         $config{makedepprog} = $ccpcc
1229             if (/clang/ || (/gcc/ && $compiler_major >= 3));
1230         $ecc = "clang" if /clang/;
1231         $ecc = "gcc" if /gcc/;
1232         last if ($config{makedepprog} || !$lines--);
1233     }
1234     close(PIPE);
1235
1236     $config{makedepprog} = which('makedepend') unless $config{makedepprog};
1237     $disabled{makedepend} = "unavailable" unless $config{makedepprog};
1238 }
1239
1240
1241
1242 # Deal with bn_ops ###################################################
1243
1244 $config{bn_ll}                  =0;
1245 $config{export_var_as_fn}       =0;
1246 my $def_int="unsigned int";
1247 $config{rc4_int}                =$def_int;
1248 ($config{b64l},$config{b64},$config{b32})=(0,0,1);
1249
1250 my $count = 0;
1251 foreach (sort split(/\s+/,$target{bn_ops})) {
1252     $count++ if /SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT/;
1253     $config{export_var_as_fn}=1                 if $_ eq 'EXPORT_VAR_AS_FN';
1254     $config{bn_ll}=1                            if $_ eq 'BN_LLONG';
1255     $config{rc4_int}="unsigned char"            if $_ eq 'RC4_CHAR';
1256     ($config{b64l},$config{b64},$config{b32})
1257         =(0,1,0)                                if $_ eq 'SIXTY_FOUR_BIT';
1258     ($config{b64l},$config{b64},$config{b32})
1259         =(1,0,0)                                if $_ eq 'SIXTY_FOUR_BIT_LONG';
1260     ($config{b64l},$config{b64},$config{b32})
1261         =(0,0,1)                                if $_ eq 'THIRTY_TWO_BIT';
1262 }
1263 die "Exactly one of SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT can be set in bn_ops\n"
1264     if $count > 1;
1265
1266
1267 # Hack cflags for better warnings (dev option) #######################
1268
1269 # "Stringify" the C flags string.  This permits it to be made part of a string
1270 # and works as well on command lines.
1271 $config{cflags} =~ s/([\\\"])/\\$1/g;
1272
1273 if (defined($config{api})) {
1274     $config{openssl_api_defines} = [ "OPENSSL_MIN_API=".$apitable->{$config{api}} ];
1275     my $apiflag = sprintf("OPENSSL_API_COMPAT=%s", $apitable->{$config{api}});
1276     push @{$config{defines}}, $apiflag;
1277 }
1278
1279 if ($strict_warnings)
1280         {
1281         my $wopt;
1282         die "ERROR --strict-warnings requires gcc or clang"
1283             unless $ecc eq 'gcc' || $ecc eq 'clang';
1284         foreach $wopt (split /\s+/, $gcc_devteam_warn)
1285                 {
1286                 $config{cflags} .= " $wopt" unless ($config{cflags} =~ /(?:^|\s)$wopt(?:\s|$)/)
1287                 }
1288         if ($ecc eq "clang")
1289                 {
1290                 foreach $wopt (split /\s+/, $clang_devteam_warn)
1291                         {
1292                         $config{cflags} .= " $wopt" unless ($config{cflags} =~ /(?:^|\s)$wopt(?:\s|$)/)
1293                         }
1294                 }
1295         }
1296
1297 unless ($disabled{"crypto-mdebug-backtrace"})
1298         {
1299         foreach my $wopt (split /\s+/, $memleak_devteam_backtrace)
1300                 {
1301                 $config{cflags} .= " $wopt" unless ($config{cflags} =~ /(?:^|\s)$wopt(?:\s|$)/)
1302                 }
1303         if ($target =~ /^BSD-/)
1304                 {
1305                 $config{ex_libs} .= " -lexecinfo";
1306                 }
1307         }
1308
1309 if ($user_cflags ne "") { $config{cflags}="$config{cflags}$user_cflags"; $config{cxxflags}="$config{cxxflags}$user_cflags";}
1310 else                    { $no_user_cflags=1;  }
1311 if (@user_defines) { $config{defines}=[ @{$config{defines}}, @user_defines ]; }
1312 else               { $no_user_defines=1;    }
1313
1314 # ALL MODIFICATIONS TO %config and %target MUST BE DONE FROM HERE ON
1315
1316 unless ($disabled{afalgeng}) {
1317     $config{afalgeng}="";
1318     if ($target =~ m/^linux/) {
1319         my $minver = 4*10000 + 1*100 + 0;
1320         if ($config{cross_compile_prefix} eq "") {
1321             my $verstr = `uname -r`;
1322             my ($ma, $mi1, $mi2) = split("\\.", $verstr);
1323             ($mi2) = $mi2 =~ /(\d+)/;
1324             my $ver = $ma*10000 + $mi1*100 + $mi2;
1325             if ($ver < $minver) {
1326                 $disabled{afalgeng} = "too-old-kernel";
1327             } else {
1328                 push @{$config{engdirs}}, "afalg";
1329             }
1330         } else {
1331             $disabled{afalgeng} = "cross-compiling";
1332         }
1333     } else {
1334         $disabled{afalgeng}  = "not-linux";
1335     }
1336 }
1337
1338 push @{$config{openssl_other_defines}}, "OPENSSL_NO_AFALGENG" if ($disabled{afalgeng});
1339
1340 # If we use the unified build, collect information from build.info files
1341 my %unified_info = ();
1342
1343 my $buildinfo_debug = defined($ENV{CONFIGURE_DEBUG_BUILDINFO});
1344 if ($builder eq "unified") {
1345     use lib catdir(dirname(__FILE__),"util");
1346     use with_fallback qw(Text::Template);
1347
1348     sub cleandir {
1349         my $base = shift;
1350         my $dir = shift;
1351         my $relativeto = shift || ".";
1352
1353         $dir = catdir($base,$dir) unless isabsolute($dir);
1354
1355         # Make sure the directories we're building in exists
1356         mkpath($dir);
1357
1358         my $res = abs2rel(absolutedir($dir), rel2abs($relativeto));
1359         #print STDERR "DEBUG[cleandir]: $dir , $base => $res\n";
1360         return $res;
1361     }
1362
1363     sub cleanfile {
1364         my $base = shift;
1365         my $file = shift;
1366         my $relativeto = shift || ".";
1367
1368         $file = catfile($base,$file) unless isabsolute($file);
1369
1370         my $d = dirname($file);
1371         my $f = basename($file);
1372
1373         # Make sure the directories we're building in exists
1374         mkpath($d);
1375
1376         my $res = abs2rel(catfile(absolutedir($d), $f), rel2abs($relativeto));
1377         #print STDERR "DEBUG[cleanfile]: $d , $f => $res\n";
1378         return $res;
1379     }
1380
1381     # Store the name of the template file we will build the build file from
1382     # in %config.  This may be useful for the build file itself.
1383     my @build_file_template_names =
1384         ( $builder_platform."-".$target{build_file}.".tmpl",
1385           $target{build_file}.".tmpl" );
1386     my @build_file_templates = ();
1387
1388     # First, look in the user provided directory, if given
1389     if (defined $ENV{$local_config_envname}) {
1390         @build_file_templates =
1391             map {
1392                 if ($^O eq 'VMS') {
1393                     # VMS environment variables are logical names,
1394                     # which can be used as is
1395                     $local_config_envname . ':' . $_;
1396                 } else {
1397                     catfile($ENV{$local_config_envname}, $_);
1398                 }
1399             }
1400             @build_file_template_names;
1401     }
1402     # Then, look in our standard directory
1403     push @build_file_templates,
1404         ( map { cleanfile($srcdir, catfile("Configurations", $_), $blddir) }
1405           @build_file_template_names );
1406
1407     my $build_file_template;
1408     for $_ (@build_file_templates) {
1409         $build_file_template = $_;
1410         last if -f $build_file_template;
1411
1412         $build_file_template = undef;
1413     }
1414     if (!defined $build_file_template) {
1415         die "*** Couldn't find any of:\n", join("\n", @build_file_templates), "\n";
1416     }
1417     $config{build_file_templates}
1418       = [ $build_file_template,
1419           cleanfile($srcdir, catfile("Configurations", "common.tmpl"),
1420                     $blddir) ];
1421
1422     my @build_infos = ( [ ".", "build.info" ] );
1423     foreach (@{$config{dirs}}) {
1424         push @build_infos, [ $_, "build.info" ]
1425             if (-f catfile($srcdir, $_, "build.info"));
1426     }
1427     foreach (@{$config{sdirs}}) {
1428         push @build_infos, [ catdir("crypto", $_), "build.info" ]
1429             if (-f catfile($srcdir, "crypto", $_, "build.info"));
1430     }
1431     foreach (@{$config{engdirs}}) {
1432         push @build_infos, [ catdir("engines", $_), "build.info" ]
1433             if (-f catfile($srcdir, "engines", $_, "build.info"));
1434     }
1435     foreach (@{$config{tdirs}}) {
1436         push @build_infos, [ catdir("test", $_), "build.info" ]
1437             if (-f catfile($srcdir, "test", $_, "build.info"));
1438     }
1439
1440     $config{build_infos} = [ ];
1441
1442     foreach (@build_infos) {
1443         my $sourced = catdir($srcdir, $_->[0]);
1444         my $buildd = catdir($blddir, $_->[0]);
1445
1446         mkpath($buildd);
1447
1448         my $f = $_->[1];
1449         # The basic things we're trying to build
1450         my @programs = ();
1451         my @programs_install = ();
1452         my @libraries = ();
1453         my @libraries_install = ();
1454         my @engines = ();
1455         my @engines_install = ();
1456         my @scripts = ();
1457         my @scripts_install = ();
1458         my @extra = ();
1459         my @overrides = ();
1460         my @intermediates = ();
1461         my @rawlines = ();
1462
1463         my %ordinals = ();
1464         my %sources = ();
1465         my %shared_sources = ();
1466         my %includes = ();
1467         my %depends = ();
1468         my %renames = ();
1469         my %sharednames = ();
1470         my %generate = ();
1471
1472         push @{$config{build_infos}}, catfile(abs2rel($sourced, $blddir), $f);
1473         my $template = Text::Template->new(TYPE => 'FILE',
1474                                            SOURCE => catfile($sourced, $f));
1475         die "Something went wrong with $sourced/$f: $!\n" unless $template;
1476         my @text =
1477             split /^/m,
1478             $template->fill_in(HASH => { config => \%config,
1479                                          target => \%target,
1480                                          disabled => \%disabled,
1481                                          withargs => \%withargs,
1482                                          builddir => abs2rel($buildd, $blddir),
1483                                          sourcedir => abs2rel($sourced, $blddir),
1484                                          buildtop => abs2rel($blddir, $blddir),
1485                                          sourcetop => abs2rel($srcdir, $blddir) },
1486                                DELIMITERS => [ "{-", "-}" ]);
1487
1488         # The top item of this stack has the following values
1489         # -2 positive already run and we found ELSE (following ELSIF should fail)
1490         # -1 positive already run (skip until ENDIF)
1491         # 0 negatives so far (if we're at a condition, check it)
1492         # 1 last was positive (don't skip lines until next ELSE, ELSIF or ENDIF)
1493         # 2 positive ELSE (following ELSIF should fail)
1494         my @skip = ();
1495         collect_information(
1496             collect_from_array([ @text ],
1497                                qr/\\$/ => sub { my $l1 = shift; my $l2 = shift;
1498                                                 $l1 =~ s/\\$//; $l1.$l2 }),
1499             # Info we're looking for
1500             qr/^\s*IF\[((?:\\.|[^\\\]])*)\]\s*$/
1501             => sub {
1502                 if (! @skip || $skip[$#skip] > 0) {
1503                     push @skip, !! $1;
1504                 } else {
1505                     push @skip, -1;
1506                 }
1507             },
1508             qr/^\s*ELSIF\[((?:\\.|[^\\\]])*)\]\s*$/
1509             => sub { die "ELSIF out of scope" if ! @skip;
1510                      die "ELSIF following ELSE" if abs($skip[$#skip]) == 2;
1511                      $skip[$#skip] = -1 if $skip[$#skip] != 0;
1512                      $skip[$#skip] = !! $1
1513                          if $skip[$#skip] == 0; },
1514             qr/^\s*ELSE\s*$/
1515             => sub { die "ELSE out of scope" if ! @skip;
1516                      $skip[$#skip] = -2 if $skip[$#skip] != 0;
1517                      $skip[$#skip] = 2 if $skip[$#skip] == 0; },
1518             qr/^\s*ENDIF\s*$/
1519             => sub { die "ENDIF out of scope" if ! @skip;
1520                      pop @skip; },
1521             qr/^\s*PROGRAMS(_NO_INST)?\s*=\s*(.*)\s*$/
1522             => sub {
1523                 if (!@skip || $skip[$#skip] > 0) {
1524                     my $install = $1;
1525                     my @x = tokenize($2);
1526                     push @programs, @x;
1527                     push @programs_install, @x unless $install;
1528                 }
1529             },
1530             qr/^\s*LIBS(_NO_INST)?\s*=\s*(.*)\s*$/
1531             => sub {
1532                 if (!@skip || $skip[$#skip] > 0) {
1533                     my $install = $1;
1534                     my @x = tokenize($2);
1535                     push @libraries, @x;
1536                     push @libraries_install, @x unless $install;
1537                 }
1538             },
1539             qr/^\s*ENGINES(_NO_INST)?\s*=\s*(.*)\s*$/
1540             => sub {
1541                 if (!@skip || $skip[$#skip] > 0) {
1542                     my $install = $1;
1543                     my @x = tokenize($2);
1544                     push @engines, @x;
1545                     push @engines_install, @x unless $install;
1546                 }
1547             },
1548             qr/^\s*SCRIPTS(_NO_INST)?\s*=\s*(.*)\s*$/
1549             => sub {
1550                 if (!@skip || $skip[$#skip] > 0) {
1551                     my $install = $1;
1552                     my @x = tokenize($2);
1553                     push @scripts, @x;
1554                     push @scripts_install, @x unless $install;
1555                 }
1556             },
1557             qr/^\s*EXTRA\s*=\s*(.*)\s*$/
1558             => sub { push @extra, tokenize($1)
1559                          if !@skip || $skip[$#skip] > 0 },
1560             qr/^\s*OVERRIDES\s*=\s*(.*)\s*$/
1561             => sub { push @overrides, tokenize($1)
1562                          if !@skip || $skip[$#skip] > 0 },
1563
1564             qr/^\s*ORDINALS\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/,
1565             => sub { push @{$ordinals{$1}}, tokenize($2)
1566                          if !@skip || $skip[$#skip] > 0 },
1567             qr/^\s*SOURCE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1568             => sub { push @{$sources{$1}}, tokenize($2)
1569                          if !@skip || $skip[$#skip] > 0 },
1570             qr/^\s*SHARED_SOURCE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1571             => sub { push @{$shared_sources{$1}}, tokenize($2)
1572                          if !@skip || $skip[$#skip] > 0 },
1573             qr/^\s*INCLUDE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1574             => sub { push @{$includes{$1}}, tokenize($2)
1575                          if !@skip || $skip[$#skip] > 0 },
1576             qr/^\s*DEPEND\[((?:\\.|[^\\\]])*)\]\s*=\s*(.*)\s*$/
1577             => sub { push @{$depends{$1}}, tokenize($2)
1578                          if !@skip || $skip[$#skip] > 0 },
1579             qr/^\s*GENERATE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1580             => sub { push @{$generate{$1}}, $2
1581                          if !@skip || $skip[$#skip] > 0 },
1582             qr/^\s*RENAME\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1583             => sub { push @{$renames{$1}}, tokenize($2)
1584                          if !@skip || $skip[$#skip] > 0 },
1585             qr/^\s*SHARED_NAME\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1586             => sub { push @{$sharednames{$1}}, tokenize($2)
1587                          if !@skip || $skip[$#skip] > 0 },
1588             qr/^\s*BEGINRAW\[((?:\\.|[^\\\]])+)\]\s*$/
1589             => sub {
1590                 my $lineiterator = shift;
1591                 my $target_kind = $1;
1592                 while (defined $lineiterator->()) {
1593                     s|\R$||;
1594                     if (/^\s*ENDRAW\[((?:\\.|[^\\\]])+)\]\s*$/) {
1595                         die "ENDRAW doesn't match BEGINRAW"
1596                             if $1 ne $target_kind;
1597                         last;
1598                     }
1599                     next if @skip && $skip[$#skip] <= 0;
1600                     push @rawlines,  $_
1601                         if ($target_kind eq $target{build_file}
1602                             || $target_kind eq $target{build_file}."(".$builder_platform.")");
1603                 }
1604             },
1605             qr/^\s*(?:#.*)?$/ => sub { },
1606             "OTHERWISE" => sub { die "Something wrong with this line:\n$_\nat $sourced/$f" },
1607             "BEFORE" => sub {
1608                 if ($buildinfo_debug) {
1609                     print STDERR "DEBUG: Parsing ",join(" ", @_),"\n";
1610                     print STDERR "DEBUG: ... before parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
1611                 }
1612             },
1613             "AFTER" => sub {
1614                 if ($buildinfo_debug) {
1615                     print STDERR "DEBUG: .... after parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
1616                 }
1617             },
1618             );
1619         die "runaway IF?" if (@skip);
1620
1621         foreach (keys %renames) {
1622             die "$_ renamed to more than one thing: "
1623                 ,join(" ", @{$renames{$_}}),"\n"
1624                 if scalar @{$renames{$_}} > 1;
1625             my $dest = cleanfile($buildd, $_, $blddir);
1626             my $to = cleanfile($buildd, $renames{$_}->[0], $blddir);
1627             die "$dest renamed to more than one thing: "
1628                 ,$unified_info{rename}->{$dest}, $to
1629                 unless !defined($unified_info{rename}->{$dest})
1630                 or $unified_info{rename}->{$dest} eq $to;
1631             $unified_info{rename}->{$dest} = $to;
1632         }
1633
1634         foreach (@programs) {
1635             my $program = cleanfile($buildd, $_, $blddir);
1636             if ($unified_info{rename}->{$program}) {
1637                 $program = $unified_info{rename}->{$program};
1638             }
1639             $unified_info{programs}->{$program} = 1;
1640         }
1641
1642         foreach (@programs_install) {
1643             my $program = cleanfile($buildd, $_, $blddir);
1644             if ($unified_info{rename}->{$program}) {
1645                 $program = $unified_info{rename}->{$program};
1646             }
1647             $unified_info{install}->{programs}->{$program} = 1;
1648         }
1649
1650         foreach (@libraries) {
1651             my $library = cleanfile($buildd, $_, $blddir);
1652             if ($unified_info{rename}->{$library}) {
1653                 $library = $unified_info{rename}->{$library};
1654             }
1655             $unified_info{libraries}->{$library} = 1;
1656         }
1657
1658         foreach (@libraries_install) {
1659             my $library = cleanfile($buildd, $_, $blddir);
1660             if ($unified_info{rename}->{$library}) {
1661                 $library = $unified_info{rename}->{$library};
1662             }
1663             $unified_info{install}->{libraries}->{$library} = 1;
1664         }
1665
1666         die <<"EOF" if scalar @engines and !$config{dynamic_engines};
1667 ENGINES can only be used if configured with 'dynamic-engine'.
1668 This is usually a fault in a build.info file.
1669 EOF
1670         foreach (@engines) {
1671             my $library = cleanfile($buildd, $_, $blddir);
1672             if ($unified_info{rename}->{$library}) {
1673                 $library = $unified_info{rename}->{$library};
1674             }
1675             $unified_info{engines}->{$library} = 1;
1676         }
1677
1678         foreach (@engines_install) {
1679             my $library = cleanfile($buildd, $_, $blddir);
1680             if ($unified_info{rename}->{$library}) {
1681                 $library = $unified_info{rename}->{$library};
1682             }
1683             $unified_info{install}->{engines}->{$library} = 1;
1684         }
1685
1686         foreach (@scripts) {
1687             my $script = cleanfile($buildd, $_, $blddir);
1688             if ($unified_info{rename}->{$script}) {
1689                 $script = $unified_info{rename}->{$script};
1690             }
1691             $unified_info{scripts}->{$script} = 1;
1692         }
1693
1694         foreach (@scripts_install) {
1695             my $script = cleanfile($buildd, $_, $blddir);
1696             if ($unified_info{rename}->{$script}) {
1697                 $script = $unified_info{rename}->{$script};
1698             }
1699             $unified_info{install}->{scripts}->{$script} = 1;
1700         }
1701
1702         foreach (@extra) {
1703             my $extra = cleanfile($buildd, $_, $blddir);
1704             $unified_info{extra}->{$extra} = 1;
1705         }
1706
1707         foreach (@overrides) {
1708             my $override = cleanfile($buildd, $_, $blddir);
1709             $unified_info{overrides}->{$override} = 1;
1710         }
1711
1712         push @{$unified_info{rawlines}}, @rawlines;
1713
1714         unless ($disabled{shared}) {
1715             # Check sharednames.
1716             foreach (keys %sharednames) {
1717                 my $dest = cleanfile($buildd, $_, $blddir);
1718                 if ($unified_info{rename}->{$dest}) {
1719                     $dest = $unified_info{rename}->{$dest};
1720                 }
1721                 die "shared_name for $dest with multiple values: "
1722                     ,join(" ", @{$sharednames{$_}}),"\n"
1723                     if scalar @{$sharednames{$_}} > 1;
1724                 my $to = cleanfile($buildd, $sharednames{$_}->[0], $blddir);
1725                 die "shared_name found for a library $dest that isn't defined\n"
1726                     unless $unified_info{libraries}->{$dest};
1727                 die "shared_name for $dest with multiple values: "
1728                     ,$unified_info{sharednames}->{$dest}, ", ", $to
1729                     unless !defined($unified_info{sharednames}->{$dest})
1730                     or $unified_info{sharednames}->{$dest} eq $to;
1731                 $unified_info{sharednames}->{$dest} = $to;
1732             }
1733
1734             # Additionally, we set up sharednames for libraries that don't
1735             # have any, as themselves.
1736             foreach (keys %{$unified_info{libraries}}) {
1737                 if (!defined $unified_info{sharednames}->{$_}) {
1738                     $unified_info{sharednames}->{$_} = $_
1739                 }
1740             }
1741         }
1742
1743         foreach (keys %ordinals) {
1744             my $dest = $_;
1745             my $ddest = cleanfile($buildd, $_, $blddir);
1746             if ($unified_info{rename}->{$ddest}) {
1747                 $ddest = $unified_info{rename}->{$ddest};
1748             }
1749             foreach (@{$ordinals{$dest}}) {
1750                 my %known_ordinals =
1751                     (
1752                      crypto =>
1753                      cleanfile($sourced, catfile("util", "libcrypto.num"), $blddir),
1754                      ssl =>
1755                      cleanfile($sourced, catfile("util", "libssl.num"), $blddir)
1756                     );
1757                 my $o = $known_ordinals{$_};
1758                 die "Ordinals for $ddest defined more than once\n"
1759                     if $unified_info{ordinals}->{$ddest};
1760                 $unified_info{ordinals}->{$ddest} = [ $_, $o ];
1761             }
1762         }
1763
1764         foreach (keys %sources) {
1765             my $dest = $_;
1766             my $ddest = cleanfile($buildd, $_, $blddir);
1767             if ($unified_info{rename}->{$ddest}) {
1768                 $ddest = $unified_info{rename}->{$ddest};
1769             }
1770             foreach (@{$sources{$dest}}) {
1771                 my $s = cleanfile($sourced, $_, $blddir);
1772
1773                 # If it isn't in the source tree, we assume it's generated
1774                 # in the build tree
1775                 if (! -f $s) {
1776                     $s = cleanfile($buildd, $_, $blddir);
1777                 }
1778                 # We recognise C++, C and asm files
1779                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
1780                     my $o = $_;
1781                     $o =~ s/\.[csS]$/.o/; # C and assembler
1782                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
1783                     $o = cleanfile($buildd, $o, $blddir);
1784                     $unified_info{sources}->{$ddest}->{$o} = 1;
1785                     $unified_info{sources}->{$o}->{$s} = 1;
1786                 } else {
1787                     $unified_info{sources}->{$ddest}->{$s} = 1;
1788                 }
1789             }
1790         }
1791
1792         foreach (keys %shared_sources) {
1793             my $dest = $_;
1794             my $ddest = cleanfile($buildd, $_, $blddir);
1795             if ($unified_info{rename}->{$ddest}) {
1796                 $ddest = $unified_info{rename}->{$ddest};
1797             }
1798             foreach (@{$shared_sources{$dest}}) {
1799                 my $s = cleanfile($sourced, $_, $blddir);
1800
1801                 # If it isn't in the source tree, we assume it's generated
1802                 # in the build tree
1803                 if (! -f $s) {
1804                     $s = cleanfile($buildd, $_, $blddir);
1805                 }
1806                 # We recognise C++, C and asm files
1807                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
1808                     my $o = $_;
1809                     $o =~ s/\.[csS]$/.o/; # C and assembler
1810                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
1811                     $o = cleanfile($buildd, $o, $blddir);
1812                     $unified_info{shared_sources}->{$ddest}->{$o} = 1;
1813                     $unified_info{sources}->{$o}->{$s} = 1;
1814                 } else {
1815                     die "unrecognised source file type for shared library: $s\n";
1816                 }
1817             }
1818         }
1819
1820         foreach (keys %generate) {
1821             my $dest = $_;
1822             my $ddest = cleanfile($buildd, $_, $blddir);
1823             if ($unified_info{rename}->{$ddest}) {
1824                 $ddest = $unified_info{rename}->{$ddest};
1825             }
1826             die "more than one generator for $dest: "
1827                     ,join(" ", @{$generate{$_}}),"\n"
1828                     if scalar @{$generate{$_}} > 1;
1829             my @generator = split /\s+/, $generate{$dest}->[0];
1830             $generator[0] = cleanfile($sourced, $generator[0], $blddir),
1831             $unified_info{generate}->{$ddest} = [ @generator ];
1832         }
1833
1834         foreach (keys %depends) {
1835             my $dest = $_;
1836             my $ddest = $dest eq "" ? "" : cleanfile($sourced, $_, $blddir);
1837
1838             # If the destination doesn't exist in source, it can only be
1839             # a generated file in the build tree.
1840             if ($ddest ne "" && ! -f $ddest) {
1841                 $ddest = cleanfile($buildd, $_, $blddir);
1842                 if ($unified_info{rename}->{$ddest}) {
1843                     $ddest = $unified_info{rename}->{$ddest};
1844                 }
1845             }
1846             foreach (@{$depends{$dest}}) {
1847                 my $d = cleanfile($sourced, $_, $blddir);
1848
1849                 # If we know it's generated, or assume it is because we can't
1850                 # find it in the source tree, we set file we depend on to be
1851                 # in the build tree rather than the source tree, and assume
1852                 # and that there are lines to build it in a BEGINRAW..ENDRAW
1853                 # section or in the Makefile template.
1854                 if (! -f $d
1855                     || (grep { $d eq $_ }
1856                         map { cleanfile($srcdir, $_, $blddir) }
1857                         grep { /\.h$/ } keys %{$unified_info{generate}})) {
1858                     $d = cleanfile($buildd, $_, $blddir);
1859                 }
1860                 # Take note if the file to depend on is being renamed
1861                 # Take extra care with files ending with .a, they should
1862                 # be treated without that extension, and the extension
1863                 # should be added back after treatment.
1864                 $d =~ /(\.a)?$/;
1865                 my $e = $1 // "";
1866                 $d = $`;
1867                 if ($unified_info{rename}->{$d}) {
1868                     $d = $unified_info{rename}->{$d};
1869                 }
1870                 $d .= $e;
1871                 $unified_info{depends}->{$ddest}->{$d} = 1;
1872                 # If we depend on a header file or a perl module, let's make
1873                 # sure it can get included
1874                 if ($dest ne "" && $d =~ /\.(h|pm)$/) {
1875                     my $i = dirname($d);
1876                     push @{$unified_info{includes}->{$ddest}->{source}}, $i
1877                         unless grep { $_ eq $i } @{$unified_info{includes}->{$ddest}->{source}};
1878                 }
1879             }
1880         }
1881
1882         foreach (keys %includes) {
1883             my $dest = $_;
1884             my $ddest = cleanfile($sourced, $_, $blddir);
1885
1886             # If the destination doesn't exist in source, it can only be
1887             # a generated file in the build tree.
1888             if (! -f $ddest) {
1889                 $ddest = cleanfile($buildd, $_, $blddir);
1890                 if ($unified_info{rename}->{$ddest}) {
1891                     $ddest = $unified_info{rename}->{$ddest};
1892                 }
1893             }
1894             foreach (@{$includes{$dest}}) {
1895                 my $is = cleandir($sourced, $_, $blddir);
1896                 my $ib = cleandir($buildd, $_, $blddir);
1897                 push @{$unified_info{includes}->{$ddest}->{source}}, $is
1898                     unless grep { $_ eq $is } @{$unified_info{includes}->{$ddest}->{source}};
1899                 push @{$unified_info{includes}->{$ddest}->{build}}, $ib
1900                     unless grep { $_ eq $ib } @{$unified_info{includes}->{$ddest}->{build}};
1901             }
1902         }
1903     }
1904
1905     ### Make unified_info a bit more efficient
1906     # One level structures
1907     foreach (("programs", "libraries", "engines", "scripts", "extra", "overrides")) {
1908         $unified_info{$_} = [ sort keys %{$unified_info{$_}} ];
1909     }
1910     # Two level structures
1911     foreach my $l1 (("install", "sources", "shared_sources", "ldadd", "depends")) {
1912         foreach my $l2 (sort keys %{$unified_info{$l1}}) {
1913             $unified_info{$l1}->{$l2} =
1914                 [ sort keys %{$unified_info{$l1}->{$l2}} ];
1915         }
1916     }
1917     # Includes
1918     foreach my $dest (sort keys %{$unified_info{includes}}) {
1919         if (defined($unified_info{includes}->{$dest}->{build})) {
1920             my @source_includes =
1921                 ( @{$unified_info{includes}->{$dest}->{source}} );
1922             $unified_info{includes}->{$dest} =
1923                 [ @{$unified_info{includes}->{$dest}->{build}} ];
1924             foreach my $inc (@source_includes) {
1925                 push @{$unified_info{includes}->{$dest}}, $inc
1926                     unless grep { $_ eq $inc } @{$unified_info{includes}->{$dest}};
1927             }
1928         } else {
1929             $unified_info{includes}->{$dest} =
1930                 [ @{$unified_info{includes}->{$dest}->{source}} ];
1931         }
1932     }
1933 }
1934
1935 # For the schemes that need it, we provide the old *_obj configs
1936 # from the *_asm_obj ones
1937 foreach (grep /_(asm|aux)_src$/, keys %target) {
1938     my $src = $_;
1939     (my $obj = $_) =~ s/_(asm|aux)_src$/_obj/;
1940     $target{$obj} = $target{$src};
1941     $target{$obj} =~ s/\.[csS]\b/.o/g; # C and assembler
1942     $target{$obj} =~ s/\.(cc|cpp)\b/_cc.o/g; # C++
1943 }
1944
1945 # Write down our configuration where it fits #########################
1946
1947 open(OUT,">configdata.pm") || die "unable to create configdata.pm: $!\n";
1948 print OUT <<"EOF";
1949 package configdata;
1950
1951 use strict;
1952 use warnings;
1953
1954 use Exporter;
1955 #use vars qw(\@ISA \@EXPORT);
1956 our \@ISA = qw(Exporter);
1957 our \@EXPORT = qw(\%config \%target \%disabled \%withargs \%unified_info \@disablables);
1958
1959 EOF
1960 print OUT "our %config = (\n";
1961 foreach (sort keys %config) {
1962     if (ref($config{$_}) eq "ARRAY") {
1963         print OUT "  ", $_, " => [ ", join(", ",
1964                                            map { quotify("perl", $_) }
1965                                            @{$config{$_}}), " ],\n";
1966     } else {
1967         print OUT "  ", $_, " => ", quotify("perl", $config{$_}), ",\n"
1968     }
1969 }
1970 print OUT <<"EOF";
1971 );
1972
1973 EOF
1974 print OUT "our %target = (\n";
1975 foreach (sort keys %target) {
1976     if (ref($target{$_}) eq "ARRAY") {
1977         print OUT "  ", $_, " => [ ", join(", ",
1978                                            map { quotify("perl", $_) }
1979                                            @{$target{$_}}), " ],\n";
1980     } else {
1981         print OUT "  ", $_, " => ", quotify("perl", $target{$_}), ",\n"
1982     }
1983 }
1984 print OUT <<"EOF";
1985 );
1986
1987 EOF
1988 print OUT "our \%available_protocols = (\n";
1989 print OUT "  tls => [ ", join(", ", map { quotify("perl", $_) } @tls), " ],\n";
1990 print OUT "  dtls => [ ", join(", ", map { quotify("perl", $_) } @dtls), " ],\n";
1991 print OUT <<"EOF";
1992 );
1993
1994 EOF
1995 print OUT "our \@disablables = (\n";
1996 foreach (@disablables) {
1997     print OUT "  ", quotify("perl", $_), ",\n";
1998 }
1999 print OUT <<"EOF";
2000 );
2001
2002 EOF
2003 print OUT "our \%disabled = (\n";
2004 foreach (sort keys %disabled) {
2005     print OUT "  ", quotify("perl", $_), " => ", quotify("perl", $disabled{$_}), ",\n";
2006 }
2007 print OUT <<"EOF";
2008 );
2009
2010 EOF
2011 print OUT "our %withargs = (\n";
2012 foreach (sort keys %withargs) {
2013     if (ref($withargs{$_}) eq "ARRAY") {
2014         print OUT "  ", $_, " => [ ", join(", ",
2015                                            map { quotify("perl", $_) }
2016                                            @{$withargs{$_}}), " ],\n";
2017     } else {
2018         print OUT "  ", $_, " => ", quotify("perl", $withargs{$_}), ",\n"
2019     }
2020 }
2021 print OUT <<"EOF";
2022 );
2023
2024 EOF
2025 if ($builder eq "unified") {
2026     my $recurse;
2027     $recurse = sub {
2028         my $indent = shift;
2029         foreach (@_) {
2030             if (ref $_ eq "ARRAY") {
2031                 print OUT " "x$indent, "[\n";
2032                 foreach (@$_) {
2033                     $recurse->($indent + 4, $_);
2034                 }
2035                 print OUT " "x$indent, "],\n";
2036             } elsif (ref $_ eq "HASH") {
2037                 my %h = %$_;
2038                 print OUT " "x$indent, "{\n";
2039                 foreach (sort keys %h) {
2040                     if (ref $h{$_} eq "") {
2041                         print OUT " "x($indent + 4), quotify("perl", $_), " => ", quotify("perl", $h{$_}), ",\n";
2042                     } else {
2043                         print OUT " "x($indent + 4), quotify("perl", $_), " =>\n";
2044                         $recurse->($indent + 8, $h{$_});
2045                     }
2046                 }
2047                 print OUT " "x$indent, "},\n";
2048             } else {
2049                 print OUT " "x$indent, quotify("perl", $_), ",\n";
2050             }
2051         }
2052     };
2053     print OUT "our %unified_info = (\n";
2054     foreach (sort keys %unified_info) {
2055         if (ref $unified_info{$_} eq "") {
2056             print OUT " "x4, quotify("perl", $_), " => ", quotify("perl", $unified_info{$_}), ",\n";
2057         } else {
2058             print OUT " "x4, quotify("perl", $_), " =>\n";
2059             $recurse->(8, $unified_info{$_});
2060         }
2061     }
2062     print OUT <<"EOF";
2063 );
2064
2065 EOF
2066 }
2067 print OUT "1;\n";
2068 close(OUT);
2069
2070 print "\n";
2071 print "PROCESSOR     =$config{processor}\n" if $config{processor};
2072 print "PERL          =$config{perl}\n";
2073 print "PERLVERSION   =$Config{version} for $Config{archname}\n";
2074 print "HASHBANGPERL  =$config{hashbangperl}\n";
2075 print "CC            =$config{cross_compile_prefix}$target{cc}\n";
2076 print "CFLAG         =$target{cflags} $config{cflags}\n";
2077 print "CXX           =$config{cross_compile_prefix}$target{cxx}\n"
2078     if defined $target{cxx};
2079 print "CXXFLAG       =$target{cxxflags} $config{cxxflags}\n"
2080     if defined $target{cxx};
2081 print "DEFINES       =",join(" ", @{$target{defines}}, @{$config{defines}}),"\n";
2082 #print "RANLIB        =", $target{ranlib} eq '$(CROSS_COMPILE)ranlib' ?
2083 #                             "$config{cross_compile_prefix}ranlib" :
2084 #                             "$target{ranlib}", "\n";
2085 print "EX_LIBS       =$target{ex_libs} $config{ex_libs}\n";
2086
2087 my %builders = (
2088     unified => sub {
2089         run_dofile(catfile($blddir, $target{build_file}),
2090                    @{$config{build_file_templates}});
2091     },
2092     );
2093
2094 $builders{$builder}->($builder_platform, @builder_opts);
2095
2096 print <<"EOF" if ($disabled{threads} eq "unavailable");
2097
2098 The library could not be configured for supporting multi-threaded
2099 applications as the compiler options required on this system are not known.
2100 See file INSTALL for details if you need multi-threading.
2101 EOF
2102
2103 print <<"EOF" if ($no_shared_warn);
2104
2105 The options 'shared', 'pic' and 'dynamic-engine' aren't supported on this
2106 platform, so we will pretend you gave the option 'no-pic', which also disables
2107 'shared' and 'dynamic-engine'.  If you know how to implement shared libraries
2108 or position independent code, please let us know (but please first make sure
2109 you have tried with a current version of OpenSSL).
2110 EOF
2111
2112 print <<"EOF" if (-f catfile($srcdir, "configdata.pm") && $srcdir ne $blddir);
2113
2114 WARNING: there are indications that another build was made in the source
2115 directory.  This build may have picked up artifacts from that build, the
2116 safest course of action is to clean the source directory and redo this
2117 configuration.
2118 EOF
2119
2120 exit(0);
2121
2122 ######################################################################
2123 #
2124 # Helpers and utility functions
2125 #
2126
2127 # Configuration file reading #########################################
2128
2129 # Note: All of the helper functions are for lazy evaluation.  They all
2130 # return a CODE ref, which will return the intended value when evaluated.
2131 # Thus, whenever there's mention of a returned value, it's about that
2132 # intended value.
2133
2134 # Helper function to implement conditional inheritance depending on the
2135 # value of $disabled{asm}.  Used in inherit_from values as follows:
2136 #
2137 #      inherit_from => [ "template", asm("asm_tmpl") ]
2138 #
2139 sub asm {
2140     my @x = @_;
2141     sub {
2142         $disabled{asm} ? () : @x;
2143     }
2144 }
2145
2146 # Helper function to implement conditional value variants, with a default
2147 # plus additional values based on the value of $config{build_type}.
2148 # Arguments are given in hash table form:
2149 #
2150 #       picker(default => "Basic string: ",
2151 #              debug   => "debug",
2152 #              release => "release")
2153 #
2154 # When configuring with --debug, the resulting string will be
2155 # "Basic string: debug", and when not, it will be "Basic string: release"
2156 #
2157 # This can be used to create variants of sets of flags according to the
2158 # build type:
2159 #
2160 #       cflags => picker(default => "-Wall",
2161 #                        debug   => "-g -O0",
2162 #                        release => "-O3")
2163 #
2164 sub picker {
2165     my %opts = @_;
2166     return sub { add($opts{default} || (),
2167                      $opts{$config{build_type}} || ())->(); }
2168 }
2169
2170 # Helper function to combine several values of different types into one.
2171 # This is useful if you want to combine a string with the result of a
2172 # lazy function, such as:
2173 #
2174 #       cflags => combine("-Wall", sub { $disabled{zlib} ? () : "-DZLIB" })
2175 #
2176 sub combine {
2177     my @stuff = @_;
2178     return sub { add(@stuff)->(); }
2179 }
2180
2181 # Helper function to implement conditional values depending on the value
2182 # of $disabled{threads}.  Can be used as follows:
2183 #
2184 #       cflags => combine("-Wall", threads("-pthread"))
2185 #
2186 sub threads {
2187     my @flags = @_;
2188     return sub { add($disabled{threads} ? () : @flags)->(); }
2189 }
2190
2191
2192
2193 our $add_called = 0;
2194 # Helper function to implement adding values to already existing configuration
2195 # values.  It handles elements that are ARRAYs, CODEs and scalars
2196 sub _add {
2197     my $separator = shift;
2198
2199     # If there's any ARRAY in the collection of values OR the separator
2200     # is undef, we will return an ARRAY of combined values, otherwise a
2201     # string of joined values with $separator as the separator.
2202     my $found_array = !defined($separator);
2203
2204     my @values =
2205         map {
2206             my $res = $_;
2207             while (ref($res) eq "CODE") {
2208                 $res = $res->();
2209             }
2210             if (defined($res)) {
2211                 if (ref($res) eq "ARRAY") {
2212                     $found_array = 1;
2213                     @$res;
2214                 } else {
2215                     $res;
2216                 }
2217             } else {
2218                 ();
2219             }
2220     } (@_);
2221
2222     $add_called = 1;
2223
2224     if ($found_array) {
2225         [ @values ];
2226     } else {
2227         join($separator, grep { defined($_) && $_ ne "" } @values);
2228     }
2229 }
2230 sub add_before {
2231     my $separator = " ";
2232     if (ref($_[$#_]) eq "HASH") {
2233         my $opts = pop;
2234         $separator = $opts->{separator};
2235     }
2236     my @x = @_;
2237     sub { _add($separator, @x, @_) };
2238 }
2239 sub add {
2240     my $separator = " ";
2241     if (ref($_[$#_]) eq "HASH") {
2242         my $opts = pop;
2243         $separator = $opts->{separator};
2244     }
2245     my @x = @_;
2246     sub { _add($separator, @_, @x) };
2247 }
2248
2249 # configuration reader, evaluates the input file as a perl script and expects
2250 # it to fill %targets with target configurations.  Those are then added to
2251 # %table.
2252 sub read_config {
2253     my $fname = shift;
2254     open(CONFFILE, "< $fname")
2255         or die "Can't open configuration file '$fname'!\n";
2256     my $x = $/;
2257     undef $/;
2258     my $content = <CONFFILE>;
2259     $/ = $x;
2260     close(CONFFILE);
2261     my %targets = ();
2262     {
2263         # Protect certain tables from tampering
2264         local %table = %::table;
2265
2266         eval $content;
2267         warn $@ if $@;
2268     }
2269
2270     # For each target, check that it's configured with a hash table.
2271     foreach (keys %targets) {
2272         if (ref($targets{$_}) ne "HASH") {
2273             if (ref($targets{$_}) eq "") {
2274                 warn "Deprecated target configuration for $_, ignoring...\n";
2275             } else {
2276                 warn "Misconfigured target configuration for $_ (should be a hash table), ignoring...\n";
2277             }
2278             delete $targets{$_};
2279         } else {
2280             $targets{$_}->{_conf_fname_int} = add([ $fname ]);
2281         }
2282     }
2283
2284     %table = (%table, %targets);
2285
2286 }
2287
2288 # configuration resolver.  Will only resolve all the lazy evaluation
2289 # codeblocks for the chosen target and all those it inherits from,
2290 # recursively
2291 sub resolve_config {
2292     my $target = shift;
2293     my @breadcrumbs = @_;
2294
2295 #    my $extra_checks = defined($ENV{CONFIGURE_EXTRA_CHECKS});
2296
2297     if (grep { $_ eq $target } @breadcrumbs) {
2298         die "inherit_from loop!  target backtrace:\n  "
2299             ,$target,"\n  ",join("\n  ", @breadcrumbs),"\n";
2300     }
2301
2302     if (!defined($table{$target})) {
2303         warn "Warning! target $target doesn't exist!\n";
2304         return ();
2305     }
2306     # Recurse through all inheritances.  They will be resolved on the
2307     # fly, so when this operation is done, they will all just be a
2308     # bunch of attributes with string values.
2309     # What we get here, though, are keys with references to lists of
2310     # the combined values of them all.  We will deal with lists after
2311     # this stage is done.
2312     my %combined_inheritance = ();
2313     if ($table{$target}->{inherit_from}) {
2314         my @inherit_from =
2315             map { ref($_) eq "CODE" ? $_->() : $_ } @{$table{$target}->{inherit_from}};
2316         foreach (@inherit_from) {
2317             my %inherited_config = resolve_config($_, $target, @breadcrumbs);
2318
2319             # 'template' is a marker that's considered private to
2320             # the config that had it.
2321             delete $inherited_config{template};
2322
2323             foreach (keys %inherited_config) {
2324                 if (!$combined_inheritance{$_}) {
2325                     $combined_inheritance{$_} = [];
2326                 }
2327                 push @{$combined_inheritance{$_}}, $inherited_config{$_};
2328             }
2329         }
2330     }
2331
2332     # We won't need inherit_from in this target any more, since we've
2333     # resolved all the inheritances that lead to this
2334     delete $table{$target}->{inherit_from};
2335
2336     # Now is the time to deal with those lists.  Here's the place to
2337     # decide what shall be done with those lists, all based on the
2338     # values of the target we're currently dealing with.
2339     # - If a value is a coderef, it will be executed with the list of
2340     #   inherited values as arguments.
2341     # - If the corresponding key doesn't have a value at all or is the
2342     #   empty string, the inherited value list will be run through the
2343     #   default combiner (below), and the result becomes this target's
2344     #   value.
2345     # - Otherwise, this target's value is assumed to be a string that
2346     #   will simply override the inherited list of values.
2347     my $default_combiner = add();
2348
2349     my %all_keys =
2350         map { $_ => 1 } (keys %combined_inheritance,
2351                          keys %{$table{$target}});
2352
2353     sub process_values {
2354         my $object    = shift;
2355         my $inherited = shift;  # Always a [ list ]
2356         my $target    = shift;
2357         my $entry     = shift;
2358
2359         $add_called = 0;
2360
2361         while(ref($object) eq "CODE") {
2362             $object = $object->(@$inherited);
2363         }
2364         if (!defined($object)) {
2365             return ();
2366         }
2367         elsif (ref($object) eq "ARRAY") {
2368             local $add_called;  # To make sure recursive calls don't affect it
2369             return [ map { process_values($_, $inherited, $target, $entry) }
2370                      @$object ];
2371         } elsif (ref($object) eq "") {
2372             return $object;
2373         } else {
2374             die "cannot handle reference type ",ref($object)
2375                 ," found in target ",$target," -> ",$entry,"\n";
2376         }
2377     }
2378
2379     foreach (sort keys %all_keys) {
2380         my $previous = $combined_inheritance{$_};
2381
2382         # Current target doesn't have a value for the current key?
2383         # Assign it the default combiner, the rest of this loop body
2384         # will handle it just like any other coderef.
2385         if (!exists $table{$target}->{$_}) {
2386             $table{$target}->{$_} = $default_combiner;
2387         }
2388
2389         $table{$target}->{$_} = process_values($table{$target}->{$_},
2390                                                $combined_inheritance{$_},
2391                                                $target, $_);
2392         unless(defined($table{$target}->{$_})) {
2393             delete $table{$target}->{$_};
2394         }
2395 #        if ($extra_checks &&
2396 #            $previous && !($add_called ||  $previous ~~ $table{$target}->{$_})) {
2397 #            warn "$_ got replaced in $target\n";
2398 #        }
2399     }
2400
2401     # Finally done, return the result.
2402     return %{$table{$target}};
2403 }
2404
2405 sub usage
2406         {
2407         print STDERR $usage;
2408         print STDERR "\npick os/compiler from:\n";
2409         my $j=0;
2410         my $i;
2411         my $k=0;
2412         foreach $i (sort keys %table)
2413                 {
2414                 next if $table{$i}->{template};
2415                 next if $i =~ /^debug/;
2416                 $k += length($i) + 1;
2417                 if ($k > 78)
2418                         {
2419                         print STDERR "\n";
2420                         $k=length($i);
2421                         }
2422                 print STDERR $i . " ";
2423                 }
2424         foreach $i (sort keys %table)
2425                 {
2426                 next if $table{$i}->{template};
2427                 next if $i !~ /^debug/;
2428                 $k += length($i) + 1;
2429                 if ($k > 78)
2430                         {
2431                         print STDERR "\n";
2432                         $k=length($i);
2433                         }
2434                 print STDERR $i . " ";
2435                 }
2436         print STDERR "\n\nNOTE: If in doubt, on Unix-ish systems use './config'.\n";
2437         exit(1);
2438         }
2439
2440 sub run_dofile
2441 {
2442     my $out = shift;
2443     my @templates = @_;
2444
2445     unlink $out || warn "Can't remove $out, $!"
2446         if -f $out;
2447     foreach (@templates) {
2448         die "Can't open $_, $!" unless -f $_;
2449     }
2450     my $perlcmd = (quotify("maybeshell", $config{perl}))[0];
2451     my $cmd = "$perlcmd \"-I.\" \"-Mconfigdata\" \"$dofile\" -o\"Configure\" \"".join("\" \"",@templates)."\" > \"$out.new\"";
2452     #print STDERR "DEBUG[run_dofile]: \$cmd = $cmd\n";
2453     system($cmd);
2454     exit 1 if $? != 0;
2455     rename("$out.new", $out) || die "Can't rename $out.new, $!";
2456 }
2457
2458 sub which
2459 {
2460     my ($name)=@_;
2461
2462     if (eval { require IPC::Cmd; 1; }) {
2463         IPC::Cmd->import();
2464         return scalar IPC::Cmd::can_run($name);
2465     } else {
2466         # if there is $directories component in splitpath,
2467         # then it's not something to test with $PATH...
2468         return $name if (File::Spec->splitpath($name))[1];
2469
2470         foreach (File::Spec->path()) {
2471             my $fullpath = catfile($_, "$name$target{exe_extension}");
2472             if (-f $fullpath and -x $fullpath) {
2473                 return $fullpath;
2474             }
2475         }
2476     }
2477 }
2478
2479 # Configuration printer ##############################################
2480
2481 sub print_table_entry
2482 {
2483     my $target = shift;
2484     my %target = resolve_config($target);
2485     my $type = shift;
2486
2487     # Don't print the templates
2488     return if $target{template};
2489
2490     my @sequence = (
2491         "sys_id",
2492         "cc",
2493         "cflags",
2494         "defines",
2495         "unistd",
2496         "ld",
2497         "lflags",
2498         "loutflag",
2499         "plib_lflags",
2500         "ex_libs",
2501         "bn_ops",
2502         "apps_aux_src",
2503         "cpuid_asm_src",
2504         "uplink_aux_src",
2505         "bn_asm_src",
2506         "ec_asm_src",
2507         "des_asm_src",
2508         "aes_asm_src",
2509         "bf_asm_src",
2510         "md5_asm_src",
2511         "cast_asm_src",
2512         "sha1_asm_src",
2513         "rc4_asm_src",
2514         "rmd160_asm_src",
2515         "rc5_asm_src",
2516         "wp_asm_src",
2517         "cmll_asm_src",
2518         "modes_asm_src",
2519         "padlock_asm_src",
2520         "chacha_asm_src",
2521         "poly1035_asm_src",
2522         "thread_scheme",
2523         "perlasm_scheme",
2524         "dso_scheme",
2525         "shared_target",
2526         "shared_cflag",
2527         "shared_defines",
2528         "shared_ldflag",
2529         "shared_rcflag",
2530         "shared_extension",
2531         "dso_extension",
2532         "obj_extension",
2533         "exe_extension",
2534         "ranlib",
2535         "ar",
2536         "arflags",
2537         "aroutflag",
2538         "rc",
2539         "rcflags",
2540         "rcoutflag",
2541         "mt",
2542         "mtflags",
2543         "mtinflag",
2544         "mtoutflag",
2545         "multilib",
2546         "build_scheme",
2547         );
2548
2549     if ($type eq "TABLE") {
2550         print "\n";
2551         print "*** $target\n";
2552         foreach (@sequence) {
2553             if (ref($target{$_}) eq "ARRAY") {
2554                 printf "\$%-12s = %s\n", $_, join(" ", @{$target{$_}});
2555             } else {
2556                 printf "\$%-12s = %s\n", $_, $target{$_};
2557             }
2558         }
2559     } elsif ($type eq "HASH") {
2560         my $largest =
2561             length((sort { length($a) <=> length($b) } @sequence)[-1]);
2562         print "    '$target' => {\n";
2563         foreach (@sequence) {
2564             if ($target{$_}) {
2565                 if (ref($target{$_}) eq "ARRAY") {
2566                     print "      '",$_,"'"," " x ($largest - length($_))," => [ ",join(", ", map { "'$_'" } @{$target{$_}})," ],\n";
2567                 } else {
2568                     print "      '",$_,"'"," " x ($largest - length($_))," => '",$target{$_},"',\n";
2569                 }
2570             }
2571         }
2572         print "    },\n";
2573     }
2574 }
2575
2576 # Utility routines ###################################################
2577
2578 # On VMS, if the given file is a logical name, File::Spec::Functions
2579 # will consider it an absolute path.  There are cases when we want a
2580 # purely syntactic check without checking the environment.
2581 sub isabsolute {
2582     my $file = shift;
2583
2584     # On non-platforms, we just use file_name_is_absolute().
2585     return file_name_is_absolute($file) unless $^O eq "VMS";
2586
2587     # If the file spec includes a device or a directpry spec,
2588     # file_name_is_absolute() is perfectly safe.
2589     return file_name_is_absolute($file) if $file =~ m|[:\[]|;
2590
2591     # Here, we know the given file spec isn't absolute
2592     return 0;
2593 }
2594
2595 # Makes a directory absolute and cleans out /../ in paths like foo/../bar
2596 # On some platforms, this uses rel2abs(), while on others, realpath() is used.
2597 # realpath() requires that at least all path components except the last is an
2598 # existing directory.  On VMS, the last component of the directory spec must
2599 # exist.
2600 sub absolutedir {
2601     my $dir = shift;
2602
2603     # realpath() is quite buggy on VMS.  It uses LIB$FID_TO_NAME, which
2604     # will return the volume name for the device, no matter what.  Also,
2605     # it will return an incorrect directory spec if the argument is a
2606     # directory that doesn't exist.
2607     if ($^O eq "VMS") {
2608         return rel2abs($dir);
2609     }
2610
2611     # We use realpath() on Unix, since no other will properly clean out
2612     # a directory spec.
2613     use Cwd qw/realpath/;
2614
2615     return realpath($dir);
2616 }
2617
2618 sub quotify {
2619     my %processors = (
2620         perl    => sub { my $x = shift;
2621                          $x =~ s/([\\\$\@"])/\\$1/g;
2622                          return '"'.$x.'"'; },
2623         maybeshell => sub { my $x = shift;
2624                             (my $y = $x) =~ s/([\\\"])/\\$1/g;
2625                             if ($x ne $y || $x =~ m|\s|) {
2626                                 return '"'.$y.'"';
2627                             } else {
2628                                 return $x;
2629                             }
2630                         },
2631         );
2632     my $for = shift;
2633     my $processor =
2634         defined($processors{$for}) ? $processors{$for} : sub { shift; };
2635
2636     return map { $processor->($_); } @_;
2637 }
2638
2639 # collect_from_file($filename, $line_concat_cond_re, $line_concat)
2640 # $filename is a file name to read from
2641 # $line_concat_cond_re is a regexp detecting a line continuation ending
2642 # $line_concat is a CODEref that takes care of concatenating two lines
2643 sub collect_from_file {
2644     my $filename = shift;
2645     my $line_concat_cond_re = shift;
2646     my $line_concat = shift;
2647
2648     open my $fh, $filename || die "unable to read $filename: $!\n";
2649     return sub {
2650         my $saved_line = "";
2651         $_ = "";
2652         while (<$fh>) {
2653             s|\R$||;
2654             if (defined $line_concat) {
2655                 $_ = $line_concat->($saved_line, $_);
2656                 $saved_line = "";
2657             }
2658             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
2659                 $saved_line = $_;
2660                 next;
2661             }
2662             return $_;
2663         }
2664         die "$filename ending with continuation line\n" if $_;
2665         close $fh;
2666         return undef;
2667     }
2668 }
2669
2670 # collect_from_array($array, $line_concat_cond_re, $line_concat)
2671 # $array is an ARRAYref of lines
2672 # $line_concat_cond_re is a regexp detecting a line continuation ending
2673 # $line_concat is a CODEref that takes care of concatenating two lines
2674 sub collect_from_array {
2675     my $array = shift;
2676     my $line_concat_cond_re = shift;
2677     my $line_concat = shift;
2678     my @array = (@$array);
2679
2680     return sub {
2681         my $saved_line = "";
2682         $_ = "";
2683         while (defined($_ = shift @array)) {
2684             s|\R$||;
2685             if (defined $line_concat) {
2686                 $_ = $line_concat->($saved_line, $_);
2687                 $saved_line = "";
2688             }
2689             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
2690                 $saved_line = $_;
2691                 next;
2692             }
2693             return $_;
2694         }
2695         die "input text ending with continuation line\n" if $_;
2696         return undef;
2697     }
2698 }
2699
2700 # collect_information($lineiterator, $line_continue, $regexp => $CODEref, ...)
2701 # $lineiterator is a CODEref that delivers one line at a time.
2702 # All following arguments are regex/CODEref pairs, where the regexp detects a
2703 # line and the CODEref does something with the result of the regexp.
2704 sub collect_information {
2705     my $lineiterator = shift;
2706     my %collectors = @_;
2707
2708     while(defined($_ = $lineiterator->())) {
2709         s|\R$||;
2710         my $found = 0;
2711         if ($collectors{"BEFORE"}) {
2712             $collectors{"BEFORE"}->($_);
2713         }
2714         foreach my $re (keys %collectors) {
2715             if ($re !~ /^OTHERWISE|BEFORE|AFTER$/ && /$re/) {
2716                 $collectors{$re}->($lineiterator);
2717                 $found = 1;
2718             };
2719         }
2720         if ($collectors{"OTHERWISE"}) {
2721             $collectors{"OTHERWISE"}->($lineiterator, $_)
2722                 unless $found || !defined $collectors{"OTHERWISE"};
2723         }
2724         if ($collectors{"AFTER"}) {
2725             $collectors{"AFTER"}->($_);
2726         }
2727     }
2728 }
2729
2730 # tokenize($line)
2731 # $line is a line of text to split up into tokens
2732 # returns a list of tokens
2733 #
2734 # Tokens are divided by spaces.  If the tokens include spaces, they
2735 # have to be quoted with single or double quotes.  Double quotes
2736 # inside a double quoted token must be escaped.  Escaping is done
2737 # with backslash.
2738 # Basically, the same quoting rules apply for " and ' as in any
2739 # Unix shell.
2740 sub tokenize {
2741     my $line = my $debug_line = shift;
2742     my @result = ();
2743
2744     while ($line =~ s|^\s+||, $line ne "") {
2745         my $token = "";
2746         while ($line ne "" && $line !~ m|^\s|) {
2747             if ($line =~ m/^"((?:[^"\\]+|\\.)*)"/) {
2748                 $token .= $1;
2749                 $line = $';
2750             } elsif ($line =~ m/^'([^']*)'/) {
2751                 $token .= $1;
2752                 $line = $';
2753             } elsif ($line =~ m/^(\S+)/) {
2754                 $token .= $1;
2755                 $line = $';
2756             }
2757         }
2758         push @result, $token;
2759     }
2760
2761     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
2762         print STDERR "DEBUG[tokenize]: Parsed '$debug_line' into:\n";
2763         print STDERR "DEBUG[tokenize]: ('", join("', '", @result), "')\n";
2764     }
2765     return @result;
2766 }