Configure

   1 #! /usr/bin/env perl
   2 # -*- mode: perl; -*-
   3 # Copyright 2016-2018 The OpenSSL Project Authors. All Rights Reserved.
   4 #
   5 # Licensed under the Apache License 2.0 (the "License").  You may not use
   6 # this file except in compliance with the License.  You can obtain a copy
   7 # in the file LICENSE in the source distribution or at
   8 # https://www.openssl.org/source/license.html
   9
  10 ##  Configure -- OpenSSL source tree configuration script
  11
  12 use 5.10.0;
  13 use strict;
  14 use Config;
  15 use FindBin;
  16 use lib "$FindBin::Bin/util/perl";
  17 use File::Basename;
  18 use File::Spec::Functions qw/:DEFAULT abs2rel rel2abs splitdir/;
  19 use File::Path qw/mkpath/;
  20 use OpenSSL::Glob;
  21
  22 # see INSTALL for instructions.
  23
  24 my $orig_death_handler = $SIG{__DIE__};
  25 $SIG{__DIE__} = \&death_handler;
  26
  27 my $usage="Usage: Configure [no-<cipher> ...] [enable-<cipher> ...] [-Dxxx] [-lxxx] [-Lxxx] [-fxxx] [-Kxxx] [no-hw-xxx|no-hw] [[no-]threads] [[no-]shared] [[no-]zlib|zlib-dynamic] [no-asm] [no-egd] [sctp] [386] [--prefix=DIR] [--openssldir=OPENSSLDIR] [--with-xxx[=vvv]] [--config=FILE] os/compiler[:flags]\n";
  28
  29 # Options:
  30 #
  31 # --config      add the given configuration file, which will be read after
  32 #               any "Configurations*" files that are found in the same
  33 #               directory as this script.
  34 # --prefix      prefix for the OpenSSL installation, which includes the
  35 #               directories bin, lib, include, share/man, share/doc/openssl
  36 #               This becomes the value of INSTALLTOP in Makefile
  37 #               (Default: /usr/local)
  38 # --openssldir  OpenSSL data area, such as openssl.cnf, certificates and keys.
  39 #               If it's a relative directory, it will be added on the directory
  40 #               given with --prefix.
  41 #               This becomes the value of OPENSSLDIR in Makefile and in C.
  42 #               (Default: PREFIX/ssl)
  43 #
  44 # --cross-compile-prefix Add specified prefix to binutils components.
  45 #
  46 # --api         One of 0.9.8, 1.0.0, 1.0.1, 1.0.2, 1.1.0, 1.1.1, or 3.0.0 / 3.
  47 #               Do not compile support for interfaces deprecated as of the
  48 #               specified OpenSSL version.
  49 #
  50 # no-hw-xxx     do not compile support for specific crypto hardware.
  51 #               Generic OpenSSL-style methods relating to this support
  52 #               are always compiled but return NULL if the hardware
  53 #               support isn't compiled.
  54 # no-hw         do not compile support for any crypto hardware.
  55 # [no-]threads  [don't] try to create a library that is suitable for
  56 #               multithreaded applications (default is "threads" if we
  57 #               know how to do it)
  58 # [no-]shared   [don't] try to create shared libraries when supported.
  59 # [no-]pic      [don't] try to build position independent code when supported.
  60 #               If disabled, it also disables shared and dynamic-engine.
  61 # no-asm        do not use assembler
  62 # no-egd        do not compile support for the entropy-gathering daemon APIs
  63 # [no-]zlib     [don't] compile support for zlib compression.
  64 # zlib-dynamic  Like "zlib", but the zlib library is expected to be a shared
  65 #               library and will be loaded in run-time by the OpenSSL library.
  66 # sctp          include SCTP support
  67 # no-uplink     Don't build support for UPLINK interface.
  68 # enable-weak-ssl-ciphers
  69 #               Enable weak ciphers that are disabled by default.
  70 # 386           generate 80386 code in assembly modules
  71 # no-sse2       disables IA-32 SSE2 code in assembly modules, the above
  72 #               mentioned '386' option implies this one
  73 # no-<cipher>   build without specified algorithm (rsa, idea, rc5, ...)
  74 # -<xxx> +<xxx> compiler options are passed through
  75 # -static       while -static is also a pass-through compiler option (and
  76 #               as such is limited to environments where it's actually
  77 #               meaningful), it triggers a number configuration options,
  78 #               namely no-pic, no-shared and no-threads. It is
  79 #               argued that the only reason to produce statically linked
  80 #               binaries (and in context it means executables linked with
  81 #               -static flag, and not just executables linked with static
  82 #               libcrypto.a) is to eliminate dependency on specific run-time,
  83 #               a.k.a. libc version. The mentioned config options are meant
  84 #               to achieve just that. Unfortunately on Linux it's impossible
  85 #               to eliminate the dependency completely for openssl executable
  86 #               because of getaddrinfo and gethostbyname calls, which can
  87 #               invoke dynamically loadable library facility anyway to meet
  88 #               the lookup requests. For this reason on Linux statically
  89 #               linked openssl executable has rather debugging value than
  90 #               production quality.
  91 #
  92 # BN_LLONG      use the type 'long long' in crypto/bn/bn.h
  93 # RC4_CHAR      use 'char' instead of 'int' for RC4_INT in crypto/rc4/rc4.h
  94 # Following are set automatically by this script
  95 #
  96 # MD5_ASM       use some extra md5 assembler,
  97 # SHA1_ASM      use some extra sha1 assembler, must define L_ENDIAN for x86
  98 # RMD160_ASM    use some extra ripemd160 assembler,
  99 # SHA256_ASM    sha256_block is implemented in assembler
 100 # SHA512_ASM    sha512_block is implemented in assembler
 101 # AES_ASM       AES_[en|de]crypt is implemented in assembler
 102
 103 # Minimum warning options... any contributions to OpenSSL should at least
 104 # get past these.  Note that we only use these with C compilers, not with
 105 # C++ compilers.
 106
 107 # DEBUG_UNUSED enables __owur (warn unused result) checks.
 108 # -DPEDANTIC complements -pedantic and is meant to mask code that
 109 # is not strictly standard-compliant and/or implementation-specific,
 110 # e.g. inline assembly, disregards to alignment requirements, such
 111 # that -pedantic would complain about. Incidentally -DPEDANTIC has
 112 # to be used even in sanitized builds, because sanitizer too is
 113 # supposed to and does take notice of non-standard behaviour. Then
 114 # -pedantic with pre-C9x compiler would also complain about 'long
 115 # long' not being supported. As 64-bit algorithms are common now,
 116 # it grew impossible to resolve this without sizeable additional
 117 # code, so we just tell compiler to be pedantic about everything
 118 # but 'long long' type.
 119
 120 my @gcc_devteam_warn = qw(
 121     -DDEBUG_UNUSED
 122     -DPEDANTIC -pedantic -Wno-long-long
 123     -Wall
 124     -Wextra
 125     -Wno-unused-parameter
 126     -Wno-missing-field-initializers
 127     -Wswitch
 128     -Wsign-compare
 129     -Wshadow
 130     -Wformat
 131     -Wtype-limits
 132     -Wundef
 133     -Werror
 134     -Wmissing-prototypes
 135     -Wstrict-prototypes
 136 );
 137
 138 # These are used in addition to $gcc_devteam_warn when the compiler is clang.
 139 # TODO(openssl-team): fix problems and investigate if (at least) the
 140 # following warnings can also be enabled:
 141 #       -Wcast-align
 142 #       -Wunreachable-code -- no, too ugly/compiler-specific
 143 #       -Wlanguage-extension-token -- no, we use asm()
 144 #       -Wunused-macros -- no, too tricky for BN and _XOPEN_SOURCE etc
 145 #       -Wextended-offsetof -- no, needed in CMS ASN1 code
 146 my @clang_devteam_warn = qw(
 147     -Wswitch-default
 148     -Wno-parentheses-equality
 149     -Wno-language-extension-token
 150     -Wno-extended-offsetof
 151     -Wconditional-uninitialized
 152     -Wincompatible-pointer-types-discards-qualifiers
 153     -Wno-unknown-warning-option
 154     -Wmissing-variable-declarations
 155 );
 156
 157 # This adds backtrace information to the memory leak info.  Is only used
 158 # when crypto-mdebug-backtrace is enabled.
 159 my $memleak_devteam_backtrace = "-rdynamic";
 160
 161 my $strict_warnings = 0;
 162
 163 # As for $BSDthreads. Idea is to maintain "collective" set of flags,
 164 # which would cover all BSD flavors. -pthread applies to them all,
 165 # but is treated differently. OpenBSD expands is as -D_POSIX_THREAD
 166 # -lc_r, which is sufficient. FreeBSD 4.x expands it as -lc_r,
 167 # which has to be accompanied by explicit -D_THREAD_SAFE and
 168 # sometimes -D_REENTRANT. FreeBSD 5.x expands it as -lc_r, which
 169 # seems to be sufficient?
 170 our $BSDthreads="-pthread -D_THREAD_SAFE -D_REENTRANT";
 171
 172 #
 173 # API compatibility name to version number mapping.
 174 #
 175 my $maxapi = "3.0.0";           # API for "no-deprecated" builds
 176 my $apitable = {
 177     "3.0.0" => 3,
 178     "1.1.1" => 2,
 179     "1.1.0" => 2,
 180     "1.0.2" => 1,
 181     "1.0.1" => 1,
 182     "1.0.0" => 1,
 183     "0.9.8" => 0,
 184 };
 185
 186 our %table = ();
 187 our %config = ();
 188 our %withargs = ();
 189 our $now_printing;      # set to current entry's name in print_table_entry
 190                         # (todo: right thing would be to encapsulate name
 191                         # into %target [class] and make print_table_entry
 192                         # a method)
 193
 194 # Forward declarations ###############################################
 195
 196 # read_config(filename)
 197 #
 198 # Reads a configuration file and populates %table with the contents
 199 # (which the configuration file places in %targets).
 200 sub read_config;
 201
 202 # resolve_config(target)
 203 #
 204 # Resolves all the late evaluations, inheritances and so on for the
 205 # chosen target and any target it inherits from.
 206 sub resolve_config;
 207
 208
 209 # Information collection #############################################
 210
 211 # Unified build supports separate build dir
 212 my $srcdir = catdir(absolutedir(dirname($0))); # catdir ensures local syntax
 213 my $blddir = catdir(absolutedir("."));         # catdir ensures local syntax
 214 my $dofile = abs2rel(catfile($srcdir, "util/dofile.pl"));
 215
 216 my $local_config_envname = 'OPENSSL_LOCAL_CONFIG_DIR';
 217
 218 $config{sourcedir} = abs2rel($srcdir);
 219 $config{builddir} = abs2rel($blddir);
 220
 221 # Collect reconfiguration information if needed
 222 my @argvcopy=@ARGV;
 223
 224 if (grep /^reconf(igure)?$/, @argvcopy) {
 225     die "reconfiguring with other arguments present isn't supported"
 226         if scalar @argvcopy > 1;
 227     if (-f "./configdata.pm") {
 228         my $file = "./configdata.pm";
 229         unless (my $return = do $file) {
 230             die "couldn't parse $file: $@" if $@;
 231             die "couldn't do $file: $!"    unless defined $return;
 232             die "couldn't run $file"       unless $return;
 233         }
 234
 235         @argvcopy = defined($configdata::config{perlargv}) ?
 236             @{$configdata::config{perlargv}} : ();
 237         die "Incorrect data to reconfigure, please do a normal configuration\n"
 238             if (grep(/^reconf/,@argvcopy));
 239         $config{perlenv} = $configdata::config{perlenv} // {};
 240     } else {
 241         die "Insufficient data to reconfigure, please do a normal configuration\n";
 242     }
 243 }
 244
 245 $config{perlargv} = [ @argvcopy ];
 246
 247 # Collect version numbers
 248 $config{major} = "unknown";
 249 $config{minor} = "unknown";
 250 $config{patch} = "unknown";
 251 $config{prerelease} = "";
 252 $config{build_metadata} = "";
 253 $config{shlib_version} = "unknown";
 254
 255 collect_information(
 256     collect_from_file(catfile($srcdir,'include/openssl/opensslv.h')),
 257     qr/#\s+define\s+OPENSSL_VERSION_MAJOR\s+(\d+)/ =>
 258         sub { $config{major} = $1; },
 259     qr/#\s+define\s+OPENSSL_VERSION_MINOR\s+(\d+)/ =>
 260         sub { $config{minor} = $1; },
 261     qr/#\s+define\s+OPENSSL_VERSION_PATCH\s+(\d+)/ =>
 262         sub { $config{patch} = $1; },
 263     qr/#\s+define\s+OPENSSL_VERSION_PRE_RELEASE\s+"((?:\\.|[^"])*)"/ =>
 264         sub { $config{prerelease} = $1; },
 265     qr/#\s+define\s+OPENSSL_VERSION_BUILD_METADATA\s+"((?:\\.|[^"])*)"/ =>
 266         sub { $config{build_metadata} = $1; },
 267     qr/#\s+define\s+OPENSSL_SHLIB_VERSION\s+([\d\.]+)/ =>
 268         sub { $config{shlib_version} = $1; },
 269     );
 270 die "erroneous version information in opensslv.h: ",
 271     "$config{major}.$config{minor}.$config{patch}, $config{shlib_version}\n"
 272     if ($config{major} eq "unknown"
 273             || $config{minor} eq "unknown"
 274             || $config{patch} eq "unknown"
 275             || $config{shlib_version} eq "unknown");
 276
 277 $config{version} = "$config{major}.$config{minor}.$config{patch}";
 278 $config{full_version} = "$config{version}$config{prerelease}$config{build_metadata}";
 279
 280 # Collect target configurations
 281
 282 my $pattern = catfile(dirname($0), "Configurations", "*.conf");
 283 foreach (sort glob($pattern)) {
 284     &read_config($_);
 285 }
 286
 287 if (defined env($local_config_envname)) {
 288     if ($^O eq 'VMS') {
 289         # VMS environment variables are logical names,
 290         # which can be used as is
 291         $pattern = $local_config_envname . ':' . '*.conf';
 292     } else {
 293         $pattern = catfile(env($local_config_envname), '*.conf');
 294     }
 295
 296     foreach (sort glob($pattern)) {
 297         &read_config($_);
 298     }
 299 }
 300
 301 # Save away perl command information
 302 $config{perl_cmd} = $^X;
 303 $config{perl_version} = $Config{version};
 304 $config{perl_archname} = $Config{archname};
 305
 306 $config{prefix}="";
 307 $config{openssldir}="";
 308 $config{processor}="";
 309 $config{libdir}="";
 310 my $auto_threads=1;    # enable threads automatically? true by default
 311 my $default_ranlib;
 312
 313 # Known TLS and DTLS protocols
 314 my @tls = qw(ssl3 tls1 tls1_1 tls1_2 tls1_3);
 315 my @dtls = qw(dtls1 dtls1_2);
 316
 317 # Explicitly known options that are possible to disable.  They can
 318 # be regexps, and will be used like this: /^no-${option}$/
 319 # For developers: keep it sorted alphabetically
 320
 321 my @disablables = (
 322     "ktls",
 323     "afalgeng",
 324     "aria",
 325     "asan",
 326     "asm",
 327     "async",
 328     "autoalginit",
 329     "autoerrinit",
 330     "autoload-config",
 331     "bf",
 332     "blake2",
 333     "buildtest-c++",
 334     "camellia",
 335     "capieng",
 336     "cast",
 337     "chacha",
 338     "cmac",
 339     "cmp",
 340     "cms",
 341     "comp",
 342     "crypto-mdebug",
 343     "crypto-mdebug-backtrace",
 344     "ct",
 345     "deprecated",
 346     "des",
 347     "devcryptoeng",
 348     "dgram",
 349     "dh",
 350     "dsa",
 351     "dtls",
 352     "dynamic-engine",
 353     "ec",
 354     "ec2m",
 355     "ecdh",
 356     "ecdsa",
 357     "ec_nistp_64_gcc_128",
 358     "egd",
 359     "engine",
 360     "err",
 361     "external-tests",
 362     "filenames",
 363     "fips",
 364     "fuzz-libfuzzer",
 365     "fuzz-afl",
 366     "gost",
 367     "idea",
 368     "legacy",
 369     "makedepend",
 370     "md2",
 371     "md4",
 372     "mdc2",
 373     "module",
 374     "msan",
 375     "multiblock",
 376     "nextprotoneg",
 377     "pinshared",
 378     "ocb",
 379     "ocsp",
 380     "padlockeng",
 381     "pic",
 382     "poly1305",
 383     "posix-io",
 384     "psk",
 385     "rc2",
 386     "rc4",
 387     "rc5",
 388     "rdrand",
 389     "rfc3779",
 390     "rmd160",
 391     "scrypt",
 392     "sctp",
 393     "seed",
 394     "shared",
 395     "siphash",
 396     "siv",
 397     "sm2",
 398     "sm3",
 399     "sm4",
 400     "sock",
 401     "srp",
 402     "srtp",
 403     "sse2",
 404     "ssl",
 405     "ssl-trace",
 406     "static-engine",
 407     "stdio",
 408     "tests",
 409     "threads",
 410     "tls",
 411     "trace",
 412     "ts",
 413     "ubsan",
 414     "ui-console",
 415     "unit-test",
 416     "uplink",
 417     "whirlpool",
 418     "weak-ssl-ciphers",
 419     "zlib",
 420     "zlib-dynamic",
 421     );
 422 foreach my $proto ((@tls, @dtls))
 423         {
 424         push(@disablables, $proto);
 425         push(@disablables, "$proto-method") unless $proto eq "tls1_3";
 426         }
 427
 428 # Internal disablables, for aliasing purposes.  They serve no special
 429 # purpose here, but allow scripts to get to know them through configdata.pm,
 430 # where these are merged with @disablables.
 431 # The actual aliasing mechanism is done via %disable_cascades
 432 my @disablables_int = qw(
 433     crmf
 434     );
 435
 436 my %deprecated_disablables = (
 437     "ssl2" => undef,
 438     "buf-freelists" => undef,
 439     "hw" => "hw",               # causes cascade, but no macro
 440     "hw-padlock" => "padlockeng",
 441     "ripemd" => "rmd160",
 442     "ui" => "ui-console",
 443     "dso" => undef,
 444     "heartbeats" => undef,
 445     );
 446
 447 # All of the following are disabled by default:
 448
 449 our %disabled = ( # "what"         => "comment"
 450                   "asan"                => "default",
 451                   "buildtest-c++"       => "default",
 452                   "crypto-mdebug"       => "default",
 453                   "crypto-mdebug-backtrace" => "default",
 454                   "devcryptoeng"        => "default",
 455                   "ec_nistp_64_gcc_128" => "default",
 456                   "egd"                 => "default",
 457                   "external-tests"      => "default",
 458                   "fuzz-libfuzzer"      => "default",
 459                   "fuzz-afl"            => "default",
 460                   "md2"                 => "default",
 461                   "msan"                => "default",
 462                   "rc5"                 => "default",
 463                   "sctp"                => "default",
 464                   "ssl-trace"           => "default",
 465                   "ssl3"                => "default",
 466                   "ssl3-method"         => "default",
 467                   "trace"               => "default",
 468                   "ubsan"               => "default",
 469                   "unit-test"           => "default",
 470                   "weak-ssl-ciphers"    => "default",
 471                   "zlib"                => "default",
 472                   "zlib-dynamic"        => "default",
 473                   "ktls"                => "default",
 474                 );
 475
 476 # Note: => pair form used for aesthetics, not to truly make a hash table
 477 my @disable_cascades = (
 478     # "what"            => [ "cascade", ... ]
 479     sub { $config{processor} eq "386" }
 480                         => [ "sse2" ],
 481     "ssl"               => [ "ssl3" ],
 482     "ssl3-method"       => [ "ssl3" ],
 483     "zlib"              => [ "zlib-dynamic" ],
 484     "des"               => [ "mdc2" ],
 485     "ec"                => [ "ecdsa", "ecdh", "sm2" ],
 486     sub { $disabled{"ec"} && $disabled{"dh"} }
 487                         => [ "tls1_3" ],
 488     "dgram"             => [ "dtls", "sctp" ],
 489     "sock"              => [ "dgram" ],
 490     "dtls"              => [ @dtls ],
 491     sub { 0 == scalar grep { !$disabled{$_} } @dtls }
 492                         => [ "dtls" ],
 493
 494     "tls"               => [ @tls ],
 495     sub { 0 == scalar grep { !$disabled{$_} } @tls }
 496                         => [ "tls" ],
 497
 498     "crypto-mdebug"     => [ "crypto-mdebug-backtrace" ],
 499
 500     # If no modules, then no dynamic engines either
 501     "module"            => [ "dynamic-engine" ],
 502
 503     # Without shared libraries, dynamic engines aren't possible.
 504     # This is due to them having to link with libcrypto and register features
 505     # using the ENGINE functionality, and since that relies on global tables,
 506     # those *have* to be exacty the same as the ones accessed from the app,
 507     # which cannot be guaranteed if shared libraries aren't present.
 508     # (note that even with shared libraries, both the app and dynamic engines
 509     # must be linked with the same library)
 510     "shared"            => [ "dynamic-engine", "uplink" ],
 511     # Other modules don't necessarily have to link with libcrypto, so shared
 512     # libraries do not have to be a condition to produce those.
 513
 514     # Without position independent code, there can be no shared libraries
 515     # or modules.
 516     "pic"               => [ "shared", "module" ],
 517
 518     "module"            => [ "fips", "legacy" ],
 519
 520     "engine"            => [ grep /eng$/, @disablables ],
 521     "hw"                => [ "padlockeng" ],
 522
 523     # no-autoalginit is only useful when building non-shared
 524     "autoalginit"       => [ "shared", "apps" ],
 525
 526     "stdio"             => [ "apps", "capieng", "egd" ],
 527     "apps"              => [ "tests" ],
 528     "tests"             => [ "external-tests" ],
 529     "comp"              => [ "zlib" ],
 530     "sm3"               => [ "sm2" ],
 531     sub { !$disabled{"unit-test"} } => [ "heartbeats" ],
 532
 533     sub { !$disabled{"msan"} } => [ "asm" ],
 534
 535     sub { $disabled{cmac}; } => [ "siv" ],
 536     "legacy"                 => [ "md2" ],
 537
 538     "cmp"               => [ "crmf" ],
 539     );
 540
 541 # Avoid protocol support holes.  Also disable all versions below N, if version
 542 # N is disabled while N+1 is enabled.
 543 #
 544 my @list = (reverse @tls);
 545 while ((my $first, my $second) = (shift @list, shift @list)) {
 546     last unless @list;
 547     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 548                               => [ @list ] );
 549     unshift @list, $second;
 550 }
 551 my @list = (reverse @dtls);
 552 while ((my $first, my $second) = (shift @list, shift @list)) {
 553     last unless @list;
 554     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 555                               => [ @list ] );
 556     unshift @list, $second;
 557 }
 558
 559 # Explicit "no-..." options will be collected in %disabled along with the defaults.
 560 # To remove something from %disabled, use "enable-foo".
 561 # For symmetry, "disable-foo" is a synonym for "no-foo".
 562
 563 &usage if ($#ARGV < 0);
 564
 565 # For the "make variables" CINCLUDES and CDEFINES, we support lists with
 566 # platform specific list separators.  Users from those platforms should
 567 # recognise those separators from how you set up the PATH to find executables.
 568 # The default is the Unix like separator, :, but as an exception, we also
 569 # support the space as separator.
 570 my $list_separator_re =
 571     { VMS           => qr/(?<!\^),/,
 572       MSWin32       => qr/(?<!\\);/ } -> {$^O} // qr/(?<!\\)[:\s]/;
 573 # All the "make variables" we support
 574 # Some get pre-populated for the sake of backward compatibility
 575 # (we supported those before the change to "make variable" support.
 576 my %user = (
 577     AR          => env('AR'),
 578     ARFLAGS     => [],
 579     AS          => undef,
 580     ASFLAGS     => [],
 581     CC          => env('CC'),
 582     CFLAGS      => [ env('CFLAGS') || () ],
 583     CXX         => env('CXX'),
 584     CXXFLAGS    => [ env('CXXFLAGS') || () ],
 585     CPP         => undef,
 586     CPPFLAGS    => [ env('CPPFLAGS') || () ],  # -D, -I, -Wp,
 587     CPPDEFINES  => [],  # Alternative for -D
 588     CPPINCLUDES => [],  # Alternative for -I
 589     CROSS_COMPILE => env('CROSS_COMPILE'),
 590     HASHBANGPERL=> env('HASHBANGPERL') || env('PERL'),
 591     LD          => undef,
 592     LDFLAGS     => [ env('LDFLAGS') || () ],  # -L, -Wl,
 593     LDLIBS      => [ env('LDLIBS') || () ],  # -l
 594     MT          => undef,
 595     MTFLAGS     => [],
 596     PERL        => env('PERL') || ($^O ne "VMS" ? $^X : "perl"),
 597     RANLIB      => env('RANLIB'),
 598     RC          => env('RC') || env('WINDRES'),
 599     RCFLAGS     => [ env('RCFLAGS') || () ],
 600     RM          => undef,
 601    );
 602 # Info about what "make variables" may be prefixed with the cross compiler
 603 # prefix.  This should NEVER mention any such variable with a list for value.
 604 my @user_crossable = qw ( AR AS CC CXX CPP LD MT RANLIB RC );
 605 # The same but for flags given as Configure options.  These are *additional*
 606 # input, as opposed to the VAR=string option that override the corresponding
 607 # config target attributes
 608 my %useradd = (
 609     CPPDEFINES  => [],
 610     CPPINCLUDES => [],
 611     CPPFLAGS    => [],
 612     CFLAGS      => [],
 613     CXXFLAGS    => [],
 614     LDFLAGS     => [],
 615     LDLIBS      => [],
 616     RCFLAGS     => [],
 617    );
 618
 619 my %user_synonyms = (
 620     HASHBANGPERL=> 'PERL',
 621     RC          => 'WINDRES',
 622    );
 623
 624 # Some target attributes have been renamed, this is the translation table
 625 my %target_attr_translate =(
 626     ar          => 'AR',
 627     as          => 'AS',
 628     cc          => 'CC',
 629     cxx         => 'CXX',
 630     cpp         => 'CPP',
 631     hashbangperl => 'HASHBANGPERL',
 632     ld          => 'LD',
 633     mt          => 'MT',
 634     ranlib      => 'RANLIB',
 635     rc          => 'RC',
 636     rm          => 'RM',
 637    );
 638
 639 # Initialisers coming from 'config' scripts
 640 $config{defines} = [ split(/$list_separator_re/, env('__CNF_CPPDEFINES')) ];
 641 $config{includes} = [ split(/$list_separator_re/, env('__CNF_CPPINCLUDES')) ];
 642 $config{cppflags} = [ env('__CNF_CPPFLAGS') || () ];
 643 $config{cflags} = [ env('__CNF_CFLAGS') || () ];
 644 $config{cxxflags} = [ env('__CNF_CXXFLAGS') || () ];
 645 $config{lflags} = [ env('__CNF_LDFLAGS') || () ];
 646 $config{ex_libs} = [ env('__CNF_LDLIBS') || () ];
 647
 648 $config{openssl_api_defines}=[];
 649 $config{openssl_sys_defines}=[];
 650 $config{openssl_feature_defines}=[];
 651 $config{options}="";
 652 $config{build_type} = "release";
 653 my $target="";
 654
 655 my %cmdvars = ();               # Stores FOO='blah' type arguments
 656 my %unsupported_options = ();
 657 my %deprecated_options = ();
 658 # If you change this, update apps/version.c
 659 my @known_seed_sources = qw(getrandom devrandom os egd none rdcpu librandom);
 660 my @seed_sources = ();
 661 while (@argvcopy)
 662         {
 663         $_ = shift @argvcopy;
 664
 665         # Support env variable assignments among the options
 666         if (m|^(\w+)=(.+)?$|)
 667                 {
 668                 $cmdvars{$1} = $2;
 669                 # Every time a variable is given as a configuration argument,
 670                 # it acts as a reset if the variable.
 671                 if (exists $user{$1})
 672                         {
 673                         $user{$1} = ref $user{$1} eq "ARRAY" ? [] : undef;
 674                         }
 675                 #if (exists $useradd{$1})
 676                 #       {
 677                 #       $useradd{$1} = [];
 678                 #       }
 679                 next;
 680                 }
 681
 682         # VMS is a case insensitive environment, and depending on settings
 683         # out of our control, we may receive options uppercased.  Let's
 684         # downcase at least the part before any equal sign.
 685         if ($^O eq "VMS")
 686                 {
 687                 s/^([^=]*)/lc($1)/e;
 688                 }
 689
 690         # some people just can't read the instructions, clang people have to...
 691         s/^-no-(?!integrated-as)/no-/;
 692
 693         # rewrite some options in "enable-..." form
 694         s /^-?-?shared$/enable-shared/;
 695         s /^sctp$/enable-sctp/;
 696         s /^threads$/enable-threads/;
 697         s /^zlib$/enable-zlib/;
 698         s /^zlib-dynamic$/enable-zlib-dynamic/;
 699
 700         if (/^(no|disable|enable)-(.+)$/)
 701                 {
 702                 my $word = $2;
 703                 if ($word !~ m|hw(?:-.+)| # special treatment for hw regexp opt
 704                         && !exists $deprecated_disablables{$word}
 705                         && !grep { $word eq $_ } @disablables)
 706                         {
 707                         $unsupported_options{$_} = 1;
 708                         next;
 709                         }
 710                 }
 711         if (/^no-(.+)$/ || /^disable-(.+)$/)
 712                 {
 713                 foreach my $proto ((@tls, @dtls))
 714                         {
 715                         if ($1 eq "$proto-method")
 716                                 {
 717                                 $disabled{"$proto"} = "option($proto-method)";
 718                                 last;
 719                                 }
 720                         }
 721                 if ($1 eq "dtls")
 722                         {
 723                         foreach my $proto (@dtls)
 724                                 {
 725                                 $disabled{$proto} = "option(dtls)";
 726                                 }
 727                         $disabled{"dtls"} = "option(dtls)";
 728                         }
 729                 elsif ($1 eq "ssl")
 730                         {
 731                         # Last one of its kind
 732                         $disabled{"ssl3"} = "option(ssl)";
 733                         }
 734                 elsif ($1 eq "tls")
 735                         {
 736                         # XXX: Tests will fail if all SSL/TLS
 737                         # protocols are disabled.
 738                         foreach my $proto (@tls)
 739                                 {
 740                                 $disabled{$proto} = "option(tls)";
 741                                 }
 742                         }
 743                 elsif ($1 eq "static-engine")
 744                         {
 745                         delete $disabled{"dynamic-engine"};
 746                         }
 747                 elsif ($1 eq "dynamic-engine")
 748                         {
 749                         $disabled{"dynamic-engine"} = "option";
 750                         }
 751                 elsif (exists $deprecated_disablables{$1})
 752                         {
 753                         $deprecated_options{$_} = 1;
 754                         if (defined $deprecated_disablables{$1})
 755                                 {
 756                                 $disabled{$deprecated_disablables{$1}} = "option";
 757                                 }
 758                         }
 759                 elsif ($1 =~ m|hw(?:-.+)|) # deprecate hw options in regexp form
 760                         {
 761                         $deprecated_options{$_} = 1;
 762                         }
 763                 else
 764                         {
 765                         $disabled{$1} = "option";
 766                         }
 767                 # No longer an automatic choice
 768                 $auto_threads = 0 if ($1 eq "threads");
 769                 }
 770         elsif (/^enable-(.+)$/)
 771                 {
 772                 if ($1 eq "static-engine")
 773                         {
 774                         $disabled{"dynamic-engine"} = "option";
 775                         }
 776                 elsif ($1 eq "dynamic-engine")
 777                         {
 778                         delete $disabled{"dynamic-engine"};
 779                         }
 780                 elsif ($1 eq "zlib-dynamic")
 781                         {
 782                         delete $disabled{"zlib"};
 783                         }
 784                 my $algo = $1;
 785                 delete $disabled{$algo};
 786
 787                 # No longer an automatic choice
 788                 $auto_threads = 0 if ($1 eq "threads");
 789                 }
 790         elsif (/^--strict-warnings$/)
 791                 {
 792                 # Pretend that our strict flags is a C flag, and replace it
 793                 # with the proper flags later on
 794                 push @{$useradd{CFLAGS}}, '--ossl-strict-warnings';
 795                 $strict_warnings=1;
 796                 }
 797         elsif (/^--debug$/)
 798                 {
 799                 $config{build_type} = "debug";
 800                 }
 801         elsif (/^--release$/)
 802                 {
 803                 $config{build_type} = "release";
 804                 }
 805         elsif (/^386$/)
 806                 { $config{processor}=386; }
 807         elsif (/^fips$/)
 808                 {
 809                 die "FIPS mode not supported\n";
 810                 }
 811         elsif (/^rsaref$/)
 812                 {
 813                 # No RSAref support any more since it's not needed.
 814                 # The check for the option is there so scripts aren't
 815                 # broken
 816                 }
 817         elsif (/^nofipscanistercheck$/)
 818                 {
 819                 die "FIPS mode not supported\n";
 820                 }
 821         elsif (/^[-+]/)
 822                 {
 823                 if (/^--prefix=(.*)$/)
 824                         {
 825                         $config{prefix}=$1;
 826                         die "Directory given with --prefix MUST be absolute\n"
 827                                 unless file_name_is_absolute($config{prefix});
 828                         }
 829                 elsif (/^--api=(.*)$/)
 830                         {
 831                         $config{api}=$1;
 832                         }
 833                 elsif (/^--libdir=(.*)$/)
 834                         {
 835                         $config{libdir}=$1;
 836                         }
 837                 elsif (/^--openssldir=(.*)$/)
 838                         {
 839                         $config{openssldir}=$1;
 840                         }
 841                 elsif (/^--with-zlib-lib=(.*)$/)
 842                         {
 843                         $withargs{zlib_lib}=$1;
 844                         }
 845                 elsif (/^--with-zlib-include=(.*)$/)
 846                         {
 847                         $withargs{zlib_include}=$1;
 848                         }
 849                 elsif (/^--with-fuzzer-lib=(.*)$/)
 850                         {
 851                         $withargs{fuzzer_lib}=$1;
 852                         }
 853                 elsif (/^--with-fuzzer-include=(.*)$/)
 854                         {
 855                         $withargs{fuzzer_include}=$1;
 856                         }
 857                 elsif (/^--with-rand-seed=(.*)$/)
 858                         {
 859                         foreach my $x (split(m|,|, $1))
 860                             {
 861                             die "Unknown --with-rand-seed choice $x\n"
 862                                 if ! grep { $x eq $_ } @known_seed_sources;
 863                             push @seed_sources, $x;
 864                             }
 865                         }
 866                 elsif (/^--cross-compile-prefix=(.*)$/)
 867                         {
 868                         $user{CROSS_COMPILE}=$1;
 869                         }
 870                 elsif (/^--config=(.*)$/)
 871                         {
 872                         read_config $1;
 873                         }
 874                 elsif (/^-l(.*)$/)
 875                         {
 876                         push @{$useradd{LDLIBS}}, $_;
 877                         }
 878                 elsif (/^-framework$/)
 879                         {
 880                         push @{$useradd{LDLIBS}}, $_, shift(@argvcopy);
 881                         }
 882                 elsif (/^-L(.*)$/ or /^-Wl,/)
 883                         {
 884                         push @{$useradd{LDFLAGS}}, $_;
 885                         }
 886                 elsif (/^-rpath$/ or /^-R$/)
 887                         # -rpath is the OSF1 rpath flag
 888                         # -R is the old Solaris rpath flag
 889                         {
 890                         my $rpath = shift(@argvcopy) || "";
 891                         $rpath .= " " if $rpath ne "";
 892                         push @{$useradd{LDFLAGS}}, $_, $rpath;
 893                         }
 894                 elsif (/^-static$/)
 895                         {
 896                         push @{$useradd{LDFLAGS}}, $_;
 897                         }
 898                 elsif (/^-D(.*)$/)
 899                         {
 900                         push @{$useradd{CPPDEFINES}}, $1;
 901                         }
 902                 elsif (/^-I(.*)$/)
 903                         {
 904                         push @{$useradd{CPPINCLUDES}}, $1;
 905                         }
 906                 elsif (/^-Wp,$/)
 907                         {
 908                         push @{$useradd{CPPFLAGS}}, $1;
 909                         }
 910                 else    # common if (/^[-+]/), just pass down...
 911                         {
 912                         $_ =~ s/%([0-9a-f]{1,2})/chr(hex($1))/gei;
 913                         push @{$useradd{CFLAGS}}, $_;
 914                         push @{$useradd{CXXFLAGS}}, $_;
 915                         }
 916                 }
 917         else
 918                 {
 919                 die "target already defined - $target (offending arg: $_)\n" if ($target ne "");
 920                 $target=$_;
 921                 }
 922         unless ($_ eq $target || /^no-/ || /^disable-/)
 923                 {
 924                 # "no-..." follows later after implied deactivations
 925                 # have been derived.  (Don't take this too seriously,
 926                 # we really only write OPTIONS to the Makefile out of
 927                 # nostalgia.)
 928
 929                 if ($config{options} eq "")
 930                         { $config{options} = $_; }
 931                 else
 932                         { $config{options} .= " ".$_; }
 933                 }
 934         }
 935
 936 if (defined($config{api}) && !exists $apitable->{$config{api}}) {
 937         die "***** Unsupported api compatibility level: $config{api}\n",
 938 }
 939
 940 if (keys %deprecated_options)
 941         {
 942         warn "***** Deprecated options: ",
 943                 join(", ", keys %deprecated_options), "\n";
 944         }
 945 if (keys %unsupported_options)
 946         {
 947         die "***** Unsupported options: ",
 948                 join(", ", keys %unsupported_options), "\n";
 949         }
 950
 951 # If any %useradd entry has been set, we must check that the "make
 952 # variables" haven't been set.  We start by checking of any %useradd entry
 953 # is set.
 954 if (grep { scalar @$_ > 0 } values %useradd) {
 955     # Hash of env / make variables names.  The possible values are:
 956     # 1 - "make vars"
 957     # 2 - %useradd entry set
 958     # 3 - both set
 959     my %detected_vars =
 960         map { my $v = 0;
 961               $v += 1 if $cmdvars{$_};
 962               $v += 2 if @{$useradd{$_}};
 963               $_ => $v }
 964         keys %useradd;
 965
 966     # If any of the corresponding "make variables" is set, we error
 967     if (grep { $_ & 1 } values %detected_vars) {
 968         my $names = join(', ', grep { $detected_vars{$_} > 0 }
 969                                sort keys %detected_vars);
 970         die <<"_____";
 971 ***** Mixing make variables and additional compiler/linker flags as
 972 ***** configure command line option is not permitted.
 973 ***** Affected make variables: $names
 974 _____
 975     }
 976 }
 977
 978 # Check through all supported command line variables to see if any of them
 979 # were set, and canonicalise the values we got.  If no compiler or linker
 980 # flag or anything else that affects %useradd was set, we also check the
 981 # environment for values.
 982 my $anyuseradd =
 983     grep { defined $_ && (ref $_ ne 'ARRAY' || @$_) } values %useradd;
 984 foreach (keys %user) {
 985     my $value = $cmdvars{$_};
 986     $value //= env($_) unless $anyuseradd;
 987     $value //=
 988         defined $user_synonyms{$_} ? $cmdvars{$user_synonyms{$_}} : undef;
 989     $value //= defined $user_synonyms{$_} ? env($user_synonyms{$_}) : undef
 990         unless $anyuseradd;
 991
 992     if (defined $value) {
 993         if (ref $user{$_} eq 'ARRAY') {
 994             $user{$_} = [ split /$list_separator_re/, $value ];
 995         } elsif (!defined $user{$_}) {
 996             $user{$_} = $value;
 997         }
 998     }
 999 }
1000
1001 if (grep { /-rpath\b/ } ($user{LDFLAGS} ? @{$user{LDFLAGS}} : ())
1002     && !$disabled{shared}
1003     && !($disabled{asan} && $disabled{msan} && $disabled{ubsan})) {
1004     die "***** Cannot simultaneously use -rpath, shared libraries, and\n",
1005         "***** any of asan, msan or ubsan\n";
1006 }
1007
1008 sub disable {
1009     my $disable_type = shift;
1010
1011     for (@_) {
1012         $disabled{$_} = $disable_type;
1013     }
1014
1015     my @tocheckfor = (@_ ? @_ : keys %disabled);
1016     while (@tocheckfor) {
1017         my %new_tocheckfor = ();
1018         my @cascade_copy = (@disable_cascades);
1019         while (@cascade_copy) {
1020             my ($test, $descendents) =
1021                 (shift @cascade_copy, shift @cascade_copy);
1022             if (ref($test) eq "CODE" ? $test->() : defined($disabled{$test})) {
1023                 foreach (grep { !defined($disabled{$_}) } @$descendents) {
1024                     $new_tocheckfor{$_} = 1; $disabled{$_} = "cascade";
1025                 }
1026             }
1027         }
1028         @tocheckfor = (keys %new_tocheckfor);
1029     }
1030 }
1031 disable();                     # First cascade run
1032
1033 our $die = sub { die @_; };
1034 if ($target eq "TABLE") {
1035     local $die = sub { warn @_; };
1036     foreach (sort keys %table) {
1037         print_table_entry($_, "TABLE");
1038     }
1039     exit 0;
1040 }
1041
1042 if ($target eq "LIST") {
1043     foreach (sort keys %table) {
1044         print $_,"\n" unless $table{$_}->{template};
1045     }
1046     exit 0;
1047 }
1048
1049 if ($target eq "HASH") {
1050     local $die = sub { warn @_; };
1051     print "%table = (\n";
1052     foreach (sort keys %table) {
1053         print_table_entry($_, "HASH");
1054     }
1055     exit 0;
1056 }
1057
1058 print "Configuring OpenSSL version $config{full_version} ";
1059 print "for target $target\n";
1060
1061 if (scalar(@seed_sources) == 0) {
1062     print "Using os-specific seed configuration\n";
1063     push @seed_sources, 'os';
1064 }
1065 if (scalar(grep { $_ eq 'none' } @seed_sources) > 0) {
1066     die "Cannot seed with none and anything else" if scalar(@seed_sources) > 1;
1067     warn <<_____ if scalar(@seed_sources) == 1;
1068
1069 ============================== WARNING ===============================
1070 You have selected the --with-rand-seed=none option, which effectively
1071 disables automatic reseeding of the OpenSSL random generator.
1072 All operations depending on the random generator such as creating keys
1073 will not work unless the random generator is seeded manually by the
1074 application.
1075
1076 Please read the 'Note on random number generation' section in the
1077 INSTALL instructions and the RAND_DRBG(7) manual page for more details.
1078 ============================== WARNING ===============================
1079
1080 _____
1081 }
1082 push @{$config{openssl_feature_defines}},
1083      map { (my $x = $_) =~ tr|[\-a-z]|[_A-Z]|; "OPENSSL_RAND_SEED_$x" }
1084         @seed_sources;
1085
1086 # Backward compatibility?
1087 if ($target =~ m/^CygWin32(-.*)$/) {
1088     $target = "Cygwin".$1;
1089 }
1090
1091 # Support for legacy targets having a name starting with 'debug-'
1092 my ($d, $t) = $target =~ m/^(debug-)?(.*)$/;
1093 if ($d) {
1094     $config{build_type} = "debug";
1095
1096     # If we do not find debug-foo in the table, the target is set to foo.
1097     if (!$table{$target}) {
1098         $target = $t;
1099     }
1100 }
1101
1102 &usage if !$table{$target} || $table{$target}->{template};
1103
1104 $config{target} = $target;
1105 my %target = resolve_config($target);
1106
1107 foreach (keys %target_attr_translate) {
1108     $target{$target_attr_translate{$_}} = $target{$_}
1109         if $target{$_};
1110     delete $target{$_};
1111 }
1112
1113 %target = ( %{$table{DEFAULTS}}, %target );
1114
1115 my %conf_files = map { $_ => 1 } (@{$target{_conf_fname_int}});
1116 $config{conf_files} = [ sort keys %conf_files ];
1117
1118 # Using sub disable within these loops may prove fragile, so we run
1119 # a cascade afterwards
1120 foreach my $feature (@{$target{disable}}) {
1121     if (exists $deprecated_disablables{$feature}) {
1122         warn "***** config $target disables deprecated feature $feature\n";
1123     } elsif (!grep { $feature eq $_ } @disablables) {
1124         die "***** config $target disables unknown feature $feature\n";
1125     }
1126     $disabled{$feature} = 'config';
1127 }
1128 foreach my $feature (@{$target{enable}}) {
1129     if ("default" eq ($disabled{$feature} // "")) {
1130         if (exists $deprecated_disablables{$feature}) {
1131             warn "***** config $target enables deprecated feature $feature\n";
1132         } elsif (!grep { $feature eq $_ } @disablables) {
1133             die "***** config $target enables unknown feature $feature\n";
1134         }
1135         delete $disabled{$feature};
1136     }
1137 }
1138
1139 # If uplink_arch isn't defined, disable uplink
1140 $disabled{uplink} = 'no uplink_arch' unless (defined $target{uplink_arch});
1141 # If asm_arch isn't defined, disable asm
1142 $disabled{asm} = 'no asm_arch' unless (defined $target{asm_arch});
1143
1144 disable();                      # Run a cascade now
1145
1146 $target{CXXFLAGS}//=$target{CFLAGS} if $target{CXX};
1147 $target{cxxflags}//=$target{cflags} if $target{CXX};
1148 $target{exe_extension}=".exe" if ($config{target} eq "DJGPP");
1149 $target{exe_extension}=".pm"  if ($config{target} =~ /vos/);
1150
1151 # Fill %config with values from %user, and in case those are undefined or
1152 # empty, use values from %target (acting as a default).
1153 foreach (keys %user) {
1154     my $ref_type = ref $user{$_};
1155
1156     # Temporary function.  Takes an intended ref type (empty string or "ARRAY")
1157     # and a value that's to be coerced into that type.
1158     my $mkvalue = sub {
1159         my $type = shift;
1160         my $value = shift;
1161         my $undef_p = shift;
1162
1163         die "Too many arguments for \$mkvalue" if @_;
1164
1165         while (ref $value eq 'CODE') {
1166             $value = $value->();
1167         }
1168
1169         if ($type eq 'ARRAY') {
1170             return undef unless defined $value;
1171             return undef if ref $value ne 'ARRAY' && !$value;
1172             return undef if ref $value eq 'ARRAY' && !@$value;
1173             return [ $value ] unless ref $value eq 'ARRAY';
1174         }
1175         return undef unless $value;
1176         return $value;
1177     };
1178
1179     $config{$_} =
1180         $mkvalue->($ref_type, $user{$_})
1181         || $mkvalue->($ref_type, $target{$_});
1182     delete $config{$_} unless defined $config{$_};
1183 }
1184
1185 # Finish up %config by appending things the user gave us on the command line
1186 # apart from "make variables"
1187 foreach (keys %useradd) {
1188     # The must all be lists, so we assert that here
1189     die "internal error: \$useradd{$_} isn't an ARRAY\n"
1190         unless ref $useradd{$_} eq 'ARRAY';
1191
1192     if (defined $config{$_}) {
1193         push @{$config{$_}}, @{$useradd{$_}};
1194     } else {
1195         $config{$_} = [ @{$useradd{$_}} ];
1196     }
1197 }
1198 # At this point, we can forget everything about %user and %useradd,
1199 # because it's now all been merged into the corresponding $config entry
1200
1201 # Allow overriding the build file name
1202 $config{build_file} = env('BUILDFILE') || $target{build_file} || "Makefile";
1203
1204 ######################################################################
1205 # Build up information for skipping certain directories depending on disabled
1206 # features, as well as setting up macros for disabled features.
1207
1208 # This is a tentative database of directories to skip.  Some entries may not
1209 # correspond to anything real, but that's ok, they will simply be ignored.
1210 # The actual processing of these entries is done in the build.info lookup
1211 # loop further down.
1212 #
1213 # The key is a Unix formated path in the source tree, the value is an index
1214 # into %disabled_info, so any existing path gets added to a corresponding
1215 # 'skipped' entry in there with the list of skipped directories.
1216 my %skipdir = ();
1217 my %disabled_info = ();         # For configdata.pm
1218 foreach my $what (sort keys %disabled) {
1219     # There are deprecated disablables that translate to themselves.
1220     # They cause disabling cascades, but should otherwise not regiter.
1221     next if $deprecated_disablables{$what};
1222
1223     $config{options} .= " no-$what";
1224
1225     if (!grep { $what eq $_ } ( 'buildtest-c++', 'fips', 'threads', 'shared',
1226                                 'module', 'pic', 'dynamic-engine', 'makedepend',
1227                                 'zlib-dynamic', 'zlib', 'sse2', 'legacy' )) {
1228         (my $WHAT = uc $what) =~ s|-|_|g;
1229         my $skipdir = $what;
1230
1231         # fix-up crypto/directory name(s)
1232         $skipdir = "ripemd" if $what eq "rmd160";
1233         $skipdir = "whrlpool" if $what eq "whirlpool";
1234
1235         my $macro = $disabled_info{$what}->{macro} = "OPENSSL_NO_$WHAT";
1236         push @{$config{openssl_feature_defines}}, $macro;
1237
1238         $skipdir{engines} = $what if $what eq 'engine';
1239         $skipdir{"crypto/$skipdir"} = $what
1240             unless $what eq 'async' || $what eq 'err';
1241     }
1242 }
1243
1244 # Make sure build_scheme is consistent.
1245 $target{build_scheme} = [ $target{build_scheme} ]
1246     if ref($target{build_scheme}) ne "ARRAY";
1247
1248 my ($builder, $builder_platform, @builder_opts) =
1249     @{$target{build_scheme}};
1250
1251 foreach my $checker (($builder_platform."-".$target{build_file}."-checker.pm",
1252                       $builder_platform."-checker.pm")) {
1253     my $checker_path = catfile($srcdir, "Configurations", $checker);
1254     if (-f $checker_path) {
1255         my $fn = $ENV{CONFIGURE_CHECKER_WARN}
1256             ? sub { warn $@; } : sub { die $@; };
1257         if (! do $checker_path) {
1258             if ($@) {
1259                 $fn->($@);
1260             } elsif ($!) {
1261                 $fn->($!);
1262             } else {
1263                 $fn->("The detected tools didn't match the platform\n");
1264             }
1265         }
1266         last;
1267     }
1268 }
1269
1270 push @{$config{defines}}, "NDEBUG"    if $config{build_type} eq "release";
1271
1272 if ($target =~ /^mingw/ && `$config{CC} --target-help 2>&1` =~ m/-mno-cygwin/m)
1273         {
1274         push @{$config{cflags}}, "-mno-cygwin";
1275         push @{$config{cxxflags}}, "-mno-cygwin" if $config{CXX};
1276         push @{$config{shared_ldflag}}, "-mno-cygwin";
1277         }
1278
1279 if ($target =~ /linux.*-mips/ && !$disabled{asm}
1280         && !grep { $_ !~ /-m(ips|arch=)/ } (@{$config{CFLAGS}})) {
1281         # minimally required architecture flags for assembly modules
1282         my $value;
1283         $value = '-mips2' if ($target =~ /mips32/);
1284         $value = '-mips3' if ($target =~ /mips64/);
1285         unshift @{$config{cflags}}, $value;
1286         unshift @{$config{cxxflags}}, $value if $config{CXX};
1287 }
1288
1289 # If threads aren't disabled, check how possible they are
1290 unless ($disabled{threads}) {
1291     if ($auto_threads) {
1292         # Enabled by default, disable it forcibly if unavailable
1293         if ($target{thread_scheme} eq "(unknown)") {
1294             disable("unavailable", 'threads');
1295         }
1296     } else {
1297         # The user chose to enable threads explicitly, let's see
1298         # if there's a chance that's possible
1299         if ($target{thread_scheme} eq "(unknown)") {
1300             # If the user asked for "threads" and we don't have internal
1301             # knowledge how to do it, [s]he is expected to provide any
1302             # system-dependent compiler options that are necessary.  We
1303             # can't truly check that the given options are correct, but
1304             # we expect the user to know what [s]He is doing.
1305             if (!@{$config{CFLAGS}} && !@{$config{CPPDEFINES}}) {
1306                 die "You asked for multi-threading support, but didn't\n"
1307                     ,"provide any system-specific compiler options\n";
1308             }
1309         }
1310     }
1311 }
1312
1313 # Find out if clang's sanitizers have been enabled with -fsanitize
1314 # flags and ensure that the corresponding %disabled elements area
1315 # removed to reflect that the sanitizers are indeed enabled.
1316 my %detected_sanitizers = ();
1317 foreach (grep /^-fsanitize=/, @{$config{CFLAGS} || []}) {
1318     (my $checks = $_) =~ s/^-fsanitize=//;
1319     foreach (split /,/, $checks) {
1320         my $d = { address       => 'asan',
1321                   undefined     => 'ubsan',
1322                   memory        => 'msan' } -> {$_};
1323         next unless defined $d;
1324
1325         $detected_sanitizers{$d} = 1;
1326         if (defined $disabled{$d}) {
1327             die "***** Conflict between disabling $d and enabling $_ sanitizer"
1328                 if $disabled{$d} ne "default";
1329             delete $disabled{$d};
1330         }
1331     }
1332 }
1333
1334 # If threads still aren't disabled, add a C macro to ensure the source
1335 # code knows about it.  Any other flag is taken care of by the configs.
1336 unless($disabled{threads}) {
1337     push @{$config{openssl_feature_defines}}, "OPENSSL_THREADS";
1338 }
1339
1340 # With "deprecated" disable all deprecated features.
1341 if (defined($disabled{"deprecated"})) {
1342         $config{api} = $maxapi;
1343 }
1344
1345 my $no_shared_warn=0;
1346 if ($target{shared_target} eq "")
1347         {
1348         $no_shared_warn = 1
1349             if (!$disabled{shared} || !$disabled{"dynamic-engine"});
1350         disable('no-shared-target', 'pic');
1351         }
1352
1353 if ($disabled{"dynamic-engine"}) {
1354         push @{$config{openssl_feature_defines}}, "OPENSSL_NO_DYNAMIC_ENGINE";
1355         $config{dynamic_engines} = 0;
1356 } else {
1357         push @{$config{openssl_feature_defines}}, "OPENSSL_NO_STATIC_ENGINE";
1358         $config{dynamic_engines} = 1;
1359 }
1360
1361 unless ($disabled{asan} || defined $detected_sanitizers{asan}) {
1362     push @{$config{cflags}}, "-fsanitize=address";
1363 }
1364
1365 unless ($disabled{ubsan} || defined $detected_sanitizers{ubsan}) {
1366     # -DPEDANTIC or -fnosanitize=alignment may also be required on some
1367     # platforms.
1368     push @{$config{cflags}}, "-fsanitize=undefined", "-fno-sanitize-recover=all";
1369 }
1370
1371 unless ($disabled{msan} || defined $detected_sanitizers{msan}) {
1372   push @{$config{cflags}}, "-fsanitize=memory";
1373 }
1374
1375 unless ($disabled{"fuzz-libfuzzer"} && $disabled{"fuzz-afl"}
1376         && $disabled{asan} && $disabled{ubsan} && $disabled{msan}) {
1377     push @{$config{cflags}}, "-fno-omit-frame-pointer", "-g";
1378     push @{$config{cxxflags}}, "-fno-omit-frame-pointer", "-g" if $config{CXX};
1379 }
1380 #
1381 # Platform fix-ups
1382 #
1383
1384 # This saves the build files from having to check
1385 if ($disabled{pic})
1386         {
1387         foreach (qw(shared_cflag shared_cxxflag shared_cppflag
1388                     shared_defines shared_includes shared_ldflag
1389                     module_cflags module_cxxflags module_cppflags
1390                     module_defines module_includes module_lflags))
1391                 {
1392                 delete $config{$_};
1393                 $target{$_} = "";
1394                 }
1395         }
1396 else
1397         {
1398         push @{$config{lib_defines}}, "OPENSSL_PIC";
1399         }
1400
1401 if ($target{sys_id} ne "")
1402         {
1403         push @{$config{openssl_sys_defines}}, "OPENSSL_SYS_$target{sys_id}";
1404         }
1405
1406 unless ($disabled{asm}) {
1407     if ($target{keccak1600_asm_src} ne $table{DEFAULTS}->{keccak1600_asm_src}) {
1408         push @{$config{lib_defines}}, "KECCAK1600_ASM";
1409     }
1410     if ($target{padlock_asm_src} ne $table{DEFAULTS}->{padlock_asm_src}) {
1411         push @{$config{dso_defines}}, "PADLOCK_ASM";
1412     }
1413     if ($target{poly1305_asm_src} ne "") {
1414         push @{$config{lib_defines}}, "POLY1305_ASM";
1415     }
1416 }
1417
1418 my %predefined_C = compiler_predefined($config{CROSS_COMPILE}.$config{CC});
1419 my %predefined_CXX = $config{CXX}
1420     ? compiler_predefined($config{CROSS_COMPILE}.$config{CXX})
1421     : ();
1422
1423 # Check for makedepend capabilities.
1424 if (!$disabled{makedepend}) {
1425     if ($config{target} =~ /^(VC|vms)-/) {
1426         # For VC- and vms- targets, there's nothing more to do here.  The
1427         # functionality is hard coded in the corresponding build files for
1428         # cl (Windows) and CC/DECC (VMS).
1429     } elsif (($predefined_C{__GNUC__} // -1) >= 3
1430              && !($predefined_C{__APPLE_CC__} && !$predefined_C{__clang__})) {
1431         # We know that GNU C version 3 and up as well as all clang
1432         # versions support dependency generation, but Xcode did not
1433         # handle $cc -M before clang support (but claims __GNUC__ = 3)
1434         $config{makedepprog} = "\$(CROSS_COMPILE)$config{CC}";
1435     } else {
1436         # In all other cases, we look for 'makedepend', and disable the
1437         # capability if not found.
1438         $config{makedepprog} = which('makedepend');
1439         disable('unavailable', 'makedepend') unless $config{makedepprog};
1440     }
1441 }
1442
1443 if (!$disabled{asm} && !$predefined_C{__MACH__} && $^O ne 'VMS') {
1444     # probe for -Wa,--noexecstack option...
1445     if ($predefined_C{__clang__}) {
1446         # clang has builtin assembler, which doesn't recognize --help,
1447         # but it apparently recognizes the option in question on all
1448         # supported platforms even when it's meaningless. In other words
1449         # probe would fail, but probed option always accepted...
1450         push @{$config{cflags}}, "-Wa,--noexecstack", "-Qunused-arguments";
1451     } else {
1452         my $cc = $config{CROSS_COMPILE}.$config{CC};
1453         open(PIPE, "$cc -Wa,--help -c -o null.$$.o -x assembler /dev/null 2>&1 |");
1454         while(<PIPE>) {
1455             if (m/--noexecstack/) {
1456                 push @{$config{cflags}}, "-Wa,--noexecstack";
1457                 last;
1458             }
1459         }
1460         close(PIPE);
1461         unlink("null.$$.o");
1462     }
1463 }
1464
1465 # Deal with bn_ops ###################################################
1466
1467 $config{bn_ll}                  =0;
1468 $config{export_var_as_fn}       =0;
1469 my $def_int="unsigned int";
1470 $config{rc4_int}                =$def_int;
1471 ($config{b64l},$config{b64},$config{b32})=(0,0,1);
1472
1473 my $count = 0;
1474 foreach (sort split(/\s+/,$target{bn_ops})) {
1475     $count++ if /SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT/;
1476     $config{export_var_as_fn}=1                 if $_ eq 'EXPORT_VAR_AS_FN';
1477     $config{bn_ll}=1                            if $_ eq 'BN_LLONG';
1478     $config{rc4_int}="unsigned char"            if $_ eq 'RC4_CHAR';
1479     ($config{b64l},$config{b64},$config{b32})
1480         =(0,1,0)                                if $_ eq 'SIXTY_FOUR_BIT';
1481     ($config{b64l},$config{b64},$config{b32})
1482         =(1,0,0)                                if $_ eq 'SIXTY_FOUR_BIT_LONG';
1483     ($config{b64l},$config{b64},$config{b32})
1484         =(0,0,1)                                if $_ eq 'THIRTY_TWO_BIT';
1485 }
1486 die "Exactly one of SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT can be set in bn_ops\n"
1487     if $count > 1;
1488
1489
1490 # Hack cflags for better warnings (dev option) #######################
1491
1492 # "Stringify" the C and C++ flags string.  This permits it to be made part of
1493 # a string and works as well on command lines.
1494 $config{cflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1495                         @{$config{cflags}} ];
1496 $config{cxxflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1497                           @{$config{cxxflags}} ] if $config{CXX};
1498
1499 $config{openssl_api_defines} = [
1500     "OPENSSL_MIN_API=".($apitable->{$config{api} // ""} // -1)
1501 ];
1502
1503 my @strict_warnings_collection=();
1504 if ($strict_warnings)
1505         {
1506         my $wopt;
1507         my $gccver = $predefined_C{__GNUC__} // -1;
1508
1509         warn "WARNING --strict-warnings requires gcc[>=4] or gcc-alike"
1510             unless $gccver >= 4;
1511         push @strict_warnings_collection, @gcc_devteam_warn;
1512         push @strict_warnings_collection, @clang_devteam_warn
1513             if (defined($predefined_C{__clang__}));
1514         }
1515
1516 if (grep { $_ eq '-static' } @{$config{LDFLAGS}}) {
1517     disable('static', 'pic', 'threads');
1518 }
1519
1520 $config{CFLAGS} = [ map { $_ eq '--ossl-strict-warnings'
1521                               ? @strict_warnings_collection
1522                               : ( $_ ) }
1523                     @{$config{CFLAGS}} ];
1524
1525 unless ($disabled{"crypto-mdebug-backtrace"})
1526         {
1527         foreach my $wopt (split /\s+/, $memleak_devteam_backtrace)
1528                 {
1529                 push @{$config{cflags}}, $wopt
1530                         unless grep { $_ eq $wopt } @{$config{cflags}};
1531                 }
1532         if ($target =~ /^BSD-/)
1533                 {
1534                 push @{$config{ex_libs}}, "-lexecinfo";
1535                 }
1536         }
1537
1538 unless ($disabled{afalgeng}) {
1539     $config{afalgeng}="";
1540     if (grep { $_ eq 'afalgeng' } @{$target{enable}}) {
1541         my $minver = 4*10000 + 1*100 + 0;
1542         if ($config{CROSS_COMPILE} eq "") {
1543             my $verstr = `uname -r`;
1544             my ($ma, $mi1, $mi2) = split("\\.", $verstr);
1545             ($mi2) = $mi2 =~ /(\d+)/;
1546             my $ver = $ma*10000 + $mi1*100 + $mi2;
1547             if ($ver < $minver) {
1548                 disable('too-old-kernel', 'afalgeng');
1549             } else {
1550                 push @{$config{engdirs}}, "afalg";
1551             }
1552         } else {
1553             disable('cross-compiling', 'afalgeng');
1554         }
1555     } else {
1556         disable('not-linux', 'afalgeng');
1557     }
1558 }
1559
1560 push @{$config{openssl_feature_defines}}, "OPENSSL_NO_AFALGENG" if ($disabled{afalgeng});
1561
1562 unless ($disabled{ktls}) {
1563     $config{ktls}="";
1564     if ($target =~ m/^linux/) {
1565         my $usr = "/usr/$config{cross_compile_prefix}";
1566         chop($usr);
1567         if ($config{cross_compile_prefix} eq "") {
1568             $usr = "/usr";
1569         }
1570         my $minver = (4 << 16) + (13 << 8) + 0;
1571         my @verstr = split(" ",`cat $usr/include/linux/version.h | grep LINUX_VERSION_CODE`);
1572
1573         if ($verstr[2] < $minver) {
1574             disable('too-old-kernel', 'ktls');
1575         }
1576     } else {
1577         disable('not-linux', 'ktls');
1578     }
1579 }
1580
1581 push @{$config{openssl_other_defines}}, "OPENSSL_NO_KTLS" if ($disabled{ktls});
1582
1583 # Get the extra flags used when building shared libraries and modules.  We
1584 # do this late because some of them depend on %disabled.
1585
1586 # Make the flags to build DSOs the same as for shared libraries unless they
1587 # are already defined
1588 $target{module_cflags} = $target{shared_cflag} unless defined $target{module_cflags};
1589 $target{module_cxxflags} = $target{shared_cxxflag} unless defined $target{module_cxxflags};
1590 $target{module_ldflags} = $target{shared_ldflag} unless defined $target{module_ldflags};
1591 {
1592     my $shared_info_pl =
1593         catfile(dirname($0), "Configurations", "shared-info.pl");
1594     my %shared_info = read_eval_file($shared_info_pl);
1595     push @{$target{_conf_fname_int}}, $shared_info_pl;
1596     my $si = $target{shared_target};
1597     while (ref $si ne "HASH") {
1598         last if ! defined $si;
1599         if (ref $si eq "CODE") {
1600             $si = $si->();
1601         } else {
1602             $si = $shared_info{$si};
1603         }
1604     }
1605
1606     # Some of the 'shared_target' values don't have any entries in
1607     # %shared_info.  That's perfectly fine, AS LONG AS the build file
1608     # template knows how to handle this.  That is currently the case for
1609     # Windows and VMS.
1610     if (defined $si) {
1611         # Just as above, copy certain shared_* attributes to the corresponding
1612         # module_ attribute unless the latter is already defined
1613         $si->{module_cflags} = $si->{shared_cflag} unless defined $si->{module_cflags};
1614         $si->{module_cxxflags} = $si->{shared_cxxflag} unless defined $si->{module_cxxflags};
1615         $si->{module_ldflags} = $si->{shared_ldflag} unless defined $si->{module_ldflags};
1616         foreach (sort keys %$si) {
1617             $target{$_} = defined $target{$_}
1618                 ? add($si->{$_})->($target{$_})
1619                 : $si->{$_};
1620         }
1621     }
1622 }
1623
1624 # ALL MODIFICATIONS TO %disabled, %config and %target MUST BE DONE FROM HERE ON
1625
1626 # If we use the unified build, collect information from build.info files
1627 my %unified_info = ();
1628
1629 my $buildinfo_debug = defined($ENV{CONFIGURE_DEBUG_BUILDINFO});
1630 if ($builder eq "unified") {
1631     use with_fallback qw(Text::Template);
1632
1633     sub cleandir {
1634         my $base = shift;
1635         my $dir = shift;
1636         my $relativeto = shift || ".";
1637
1638         $dir = catdir($base,$dir) unless isabsolute($dir);
1639
1640         # Make sure the directories we're building in exists
1641         mkpath($dir);
1642
1643         my $res = abs2rel(absolutedir($dir), rel2abs($relativeto));
1644         #print STDERR "DEBUG[cleandir]: $dir , $base => $res\n";
1645         return $res;
1646     }
1647
1648     sub cleanfile {
1649         my $base = shift;
1650         my $file = shift;
1651         my $relativeto = shift || ".";
1652
1653         $file = catfile($base,$file) unless isabsolute($file);
1654
1655         my $d = dirname($file);
1656         my $f = basename($file);
1657
1658         # Make sure the directories we're building in exists
1659         mkpath($d);
1660
1661         my $res = abs2rel(catfile(absolutedir($d), $f), rel2abs($relativeto));
1662         #print STDERR "DEBUG[cleanfile]: $d , $f => $res\n";
1663         return $res;
1664     }
1665
1666     # Store the name of the template file we will build the build file from
1667     # in %config.  This may be useful for the build file itself.
1668     my @build_file_template_names =
1669         ( $builder_platform."-".$target{build_file}.".tmpl",
1670           $target{build_file}.".tmpl" );
1671     my @build_file_templates = ();
1672
1673     # First, look in the user provided directory, if given
1674     if (defined env($local_config_envname)) {
1675         @build_file_templates =
1676             map {
1677                 if ($^O eq 'VMS') {
1678                     # VMS environment variables are logical names,
1679                     # which can be used as is
1680                     $local_config_envname . ':' . $_;
1681                 } else {
1682                     catfile(env($local_config_envname), $_);
1683                 }
1684             }
1685             @build_file_template_names;
1686     }
1687     # Then, look in our standard directory
1688     push @build_file_templates,
1689         ( map { cleanfile($srcdir, catfile("Configurations", $_), $blddir) }
1690           @build_file_template_names );
1691
1692     my $build_file_template;
1693     for $_ (@build_file_templates) {
1694         $build_file_template = $_;
1695         last if -f $build_file_template;
1696
1697         $build_file_template = undef;
1698     }
1699     if (!defined $build_file_template) {
1700         die "*** Couldn't find any of:\n", join("\n", @build_file_templates), "\n";
1701     }
1702     $config{build_file_templates}
1703       = [ cleanfile($srcdir, catfile("Configurations", "common0.tmpl"),
1704                     $blddir),
1705           $build_file_template,
1706           cleanfile($srcdir, catfile("Configurations", "common.tmpl"),
1707                     $blddir) ];
1708
1709     my @build_dirs = ( [ ] );   # current directory
1710
1711     $config{build_infos} = [ ];
1712
1713     my %ordinals = ();
1714     while (@build_dirs) {
1715         my @curd = @{shift @build_dirs};
1716         my $sourced = catdir($srcdir, @curd);
1717         my $buildd = catdir($blddir, @curd);
1718
1719         my $unixdir = join('/', @curd);
1720         if (exists $skipdir{$unixdir}) {
1721             my $what = $skipdir{$unixdir};
1722             push @{$disabled_info{$what}->{skipped}}, catdir(@curd);
1723             next;
1724         }
1725
1726         mkpath($buildd);
1727
1728         my $f = 'build.info';
1729         # The basic things we're trying to build
1730         my @programs = ();
1731         my @libraries = ();
1732         my @modules = ();
1733         my @scripts = ();
1734
1735         my %attributes = ();
1736         my %sources = ();
1737         my %shared_sources = ();
1738         my %includes = ();
1739         my %defines = ();
1740         my %depends = ();
1741         my %generate = ();
1742
1743         # Support for $variablename in build.info files.
1744         # Embedded perl code is the ultimate master, still.  If its output
1745         # contains a dollar sign, it had better be escaped, or it will be
1746         # taken for a variable name prefix.
1747         my %variables = ();
1748         my $variable_re = qr/\$([[:alpha:]][[:alnum:]_]*)/;
1749         my $expand_variables = sub {
1750             my $value = '';
1751             my $value_rest = shift;
1752
1753             while ($value_rest =~ /(?<!\\)${variable_re}/) {
1754                 $value .= $`;
1755                 $value .= $variables{$1};
1756                 $value_rest = $';
1757             }
1758             return $value . $value_rest;
1759         };
1760
1761         # We want to detect configdata.pm in the source tree, so we
1762         # don't use it if the build tree is different.
1763         my $src_configdata = cleanfile($srcdir, "configdata.pm", $blddir);
1764
1765         push @{$config{build_infos}}, catfile(abs2rel($sourced, $blddir), $f);
1766         my $template =
1767             Text::Template->new(TYPE => 'FILE',
1768                                 SOURCE => catfile($sourced, $f),
1769                                 PREPEND => qq{use lib "$FindBin::Bin/util/perl";});
1770         die "Something went wrong with $sourced/$f: $!\n" unless $template;
1771         my @text =
1772             split /^/m,
1773             $template->fill_in(HASH => { config => \%config,
1774                                          target => \%target,
1775                                          disabled => \%disabled,
1776                                          withargs => \%withargs,
1777                                          builddir => abs2rel($buildd, $blddir),
1778                                          sourcedir => abs2rel($sourced, $blddir),
1779                                          buildtop => abs2rel($blddir, $blddir),
1780                                          sourcetop => abs2rel($srcdir, $blddir) },
1781                                DELIMITERS => [ "{-", "-}" ]);
1782
1783         # The top item of this stack has the following values
1784         # -2 positive already run and we found ELSE (following ELSIF should fail)
1785         # -1 positive already run (skip until ENDIF)
1786         # 0 negatives so far (if we're at a condition, check it)
1787         # 1 last was positive (don't skip lines until next ELSE, ELSIF or ENDIF)
1788         # 2 positive ELSE (following ELSIF should fail)
1789         my @skip = ();
1790         collect_information(
1791             collect_from_array([ @text ],
1792                                qr/\\$/ => sub { my $l1 = shift; my $l2 = shift;
1793                                                 $l1 =~ s/\\$//; $l1.$l2 }),
1794             # Info we're looking for
1795             qr/^\s*IF\[((?:\\.|[^\\\]])*)\]\s*$/
1796             => sub {
1797                 if (! @skip || $skip[$#skip] > 0) {
1798                     push @skip, !! $expand_variables->($1);
1799                 } else {
1800                     push @skip, -1;
1801                 }
1802             },
1803             qr/^\s*ELSIF\[((?:\\.|[^\\\]])*)\]\s*$/
1804             => sub { die "ELSIF out of scope" if ! @skip;
1805                      die "ELSIF following ELSE" if abs($skip[$#skip]) == 2;
1806                      $skip[$#skip] = -1 if $skip[$#skip] != 0;
1807                      $skip[$#skip] = !! $expand_variables->($1)
1808                          if $skip[$#skip] == 0; },
1809             qr/^\s*ELSE\s*$/
1810             => sub { die "ELSE out of scope" if ! @skip;
1811                      $skip[$#skip] = -2 if $skip[$#skip] != 0;
1812                      $skip[$#skip] = 2 if $skip[$#skip] == 0; },
1813             qr/^\s*ENDIF\s*$/
1814             => sub { die "ENDIF out of scope" if ! @skip;
1815                      pop @skip; },
1816             qr/^\s*${variable_re}\s*=\s*(.*?)\s*$/
1817             => sub {
1818                 if (!@skip || $skip[$#skip] > 0) {
1819                     my $n = $1;
1820                     my $v = $2;
1821                     $variables{$n} = $expand_variables->($v);
1822                 }
1823             },
1824             qr/^\s*SUBDIRS\s*=\s*(.*)\s*$/
1825             => sub {
1826                 if (!@skip || $skip[$#skip] > 0) {
1827                     foreach (tokenize($expand_variables->($1))) {
1828                         push @build_dirs, [ @curd, splitdir($_, 1) ];
1829                     }
1830                 }
1831             },
1832             qr/^\s*PROGRAMS(?:{([\w=]+(?:\s*,\s*[\w=]+)*)})?\s*=\s*(.*)\s*$/
1833             => sub {
1834                 if (!@skip || $skip[$#skip] > 0) {
1835                     my @a = tokenize($1, qr|\s*,\s*|);
1836                     my @p = tokenize($expand_variables->($2));
1837                     push @programs, @p;
1838                     foreach my $a (@a) {
1839                         my $ak = $a;
1840                         my $av = 1;
1841                         if ($a =~ m|^(.*?)\s*=\s*(.*?)$|) {
1842                             $ak = $1;
1843                             $av = $2;
1844                         }
1845                         foreach my $p (@p) {
1846                             $attributes{$p}->{$ak} = $av;
1847                         }
1848                     }
1849                 }
1850             },
1851             qr/^\s*LIBS(?:{([\w=]+(?:\s*,\s*[\w=]+)*)})?\s*=\s*(.*)\s*$/
1852             => sub {
1853                 if (!@skip || $skip[$#skip] > 0) {
1854                     my @a = tokenize($1, qr|\s*,\s*|);
1855                     my @l = tokenize($expand_variables->($2));
1856                     push @libraries, @l;
1857                     foreach my $a (@a) {
1858                         my $ak = $a;
1859                         my $av = 1;
1860                         if ($a =~ m|^(.*?)\s*=\s*(.*?)$|) {
1861                             $ak = $1;
1862                             $av = $2;
1863                         }
1864                         foreach my $l (@l) {
1865                             $attributes{$l}->{$ak} = $av;
1866                         }
1867                     }
1868                 }
1869             },
1870             qr/^\s*MODULES(?:{([\w=]+(?:\s*,\s*[\w=]+)*)})?\s*=\s*(.*)\s*$/
1871             => sub {
1872                 if (!@skip || $skip[$#skip] > 0) {
1873                     my @a = tokenize($1, qr|\s*,\s*|);
1874                     my @m = tokenize($expand_variables->($2));
1875                     push @modules, @m;
1876                     foreach my $a (@a) {
1877                         my $ak = $a;
1878                         my $av = 1;
1879                         if ($a =~ m|^(.*?)\s*=\s*(.*?)$|) {
1880                             $ak = $1;
1881                             $av = $2;
1882                         }
1883                         foreach my $m (@m) {
1884                             $attributes{$m}->{$ak} = $av;
1885                         }
1886                     }
1887                 }
1888             },
1889             qr/^\s*SCRIPTS(?:{([\w=]+(?:\s*,\s*[\w=]+)*)})?\s*=\s*(.*)\s*$/
1890             => sub {
1891                 if (!@skip || $skip[$#skip] > 0) {
1892                     my @a = tokenize($1, qr|\s*,\s*|);
1893                     my @s = tokenize($expand_variables->($2));
1894                     push @scripts, @s;
1895                     foreach my $a (@a) {
1896                         my $ak = $a;
1897                         my $av = 1;
1898                         if ($a =~ m|^(.*?)\s*=\s*(.*?)$|) {
1899                             $ak = $1;
1900                             $av = $2;
1901                         }
1902                         foreach my $s (@s) {
1903                             $attributes{$s}->{$ak} = $av;
1904                         }
1905                     }
1906                 }
1907             },
1908
1909             qr/^\s*ORDINALS\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/,
1910             => sub { push @{$ordinals{$1}}, tokenize($expand_variables->($2))
1911                          if !@skip || $skip[$#skip] > 0 },
1912             qr/^\s*SOURCE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1913             => sub { push @{$sources{$1}}, tokenize($expand_variables->($2))
1914                          if !@skip || $skip[$#skip] > 0 },
1915             qr/^\s*SHARED_SOURCE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1916             => sub { push @{$shared_sources{$1}},
1917                          tokenize($expand_variables->($2))
1918                          if !@skip || $skip[$#skip] > 0 },
1919             qr/^\s*INCLUDE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1920             => sub { push @{$includes{$1}}, tokenize($expand_variables->($2))
1921                          if !@skip || $skip[$#skip] > 0 },
1922             qr/^\s*DEFINE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1923             => sub { push @{$defines{$1}}, tokenize($expand_variables->($2))
1924                          if !@skip || $skip[$#skip] > 0 },
1925             qr/^\s*DEPEND\[((?:\\.|[^\\\]])*)\]\s*=\s*(.*)\s*$/
1926             => sub { push @{$depends{$1}}, tokenize($expand_variables->($2))
1927                          if !@skip || $skip[$#skip] > 0 },
1928             qr/^\s*GENERATE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1929             => sub { push @{$generate{$1}}, $2
1930                          if !@skip || $skip[$#skip] > 0 },
1931             qr/^\s*(?:#.*)?$/ => sub { },
1932             "OTHERWISE" => sub { die "Something wrong with this line:\n$_\nat $sourced/$f" },
1933             "BEFORE" => sub {
1934                 if ($buildinfo_debug) {
1935                     print STDERR "DEBUG: Parsing ",join(" ", @_),"\n";
1936                     print STDERR "DEBUG: ... before parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
1937                 }
1938             },
1939             "AFTER" => sub {
1940                 if ($buildinfo_debug) {
1941                     print STDERR "DEBUG: .... after parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
1942                 }
1943             },
1944             );
1945         die "runaway IF?" if (@skip);
1946
1947         if (grep { defined $attributes{$_}->{engine} } keys %attributes
1948                 and !$config{dynamic_engines}) {
1949             die <<"EOF"
1950 ENGINES can only be used if configured with 'dynamic-engine'.
1951 This is usually a fault in a build.info file.
1952 EOF
1953         }
1954
1955         foreach (keys %attributes) {
1956             my $dest = $_;
1957             my $ddest = cleanfile($buildd, $_, $blddir);
1958             foreach (keys %{$attributes{$dest} // {}}) {
1959                 $unified_info{attributes}->{$ddest}->{$_} =
1960                     $attributes{$dest}->{$_};
1961             }
1962         }
1963
1964         {
1965             my %infos = ( programs  => [ @programs  ],
1966                           libraries => [ @libraries ],
1967                           modules   => [ @modules   ],
1968                           scripts   => [ @scripts   ] );
1969             foreach my $k (keys %infos) {
1970                 foreach (@{$infos{$k}}) {
1971                     my $item = cleanfile($buildd, $_, $blddir);
1972                     $unified_info{$k}->{$item} = 1;
1973                 }
1974             }
1975         }
1976
1977         # Check that we haven't defined any library as both shared and
1978         # explicitly static.  That is forbidden.
1979         my @doubles = ();
1980         foreach (grep /\.a$/, keys %{$unified_info{libraries}}) {
1981             (my $l = $_) =~ s/\.a$//;
1982             push @doubles, $l if defined $unified_info{libraries}->{$l};
1983         }
1984         die "these libraries are both explicitly static and shared:\n  ",
1985             join(" ", @doubles), "\n"
1986             if @doubles;
1987
1988         foreach (keys %sources) {
1989             my $dest = $_;
1990             my $ddest = cleanfile($buildd, $_, $blddir);
1991             foreach (@{$sources{$dest}}) {
1992                 my $s = cleanfile($sourced, $_, $blddir);
1993
1994                 # If it isn't in the source tree, we assume it's generated
1995                 # in the build tree
1996                 if ($s eq $src_configdata || ! -f $s || $generate{$_}) {
1997                     $s = cleanfile($buildd, $_, $blddir);
1998                 }
1999                 # We recognise C++, C and asm files
2000                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
2001                     my $o = $_;
2002                     $o =~ s/\.[csS]$/.o/; # C and assembler
2003                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
2004                     $o = cleanfile($buildd, $o, $blddir);
2005                     $unified_info{sources}->{$ddest}->{$o} = -1;
2006                     $unified_info{sources}->{$o}->{$s} = -1;
2007                 } elsif ($s =~ /\.rc$/) {
2008                     # We also recognise resource files
2009                     my $o = $_;
2010                     $o =~ s/\.rc$/.res/; # Resource configuration
2011                     my $o = cleanfile($buildd, $o, $blddir);
2012                     $unified_info{sources}->{$ddest}->{$o} = -1;
2013                     $unified_info{sources}->{$o}->{$s} = -1;
2014                 } else {
2015                     $unified_info{sources}->{$ddest}->{$s} = 1;
2016                 }
2017             }
2018         }
2019
2020         foreach (keys %shared_sources) {
2021             my $dest = $_;
2022             my $ddest = cleanfile($buildd, $_, $blddir);
2023             foreach (@{$shared_sources{$dest}}) {
2024                 my $s = cleanfile($sourced, $_, $blddir);
2025
2026                 # If it isn't in the source tree, we assume it's generated
2027                 # in the build tree
2028                 if ($s eq $src_configdata || ! -f $s || $generate{$_}) {
2029                     $s = cleanfile($buildd, $_, $blddir);
2030                 }
2031
2032                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
2033                     # We recognise C++, C and asm files
2034                     my $o = $_;
2035                     $o =~ s/\.[csS]$/.o/; # C and assembler
2036                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
2037                     $o = cleanfile($buildd, $o, $blddir);
2038                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2039                     $unified_info{sources}->{$o}->{$s} = -1;
2040                 } elsif ($s =~ /\.rc$/) {
2041                     # We also recognise resource files
2042                     my $o = $_;
2043                     $o =~ s/\.rc$/.res/; # Resource configuration
2044                     my $o = cleanfile($buildd, $o, $blddir);
2045                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2046                     $unified_info{sources}->{$o}->{$s} = -1;
2047                 } elsif ($s =~ /\.ld$/) {
2048                     # We also recognise linker scripts (or corresponding)
2049                     # We know they are generated files
2050                     my $ld = cleanfile($buildd, $_, $blddir);
2051                     $unified_info{shared_sources}->{$ddest}->{$ld} = 1;
2052                 } else {
2053                     die "unrecognised source file type for shared library: $s\n";
2054                 }
2055             }
2056         }
2057
2058         foreach (keys %generate) {
2059             my $dest = $_;
2060             my $ddest = cleanfile($buildd, $_, $blddir);
2061             die "more than one generator for $dest: "
2062                     ,join(" ", @{$generate{$_}}),"\n"
2063                     if scalar @{$generate{$_}} > 1;
2064             my @generator = split /\s+/, $generate{$dest}->[0];
2065             $generator[0] = cleanfile($sourced, $generator[0], $blddir),
2066             $unified_info{generate}->{$ddest} = [ @generator ];
2067         }
2068
2069         foreach (keys %depends) {
2070             my $dest = $_;
2071             my $ddest = $dest eq "" ? "" : cleanfile($sourced, $_, $blddir);
2072
2073             # If the destination doesn't exist in source, it can only be
2074             # a generated file in the build tree.
2075             if ($ddest ne "" && ($ddest eq $src_configdata || ! -f $ddest)) {
2076                 $ddest = cleanfile($buildd, $_, $blddir);
2077             }
2078             foreach (@{$depends{$dest}}) {
2079                 my $d = cleanfile($sourced, $_, $blddir);
2080
2081                 # If we know it's generated, or assume it is because we can't
2082                 # find it in the source tree, we set file we depend on to be
2083                 # in the build tree rather than the source tree, and assume
2084                 # and that there are lines to build it in a BEGINRAW..ENDRAW
2085                 # section or in the Makefile template.
2086                 if ($d eq $src_configdata
2087                     || ! -f $d
2088                     || (grep { $d eq $_ }
2089                         map { cleanfile($srcdir, $_, $blddir) }
2090                         grep { /\.h$/ } keys %{$unified_info{generate}})) {
2091                     $d = cleanfile($buildd, $_, $blddir);
2092                 }
2093                 # Take note if the file to depend on is being renamed
2094                 # Take extra care with files ending with .a, they should
2095                 # be treated without that extension, and the extension
2096                 # should be added back after treatment.
2097                 $d =~ /(\.a)?$/;
2098                 my $e = $1 // "";
2099                 $d = $`.$e;
2100                 $unified_info{depends}->{$ddest}->{$d} = 1;
2101             }
2102         }
2103
2104         foreach (keys %includes) {
2105             my $dest = $_;
2106             my $ddest = cleanfile($sourced, $_, $blddir);
2107
2108             # If the destination doesn't exist in source, it can only be
2109             # a generated file in the build tree.
2110             if ($ddest eq $src_configdata || ! -f $ddest) {
2111                 $ddest = cleanfile($buildd, $_, $blddir);
2112             }
2113             foreach (@{$includes{$dest}}) {
2114                 my $is = cleandir($sourced, $_, $blddir);
2115                 my $ib = cleandir($buildd, $_, $blddir);
2116                 push @{$unified_info{includes}->{$ddest}->{source}}, $is
2117                     unless grep { $_ eq $is } @{$unified_info{includes}->{$ddest}->{source}};
2118                 push @{$unified_info{includes}->{$ddest}->{build}}, $ib
2119                     unless grep { $_ eq $ib } @{$unified_info{includes}->{$ddest}->{build}};
2120             }
2121         }
2122
2123         foreach (keys %defines) {
2124             my $dest = $_;
2125             my $ddest = cleanfile($sourced, $_, $blddir);
2126
2127             # If the destination doesn't exist in source, it can only be
2128             # a generated file in the build tree.
2129             if (! -f $ddest) {
2130                 $ddest = cleanfile($buildd, $_, $blddir);
2131                 if ($unified_info{rename}->{$ddest}) {
2132                     $ddest = $unified_info{rename}->{$ddest};
2133                 }
2134             }
2135             foreach (@{$defines{$dest}}) {
2136                 m|^([^=]*)(=.*)?$|;
2137                 die "0 length macro name not permitted\n" if $1 eq "";
2138                 die "$1 defined more than once\n"
2139                     if defined $unified_info{defines}->{$ddest}->{$1};
2140                 $unified_info{defines}->{$ddest}->{$1} = $2;
2141             }
2142         }
2143     }
2144
2145     my $ordinals_text = join(', ', sort keys %ordinals);
2146     warn <<"EOF" if $ordinals_text;
2147
2148 WARNING: ORDINALS were specified for $ordinals_text
2149 They are ignored and should be replaced with a combination of GENERATE,
2150 DEPEND and SHARED_SOURCE.
2151 EOF
2152
2153
2154     # Go through the sources of all libraries and check that the same basename
2155     # doesn't appear more than once.  Some static library archivers depend on
2156     # them being unique.
2157     {
2158         my $err = 0;
2159         foreach my $prod (keys %{$unified_info{libraries}}) {
2160             my @prod_sources =
2161                 map { keys %{$unified_info{sources}->{$_}} }
2162                 keys %{$unified_info{sources}->{$prod}};
2163             my %srccnt = ();
2164
2165             # Count how many times a given each source basename
2166             # appears for each product.
2167             foreach my $src (@prod_sources) {
2168                 $srccnt{basename $src}++;
2169             }
2170
2171             foreach my $src (keys %srccnt) {
2172                 if ((my $cnt = $srccnt{$src}) > 1) {
2173                     print STDERR "$src appears $cnt times for the product $prod\n";
2174                     $err++
2175                 }
2176             }
2177         }
2178         die if $err > 0;
2179     }
2180
2181     # Massage the result
2182
2183     # If we depend on a header file or a perl module, add an inclusion of
2184     # its directory to allow smoothe inclusion
2185     foreach my $dest (keys %{$unified_info{depends}}) {
2186         next if $dest eq "";
2187         foreach my $d (keys %{$unified_info{depends}->{$dest}}) {
2188             next unless $d =~ /\.(h|pm)$/;
2189             my $i = dirname($d);
2190             my $spot =
2191                 $d eq "configdata.pm" || defined($unified_info{generate}->{$d})
2192                 ? 'build' : 'source';
2193             push @{$unified_info{includes}->{$dest}->{$spot}}, $i
2194                 unless grep { $_ eq $i } @{$unified_info{includes}->{$dest}->{$spot}};
2195         }
2196     }
2197
2198     # Go through all intermediary files and change their names to something that
2199     # reflects what they will be built for.  Note that for some source files,
2200     # this leads to duplicate object files because they are used multiple times.
2201     # the goal is to rename all object files according to this scheme:
2202     #    {productname}-{midfix}-{origobjname}.[o|res]
2203     # the {midfix} is a keyword indicating the type of product, which is mostly
2204     # valuable for libraries since they come in two forms.
2205     #
2206     # This also reorganises the {sources} and {shared_sources} so that the
2207     # former only contains ALL object files that are supposed to end up in
2208     # static libraries and programs, while the latter contains ALL object files
2209     # that are supposed to end up in shared libraries and DSOs.
2210     # The main reason for having two different source structures is to allow
2211     # the same name to be used for the static and the shared variants of a
2212     # library.
2213     {
2214         # Take copies so we don't get interference from added stuff
2215         my %unified_copy = ();
2216         foreach (('sources', 'shared_sources')) {
2217             $unified_copy{$_} = { %{$unified_info{$_}} }
2218                 if defined($unified_info{$_});
2219             delete $unified_info{$_};
2220         }
2221         foreach my $prodtype (('programs', 'libraries', 'modules', 'scripts')) {
2222             # $intent serves multi purposes:
2223             # - give a prefix for the new object files names
2224             # - in the case of libraries, rearrange the object files so static
2225             #   libraries use the 'sources' structure exclusively, while shared
2226             #   libraries use the 'shared_sources' structure exclusively.
2227             my $intent = {
2228                 programs  => { bin    => { src => [ 'sources' ],
2229                                            dst => 'sources' } },
2230                 libraries => { lib    => { src => [ 'sources' ],
2231                                            dst => 'sources' },
2232                                shlib  => { prodselect =>
2233                                                sub { grep !/\.a$/, @_ },
2234                                            src => [ 'sources',
2235                                                     'shared_sources' ],
2236                                            dst => 'shared_sources' } },
2237                 modules   => { dso    => { src => [ 'sources' ],
2238                                            dst => 'sources' } },
2239                 scripts   => { script => { src => [ 'sources' ],
2240                                            dst => 'sources' } }
2241                } -> {$prodtype};
2242             foreach my $kind (keys %$intent) {
2243                 next if ($intent->{$kind}->{dst} eq 'shared_sources'
2244                              && $disabled{shared});
2245
2246                 my @src = @{$intent->{$kind}->{src}};
2247                 my $dst = $intent->{$kind}->{dst};
2248                 my $prodselect = $intent->{$kind}->{prodselect} // sub { @_ };
2249                 foreach my $prod ($prodselect->(keys %{$unified_info{$prodtype}})) {
2250                     # %prod_sources has all applicable objects as keys, and
2251                     # their corresponding sources as values
2252                     my %prod_sources =
2253                         map { $_ => [ keys %{$unified_copy{sources}->{$_}} ] }
2254                         map { keys %{$unified_copy{$_}->{$prod}} }
2255                         @src;
2256                     foreach (keys %prod_sources) {
2257                         # Only affect object files and resource files,
2258                         # the others simply get a new value
2259                         # (+1 instead of -1)
2260                         if ($_ =~ /\.(o|res)$/) {
2261                             (my $prodname = $prod) =~ s|\.a$||;
2262                             my $newobj =
2263                                 catfile(dirname($_),
2264                                         basename($prodname)
2265                                             . '-' . $kind
2266                                             . '-' . basename($_));
2267                             $unified_info{$dst}->{$prod}->{$newobj} = 1;
2268                             foreach my $src (@{$prod_sources{$_}}) {
2269                                 $unified_info{sources}->{$newobj}->{$src} = 1;
2270                             }
2271                             # Adjust dependencies
2272                             foreach my $deps (keys %{$unified_info{depends}->{$_}}) {
2273                                 $unified_info{depends}->{$_}->{$deps} = -1;
2274                                 $unified_info{depends}->{$newobj}->{$deps} = 1;
2275                             }
2276                             # Adjust includes
2277                             foreach my $k (('source', 'build')) {
2278                                 next unless
2279                                     defined($unified_info{includes}->{$_}->{$k});
2280                                 my @incs = @{$unified_info{includes}->{$_}->{$k}};
2281                                 $unified_info{includes}->{$newobj}->{$k} = [ @incs ];
2282                             }
2283                         } else {
2284                             $unified_info{$dst}->{$prod}->{$_} = 1;
2285                         }
2286                     }
2287                 }
2288             }
2289         }
2290     }
2291
2292     # At this point, we have a number of sources with the value -1.  They
2293     # aren't part of the local build and are probably meant for a different
2294     # platform, and can therefore be cleaned away.  That happens when making
2295     # %unified_info more efficient below.
2296
2297     ### Make unified_info a bit more efficient
2298     # One level structures
2299     foreach (("programs", "libraries", "modules", "scripts")) {
2300         $unified_info{$_} = [ sort keys %{$unified_info{$_}} ];
2301     }
2302     # Two level structures
2303     foreach my $l1 (("sources", "shared_sources", "ldadd", "depends")) {
2304         foreach my $l2 (sort keys %{$unified_info{$l1}}) {
2305             my @items =
2306                 sort
2307                 grep { $unified_info{$l1}->{$l2}->{$_} > 0 }
2308                 keys %{$unified_info{$l1}->{$l2}};
2309             if (@items) {
2310                 $unified_info{$l1}->{$l2} = [ @items ];
2311             } else {
2312                 delete $unified_info{$l1}->{$l2};
2313             }
2314         }
2315     }
2316     # Defines
2317     foreach my $dest (sort keys %{$unified_info{defines}}) {
2318         $unified_info{defines}->{$dest}
2319             = [ map { $_.$unified_info{defines}->{$dest}->{$_} }
2320                 sort keys %{$unified_info{defines}->{$dest}} ];
2321     }
2322     # Includes
2323     foreach my $dest (sort keys %{$unified_info{includes}}) {
2324         if (defined($unified_info{includes}->{$dest}->{build})) {
2325             my @source_includes = ();
2326             @source_includes = ( @{$unified_info{includes}->{$dest}->{source}} )
2327                 if defined($unified_info{includes}->{$dest}->{source});
2328             $unified_info{includes}->{$dest} =
2329                 [ @{$unified_info{includes}->{$dest}->{build}} ];
2330             foreach my $inc (@source_includes) {
2331                 push @{$unified_info{includes}->{$dest}}, $inc
2332                     unless grep { $_ eq $inc } @{$unified_info{includes}->{$dest}};
2333             }
2334         } elsif (defined($unified_info{includes}->{$dest}->{source})) {
2335             $unified_info{includes}->{$dest} =
2336                 [ @{$unified_info{includes}->{$dest}->{source}} ];
2337         } else {
2338             delete $unified_info{includes}->{$dest};
2339         }
2340     }
2341
2342     # For convenience collect information regarding directories where
2343     # files are generated, those generated files and the end product
2344     # they end up in where applicable.  Then, add build rules for those
2345     # directories
2346     my %loopinfo = ( "lib" => [ @{$unified_info{libraries}} ],
2347                      "dso" => [ @{$unified_info{modules}} ],
2348                      "bin" => [ @{$unified_info{programs}} ],
2349                      "script" => [ @{$unified_info{scripts}} ] );
2350     foreach my $type (keys %loopinfo) {
2351         foreach my $product (@{$loopinfo{$type}}) {
2352             my %dirs = ();
2353             my $pd = dirname($product);
2354
2355             foreach (@{$unified_info{sources}->{$product} // []},
2356                      @{$unified_info{shared_sources}->{$product} // []}) {
2357                 my $d = dirname($_);
2358
2359                 # We don't want to create targets for source directories
2360                 # when building out of source
2361                 next if ($config{sourcedir} ne $config{builddir}
2362                              && $d =~ m|^\Q$config{sourcedir}\E|);
2363                 # We already have a "test" target, and the current directory
2364                 # is just silly to make a target for
2365                 next if $d eq "test" || $d eq ".";
2366
2367                 $dirs{$d} = 1;
2368                 push @{$unified_info{dirinfo}->{$d}->{deps}}, $_
2369                     if $d ne $pd;
2370             }
2371             foreach (keys %dirs) {
2372                 push @{$unified_info{dirinfo}->{$_}->{products}->{$type}},
2373                     $product;
2374             }
2375         }
2376     }
2377 }
2378
2379 # For the schemes that need it, we provide the old *_obj configs
2380 # from the *_asm_obj ones
2381 foreach (grep /_(asm|aux)_src$/, keys %target) {
2382     my $src = $_;
2383     (my $obj = $_) =~ s/_(asm|aux)_src$/_obj/;
2384     $target{$obj} = $target{$src};
2385     $target{$obj} =~ s/\.[csS]\b/.o/g; # C and assembler
2386     $target{$obj} =~ s/\.(cc|cpp)\b/_cc.o/g; # C++
2387 }
2388
2389 # Write down our configuration where it fits #########################
2390
2391 print "Creating configdata.pm\n";
2392 open(OUT,">configdata.pm") || die "unable to create configdata.pm: $!\n";
2393 print OUT <<"EOF";
2394 #! $config{HASHBANGPERL}
2395
2396 package configdata;
2397
2398 use strict;
2399 use warnings;
2400
2401 use Exporter;
2402 #use vars qw(\@ISA \@EXPORT);
2403 our \@ISA = qw(Exporter);
2404 our \@EXPORT = qw(\%config \%target \%disabled \%withargs \%unified_info \@disablables \@disablables_int);
2405
2406 EOF
2407 print OUT "our %config = (\n";
2408 foreach (sort keys %config) {
2409     if (ref($config{$_}) eq "ARRAY") {
2410         print OUT "  ", $_, " => [ ", join(", ",
2411                                            map { quotify("perl", $_) }
2412                                            @{$config{$_}}), " ],\n";
2413     } elsif (ref($config{$_}) eq "HASH") {
2414         print OUT "  ", $_, " => {";
2415         if (scalar keys %{$config{$_}} > 0) {
2416             print OUT "\n";
2417             foreach my $key (sort keys %{$config{$_}}) {
2418                 print OUT "      ",
2419                     join(" => ",
2420                          quotify("perl", $key),
2421                          defined $config{$_}->{$key}
2422                              ? quotify("perl", $config{$_}->{$key})
2423                              : "undef");
2424                 print OUT ",\n";
2425             }
2426             print OUT "  ";
2427         }
2428         print OUT "},\n";
2429     } else {
2430         print OUT "  ", $_, " => ", quotify("perl", $config{$_}), ",\n"
2431     }
2432 }
2433 print OUT <<"EOF";
2434 );
2435
2436 EOF
2437 print OUT "our %target = (\n";
2438 foreach (sort keys %target) {
2439     if (ref($target{$_}) eq "ARRAY") {
2440         print OUT "  ", $_, " => [ ", join(", ",
2441                                            map { quotify("perl", $_) }
2442                                            @{$target{$_}}), " ],\n";
2443     } else {
2444         print OUT "  ", $_, " => ", quotify("perl", $target{$_}), ",\n"
2445     }
2446 }
2447 print OUT <<"EOF";
2448 );
2449
2450 EOF
2451 print OUT "our \%available_protocols = (\n";
2452 print OUT "  tls => [ ", join(", ", map { quotify("perl", $_) } @tls), " ],\n";
2453 print OUT "  dtls => [ ", join(", ", map { quotify("perl", $_) } @dtls), " ],\n";
2454 print OUT <<"EOF";
2455 );
2456
2457 EOF
2458 print OUT "our \@disablables = (\n";
2459 foreach (@disablables) {
2460     print OUT "  ", quotify("perl", $_), ",\n";
2461 }
2462 print OUT <<"EOF";
2463 );
2464
2465 EOF
2466 print OUT "# The following come from Configure's @disablables_int\n";
2467 print OUT "our \@disablables_int = (\n";
2468 foreach (@disablables_int) {
2469     print OUT "  ", quotify("perl", $_), ",\n";
2470 }
2471 print OUT <<"EOF";
2472 );
2473
2474 EOF
2475 print OUT "our \%disabled = (\n";
2476 foreach (sort keys %disabled) {
2477     print OUT "  ", quotify("perl", $_), " => ", quotify("perl", $disabled{$_}), ",\n";
2478 }
2479 print OUT <<"EOF";
2480 );
2481
2482 EOF
2483 print OUT "our %withargs = (\n";
2484 foreach (sort keys %withargs) {
2485     if (ref($withargs{$_}) eq "ARRAY") {
2486         print OUT "  ", $_, " => [ ", join(", ",
2487                                            map { quotify("perl", $_) }
2488                                            @{$withargs{$_}}), " ],\n";
2489     } else {
2490         print OUT "  ", $_, " => ", quotify("perl", $withargs{$_}), ",\n"
2491     }
2492 }
2493 print OUT <<"EOF";
2494 );
2495
2496 EOF
2497 if ($builder eq "unified") {
2498     my $recurse;
2499     $recurse = sub {
2500         my $indent = shift;
2501         foreach (@_) {
2502             if (ref $_ eq "ARRAY") {
2503                 print OUT " "x$indent, "[\n";
2504                 foreach (@$_) {
2505                     $recurse->($indent + 4, $_);
2506                 }
2507                 print OUT " "x$indent, "],\n";
2508             } elsif (ref $_ eq "HASH") {
2509                 my %h = %$_;
2510                 print OUT " "x$indent, "{\n";
2511                 foreach (sort keys %h) {
2512                     if (ref $h{$_} eq "") {
2513                         print OUT " "x($indent + 4), quotify("perl", $_), " => ", quotify("perl", $h{$_}), ",\n";
2514                     } else {
2515                         print OUT " "x($indent + 4), quotify("perl", $_), " =>\n";
2516                         $recurse->($indent + 8, $h{$_});
2517                     }
2518                 }
2519                 print OUT " "x$indent, "},\n";
2520             } else {
2521                 print OUT " "x$indent, quotify("perl", $_), ",\n";
2522             }
2523         }
2524     };
2525     print OUT "our %unified_info = (\n";
2526     foreach (sort keys %unified_info) {
2527         if (ref $unified_info{$_} eq "") {
2528             print OUT " "x4, quotify("perl", $_), " => ", quotify("perl", $unified_info{$_}), ",\n";
2529         } else {
2530             print OUT " "x4, quotify("perl", $_), " =>\n";
2531             $recurse->(8, $unified_info{$_});
2532         }
2533     }
2534     print OUT <<"EOF";
2535 );
2536
2537 EOF
2538 }
2539 print OUT
2540     "# The following data is only used when this files is use as a script\n";
2541 print OUT "my \@makevars = (\n";
2542 foreach (sort keys %user) {
2543     print OUT "    '",$_,"',\n";
2544 }
2545 print OUT ");\n";
2546 print OUT "my \%disabled_info = (\n";
2547 foreach my $what (sort keys %disabled_info) {
2548     print OUT "    '$what' => {\n";
2549     foreach my $info (sort keys %{$disabled_info{$what}}) {
2550         if (ref $disabled_info{$what}->{$info} eq 'ARRAY') {
2551             print OUT "        $info => [ ",
2552                 join(', ', map { "'$_'" } @{$disabled_info{$what}->{$info}}),
2553                 " ],\n";
2554         } else {
2555             print OUT "        $info => '", $disabled_info{$what}->{$info},
2556                 "',\n";
2557         }
2558     }
2559     print OUT "    },\n";
2560 }
2561 print OUT ");\n";
2562 print OUT 'my @user_crossable = qw( ', join (' ', @user_crossable), " );\n";
2563 print OUT << 'EOF';
2564 # If run directly, we can give some answers, and even reconfigure
2565 unless (caller) {
2566     use Getopt::Long;
2567     use File::Spec::Functions;
2568     use File::Basename;
2569     use Pod::Usage;
2570
2571     my $here = dirname($0);
2572
2573     my $dump = undef;
2574     my $cmdline = undef;
2575     my $options = undef;
2576     my $target = undef;
2577     my $envvars = undef;
2578     my $makevars = undef;
2579     my $buildparams = undef;
2580     my $reconf = undef;
2581     my $verbose = undef;
2582     my $help = undef;
2583     my $man = undef;
2584     GetOptions('dump|d'                 => \$dump,
2585                'command-line|c'         => \$cmdline,
2586                'options|o'              => \$options,
2587                'target|t'               => \$target,
2588                'environment|e'          => \$envvars,
2589                'make-variables|m'       => \$makevars,
2590                'build-parameters|b'     => \$buildparams,
2591                'reconfigure|reconf|r'   => \$reconf,
2592                'verbose|v'              => \$verbose,
2593                'help'                   => \$help,
2594                'man'                    => \$man)
2595         or die "Errors in command line arguments\n";
2596
2597     unless ($dump || $cmdline || $options || $target || $envvars || $makevars
2598             || $buildparams || $reconf || $verbose || $help || $man) {
2599         print STDERR <<"_____";
2600 You must give at least one option.
2601 For more information, do '$0 --help'
2602 _____
2603         exit(2);
2604     }
2605
2606     if ($help) {
2607         pod2usage(-exitval => 0,
2608                   -verbose => 1);
2609     }
2610     if ($man) {
2611         pod2usage(-exitval => 0,
2612                   -verbose => 2);
2613     }
2614     if ($dump || $cmdline) {
2615         print "\nCommand line (with current working directory = $here):\n\n";
2616         print '    ',join(' ',
2617                           $config{PERL},
2618                           catfile($config{sourcedir}, 'Configure'),
2619                           @{$config{perlargv}}), "\n";
2620         print "\nPerl information:\n\n";
2621         print '    ',$config{perl_cmd},"\n";
2622         print '    ',$config{perl_version},' for ',$config{perl_archname},"\n";
2623     }
2624     if ($dump || $options) {
2625         my $longest = 0;
2626         my $longest2 = 0;
2627         foreach my $what (@disablables) {
2628             $longest = length($what) if $longest < length($what);
2629             $longest2 = length($disabled{$what})
2630                 if $disabled{$what} && $longest2 < length($disabled{$what});
2631         }
2632         print "\nEnabled features:\n\n";
2633         foreach my $what (@disablables) {
2634             print "    $what\n" unless $disabled{$what};
2635         }
2636         print "\nDisabled features:\n\n";
2637         foreach my $what (@disablables) {
2638             if ($disabled{$what}) {
2639                 print "    $what", ' ' x ($longest - length($what) + 1),
2640                     "[$disabled{$what}]", ' ' x ($longest2 - length($disabled{$what}) + 1);
2641                 print $disabled_info{$what}->{macro}
2642                     if $disabled_info{$what}->{macro};
2643                 print ' (skip ',
2644                     join(', ', @{$disabled_info{$what}->{skipped}}),
2645                     ')'
2646                     if $disabled_info{$what}->{skipped};
2647                 print "\n";
2648             }
2649         }
2650     }
2651     if ($dump || $target) {
2652         print "\nConfig target attributes:\n\n";
2653         foreach (sort keys %target) {
2654             next if $_ =~ m|^_| || $_ eq 'template';
2655             my $quotify = sub {
2656                 map { (my $x = $_) =~ s|([\\\$\@"])|\\$1|g; "\"$x\""} @_;
2657             };
2658             print '    ', $_, ' => ';
2659             if (ref($target{$_}) eq "ARRAY") {
2660                 print '[ ', join(', ', $quotify->(@{$target{$_}})), " ],\n";
2661             } else {
2662                 print $quotify->($target{$_}), ",\n"
2663             }
2664         }
2665     }
2666     if ($dump || $envvars) {
2667         print "\nRecorded environment:\n\n";
2668         foreach (sort keys %{$config{perlenv}}) {
2669             print '    ',$_,' = ',($config{perlenv}->{$_} || ''),"\n";
2670         }
2671     }
2672     if ($dump || $makevars) {
2673         print "\nMakevars:\n\n";
2674         foreach my $var (@makevars) {
2675             my $prefix = '';
2676             $prefix = $config{CROSS_COMPILE}
2677                 if grep { $var eq $_ } @user_crossable;
2678             $prefix //= '';
2679             print '    ',$var,' ' x (16 - length $var),'= ',
2680                 (ref $config{$var} eq 'ARRAY'
2681                  ? join(' ', @{$config{$var}})
2682                  : $prefix.$config{$var}),
2683                 "\n"
2684                 if defined $config{$var};
2685         }
2686
2687         my @buildfile = ($config{builddir}, $config{build_file});
2688         unshift @buildfile, $here
2689             unless file_name_is_absolute($config{builddir});
2690         my $buildfile = canonpath(catdir(@buildfile));
2691         print <<"_____";
2692
2693 NOTE: These variables only represent the configuration view.  The build file
2694 template may have processed these variables further, please have a look at the
2695 build file for more exact data:
2696     $buildfile
2697 _____
2698     }
2699     if ($dump || $buildparams) {
2700         my @buildfile = ($config{builddir}, $config{build_file});
2701         unshift @buildfile, $here
2702             unless file_name_is_absolute($config{builddir});
2703         print "\nbuild file:\n\n";
2704         print "    ", canonpath(catfile(@buildfile)),"\n";
2705
2706         print "\nbuild file templates:\n\n";
2707         foreach (@{$config{build_file_templates}}) {
2708             my @tmpl = ($_);
2709             unshift @tmpl, $here
2710                 unless file_name_is_absolute($config{sourcedir});
2711             print '    ',canonpath(catfile(@tmpl)),"\n";
2712         }
2713     }
2714     if ($reconf) {
2715         if ($verbose) {
2716             print 'Reconfiguring with: ', join(' ',@{$config{perlargv}}), "\n";
2717             foreach (sort keys %{$config{perlenv}}) {
2718                 print '    ',$_,' = ',($config{perlenv}->{$_} || ""),"\n";
2719             }
2720         }
2721
2722         chdir $here;
2723         exec $^X,catfile($config{sourcedir}, 'Configure'),'reconf';
2724     }
2725 }
2726
2727 1;
2728
2729 __END__
2730
2731 =head1 NAME
2732
2733 configdata.pm - configuration data for OpenSSL builds
2734
2735 =head1 SYNOPSIS
2736
2737 Interactive:
2738
2739   perl configdata.pm [options]
2740
2741 As data bank module:
2742
2743   use configdata;
2744
2745 =head1 DESCRIPTION
2746
2747 This module can be used in two modes, interactively and as a module containing
2748 all the data recorded by OpenSSL's Configure script.
2749
2750 When used interactively, simply run it as any perl script, with at least one
2751 option, and you will get the information you ask for.  See L</OPTIONS> below.
2752
2753 When loaded as a module, you get a few databanks with useful information to
2754 perform build related tasks.  The databanks are:
2755
2756     %config             Configured things.
2757     %target             The OpenSSL config target with all inheritances
2758                         resolved.
2759     %disabled           The features that are disabled.
2760     @disablables        The list of features that can be disabled.
2761     %withargs           All data given through --with-THING options.
2762     %unified_info       All information that was computed from the build.info
2763                         files.
2764
2765 =head1 OPTIONS
2766
2767 =over 4
2768
2769 =item B<--help>
2770
2771 Print a brief help message and exit.
2772
2773 =item B<--man>
2774
2775 Print the manual page and exit.
2776
2777 =item B<--dump> | B<-d>
2778
2779 Print all relevant configuration data.  This is equivalent to B<--command-line>
2780 B<--options> B<--target> B<--environment> B<--make-variables>
2781 B<--build-parameters>.
2782
2783 =item B<--command-line> | B<-c>
2784
2785 Print the current configuration command line.
2786
2787 =item B<--options> | B<-o>
2788
2789 Print the features, both enabled and disabled, and display defined macro and
2790 skipped directories where applicable.
2791
2792 =item B<--target> | B<-t>
2793
2794 Print the config attributes for this config target.
2795
2796 =item B<--environment> | B<-e>
2797
2798 Print the environment variables and their values at the time of configuration.
2799
2800 =item B<--make-variables> | B<-m>
2801
2802 Print the main make variables generated in the current configuration
2803
2804 =item B<--build-parameters> | B<-b>
2805
2806 Print the build parameters, i.e. build file and build file templates.
2807
2808 =item B<--reconfigure> | B<--reconf> | B<-r>
2809
2810 Redo the configuration.
2811
2812 =item B<--verbose> | B<-v>
2813
2814 Verbose output.
2815
2816 =back
2817
2818 =cut
2819
2820 EOF
2821 close(OUT);
2822 if ($builder_platform eq 'unix') {
2823     my $mode = (0755 & ~umask);
2824     chmod $mode, 'configdata.pm'
2825         or warn sprintf("WARNING: Couldn't change mode for 'configdata.pm' to 0%03o: %s\n",$mode,$!);
2826 }
2827
2828 my %builders = (
2829     unified => sub {
2830         print 'Creating ',$target{build_file},"\n";
2831         run_dofile(catfile($blddir, $target{build_file}),
2832                    @{$config{build_file_templates}});
2833     },
2834     );
2835
2836 $builders{$builder}->($builder_platform, @builder_opts);
2837
2838 $SIG{__DIE__} = $orig_death_handler;
2839
2840 print <<"EOF" if ($disabled{threads} eq "unavailable");
2841
2842 The library could not be configured for supporting multi-threaded
2843 applications as the compiler options required on this system are not known.
2844 See file INSTALL for details if you need multi-threading.
2845 EOF
2846
2847 print <<"EOF" if ($no_shared_warn);
2848
2849 The options 'shared', 'pic' and 'dynamic-engine' aren't supported on this
2850 platform, so we will pretend you gave the option 'no-pic', which also disables
2851 'shared' and 'dynamic-engine'.  If you know how to implement shared libraries
2852 or position independent code, please let us know (but please first make sure
2853 you have tried with a current version of OpenSSL).
2854 EOF
2855
2856 print <<"EOF";
2857
2858 **********************************************************************
2859 ***                                                                ***
2860 ***   OpenSSL has been successfully configured                     ***
2861 ***                                                                ***
2862 ***   If you encounter a problem while building, please open an    ***
2863 ***   issue on GitHub <https://github.com/openssl/openssl/issues>  ***
2864 ***   and include the output from the following command:           ***
2865 ***                                                                ***
2866 ***       perl configdata.pm --dump                                ***
2867 ***                                                                ***
2868 ***   (If you are new to OpenSSL, you might want to consult the    ***
2869 ***   'Troubleshooting' section in the INSTALL file first)         ***
2870 ***                                                                ***
2871 **********************************************************************
2872 EOF
2873
2874 exit(0);
2875
2876 ######################################################################
2877 #
2878 # Helpers and utility functions
2879 #
2880
2881 # Death handler, to print a helpful message in case of failure #######
2882 #
2883 sub death_handler {
2884     die @_ if $^S;              # To prevent the added message in eval blocks
2885     my $build_file = $target{build_file} // "build file";
2886     my @message = ( <<"_____", @_ );
2887
2888 Failure!  $build_file wasn't produced.
2889 Please read INSTALL and associated NOTES files.  You may also have to look over
2890 your available compiler tool chain or change your configuration.
2891
2892 _____
2893
2894     # Dying is terminal, so it's ok to reset the signal handler here.
2895     $SIG{__DIE__} = $orig_death_handler;
2896     die @message;
2897 }
2898
2899 # Configuration file reading #########################################
2900
2901 # Note: All of the helper functions are for lazy evaluation.  They all
2902 # return a CODE ref, which will return the intended value when evaluated.
2903 # Thus, whenever there's mention of a returned value, it's about that
2904 # intended value.
2905
2906 # Helper function to implement conditional inheritance depending on the
2907 # value of $disabled{asm}.  Used in inherit_from values as follows:
2908 #
2909 #      inherit_from => [ "template", asm("asm_tmpl") ]
2910 #
2911 sub asm {
2912     my @x = @_;
2913     sub {
2914         $disabled{asm} ? () : @x;
2915     }
2916 }
2917
2918 # Helper function to implement conditional value variants, with a default
2919 # plus additional values based on the value of $config{build_type}.
2920 # Arguments are given in hash table form:
2921 #
2922 #       picker(default => "Basic string: ",
2923 #              debug   => "debug",
2924 #              release => "release")
2925 #
2926 # When configuring with --debug, the resulting string will be
2927 # "Basic string: debug", and when not, it will be "Basic string: release"
2928 #
2929 # This can be used to create variants of sets of flags according to the
2930 # build type:
2931 #
2932 #       cflags => picker(default => "-Wall",
2933 #                        debug   => "-g -O0",
2934 #                        release => "-O3")
2935 #
2936 sub picker {
2937     my %opts = @_;
2938     return sub { add($opts{default} || (),
2939                      $opts{$config{build_type}} || ())->(); }
2940 }
2941
2942 # Helper function to combine several values of different types into one.
2943 # This is useful if you want to combine a string with the result of a
2944 # lazy function, such as:
2945 #
2946 #       cflags => combine("-Wall", sub { $disabled{zlib} ? () : "-DZLIB" })
2947 #
2948 sub combine {
2949     my @stuff = @_;
2950     return sub { add(@stuff)->(); }
2951 }
2952
2953 # Helper function to implement conditional values depending on the value
2954 # of $disabled{threads}.  Can be used as follows:
2955 #
2956 #       cflags => combine("-Wall", threads("-pthread"))
2957 #
2958 sub threads {
2959     my @flags = @_;
2960     return sub { add($disabled{threads} ? () : @flags)->(); }
2961 }
2962
2963 sub shared {
2964     my @flags = @_;
2965     return sub { add($disabled{shared} ? () : @flags)->(); }
2966 }
2967
2968 our $add_called = 0;
2969 # Helper function to implement adding values to already existing configuration
2970 # values.  It handles elements that are ARRAYs, CODEs and scalars
2971 sub _add {
2972     my $separator = shift;
2973
2974     # If there's any ARRAY in the collection of values OR the separator
2975     # is undef, we will return an ARRAY of combined values, otherwise a
2976     # string of joined values with $separator as the separator.
2977     my $found_array = !defined($separator);
2978
2979     my @values =
2980         map {
2981             my $res = $_;
2982             while (ref($res) eq "CODE") {
2983                 $res = $res->();
2984             }
2985             if (defined($res)) {
2986                 if (ref($res) eq "ARRAY") {
2987                     $found_array = 1;
2988                     @$res;
2989                 } else {
2990                     $res;
2991                 }
2992             } else {
2993                 ();
2994             }
2995     } (@_);
2996
2997     $add_called = 1;
2998
2999     if ($found_array) {
3000         [ @values ];
3001     } else {
3002         join($separator, grep { defined($_) && $_ ne "" } @values);
3003     }
3004 }
3005 sub add_before {
3006     my $separator = " ";
3007     if (ref($_[$#_]) eq "HASH") {
3008         my $opts = pop;
3009         $separator = $opts->{separator};
3010     }
3011     my @x = @_;
3012     sub { _add($separator, @x, @_) };
3013 }
3014 sub add {
3015     my $separator = " ";
3016     if (ref($_[$#_]) eq "HASH") {
3017         my $opts = pop;
3018         $separator = $opts->{separator};
3019     }
3020     my @x = @_;
3021     sub { _add($separator, @_, @x) };
3022 }
3023
3024 sub read_eval_file {
3025     my $fname = shift;
3026     my $content;
3027     my @result;
3028
3029     open F, "< $fname" or die "Can't open '$fname': $!\n";
3030     {
3031         undef local $/;
3032         $content = <F>;
3033     }
3034     close F;
3035     {
3036         local $@;
3037
3038         @result = ( eval $content );
3039         warn $@ if $@;
3040     }
3041     return wantarray ? @result : $result[0];
3042 }
3043
3044 # configuration reader, evaluates the input file as a perl script and expects
3045 # it to fill %targets with target configurations.  Those are then added to
3046 # %table.
3047 sub read_config {
3048     my $fname = shift;
3049     my %targets;
3050
3051     {
3052         # Protect certain tables from tampering
3053         local %table = ();
3054
3055         %targets = read_eval_file($fname);
3056     }
3057     my %preexisting = ();
3058     foreach (sort keys %targets) {
3059         $preexisting{$_} = 1 if $table{$_};
3060     }
3061     die <<"EOF",
3062 The following config targets from $fname
3063 shadow pre-existing config targets with the same name:
3064 EOF
3065         map { "  $_\n" } sort keys %preexisting
3066         if %preexisting;
3067
3068
3069     # For each target, check that it's configured with a hash table.
3070     foreach (keys %targets) {
3071         if (ref($targets{$_}) ne "HASH") {
3072             if (ref($targets{$_}) eq "") {
3073                 warn "Deprecated target configuration for $_, ignoring...\n";
3074             } else {
3075                 warn "Misconfigured target configuration for $_ (should be a hash table), ignoring...\n";
3076             }
3077             delete $targets{$_};
3078         } else {
3079             $targets{$_}->{_conf_fname_int} = add([ $fname ]);
3080         }
3081     }
3082
3083     %table = (%table, %targets);
3084
3085 }
3086
3087 # configuration resolver.  Will only resolve all the lazy evaluation
3088 # codeblocks for the chosen target and all those it inherits from,
3089 # recursively
3090 sub resolve_config {
3091     my $target = shift;
3092     my @breadcrumbs = @_;
3093
3094 #    my $extra_checks = defined($ENV{CONFIGURE_EXTRA_CHECKS});
3095
3096     if (grep { $_ eq $target } @breadcrumbs) {
3097         die "inherit_from loop!  target backtrace:\n  "
3098             ,$target,"\n  ",join("\n  ", @breadcrumbs),"\n";
3099     }
3100
3101     if (!defined($table{$target})) {
3102         warn "Warning! target $target doesn't exist!\n";
3103         return ();
3104     }
3105     # Recurse through all inheritances.  They will be resolved on the
3106     # fly, so when this operation is done, they will all just be a
3107     # bunch of attributes with string values.
3108     # What we get here, though, are keys with references to lists of
3109     # the combined values of them all.  We will deal with lists after
3110     # this stage is done.
3111     my %combined_inheritance = ();
3112     if ($table{$target}->{inherit_from}) {
3113         my @inherit_from =
3114             map { ref($_) eq "CODE" ? $_->() : $_ } @{$table{$target}->{inherit_from}};
3115         foreach (@inherit_from) {
3116             my %inherited_config = resolve_config($_, $target, @breadcrumbs);
3117
3118             # 'template' is a marker that's considered private to
3119             # the config that had it.
3120             delete $inherited_config{template};
3121
3122             foreach (keys %inherited_config) {
3123                 if (!$combined_inheritance{$_}) {
3124                     $combined_inheritance{$_} = [];
3125                 }
3126                 push @{$combined_inheritance{$_}}, $inherited_config{$_};
3127             }
3128         }
3129     }
3130
3131     # We won't need inherit_from in this target any more, since we've
3132     # resolved all the inheritances that lead to this
3133     delete $table{$target}->{inherit_from};
3134
3135     # Now is the time to deal with those lists.  Here's the place to
3136     # decide what shall be done with those lists, all based on the
3137     # values of the target we're currently dealing with.
3138     # - If a value is a coderef, it will be executed with the list of
3139     #   inherited values as arguments.
3140     # - If the corresponding key doesn't have a value at all or is the
3141     #   empty string, the inherited value list will be run through the
3142     #   default combiner (below), and the result becomes this target's
3143     #   value.
3144     # - Otherwise, this target's value is assumed to be a string that
3145     #   will simply override the inherited list of values.
3146     my $default_combiner = add();
3147
3148     my %all_keys =
3149         map { $_ => 1 } (keys %combined_inheritance,
3150                          keys %{$table{$target}});
3151
3152     sub process_values {
3153         my $object    = shift;
3154         my $inherited = shift;  # Always a [ list ]
3155         my $target    = shift;
3156         my $entry     = shift;
3157
3158         $add_called = 0;
3159
3160         while(ref($object) eq "CODE") {
3161             $object = $object->(@$inherited);
3162         }
3163         if (!defined($object)) {
3164             return ();
3165         }
3166         elsif (ref($object) eq "ARRAY") {
3167             local $add_called;  # To make sure recursive calls don't affect it
3168             return [ map { process_values($_, $inherited, $target, $entry) }
3169                      @$object ];
3170         } elsif (ref($object) eq "") {
3171             return $object;
3172         } else {
3173             die "cannot handle reference type ",ref($object)
3174                 ," found in target ",$target," -> ",$entry,"\n";
3175         }
3176     }
3177
3178     foreach (sort keys %all_keys) {
3179         my $previous = $combined_inheritance{$_};
3180
3181         # Current target doesn't have a value for the current key?
3182         # Assign it the default combiner, the rest of this loop body
3183         # will handle it just like any other coderef.
3184         if (!exists $table{$target}->{$_}) {
3185             $table{$target}->{$_} = $default_combiner;
3186         }
3187
3188         $table{$target}->{$_} = process_values($table{$target}->{$_},
3189                                                $combined_inheritance{$_},
3190                                                $target, $_);
3191         unless(defined($table{$target}->{$_})) {
3192             delete $table{$target}->{$_};
3193         }
3194 #        if ($extra_checks &&
3195 #            $previous && !($add_called ||  $previous ~~ $table{$target}->{$_})) {
3196 #            warn "$_ got replaced in $target\n";
3197 #        }
3198     }
3199
3200     # Finally done, return the result.
3201     return %{$table{$target}};
3202 }
3203
3204 sub usage
3205         {
3206         print STDERR $usage;
3207         print STDERR "\npick os/compiler from:\n";
3208         my $j=0;
3209         my $i;
3210         my $k=0;
3211         foreach $i (sort keys %table)
3212                 {
3213                 next if $table{$i}->{template};
3214                 next if $i =~ /^debug/;
3215                 $k += length($i) + 1;
3216                 if ($k > 78)
3217                         {
3218                         print STDERR "\n";
3219                         $k=length($i);
3220                         }
3221                 print STDERR $i . " ";
3222                 }
3223         foreach $i (sort keys %table)
3224                 {
3225                 next if $table{$i}->{template};
3226                 next if $i !~ /^debug/;
3227                 $k += length($i) + 1;
3228                 if ($k > 78)
3229                         {
3230                         print STDERR "\n";
3231                         $k=length($i);
3232                         }
3233                 print STDERR $i . " ";
3234                 }
3235         print STDERR "\n\nNOTE: If in doubt, on Unix-ish systems use './config'.\n";
3236         exit(1);
3237         }
3238
3239 sub run_dofile
3240 {
3241     my $out = shift;
3242     my @templates = @_;
3243
3244     unlink $out || warn "Can't remove $out, $!"
3245         if -f $out;
3246     foreach (@templates) {
3247         die "Can't open $_, $!" unless -f $_;
3248     }
3249     my $perlcmd = (quotify("maybeshell", $config{PERL}))[0];
3250     my $cmd = "$perlcmd \"-I.\" \"-Mconfigdata\" \"$dofile\" -o\"Configure\" \"".join("\" \"",@templates)."\" > \"$out.new\"";
3251     #print STDERR "DEBUG[run_dofile]: \$cmd = $cmd\n";
3252     system($cmd);
3253     exit 1 if $? != 0;
3254     rename("$out.new", $out) || die "Can't rename $out.new, $!";
3255 }
3256
3257 sub compiler_predefined {
3258     state %predefined;
3259     my $cc = shift;
3260
3261     return () if $^O eq 'VMS';
3262
3263     die 'compiler_predefined called without a compiler command'
3264         unless $cc;
3265
3266     if (! $predefined{$cc}) {
3267
3268         $predefined{$cc} = {};
3269
3270         # collect compiler pre-defines from gcc or gcc-alike...
3271         open(PIPE, "$cc -dM -E -x c /dev/null 2>&1 |");
3272         while (my $l = <PIPE>) {
3273             $l =~ m/^#define\s+(\w+(?:\(\w+\))?)(?:\s+(.+))?/ or last;
3274             $predefined{$cc}->{$1} = $2 // '';
3275         }
3276         close(PIPE);
3277     }
3278
3279     return %{$predefined{$cc}};
3280 }
3281
3282 sub which
3283 {
3284     my ($name)=@_;
3285
3286     if (eval { require IPC::Cmd; 1; }) {
3287         IPC::Cmd->import();
3288         return scalar IPC::Cmd::can_run($name);
3289     } else {
3290         # if there is $directories component in splitpath,
3291         # then it's not something to test with $PATH...
3292         return $name if (File::Spec->splitpath($name))[1];
3293
3294         foreach (File::Spec->path()) {
3295             my $fullpath = catfile($_, "$name$target{exe_extension}");
3296             if (-f $fullpath and -x $fullpath) {
3297                 return $fullpath;
3298             }
3299         }
3300     }
3301 }
3302
3303 sub env
3304 {
3305     my $name = shift;
3306     my %opts = @_;
3307
3308     unless ($opts{cacheonly}) {
3309         # Note that if $ENV{$name} doesn't exist or is undefined,
3310         # $config{perlenv}->{$name} will be created with the value
3311         # undef.  This is intentional.
3312
3313         $config{perlenv}->{$name} = $ENV{$name}
3314             if ! exists $config{perlenv}->{$name};
3315     }
3316     return $config{perlenv}->{$name};
3317 }
3318
3319 # Configuration printer ##############################################
3320
3321 sub print_table_entry
3322 {
3323     local $now_printing = shift;
3324     my %target = resolve_config($now_printing);
3325     my $type = shift;
3326
3327     # Don't print the templates
3328     return if $target{template};
3329
3330     my @sequence = (
3331         "sys_id",
3332         "cpp",
3333         "cppflags",
3334         "defines",
3335         "includes",
3336         "cc",
3337         "cflags",
3338         "unistd",
3339         "ld",
3340         "lflags",
3341         "loutflag",
3342         "ex_libs",
3343         "bn_ops",
3344         "padlock_asm_src",
3345         "chacha_asm_src",
3346         "poly1035_asm_src",
3347         "thread_scheme",
3348         "perlasm_scheme",
3349         "dso_scheme",
3350         "shared_target",
3351         "shared_cflag",
3352         "shared_defines",
3353         "shared_ldflag",
3354         "shared_rcflag",
3355         "shared_extension",
3356         "dso_extension",
3357         "obj_extension",
3358         "exe_extension",
3359         "ranlib",
3360         "ar",
3361         "arflags",
3362         "aroutflag",
3363         "rc",
3364         "rcflags",
3365         "rcoutflag",
3366         "mt",
3367         "mtflags",
3368         "mtinflag",
3369         "mtoutflag",
3370         "multilib",
3371         "build_scheme",
3372         );
3373
3374     if ($type eq "TABLE") {
3375         print "\n";
3376         print "*** $now_printing\n";
3377         foreach (@sequence) {
3378             if (ref($target{$_}) eq "ARRAY") {
3379                 printf "\$%-12s = %s\n", $_, join(" ", @{$target{$_}});
3380             } else {
3381                 printf "\$%-12s = %s\n", $_, $target{$_};
3382             }
3383         }
3384     } elsif ($type eq "HASH") {
3385         my $largest =
3386             length((sort { length($a) <=> length($b) } @sequence)[-1]);
3387         print "    '$now_printing' => {\n";
3388         foreach (@sequence) {
3389             if ($target{$_}) {
3390                 if (ref($target{$_}) eq "ARRAY") {
3391                     print "      '",$_,"'"," " x ($largest - length($_))," => [ ",join(", ", map { "'$_'" } @{$target{$_}})," ],\n";
3392                 } else {
3393                     print "      '",$_,"'"," " x ($largest - length($_))," => '",$target{$_},"',\n";
3394                 }
3395             }
3396         }
3397         print "    },\n";
3398     }
3399 }
3400
3401 # Utility routines ###################################################
3402
3403 # On VMS, if the given file is a logical name, File::Spec::Functions
3404 # will consider it an absolute path.  There are cases when we want a
3405 # purely syntactic check without checking the environment.
3406 sub isabsolute {
3407     my $file = shift;
3408
3409     # On non-platforms, we just use file_name_is_absolute().
3410     return file_name_is_absolute($file) unless $^O eq "VMS";
3411
3412     # If the file spec includes a device or a directory spec,
3413     # file_name_is_absolute() is perfectly safe.
3414     return file_name_is_absolute($file) if $file =~ m|[:\[]|;
3415
3416     # Here, we know the given file spec isn't absolute
3417     return 0;
3418 }
3419
3420 # Makes a directory absolute and cleans out /../ in paths like foo/../bar
3421 # On some platforms, this uses rel2abs(), while on others, realpath() is used.
3422 # realpath() requires that at least all path components except the last is an
3423 # existing directory.  On VMS, the last component of the directory spec must
3424 # exist.
3425 sub absolutedir {
3426     my $dir = shift;
3427
3428     # realpath() is quite buggy on VMS.  It uses LIB$FID_TO_NAME, which
3429     # will return the volume name for the device, no matter what.  Also,
3430     # it will return an incorrect directory spec if the argument is a
3431     # directory that doesn't exist.
3432     if ($^O eq "VMS") {
3433         return rel2abs($dir);
3434     }
3435
3436     # We use realpath() on Unix, since no other will properly clean out
3437     # a directory spec.
3438     use Cwd qw/realpath/;
3439
3440     return realpath($dir);
3441 }
3442
3443 sub quotify {
3444     my %processors = (
3445         perl    => sub { my $x = shift;
3446                          $x =~ s/([\\\$\@"])/\\$1/g;
3447                          return '"'.$x.'"'; },
3448         maybeshell => sub { my $x = shift;
3449                             (my $y = $x) =~ s/([\\\"])/\\$1/g;
3450                             if ($x ne $y || $x =~ m|\s|) {
3451                                 return '"'.$y.'"';
3452                             } else {
3453                                 return $x;
3454                             }
3455                         },
3456         );
3457     my $for = shift;
3458     my $processor =
3459         defined($processors{$for}) ? $processors{$for} : sub { shift; };
3460
3461     return map { $processor->($_); } @_;
3462 }
3463
3464 # collect_from_file($filename, $line_concat_cond_re, $line_concat)
3465 # $filename is a file name to read from
3466 # $line_concat_cond_re is a regexp detecting a line continuation ending
3467 # $line_concat is a CODEref that takes care of concatenating two lines
3468 sub collect_from_file {
3469     my $filename = shift;
3470     my $line_concat_cond_re = shift;
3471     my $line_concat = shift;
3472
3473     open my $fh, $filename || die "unable to read $filename: $!\n";
3474     return sub {
3475         my $saved_line = "";
3476         $_ = "";
3477         while (<$fh>) {
3478             s|\R$||;
3479             if (defined $line_concat) {
3480                 $_ = $line_concat->($saved_line, $_);
3481                 $saved_line = "";
3482             }
3483             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3484                 $saved_line = $_;
3485                 next;
3486             }
3487             return $_;
3488         }
3489         die "$filename ending with continuation line\n" if $_;
3490         close $fh;
3491         return undef;
3492     }
3493 }
3494
3495 # collect_from_array($array, $line_concat_cond_re, $line_concat)
3496 # $array is an ARRAYref of lines
3497 # $line_concat_cond_re is a regexp detecting a line continuation ending
3498 # $line_concat is a CODEref that takes care of concatenating two lines
3499 sub collect_from_array {
3500     my $array = shift;
3501     my $line_concat_cond_re = shift;
3502     my $line_concat = shift;
3503     my @array = (@$array);
3504
3505     return sub {
3506         my $saved_line = "";
3507         $_ = "";
3508         while (defined($_ = shift @array)) {
3509             s|\R$||;
3510             if (defined $line_concat) {
3511                 $_ = $line_concat->($saved_line, $_);
3512                 $saved_line = "";
3513             }
3514             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3515                 $saved_line = $_;
3516                 next;
3517             }
3518             return $_;
3519         }
3520         die "input text ending with continuation line\n" if $_;
3521         return undef;
3522     }
3523 }
3524
3525 # collect_information($lineiterator, $line_continue, $regexp => $CODEref, ...)
3526 # $lineiterator is a CODEref that delivers one line at a time.
3527 # All following arguments are regex/CODEref pairs, where the regexp detects a
3528 # line and the CODEref does something with the result of the regexp.
3529 sub collect_information {
3530     my $lineiterator = shift;
3531     my %collectors = @_;
3532
3533     while(defined($_ = $lineiterator->())) {
3534         s|\R$||;
3535         my $found = 0;
3536         if ($collectors{"BEFORE"}) {
3537             $collectors{"BEFORE"}->($_);
3538         }
3539         foreach my $re (keys %collectors) {
3540             if ($re !~ /^OTHERWISE|BEFORE|AFTER$/ && /$re/) {
3541                 $collectors{$re}->($lineiterator);
3542                 $found = 1;
3543             };
3544         }
3545         if ($collectors{"OTHERWISE"}) {
3546             $collectors{"OTHERWISE"}->($lineiterator, $_)
3547                 unless $found || !defined $collectors{"OTHERWISE"};
3548         }
3549         if ($collectors{"AFTER"}) {
3550             $collectors{"AFTER"}->($_);
3551         }
3552     }
3553 }
3554
3555 # tokenize($line)
3556 # tokenize($line,$separator)
3557 # $line is a line of text to split up into tokens
3558 # $separator [optional] is a regular expression that separates the tokens,
3559 # the default being spaces.  Do not use quotes of any kind as separators,
3560 # that will give undefined results.
3561 # Returns a list of tokens.
3562 #
3563 # Tokens are divided by separator (spaces by default).  If the tokens include
3564 # the separators, they have to be quoted with single or double quotes.
3565 # Double quotes inside a double quoted token must be escaped.  Escaping is done
3566 # with backslash.
3567 # Basically, the same quoting rules apply for " and ' as in any
3568 # Unix shell.
3569 sub tokenize {
3570     my $line = my $debug_line = shift;
3571     my $separator = shift // qr|\s+|;
3572     my @result = ();
3573
3574     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
3575         print STDERR "DEBUG[tokenize]: \$separator = $separator\n";
3576     }
3577
3578     while ($line =~ s|^${separator}||, $line ne "") {
3579         my $token = "";
3580     again:
3581         $line =~ m/^(.*?)(${separator}|"|'|$)/;
3582         $token .= $1;
3583         $line = $2.$';
3584
3585         if ($line =~ m/^"((?:[^"\\]+|\\.)*)"/) {
3586             $token .= $1;
3587             $line = $';
3588             goto again;
3589         } elsif ($line =~ m/^'([^']*)'/) {
3590             $token .= $1;
3591             $line = $';
3592             goto again;
3593         }
3594         push @result, $token;
3595     }
3596
3597     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
3598         print STDERR "DEBUG[tokenize]: Parsed '$debug_line' into:\n";
3599         print STDERR "DEBUG[tokenize]: ('", join("', '", @result), "')\n";
3600     }
3601     return @result;
3602 }