binutils/configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl   Copyright (C) 2012-2020 Free Software Foundation, Inc.
   4 dnl
   5 dnl This file is free software; you can redistribute it and/or modify
   6 dnl it under the terms of the GNU General Public License as published by
   7 dnl the Free Software Foundation; either version 3 of the License, or
   8 dnl (at your option) any later version.
   9 dnl
  10 dnl This program is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 dnl GNU General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU General Public License
  16 dnl along with this program; see the file COPYING3.  If not see
  17 dnl <http://www.gnu.org/licenses/>.
  18 dnl
  19
  20 m4_include([../bfd/version.m4])
  21 m4_include([../config/debuginfod.m4])
  22 AC_INIT([binutils], BFD_VERSION)
  23 AC_CONFIG_SRCDIR(ar.c)
  24
  25 AC_CANONICAL_TARGET
  26 AC_ISC_POSIX
  27
  28 AM_INIT_AUTOMAKE
  29
  30 AC_PROG_CC
  31 AC_GNU_SOURCE
  32 AC_USE_SYSTEM_EXTENSIONS
  33
  34 LT_INIT
  35 ACX_LARGEFILE
  36
  37 AC_ARG_ENABLE(targets,
  38 [  --enable-targets        alternative target configurations],
  39 [case "${enableval}" in
  40   yes | "") AC_MSG_ERROR(enable-targets option must specify target names or 'all')
  41             ;;
  42   no)       enable_targets= ;;
  43   *)        enable_targets=$enableval ;;
  44 esac])dnl
  45
  46 AC_ARG_ENABLE(deterministic-archives,
  47 [AS_HELP_STRING([--enable-deterministic-archives],
  48                 [ar and ranlib default to -D behavior])], [
  49 if test "${enableval}" = no; then
  50   default_ar_deterministic=0
  51 else
  52   default_ar_deterministic=1
  53 fi], [default_ar_deterministic=0])
  54
  55 AC_DEFINE_UNQUOTED(DEFAULT_AR_DETERMINISTIC, $default_ar_deterministic,
  56                    [Should ar and ranlib use -D behavior by default?])
  57
  58 AC_ARG_ENABLE(default-strings-all,
  59 [AS_HELP_STRING([--disable-default-strings-all],
  60                 [strings defaults to --data behavior])], [
  61 if test "${enableval}" = no; then
  62   default_strings_all=0
  63 else
  64   default_strings_all=1
  65 fi], [default_strings_all=1])
  66
  67 AC_DEBUGINFOD
  68
  69 AC_DEFINE_UNQUOTED(DEFAULT_STRINGS_ALL, $default_strings_all,
  70                    [Should strings use -a behavior by default?])
  71
  72 AM_BINUTILS_WARNINGS
  73
  74 AC_CONFIG_HEADERS(config.h:config.in)
  75
  76 AH_VERBATIM([00_CONFIG_H_CHECK],
  77 [/* Check that config.h is #included before system headers
  78    (this works only for glibc, but that should be enough).  */
  79 #if defined(__GLIBC__) && !defined(__FreeBSD_kernel__) && !defined(__CONFIG_H__)
  80 #  error config.h must be #included before system headers
  81 #endif
  82 #define __CONFIG_H__ 1])
  83
  84 if test -z "$target" ; then
  85     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
  86 fi
  87 if test -z "$host" ; then
  88     AC_MSG_ERROR(Unrecognized host system type; please check config.sub.)
  89 fi
  90
  91 AC_PROG_YACC
  92 AM_PROG_LEX
  93
  94 ALL_LINGUAS="bg ca da es fi fr hr id it ja pt ro ru rw sk sr sv tr uk vi zh_CN zh_TW"
  95 ZW_GNU_GETTEXT_SISTER_DIR
  96 AM_PO_SUBDIRS
  97
  98 AM_MAINTAINER_MODE
  99 AM_CONDITIONAL(GENINSRC_NEVER, false)
 100 AC_EXEEXT
 101 if test -n "$EXEEXT"; then
 102   AC_DEFINE(HAVE_EXECUTABLE_SUFFIX, 1,
 103             [Does the platform use an executable suffix?])
 104 fi
 105 AC_DEFINE_UNQUOTED(EXECUTABLE_SUFFIX, "${EXEEXT}",
 106                    [Suffix used for executables, if any.])
 107
 108 # host-specific stuff:
 109
 110 HDEFINES=
 111
 112 . ${srcdir}/../bfd/configure.host
 113
 114 AC_SUBST(HDEFINES)
 115 AR=${AR-ar}
 116 AC_SUBST(AR)
 117 AC_PROG_RANLIB
 118 AC_PROG_INSTALL
 119
 120 BFD_CC_FOR_BUILD
 121
 122 DEMANGLER_NAME=c++filt
 123 case "${host}" in
 124   *-*-go32* | *-*-msdos*)
 125     DEMANGLER_NAME=cxxfilt
 126 esac
 127 AC_SUBST(DEMANGLER_NAME)
 128
 129 AC_CHECK_SIZEOF([long])
 130 AC_CHECK_TYPES([long long], [AC_CHECK_SIZEOF(long long)])
 131
 132 AC_CHECK_HEADERS(string.h strings.h stdlib.h unistd.h fcntl.h sys/file.h limits.h locale.h sys/param.h wchar.h)
 133 AC_HEADER_SYS_WAIT
 134 ACX_HEADER_STRING
 135 AC_FUNC_ALLOCA
 136 AC_FUNC_MMAP
 137 AC_CHECK_FUNCS(sbrk utimes setmode getc_unlocked strcoll setlocale)
 138 AC_CHECK_FUNC([mkstemp],
 139               AC_DEFINE([HAVE_MKSTEMP], 1,
 140               [Define to 1 if you have the `mkstemp' function.]))
 141 AC_CHECK_FUNC([mkdtemp],
 142               AC_DEFINE([HAVE_MKDTEMP], 1,
 143               [Define to 1 if you have the `mkdtemp' function.]))
 144   AC_MSG_CHECKING([for mbstate_t])
 145   AC_TRY_COMPILE([#include <wchar.h>],
 146   [mbstate_t teststate;],
 147   have_mbstate_t=yes, have_mbstate_t=no)
 148   AC_MSG_RESULT($have_mbstate_t)
 149   if test x"$have_mbstate_t" = xyes; then
 150     AC_DEFINE(HAVE_MBSTATE_T,1,[Define if mbstate_t exists in wchar.h.])
 151   fi
 152
 153 # Some systems have frexp only in -lm, not in -lc.
 154 AC_SEARCH_LIBS(frexp, m)
 155
 156 AM_LC_MESSAGES
 157
 158 AC_MSG_CHECKING(for time_t in time.h)
 159 AC_CACHE_VAL(bu_cv_decl_time_t_time_h,
 160 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <time.h>], [time_t i;])],
 161 bu_cv_decl_time_t_time_h=yes, bu_cv_decl_time_t_time_h=no)])
 162 AC_MSG_RESULT($bu_cv_decl_time_t_time_h)
 163 if test $bu_cv_decl_time_t_time_h = yes; then
 164   AC_DEFINE([HAVE_TIME_T_IN_TIME_H], 1,
 165             [Is the type time_t defined in <time.h>?])
 166 fi
 167
 168 AC_MSG_CHECKING(for time_t in sys/types.h)
 169 AC_CACHE_VAL(bu_cv_decl_time_t_types_h,
 170 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>], [time_t i;])],
 171 bu_cv_decl_time_t_types_h=yes, bu_cv_decl_time_t_types_h=no)])
 172 AC_MSG_RESULT($bu_cv_decl_time_t_types_h)
 173 if test $bu_cv_decl_time_t_types_h = yes; then
 174   AC_DEFINE([HAVE_TIME_T_IN_TYPES_H], 1,
 175             [Is the type time_t defined in <sys/types.h>?])
 176 fi
 177
 178 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
 179 AC_CACHE_VAL(bu_cv_decl_getopt_unistd_h,
 180 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);])],
 181 bu_cv_decl_getopt_unistd_h=yes, bu_cv_decl_getopt_unistd_h=no)])
 182 AC_MSG_RESULT($bu_cv_decl_getopt_unistd_h)
 183 if test $bu_cv_decl_getopt_unistd_h = yes; then
 184   AC_DEFINE([HAVE_DECL_GETOPT], 1,
 185             [Is the prototype for getopt in <unistd.h> in the expected format?])
 186 fi
 187
 188 # Under Next 3.2 <utime.h> apparently does not define struct utimbuf
 189 # by default.
 190 AC_MSG_CHECKING([for utime.h])
 191 AC_CACHE_VAL(bu_cv_header_utime_h,
 192 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
 193 #ifdef HAVE_TIME_H
 194 #include <time.h>
 195 #endif
 196 #include <utime.h>],
 197 [struct utimbuf s;])],
 198 bu_cv_header_utime_h=yes, bu_cv_header_utime_h=no)])
 199 AC_MSG_RESULT($bu_cv_header_utime_h)
 200 if test $bu_cv_header_utime_h = yes; then
 201   AC_DEFINE(HAVE_GOOD_UTIME_H, 1, [Does <utime.h> define struct utimbuf?])
 202 fi
 203
 204 AC_CHECK_DECLS([asprintf, environ, fprintf, getc_unlocked, getenv,
 205                 sbrk, snprintf, stpcpy, strnlen, strstr, vsnprintf])
 206
 207 # Link in zlib if we can.  This allows us to read compressed debug
 208 # sections.  This is used only by readelf.c (objdump uses bfd for
 209 # reading compressed sections).
 210 AM_ZLIB
 211
 212 BFD_BINARY_FOPEN
 213
 214 # target-specific stuff:
 215
 216 # Canonicalize the secondary target names.
 217 if test -n "$enable_targets"; then
 218     for targ in `echo $enable_targets | sed 's/,/ /g'`
 219     do
 220         result=`$ac_config_sub $targ 2>/dev/null`
 221         if test -n "$result"; then
 222             canon_targets="$canon_targets $result"
 223         else
 224             # Allow targets that config.sub doesn't recognize, like "all".
 225             canon_targets="$canon_targets $targ"
 226         fi
 227     done
 228 fi
 229
 230 AC_CHECK_HEADER(iconv.h)
 231 AM_ICONV
 232
 233 all_targets=false
 234 BUILD_SRCONV=
 235 BUILD_DLLTOOL=
 236 DLLTOOL_DEFS=
 237 DLLTOOL_DEFAULT=
 238 BUILD_WINDRES=
 239 BUILD_WINDMC=
 240 BUILD_DLLWRAP=
 241 BUILD_MISC=
 242 BUILD_INSTALL_MISC=
 243 OBJDUMP_DEFS=
 244 OBJDUMP_PRIVATE_VECTORS=
 245 OBJDUMP_PRIVATE_OFILES=
 246 od_vectors=
 247
 248 for targ in $target $canon_targets
 249 do
 250     if test "x$targ" = "xall"; then
 251         all_targets=true
 252         BUILD_SRCONV='$(SRCONV_PROG)'
 253         BUILD_MISC="${BUILD_MISC} "'bin2c$(EXEEXT_FOR_BUILD)'
 254         BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 255         BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 256         BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 257         if test -z "$DLLTOOL_DEFAULT"; then
 258           DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_I386"
 259         fi
 260         DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_I386"
 261         BUILD_DLLWRAP='$(DLLWRAP_PROG)$(EXEEXT)'
 262         od_vectors="$od_vectors objdump_private_desc_xcoff"
 263     else
 264         case $targ in
 265         *-*-hms*) BUILD_SRCONV='$(SRCONV_PROG)' ;;
 266         esac
 267
 268         case $targ in
 269         arm-wince-pe* | arm-*-wince | arm*-*-cegcc* | arm*-*-mingw32ce*)
 270           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 271           if test -z "$DLLTOOL_DEFAULT"; then
 272             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_ARM_WINCE"
 273           fi
 274           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_ARM_WINCE -DDLLTOOL_ARM"
 275           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 276           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 277           ;;
 278         arm-*-pe*)
 279           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 280           if test -z "$DLLTOOL_DEFAULT"; then
 281             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_ARM"
 282           fi
 283           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_ARM"
 284           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 285           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 286           ;;
 287         x86_64-*-mingw* | x86_64-*-cygwin*)
 288           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 289           if test -z "$DLLTOOL_DEFAULT"; then
 290             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_MX86_64"
 291           fi
 292           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_MX86_64"
 293           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 294           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 295           BUILD_DLLWRAP='$(DLLWRAP_PROG)$(EXEEXT)'
 296           ;;
 297 changequote(,)dnl
 298         i[3-7]86-*-pe* | i[3-7]86-*-cygwin* | i[3-7]86-*-mingw32** | i[3-7]86-*-netbsdpe*)
 299 changequote([,])dnl
 300           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 301           if test -z "$DLLTOOL_DEFAULT"; then
 302             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_I386"
 303           fi
 304           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_I386"
 305           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 306           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 307           BUILD_DLLWRAP='$(DLLWRAP_PROG)$(EXEEXT)'
 308           ;;
 309 changequote(,)dnl
 310         i[3-7]86-*-interix)
 311 changequote([,])dnl
 312           BUILD_DLLTOOL='$(DLLTOOL_PROG)'
 313           if test -z "$DLLTOOL_DEFAULT"; then
 314             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_I386"
 315           fi
 316           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_I386"
 317           ;;
 318 changequote(,)dnl
 319         powerpc*-aix5.[01])
 320 changequote([,])dnl
 321           ;;
 322 changequote(,)dnl
 323         powerpc*-aix[5-9].*)
 324 changequote([,])dnl
 325           OBJDUMP_DEFS="-DAIX_WEAK_SUPPORT"
 326           ;;
 327         powerpc*-*-pe* | powerpc*-*-cygwin*)
 328           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 329           if test -z "$DLLTOOL_DEFAULT"; then
 330             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_PPC"
 331           fi
 332           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_PPC"
 333           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 334           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 335           ;;
 336         powerpc*-*-linux* | powerpc*-*-elf* | powerpc*-*-eabi*)
 337           case "$BUILD_INSTALL_MISC" in
 338             *embedspu*) ;;
 339             *) BUILD_INSTALL_MISC="${BUILD_INSTALL_MISC} embedspu"
 340           esac
 341           ;;
 342         sh*-*-pe)
 343           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 344           if test -z "$DLLTOOL_DEFAULT"; then
 345             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_SH"
 346           fi
 347           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_SH"
 348           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 349           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 350           ;;
 351         spu-*-*)
 352           BUILD_MISC="${BUILD_MISC} "'bin2c$(EXEEXT_FOR_BUILD)'
 353           ;;
 354         mips*-*-pe)
 355           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 356           if test -z "$DLLTOOL_DEFAULT"; then
 357             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_MIPS"
 358           fi
 359           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_MIPS"
 360           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 361           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 362           ;;
 363         mcore-*-pe)
 364           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 365           if test -z "$DLLTOOL_DEFAULT"; then
 366             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_MCORE"
 367           fi
 368           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_MCORE"
 369           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 370           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 371           ;;
 372         mcore-*-elf)
 373           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 374           if test -z "$DLLTOOL_DEFAULT"; then
 375             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_MCORE_ELF"
 376           fi
 377           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_MCORE_ELF"
 378           ;;
 379         mep-*)
 380           OBJDUMP_DEFS="-DSKIP_ZEROES=256 -DSKIP_ZEROES_AT_END=0"
 381           ;;
 382         esac
 383
 384         # Add objdump private vectors.
 385         case $targ in
 386         avr-*-*)
 387           od_vectors="$od_vectors objdump_private_desc_elf32_avr"
 388           ;;
 389         powerpc*-*-aix* | rs6000-*-aix*)
 390           od_vectors="$od_vectors objdump_private_desc_xcoff"
 391           ;;
 392         *-*-darwin*)
 393           od_vectors="$od_vectors objdump_private_desc_mach_o"
 394           ;;
 395         esac
 396     fi
 397 done
 398
 399 # Uniq objdump private vector, build objdump target ofiles.
 400 od_files=
 401 f=""
 402 for i in $od_vectors ; do
 403     case " $f " in
 404     *" $i "*) ;;
 405     *)
 406         f="$f $i"
 407         OBJDUMP_PRIVATE_VECTORS="$OBJDUMP_PRIVATE_VECTORS &$i,"
 408         case $i in
 409         objdump_private_desc_elf32_avr)
 410             od_files="$od_files od-elf32_avr" ;;
 411         objdump_private_desc_xcoff)
 412             od_files="$od_files od-xcoff" ;;
 413         objdump_private_desc_mach_o)
 414             od_files="$od_files od-macho" ;;
 415         *) AC_MSG_ERROR(*** unknown private vector $i) ;;
 416         esac
 417         ;;
 418     esac
 419 done
 420
 421 # Uniq objdump target ofiles
 422 f=""
 423 for i in $od_files ; do
 424     case " $f " in
 425     *" $i "*) ;;
 426     *)
 427         f="$f $i"
 428         OBJDUMP_PRIVATE_OFILES="$OBJDUMP_PRIVATE_OFILES $i.$objext"
 429         ;;
 430     esac
 431 done
 432
 433 DLLTOOL_DEFS="$DLLTOOL_DEFS $DLLTOOL_DEFAULT"
 434
 435 if test "${with_windres+set}" = set; then
 436           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 437 fi
 438
 439 if test "${with_windmc+set}" = set; then
 440           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 441 fi
 442
 443 OBJDUMP_DEFS="${OBJDUMP_DEFS} -DOBJDUMP_PRIVATE_VECTORS=\"${OBJDUMP_PRIVATE_VECTORS}\""
 444
 445 AC_SUBST(BUILD_SRCONV)
 446 AC_SUBST(BUILD_DLLTOOL)
 447 AC_SUBST(DLLTOOL_DEFS)
 448 AC_SUBST(BUILD_WINDRES)
 449 AC_SUBST(BUILD_WINDMC)
 450 AC_SUBST(BUILD_DLLWRAP)
 451 AC_SUBST(BUILD_MISC)
 452 AC_SUBST(BUILD_INSTALL_MISC)
 453 AC_SUBST(OBJDUMP_DEFS)
 454 AC_SUBST(OBJDUMP_PRIVATE_OFILES)
 455
 456 AC_DEFINE_UNQUOTED(TARGET, "${target}", [Configured target name.])
 457
 458 targ=$target
 459 . $srcdir/../bfd/config.bfd
 460 if test "x$targ_underscore" = "xyes"; then
 461     UNDERSCORE=1
 462 else
 463     UNDERSCORE=0
 464 fi
 465 AC_DEFINE_UNQUOTED(TARGET_PREPENDS_UNDERSCORE, $UNDERSCORE,
 466  [Define to 1 if user symbol names have a leading underscore, 0 if not.])
 467
 468 # Emulation
 469 targ=$target
 470 . ${srcdir}/configure.tgt
 471 EMULATION=$targ_emul
 472 EMULATION_VECTOR=$targ_emul_vector
 473
 474 AC_SUBST(EMULATION)
 475 AC_SUBST(EMULATION_VECTOR)
 476
 477 # Required for html and install-html
 478 AC_SUBST(datarootdir)
 479 AC_SUBST(docdir)
 480 AC_SUBST(htmldir)
 481 AC_SUBST(pdfdir)
 482
 483 AC_CONFIG_FILES(Makefile doc/Makefile po/Makefile.in:po/Make-in)
 484 AC_OUTPUT