configure.ac

   1 AC_INIT([xfsprogs], [5.8.0-rc1], [linux-xfs@vger.kernel.org])
   2 AC_PREREQ(2.50)
   3 AC_CONFIG_AUX_DIR([.])
   4 AC_CONFIG_MACRO_DIR([m4])
   5 AC_CONFIG_SRCDIR([include/libxfs.h])
   6 AC_CONFIG_HEADER(include/platform_defs.h)
   7 AC_PREFIX_DEFAULT(/usr)
   8
   9 AC_PROG_INSTALL
  10 AC_PROG_LIBTOOL
  11
  12 AC_PROG_CC
  13 AC_ARG_VAR(BUILD_CC, [C compiler for build tools])
  14 if test "${BUILD_CC+set}" != "set"; then
  15   if test $cross_compiling = no; then
  16     BUILD_CC="$CC"
  17   else
  18     AC_CHECK_PROGS(BUILD_CC, gcc cc)
  19   fi
  20 fi
  21 AC_ARG_VAR(BUILD_CFLAGS, [C compiler flags for build tools])
  22 if test "${BUILD_CFLAGS+set}" != "set"; then
  23   if test $cross_compiling = no; then
  24     BUILD_CFLAGS="$CFLAGS"
  25   else
  26     BUILD_CFLAGS="-g -O2"
  27   fi
  28 fi
  29
  30 AC_ARG_ENABLE(shared,
  31 [  --enable-shared=[yes/no]  Enable use of shared libraries [default=yes]],,
  32         enable_shared=yes)
  33 AC_SUBST(enable_shared)
  34
  35 AC_ARG_ENABLE(gettext,
  36 [  --enable-gettext=[yes/no] Enable alternate language support [default=yes]],,
  37         enable_gettext=yes)
  38 AC_SUBST(enable_gettext)
  39
  40 AC_ARG_ENABLE(blkid,
  41 [  --enable-blkid=[yes/no]   Enable use of block device id library [default=yes]],,
  42         enable_blkid=yes)
  43 AC_SUBST(enable_blkid)
  44
  45 AC_ARG_ENABLE(editline,
  46 [  --enable-editline=[yes/no] Enable editline command editing [default=no]],
  47         test $enable_editline = yes && libeditline="-ledit",
  48         enable_editline=no)
  49 AC_SUBST(libeditline)
  50 AC_SUBST(enable_editline)
  51
  52 AC_ARG_ENABLE(termcap,
  53 [  --enable-termcap=[yes/no] Enable terminal capabilities library [default=no]],
  54         test $enable_termcap = yes && libtermcap="-ltermcap",)
  55 AC_SUBST(libtermcap)
  56
  57
  58 AC_ARG_ENABLE(lib64,
  59 [  --enable-lib64=[yes/no]   Enable lib64 support [default=yes]],,
  60         enable_lib64=yes)
  61 AC_SUBST(enable_lib64)
  62
  63 AC_ARG_ENABLE(librt,
  64 [  --enable-librt=[yes/no]   Enable librt support [default=yes]],,
  65         enable_librt=yes)
  66 AC_SUBST(enable_librt)
  67
  68 # Enable UBSAN; set enable_ubsan=probe below to enable autoprobe.
  69 AC_ARG_ENABLE(ubsan,
  70 [  --enable-ubsan=[yes/no]   Enable Undefined Behavior Sanitizer (UBSAN) [default=no]],,
  71         enable_ubsan=no)
  72 AC_SUBST(enable_ubsan)
  73
  74 # Enable ADDRSAN; set enable_addrsan=probe below to enable autoprobe.
  75 AC_ARG_ENABLE(addrsan,
  76 [  --enable-addrsan=[yes/no] Enable Address Sanitizer (ADDRSAN) [default=no]],,
  77         enable_addrsan=no)
  78 AC_SUBST(enable_addrsan)
  79
  80 # Enable THREADSAN; set enable_threadsan=probe to enable autoprobe.
  81 AC_ARG_ENABLE(threadsan,
  82 [  --enable-threadsan=[yes/no] Enable Thread Sanitizer (THREADSAN) [default=no]],,
  83         enable_threadsan=no)
  84 AC_SUBST(enable_threadsan)
  85
  86 AC_ARG_ENABLE(lto,
  87 [  --enable-lto=[yes/no]     Enable link time optimization (LTO) [default=no]],,
  88         enable_lto=no)
  89 AC_SUBST(enable_lto)
  90
  91 # Enable xfs_scrub build
  92 AC_ARG_ENABLE(scrub,
  93 [  --enable-scrub=[yes/no]   Enable build of xfs_scrub utility [default=yes]],,
  94         enable_scrub=yes)
  95 AC_SUBST(enable_scrub)
  96
  97 # Enable libicu for xfs_scrubbing of malicious unicode sequences in names
  98 AC_ARG_ENABLE(libicu,
  99 [  --enable-libicu=[yes/no]  Enable Unicode name scanning in xfs_scrub (libicu) [default=probe]],,
 100         enable_libicu=probe)
 101
 102 #
 103 # If the user specified a libdir ending in lib64 do not append another
 104 # 64 to the library names.
 105 #
 106 base_libdir=`basename "$libdir"`
 107 case $base_libdir in
 108 lib64)
 109   enable_lib64=no
 110 esac
 111
 112 #
 113 # Some important tools should be installed into the root partitions.
 114 #
 115 # Check whether exec_prefix=/usr: and install them to /sbin in that
 116 # case.  If the user choses a different prefix assume he just wants
 117 # a local install for testing and not a system install.
 118 #
 119 case $exec_prefix:$prefix in
 120 NONE:NONE | NONE:/usr | /usr:*)
 121   root_sbindir='/sbin'
 122   root_libdir="/${base_libdir}"
 123   ;;
 124 *)
 125   root_sbindir="${sbindir}"
 126   root_libdir="${libdir}"
 127   ;;
 128 esac
 129
 130 AC_SUBST([root_sbindir])
 131 AC_SUBST([root_libdir])
 132
 133 # Find localized files.  Don't descend into any "dot directories"
 134 # (like .git or .pc from quilt).  Strangely, the "-print" argument
 135 # to "find" is required, to avoid including such directories in the
 136 # list.
 137 LOCALIZED_FILES=""
 138 for lfile in `find ${srcdir} -path './.??*' -prune -o -name '*.c' -type f -print || exit 1`; do
 139     LOCALIZED_FILES="$LOCALIZED_FILES \$(TOPDIR)/$lfile"
 140 done
 141 AC_SUBST(LOCALIZED_FILES)
 142
 143 AC_PACKAGE_GLOBALS(xfsprogs)
 144 AC_PACKAGE_UTILITIES(xfsprogs)
 145 AC_MULTILIB($enable_lib64)
 146 AC_RT($enable_librt)
 147
 148 AC_PACKAGE_NEED_UUID_H
 149 AC_PACKAGE_NEED_UUIDCOMPARE
 150
 151 AC_PACKAGE_NEED_PTHREAD_H
 152 AC_PACKAGE_NEED_PTHREADMUTEXINIT
 153
 154 AC_HAVE_FADVISE
 155 AC_HAVE_MADVISE
 156 AC_HAVE_MINCORE
 157 AC_HAVE_SENDFILE
 158 AC_HAVE_GETMNTENT
 159 AC_HAVE_FALLOCATE
 160 AC_HAVE_FIEMAP
 161 AC_HAVE_PWRITEV2
 162 AC_HAVE_PREADV
 163 AC_HAVE_COPY_FILE_RANGE
 164 AC_HAVE_SYNC_FILE_RANGE
 165 AC_HAVE_SYNCFS
 166 AC_HAVE_MNTENT
 167 AC_HAVE_FLS
 168 AC_HAVE_READDIR
 169 AC_HAVE_FSETXATTR
 170 AC_HAVE_MREMAP
 171 AC_NEED_INTERNAL_FSXATTR
 172 AC_NEED_INTERNAL_FSCRYPT_ADD_KEY_ARG
 173 AC_HAVE_GETFSMAP
 174 AC_HAVE_STATFS_FLAGS
 175 AC_HAVE_MAP_SYNC
 176 AC_HAVE_DEVMAPPER
 177 AC_HAVE_MALLINFO
 178 AC_PACKAGE_WANT_ATTRIBUTES_H
 179 AC_HAVE_LIBATTR
 180 if test "$enable_scrub" = "yes"; then
 181         if test "$enable_libicu" = "yes" || test "$enable_libicu" = "probe"; then
 182                 AC_HAVE_LIBICU
 183         fi
 184         if test "$enable_libicu" = "yes" && test "$have_libicu" != "yes"; then
 185                 AC_MSG_ERROR([libicu not found.])
 186         fi
 187 fi
 188 AC_HAVE_OPENAT
 189 AC_HAVE_FSTATAT
 190 AC_HAVE_SG_IO
 191 AC_HAVE_HDIO_GETGEO
 192 AC_CONFIG_SYSTEMD_SYSTEM_UNIT_DIR
 193 AC_CONFIG_CROND_DIR
 194
 195 if test "$enable_blkid" = yes; then
 196 AC_HAVE_BLKID_TOPO
 197 fi
 198
 199 if test "$enable_ubsan" = "yes" || test "$enable_ubsan" = "probe"; then
 200         AC_PACKAGE_CHECK_UBSAN
 201 fi
 202 if test "$enable_ubsan" = "yes" && test "$have_ubsan" != "yes"; then
 203         AC_MSG_ERROR([UBSAN not supported by compiler.])
 204 fi
 205
 206 if test "$enable_addrsan" = "yes" || test "$enable_addrsan" = "probe"; then
 207         AC_PACKAGE_CHECK_ADDRSAN
 208 fi
 209 if test "$enable_addrsan" = "yes" && test "$have_addrsan" != "yes"; then
 210         AC_MSG_ERROR([ADDRSAN not supported by compiler.])
 211 fi
 212
 213 if test "$enable_threadsan" = "yes" || test "$enable_threadsan" = "probe"; then
 214         AC_PACKAGE_CHECK_THREADSAN
 215 fi
 216 if test "$enable_threadsan" = "yes" && test "$have_threadsan" != "yes"; then
 217         AC_MSG_ERROR([THREADSAN not supported by compiler.])
 218 fi
 219
 220 if test "$have_threadsan" = "yes" && test "$have_addrsan" = "yes"; then
 221         AC_MSG_WARN([ADDRSAN and THREADSAN are not known to work together.])
 222 fi
 223
 224 if test "$enable_lto" = "yes" || test "$enable_lto" = "probe"; then
 225         AC_PACKAGE_CHECK_LTO
 226 fi
 227 if test "$enable_lto" = "yes" && test "$have_lto" != "yes"; then
 228         AC_MSG_ERROR([LTO not supported by compiler.])
 229 fi
 230
 231 AC_CHECK_SIZEOF([long])
 232 AC_CHECK_SIZEOF([char *])
 233 AC_TYPE_UMODE_T
 234 AC_MANUAL_FORMAT
 235
 236 AC_CONFIG_FILES([include/builddefs])
 237 AC_OUTPUT