configure.ac

   1 AC_PREREQ(2.60)
   2 AC_INIT([libloc],
   3         [0.9.8],
   4         [location@lists.ipfire.org],
   5         [libloc],
   6         [https://location.ipfire.org/])
   7
   8 AC_CONFIG_SRCDIR([src/libloc.c])
   9 AC_CONFIG_AUX_DIR([build-aux])
  10 AM_INIT_AUTOMAKE([
  11         foreign
  12         1.11
  13         -Wall
  14         -Wno-portability
  15         silent-rules
  16         tar-pax
  17         no-dist-gzip
  18         dist-xz
  19         subdir-objects
  20 ])
  21 AC_PROG_CC_STDC
  22 AC_USE_SYSTEM_EXTENSIONS
  23 AC_SYS_LARGEFILE
  24 AC_CONFIG_MACRO_DIR([m4])
  25 AM_SILENT_RULES([yes])
  26 LT_INIT([
  27         disable-static
  28         pic-only
  29 ])
  30 AC_PREFIX_DEFAULT([/usr])
  31 gl_LD_VERSION_SCRIPT
  32
  33 IT_PROG_INTLTOOL([0.40.0])
  34
  35 # Interpret embedded Python in HTML files
  36 XGETTEXT="${XGETTEXT} -L Python --keyword=_:1,2 --keyword=N_:1,2 --no-location"
  37
  38 GETTEXT_PACKAGE=${PACKAGE_TARNAME}
  39 AC_SUBST(GETTEXT_PACKAGE)
  40
  41 AC_PROG_SED
  42 AC_PROG_MKDIR_P
  43
  44 # - man ------------------------------------------------------------------------
  45
  46 have_man_pages=no
  47 AC_ARG_ENABLE(man_pages, AS_HELP_STRING([--disable-man-pages],
  48         [do not install man pages]))
  49 AS_IF([test "x$enable_man_pages" != xno], [have_man_pages=yes])
  50 AM_CONDITIONAL(ENABLE_MAN_PAGES, [test "x$have_man_pages" = "xyes"])
  51
  52 AC_PATH_PROG([XSLTPROC], [xsltproc])
  53
  54 AC_CHECK_PROGS(ASCIIDOC, [asciidoc])
  55 if test "${have_man_pages}" = "yes" && test -z "${ASCIIDOC}"; then
  56         AC_MSG_ERROR([Required program 'asciidoc' not found])
  57 fi
  58 # - debug ----------------------------------------------------------------------
  59
  60 AC_ARG_ENABLE([debug],
  61         AS_HELP_STRING([--enable-debug], [enable debug messages @<:@default=disabled@:>@]),
  62         [], [enable_debug=no])
  63 AS_IF([test "x$enable_debug" = "xyes"], [
  64         AC_DEFINE(ENABLE_DEBUG, [1], [Debug messages.])
  65 ])
  66
  67 AC_CHECK_HEADERS_ONCE([
  68         arpa/inet.h \
  69         arpa/nameser.h \
  70         arpa/nameser_compat.h \
  71         endian.h \
  72         netinet/in.h \
  73     resolv.h \
  74         string.h \
  75 ])
  76
  77 AC_CHECK_FUNCS([ \
  78     be16toh \
  79     be32toh \
  80     be64toh \
  81     htobe16 \
  82     htobe32 \
  83     htobe64 \
  84     mmap \
  85     munmap \
  86     res_query \
  87         __secure_getenv \
  88         secure_getenv \
  89     qsort \
  90 ])
  91
  92 my_CFLAGS="\
  93 -Wall \
  94 -Wchar-subscripts \
  95 -Wformat-security \
  96 -Wmissing-declarations \
  97 -Wmissing-prototypes \
  98 -Wnested-externs \
  99 -Wpointer-arith \
 100 -Wshadow \
 101 -Wsign-compare \
 102 -Wstrict-prototypes \
 103 -Wtype-limits \
 104 "
 105 AC_SUBST([my_CFLAGS])
 106
 107 # Enable -fanalyzer if requested
 108 AC_ARG_ENABLE([analyzer],
 109         AS_HELP_STRING([--enable-analyzer], [enable static analyzer (-fanalyzer) @<:@default=disabled@:>@]),
 110         [], [enable_analyzer=no])
 111 AS_IF([test "x$enable_analyzer" = "xyes"],
 112         CC_CHECK_FLAGS_APPEND([my_CFLAGS], [CFLAGS], [-fanalyzer])
 113 )
 114
 115 # ------------------------------------------------------------------------------
 116
 117 AC_ARG_WITH([systemd],
 118         AS_HELP_STRING([--with-systemd], [Enable systemd support.])
 119 )
 120
 121 AS_IF([test "x$with_systemd" != "xno"],
 122       [PKG_CHECK_MODULES(systemd, [libsystemd],
 123       [have_systemd=yes], [have_systemd=no])],
 124       [have_systemd=no]
 125 )
 126
 127 AS_IF([test "x$have_systemd" = "xyes"],
 128       [AC_MSG_CHECKING([for systemd system unit directory])
 129         AC_ARG_WITH([systemdsystemunitdir],
 130                 AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [Directory for systemd service files]),
 131                 [], [with_systemdsystemunitdir=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)]
 132         )
 133
 134         AC_SUBST([systemdsystemunitdir], [$with_systemdsystemunitdir])
 135
 136         if test -n "$systemdsystemunitdir" -a "x$systemdsystemunitdir" != xno; then
 137                 AC_MSG_RESULT([$systemdsystemunitdir])
 138         else
 139                 AC_MSG_ERROR([not found (try --with-systemdsystemunitdir)])
 140         fi
 141       ],
 142       [AS_IF([test "x$with_systemd" = "xyes"],
 143              [AC_MSG_ERROR([Systemd support is enabled but no systemd has been found.])
 144       ])
 145 ])
 146
 147 AM_CONDITIONAL(HAVE_SYSTEMD, [test "x$have_systemd" = "xyes"])
 148
 149 # ------------------------------------------------------------------------------
 150
 151 # Python
 152 AM_PATH_PYTHON([3.4])
 153 PKG_CHECK_MODULES([PYTHON], [python-${PYTHON_VERSION}])
 154
 155 # Perl
 156 AC_PATH_PROG(PERL, perl, no)
 157 AC_SUBST(PERL)
 158
 159 AX_PROG_PERL_MODULES(ExtUtils::MakeMaker,, AC_MSG_WARN(Need some Perl modules))
 160
 161 AC_ARG_ENABLE(perl, AS_HELP_STRING([--disable-perl], [do not build the perl modules]), [],[enable_perl=yes])
 162 AM_CONDITIONAL(ENABLE_PERL, test "$enable_perl" = "yes")
 163
 164 dnl Checking for libresolv
 165 case "${host}" in
 166         *-gnu*)
 167                 AC_CHECK_LIB(resolv, ns_msg_getflag, [LIBS="-lresolv $LIBS"], AC_MSG_ERROR([libresolv has not been found]), -lresolv)
 168                 ;;
 169         *)
 170                 AC_CHECK_LIB(resolv, res_init, [LIBS="-lresolv $LIBS"], AC_MSG_ERROR([libresolv has not been found]), -lresolv)
 171                 ;;
 172 esac
 173 RESOLV_LIBS="${LIBS}"
 174 AC_SUBST(RESOLV_LIBS)
 175
 176 dnl Checking for OpenSSL
 177 LIBS=
 178 AC_CHECK_LIB(crypto, EVP_EncryptInit,, AC_MSG_ERROR([libcrypto has not been found]))
 179 OPENSSL_LIBS="${LIBS}"
 180 AC_SUBST(OPENSSL_LIBS)
 181
 182 AC_CONFIG_HEADERS(config.h)
 183 AC_CONFIG_FILES([
 184         Makefile
 185         po/Makefile.in
 186 ])
 187
 188 AC_OUTPUT
 189 AC_MSG_RESULT([
 190         $PACKAGE $VERSION
 191         =====
 192
 193         prefix:                 ${prefix}
 194         sysconfdir:             ${sysconfdir}
 195         libdir:                 ${libdir}
 196         includedir:             ${includedir}
 197
 198         compiler:               ${CC}
 199         cflags:                 ${CFLAGS}
 200         ldflags:                ${LDFLAGS}
 201
 202         debug:                  ${enable_debug}
 203         systemd support:        ${have_systemd}
 204
 205         Bindings:
 206           perl:                 ${enable_perl}
 207 ])