configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_INIT([sarg],[2.3-pre5])
   3 AC_CONFIG_SRCDIR([log.c])
   4 AC_CONFIG_AUX_DIR(cfgaux)
   5
   6 AC_CANONICAL_HOST
   7
   8 AC_ARG_WITH(gcc,
   9 [  --without-gcc           use CC to compile])
  10
  11 test -n "$CC" && cc_specified=yes
  12 case ${with_gcc} in
  13   yes ) CC=gcc ;;
  14 dnl yes ) CC=g++ ;;
  15   no  ) CC=cc ;;
  16   *   ) AC_PROG_CC;;
  17 dnl  *   ) AC_PROG_CXX ;;
  18 esac
  19
  20 if test "${CC}" = "cc" ; then
  21    CFLAGS="${CFLAGS} -g -O2 -Aa"
  22 fi
  23 CFLAGS="${CFLAGS} -Wall -Wno-sign-compare"
  24
  25 dnl Check for supported compiler options
  26
  27 AC_MSG_CHECKING([for extra warnings flag in $CC])
  28 saved_CFLAGS="${CFLAGS}"
  29 CFLAGS="${CFLAGS} -Wextra -Wno-unused-parameter"
  30 AC_COMPILE_IFELSE([AC_LANG_SOURCE([])],[have_extra_warnings="yes"],[have_extra_warnings="no"])
  31 AC_MSG_RESULT($have_extra_warnings)
  32 if test "$have_extra_warnings" == "no" ; then
  33     CFLAGS="${saved_CFLAGS}"
  34 fi
  35
  36 AC_MSG_CHECKING([for implicit-function-declaration error flag in $CC])
  37 saved_CFLAGS="${CFLAGS}"
  38 CFLAGS="${CFLAGS} -Werror=implicit-function-declaration"
  39 AC_COMPILE_IFELSE([AC_LANG_SOURCE([])],[have_implicit_function_declaration="yes"],[have_implicit_function_declaration="no"])
  40 AC_MSG_RESULT($have_implicit_function_declaration)
  41 if test "$have_implicit_function_declaration" == "no" ; then
  42     CFLAGS="${saved_CFLAGS}"
  43 fi
  44
  45 AC_MSG_CHECKING([for format error flag in $CC])
  46 saved_CFLAGS="${CFLAGS}"
  47 CFLAGS="${CFLAGS} -Werror=format"
  48 AC_COMPILE_IFELSE([AC_LANG_SOURCE([])],[have_error_format="yes"],[have_error_format="no"])
  49 AC_MSG_RESULT($have_error_format)
  50 if test "$have_implicit_function_declaration" == "no" ; then
  51     CFLAGS="${saved_CFLAGS}"
  52 fi
  53
  54 case "$host" in
  55    *-solaris*)
  56    LDFLAGS="${LDFLAGS} -lsocket -lnsl"
  57    CFLAGS="-DSOLARIS ${CFLAGS}"
  58    ;;
  59 esac
  60
  61 #dnl Checks for programs.
  62 #AC_PROG_CC
  63
  64 dnl Check for headers
  65 AC_HEADER_DIRENT
  66 AC_HEADER_STDC
  67
  68 dnl Check for iconv
  69 AM_ICONV
  70 if test -n "$LIBICONV" ; then
  71   LIBS="$LIBS $LIBICONV"
  72 fi
  73
  74 AC_CHECK_HEADERS(stdio.h stdlib.h string.h strings.h sys/time.h time.h unistd.h sys/dirent.h \
  75                 dirent.h sys/socket.h netdb.h arpa/inet.h sys/types.h netinet/in.h sys/stat.h \
  76                 ctype.h gd.h gdfontl.h gdfontt.h gdfonts.h gdfontmb.h gdfontg.h iconv.h \
  77                 errno.h sys/resource.h sys/wait.h stdarg.h inttypes.h limits.h locale.h \
  78                 execinfo.h ldap.h math.h libintl.h libgen.h stdbool.h getopt.h)
  79
  80 if test $ac_cv_header_getopt_h = "no" ; then
  81    AC_MSG_ERROR("getopt.h is required to compile sarg")
  82 fi
  83
  84 AC_CHECK_LIB(gd, gdImagePng,LIBS="-lgd ${LIBS}"; HAVE_GD_LIB="yes", HAVE_GD_LIB="")
  85 AC_CHECK_LIB(ldap, ldap_init,LIBS="-lldap ${LIBS}"; HAVE_LDAP="yes", HAVE_LDAP="")
  86
  87 dnl Checks for typedefs, structures, and compiler characteristics.
  88 AC_C_CONST
  89 AC_STRUCT_TM
  90
  91 AM_GNU_GETTEXT_VERSION([0.17])
  92 AM_GNU_GETTEXT([external])
  93
  94 AC_SYS_LARGEFILE
  95
  96 # Check whether fopen64 is available and whether _LARGEFILE64_SOURCE
  97 # needs to be defined for it
  98 AC_MSG_CHECKING([for fopen64])
  99 AC_CACHE_VAL(bu_cv_have_fopen64,
 100 [noerror_CFLAGS=$CFLAGS
 101  CFLAGS="$CFLAGS -Werror"
 102  AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>]], [[FILE *f = fopen64 ("/tmp/foo","r");fclose(f);]])],[bu_cv_have_fopen64=yes],
 103  [CFLAGS="$CFLAGS -D_LARGEFILE64_SOURCE"
 104  AC_TRY_LINK([#include <stdio.h>], [FILE *f = fopen64 ("/tmp/foo","r");fclose(f);],
 105 bu_cv_have_fopen64="need -D_LARGEFILE64_SOURCE",
 106  CFLAGS=$noerror_CFLAGS
 107  AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>]], [[FILE *f = fopen64 ("/tmp/foo","r");fclose(f);]])],[bu_cv_have_fopen64="yes without -Werror"
 108  werror_status="fail"],
 109  [CFLAGS="$CFLAGS -D_LARGEFILE64_SOURCE"
 110  AC_TRY_LINK([#include <stdio.h>], [FILE *f = fopen64 ("/tmp/foo","r");fclose(f);],
 111 bu_cv_have_fopen64="need -D_LARGEFILE64_SOURCE and no -Werror"
 112 werror_status="fail",
 113 bu_cv_have_fopen64=no)]))
 114  ])
 115  CFLAGS=$noerror_CFLAGS])
 116 AC_MSG_RESULT($bu_cv_have_fopen64)
 117 if test "$bu_cv_have_fopen64" != no; then
 118   AC_DEFINE([HAVE_FOPEN64], 1,
 119             [Is fopen64 available?])
 120   if test "$bu_cv_have_fopen64" = "need -D_LARGEFILE64_SOURCE"; then
 121     AC_DEFINE([_LARGEFILE64_SOURCE], 1,
 122               [Enable LFS])
 123   fi
 124 fi
 125
 126 dnl check for functions
 127 AC_CHECK_FUNCS(bzero)
 128 AC_CHECK_FUNCS(backtrace)
 129 AC_CHECK_FUNCS(symlink)
 130 AC_CHECK_FUNCS(lstat)
 131 AC_CHECK_FUNCS(getnameinfo)
 132
 133 dnl check for the rlim_t size
 134 AC_CHECK_SIZEOF(rlim_t,1,[#if HAVE_SYS_RESOURCE_H
 135 #include <sys/resource.h>
 136 #endif
 137 ])
 138 if test $ac_cv_sizeof_rlim_t = "4"; then
 139     AC_DEFINE(RLIM_STRING, "%d", [Rlim string])
 140 elif test $ac_cv_sizeof_rlim_t = "8"; then
 141     AC_DEFINE(RLIM_STRING, "%lli", [Rlim string])
 142 else
 143     AC_MSG_WARN([can not detect the size of your system\'s rlim_t type])
 144 fi
 145
 146 dnl Select sarg-php directory
 147 AC_ARG_ENABLE(sargphp,
 148 [  --enable-sargphp=sargphpdir
 149                         Select sargphpdir as the directory to install sarg-php into ],
 150 [
 151     if test "$enableval" -a "x$enableval" != "xno" ; then
 152         SARGPHPDIR=$enableval
 153     fi
 154 ],[SARGPHPDIR="/var/www/html"])
 155 if test "$SARGPHPDIR" ; then
 156    echo "using $SARGPHPDIR as the directory to install sarg-php"
 157    AC_SUBST(SARGPHPDIR)
 158 fi
 159
 160 dnl Select fonts dir
 161 AC_ARG_ENABLE(fontdir,
 162 [  --enable-fontdir=fontdir
 163                         Select fontdir as the directory with the fonts to use in the reports ],
 164 [
 165     if test "$enableval" -a "x$enableval" != "xno" ; then
 166         FONTDIR=$enableval
 167     fi
 168 ],[FONTDIR="${datarootdir}/sarg/fonts"])
 169 if test "$FONTDIR" ; then
 170    if test "x$prefix" == "xNONE" ; then
 171       tempfullpath=`prefix=$ac_default_prefix ; eval "echo $FONTDIR"`
 172    else
 173       tempfullpath=`eval "echo $FONTDIR"`
 174    fi
 175    echo "using $tempfullpath as the directory of the fonts"
 176    AC_SUBST(FONTDIR)
 177 fi
 178
 179 dnl Select images dir
 180 AC_ARG_ENABLE(imagedir,
 181 [  --enable-imagedir=imagedir
 182                         Select imagedir as the directory with the images to use in the reports ],
 183 [
 184     if test "$enableval"; then
 185         IMAGEDIR=$enableval
 186     fi
 187 ],[IMAGEDIR="${datarootdir}/sarg/images"])
 188 if test "x$prefix" == "xNONE" ; then
 189    tempfullpath=`prefix=$ac_default_prefix ; eval "echo $IMAGEDIR"`
 190 else
 191    tempfullpath=`eval "echo $IMAGEDIR"`
 192 fi
 193 echo "using $tempfullpath as the directory of the images"
 194 AC_SUBST(IMAGEDIR)
 195
 196 dnl Enable extra compile and run time protection
 197 AC_ARG_ENABLE(extraprotection,
 198 [  --enable-extraprotection
 199                         Enable compile and runtime extra protections ],
 200 [
 201     if test "$enableval"; then
 202        CFLAGS="${CFLAGS} -fstack-protector -D_FORTIFY_SOURCE=2"
 203        if test "x$werror_status" != "xfail" ; then
 204           CFLAGS="${CFLAGS} -Werror"
 205        fi
 206
 207        AC_MSG_CHECKING([for format security flag in $CC])
 208        saved_CFLAGS="${CFLAGS}"
 209        CFLAGS="${CFLAGS} -Wformat -Werror=format-security"
 210        AC_COMPILE_IFELSE([AC_LANG_SOURCE([])],[have_format_security="yes"],[have_format_security="no"])
 211        AC_MSG_RESULT($have_format_security)
 212        if test "$have_format_security" == "no" ; then
 213           CFLAGS="${saved_CFLAGS}"
 214        fi
 215     fi
 216 ])
 217
 218 AC_SUBST(PACKAGE,"$PACKAGE_NAME")
 219 AC_SUBST(VERSION,"$PACKAGE_VERSION")
 220
 221 AC_CONFIG_FILES([Makefile po/Makefile.in])
 222 AC_OUTPUT