binutils/configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl   Copyright (C) 2012-2022 Free Software Foundation, Inc.
   4 dnl
   5 dnl This file is free software; you can redistribute it and/or modify
   6 dnl it under the terms of the GNU General Public License as published by
   7 dnl the Free Software Foundation; either version 3 of the License, or
   8 dnl (at your option) any later version.
   9 dnl
  10 dnl This program is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 dnl GNU General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU General Public License
  16 dnl along with this program; see the file COPYING3.  If not see
  17 dnl <http://www.gnu.org/licenses/>.
  18 dnl
  19
  20 m4_include([../bfd/version.m4])
  21 m4_include([../config/debuginfod.m4])
  22 AC_INIT([binutils], BFD_VERSION)
  23 AC_CONFIG_SRCDIR(ar.c)
  24
  25 AC_CANONICAL_TARGET
  26
  27 AM_INIT_AUTOMAKE
  28 AM_SILENT_RULES([yes])
  29
  30 AC_PROG_CC
  31 AC_GNU_SOURCE
  32 AC_USE_SYSTEM_EXTENSIONS
  33
  34 LT_INIT
  35 ACX_LARGEFILE
  36
  37 ac_checking=
  38 . ${srcdir}/../bfd/development.sh
  39 test "$development" = true && ac_checking=yes
  40 AC_ARG_ENABLE(checking,
  41 [  --enable-checking       enable run-time checks],
  42 [case "${enableval}" in
  43   no|none)  ac_checking= ;;
  44   *)        ac_checking=yes ;;
  45 esac])dnl
  46 if test x$ac_checking != x ; then
  47   AC_DEFINE(ENABLE_CHECKING, 1, [Define if you want run-time sanity checks.])
  48 fi
  49
  50 AC_ARG_ENABLE(targets,
  51 [  --enable-targets        alternative target configurations],
  52 [case "${enableval}" in
  53   yes | "") AC_MSG_ERROR(enable-targets option must specify target names or 'all')
  54             ;;
  55   no)       enable_targets= ;;
  56   *)        enable_targets=$enableval ;;
  57 esac])dnl
  58
  59
  60 AC_ARG_ENABLE(deterministic-archives,
  61 [AS_HELP_STRING([--enable-deterministic-archives],
  62                 [ar and ranlib default to -D behavior])], [
  63 if test "${enableval}" = no; then
  64   default_ar_deterministic=0
  65 else
  66   default_ar_deterministic=1
  67 fi], [default_ar_deterministic=0])
  68
  69 AC_DEFINE_UNQUOTED(DEFAULT_AR_DETERMINISTIC, $default_ar_deterministic,
  70                    [Should ar and ranlib use -D behavior by default?])
  71
  72
  73 AC_ARG_ENABLE(default-strings-all,
  74 [AS_HELP_STRING([--disable-default-strings-all],
  75                 [strings defaults to --data behavior])], [
  76 if test "${enableval}" = no; then
  77   default_strings_all=0
  78 else
  79   default_strings_all=1
  80 fi], [default_strings_all=1])
  81
  82 AC_DEFINE_UNQUOTED(DEFAULT_STRINGS_ALL, $default_strings_all,
  83                    [Should strings use -a behavior by default?])
  84
  85
  86 AC_ARG_ENABLE(f-for-ifunc-symbols,
  87 [AS_HELP_STRING([--enable-f-for-ifunc-symbols],
  88         [Have nm use F and f for global and local ifunc symbols])], [
  89 if test "${enableval}" = no; then
  90   default_f_for_ifunc=0
  91 else
  92   default_f_for_ifunc=1
  93 fi], [default_f_for_ifunc=0])
  94
  95 AC_DEFINE_UNQUOTED(DEFAULT_F_FOR_IFUNC_SYMBOLS, $default_f_for_ifunc,
  96                    [Have nm use F and f for global and local ifunc symbols])
  97
  98
  99 AC_ARG_ENABLE(follow-debug-links,
 100 [AS_HELP_STRING([--enable-follow-debug-links],
 101         [Have readelf and objdump follow debug links by default])], [
 102 if test "${enableval}" = no; then
 103   default_for_follow_links=0
 104 else
 105   default_for_follow_links=1
 106 fi], [default_for_follow_links=1])
 107
 108 AC_DEFINE_UNQUOTED(DEFAULT_FOR_FOLLOW_LINKS, $default_for_follow_links,
 109                    [Have readelf and objdump follow debug links by default])
 110
 111
 112 AC_DEBUGINFOD
 113
 114 GCC_ENABLE([libctf], [yes], [], [Handle .ctf type-info sections])
 115 if test "${enable_libctf}" = yes; then
 116     AC_DEFINE(ENABLE_LIBCTF, 1, [Handle .ctf type-info sections])
 117 fi
 118 AM_CONDITIONAL(ENABLE_LIBCTF, test "${enable_libctf}" = yes)
 119
 120 AM_BINUTILS_WARNINGS
 121
 122 AC_CONFIG_HEADERS(config.h:config.in)
 123
 124 AH_VERBATIM([00_CONFIG_H_CHECK],
 125 [/* Check that config.h is #included before system headers
 126    (this works only for glibc, but that should be enough).  */
 127 #if defined(__GLIBC__) && !defined(__FreeBSD_kernel__) && !defined(__CONFIG_H__)
 128 #  error config.h must be #included before system headers
 129 #endif
 130 #define __CONFIG_H__ 1])
 131
 132 if test -z "$target" ; then
 133     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
 134 fi
 135 if test -z "$host" ; then
 136     AC_MSG_ERROR(Unrecognized host system type; please check config.sub.)
 137 fi
 138
 139 AC_PROG_YACC
 140 AM_PROG_LEX
 141
 142 ALL_LINGUAS="bg ca da es fi fr hr id it ja pt ro ru rw sk sr sv tr uk vi zh_CN zh_TW"
 143 ZW_GNU_GETTEXT_SISTER_DIR
 144 AM_PO_SUBDIRS
 145
 146 AM_MAINTAINER_MODE
 147 AM_CONDITIONAL(GENINSRC_NEVER, false)
 148 AC_EXEEXT
 149 if test -n "$EXEEXT"; then
 150   AC_DEFINE(HAVE_EXECUTABLE_SUFFIX, 1,
 151             [Does the platform use an executable suffix?])
 152 fi
 153 AC_DEFINE_UNQUOTED(EXECUTABLE_SUFFIX, "${EXEEXT}",
 154                    [Suffix used for executables, if any.])
 155
 156 # host-specific stuff:
 157
 158 HDEFINES=
 159
 160 . ${srcdir}/../bfd/configure.host
 161
 162 AC_SUBST(HDEFINES)
 163 AR=${AR-ar}
 164 AC_SUBST(AR)
 165 AC_PROG_RANLIB
 166 AC_PROG_INSTALL
 167
 168 BFD_CC_FOR_BUILD
 169
 170 DEMANGLER_NAME=c++filt
 171 case "${host}" in
 172   *-*-go32* | *-*-msdos*)
 173     DEMANGLER_NAME=cxxfilt
 174 esac
 175 AC_SUBST(DEMANGLER_NAME)
 176
 177 AC_CHECK_SIZEOF([long])
 178 AC_CHECK_SIZEOF([long long])
 179
 180 # We use headers from include/ that check various HAVE_*_H macros, thus
 181 # should ensure they are set by configure.  This is true even when C99
 182 # guarantees they are available.
 183 # plugin-api.h tests HAVE_STDINT_H and HAVE_INTTYPES_H
 184 # Besides those, we need to check anything used in binutils/ not in C99.
 185 AC_CHECK_HEADERS(fcntl.h inttypes.h stdint.h sys/file.h \
 186                  sys/stat.h sys/time.h sys/types.h unistd.h)
 187 AC_HEADER_SYS_WAIT
 188 AC_FUNC_MMAP
 189 AC_CHECK_FUNCS(getc_unlocked mkdtemp mkstemp utimensat utimes)
 190
 191 AC_MSG_CHECKING([for mbstate_t])
 192 AC_TRY_COMPILE([#include <wchar.h>],
 193 [mbstate_t teststate;],
 194 have_mbstate_t=yes, have_mbstate_t=no)
 195 AC_MSG_RESULT($have_mbstate_t)
 196 if test x"$have_mbstate_t" = xyes; then
 197   AC_DEFINE(HAVE_MBSTATE_T,1,[Define if mbstate_t exists in wchar.h.])
 198 fi
 199
 200 # Copied from gnulib stat-time.m4.
 201 # We should just switch over to using gnulib.
 202 AC_CHECK_MEMBERS([struct stat.st_atim.tv_nsec],
 203   [AC_CACHE_CHECK([whether struct stat.st_atim is of type struct timespec],
 204      [ac_cv_typeof_struct_stat_st_atim_is_struct_timespec],
 205      [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 206         [[
 207           #include <sys/types.h>
 208           #include <sys/stat.h>
 209           #if HAVE_SYS_TIME_H
 210           # include <sys/time.h>
 211           #endif
 212           #include <time.h>
 213           struct timespec ts;
 214           struct stat st;
 215         ]],
 216         [[
 217           st.st_atim = ts;
 218         ]])],
 219         [ac_cv_typeof_struct_stat_st_atim_is_struct_timespec=yes],
 220         [ac_cv_typeof_struct_stat_st_atim_is_struct_timespec=no])])
 221    if test $ac_cv_typeof_struct_stat_st_atim_is_struct_timespec = yes; then
 222      AC_DEFINE([TYPEOF_STRUCT_STAT_ST_ATIM_IS_STRUCT_TIMESPEC], [1],
 223        [Define to 1 if the type of the st_atim member of a struct stat is
 224         struct timespec.])
 225    fi],
 226   [AC_CHECK_MEMBERS([struct stat.st_atimespec.tv_nsec], [],
 227      [AC_CHECK_MEMBERS([struct stat.st_atimensec], [],
 228         [AC_CHECK_MEMBERS([struct stat.st_atim.st__tim.tv_nsec], [], [],
 229            [#include <sys/types.h>
 230             #include <sys/stat.h>])],
 231         [#include <sys/types.h>
 232          #include <sys/stat.h>])],
 233      [#include <sys/types.h>
 234       #include <sys/stat.h>])],
 235   [#include <sys/types.h>
 236    #include <sys/stat.h>])
 237
 238 # Some systems have frexp only in -lm, not in -lc.
 239 AC_SEARCH_LIBS(frexp, m)
 240
 241 AM_LC_MESSAGES
 242
 243 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
 244 AC_CACHE_VAL(bu_cv_decl_getopt_unistd_h,
 245 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);])],
 246 bu_cv_decl_getopt_unistd_h=yes, bu_cv_decl_getopt_unistd_h=no)])
 247 AC_MSG_RESULT($bu_cv_decl_getopt_unistd_h)
 248 if test $bu_cv_decl_getopt_unistd_h = yes; then
 249   AC_DEFINE([HAVE_DECL_GETOPT], 1,
 250             [Is the prototype for getopt in <unistd.h> in the expected format?])
 251 fi
 252
 253 # Under Next 3.2 <utime.h> apparently does not define struct utimbuf
 254 # by default.
 255 AC_MSG_CHECKING([for utime.h])
 256 AC_CACHE_VAL(bu_cv_header_utime_h,
 257 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
 258 #ifdef HAVE_TIME_H
 259 #include <time.h>
 260 #endif
 261 #include <utime.h>],
 262 [struct utimbuf s;])],
 263 bu_cv_header_utime_h=yes, bu_cv_header_utime_h=no)])
 264 AC_MSG_RESULT($bu_cv_header_utime_h)
 265 if test $bu_cv_header_utime_h = yes; then
 266   AC_DEFINE(HAVE_GOOD_UTIME_H, 1, [Does <utime.h> define struct utimbuf?])
 267 fi
 268
 269 AC_CHECK_DECLS([asprintf, environ, getc_unlocked, stpcpy, strnlen])
 270
 271 # Link in zlib if we can.  This allows us to read compressed debug
 272 # sections.  This is used only by readelf.c (objdump uses bfd for
 273 # reading compressed sections).
 274 AM_ZLIB
 275
 276 BFD_BINARY_FOPEN
 277
 278 # Support for the msgpack C library.
 279 AC_ARG_WITH([msgpack],
 280             AC_HELP_STRING([--with-msgpack], [Enable msgpack support (auto/yes/no)]),
 281             [],
 282             [with_msgpack=auto])
 283
 284
 285 if test "$with_msgpack" != no; then
 286   PKG_CHECK_MODULES(MSGPACK, msgpack, [
 287     AC_DEFINE([HAVE_MSGPACK], [1], [Define to 1 if msgpack is available.])
 288   ], [
 289       if test "$with_msgpack" = yes; then
 290         AC_MSG_ERROR([--with-msgpack was given, but msgpack is missing or unusable.])
 291       fi
 292   ])
 293 fi
 294
 295 # target-specific stuff:
 296
 297 # Canonicalize the secondary target names.
 298 if test -n "$enable_targets"; then
 299     for targ in `echo $enable_targets | sed 's/,/ /g'`
 300     do
 301         result=`$ac_config_sub $targ 2>/dev/null`
 302         if test -n "$result"; then
 303             canon_targets="$canon_targets $result"
 304         else
 305             # Allow targets that config.sub doesn't recognize, like "all".
 306             canon_targets="$canon_targets $targ"
 307         fi
 308     done
 309 fi
 310
 311 AC_CHECK_HEADER(iconv.h)
 312 AM_ICONV
 313
 314 all_targets=false
 315 BUILD_SRCONV=
 316 BUILD_DLLTOOL=
 317 DLLTOOL_DEFS=
 318 DLLTOOL_DEFAULT=
 319 BUILD_WINDRES=
 320 BUILD_WINDMC=
 321 BUILD_DLLWRAP=
 322 BUILD_MISC=
 323 BUILD_INSTALL_MISC=
 324 OBJDUMP_DEFS=
 325 OBJDUMP_PRIVATE_VECTORS=
 326 OBJDUMP_PRIVATE_OFILES=
 327 od_vectors=
 328
 329 for targ in $target $canon_targets
 330 do
 331     if test "x$targ" = "xall"; then
 332         all_targets=true
 333         BUILD_SRCONV='$(SRCONV_PROG)'
 334         BUILD_MISC="${BUILD_MISC} "'bin2c$(EXEEXT_FOR_BUILD)'
 335         BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 336         BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 337         BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 338         if test -z "$DLLTOOL_DEFAULT"; then
 339           DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_I386"
 340         fi
 341         DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_I386"
 342         BUILD_DLLWRAP='$(DLLWRAP_PROG)$(EXEEXT)'
 343         od_vectors="$od_vectors objdump_private_desc_xcoff"
 344     else
 345         case $targ in
 346         *-*-hms*) BUILD_SRCONV='$(SRCONV_PROG)' ;;
 347         esac
 348
 349         case $targ in
 350         arm-wince-pe* | arm-*-wince | arm*-*-cegcc* | arm*-*-mingw32ce*)
 351           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 352           if test -z "$DLLTOOL_DEFAULT"; then
 353             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_ARM_WINCE"
 354           fi
 355           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_ARM_WINCE -DDLLTOOL_ARM"
 356           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 357           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 358           ;;
 359         arm-*-pe*)
 360           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 361           if test -z "$DLLTOOL_DEFAULT"; then
 362             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_ARM"
 363           fi
 364           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_ARM"
 365           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 366           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 367           ;;
 368         x86_64-*-mingw* | x86_64-*-cygwin*)
 369           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 370           if test -z "$DLLTOOL_DEFAULT"; then
 371             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_MX86_64"
 372           fi
 373           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_MX86_64"
 374           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 375           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 376           BUILD_DLLWRAP='$(DLLWRAP_PROG)$(EXEEXT)'
 377           ;;
 378 changequote(,)dnl
 379         i[3-7]86-*-pe* | i[3-7]86-*-cygwin* | i[3-7]86-*-mingw32**)
 380 changequote([,])dnl
 381           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 382           if test -z "$DLLTOOL_DEFAULT"; then
 383             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_I386"
 384           fi
 385           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_I386"
 386           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 387           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 388           BUILD_DLLWRAP='$(DLLWRAP_PROG)$(EXEEXT)'
 389           ;;
 390 changequote(,)dnl
 391         i[3-7]86-*-interix)
 392 changequote([,])dnl
 393           BUILD_DLLTOOL='$(DLLTOOL_PROG)'
 394           if test -z "$DLLTOOL_DEFAULT"; then
 395             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_I386"
 396           fi
 397           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_I386"
 398           ;;
 399 changequote(,)dnl
 400         powerpc*-aix5.[01])
 401 changequote([,])dnl
 402           ;;
 403 changequote(,)dnl
 404         powerpc*-aix[5-9].*)
 405 changequote([,])dnl
 406           OBJDUMP_DEFS="-DAIX_WEAK_SUPPORT"
 407           ;;
 408         powerpc*-*-linux* | powerpc*-*-elf* | powerpc*-*-eabi*)
 409           case "$BUILD_INSTALL_MISC" in
 410             *embedspu*) ;;
 411             *) BUILD_INSTALL_MISC="${BUILD_INSTALL_MISC} embedspu"
 412           esac
 413           ;;
 414         sh*-*-pe)
 415           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 416           if test -z "$DLLTOOL_DEFAULT"; then
 417             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_SH"
 418           fi
 419           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_SH"
 420           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 421           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 422           ;;
 423         spu-*-*)
 424           BUILD_MISC="${BUILD_MISC} "'bin2c$(EXEEXT_FOR_BUILD)'
 425           ;;
 426         mips*-*-pe)
 427           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 428           if test -z "$DLLTOOL_DEFAULT"; then
 429             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_MIPS"
 430           fi
 431           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_MIPS"
 432           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 433           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 434           ;;
 435         mcore-*-pe)
 436           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 437           if test -z "$DLLTOOL_DEFAULT"; then
 438             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_MCORE"
 439           fi
 440           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_MCORE"
 441           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 442           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 443           ;;
 444         mcore-*-elf)
 445           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 446           if test -z "$DLLTOOL_DEFAULT"; then
 447             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_MCORE_ELF"
 448           fi
 449           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_MCORE_ELF"
 450           ;;
 451         mep-*)
 452           OBJDUMP_DEFS="-DSKIP_ZEROES=256 -DSKIP_ZEROES_AT_END=0"
 453           ;;
 454         esac
 455
 456         # Add objdump private vectors.
 457         case $targ in
 458         avr-*-*)
 459           od_vectors="$od_vectors objdump_private_desc_elf32_avr"
 460           ;;
 461         powerpc*-*-aix* | rs6000-*-aix*)
 462           od_vectors="$od_vectors objdump_private_desc_xcoff"
 463           ;;
 464         *-*-darwin*)
 465           od_vectors="$od_vectors objdump_private_desc_mach_o"
 466           ;;
 467         esac
 468     fi
 469 done
 470
 471 # Uniq objdump private vector, build objdump target ofiles.
 472 od_files=
 473 f=""
 474 for i in $od_vectors ; do
 475     case " $f " in
 476     *" $i "*) ;;
 477     *)
 478         f="$f $i"
 479         OBJDUMP_PRIVATE_VECTORS="$OBJDUMP_PRIVATE_VECTORS &$i,"
 480         case $i in
 481         objdump_private_desc_elf32_avr)
 482             od_files="$od_files od-elf32_avr" ;;
 483         objdump_private_desc_xcoff)
 484             od_files="$od_files od-xcoff" ;;
 485         objdump_private_desc_mach_o)
 486             od_files="$od_files od-macho" ;;
 487         *) AC_MSG_ERROR(*** unknown private vector $i) ;;
 488         esac
 489         ;;
 490     esac
 491 done
 492
 493 # Uniq objdump target ofiles
 494 f=""
 495 for i in $od_files ; do
 496     case " $f " in
 497     *" $i "*) ;;
 498     *)
 499         f="$f $i"
 500         OBJDUMP_PRIVATE_OFILES="$OBJDUMP_PRIVATE_OFILES $i.$objext"
 501         ;;
 502     esac
 503 done
 504
 505 DLLTOOL_DEFS="$DLLTOOL_DEFS $DLLTOOL_DEFAULT"
 506
 507 if test "${with_windres+set}" = set; then
 508           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 509 fi
 510
 511 if test "${with_windmc+set}" = set; then
 512           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 513 fi
 514
 515 OBJDUMP_DEFS="${OBJDUMP_DEFS} -DOBJDUMP_PRIVATE_VECTORS=\"${OBJDUMP_PRIVATE_VECTORS}\""
 516
 517 AC_SUBST(BUILD_SRCONV)
 518 AC_SUBST(BUILD_DLLTOOL)
 519 AC_SUBST(DLLTOOL_DEFS)
 520 AC_SUBST(BUILD_WINDRES)
 521 AC_SUBST(BUILD_WINDMC)
 522 AC_SUBST(BUILD_DLLWRAP)
 523 AC_SUBST(BUILD_MISC)
 524 AC_SUBST(BUILD_INSTALL_MISC)
 525 AC_SUBST(OBJDUMP_DEFS)
 526 AC_SUBST(OBJDUMP_PRIVATE_OFILES)
 527
 528 AC_DEFINE_UNQUOTED(TARGET, "${target}", [Configured target name.])
 529
 530 targ=$target
 531 . $srcdir/../bfd/config.bfd
 532 if test "x$targ_underscore" = "xyes"; then
 533     UNDERSCORE=1
 534 else
 535     UNDERSCORE=0
 536 fi
 537 AC_DEFINE_UNQUOTED(TARGET_PREPENDS_UNDERSCORE, $UNDERSCORE,
 538  [Define to 1 if user symbol names have a leading underscore, 0 if not.])
 539
 540 # Emulation
 541 targ=$target
 542 . ${srcdir}/configure.tgt
 543 EMULATION=$targ_emul
 544 EMULATION_VECTOR=$targ_emul_vector
 545
 546 AC_SUBST(EMULATION)
 547 AC_SUBST(EMULATION_VECTOR)
 548
 549 # Required for html and install-html
 550 AC_SUBST(datarootdir)
 551 AC_SUBST(docdir)
 552 AC_SUBST(htmldir)
 553 AC_SUBST(pdfdir)
 554
 555 AC_CONFIG_FILES(Makefile po/Makefile.in:po/Make-in)
 556 AC_OUTPUT
 557
 558 GNU_MAKE_JOBSERVER