binutils/configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl   Copyright (C) 2012-2023 Free Software Foundation, Inc.
   4 dnl
   5 dnl This file is free software; you can redistribute it and/or modify
   6 dnl it under the terms of the GNU General Public License as published by
   7 dnl the Free Software Foundation; either version 3 of the License, or
   8 dnl (at your option) any later version.
   9 dnl
  10 dnl This program is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 dnl GNU General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU General Public License
  16 dnl along with this program; see the file COPYING3.  If not see
  17 dnl <http://www.gnu.org/licenses/>.
  18 dnl
  19
  20 m4_include([../bfd/version.m4])
  21 m4_include([../config/debuginfod.m4])
  22 AC_INIT([binutils], BFD_VERSION)
  23 AC_CONFIG_SRCDIR(ar.c)
  24
  25 AC_CANONICAL_TARGET
  26
  27 AM_INIT_AUTOMAKE
  28 AM_SILENT_RULES([yes])
  29
  30 AC_PROG_CC
  31 AC_GNU_SOURCE
  32 AC_USE_SYSTEM_EXTENSIONS
  33
  34 LT_INIT
  35 ACX_LARGEFILE
  36
  37 ac_checking=
  38 . ${srcdir}/../bfd/development.sh
  39 test "$development" = true && ac_checking=yes
  40 AC_ARG_ENABLE(checking,
  41 [  --enable-checking       enable run-time checks],
  42 [case "${enableval}" in
  43   no|none)  ac_checking= ;;
  44   *)        ac_checking=yes ;;
  45 esac])dnl
  46 if test x$ac_checking != x ; then
  47   AC_DEFINE(ENABLE_CHECKING, 1, [Define if you want run-time sanity checks.])
  48 fi
  49
  50 AC_ARG_ENABLE(targets,
  51 [  --enable-targets        alternative target configurations],
  52 [case "${enableval}" in
  53   yes | "") AC_MSG_ERROR(enable-targets option must specify target names or 'all')
  54             ;;
  55   no)       enable_targets= ;;
  56   *)        enable_targets=$enableval ;;
  57 esac])dnl
  58
  59
  60 AC_ARG_ENABLE(deterministic-archives,
  61 [AS_HELP_STRING([--enable-deterministic-archives],
  62                 [ar and ranlib default to -D behavior])], [
  63 if test "${enableval}" = no; then
  64   default_ar_deterministic=0
  65 else
  66   default_ar_deterministic=1
  67 fi], [default_ar_deterministic=0])
  68
  69 AC_DEFINE_UNQUOTED(DEFAULT_AR_DETERMINISTIC, $default_ar_deterministic,
  70                    [Should ar and ranlib use -D behavior by default?])
  71
  72
  73 AC_ARG_ENABLE(default-strings-all,
  74 [AS_HELP_STRING([--disable-default-strings-all],
  75                 [strings defaults to --data behavior])], [
  76 if test "${enableval}" = no; then
  77   default_strings_all=0
  78 else
  79   default_strings_all=1
  80 fi], [default_strings_all=1])
  81
  82 AC_DEFINE_UNQUOTED(DEFAULT_STRINGS_ALL, $default_strings_all,
  83                    [Should strings use -a behavior by default?])
  84
  85
  86 AC_ARG_ENABLE(f-for-ifunc-symbols,
  87 [AS_HELP_STRING([--enable-f-for-ifunc-symbols],
  88         [Have nm use F and f for global and local ifunc symbols])], [
  89 if test "${enableval}" = no; then
  90   default_f_for_ifunc=0
  91 else
  92   default_f_for_ifunc=1
  93 fi], [default_f_for_ifunc=0])
  94
  95 AC_DEFINE_UNQUOTED(DEFAULT_F_FOR_IFUNC_SYMBOLS, $default_f_for_ifunc,
  96                    [Have nm use F and f for global and local ifunc symbols])
  97
  98
  99 AC_ARG_ENABLE(follow-debug-links,
 100 [AS_HELP_STRING([--enable-follow-debug-links],
 101         [Have readelf and objdump follow debug links by default])], [
 102 if test "${enableval}" = no; then
 103   default_for_follow_links=0
 104 else
 105   default_for_follow_links=1
 106 fi], [default_for_follow_links=1])
 107
 108 AC_DEFINE_UNQUOTED(DEFAULT_FOR_FOLLOW_LINKS, $default_for_follow_links,
 109                    [Have readelf and objdump follow debug links by default])
 110
 111
 112
 113
 114 AC_ARG_ENABLE(colored-disassembly,
 115 [AS_HELP_STRING([--enable-colored-disassembly],
 116         [Have objdump use colors in its disassembly by default])], [
 117 if test "${enableval}" = no; then
 118   default_for_colored_disassembly=0
 119 else
 120   default_for_colored_disassembly=1
 121 fi], [default_for_colored_disassembly=0])
 122
 123 AC_DEFINE_UNQUOTED(DEFAULT_FOR_COLORED_DISASSEMBLY, $default_for_colored_disassembly,
 124                    [Have objdump use colors in its disassembly by default])
 125
 126
 127 AC_DEBUGINFOD
 128
 129 GCC_ENABLE([libctf], [yes], [], [Handle .ctf type-info sections])
 130 if test "${enable_libctf}" = yes; then
 131     AC_DEFINE(ENABLE_LIBCTF, 1, [Handle .ctf type-info sections])
 132 fi
 133 AM_CONDITIONAL(ENABLE_LIBCTF, test "${enable_libctf}" = yes)
 134
 135 AM_BINUTILS_WARNINGS
 136
 137 AC_CONFIG_HEADERS(config.h:config.in)
 138
 139 AH_VERBATIM([00_CONFIG_H_CHECK],
 140 [/* Check that config.h is #included before system headers
 141    (this works only for glibc, but that should be enough).  */
 142 #if defined(__GLIBC__) && !defined(__FreeBSD_kernel__) && !defined(__CONFIG_H__)
 143 #  error config.h must be #included before system headers
 144 #endif
 145 #define __CONFIG_H__ 1])
 146
 147 if test -z "$target" ; then
 148     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
 149 fi
 150 if test -z "$host" ; then
 151     AC_MSG_ERROR(Unrecognized host system type; please check config.sub.)
 152 fi
 153
 154 AC_PROG_YACC
 155 AM_PROG_LEX
 156
 157 ALL_LINGUAS="bg ca da es fi fr hr id it ja pt ro ru rw sk sr sv tr uk vi zh_CN zh_TW"
 158 ZW_GNU_GETTEXT_SISTER_DIR
 159 AM_PO_SUBDIRS
 160
 161 AM_MAINTAINER_MODE
 162 AM_CONDITIONAL(GENINSRC_NEVER, false)
 163 AC_EXEEXT
 164 if test -n "$EXEEXT"; then
 165   AC_DEFINE(HAVE_EXECUTABLE_SUFFIX, 1,
 166             [Does the platform use an executable suffix?])
 167 fi
 168 AC_DEFINE_UNQUOTED(EXECUTABLE_SUFFIX, "${EXEEXT}",
 169                    [Suffix used for executables, if any.])
 170
 171 # host-specific stuff:
 172
 173 HDEFINES=
 174
 175 . ${srcdir}/../bfd/configure.host
 176
 177 AC_SUBST(HDEFINES)
 178 AR=${AR-ar}
 179 AC_SUBST(AR)
 180 AC_PROG_RANLIB
 181 AC_PROG_INSTALL
 182
 183 BFD_CC_FOR_BUILD
 184
 185 DEMANGLER_NAME=c++filt
 186 case "${host}" in
 187   *-*-go32* | *-*-msdos*)
 188     DEMANGLER_NAME=cxxfilt
 189 esac
 190 AC_SUBST(DEMANGLER_NAME)
 191
 192 # We use headers from include/ that check various HAVE_*_H macros, thus
 193 # should ensure they are set by configure.  This is true even when C99
 194 # guarantees they are available.
 195 # plugin-api.h tests HAVE_STDINT_H and HAVE_INTTYPES_H
 196 # Besides those, we need to check anything used in binutils/ not in C99.
 197 AC_CHECK_HEADERS(fcntl.h inttypes.h stdint.h sys/file.h \
 198                  sys/stat.h sys/time.h sys/types.h unistd.h)
 199 AC_HEADER_SYS_WAIT
 200 AC_FUNC_MMAP
 201 AC_CHECK_FUNCS(fseeko fseeko64 getc_unlocked mkdtemp mkstemp utimensat utimes)
 202
 203 AC_MSG_CHECKING([for mbstate_t])
 204 AC_TRY_COMPILE([#include <wchar.h>],
 205 [mbstate_t teststate;],
 206 have_mbstate_t=yes, have_mbstate_t=no)
 207 AC_MSG_RESULT($have_mbstate_t)
 208 if test x"$have_mbstate_t" = xyes; then
 209   AC_DEFINE(HAVE_MBSTATE_T,1,[Define if mbstate_t exists in wchar.h.])
 210 fi
 211
 212 # Copied from gnulib stat-time.m4.
 213 # We should just switch over to using gnulib.
 214 AC_CHECK_MEMBERS([struct stat.st_atim.tv_nsec],
 215   [AC_CACHE_CHECK([whether struct stat.st_atim is of type struct timespec],
 216      [ac_cv_typeof_struct_stat_st_atim_is_struct_timespec],
 217      [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 218         [[
 219           #include <sys/types.h>
 220           #include <sys/stat.h>
 221           #if HAVE_SYS_TIME_H
 222           # include <sys/time.h>
 223           #endif
 224           #include <time.h>
 225           struct timespec ts;
 226           struct stat st;
 227         ]],
 228         [[
 229           st.st_atim = ts;
 230         ]])],
 231         [ac_cv_typeof_struct_stat_st_atim_is_struct_timespec=yes],
 232         [ac_cv_typeof_struct_stat_st_atim_is_struct_timespec=no])])
 233    if test $ac_cv_typeof_struct_stat_st_atim_is_struct_timespec = yes; then
 234      AC_DEFINE([TYPEOF_STRUCT_STAT_ST_ATIM_IS_STRUCT_TIMESPEC], [1],
 235        [Define to 1 if the type of the st_atim member of a struct stat is
 236         struct timespec.])
 237    fi],
 238   [AC_CHECK_MEMBERS([struct stat.st_atimespec.tv_nsec], [],
 239      [AC_CHECK_MEMBERS([struct stat.st_atimensec], [],
 240         [AC_CHECK_MEMBERS([struct stat.st_atim.st__tim.tv_nsec], [], [],
 241            [#include <sys/types.h>
 242             #include <sys/stat.h>])],
 243         [#include <sys/types.h>
 244          #include <sys/stat.h>])],
 245      [#include <sys/types.h>
 246       #include <sys/stat.h>])],
 247   [#include <sys/types.h>
 248    #include <sys/stat.h>])
 249
 250 # Some systems have frexp only in -lm, not in -lc.
 251 AC_SEARCH_LIBS(frexp, m)
 252
 253 AM_LC_MESSAGES
 254
 255 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
 256 AC_CACHE_VAL(bu_cv_decl_getopt_unistd_h,
 257 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);])],
 258 bu_cv_decl_getopt_unistd_h=yes, bu_cv_decl_getopt_unistd_h=no)])
 259 AC_MSG_RESULT($bu_cv_decl_getopt_unistd_h)
 260 if test $bu_cv_decl_getopt_unistd_h = yes; then
 261   AC_DEFINE([HAVE_DECL_GETOPT], 1,
 262             [Is the prototype for getopt in <unistd.h> in the expected format?])
 263 fi
 264
 265 # Under Next 3.2 <utime.h> apparently does not define struct utimbuf
 266 # by default.
 267 AC_MSG_CHECKING([for utime.h])
 268 AC_CACHE_VAL(bu_cv_header_utime_h,
 269 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
 270 #ifdef HAVE_TIME_H
 271 #include <time.h>
 272 #endif
 273 #include <utime.h>],
 274 [struct utimbuf s;])],
 275 bu_cv_header_utime_h=yes, bu_cv_header_utime_h=no)])
 276 AC_MSG_RESULT($bu_cv_header_utime_h)
 277 if test $bu_cv_header_utime_h = yes; then
 278   AC_DEFINE(HAVE_GOOD_UTIME_H, 1, [Does <utime.h> define struct utimbuf?])
 279 fi
 280
 281 AC_CHECK_DECLS([asprintf, environ, getc_unlocked, stpcpy, strnlen])
 282
 283 # Link in zlib/zstd if we can.  This allows us to read compressed debug
 284 # sections.  This is used only by readelf.c (objdump uses bfd for
 285 # reading compressed sections).
 286 AM_ZLIB
 287 AC_ZSTD
 288
 289 BFD_BINARY_FOPEN
 290
 291 # Support for the msgpack C library.
 292 AC_ARG_WITH([msgpack],
 293             AC_HELP_STRING([--with-msgpack], [Enable msgpack support (auto/yes/no)]),
 294             [],
 295             [with_msgpack=auto])
 296
 297 AS_IF([test "$with_msgpack" != no],
 298   [PKG_CHECK_MODULES(MSGPACK, msgpack,
 299     [AC_DEFINE([HAVE_MSGPACK], [1], [Define to 1 if msgpack is available.])],
 300     [AS_IF([test "$with_msgpack" = yes],
 301       [AC_MSG_ERROR([--with-msgpack was given, but msgpack is missing or unusable.])])])])
 302
 303 # target-specific stuff:
 304
 305 # Canonicalize the secondary target names.
 306 if test -n "$enable_targets"; then
 307     for targ in `echo $enable_targets | sed 's/,/ /g'`
 308     do
 309         result=`$ac_config_sub $targ 2>/dev/null`
 310         if test -n "$result"; then
 311             canon_targets="$canon_targets $result"
 312         else
 313             # Allow targets that config.sub doesn't recognize, like "all".
 314             canon_targets="$canon_targets $targ"
 315         fi
 316     done
 317 fi
 318
 319 AC_CHECK_HEADER(iconv.h)
 320 AM_ICONV
 321
 322 all_targets=false
 323 BUILD_SRCONV=
 324 BUILD_DLLTOOL=
 325 DLLTOOL_DEFS=
 326 DLLTOOL_DEFAULT=
 327 BUILD_WINDRES=
 328 BUILD_WINDMC=
 329 BUILD_DLLWRAP=
 330 BUILD_MISC=
 331 BUILD_INSTALL_MISC=
 332 OBJDUMP_DEFS=
 333 OBJDUMP_PRIVATE_VECTORS=
 334 OBJDUMP_PRIVATE_OFILES=
 335 od_vectors=
 336
 337 for targ in $target $canon_targets
 338 do
 339     if test "x$targ" = "xall"; then
 340         all_targets=true
 341         BUILD_SRCONV='$(SRCONV_PROG)'
 342         BUILD_MISC="${BUILD_MISC} "'bin2c$(EXEEXT_FOR_BUILD)'
 343         BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 344         BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 345         BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 346         if test -z "$DLLTOOL_DEFAULT"; then
 347           DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_I386"
 348         fi
 349         DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_I386"
 350         BUILD_DLLWRAP='$(DLLWRAP_PROG)$(EXEEXT)'
 351         od_vectors="$od_vectors objdump_private_desc_xcoff objdump_private_desc_pe"
 352     else
 353         case $targ in
 354         *-*-hms*) BUILD_SRCONV='$(SRCONV_PROG)' ;;
 355         esac
 356
 357         case $targ in
 358         aarch64-*-mingw*)
 359           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 360           if test -z "$DLLTOOL_DEFAULT"; then
 361             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_AARCH64"
 362           fi
 363           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_AARCH64"
 364           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 365           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 366           BUILD_DLLWRAP='$(DLLWRAP_PROG)$(EXEEXT)'
 367           ;;
 368         arm-wince-pe* | arm-*-wince | arm*-*-cegcc* | arm*-*-mingw32ce*)
 369           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 370           if test -z "$DLLTOOL_DEFAULT"; then
 371             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_ARM_WINCE"
 372           fi
 373           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_ARM_WINCE -DDLLTOOL_ARM"
 374           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 375           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 376           ;;
 377         arm-*-pe*)
 378           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 379           if test -z "$DLLTOOL_DEFAULT"; then
 380             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_ARM"
 381           fi
 382           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_ARM"
 383           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 384           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 385           ;;
 386         x86_64-*-mingw* | x86_64-*-cygwin*)
 387           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 388           if test -z "$DLLTOOL_DEFAULT"; then
 389             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_MX86_64"
 390           fi
 391           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_MX86_64"
 392           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 393           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 394           BUILD_DLLWRAP='$(DLLWRAP_PROG)$(EXEEXT)'
 395           ;;
 396 changequote(,)dnl
 397         i[3-7]86-*-pe* | i[3-7]86-*-cygwin* | i[3-7]86-*-mingw32**)
 398 changequote([,])dnl
 399           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 400           if test -z "$DLLTOOL_DEFAULT"; then
 401             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_I386"
 402           fi
 403           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_I386"
 404           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 405           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 406           BUILD_DLLWRAP='$(DLLWRAP_PROG)$(EXEEXT)'
 407           ;;
 408 changequote(,)dnl
 409         i[3-7]86-*-interix)
 410 changequote([,])dnl
 411           BUILD_DLLTOOL='$(DLLTOOL_PROG)'
 412           if test -z "$DLLTOOL_DEFAULT"; then
 413             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_I386"
 414           fi
 415           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_I386"
 416           ;;
 417 changequote(,)dnl
 418         powerpc*-aix5.[01])
 419 changequote([,])dnl
 420           ;;
 421 changequote(,)dnl
 422         powerpc*-aix[5-9].*)
 423 changequote([,])dnl
 424           OBJDUMP_DEFS="-DAIX_WEAK_SUPPORT"
 425           ;;
 426         powerpc*-*-linux* | powerpc*-*-elf* | powerpc*-*-eabi*)
 427           case "$BUILD_INSTALL_MISC" in
 428             *embedspu*) ;;
 429             *) BUILD_INSTALL_MISC="${BUILD_INSTALL_MISC} embedspu"
 430           esac
 431           ;;
 432         sh*-*-pe)
 433           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 434           if test -z "$DLLTOOL_DEFAULT"; then
 435             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_SH"
 436           fi
 437           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_SH"
 438           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 439           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 440           ;;
 441         spu-*-*)
 442           BUILD_MISC="${BUILD_MISC} "'bin2c$(EXEEXT_FOR_BUILD)'
 443           ;;
 444         mcore-*-pe)
 445           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 446           if test -z "$DLLTOOL_DEFAULT"; then
 447             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_MCORE"
 448           fi
 449           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_MCORE"
 450           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 451           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 452           ;;
 453         mcore-*-elf)
 454           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 455           if test -z "$DLLTOOL_DEFAULT"; then
 456             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_MCORE_ELF"
 457           fi
 458           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_MCORE_ELF"
 459           ;;
 460         mep-*)
 461           OBJDUMP_DEFS="-DSKIP_ZEROES=256 -DSKIP_ZEROES_AT_END=0"
 462           ;;
 463         esac
 464
 465         # Add objdump private vectors.
 466         case $targ in
 467         avr-*-*)
 468           od_vectors="$od_vectors objdump_private_desc_elf32_avr"
 469           ;;
 470         powerpc*-*-aix* | rs6000-*-aix*)
 471           od_vectors="$od_vectors objdump_private_desc_xcoff"
 472           ;;
 473         *-*-pe* | *-*-cygwin* | *-*-mingw*)
 474           od_vectors="$od_vectors objdump_private_desc_pe"
 475           ;;
 476         *-*-darwin*)
 477           od_vectors="$od_vectors objdump_private_desc_mach_o"
 478           ;;
 479         esac
 480     fi
 481 done
 482
 483 # Uniq objdump private vector, build objdump target ofiles.
 484 od_files=
 485 f=""
 486 for i in $od_vectors ; do
 487     case " $f " in
 488     *" $i "*) ;;
 489     *)
 490         f="$f $i"
 491         OBJDUMP_PRIVATE_VECTORS="$OBJDUMP_PRIVATE_VECTORS &$i,"
 492         case $i in
 493         objdump_private_desc_elf32_avr)
 494             od_files="$od_files od-elf32_avr" ;;
 495         objdump_private_desc_xcoff)
 496             od_files="$od_files od-xcoff" ;;
 497         objdump_private_desc_pe)
 498             od_files="$od_files od-pe" ;;
 499         objdump_private_desc_mach_o)
 500             od_files="$od_files od-macho" ;;
 501         *) AC_MSG_ERROR(*** unknown private vector $i) ;;
 502         esac
 503         ;;
 504     esac
 505 done
 506
 507 # Uniq objdump target ofiles
 508 f=""
 509 for i in $od_files ; do
 510     case " $f " in
 511     *" $i "*) ;;
 512     *)
 513         f="$f $i"
 514         OBJDUMP_PRIVATE_OFILES="$OBJDUMP_PRIVATE_OFILES $i.$objext"
 515         ;;
 516     esac
 517 done
 518
 519 DLLTOOL_DEFS="$DLLTOOL_DEFS $DLLTOOL_DEFAULT"
 520
 521 if test "${with_windres+set}" = set; then
 522           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 523 fi
 524
 525 if test "${with_windmc+set}" = set; then
 526           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 527 fi
 528
 529 OBJDUMP_DEFS="${OBJDUMP_DEFS} -DOBJDUMP_PRIVATE_VECTORS=\"${OBJDUMP_PRIVATE_VECTORS}\""
 530
 531 AC_SUBST(BUILD_SRCONV)
 532 AC_SUBST(BUILD_DLLTOOL)
 533 AC_SUBST(DLLTOOL_DEFS)
 534 AC_SUBST(BUILD_WINDRES)
 535 AC_SUBST(BUILD_WINDMC)
 536 AC_SUBST(BUILD_DLLWRAP)
 537 AC_SUBST(BUILD_MISC)
 538 AC_SUBST(BUILD_INSTALL_MISC)
 539 AC_SUBST(OBJDUMP_DEFS)
 540 AC_SUBST(OBJDUMP_PRIVATE_OFILES)
 541
 542 AC_DEFINE_UNQUOTED(TARGET, "${target}", [Configured target name.])
 543
 544 targ=$target
 545 . $srcdir/../bfd/config.bfd
 546 if test "x$targ_underscore" = "xyes"; then
 547     UNDERSCORE=1
 548 else
 549     UNDERSCORE=0
 550 fi
 551 AC_DEFINE_UNQUOTED(TARGET_PREPENDS_UNDERSCORE, $UNDERSCORE,
 552  [Define to 1 if user symbol names have a leading underscore, 0 if not.])
 553
 554 # Emulation
 555 targ=$target
 556 . ${srcdir}/configure.tgt
 557 EMULATION=$targ_emul
 558 EMULATION_VECTOR=$targ_emul_vector
 559
 560 AC_SUBST(EMULATION)
 561 AC_SUBST(EMULATION_VECTOR)
 562
 563 # Required for html and install-html
 564 AC_SUBST(datarootdir)
 565 AC_SUBST(docdir)
 566 AC_SUBST(htmldir)
 567 AC_SUBST(pdfdir)
 568
 569 AC_CONFIG_FILES(Makefile po/Makefile.in:po/Make-in)
 570 AC_OUTPUT
 571
 572 GNU_MAKE_JOBSERVER