Configure

   1 #! /usr/bin/env perl
   2 # -*- mode: perl; -*-
   3 # Copyright 2016-2017 The OpenSSL Project Authors. All Rights Reserved.
   4 #
   5 # Licensed under the OpenSSL license (the "License").  You may not use
   6 # this file except in compliance with the License.  You can obtain a copy
   7 # in the file LICENSE in the source distribution or at
   8 # https://www.openssl.org/source/license.html
   9
  10 ##  Configure -- OpenSSL source tree configuration script
  11
  12 use 5.10.0;
  13 use strict;
  14 use Config;
  15 use File::Basename;
  16 use File::Spec::Functions qw/:DEFAULT abs2rel rel2abs/;
  17 use File::Path qw/mkpath/;
  18 use if $^O ne "VMS", 'File::Glob' => qw/glob/;
  19
  20 # see INSTALL for instructions.
  21
  22 my $usage="Usage: Configure [no-<cipher> ...] [enable-<cipher> ...] [-Dxxx] [-lxxx] [-Lxxx] [-fxxx] [-Kxxx] [no-hw-xxx|no-hw] [[no-]threads] [[no-]shared] [[no-]zlib|zlib-dynamic] [no-asm] [no-dso] [no-egd] [sctp] [386] [--prefix=DIR] [--openssldir=OPENSSLDIR] [--with-xxx[=vvv]] [--config=FILE] os/compiler[:flags]\n";
  23
  24 # Options:
  25 #
  26 # --config      add the given configuration file, which will be read after
  27 #               any "Configurations*" files that are found in the same
  28 #               directory as this script.
  29 # --prefix      prefix for the OpenSSL installation, which includes the
  30 #               directories bin, lib, include, share/man, share/doc/openssl
  31 #               This becomes the value of INSTALLTOP in Makefile
  32 #               (Default: /usr/local)
  33 # --openssldir  OpenSSL data area, such as openssl.cnf, certificates and keys.
  34 #               If it's a relative directory, it will be added on the directory
  35 #               given with --prefix.
  36 #               This becomes the value of OPENSSLDIR in Makefile and in C.
  37 #               (Default: PREFIX/ssl)
  38 #
  39 # --cross-compile-prefix Add specified prefix to binutils components.
  40 #
  41 # --api         One of 0.9.8, 1.0.0 or 1.1.0.  Do not compile support for
  42 #               interfaces deprecated as of the specified OpenSSL version.
  43 #
  44 # no-hw-xxx     do not compile support for specific crypto hardware.
  45 #               Generic OpenSSL-style methods relating to this support
  46 #               are always compiled but return NULL if the hardware
  47 #               support isn't compiled.
  48 # no-hw         do not compile support for any crypto hardware.
  49 # [no-]threads  [don't] try to create a library that is suitable for
  50 #               multithreaded applications (default is "threads" if we
  51 #               know how to do it)
  52 # [no-]shared   [don't] try to create shared libraries when supported.
  53 # [no-]pic      [don't] try to build position independent code when supported.
  54 #               If disabled, it also disables shared and dynamic-engine.
  55 # no-asm        do not use assembler
  56 # no-dso        do not compile in any native shared-library methods. This
  57 #               will ensure that all methods just return NULL.
  58 # no-egd        do not compile support for the entropy-gathering daemon APIs
  59 # [no-]zlib     [don't] compile support for zlib compression.
  60 # zlib-dynamic  Like "zlib", but the zlib library is expected to be a shared
  61 #               library and will be loaded in run-time by the OpenSSL library.
  62 # sctp          include SCTP support
  63 # enable-weak-ssl-ciphers
  64 #               Enable weak ciphers that are disabled by default.
  65 # 386           generate 80386 code in assembly modules
  66 # no-sse2       disables IA-32 SSE2 code in assembly modules, the above
  67 #               mentioned '386' option implies this one
  68 # no-<cipher>   build without specified algorithm (rsa, idea, rc5, ...)
  69 # -<xxx> +<xxx> compiler options are passed through
  70 # -static       while -static is also a pass-through compiler option (and
  71 #               as such is limited to environments where it's actually
  72 #               meaningful), it triggers a number configuration options,
  73 #               namely no-dso, no-pic, no-shared and no-threads. It is
  74 #               argued that the only reason to produce statically linked
  75 #               binaries (and in context it means executables linked with
  76 #               -static flag, and not just executables linked with static
  77 #               libcrypto.a) is to eliminate dependency on specific run-time,
  78 #               a.k.a. libc version. The mentioned config options are meant
  79 #               to achieve just that. Unfortunately on Linux it's impossible
  80 #               to eliminate the dependency completely for openssl executable
  81 #               because of getaddrinfo and gethostbyname calls, which can
  82 #               invoke dynamically loadable library facility anyway to meet
  83 #               the lookup requests. For this reason on Linux statically
  84 #               linked openssl executable has rather debugging value than
  85 #               production quality.
  86 #
  87 # DEBUG_SAFESTACK use type-safe stacks to enforce type-safety on stack items
  88 #               provided to stack calls. Generates unique stack functions for
  89 #               each possible stack type.
  90 # BN_LLONG      use the type 'long long' in crypto/bn/bn.h
  91 # RC4_CHAR      use 'char' instead of 'int' for RC4_INT in crypto/rc4/rc4.h
  92 # Following are set automatically by this script
  93 #
  94 # MD5_ASM       use some extra md5 assembler,
  95 # SHA1_ASM      use some extra sha1 assembler, must define L_ENDIAN for x86
  96 # RMD160_ASM    use some extra ripemd160 assembler,
  97 # SHA256_ASM    sha256_block is implemented in assembler
  98 # SHA512_ASM    sha512_block is implemented in assembler
  99 # AES_ASM       AES_[en|de]crypt is implemented in assembler
 100
 101 # Minimum warning options... any contributions to OpenSSL should at least get
 102 # past these.
 103
 104 # DEBUG_UNUSED enables __owur (warn unused result) checks.
 105 # -DPEDANTIC complements -pedantic and is meant to mask code that
 106 # is not strictly standard-compliant and/or implementation-specific,
 107 # e.g. inline assembly, disregards to alignment requirements, such
 108 # that -pedantic would complain about. Incidentally -DPEDANTIC has
 109 # to be used even in sanitized builds, because sanitizer too is
 110 # supposed to and does take notice of non-standard behaviour. Then
 111 # -pedantic with pre-C9x compiler would also complain about 'long
 112 # long' not being supported. As 64-bit algorithms are common now,
 113 # it grew impossible to resolve this without sizeable additional
 114 # code, so we just tell compiler to be pedantic about everything
 115 # but 'long long' type.
 116
 117 my $gcc_devteam_warn = "-DDEBUG_UNUSED"
 118         . " -Wswitch"
 119         . " -DPEDANTIC -pedantic -Wno-long-long"
 120         . " -Wall"
 121         . " -Wextra"
 122         . " -Wno-unused-parameter"
 123         . " -Wno-missing-field-initializers"
 124         . " -Wsign-compare"
 125         . " -Wmissing-prototypes"
 126         . " -Wshadow"
 127         . " -Wformat"
 128         . " -Wtype-limits"
 129         . " -Wundef"
 130         . " -Werror"
 131         ;
 132
 133 # These are used in addition to $gcc_devteam_warn when the compiler is clang.
 134 # TODO(openssl-team): fix problems and investigate if (at least) the
 135 # following warnings can also be enabled:
 136 #       -Wcast-align
 137 #       -Wunreachable-code -- no, too ugly/compiler-specific
 138 #       -Wlanguage-extension-token -- no, we use asm()
 139 #       -Wunused-macros -- no, too tricky for BN and _XOPEN_SOURCE etc
 140 #       -Wextended-offsetof -- no, needed in CMS ASN1 code
 141 my $clang_devteam_warn = ""
 142         . " -Qunused-arguments"
 143         . " -Wswitch-default"
 144         . " -Wno-parentheses-equality"
 145         . " -Wno-language-extension-token"
 146         . " -Wno-extended-offsetof"
 147         . " -Wconditional-uninitialized"
 148         . " -Wincompatible-pointer-types-discards-qualifiers"
 149         . " -Wmissing-variable-declarations"
 150         ;
 151
 152 # This adds backtrace information to the memory leak info.  Is only used
 153 # when crypto-mdebug-backtrace is enabled.
 154 my $memleak_devteam_backtrace = "-rdynamic";
 155
 156 my $strict_warnings = 0;
 157
 158 # As for $BSDthreads. Idea is to maintain "collective" set of flags,
 159 # which would cover all BSD flavors. -pthread applies to them all,
 160 # but is treated differently. OpenBSD expands is as -D_POSIX_THREAD
 161 # -lc_r, which is sufficient. FreeBSD 4.x expands it as -lc_r,
 162 # which has to be accompanied by explicit -D_THREAD_SAFE and
 163 # sometimes -D_REENTRANT. FreeBSD 5.x expands it as -lc_r, which
 164 # seems to be sufficient?
 165 our $BSDthreads="-pthread -D_THREAD_SAFE -D_REENTRANT";
 166
 167 #
 168 # API compatibility name to version number mapping.
 169 #
 170 my $maxapi = "1.1.0";           # API for "no-deprecated" builds
 171 my $apitable = {
 172     "1.1.0" => "0x10100000L",
 173     "1.0.0" => "0x10000000L",
 174     "0.9.8" => "0x00908000L",
 175 };
 176
 177 our %table = ();
 178 our %config = ();
 179 our %withargs = ();
 180
 181 # Forward declarations ###############################################
 182
 183 # read_config(filename)
 184 #
 185 # Reads a configuration file and populates %table with the contents
 186 # (which the configuration file places in %targets).
 187 sub read_config;
 188
 189 # resolve_config(target)
 190 #
 191 # Resolves all the late evaluations, inheritances and so on for the
 192 # chosen target and any target it inherits from.
 193 sub resolve_config;
 194
 195
 196 # Information collection #############################################
 197
 198 # Unified build supports separate build dir
 199 my $srcdir = catdir(absolutedir(dirname($0))); # catdir ensures local syntax
 200 my $blddir = catdir(absolutedir("."));         # catdir ensures local syntax
 201 my $dofile = abs2rel(catfile($srcdir, "util/dofile.pl"));
 202
 203 my $local_config_envname = 'OPENSSL_LOCAL_CONFIG_DIR';
 204
 205 $config{sourcedir} = abs2rel($srcdir);
 206 $config{builddir} = abs2rel($blddir);
 207
 208 # Collect reconfiguration information if needed
 209 my @argvcopy=@ARGV;
 210
 211 if (grep /^reconf(igure)?$/, @argvcopy) {
 212     if (-f "./configdata.pm") {
 213         my $file = "./configdata.pm";
 214         unless (my $return = do $file) {
 215             die "couldn't parse $file: $@" if $@;
 216             die "couldn't do $file: $!"    unless defined $return;
 217             die "couldn't run $file"       unless $return;
 218         }
 219
 220         @argvcopy = defined($configdata::config{perlargv}) ?
 221             @{$configdata::config{perlargv}} : ();
 222         die "Incorrect data to reconfigure, please do a normal configuration\n"
 223             if (grep(/^reconf/,@argvcopy));
 224         $ENV{CROSS_COMPILE} = $configdata::config{cross_compile_prefix}
 225             if defined($configdata::config{cross_compile_prefix});
 226         $ENV{CC} = $configdata::config{cc}
 227             if defined($configdata::config{cc});
 228         $ENV{CXX} = $configdata::config{cxx}
 229             if defined($configdata::config{cxx});
 230         $ENV{BUILDFILE} = $configdata::config{build_file}
 231             if defined($configdata::config{build_file});
 232         $ENV{$local_config_envname} = $configdata::config{local_config_dir}
 233             if defined($configdata::config{local_config_dir});
 234
 235         print "Reconfiguring with: ", join(" ",@argvcopy), "\n";
 236         print "    CROSS_COMPILE = ",$ENV{CROSS_COMPILE},"\n"
 237             if $ENV{CROSS_COMPILE};
 238         print "    CC = ",$ENV{CC},"\n" if $ENV{CC};
 239         print "    CXX = ",$ENV{CXX},"\n" if $ENV{CXX};
 240         print "    BUILDFILE = ",$ENV{BUILDFILE},"\n" if $ENV{BUILDFILE};
 241         print "    $local_config_envname = ",$ENV{$local_config_envname},"\n"
 242             if $ENV{$local_config_envname};
 243     } else {
 244         die "Insufficient data to reconfigure, please do a normal configuration\n";
 245     }
 246 }
 247
 248 $config{perlargv} = [ @argvcopy ];
 249
 250 # Collect version numbers
 251 $config{version} = "unknown";
 252 $config{version_num} = "unknown";
 253 $config{shlib_version_number} = "unknown";
 254 $config{shlib_version_history} = "unknown";
 255
 256 collect_information(
 257     collect_from_file(catfile($srcdir,'include/openssl/opensslv.h')),
 258     qr/OPENSSL.VERSION.TEXT.*OpenSSL (\S+) / => sub { $config{version} = $1; },
 259     qr/OPENSSL.VERSION.NUMBER.*(0x\S+)/      => sub { $config{version_num}=$1 },
 260     qr/SHLIB_VERSION_NUMBER *"([^"]+)"/      => sub { $config{shlib_version_number}=$1 },
 261     qr/SHLIB_VERSION_HISTORY *"([^"]*)"/     => sub { $config{shlib_version_history}=$1 }
 262     );
 263 if ($config{shlib_version_history} ne "") { $config{shlib_version_history} .= ":"; }
 264
 265 ($config{major}, $config{minor})
 266     = ($config{version} =~ /^([0-9]+)\.([0-9\.]+)/);
 267 ($config{shlib_major}, $config{shlib_minor})
 268     = ($config{shlib_version_number} =~ /^([0-9]+)\.([0-9\.]+)/);
 269 die "erroneous version information in opensslv.h: ",
 270     "$config{major}, $config{minor}, $config{shlib_major}, $config{shlib_minor}\n"
 271     if ($config{major} eq "" || $config{minor} eq ""
 272         || $config{shlib_major} eq "" ||  $config{shlib_minor} eq "");
 273
 274 # Collect target configurations
 275
 276 my $pattern = catfile(dirname($0), "Configurations", "*.conf");
 277 foreach (sort glob($pattern)) {
 278     &read_config($_);
 279 }
 280
 281 if (defined $ENV{$local_config_envname}) {
 282     if ($^O eq 'VMS') {
 283         # VMS environment variables are logical names,
 284         # which can be used as is
 285         $pattern = $local_config_envname . ':' . '*.conf';
 286     } else {
 287         $pattern = catfile($ENV{$local_config_envname}, '*.conf');
 288     }
 289
 290     foreach (sort glob($pattern)) {
 291         &read_config($_);
 292     }
 293 }
 294
 295 $config{prefix}="";
 296 $config{openssldir}="";
 297 $config{processor}="";
 298 $config{libdir}="";
 299 $config{cross_compile_prefix}="";
 300 my $auto_threads=1;    # enable threads automatically? true by default
 301 my $default_ranlib;
 302
 303 # Top level directories to build
 304 $config{dirs} = [ "crypto", "ssl", "engines", "apps", "test", "util", "tools", "fuzz" ];
 305 # crypto/ subdirectories to build
 306 $config{sdirs} = [
 307     "objects",
 308     "md2", "md4", "md5", "sha", "mdc2", "hmac", "ripemd", "whrlpool", "poly1305", "blake2", "siphash",
 309     "des", "aes", "rc2", "rc4", "rc5", "idea", "aria", "bf", "cast", "camellia", "seed", "chacha", "modes",
 310     "bn", "ec", "rsa", "dsa", "dh", "dso", "engine",
 311     "buffer", "bio", "stack", "lhash", "rand", "err",
 312     "evp", "asn1", "pem", "x509", "x509v3", "conf", "txt_db", "pkcs7", "pkcs12", "comp", "ocsp", "ui",
 313     "cms", "ts", "srp", "cmac", "ct", "async", "kdf", "store"
 314     ];
 315 # test/ subdirectories to build
 316 $config{tdirs} = [ "ossl_shim" ];
 317
 318 # Known TLS and DTLS protocols
 319 my @tls = qw(ssl3 tls1 tls1_1 tls1_2 tls1_3);
 320 my @dtls = qw(dtls1 dtls1_2);
 321
 322 # Explicitly known options that are possible to disable.  They can
 323 # be regexps, and will be used like this: /^no-${option}$/
 324 # For developers: keep it sorted alphabetically
 325
 326 my @disablables = (
 327     "afalgeng",
 328     "aria",
 329     "asan",
 330     "asm",
 331     "async",
 332     "autoalginit",
 333     "autoerrinit",
 334     "bf",
 335     "blake2",
 336     "camellia",
 337     "capieng",
 338     "cast",
 339     "chacha",
 340     "cmac",
 341     "cms",
 342     "comp",
 343     "crypto-mdebug",
 344     "crypto-mdebug-backtrace",
 345     "ct",
 346     "deprecated",
 347     "des",
 348     "devcryptoeng",
 349     "dgram",
 350     "dh",
 351     "dsa",
 352     "dso",
 353     "dtls",
 354     "dynamic-engine",
 355     "ec",
 356     "ec2m",
 357     "ecdh",
 358     "ecdsa",
 359     "ec_nistp_64_gcc_128",
 360     "egd",
 361     "engine",
 362     "err",
 363     "external-tests",
 364     "filenames",
 365     "fuzz-libfuzzer",
 366     "fuzz-afl",
 367     "gost",
 368     "heartbeats",
 369     "hw(-.+)?",
 370     "idea",
 371     "makedepend",
 372     "md2",
 373     "md4",
 374     "mdc2",
 375     "msan",
 376     "multiblock",
 377     "nextprotoneg",
 378     "ocb",
 379     "ocsp",
 380     "pic",
 381     "poly1305",
 382     "posix-io",
 383     "psk",
 384     "rc2",
 385     "rc4",
 386     "rc5",
 387     "rdrand",
 388     "rfc3779",
 389     "rmd160",
 390     "scrypt",
 391     "sctp",
 392     "seed",
 393     "shared",
 394     "siphash",
 395     "sock",
 396     "srp",
 397     "srtp",
 398     "sse2",
 399     "ssl",
 400     "ssl-trace",
 401     "static-engine",
 402     "stdio",
 403     "tests",
 404     "threads",
 405     "tls",
 406     "tls13downgrade",
 407     "ts",
 408     "ubsan",
 409     "ui-console",
 410     "unit-test",
 411     "whirlpool",
 412     "weak-ssl-ciphers",
 413     "zlib",
 414     "zlib-dynamic",
 415     );
 416 foreach my $proto ((@tls, @dtls))
 417         {
 418         push(@disablables, $proto);
 419         push(@disablables, "$proto-method") unless $proto eq "tls1_3";
 420         }
 421
 422 my %deprecated_disablables = (
 423     "ssl2" => undef,
 424     "buf-freelists" => undef,
 425     "ripemd" => "rmd160",
 426     "ui" => "ui-console",
 427     );
 428
 429 # All of the following is disabled by default (RC5 was enabled before 0.9.8):
 430
 431 our %disabled = ( # "what"         => "comment"
 432                   "aria"                => "default",
 433                   "asan"                => "default",
 434                   "crypto-mdebug"       => "default",
 435                   "crypto-mdebug-backtrace" => "default",
 436                   "devcryptoeng"        => "default",
 437                   "ec_nistp_64_gcc_128" => "default",
 438                   "egd"                 => "default",
 439                   "external-tests"      => "default",
 440                   "fuzz-libfuzzer"      => "default",
 441                   "fuzz-afl"            => "default",
 442                   "heartbeats"          => "default",
 443                   "md2"                 => "default",
 444                   "msan"                => "default",
 445                   "rc5"                 => "default",
 446                   "sctp"                => "default",
 447                   "ssl-trace"           => "default",
 448                   "ssl3"                => "default",
 449                   "ssl3-method"         => "default",
 450                   "ubsan"               => "default",
 451           #TODO(TLS1.3): Temporarily disabled while this is a WIP
 452                   "tls1_3"              => "default",
 453                   "tls13downgrade"      => "default",
 454                   "unit-test"           => "default",
 455                   "weak-ssl-ciphers"    => "default",
 456                   "zlib"                => "default",
 457                   "zlib-dynamic"        => "default",
 458                 );
 459
 460 # Note: => pair form used for aesthetics, not to truly make a hash table
 461 my @disable_cascades = (
 462     # "what"            => [ "cascade", ... ]
 463     sub { $config{processor} eq "386" }
 464                         => [ "sse2" ],
 465     "ssl"               => [ "ssl3" ],
 466     "ssl3-method"       => [ "ssl3" ],
 467     "zlib"              => [ "zlib-dynamic" ],
 468     "des"               => [ "mdc2" ],
 469     "ec"                => [ "ecdsa", "ecdh" ],
 470
 471     "dgram"             => [ "dtls", "sctp" ],
 472     "sock"              => [ "dgram" ],
 473     "dtls"              => [ @dtls ],
 474     sub { 0 == scalar grep { !$disabled{$_} } @dtls }
 475                         => [ "dtls" ],
 476
 477     # SSL 3.0, (D)TLS 1.0 and TLS 1.1 require MD5 and SHA
 478     "md5"               => [ "ssl", "tls1", "tls1_1", "dtls1" ],
 479     "sha"               => [ "ssl", "tls1", "tls1_1", "dtls1" ],
 480
 481     # Additionally, SSL 3.0 requires either RSA or DSA+DH
 482     sub { $disabled{rsa}
 483           && ($disabled{dsa} || $disabled{dh}); }
 484                         => [ "ssl" ],
 485
 486     # (D)TLS 1.0 and TLS 1.1 also require either RSA or DSA+DH
 487     # or ECDSA + ECDH.  (D)TLS 1.2 has this requirement as well.
 488     # (XXX: We don't support PSK-only builds).
 489     sub { $disabled{rsa}
 490           && ($disabled{dsa} || $disabled{dh})
 491           && ($disabled{ecdsa} || $disabled{ecdh}); }
 492                         => [ "tls1", "tls1_1", "tls1_2", "tls1_3",
 493                              "dtls1", "dtls1_2" ],
 494
 495     "tls"               => [ @tls ],
 496     sub { 0 == scalar grep { !$disabled{$_} } @tls }
 497                         => [ "tls" ],
 498
 499     # SRP and HEARTBEATS require TLSEXT
 500     "tlsext"            => [ "srp", "heartbeats" ],
 501
 502     "crypto-mdebug"     => [ "crypto-mdebug-backtrace" ],
 503
 504     # Without DSO, we can't load dynamic engines, so don't build them dynamic
 505     "dso"               => [ "dynamic-engine" ],
 506
 507     # Without position independent code, there can be no shared libraries or DSOs
 508     "pic"               => [ "shared" ],
 509     "shared"            => [ "dynamic-engine" ],
 510     "engine"            => [ "afalgeng", "devcryptoeng" ],
 511
 512     # no-autoalginit is only useful when building non-shared
 513     "autoalginit"       => [ "shared", "apps" ],
 514
 515     "stdio"             => [ "apps", "capieng" ],
 516     "apps"              => [ "tests" ],
 517     "comp"              => [ "zlib" ],
 518     "ec"                => [ "tls1_3" ],
 519     sub { !$disabled{"unit-test"} } => [ "heartbeats" ],
 520
 521     sub { !$disabled{"msan"} } => [ "asm" ],
 522     );
 523
 524 # Avoid protocol support holes.  Also disable all versions below N, if version
 525 # N is disabled while N+1 is enabled.
 526 #
 527 my @list = (reverse @tls);
 528 while ((my $first, my $second) = (shift @list, shift @list)) {
 529     last unless @list;
 530     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 531                               => [ @list ] );
 532     unshift @list, $second;
 533 }
 534 my @list = (reverse @dtls);
 535 while ((my $first, my $second) = (shift @list, shift @list)) {
 536     last unless @list;
 537     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 538                               => [ @list ] );
 539     unshift @list, $second;
 540 }
 541
 542 # Explicit "no-..." options will be collected in %disabled along with the defaults.
 543 # To remove something from %disabled, use "enable-foo".
 544 # For symmetry, "disable-foo" is a synonym for "no-foo".
 545
 546 my $no_sse2=0;
 547
 548 &usage if ($#ARGV < 0);
 549
 550 my $user_cflags="";
 551 my @user_defines=();
 552 $config{openssl_api_defines}=[];
 553 $config{openssl_algorithm_defines}=[];
 554 $config{openssl_thread_defines}=[];
 555 $config{openssl_sys_defines}=[];
 556 $config{openssl_other_defines}=[];
 557 my $libs="";
 558 my $target="";
 559 $config{options}="";
 560 $config{build_type} = "release";
 561
 562 my %unsupported_options = ();
 563 my %deprecated_options = ();
 564 while (@argvcopy)
 565         {
 566         $_ = shift @argvcopy;
 567         # VMS is a case insensitive environment, and depending on settings
 568         # out of our control, we may receive options uppercased.  Let's
 569         # downcase at least the part before any equal sign.
 570         if ($^O eq "VMS")
 571                 {
 572                 s/^([^=]*)/lc($1)/e;
 573                 }
 574         s /^-no-/no-/; # some people just can't read the instructions
 575
 576         # rewrite some options in "enable-..." form
 577         s /^-?-?shared$/enable-shared/;
 578         s /^sctp$/enable-sctp/;
 579         s /^threads$/enable-threads/;
 580         s /^zlib$/enable-zlib/;
 581         s /^zlib-dynamic$/enable-zlib-dynamic/;
 582
 583         if (/^(no|disable|enable)-(.+)$/)
 584                 {
 585                 my $word = $2;
 586                 if (!exists $deprecated_disablables{$word}
 587                         && !grep { $word =~ /^${_}$/ } @disablables)
 588                         {
 589                         $unsupported_options{$_} = 1;
 590                         next;
 591                         }
 592                 }
 593         if (/^no-(.+)$/ || /^disable-(.+)$/)
 594                 {
 595                 foreach my $proto ((@tls, @dtls))
 596                         {
 597                         if ($1 eq "$proto-method")
 598                                 {
 599                                 $disabled{"$proto"} = "option($proto-method)";
 600                                 last;
 601                                 }
 602                         }
 603                 if ($1 eq "dtls")
 604                         {
 605                         foreach my $proto (@dtls)
 606                                 {
 607                                 $disabled{$proto} = "option(dtls)";
 608                                 }
 609                         $disabled{"dtls"} = "option(dtls)";
 610                         }
 611                 elsif ($1 eq "ssl")
 612                         {
 613                         # Last one of its kind
 614                         $disabled{"ssl3"} = "option(ssl)";
 615                         }
 616                 elsif ($1 eq "tls")
 617                         {
 618                         # XXX: Tests will fail if all SSL/TLS
 619                         # protocols are disabled.
 620                         foreach my $proto (@tls)
 621                                 {
 622                                 $disabled{$proto} = "option(tls)";
 623                                 }
 624                         }
 625                 elsif ($1 eq "static-engine")
 626                         {
 627                         delete $disabled{"dynamic-engine"};
 628                         }
 629                 elsif ($1 eq "dynamic-engine")
 630                         {
 631                         $disabled{"dynamic-engine"} = "option";
 632                         }
 633                 elsif (exists $deprecated_disablables{$1})
 634                         {
 635                         $deprecated_options{$_} = 1;
 636                         if (defined $deprecated_disablables{$1})
 637                                 {
 638                                 $disabled{$deprecated_disablables{$1}} = "option";
 639                                 }
 640                         }
 641                 else
 642                         {
 643                         $disabled{$1} = "option";
 644                         }
 645                 # No longer an automatic choice
 646                 $auto_threads = 0 if ($1 eq "threads");
 647                 }
 648         elsif (/^enable-(.+)$/)
 649                 {
 650                 if ($1 eq "static-engine")
 651                         {
 652                         $disabled{"dynamic-engine"} = "option";
 653                         }
 654                 elsif ($1 eq "dynamic-engine")
 655                         {
 656                         delete $disabled{"dynamic-engine"};
 657                         }
 658                 elsif ($1 eq "zlib-dynamic")
 659                         {
 660                         delete $disabled{"zlib"};
 661                         }
 662                 my $algo = $1;
 663                 delete $disabled{$algo};
 664
 665                 # No longer an automatic choice
 666                 $auto_threads = 0 if ($1 eq "threads");
 667                 }
 668         elsif (/^--strict-warnings$/)
 669                 {
 670                 $strict_warnings = 1;
 671                 }
 672         elsif (/^--debug$/)
 673                 {
 674                 $config{build_type} = "debug";
 675                 }
 676         elsif (/^--release$/)
 677                 {
 678                 $config{build_type} = "release";
 679                 }
 680         elsif (/^386$/)
 681                 { $config{processor}=386; }
 682         elsif (/^fips$/)
 683                 {
 684                 die "FIPS mode not supported\n";
 685                 }
 686         elsif (/^rsaref$/)
 687                 {
 688                 # No RSAref support any more since it's not needed.
 689                 # The check for the option is there so scripts aren't
 690                 # broken
 691                 }
 692         elsif (/^nofipscanistercheck$/)
 693                 {
 694                 die "FIPS mode not supported\n";
 695                 }
 696         elsif (/^[-+]/)
 697                 {
 698                 if (/^--prefix=(.*)$/)
 699                         {
 700                         $config{prefix}=$1;
 701                         die "Directory given with --prefix MUST be absolute\n"
 702                                 unless file_name_is_absolute($config{prefix});
 703                         }
 704                 elsif (/^--api=(.*)$/)
 705                         {
 706                         $config{api}=$1;
 707                         }
 708                 elsif (/^--libdir=(.*)$/)
 709                         {
 710                         $config{libdir}=$1;
 711                         }
 712                 elsif (/^--openssldir=(.*)$/)
 713                         {
 714                         $config{openssldir}=$1;
 715                         }
 716                 elsif (/^--with-zlib-lib=(.*)$/)
 717                         {
 718                         $withargs{zlib_lib}=$1;
 719                         }
 720                 elsif (/^--with-zlib-include=(.*)$/)
 721                         {
 722                         $withargs{zlib_include}=$1;
 723                         }
 724                 elsif (/^--with-fuzzer-lib=(.*)$/)
 725                         {
 726                         $withargs{fuzzer_lib}=$1;
 727                         }
 728                 elsif (/^--with-fuzzer-include=(.*)$/)
 729                         {
 730                         $withargs{fuzzer_include}=$1;
 731                         }
 732                 elsif (/^--cross-compile-prefix=(.*)$/)
 733                         {
 734                         $config{cross_compile_prefix}=$1;
 735                         }
 736                 elsif (/^--config=(.*)$/)
 737                         {
 738                         read_config $1;
 739                         }
 740                 elsif (/^-[lL](.*)$/ or /^-Wl,/)
 741                         {
 742                         $libs.=$_." ";
 743                         }
 744                 elsif (/^-framework$/)
 745                         {
 746                         $libs.=$_." ".shift(@argvcopy)." ";
 747                         }
 748                 elsif (/^-rpath$/ or /^-R$/)
 749                         # -rpath is the OSF1 rpath flag
 750                         # -R is the old Solaris rpath flag
 751                         {
 752                         my $rpath = shift(@argvcopy) || "";
 753                         $rpath .= " " if $rpath ne "";
 754                         $libs.=$_." ".$rpath;
 755                         }
 756                 elsif (/^-static$/)
 757                         {
 758                         $libs.=$_." ";
 759                         $disabled{"dso"} = "forced";
 760                         $disabled{"pic"} = "forced";
 761                         $disabled{"shared"} = "forced";
 762                         $disabled{"threads"} = "forced";
 763                         }
 764                 elsif (/^-D(.*)$/)
 765                         {
 766                         push @user_defines, $1;
 767                         }
 768                 else    # common if (/^[-+]/), just pass down...
 769                         {
 770                         $_ =~ s/%([0-9a-f]{1,2})/chr(hex($1))/gei;
 771                         $user_cflags.=" ".$_;
 772                         }
 773                 }
 774         else
 775                 {
 776                 die "target already defined - $target (offending arg: $_)\n" if ($target ne "");
 777                 $target=$_;
 778                 }
 779         unless ($_ eq $target || /^no-/ || /^disable-/)
 780                 {
 781                 # "no-..." follows later after implied disactivations
 782                 # have been derived.  (Don't take this too seriously,
 783                 # we really only write OPTIONS to the Makefile out of
 784                 # nostalgia.)
 785
 786                 if ($config{options} eq "")
 787                         { $config{options} = $_; }
 788                 else
 789                         { $config{options} .= " ".$_; }
 790                 }
 791
 792         if (defined($config{api}) && !exists $apitable->{$config{api}}) {
 793                 die "***** Unsupported api compatibility level: $config{api}\n",
 794         }
 795
 796         if (keys %deprecated_options)
 797                 {
 798                 warn "***** Deprecated options: ",
 799                         join(", ", keys %deprecated_options), "\n";
 800                 }
 801         if (keys %unsupported_options)
 802                 {
 803                 die "***** Unsupported options: ",
 804                         join(", ", keys %unsupported_options), "\n";
 805                 }
 806         }
 807
 808 if ($libs =~ /(^|\s)-Wl,-rpath,/
 809     && !$disabled{shared}
 810     && !($disabled{asan} && $disabled{msan} && $disabled{ubsan})) {
 811     die "***** Cannot simultaneously use -rpath, shared libraries, and\n",
 812         "***** any of asan, msan or ubsan\n";
 813 }
 814
 815 my @tocheckfor = (keys %disabled);
 816 while (@tocheckfor) {
 817     my %new_tocheckfor = ();
 818     my @cascade_copy = (@disable_cascades);
 819     while (@cascade_copy) {
 820         my ($test, $descendents) = (shift @cascade_copy, shift @cascade_copy);
 821         if (ref($test) eq "CODE" ? $test->() : defined($disabled{$test})) {
 822             foreach(grep { !defined($disabled{$_}) } @$descendents) {
 823                 $new_tocheckfor{$_} = 1; $disabled{$_} = "forced";
 824             }
 825         }
 826     }
 827     @tocheckfor = (keys %new_tocheckfor);
 828 }
 829
 830 our $die = sub { die @_; };
 831 if ($target eq "TABLE") {
 832     local $die = sub { warn @_; };
 833     foreach (sort keys %table) {
 834         print_table_entry($_, "TABLE");
 835     }
 836     exit 0;
 837 }
 838
 839 if ($target eq "LIST") {
 840     foreach (sort keys %table) {
 841         print $_,"\n" unless $table{$_}->{template};
 842     }
 843     exit 0;
 844 }
 845
 846 if ($target eq "HASH") {
 847     local $die = sub { warn @_; };
 848     print "%table = (\n";
 849     foreach (sort keys %table) {
 850         print_table_entry($_, "HASH");
 851     }
 852     exit 0;
 853 }
 854
 855 print "Configuring OpenSSL version $config{version} ($config{version_num})\n";
 856 print "for $target\n";
 857
 858 # Backward compatibility?
 859 if ($target =~ m/^CygWin32(-.*)$/) {
 860     $target = "Cygwin".$1;
 861 }
 862
 863 # Support for legacy targets having a name starting with 'debug-'
 864 my ($d, $t) = $target =~ m/^(debug-)?(.*)$/;
 865 if ($d) {
 866     $config{build_type} = "debug";
 867
 868     # If we do not find debug-foo in the table, the target is set to foo.
 869     if (!$table{$target}) {
 870         $target = $t;
 871     }
 872 }
 873 $config{target} = $target;
 874 my %target = resolve_config($target);
 875
 876 &usage if (!%target || $target{template});
 877
 878 my %conf_files = map { $_ => 1 } (@{$target{_conf_fname_int}});
 879 $config{conf_files} = [ sort keys %conf_files ];
 880 %target = ( %{$table{DEFAULTS}}, %target );
 881
 882 foreach my $feature (@{$target{disable}}) {
 883     if (exists $deprecated_disablables{$feature}) {
 884         warn "***** config $target disables deprecated feature $feature\n";
 885     } elsif (!grep { $feature eq $_ } @disablables) {
 886         die "***** config $target disables unknown feature $feature\n";
 887     }
 888     $disabled{$feature} = 'config';
 889 }
 890 foreach my $feature (@{$target{enable}}) {
 891     if ("default" eq ($disabled{$_} // "")) {
 892         if (exists $deprecated_disablables{$feature}) {
 893             warn "***** config $target enables deprecated feature $feature\n";
 894         } elsif (!grep { $feature eq $_ } @disablables) {
 895             die "***** config $target enables unknown feature $feature\n";
 896         }
 897         delete $disabled{$_};
 898     }
 899 }
 900
 901 foreach (sort (keys %disabled))
 902         {
 903         $config{options} .= " no-$_";
 904
 905         printf "    no-%-12s %-10s", $_, "[$disabled{$_}]";
 906
 907         if (/^dso$/)
 908                 { }
 909         elsif (/^threads$/)
 910                 { }
 911         elsif (/^shared$/)
 912                 { }
 913         elsif (/^pic$/)
 914                 { }
 915         elsif (/^zlib$/)
 916                 { }
 917         elsif (/^dynamic-engine$/)
 918                 { }
 919         elsif (/^makedepend$/)
 920                 { }
 921         elsif (/^zlib-dynamic$/)
 922                 { }
 923         elsif (/^sse2$/)
 924                 { $no_sse2 = 1; }
 925         elsif (/^engine$/)
 926                 {
 927                 @{$config{dirs}} = grep !/^engines$/, @{$config{dirs}};
 928                 @{$config{sdirs}} = grep !/^engine$/, @{$config{sdirs}};
 929                 push @{$config{openssl_other_defines}}, "OPENSSL_NO_ENGINE";
 930                 print " OPENSSL_NO_ENGINE (skip engines)";
 931                 }
 932         else
 933                 {
 934                 my ($WHAT, $what);
 935
 936                 ($WHAT = $what = $_) =~ tr/[\-a-z]/[_A-Z]/;
 937
 938                 # Fix up C macro end names
 939                 $WHAT = "RMD160" if $what eq "ripemd";
 940
 941                 # fix-up crypto/directory name(s)
 942                 $what = "ripemd" if $what eq "rmd160";
 943                 $what = "whrlpool" if $what eq "whirlpool";
 944
 945                 if ($what ne "async" && $what ne "err"
 946                     && grep { $_ eq $what } @{$config{sdirs}})
 947                         {
 948                         push @{$config{openssl_algorithm_defines}}, "OPENSSL_NO_$WHAT";
 949                         @{$config{sdirs}} = grep { $_ ne $what} @{$config{sdirs}};
 950
 951                         print " OPENSSL_NO_$WHAT (skip dir)";
 952                         }
 953                 else
 954                         {
 955                         push @{$config{openssl_other_defines}}, "OPENSSL_NO_$WHAT";
 956                         print " OPENSSL_NO_$WHAT";
 957
 958                         if (/^err$/)    { push @user_defines, "OPENSSL_NO_ERR"; }
 959                         }
 960                 }
 961
 962         print "\n";
 963         }
 964
 965 $target{cxxflags}=$target{cflags} unless defined $target{cxxflags};
 966 $target{exe_extension}="";
 967 $target{exe_extension}=".exe" if ($config{target} eq "DJGPP"
 968                                   || $config{target} =~ /^(?:Cygwin|mingw)/);
 969 $target{exe_extension}=".pm"  if ($config{target} =~ /vos/);
 970
 971 ($target{shared_extension_simple}=$target{shared_extension})
 972     =~ s|\.\$\(SHLIB_MAJOR\)\.\$\(SHLIB_MINOR\)||;
 973 $target{dso_extension}=$target{shared_extension_simple};
 974 ($target{shared_import_extension}=$target{shared_extension_simple}.".a")
 975     if ($config{target} =~ /^(?:Cygwin|mingw)/);
 976
 977
 978 $config{cross_compile_prefix} = $ENV{'CROSS_COMPILE'}
 979     if $config{cross_compile_prefix} eq "";
 980
 981 # Allow overriding the names of some tools.  USE WITH CARE
 982 # Note: only Unix cares about HASHBANGPERL...  that explains
 983 # the default string.
 984 $config{perl} =    ($^O ne "VMS" ? $^X : "perl");
 985 $config{hashbangperl} =
 986     $ENV{'HASHBANGPERL'}           || $ENV{'PERL'}     || "/usr/bin/env perl";
 987 $target{cc} =      $ENV{'CC'}      || $target{cc}      || "cc";
 988 $target{cxx} =     $ENV{'CXX'}     || $target{cxx}     || "c++";
 989 $target{ranlib} =  $ENV{'RANLIB'}  || $target{ranlib}  ||
 990                    (which("$config{cross_compile_prefix}ranlib") ?
 991                           "\$(CROSS_COMPILE)ranlib" : "true");
 992 $target{ar} =      $ENV{'AR'}      || $target{ar}      || "ar";
 993 $target{nm} =      $ENV{'NM'}      || $target{nm}      || "nm";
 994 $target{rc} =
 995     $ENV{'RC'}  || $ENV{'WINDRES'} || $target{rc}      || "windres";
 996
 997 # Allow overriding the build file name
 998 $target{build_file} = $ENV{BUILDFILE} || $target{build_file} || "Makefile";
 999
1000 # Cache information necessary for reconfiguration
1001 $config{cc} = $target{cc};
1002 $config{cxx} = $target{cxx};
1003 $config{build_file} = $target{build_file};
1004
1005 # For cflags, lflags, plib_lflags, ex_libs and defines, add the debug_
1006 # or release_ attributes.
1007 # Do it in such a way that no spurious space is appended (hence the grep).
1008 $config{defines} = [];
1009 $config{cflags} = "";
1010 $config{cxxflags} = "";
1011 $config{ex_libs} = "";
1012 $config{shared_ldflag} = "";
1013
1014 # Make sure build_scheme is consistent.
1015 $target{build_scheme} = [ $target{build_scheme} ]
1016     if ref($target{build_scheme}) ne "ARRAY";
1017
1018 my ($builder, $builder_platform, @builder_opts) =
1019     @{$target{build_scheme}};
1020
1021 foreach my $checker (($builder_platform."-".$target{build_file}."-checker.pm",
1022                       $builder_platform."-checker.pm")) {
1023     my $checker_path = catfile($srcdir, "Configurations", $checker);
1024     if (-f $checker_path) {
1025         my $fn = $ENV{CONFIGURE_CHECKER_WARN}
1026             ? sub { warn $@; } : sub { die $@; };
1027         if (! do $checker_path) {
1028             if ($@) {
1029                 $fn->($@);
1030             } elsif ($!) {
1031                 $fn->($!);
1032             } else {
1033                 $fn->("The detected tools didn't match the platform\n");
1034             }
1035         }
1036         last;
1037     }
1038 }
1039
1040 push @{$config{defines}}, "NDEBUG"    if $config{build_type} eq "release";
1041
1042 if ($target =~ /^mingw/ && `$target{cc} --target-help 2>&1` =~ m/-mno-cygwin/m)
1043         {
1044         $config{cflags} .= " -mno-cygwin";
1045         $config{shared_ldflag} .= " -mno-cygwin";
1046         }
1047
1048 if ($target =~ /linux.*-mips/ && !$disabled{asm} && $user_cflags !~ /-m(ips|arch=)/) {
1049         # minimally required architecture flags for assembly modules
1050         $config{cflags}="-mips2 $config{cflags}" if ($target =~ /mips32/);
1051         $config{cflags}="-mips3 $config{cflags}" if ($target =~ /mips64/);
1052 }
1053
1054 my $no_shared_warn=0;
1055 my $no_user_cflags=0;
1056 my $no_user_defines=0;
1057
1058 # The DSO code currently always implements all functions so that no
1059 # applications will have to worry about that from a compilation point
1060 # of view. However, the "method"s may return zero unless that platform
1061 # has support compiled in for them. Currently each method is enabled
1062 # by a define "DSO_<name>" ... we translate the "dso_scheme" config
1063 # string entry into using the following logic;
1064 if (!$disabled{dso} && $target{dso_scheme} ne "")
1065         {
1066         $target{dso_scheme} =~ tr/[a-z]/[A-Z]/;
1067         if ($target{dso_scheme} eq "DLFCN")
1068                 {
1069                 unshift @{$config{defines}}, "DSO_DLFCN", "HAVE_DLFCN_H";
1070                 }
1071         elsif ($target{dso_scheme} eq "DLFCN_NO_H")
1072                 {
1073                 unshift @{$config{defines}}, "DSO_DLFCN";
1074                 }
1075         else
1076                 {
1077                 unshift @{$config{defines}}, "DSO_$target{dso_scheme}";
1078                 }
1079         }
1080
1081 $config{ex_libs}="$libs$config{ex_libs}" if ($libs ne "");
1082
1083 # If threads aren't disabled, check how possible they are
1084 unless ($disabled{threads}) {
1085     if ($auto_threads) {
1086         # Enabled by default, disable it forcibly if unavailable
1087         if ($target{thread_scheme} eq "(unknown)") {
1088             $disabled{threads} = "unavailable";
1089         }
1090     } else {
1091         # The user chose to enable threads explicitly, let's see
1092         # if there's a chance that's possible
1093         if ($target{thread_scheme} eq "(unknown)") {
1094             # If the user asked for "threads" and we don't have internal
1095             # knowledge how to do it, [s]he is expected to provide any
1096             # system-dependent compiler options that are necessary.  We
1097             # can't truly check that the given options are correct, but
1098             # we expect the user to know what [s]He is doing.
1099             if ($no_user_cflags && $no_user_defines) {
1100                 die "You asked for multi-threading support, but didn't\n"
1101                     ,"provide any system-specific compiler options\n";
1102             }
1103         }
1104     }
1105 }
1106
1107 # If threads still aren't disabled, add a C macro to ensure the source
1108 # code knows about it.  Any other flag is taken care of by the configs.
1109 unless($disabled{threads}) {
1110     foreach (("defines", "openssl_thread_defines")) {
1111         push @{$config{$_}}, "OPENSSL_THREADS";
1112     }
1113 }
1114
1115 # With "deprecated" disable all deprecated features.
1116 if (defined($disabled{"deprecated"})) {
1117         $config{api} = $maxapi;
1118 }
1119
1120 if ($target{shared_target} eq "")
1121         {
1122         $no_shared_warn = 1
1123             if (!$disabled{shared} || !$disabled{"dynamic-engine"});
1124         $disabled{shared} = "no-shared-target";
1125         $disabled{pic} = $disabled{shared} = $disabled{"dynamic-engine"} =
1126             "no-shared-target";
1127         }
1128
1129 if ($disabled{"dynamic-engine"}) {
1130         push @{$config{defines}}, "OPENSSL_NO_DYNAMIC_ENGINE";
1131         $config{dynamic_engines} = 0;
1132 } else {
1133         push @{$config{defines}}, "OPENSSL_NO_STATIC_ENGINE";
1134         $config{dynamic_engines} = 1;
1135 }
1136
1137 unless ($disabled{asan}) {
1138     $config{cflags} .= "-fsanitize=address ";
1139 }
1140
1141 unless ($disabled{ubsan}) {
1142     # -DPEDANTIC or -fnosanitize=alignment may also be required on some
1143     # platforms.
1144     $config{cflags} .= "-fsanitize=undefined -fno-sanitize-recover=all ";
1145 }
1146
1147 unless ($disabled{msan}) {
1148   $config{cflags} .= "-fsanitize=memory ";
1149 }
1150
1151 unless ($disabled{"fuzz-libfuzzer"} && $disabled{"fuzz-afl"}
1152         && $disabled{asan} && $disabled{ubsan} && $disabled{msan}) {
1153     $config{cflags} .= "-fno-omit-frame-pointer -g ";
1154 }
1155 #
1156 # Platform fix-ups
1157 #
1158
1159 # This saves the build files from having to check
1160 if ($disabled{pic})
1161         {
1162         $target{shared_cflag} = $target{shared_ldflag} =
1163                 $target{shared_rcflag} = "";
1164         }
1165 else
1166         {
1167         push @{$config{defines}}, "OPENSSL_PIC";
1168         }
1169
1170 if ($target{sys_id} ne "")
1171         {
1172         push @{$config{openssl_sys_defines}}, "OPENSSL_SYS_$target{sys_id}";
1173         }
1174
1175 unless ($disabled{asm}) {
1176     $target{cpuid_asm_src}=$table{DEFAULTS}->{cpuid_asm_src} if ($config{processor} eq "386");
1177     $target{bn_asm_src} =~ s/\w+-gf2m.c// if (defined($disabled{ec2m}));
1178
1179     # bn-586 is the only one implementing bn_*_part_words
1180     push @{$config{defines}}, "OPENSSL_BN_ASM_PART_WORDS" if ($target{bn_asm_src} =~ /bn-586/);
1181     push @{$config{defines}}, "OPENSSL_IA32_SSE2" if (!$no_sse2 && $target{bn_asm_src} =~ /86/);
1182
1183     push @{$config{defines}}, "OPENSSL_BN_ASM_MONT" if ($target{bn_asm_src} =~ /-mont/);
1184     push @{$config{defines}}, "OPENSSL_BN_ASM_MONT5" if ($target{bn_asm_src} =~ /-mont5/);
1185     push @{$config{defines}}, "OPENSSL_BN_ASM_GF2m" if ($target{bn_asm_src} =~ /-gf2m/);
1186
1187     if ($target{sha1_asm_src}) {
1188         push @{$config{defines}}, "SHA1_ASM"   if ($target{sha1_asm_src} =~ /sx86/ || $target{sha1_asm_src} =~ /sha1/);
1189         push @{$config{defines}}, "SHA256_ASM" if ($target{sha1_asm_src} =~ /sha256/);
1190         push @{$config{defines}}, "SHA512_ASM" if ($target{sha1_asm_src} =~ /sha512/);
1191     }
1192     if ($target{rc4_asm_src} ne $table{DEFAULTS}->{rc4_asm_src}) {
1193         push @{$config{defines}}, "RC4_ASM";
1194     }
1195     if ($target{md5_asm_src}) {
1196         push @{$config{defines}}, "MD5_ASM";
1197     }
1198     $target{cast_asm_src}=$table{DEFAULTS}->{cast_asm_src} unless $disabled{pic}; # CAST assembler is not PIC
1199     if ($target{rmd160_asm_src}) {
1200         push @{$config{defines}}, "RMD160_ASM";
1201     }
1202     if ($target{aes_asm_src}) {
1203         push @{$config{defines}}, "AES_ASM" if ($target{aes_asm_src} =~ m/\baes-/);;
1204         # aes-ctr.fake is not a real file, only indication that assembler
1205         # module implements AES_ctr32_encrypt...
1206         push @{$config{defines}}, "AES_CTR_ASM" if ($target{aes_asm_src} =~ s/\s*aes-ctr\.fake//);
1207         # aes-xts.fake indicates presence of AES_xts_[en|de]crypt...
1208         push @{$config{defines}}, "AES_XTS_ASM" if ($target{aes_asm_src} =~ s/\s*aes-xts\.fake//);
1209         $target{aes_asm_src} =~ s/\s*(vpaes|aesni)-x86\.s//g if ($no_sse2);
1210         push @{$config{defines}}, "VPAES_ASM" if ($target{aes_asm_src} =~ m/vpaes/);
1211         push @{$config{defines}}, "BSAES_ASM" if ($target{aes_asm_src} =~ m/bsaes/);
1212     }
1213     if ($target{wp_asm_src} =~ /mmx/) {
1214         if ($config{processor} eq "386") {
1215             $target{wp_asm_src}=$table{DEFAULTS}->{wp_asm_src};
1216         } elsif (!$disabled{"whirlpool"}) {
1217             push @{$config{defines}}, "WHIRLPOOL_ASM";
1218         }
1219     }
1220     if ($target{modes_asm_src} =~ /ghash-/) {
1221         push @{$config{defines}}, "GHASH_ASM";
1222     }
1223     if ($target{ec_asm_src} =~ /ecp_nistz256/) {
1224         push @{$config{defines}}, "ECP_NISTZ256_ASM";
1225     }
1226     if ($target{padlock_asm_src} ne $table{DEFAULTS}->{padlock_asm_src}) {
1227         push @{$config{defines}}, "PADLOCK_ASM";
1228     }
1229     if ($target{poly1305_asm_src} ne "") {
1230         push @{$config{defines}}, "POLY1305_ASM";
1231     }
1232 }
1233
1234 my $ecc = $target{cc};
1235 if ($^O ne "VMS" && !$disabled{makedepend}) {
1236     # Is the compiler gcc or clang?  $ecc is used below to see if
1237     # error-checking can be turned on.
1238     my $ccpcc = "$config{cross_compile_prefix}$target{cc}";
1239     open(PIPE, "$ccpcc --version 2>&1 |");
1240     my $lines = 2;
1241     while ( <PIPE> ) {
1242         # Find the version number and save the major.
1243         m|(?:.*)\b(\d+)\.\d+\.\d+\b(?:.*)|;
1244         my $compiler_major = $1;
1245         # We know that GNU C version 3 and up as well as all clang
1246         # versions support dependency generation
1247         $config{makedepprog} = $ccpcc
1248             if (/clang/ || (/gcc/ && $compiler_major >= 3));
1249         $ecc = "clang" if /clang/;
1250         $ecc = "gcc" if /gcc/;
1251         last if ($config{makedepprog} || !$lines--);
1252     }
1253     close(PIPE);
1254
1255     $config{makedepprog} = which('makedepend') unless $config{makedepprog};
1256     $disabled{makedepend} = "unavailable" unless $config{makedepprog};
1257 }
1258
1259
1260
1261 # Deal with bn_ops ###################################################
1262
1263 $config{bn_ll}                  =0;
1264 $config{export_var_as_fn}       =0;
1265 my $def_int="unsigned int";
1266 $config{rc4_int}                =$def_int;
1267 ($config{b64l},$config{b64},$config{b32})=(0,0,1);
1268
1269 my $count = 0;
1270 foreach (sort split(/\s+/,$target{bn_ops})) {
1271     $count++ if /SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT/;
1272     $config{export_var_as_fn}=1                 if $_ eq 'EXPORT_VAR_AS_FN';
1273     $config{bn_ll}=1                            if $_ eq 'BN_LLONG';
1274     $config{rc4_int}="unsigned char"            if $_ eq 'RC4_CHAR';
1275     ($config{b64l},$config{b64},$config{b32})
1276         =(0,1,0)                                if $_ eq 'SIXTY_FOUR_BIT';
1277     ($config{b64l},$config{b64},$config{b32})
1278         =(1,0,0)                                if $_ eq 'SIXTY_FOUR_BIT_LONG';
1279     ($config{b64l},$config{b64},$config{b32})
1280         =(0,0,1)                                if $_ eq 'THIRTY_TWO_BIT';
1281 }
1282 die "Exactly one of SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT can be set in bn_ops\n"
1283     if $count > 1;
1284
1285
1286 # Hack cflags for better warnings (dev option) #######################
1287
1288 # "Stringify" the C flags string.  This permits it to be made part of a string
1289 # and works as well on command lines.
1290 $config{cflags} =~ s/([\\\"])/\\$1/g;
1291
1292 if (defined($config{api})) {
1293     $config{openssl_api_defines} = [ "OPENSSL_MIN_API=".$apitable->{$config{api}} ];
1294     my $apiflag = sprintf("OPENSSL_API_COMPAT=%s", $apitable->{$config{api}});
1295     push @{$config{defines}}, $apiflag;
1296 }
1297
1298 if ($strict_warnings)
1299         {
1300         my $wopt;
1301         die "ERROR --strict-warnings requires gcc or clang"
1302             unless $ecc eq 'gcc' || $ecc eq 'clang';
1303         foreach $wopt (split /\s+/, $gcc_devteam_warn)
1304                 {
1305                 $config{cflags} .= " $wopt" unless ($config{cflags} =~ /(?:^|\s)$wopt(?:\s|$)/)
1306                 }
1307         if ($ecc eq "clang")
1308                 {
1309                 foreach $wopt (split /\s+/, $clang_devteam_warn)
1310                         {
1311                         $config{cflags} .= " $wopt" unless ($config{cflags} =~ /(?:^|\s)$wopt(?:\s|$)/)
1312                         }
1313                 }
1314         }
1315
1316 unless ($disabled{"crypto-mdebug-backtrace"})
1317         {
1318         foreach my $wopt (split /\s+/, $memleak_devteam_backtrace)
1319                 {
1320                 $config{cflags} .= " $wopt" unless ($config{cflags} =~ /(?:^|\s)$wopt(?:\s|$)/)
1321                 }
1322         if ($target =~ /^BSD-/)
1323                 {
1324                 $config{ex_libs} .= " -lexecinfo";
1325                 }
1326         }
1327
1328 if ($user_cflags ne "") { $config{cflags}="$config{cflags}$user_cflags"; $config{cxxflags}="$config{cxxflags}$user_cflags";}
1329 else                    { $no_user_cflags=1;  }
1330 if (@user_defines) { $config{defines}=[ @{$config{defines}}, @user_defines ]; }
1331 else               { $no_user_defines=1;    }
1332
1333 # ALL MODIFICATIONS TO %config and %target MUST BE DONE FROM HERE ON
1334
1335 unless ($disabled{afalgeng}) {
1336     $config{afalgeng}="";
1337     if ($target =~ m/^linux/) {
1338         my $minver = 4*10000 + 1*100 + 0;
1339         if ($config{cross_compile_prefix} eq "") {
1340             my $verstr = `uname -r`;
1341             my ($ma, $mi1, $mi2) = split("\\.", $verstr);
1342             ($mi2) = $mi2 =~ /(\d+)/;
1343             my $ver = $ma*10000 + $mi1*100 + $mi2;
1344             if ($ver < $minver) {
1345                 $disabled{afalgeng} = "too-old-kernel";
1346             } else {
1347                 push @{$config{engdirs}}, "afalg";
1348             }
1349         } else {
1350             $disabled{afalgeng} = "cross-compiling";
1351         }
1352     } else {
1353         $disabled{afalgeng}  = "not-linux";
1354     }
1355 }
1356
1357 push @{$config{openssl_other_defines}}, "OPENSSL_NO_AFALGENG" if ($disabled{afalgeng});
1358
1359 # If we use the unified build, collect information from build.info files
1360 my %unified_info = ();
1361
1362 my $buildinfo_debug = defined($ENV{CONFIGURE_DEBUG_BUILDINFO});
1363 if ($builder eq "unified") {
1364     use lib catdir(dirname(__FILE__),"util");
1365     use with_fallback qw(Text::Template);
1366
1367     sub cleandir {
1368         my $base = shift;
1369         my $dir = shift;
1370         my $relativeto = shift || ".";
1371
1372         $dir = catdir($base,$dir) unless isabsolute($dir);
1373
1374         # Make sure the directories we're building in exists
1375         mkpath($dir);
1376
1377         my $res = abs2rel(absolutedir($dir), rel2abs($relativeto));
1378         #print STDERR "DEBUG[cleandir]: $dir , $base => $res\n";
1379         return $res;
1380     }
1381
1382     sub cleanfile {
1383         my $base = shift;
1384         my $file = shift;
1385         my $relativeto = shift || ".";
1386
1387         $file = catfile($base,$file) unless isabsolute($file);
1388
1389         my $d = dirname($file);
1390         my $f = basename($file);
1391
1392         # Make sure the directories we're building in exists
1393         mkpath($d);
1394
1395         my $res = abs2rel(catfile(absolutedir($d), $f), rel2abs($relativeto));
1396         #print STDERR "DEBUG[cleanfile]: $d , $f => $res\n";
1397         return $res;
1398     }
1399
1400     # Store the name of the template file we will build the build file from
1401     # in %config.  This may be useful for the build file itself.
1402     my @build_file_template_names =
1403         ( $builder_platform."-".$target{build_file}.".tmpl",
1404           $target{build_file}.".tmpl" );
1405     my @build_file_templates = ();
1406
1407     # First, look in the user provided directory, if given
1408     if (defined $ENV{$local_config_envname}) {
1409         @build_file_templates =
1410             map {
1411                 if ($^O eq 'VMS') {
1412                     # VMS environment variables are logical names,
1413                     # which can be used as is
1414                     $local_config_envname . ':' . $_;
1415                 } else {
1416                     catfile($ENV{$local_config_envname}, $_);
1417                 }
1418             }
1419             @build_file_template_names;
1420     }
1421     # Then, look in our standard directory
1422     push @build_file_templates,
1423         ( map { cleanfile($srcdir, catfile("Configurations", $_), $blddir) }
1424           @build_file_template_names );
1425
1426     my $build_file_template;
1427     for $_ (@build_file_templates) {
1428         $build_file_template = $_;
1429         last if -f $build_file_template;
1430
1431         $build_file_template = undef;
1432     }
1433     if (!defined $build_file_template) {
1434         die "*** Couldn't find any of:\n", join("\n", @build_file_templates), "\n";
1435     }
1436     $config{build_file_templates}
1437       = [ $build_file_template,
1438           cleanfile($srcdir, catfile("Configurations", "common.tmpl"),
1439                     $blddir) ];
1440
1441     my @build_infos = ( [ ".", "build.info" ] );
1442     foreach (@{$config{dirs}}) {
1443         push @build_infos, [ $_, "build.info" ]
1444             if (-f catfile($srcdir, $_, "build.info"));
1445     }
1446     foreach (@{$config{sdirs}}) {
1447         push @build_infos, [ catdir("crypto", $_), "build.info" ]
1448             if (-f catfile($srcdir, "crypto", $_, "build.info"));
1449     }
1450     foreach (@{$config{engdirs}}) {
1451         push @build_infos, [ catdir("engines", $_), "build.info" ]
1452             if (-f catfile($srcdir, "engines", $_, "build.info"));
1453     }
1454     foreach (@{$config{tdirs}}) {
1455         push @build_infos, [ catdir("test", $_), "build.info" ]
1456             if (-f catfile($srcdir, "test", $_, "build.info"));
1457     }
1458
1459     $config{build_infos} = [ ];
1460
1461     foreach (@build_infos) {
1462         my $sourced = catdir($srcdir, $_->[0]);
1463         my $buildd = catdir($blddir, $_->[0]);
1464
1465         mkpath($buildd);
1466
1467         my $f = $_->[1];
1468         # The basic things we're trying to build
1469         my @programs = ();
1470         my @programs_install = ();
1471         my @libraries = ();
1472         my @libraries_install = ();
1473         my @engines = ();
1474         my @engines_install = ();
1475         my @scripts = ();
1476         my @scripts_install = ();
1477         my @extra = ();
1478         my @overrides = ();
1479         my @intermediates = ();
1480         my @rawlines = ();
1481
1482         my %ordinals = ();
1483         my %sources = ();
1484         my %shared_sources = ();
1485         my %includes = ();
1486         my %depends = ();
1487         my %renames = ();
1488         my %sharednames = ();
1489         my %generate = ();
1490
1491         push @{$config{build_infos}}, catfile(abs2rel($sourced, $blddir), $f);
1492         my $template = Text::Template->new(TYPE => 'FILE',
1493                                            SOURCE => catfile($sourced, $f));
1494         die "Something went wrong with $sourced/$f: $!\n" unless $template;
1495         my @text =
1496             split /^/m,
1497             $template->fill_in(HASH => { config => \%config,
1498                                          target => \%target,
1499                                          disabled => \%disabled,
1500                                          withargs => \%withargs,
1501                                          builddir => abs2rel($buildd, $blddir),
1502                                          sourcedir => abs2rel($sourced, $blddir),
1503                                          buildtop => abs2rel($blddir, $blddir),
1504                                          sourcetop => abs2rel($srcdir, $blddir) },
1505                                DELIMITERS => [ "{-", "-}" ]);
1506
1507         # The top item of this stack has the following values
1508         # -2 positive already run and we found ELSE (following ELSIF should fail)
1509         # -1 positive already run (skip until ENDIF)
1510         # 0 negatives so far (if we're at a condition, check it)
1511         # 1 last was positive (don't skip lines until next ELSE, ELSIF or ENDIF)
1512         # 2 positive ELSE (following ELSIF should fail)
1513         my @skip = ();
1514         collect_information(
1515             collect_from_array([ @text ],
1516                                qr/\\$/ => sub { my $l1 = shift; my $l2 = shift;
1517                                                 $l1 =~ s/\\$//; $l1.$l2 }),
1518             # Info we're looking for
1519             qr/^\s*IF\[((?:\\.|[^\\\]])*)\]\s*$/
1520             => sub {
1521                 if (! @skip || $skip[$#skip] > 0) {
1522                     push @skip, !! $1;
1523                 } else {
1524                     push @skip, -1;
1525                 }
1526             },
1527             qr/^\s*ELSIF\[((?:\\.|[^\\\]])*)\]\s*$/
1528             => sub { die "ELSIF out of scope" if ! @skip;
1529                      die "ELSIF following ELSE" if abs($skip[$#skip]) == 2;
1530                      $skip[$#skip] = -1 if $skip[$#skip] != 0;
1531                      $skip[$#skip] = !! $1
1532                          if $skip[$#skip] == 0; },
1533             qr/^\s*ELSE\s*$/
1534             => sub { die "ELSE out of scope" if ! @skip;
1535                      $skip[$#skip] = -2 if $skip[$#skip] != 0;
1536                      $skip[$#skip] = 2 if $skip[$#skip] == 0; },
1537             qr/^\s*ENDIF\s*$/
1538             => sub { die "ENDIF out of scope" if ! @skip;
1539                      pop @skip; },
1540             qr/^\s*PROGRAMS(_NO_INST)?\s*=\s*(.*)\s*$/
1541             => sub {
1542                 if (!@skip || $skip[$#skip] > 0) {
1543                     my $install = $1;
1544                     my @x = tokenize($2);
1545                     push @programs, @x;
1546                     push @programs_install, @x unless $install;
1547                 }
1548             },
1549             qr/^\s*LIBS(_NO_INST)?\s*=\s*(.*)\s*$/
1550             => sub {
1551                 if (!@skip || $skip[$#skip] > 0) {
1552                     my $install = $1;
1553                     my @x = tokenize($2);
1554                     push @libraries, @x;
1555                     push @libraries_install, @x unless $install;
1556                 }
1557             },
1558             qr/^\s*ENGINES(_NO_INST)?\s*=\s*(.*)\s*$/
1559             => sub {
1560                 if (!@skip || $skip[$#skip] > 0) {
1561                     my $install = $1;
1562                     my @x = tokenize($2);
1563                     push @engines, @x;
1564                     push @engines_install, @x unless $install;
1565                 }
1566             },
1567             qr/^\s*SCRIPTS(_NO_INST)?\s*=\s*(.*)\s*$/
1568             => sub {
1569                 if (!@skip || $skip[$#skip] > 0) {
1570                     my $install = $1;
1571                     my @x = tokenize($2);
1572                     push @scripts, @x;
1573                     push @scripts_install, @x unless $install;
1574                 }
1575             },
1576             qr/^\s*EXTRA\s*=\s*(.*)\s*$/
1577             => sub { push @extra, tokenize($1)
1578                          if !@skip || $skip[$#skip] > 0 },
1579             qr/^\s*OVERRIDES\s*=\s*(.*)\s*$/
1580             => sub { push @overrides, tokenize($1)
1581                          if !@skip || $skip[$#skip] > 0 },
1582
1583             qr/^\s*ORDINALS\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/,
1584             => sub { push @{$ordinals{$1}}, tokenize($2)
1585                          if !@skip || $skip[$#skip] > 0 },
1586             qr/^\s*SOURCE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1587             => sub { push @{$sources{$1}}, tokenize($2)
1588                          if !@skip || $skip[$#skip] > 0 },
1589             qr/^\s*SHARED_SOURCE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1590             => sub { push @{$shared_sources{$1}}, tokenize($2)
1591                          if !@skip || $skip[$#skip] > 0 },
1592             qr/^\s*INCLUDE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1593             => sub { push @{$includes{$1}}, tokenize($2)
1594                          if !@skip || $skip[$#skip] > 0 },
1595             qr/^\s*DEPEND\[((?:\\.|[^\\\]])*)\]\s*=\s*(.*)\s*$/
1596             => sub { push @{$depends{$1}}, tokenize($2)
1597                          if !@skip || $skip[$#skip] > 0 },
1598             qr/^\s*GENERATE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1599             => sub { push @{$generate{$1}}, $2
1600                          if !@skip || $skip[$#skip] > 0 },
1601             qr/^\s*RENAME\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1602             => sub { push @{$renames{$1}}, tokenize($2)
1603                          if !@skip || $skip[$#skip] > 0 },
1604             qr/^\s*SHARED_NAME\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1605             => sub { push @{$sharednames{$1}}, tokenize($2)
1606                          if !@skip || $skip[$#skip] > 0 },
1607             qr/^\s*BEGINRAW\[((?:\\.|[^\\\]])+)\]\s*$/
1608             => sub {
1609                 my $lineiterator = shift;
1610                 my $target_kind = $1;
1611                 while (defined $lineiterator->()) {
1612                     s|\R$||;
1613                     if (/^\s*ENDRAW\[((?:\\.|[^\\\]])+)\]\s*$/) {
1614                         die "ENDRAW doesn't match BEGINRAW"
1615                             if $1 ne $target_kind;
1616                         last;
1617                     }
1618                     next if @skip && $skip[$#skip] <= 0;
1619                     push @rawlines,  $_
1620                         if ($target_kind eq $target{build_file}
1621                             || $target_kind eq $target{build_file}."(".$builder_platform.")");
1622                 }
1623             },
1624             qr/^\s*(?:#.*)?$/ => sub { },
1625             "OTHERWISE" => sub { die "Something wrong with this line:\n$_\nat $sourced/$f" },
1626             "BEFORE" => sub {
1627                 if ($buildinfo_debug) {
1628                     print STDERR "DEBUG: Parsing ",join(" ", @_),"\n";
1629                     print STDERR "DEBUG: ... before parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
1630                 }
1631             },
1632             "AFTER" => sub {
1633                 if ($buildinfo_debug) {
1634                     print STDERR "DEBUG: .... after parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
1635                 }
1636             },
1637             );
1638         die "runaway IF?" if (@skip);
1639
1640         foreach (keys %renames) {
1641             die "$_ renamed to more than one thing: "
1642                 ,join(" ", @{$renames{$_}}),"\n"
1643                 if scalar @{$renames{$_}} > 1;
1644             my $dest = cleanfile($buildd, $_, $blddir);
1645             my $to = cleanfile($buildd, $renames{$_}->[0], $blddir);
1646             die "$dest renamed to more than one thing: "
1647                 ,$unified_info{rename}->{$dest}, $to
1648                 unless !defined($unified_info{rename}->{$dest})
1649                 or $unified_info{rename}->{$dest} eq $to;
1650             $unified_info{rename}->{$dest} = $to;
1651         }
1652
1653         foreach (@programs) {
1654             my $program = cleanfile($buildd, $_, $blddir);
1655             if ($unified_info{rename}->{$program}) {
1656                 $program = $unified_info{rename}->{$program};
1657             }
1658             $unified_info{programs}->{$program} = 1;
1659         }
1660
1661         foreach (@programs_install) {
1662             my $program = cleanfile($buildd, $_, $blddir);
1663             if ($unified_info{rename}->{$program}) {
1664                 $program = $unified_info{rename}->{$program};
1665             }
1666             $unified_info{install}->{programs}->{$program} = 1;
1667         }
1668
1669         foreach (@libraries) {
1670             my $library = cleanfile($buildd, $_, $blddir);
1671             if ($unified_info{rename}->{$library}) {
1672                 $library = $unified_info{rename}->{$library};
1673             }
1674             $unified_info{libraries}->{$library} = 1;
1675         }
1676
1677         foreach (@libraries_install) {
1678             my $library = cleanfile($buildd, $_, $blddir);
1679             if ($unified_info{rename}->{$library}) {
1680                 $library = $unified_info{rename}->{$library};
1681             }
1682             $unified_info{install}->{libraries}->{$library} = 1;
1683         }
1684
1685         die <<"EOF" if scalar @engines and !$config{dynamic_engines};
1686 ENGINES can only be used if configured with 'dynamic-engine'.
1687 This is usually a fault in a build.info file.
1688 EOF
1689         foreach (@engines) {
1690             my $library = cleanfile($buildd, $_, $blddir);
1691             if ($unified_info{rename}->{$library}) {
1692                 $library = $unified_info{rename}->{$library};
1693             }
1694             $unified_info{engines}->{$library} = 1;
1695         }
1696
1697         foreach (@engines_install) {
1698             my $library = cleanfile($buildd, $_, $blddir);
1699             if ($unified_info{rename}->{$library}) {
1700                 $library = $unified_info{rename}->{$library};
1701             }
1702             $unified_info{install}->{engines}->{$library} = 1;
1703         }
1704
1705         foreach (@scripts) {
1706             my $script = cleanfile($buildd, $_, $blddir);
1707             if ($unified_info{rename}->{$script}) {
1708                 $script = $unified_info{rename}->{$script};
1709             }
1710             $unified_info{scripts}->{$script} = 1;
1711         }
1712
1713         foreach (@scripts_install) {
1714             my $script = cleanfile($buildd, $_, $blddir);
1715             if ($unified_info{rename}->{$script}) {
1716                 $script = $unified_info{rename}->{$script};
1717             }
1718             $unified_info{install}->{scripts}->{$script} = 1;
1719         }
1720
1721         foreach (@extra) {
1722             my $extra = cleanfile($buildd, $_, $blddir);
1723             $unified_info{extra}->{$extra} = 1;
1724         }
1725
1726         foreach (@overrides) {
1727             my $override = cleanfile($buildd, $_, $blddir);
1728             $unified_info{overrides}->{$override} = 1;
1729         }
1730
1731         push @{$unified_info{rawlines}}, @rawlines;
1732
1733         unless ($disabled{shared}) {
1734             # Check sharednames.
1735             foreach (keys %sharednames) {
1736                 my $dest = cleanfile($buildd, $_, $blddir);
1737                 if ($unified_info{rename}->{$dest}) {
1738                     $dest = $unified_info{rename}->{$dest};
1739                 }
1740                 die "shared_name for $dest with multiple values: "
1741                     ,join(" ", @{$sharednames{$_}}),"\n"
1742                     if scalar @{$sharednames{$_}} > 1;
1743                 my $to = cleanfile($buildd, $sharednames{$_}->[0], $blddir);
1744                 die "shared_name found for a library $dest that isn't defined\n"
1745                     unless $unified_info{libraries}->{$dest};
1746                 die "shared_name for $dest with multiple values: "
1747                     ,$unified_info{sharednames}->{$dest}, ", ", $to
1748                     unless !defined($unified_info{sharednames}->{$dest})
1749                     or $unified_info{sharednames}->{$dest} eq $to;
1750                 $unified_info{sharednames}->{$dest} = $to;
1751             }
1752
1753             # Additionally, we set up sharednames for libraries that don't
1754             # have any, as themselves.  Only for libraries that aren't
1755             # explicitely static.
1756             foreach (grep !/\.a$/, keys %{$unified_info{libraries}}) {
1757                 if (!defined $unified_info{sharednames}->{$_}) {
1758                     $unified_info{sharednames}->{$_} = $_
1759                 }
1760             }
1761
1762             # Check that we haven't defined any library as both shared and
1763             # explicitely static.  That is forbidden.
1764             my @doubles = ();
1765             foreach (grep /\.a$/, keys %{$unified_info{libraries}}) {
1766                 (my $l = $_) =~ s/\.a$//;
1767                 push @doubles, $l if defined $unified_info{sharednames}->{$l};
1768             }
1769             die "these libraries are both explicitely static and shared:\n  ",
1770                 join(" ", @doubles), "\n"
1771                 if @doubles;
1772         }
1773
1774         foreach (keys %ordinals) {
1775             my $dest = $_;
1776             my $ddest = cleanfile($buildd, $_, $blddir);
1777             if ($unified_info{rename}->{$ddest}) {
1778                 $ddest = $unified_info{rename}->{$ddest};
1779             }
1780             foreach (@{$ordinals{$dest}}) {
1781                 my %known_ordinals =
1782                     (
1783                      crypto =>
1784                      cleanfile($sourced, catfile("util", "libcrypto.num"), $blddir),
1785                      ssl =>
1786                      cleanfile($sourced, catfile("util", "libssl.num"), $blddir)
1787                     );
1788                 my $o = $known_ordinals{$_};
1789                 die "Ordinals for $ddest defined more than once\n"
1790                     if $unified_info{ordinals}->{$ddest};
1791                 $unified_info{ordinals}->{$ddest} = [ $_, $o ];
1792             }
1793         }
1794
1795         foreach (keys %sources) {
1796             my $dest = $_;
1797             my $ddest = cleanfile($buildd, $_, $blddir);
1798             if ($unified_info{rename}->{$ddest}) {
1799                 $ddest = $unified_info{rename}->{$ddest};
1800             }
1801             foreach (@{$sources{$dest}}) {
1802                 my $s = cleanfile($sourced, $_, $blddir);
1803
1804                 # If it isn't in the source tree, we assume it's generated
1805                 # in the build tree
1806                 if (! -f $s) {
1807                     $s = cleanfile($buildd, $_, $blddir);
1808                 }
1809                 # We recognise C++, C and asm files
1810                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
1811                     my $o = $_;
1812                     $o =~ s/\.[csS]$/.o/; # C and assembler
1813                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
1814                     $o = cleanfile($buildd, $o, $blddir);
1815                     $unified_info{sources}->{$ddest}->{$o} = 1;
1816                     $unified_info{sources}->{$o}->{$s} = 1;
1817                 } else {
1818                     $unified_info{sources}->{$ddest}->{$s} = 1;
1819                 }
1820             }
1821         }
1822
1823         foreach (keys %shared_sources) {
1824             my $dest = $_;
1825             my $ddest = cleanfile($buildd, $_, $blddir);
1826             if ($unified_info{rename}->{$ddest}) {
1827                 $ddest = $unified_info{rename}->{$ddest};
1828             }
1829             foreach (@{$shared_sources{$dest}}) {
1830                 my $s = cleanfile($sourced, $_, $blddir);
1831
1832                 # If it isn't in the source tree, we assume it's generated
1833                 # in the build tree
1834                 if (! -f $s) {
1835                     $s = cleanfile($buildd, $_, $blddir);
1836                 }
1837                 # We recognise C++, C and asm files
1838                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
1839                     my $o = $_;
1840                     $o =~ s/\.[csS]$/.o/; # C and assembler
1841                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
1842                     $o = cleanfile($buildd, $o, $blddir);
1843                     $unified_info{shared_sources}->{$ddest}->{$o} = 1;
1844                     $unified_info{sources}->{$o}->{$s} = 1;
1845                 } else {
1846                     die "unrecognised source file type for shared library: $s\n";
1847                 }
1848             }
1849         }
1850
1851         foreach (keys %generate) {
1852             my $dest = $_;
1853             my $ddest = cleanfile($buildd, $_, $blddir);
1854             if ($unified_info{rename}->{$ddest}) {
1855                 $ddest = $unified_info{rename}->{$ddest};
1856             }
1857             die "more than one generator for $dest: "
1858                     ,join(" ", @{$generate{$_}}),"\n"
1859                     if scalar @{$generate{$_}} > 1;
1860             my @generator = split /\s+/, $generate{$dest}->[0];
1861             $generator[0] = cleanfile($sourced, $generator[0], $blddir),
1862             $unified_info{generate}->{$ddest} = [ @generator ];
1863         }
1864
1865         foreach (keys %depends) {
1866             my $dest = $_;
1867             my $ddest = $dest eq "" ? "" : cleanfile($sourced, $_, $blddir);
1868
1869             # If the destination doesn't exist in source, it can only be
1870             # a generated file in the build tree.
1871             if ($ddest ne "" && ! -f $ddest) {
1872                 $ddest = cleanfile($buildd, $_, $blddir);
1873                 if ($unified_info{rename}->{$ddest}) {
1874                     $ddest = $unified_info{rename}->{$ddest};
1875                 }
1876             }
1877             foreach (@{$depends{$dest}}) {
1878                 my $d = cleanfile($sourced, $_, $blddir);
1879
1880                 # If we know it's generated, or assume it is because we can't
1881                 # find it in the source tree, we set file we depend on to be
1882                 # in the build tree rather than the source tree, and assume
1883                 # and that there are lines to build it in a BEGINRAW..ENDRAW
1884                 # section or in the Makefile template.
1885                 if (! -f $d
1886                     || (grep { $d eq $_ }
1887                         map { cleanfile($srcdir, $_, $blddir) }
1888                         grep { /\.h$/ } keys %{$unified_info{generate}})) {
1889                     $d = cleanfile($buildd, $_, $blddir);
1890                 }
1891                 # Take note if the file to depend on is being renamed
1892                 # Take extra care with files ending with .a, they should
1893                 # be treated without that extension, and the extension
1894                 # should be added back after treatment.
1895                 $d =~ /(\.a)?$/;
1896                 my $e = $1 // "";
1897                 $d = $`;
1898                 if ($unified_info{rename}->{$d}) {
1899                     $d = $unified_info{rename}->{$d};
1900                 }
1901                 $d .= $e;
1902                 $unified_info{depends}->{$ddest}->{$d} = 1;
1903                 # If we depend on a header file or a perl module, let's make
1904                 # sure it can get included
1905                 if ($dest ne "" && $d =~ /\.(h|pm)$/) {
1906                     my $i = dirname($d);
1907                     push @{$unified_info{includes}->{$ddest}->{source}}, $i
1908                         unless grep { $_ eq $i } @{$unified_info{includes}->{$ddest}->{source}};
1909                 }
1910             }
1911         }
1912
1913         foreach (keys %includes) {
1914             my $dest = $_;
1915             my $ddest = cleanfile($sourced, $_, $blddir);
1916
1917             # If the destination doesn't exist in source, it can only be
1918             # a generated file in the build tree.
1919             if (! -f $ddest) {
1920                 $ddest = cleanfile($buildd, $_, $blddir);
1921                 if ($unified_info{rename}->{$ddest}) {
1922                     $ddest = $unified_info{rename}->{$ddest};
1923                 }
1924             }
1925             foreach (@{$includes{$dest}}) {
1926                 my $is = cleandir($sourced, $_, $blddir);
1927                 my $ib = cleandir($buildd, $_, $blddir);
1928                 push @{$unified_info{includes}->{$ddest}->{source}}, $is
1929                     unless grep { $_ eq $is } @{$unified_info{includes}->{$ddest}->{source}};
1930                 push @{$unified_info{includes}->{$ddest}->{build}}, $ib
1931                     unless grep { $_ eq $ib } @{$unified_info{includes}->{$ddest}->{build}};
1932             }
1933         }
1934     }
1935
1936     ### Make unified_info a bit more efficient
1937     # One level structures
1938     foreach (("programs", "libraries", "engines", "scripts", "extra", "overrides")) {
1939         $unified_info{$_} = [ sort keys %{$unified_info{$_}} ];
1940     }
1941     # Two level structures
1942     foreach my $l1 (("install", "sources", "shared_sources", "ldadd", "depends")) {
1943         foreach my $l2 (sort keys %{$unified_info{$l1}}) {
1944             $unified_info{$l1}->{$l2} =
1945                 [ sort keys %{$unified_info{$l1}->{$l2}} ];
1946         }
1947     }
1948     # Includes
1949     foreach my $dest (sort keys %{$unified_info{includes}}) {
1950         if (defined($unified_info{includes}->{$dest}->{build})) {
1951             my @source_includes =
1952                 ( @{$unified_info{includes}->{$dest}->{source}} );
1953             $unified_info{includes}->{$dest} =
1954                 [ @{$unified_info{includes}->{$dest}->{build}} ];
1955             foreach my $inc (@source_includes) {
1956                 push @{$unified_info{includes}->{$dest}}, $inc
1957                     unless grep { $_ eq $inc } @{$unified_info{includes}->{$dest}};
1958             }
1959         } else {
1960             $unified_info{includes}->{$dest} =
1961                 [ @{$unified_info{includes}->{$dest}->{source}} ];
1962         }
1963     }
1964 }
1965
1966 # For the schemes that need it, we provide the old *_obj configs
1967 # from the *_asm_obj ones
1968 foreach (grep /_(asm|aux)_src$/, keys %target) {
1969     my $src = $_;
1970     (my $obj = $_) =~ s/_(asm|aux)_src$/_obj/;
1971     $target{$obj} = $target{$src};
1972     $target{$obj} =~ s/\.[csS]\b/.o/g; # C and assembler
1973     $target{$obj} =~ s/\.(cc|cpp)\b/_cc.o/g; # C++
1974 }
1975
1976 # Write down our configuration where it fits #########################
1977
1978 open(OUT,">configdata.pm") || die "unable to create configdata.pm: $!\n";
1979 print OUT <<"EOF";
1980 package configdata;
1981
1982 use strict;
1983 use warnings;
1984
1985 use Exporter;
1986 #use vars qw(\@ISA \@EXPORT);
1987 our \@ISA = qw(Exporter);
1988 our \@EXPORT = qw(\%config \%target \%disabled \%withargs \%unified_info \@disablables);
1989
1990 EOF
1991 print OUT "our %config = (\n";
1992 foreach (sort keys %config) {
1993     if (ref($config{$_}) eq "ARRAY") {
1994         print OUT "  ", $_, " => [ ", join(", ",
1995                                            map { quotify("perl", $_) }
1996                                            @{$config{$_}}), " ],\n";
1997     } else {
1998         print OUT "  ", $_, " => ", quotify("perl", $config{$_}), ",\n"
1999     }
2000 }
2001 print OUT <<"EOF";
2002 );
2003
2004 EOF
2005 print OUT "our %target = (\n";
2006 foreach (sort keys %target) {
2007     if (ref($target{$_}) eq "ARRAY") {
2008         print OUT "  ", $_, " => [ ", join(", ",
2009                                            map { quotify("perl", $_) }
2010                                            @{$target{$_}}), " ],\n";
2011     } else {
2012         print OUT "  ", $_, " => ", quotify("perl", $target{$_}), ",\n"
2013     }
2014 }
2015 print OUT <<"EOF";
2016 );
2017
2018 EOF
2019 print OUT "our \%available_protocols = (\n";
2020 print OUT "  tls => [ ", join(", ", map { quotify("perl", $_) } @tls), " ],\n";
2021 print OUT "  dtls => [ ", join(", ", map { quotify("perl", $_) } @dtls), " ],\n";
2022 print OUT <<"EOF";
2023 );
2024
2025 EOF
2026 print OUT "our \@disablables = (\n";
2027 foreach (@disablables) {
2028     print OUT "  ", quotify("perl", $_), ",\n";
2029 }
2030 print OUT <<"EOF";
2031 );
2032
2033 EOF
2034 print OUT "our \%disabled = (\n";
2035 foreach (sort keys %disabled) {
2036     print OUT "  ", quotify("perl", $_), " => ", quotify("perl", $disabled{$_}), ",\n";
2037 }
2038 print OUT <<"EOF";
2039 );
2040
2041 EOF
2042 print OUT "our %withargs = (\n";
2043 foreach (sort keys %withargs) {
2044     if (ref($withargs{$_}) eq "ARRAY") {
2045         print OUT "  ", $_, " => [ ", join(", ",
2046                                            map { quotify("perl", $_) }
2047                                            @{$withargs{$_}}), " ],\n";
2048     } else {
2049         print OUT "  ", $_, " => ", quotify("perl", $withargs{$_}), ",\n"
2050     }
2051 }
2052 print OUT <<"EOF";
2053 );
2054
2055 EOF
2056 if ($builder eq "unified") {
2057     my $recurse;
2058     $recurse = sub {
2059         my $indent = shift;
2060         foreach (@_) {
2061             if (ref $_ eq "ARRAY") {
2062                 print OUT " "x$indent, "[\n";
2063                 foreach (@$_) {
2064                     $recurse->($indent + 4, $_);
2065                 }
2066                 print OUT " "x$indent, "],\n";
2067             } elsif (ref $_ eq "HASH") {
2068                 my %h = %$_;
2069                 print OUT " "x$indent, "{\n";
2070                 foreach (sort keys %h) {
2071                     if (ref $h{$_} eq "") {
2072                         print OUT " "x($indent + 4), quotify("perl", $_), " => ", quotify("perl", $h{$_}), ",\n";
2073                     } else {
2074                         print OUT " "x($indent + 4), quotify("perl", $_), " =>\n";
2075                         $recurse->($indent + 8, $h{$_});
2076                     }
2077                 }
2078                 print OUT " "x$indent, "},\n";
2079             } else {
2080                 print OUT " "x$indent, quotify("perl", $_), ",\n";
2081             }
2082         }
2083     };
2084     print OUT "our %unified_info = (\n";
2085     foreach (sort keys %unified_info) {
2086         if (ref $unified_info{$_} eq "") {
2087             print OUT " "x4, quotify("perl", $_), " => ", quotify("perl", $unified_info{$_}), ",\n";
2088         } else {
2089             print OUT " "x4, quotify("perl", $_), " =>\n";
2090             $recurse->(8, $unified_info{$_});
2091         }
2092     }
2093     print OUT <<"EOF";
2094 );
2095
2096 EOF
2097 }
2098 print OUT "1;\n";
2099 close(OUT);
2100
2101 print "\n";
2102 print "PROCESSOR     =$config{processor}\n" if $config{processor};
2103 print "PERL          =$config{perl}\n";
2104 print "PERLVERSION   =$Config{version} for $Config{archname}\n";
2105 print "HASHBANGPERL  =$config{hashbangperl}\n";
2106 print "CC            =$config{cross_compile_prefix}$target{cc}\n";
2107 print "CFLAG         =$target{cflags} $config{cflags}\n";
2108 print "CXX           =$config{cross_compile_prefix}$target{cxx}\n"
2109     if defined $target{cxx};
2110 print "CXXFLAG       =$target{cxxflags} $config{cxxflags}\n"
2111     if defined $target{cxx};
2112 print "DEFINES       =",join(" ", @{$target{defines}}, @{$config{defines}}),"\n";
2113 #print "RANLIB        =", $target{ranlib} eq '$(CROSS_COMPILE)ranlib' ?
2114 #                             "$config{cross_compile_prefix}ranlib" :
2115 #                             "$target{ranlib}", "\n";
2116 print "EX_LIBS       =$target{ex_libs} $config{ex_libs}\n";
2117
2118 my %builders = (
2119     unified => sub {
2120         run_dofile(catfile($blddir, $target{build_file}),
2121                    @{$config{build_file_templates}});
2122     },
2123     );
2124
2125 $builders{$builder}->($builder_platform, @builder_opts);
2126
2127 print <<"EOF" if ($disabled{threads} eq "unavailable");
2128
2129 The library could not be configured for supporting multi-threaded
2130 applications as the compiler options required on this system are not known.
2131 See file INSTALL for details if you need multi-threading.
2132 EOF
2133
2134 print <<"EOF" if ($no_shared_warn);
2135
2136 The options 'shared', 'pic' and 'dynamic-engine' aren't supported on this
2137 platform, so we will pretend you gave the option 'no-pic', which also disables
2138 'shared' and 'dynamic-engine'.  If you know how to implement shared libraries
2139 or position independent code, please let us know (but please first make sure
2140 you have tried with a current version of OpenSSL).
2141 EOF
2142
2143 print <<"EOF" if (-f catfile($srcdir, "configdata.pm") && $srcdir ne $blddir);
2144
2145 WARNING: there are indications that another build was made in the source
2146 directory.  This build may have picked up artifacts from that build, the
2147 safest course of action is to clean the source directory and redo this
2148 configuration.
2149 EOF
2150
2151 exit(0);
2152
2153 ######################################################################
2154 #
2155 # Helpers and utility functions
2156 #
2157
2158 # Configuration file reading #########################################
2159
2160 # Note: All of the helper functions are for lazy evaluation.  They all
2161 # return a CODE ref, which will return the intended value when evaluated.
2162 # Thus, whenever there's mention of a returned value, it's about that
2163 # intended value.
2164
2165 # Helper function to implement conditional inheritance depending on the
2166 # value of $disabled{asm}.  Used in inherit_from values as follows:
2167 #
2168 #      inherit_from => [ "template", asm("asm_tmpl") ]
2169 #
2170 sub asm {
2171     my @x = @_;
2172     sub {
2173         $disabled{asm} ? () : @x;
2174     }
2175 }
2176
2177 # Helper function to implement conditional value variants, with a default
2178 # plus additional values based on the value of $config{build_type}.
2179 # Arguments are given in hash table form:
2180 #
2181 #       picker(default => "Basic string: ",
2182 #              debug   => "debug",
2183 #              release => "release")
2184 #
2185 # When configuring with --debug, the resulting string will be
2186 # "Basic string: debug", and when not, it will be "Basic string: release"
2187 #
2188 # This can be used to create variants of sets of flags according to the
2189 # build type:
2190 #
2191 #       cflags => picker(default => "-Wall",
2192 #                        debug   => "-g -O0",
2193 #                        release => "-O3")
2194 #
2195 sub picker {
2196     my %opts = @_;
2197     return sub { add($opts{default} || (),
2198                      $opts{$config{build_type}} || ())->(); }
2199 }
2200
2201 # Helper function to combine several values of different types into one.
2202 # This is useful if you want to combine a string with the result of a
2203 # lazy function, such as:
2204 #
2205 #       cflags => combine("-Wall", sub { $disabled{zlib} ? () : "-DZLIB" })
2206 #
2207 sub combine {
2208     my @stuff = @_;
2209     return sub { add(@stuff)->(); }
2210 }
2211
2212 # Helper function to implement conditional values depending on the value
2213 # of $disabled{threads}.  Can be used as follows:
2214 #
2215 #       cflags => combine("-Wall", threads("-pthread"))
2216 #
2217 sub threads {
2218     my @flags = @_;
2219     return sub { add($disabled{threads} ? () : @flags)->(); }
2220 }
2221
2222
2223
2224 our $add_called = 0;
2225 # Helper function to implement adding values to already existing configuration
2226 # values.  It handles elements that are ARRAYs, CODEs and scalars
2227 sub _add {
2228     my $separator = shift;
2229
2230     # If there's any ARRAY in the collection of values OR the separator
2231     # is undef, we will return an ARRAY of combined values, otherwise a
2232     # string of joined values with $separator as the separator.
2233     my $found_array = !defined($separator);
2234
2235     my @values =
2236         map {
2237             my $res = $_;
2238             while (ref($res) eq "CODE") {
2239                 $res = $res->();
2240             }
2241             if (defined($res)) {
2242                 if (ref($res) eq "ARRAY") {
2243                     $found_array = 1;
2244                     @$res;
2245                 } else {
2246                     $res;
2247                 }
2248             } else {
2249                 ();
2250             }
2251     } (@_);
2252
2253     $add_called = 1;
2254
2255     if ($found_array) {
2256         [ @values ];
2257     } else {
2258         join($separator, grep { defined($_) && $_ ne "" } @values);
2259     }
2260 }
2261 sub add_before {
2262     my $separator = " ";
2263     if (ref($_[$#_]) eq "HASH") {
2264         my $opts = pop;
2265         $separator = $opts->{separator};
2266     }
2267     my @x = @_;
2268     sub { _add($separator, @x, @_) };
2269 }
2270 sub add {
2271     my $separator = " ";
2272     if (ref($_[$#_]) eq "HASH") {
2273         my $opts = pop;
2274         $separator = $opts->{separator};
2275     }
2276     my @x = @_;
2277     sub { _add($separator, @_, @x) };
2278 }
2279
2280 # configuration reader, evaluates the input file as a perl script and expects
2281 # it to fill %targets with target configurations.  Those are then added to
2282 # %table.
2283 sub read_config {
2284     my $fname = shift;
2285     open(CONFFILE, "< $fname")
2286         or die "Can't open configuration file '$fname'!\n";
2287     my $x = $/;
2288     undef $/;
2289     my $content = <CONFFILE>;
2290     $/ = $x;
2291     close(CONFFILE);
2292     my %targets = ();
2293     {
2294         # Protect certain tables from tampering
2295         local %table = %::table;
2296
2297         eval $content;
2298         warn $@ if $@;
2299     }
2300
2301     # For each target, check that it's configured with a hash table.
2302     foreach (keys %targets) {
2303         if (ref($targets{$_}) ne "HASH") {
2304             if (ref($targets{$_}) eq "") {
2305                 warn "Deprecated target configuration for $_, ignoring...\n";
2306             } else {
2307                 warn "Misconfigured target configuration for $_ (should be a hash table), ignoring...\n";
2308             }
2309             delete $targets{$_};
2310         } else {
2311             $targets{$_}->{_conf_fname_int} = add([ $fname ]);
2312         }
2313     }
2314
2315     %table = (%table, %targets);
2316
2317 }
2318
2319 # configuration resolver.  Will only resolve all the lazy evaluation
2320 # codeblocks for the chosen target and all those it inherits from,
2321 # recursively
2322 sub resolve_config {
2323     my $target = shift;
2324     my @breadcrumbs = @_;
2325
2326 #    my $extra_checks = defined($ENV{CONFIGURE_EXTRA_CHECKS});
2327
2328     if (grep { $_ eq $target } @breadcrumbs) {
2329         die "inherit_from loop!  target backtrace:\n  "
2330             ,$target,"\n  ",join("\n  ", @breadcrumbs),"\n";
2331     }
2332
2333     if (!defined($table{$target})) {
2334         warn "Warning! target $target doesn't exist!\n";
2335         return ();
2336     }
2337     # Recurse through all inheritances.  They will be resolved on the
2338     # fly, so when this operation is done, they will all just be a
2339     # bunch of attributes with string values.
2340     # What we get here, though, are keys with references to lists of
2341     # the combined values of them all.  We will deal with lists after
2342     # this stage is done.
2343     my %combined_inheritance = ();
2344     if ($table{$target}->{inherit_from}) {
2345         my @inherit_from =
2346             map { ref($_) eq "CODE" ? $_->() : $_ } @{$table{$target}->{inherit_from}};
2347         foreach (@inherit_from) {
2348             my %inherited_config = resolve_config($_, $target, @breadcrumbs);
2349
2350             # 'template' is a marker that's considered private to
2351             # the config that had it.
2352             delete $inherited_config{template};
2353
2354             foreach (keys %inherited_config) {
2355                 if (!$combined_inheritance{$_}) {
2356                     $combined_inheritance{$_} = [];
2357                 }
2358                 push @{$combined_inheritance{$_}}, $inherited_config{$_};
2359             }
2360         }
2361     }
2362
2363     # We won't need inherit_from in this target any more, since we've
2364     # resolved all the inheritances that lead to this
2365     delete $table{$target}->{inherit_from};
2366
2367     # Now is the time to deal with those lists.  Here's the place to
2368     # decide what shall be done with those lists, all based on the
2369     # values of the target we're currently dealing with.
2370     # - If a value is a coderef, it will be executed with the list of
2371     #   inherited values as arguments.
2372     # - If the corresponding key doesn't have a value at all or is the
2373     #   empty string, the inherited value list will be run through the
2374     #   default combiner (below), and the result becomes this target's
2375     #   value.
2376     # - Otherwise, this target's value is assumed to be a string that
2377     #   will simply override the inherited list of values.
2378     my $default_combiner = add();
2379
2380     my %all_keys =
2381         map { $_ => 1 } (keys %combined_inheritance,
2382                          keys %{$table{$target}});
2383
2384     sub process_values {
2385         my $object    = shift;
2386         my $inherited = shift;  # Always a [ list ]
2387         my $target    = shift;
2388         my $entry     = shift;
2389
2390         $add_called = 0;
2391
2392         while(ref($object) eq "CODE") {
2393             $object = $object->(@$inherited);
2394         }
2395         if (!defined($object)) {
2396             return ();
2397         }
2398         elsif (ref($object) eq "ARRAY") {
2399             local $add_called;  # To make sure recursive calls don't affect it
2400             return [ map { process_values($_, $inherited, $target, $entry) }
2401                      @$object ];
2402         } elsif (ref($object) eq "") {
2403             return $object;
2404         } else {
2405             die "cannot handle reference type ",ref($object)
2406                 ," found in target ",$target," -> ",$entry,"\n";
2407         }
2408     }
2409
2410     foreach (sort keys %all_keys) {
2411         my $previous = $combined_inheritance{$_};
2412
2413         # Current target doesn't have a value for the current key?
2414         # Assign it the default combiner, the rest of this loop body
2415         # will handle it just like any other coderef.
2416         if (!exists $table{$target}->{$_}) {
2417             $table{$target}->{$_} = $default_combiner;
2418         }
2419
2420         $table{$target}->{$_} = process_values($table{$target}->{$_},
2421                                                $combined_inheritance{$_},
2422                                                $target, $_);
2423         unless(defined($table{$target}->{$_})) {
2424             delete $table{$target}->{$_};
2425         }
2426 #        if ($extra_checks &&
2427 #            $previous && !($add_called ||  $previous ~~ $table{$target}->{$_})) {
2428 #            warn "$_ got replaced in $target\n";
2429 #        }
2430     }
2431
2432     # Finally done, return the result.
2433     return %{$table{$target}};
2434 }
2435
2436 sub usage
2437         {
2438         print STDERR $usage;
2439         print STDERR "\npick os/compiler from:\n";
2440         my $j=0;
2441         my $i;
2442         my $k=0;
2443         foreach $i (sort keys %table)
2444                 {
2445                 next if $table{$i}->{template};
2446                 next if $i =~ /^debug/;
2447                 $k += length($i) + 1;
2448                 if ($k > 78)
2449                         {
2450                         print STDERR "\n";
2451                         $k=length($i);
2452                         }
2453                 print STDERR $i . " ";
2454                 }
2455         foreach $i (sort keys %table)
2456                 {
2457                 next if $table{$i}->{template};
2458                 next if $i !~ /^debug/;
2459                 $k += length($i) + 1;
2460                 if ($k > 78)
2461                         {
2462                         print STDERR "\n";
2463                         $k=length($i);
2464                         }
2465                 print STDERR $i . " ";
2466                 }
2467         print STDERR "\n\nNOTE: If in doubt, on Unix-ish systems use './config'.\n";
2468         exit(1);
2469         }
2470
2471 sub run_dofile
2472 {
2473     my $out = shift;
2474     my @templates = @_;
2475
2476     unlink $out || warn "Can't remove $out, $!"
2477         if -f $out;
2478     foreach (@templates) {
2479         die "Can't open $_, $!" unless -f $_;
2480     }
2481     my $perlcmd = (quotify("maybeshell", $config{perl}))[0];
2482     my $cmd = "$perlcmd \"-I.\" \"-Mconfigdata\" \"$dofile\" -o\"Configure\" \"".join("\" \"",@templates)."\" > \"$out.new\"";
2483     #print STDERR "DEBUG[run_dofile]: \$cmd = $cmd\n";
2484     system($cmd);
2485     exit 1 if $? != 0;
2486     rename("$out.new", $out) || die "Can't rename $out.new, $!";
2487 }
2488
2489 sub which
2490 {
2491     my ($name)=@_;
2492
2493     if (eval { require IPC::Cmd; 1; }) {
2494         IPC::Cmd->import();
2495         return scalar IPC::Cmd::can_run($name);
2496     } else {
2497         # if there is $directories component in splitpath,
2498         # then it's not something to test with $PATH...
2499         return $name if (File::Spec->splitpath($name))[1];
2500
2501         foreach (File::Spec->path()) {
2502             my $fullpath = catfile($_, "$name$target{exe_extension}");
2503             if (-f $fullpath and -x $fullpath) {
2504                 return $fullpath;
2505             }
2506         }
2507     }
2508 }
2509
2510 # Configuration printer ##############################################
2511
2512 sub print_table_entry
2513 {
2514     my $target = shift;
2515     my %target = resolve_config($target);
2516     my $type = shift;
2517
2518     # Don't print the templates
2519     return if $target{template};
2520
2521     my @sequence = (
2522         "sys_id",
2523         "cc",
2524         "cflags",
2525         "defines",
2526         "unistd",
2527         "ld",
2528         "lflags",
2529         "loutflag",
2530         "plib_lflags",
2531         "ex_libs",
2532         "bn_ops",
2533         "apps_aux_src",
2534         "cpuid_asm_src",
2535         "uplink_aux_src",
2536         "bn_asm_src",
2537         "ec_asm_src",
2538         "des_asm_src",
2539         "aes_asm_src",
2540         "bf_asm_src",
2541         "md5_asm_src",
2542         "cast_asm_src",
2543         "sha1_asm_src",
2544         "rc4_asm_src",
2545         "rmd160_asm_src",
2546         "rc5_asm_src",
2547         "wp_asm_src",
2548         "cmll_asm_src",
2549         "modes_asm_src",
2550         "padlock_asm_src",
2551         "chacha_asm_src",
2552         "poly1035_asm_src",
2553         "thread_scheme",
2554         "perlasm_scheme",
2555         "dso_scheme",
2556         "shared_target",
2557         "shared_cflag",
2558         "shared_defines",
2559         "shared_ldflag",
2560         "shared_rcflag",
2561         "shared_extension",
2562         "dso_extension",
2563         "obj_extension",
2564         "exe_extension",
2565         "ranlib",
2566         "ar",
2567         "arflags",
2568         "aroutflag",
2569         "rc",
2570         "rcflags",
2571         "rcoutflag",
2572         "mt",
2573         "mtflags",
2574         "mtinflag",
2575         "mtoutflag",
2576         "multilib",
2577         "build_scheme",
2578         );
2579
2580     if ($type eq "TABLE") {
2581         print "\n";
2582         print "*** $target\n";
2583         foreach (@sequence) {
2584             if (ref($target{$_}) eq "ARRAY") {
2585                 printf "\$%-12s = %s\n", $_, join(" ", @{$target{$_}});
2586             } else {
2587                 printf "\$%-12s = %s\n", $_, $target{$_};
2588             }
2589         }
2590     } elsif ($type eq "HASH") {
2591         my $largest =
2592             length((sort { length($a) <=> length($b) } @sequence)[-1]);
2593         print "    '$target' => {\n";
2594         foreach (@sequence) {
2595             if ($target{$_}) {
2596                 if (ref($target{$_}) eq "ARRAY") {
2597                     print "      '",$_,"'"," " x ($largest - length($_))," => [ ",join(", ", map { "'$_'" } @{$target{$_}})," ],\n";
2598                 } else {
2599                     print "      '",$_,"'"," " x ($largest - length($_))," => '",$target{$_},"',\n";
2600                 }
2601             }
2602         }
2603         print "    },\n";
2604     }
2605 }
2606
2607 # Utility routines ###################################################
2608
2609 # On VMS, if the given file is a logical name, File::Spec::Functions
2610 # will consider it an absolute path.  There are cases when we want a
2611 # purely syntactic check without checking the environment.
2612 sub isabsolute {
2613     my $file = shift;
2614
2615     # On non-platforms, we just use file_name_is_absolute().
2616     return file_name_is_absolute($file) unless $^O eq "VMS";
2617
2618     # If the file spec includes a device or a directory spec,
2619     # file_name_is_absolute() is perfectly safe.
2620     return file_name_is_absolute($file) if $file =~ m|[:\[]|;
2621
2622     # Here, we know the given file spec isn't absolute
2623     return 0;
2624 }
2625
2626 # Makes a directory absolute and cleans out /../ in paths like foo/../bar
2627 # On some platforms, this uses rel2abs(), while on others, realpath() is used.
2628 # realpath() requires that at least all path components except the last is an
2629 # existing directory.  On VMS, the last component of the directory spec must
2630 # exist.
2631 sub absolutedir {
2632     my $dir = shift;
2633
2634     # realpath() is quite buggy on VMS.  It uses LIB$FID_TO_NAME, which
2635     # will return the volume name for the device, no matter what.  Also,
2636     # it will return an incorrect directory spec if the argument is a
2637     # directory that doesn't exist.
2638     if ($^O eq "VMS") {
2639         return rel2abs($dir);
2640     }
2641
2642     # We use realpath() on Unix, since no other will properly clean out
2643     # a directory spec.
2644     use Cwd qw/realpath/;
2645
2646     return realpath($dir);
2647 }
2648
2649 sub quotify {
2650     my %processors = (
2651         perl    => sub { my $x = shift;
2652                          $x =~ s/([\\\$\@"])/\\$1/g;
2653                          return '"'.$x.'"'; },
2654         maybeshell => sub { my $x = shift;
2655                             (my $y = $x) =~ s/([\\\"])/\\$1/g;
2656                             if ($x ne $y || $x =~ m|\s|) {
2657                                 return '"'.$y.'"';
2658                             } else {
2659                                 return $x;
2660                             }
2661                         },
2662         );
2663     my $for = shift;
2664     my $processor =
2665         defined($processors{$for}) ? $processors{$for} : sub { shift; };
2666
2667     return map { $processor->($_); } @_;
2668 }
2669
2670 # collect_from_file($filename, $line_concat_cond_re, $line_concat)
2671 # $filename is a file name to read from
2672 # $line_concat_cond_re is a regexp detecting a line continuation ending
2673 # $line_concat is a CODEref that takes care of concatenating two lines
2674 sub collect_from_file {
2675     my $filename = shift;
2676     my $line_concat_cond_re = shift;
2677     my $line_concat = shift;
2678
2679     open my $fh, $filename || die "unable to read $filename: $!\n";
2680     return sub {
2681         my $saved_line = "";
2682         $_ = "";
2683         while (<$fh>) {
2684             s|\R$||;
2685             if (defined $line_concat) {
2686                 $_ = $line_concat->($saved_line, $_);
2687                 $saved_line = "";
2688             }
2689             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
2690                 $saved_line = $_;
2691                 next;
2692             }
2693             return $_;
2694         }
2695         die "$filename ending with continuation line\n" if $_;
2696         close $fh;
2697         return undef;
2698     }
2699 }
2700
2701 # collect_from_array($array, $line_concat_cond_re, $line_concat)
2702 # $array is an ARRAYref of lines
2703 # $line_concat_cond_re is a regexp detecting a line continuation ending
2704 # $line_concat is a CODEref that takes care of concatenating two lines
2705 sub collect_from_array {
2706     my $array = shift;
2707     my $line_concat_cond_re = shift;
2708     my $line_concat = shift;
2709     my @array = (@$array);
2710
2711     return sub {
2712         my $saved_line = "";
2713         $_ = "";
2714         while (defined($_ = shift @array)) {
2715             s|\R$||;
2716             if (defined $line_concat) {
2717                 $_ = $line_concat->($saved_line, $_);
2718                 $saved_line = "";
2719             }
2720             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
2721                 $saved_line = $_;
2722                 next;
2723             }
2724             return $_;
2725         }
2726         die "input text ending with continuation line\n" if $_;
2727         return undef;
2728     }
2729 }
2730
2731 # collect_information($lineiterator, $line_continue, $regexp => $CODEref, ...)
2732 # $lineiterator is a CODEref that delivers one line at a time.
2733 # All following arguments are regex/CODEref pairs, where the regexp detects a
2734 # line and the CODEref does something with the result of the regexp.
2735 sub collect_information {
2736     my $lineiterator = shift;
2737     my %collectors = @_;
2738
2739     while(defined($_ = $lineiterator->())) {
2740         s|\R$||;
2741         my $found = 0;
2742         if ($collectors{"BEFORE"}) {
2743             $collectors{"BEFORE"}->($_);
2744         }
2745         foreach my $re (keys %collectors) {
2746             if ($re !~ /^OTHERWISE|BEFORE|AFTER$/ && /$re/) {
2747                 $collectors{$re}->($lineiterator);
2748                 $found = 1;
2749             };
2750         }
2751         if ($collectors{"OTHERWISE"}) {
2752             $collectors{"OTHERWISE"}->($lineiterator, $_)
2753                 unless $found || !defined $collectors{"OTHERWISE"};
2754         }
2755         if ($collectors{"AFTER"}) {
2756             $collectors{"AFTER"}->($_);
2757         }
2758     }
2759 }
2760
2761 # tokenize($line)
2762 # $line is a line of text to split up into tokens
2763 # returns a list of tokens
2764 #
2765 # Tokens are divided by spaces.  If the tokens include spaces, they
2766 # have to be quoted with single or double quotes.  Double quotes
2767 # inside a double quoted token must be escaped.  Escaping is done
2768 # with backslash.
2769 # Basically, the same quoting rules apply for " and ' as in any
2770 # Unix shell.
2771 sub tokenize {
2772     my $line = my $debug_line = shift;
2773     my @result = ();
2774
2775     while ($line =~ s|^\s+||, $line ne "") {
2776         my $token = "";
2777         while ($line ne "" && $line !~ m|^\s|) {
2778             if ($line =~ m/^"((?:[^"\\]+|\\.)*)"/) {
2779                 $token .= $1;
2780                 $line = $';
2781             } elsif ($line =~ m/^'([^']*)'/) {
2782                 $token .= $1;
2783                 $line = $';
2784             } elsif ($line =~ m/^(\S+)/) {
2785                 $token .= $1;
2786                 $line = $';
2787             }
2788         }
2789         push @result, $token;
2790     }
2791
2792     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
2793         print STDERR "DEBUG[tokenize]: Parsed '$debug_line' into:\n";
2794         print STDERR "DEBUG[tokenize]: ('", join("', '", @result), "')\n";
2795     }
2796     return @result;
2797 }