apps/progs.pl

   1 #! /usr/bin/env perl
   2 # Copyright 1995-2018 The OpenSSL Project Authors. All Rights Reserved.
   3 #
   4 # Licensed under the Apache License 2.0 (the "License").  You may not use
   5 # this file except in compliance with the License.  You can obtain a copy
   6 # in the file LICENSE in the source distribution or at
   7 # https://www.openssl.org/source/license.html
   8
   9 # Generate progs.h file by looking for command mains in list of C files
  10 # passed on the command line.
  11
  12 use strict;
  13 use warnings;
  14 use lib '.';
  15 use configdata qw/@disablables %unified_info/;
  16
  17 my $opt          = shift @ARGV;
  18 die "Unrecognised option, must be -C or -H\n"
  19     unless ($opt eq '-H' || $opt eq '-C');
  20
  21 my %commands     = ();
  22 my $cmdre        = qr/^\s*int\s+([a-z_][a-z0-9_]*)_main\(\s*int\s+argc\s*,/;
  23 my $apps_openssl = shift @ARGV;
  24 my $YEAR         = [localtime()]->[5] + 1900;
  25
  26 # because the program apps/openssl has object files as sources, and
  27 # they then have the corresponding C files as source, we need to chain
  28 # the lookups in %unified_info
  29 my @openssl_source =
  30     map { @{$unified_info{sources}->{$_}} }
  31     grep { /\.o$/ }
  32         @{$unified_info{sources}->{$apps_openssl}};
  33
  34 foreach my $filename (@openssl_source) {
  35     open F, $filename or die "Couldn't open $filename: $!\n";
  36     foreach ( grep /$cmdre/, <F> ) {
  37         my @foo = /$cmdre/;
  38         $commands{$1} = 1;
  39     }
  40     close F;
  41 }
  42
  43 @ARGV = sort keys %commands;
  44
  45 if ($opt eq '-H') {
  46     print <<"EOF";
  47 /*
  48  * WARNING: do not edit!
  49  * Generated by apps/progs.pl
  50  *
  51  * Copyright 1995-$YEAR The OpenSSL Project Authors. All Rights Reserved.
  52  *
  53  * Licensed under the Apache License 2.0 (the "License").  You may not use
  54  * this file except in compliance with the License.  You can obtain a copy
  55  * in the file LICENSE in the source distribution or at
  56  * https://www.openssl.org/source/license.html
  57  */
  58
  59 #include "function.h"
  60
  61 EOF
  62
  63     foreach (@ARGV) {
  64         printf "extern int %s_main(int argc, char *argv[]);\n", $_;
  65     }
  66     print "\n";
  67
  68     foreach (@ARGV) {
  69         printf "extern const OPTIONS %s_options[];\n", $_;
  70     }
  71     print "\n";
  72     print "extern FUNCTION functions[];\n";
  73 }
  74
  75 if ($opt eq '-C') {
  76     print <<"EOF";
  77 /*
  78  * WARNING: do not edit!
  79  * Generated by apps/progs.pl
  80  *
  81  * Copyright 1995-$YEAR The OpenSSL Project Authors. All Rights Reserved.
  82  *
  83  * Licensed under the Apache License 2.0 (the "License").  You may not use
  84  * this file except in compliance with the License.  You can obtain a copy
  85  * in the file LICENSE in the source distribution or at
  86  * https://www.openssl.org/source/license.html
  87  */
  88
  89 #include "progs.h"
  90
  91 EOF
  92
  93     my %cmd_disabler = (
  94         ciphers  => "sock",
  95         genrsa   => "rsa",
  96         rsautl   => "rsa",
  97         gendsa   => "dsa",
  98         dsaparam => "dsa",
  99         gendh    => "dh",
 100         dhparam  => "dh",
 101         ecparam  => "ec",
 102         pkcs12   => "des",
 103     );
 104
 105     print "FUNCTION functions[] = {\n";
 106     foreach my $cmd ( @ARGV ) {
 107         my $str =
 108             "    {FT_general, \"$cmd\", ${cmd}_main, ${cmd}_options},\n";
 109         if ($cmd =~ /^s_/) {
 110             print "#ifndef OPENSSL_NO_SOCK\n${str}#endif\n";
 111         } elsif (grep { $cmd eq $_ } @disablables) {
 112             print "#ifndef OPENSSL_NO_" . uc($cmd) . "\n${str}#endif\n";
 113         } elsif (my $disabler = $cmd_disabler{$cmd}) {
 114             print "#ifndef OPENSSL_NO_" . uc($disabler) . "\n${str}#endif\n";
 115         } else {
 116             print $str;
 117         }
 118     }
 119
 120     my %md_disabler = (
 121         blake2b512 => "blake2",
 122         blake2s256 => "blake2",
 123     );
 124     foreach my $cmd (
 125         "md2", "md4", "md5",
 126         "gost",
 127         "sha1", "sha224", "sha256", "sha384",
 128         "sha512", "sha512-224", "sha512-256",
 129         "sha3-224", "sha3-256", "sha3-384", "sha3-512",
 130         "shake128", "shake256",
 131         "mdc2", "rmd160", "blake2b512", "blake2s256",
 132         "sm3"
 133     ) {
 134         my $str = "    {FT_md, \"$cmd\", dgst_main},\n";
 135         if (grep { $cmd eq $_ } @disablables) {
 136             print "#ifndef OPENSSL_NO_" . uc($cmd) . "\n${str}#endif\n";
 137         } elsif (my $disabler = $md_disabler{$cmd}) {
 138             print "#ifndef OPENSSL_NO_" . uc($disabler) . "\n${str}#endif\n";
 139         } else {
 140             print $str;
 141         }
 142     }
 143
 144     my %cipher_disabler = (
 145         des3  => "des",
 146         desx  => "des",
 147         cast5 => "cast",
 148     );
 149     foreach my $cmd (
 150         "aes-128-cbc", "aes-128-ecb",
 151         "aes-192-cbc", "aes-192-ecb",
 152         "aes-256-cbc", "aes-256-ecb",
 153         "aria-128-cbc", "aria-128-cfb",
 154         "aria-128-ctr", "aria-128-ecb", "aria-128-ofb",
 155         "aria-128-cfb1", "aria-128-cfb8",
 156         "aria-192-cbc", "aria-192-cfb",
 157         "aria-192-ctr", "aria-192-ecb", "aria-192-ofb",
 158         "aria-192-cfb1", "aria-192-cfb8",
 159         "aria-256-cbc", "aria-256-cfb",
 160         "aria-256-ctr", "aria-256-ecb", "aria-256-ofb",
 161         "aria-256-cfb1", "aria-256-cfb8",
 162         "camellia-128-cbc", "camellia-128-ecb",
 163         "camellia-192-cbc", "camellia-192-ecb",
 164         "camellia-256-cbc", "camellia-256-ecb",
 165         "base64", "zlib",
 166         "des", "des3", "desx", "idea", "seed", "rc4", "rc4-40",
 167         "rc2", "bf", "cast", "rc5",
 168         "des-ecb", "des-ede", "des-ede3",
 169         "des-cbc", "des-ede-cbc","des-ede3-cbc",
 170         "des-cfb", "des-ede-cfb","des-ede3-cfb",
 171         "des-ofb", "des-ede-ofb","des-ede3-ofb",
 172         "idea-cbc","idea-ecb", "idea-cfb", "idea-ofb",
 173         "seed-cbc","seed-ecb", "seed-cfb", "seed-ofb",
 174         "rc2-cbc", "rc2-ecb", "rc2-cfb","rc2-ofb", "rc2-64-cbc", "rc2-40-cbc",
 175         "bf-cbc", "bf-ecb", "bf-cfb", "bf-ofb",
 176         "cast5-cbc","cast5-ecb", "cast5-cfb","cast5-ofb",
 177         "cast-cbc", "rc5-cbc", "rc5-ecb", "rc5-cfb", "rc5-ofb",
 178         "sm4-cbc", "sm4-ecb", "sm4-cfb", "sm4-ofb", "sm4-ctr"
 179     ) {
 180         my $str = "    {FT_cipher, \"$cmd\", enc_main, enc_options},\n";
 181         (my $algo = $cmd) =~ s/-.*//g;
 182         if ($cmd eq "zlib") {
 183             print "#ifdef ZLIB\n${str}#endif\n";
 184         } elsif (grep { $algo eq $_ } @disablables) {
 185             print "#ifndef OPENSSL_NO_" . uc($algo) . "\n${str}#endif\n";
 186         } elsif (my $disabler = $cipher_disabler{$algo}) {
 187             print "#ifndef OPENSSL_NO_" . uc($disabler) . "\n${str}#endif\n";
 188         } else {
 189             print $str;
 190         }
 191     }
 192
 193     print "    {0, NULL, NULL}\n};\n";
 194 }