configure.ac

   1 #   Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000,
   2 #   2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011, 2012,
   3 #   2014, 2015, 2016, 2019, 2020 Free Software Foundation, Inc.
   4 #
   5 # This file is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; see the file COPYING3.  If not see
  17 # <http://www.gnu.org/licenses/>.
  18
  19 ##############################################################################
  20 ### WARNING: this file contains embedded tabs.  Do not run untabify on this file.
  21
  22 m4_include(config/acx.m4)
  23 m4_include(config/override.m4)
  24 m4_include(config/proginstall.m4)
  25 m4_include(config/elf.m4)
  26 m4_include(config/gcc-plugin.m4)
  27 m4_include([libtool.m4])
  28 m4_include([ltoptions.m4])
  29 m4_include([ltsugar.m4])
  30 m4_include([ltversion.m4])
  31 m4_include([lt~obsolete.m4])
  32 m4_include([config/isl.m4])
  33
  34 AC_INIT(move-if-change)
  35 AC_DISABLE_OPTION_CHECKING
  36
  37 progname=$0
  38 # if PWD already has a value, it is probably wrong.
  39 if test -n "$PWD" ; then PWD=`${PWDCMD-pwd}`; fi
  40
  41 # Export original configure arguments for use by sub-configures.
  42 # Quote arguments with shell meta charatcers.
  43 TOPLEVEL_CONFIGURE_ARGUMENTS=
  44 set -- "$progname" "$@"
  45 for ac_arg
  46 do
  47   case "$ac_arg" in
  48   *" "*|*"      "*|*[[\[\]\~\#\$\^\&\*\(\)\{\}\\\|\;\<\>\?\']]*)
  49     ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"`
  50     # if the argument is of the form -foo=baz, quote the baz part only
  51     ac_arg=`echo "'$ac_arg'" | sed "s/^'\([[-a-zA-Z0-9]]*=\)/\\1'/"` ;;
  52   *) ;;
  53   esac
  54   # Add the quoted argument to the list.
  55   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS $ac_arg"
  56 done
  57 if test "$silent" = yes; then
  58   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS --silent"
  59 fi
  60 # Remove the initial space we just introduced and, as these will be
  61 # expanded by make, quote '$'.
  62 TOPLEVEL_CONFIGURE_ARGUMENTS=`echo "x$TOPLEVEL_CONFIGURE_ARGUMENTS" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
  63 AC_SUBST(TOPLEVEL_CONFIGURE_ARGUMENTS)
  64
  65 # Find the build, host, and target systems.
  66 ACX_NONCANONICAL_BUILD
  67 ACX_NONCANONICAL_HOST
  68 ACX_NONCANONICAL_TARGET
  69
  70 dnl Autoconf 2.5x and later will set a default program prefix if
  71 dnl --target was used, even if it was the same as --host.  Disable
  72 dnl that behavior.  This must be done before AC_CANONICAL_SYSTEM
  73 dnl to take effect.
  74 test "$host_noncanonical" = "$target_noncanonical" &&
  75   test "$program_prefix$program_suffix$program_transform_name" = \
  76     NONENONEs,x,x, &&
  77   program_transform_name=s,y,y,
  78
  79 AC_CANONICAL_SYSTEM
  80 AC_ARG_PROGRAM
  81
  82 m4_pattern_allow([^AS_FOR_TARGET$])dnl
  83 m4_pattern_allow([^AS_FOR_BUILD$])dnl
  84
  85 # Get 'install' or 'install-sh' and its variants.
  86 AC_PROG_INSTALL
  87 ACX_PROG_LN
  88 AC_PROG_LN_S
  89 AC_PROG_SED
  90 AC_PROG_AWK
  91
  92 srcpwd=`cd ${srcdir} ; ${PWDCMD-pwd}`
  93
  94 # We pass INSTALL explicitly to sub-makes.  Make sure that it is not
  95 # a relative path.
  96 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
  97   INSTALL="${srcpwd}/install-sh -c"
  98 fi
  99
 100 # Set srcdir to "." if that's what it is.
 101 # This is important for multilib support.
 102 pwd=`${PWDCMD-pwd}`
 103 if test "${pwd}" = "${srcpwd}" ; then
 104   srcdir=.
 105 fi
 106
 107 topsrcdir=$srcpwd
 108
 109 extra_host_args=
 110
 111 ### To add a new directory to the tree, first choose whether it is a target
 112 ### or a host dependent tool.  Then put it into the appropriate list
 113 ### (library or tools, host or target), doing a dependency sort.
 114
 115 # Subdirs will be configured in the order listed in build_configdirs,
 116 # configdirs, or target_configdirs; see the serialization section below.
 117
 118 # Dependency sorting is only needed when *configuration* must be done in
 119 # a particular order.  In all cases a dependency should be specified in
 120 # the Makefile, whether or not it's implicitly specified here.
 121
 122 # Double entries in build_configdirs, configdirs, or target_configdirs may
 123 # cause circular dependencies and break everything horribly.
 124
 125 # these library is used by various programs built for the build
 126 # environment
 127 #
 128 build_libs="build-libiberty build-libcpp"
 129
 130 # these tools are built for the build environment
 131 build_tools="build-texinfo build-flex build-bison build-m4 build-fixincludes"
 132
 133 # these libraries are used by various programs built for the host environment
 134 #f
 135 host_libs="intl libiberty opcodes bfd readline tcl tk itcl libgui zlib libbacktrace libcpp libdecnumber gmp mpfr mpc isl libelf libiconv libctf"
 136
 137 # these tools are built for the host environment
 138 # Note, the powerpc-eabi build depends on sim occurring before gdb in order to
 139 # know that we are building the simulator.
 140 # binutils, gas and ld appear in that order because it makes sense to run
 141 # "make check" in that particular order.
 142 # If --enable-gold is used, "gold" may replace "ld".
 143 host_tools="texinfo flex bison binutils gas ld fixincludes gcc cgen sid sim gdb gdbserver gprof etc expect dejagnu m4 utils guile fastjar gnattools libcc1 gotools"
 144
 145 # these libraries are built for the target environment, and are built after
 146 # the host libraries and the host tools (which may be a cross compiler)
 147 # Note that libiberty is not a target library.
 148 target_libraries="target-libgcc \
 149                 target-libbacktrace \
 150                 target-libgloss \
 151                 target-newlib \
 152                 target-libgomp \
 153                 target-liboffloadmic \
 154                 target-libhsail-rt \
 155                 target-libatomic \
 156                 target-libitm \
 157                 target-libstdc++-v3 \
 158                 target-libsanitizer \
 159                 target-libvtv \
 160                 target-libssp \
 161                 target-libquadmath \
 162                 target-libgfortran \
 163                 target-libffi \
 164                 target-libobjc \
 165                 target-libada \
 166                 target-libgo"
 167
 168 # these tools are built using the target libraries, and are intended to
 169 # run only in the target environment
 170 #
 171 # note: any program that *uses* libraries that are in the "target_libraries"
 172 # list belongs in this list.
 173 #
 174 target_tools="target-rda"
 175
 176 ################################################################################
 177
 178 ## All tools belong in one of the four categories, and are assigned above
 179 ## We assign ${configdirs} this way to remove all embedded newlines.  This
 180 ## is important because configure will choke if they ever get through.
 181 ## ${configdirs} is directories we build using the host tools.
 182 ## ${target_configdirs} is directories we build using the target tools.
 183 configdirs=`echo ${host_libs} ${host_tools}`
 184 target_configdirs=`echo ${target_libraries} ${target_tools}`
 185 build_configdirs=`echo ${build_libs} ${build_tools}`
 186
 187 m4_divert_text([PARSE_ARGS],
 188 [case $srcdir in
 189   *" "*)
 190 m4_pushdef([AS_MESSAGE_LOG_FD], [])dnl
 191     AC_MSG_ERROR([path to source, $srcdir, contains spaces])
 192 m4_popdef([AS_MESSAGE_LOG_FD])dnl
 193     ;;
 194 esac
 195 ac_subdirs_all=`cd $srcdir && echo */configure | sed 's,/configure,,g'`
 196 ])
 197
 198 ################################################################################
 199
 200 srcname="gnu development package"
 201
 202 # This gets set non-empty for some net releases of packages.
 203 appdirs=""
 204
 205 # Define is_cross_compiler to save on calls to 'test'.
 206 is_cross_compiler=
 207 if test x"${host}" = x"${target}" ; then
 208   is_cross_compiler=no
 209 else
 210   is_cross_compiler=yes
 211 fi
 212
 213 # Find the build and target subdir names.
 214 GCC_TOPLEV_SUBDIRS
 215 # Be sure to cover against remnants of an in-tree build.
 216 if test $srcdir != .  && test -d $srcdir/host-${host_noncanonical}; then
 217   AC_MSG_ERROR([building out of tree but $srcdir contains host-${host_noncanonical}.
 218 Use a pristine source tree when building in a separate tree])
 219 fi
 220
 221 # Skipdirs are removed silently.
 222 skipdirs=
 223 # Noconfigdirs are removed loudly.
 224 noconfigdirs=""
 225
 226 use_gnu_ld=
 227 # Make sure we don't let GNU ld be added if we didn't want it.
 228 if test x$with_gnu_ld = xno ; then
 229   use_gnu_ld=no
 230   noconfigdirs="$noconfigdirs ld gold"
 231 fi
 232
 233 use_gnu_as=
 234 # Make sure we don't let GNU as be added if we didn't want it.
 235 if test x$with_gnu_as = xno ; then
 236   use_gnu_as=no
 237   noconfigdirs="$noconfigdirs gas"
 238 fi
 239
 240 use_included_zlib=
 241 AC_ARG_WITH(system-zlib,
 242 [AS_HELP_STRING([--with-system-zlib], [use installed libz])])
 243 # Make sure we don't let ZLIB be added if we didn't want it.
 244 if test x$with_system_zlib = xyes ; then
 245   use_included_zlib=no
 246   noconfigdirs="$noconfigdirs zlib"
 247 fi
 248
 249 # Don't compile the bundled readline/libreadline.a if --with-system-readline
 250 # is provided.
 251 if test x$with_system_readline = xyes ; then
 252   noconfigdirs="$noconfigdirs readline"
 253 fi
 254
 255 # some tools are so dependent upon X11 that if we're not building with X,
 256 # it's not even worth trying to configure, much less build, that tool.
 257
 258 case ${with_x} in
 259   yes | "") ;; # the default value for this tree is that X11 is available
 260   no)
 261     skipdirs="${skipdirs} tk itcl libgui"
 262     # We won't be able to build gdbtk without X.
 263     enable_gdbtk=no
 264     ;;
 265   *)  echo "*** bad value \"${with_x}\" for -with-x flag; ignored" 1>&2 ;;
 266 esac
 267
 268 # Some are only suitable for cross toolchains.
 269 # Remove these if host=target.
 270 cross_only="target-libgloss target-newlib target-opcodes"
 271
 272 case $is_cross_compiler in
 273   no) skipdirs="${skipdirs} ${cross_only}" ;;
 274 esac
 275
 276 # If both --with-headers and --with-libs are specified, default to
 277 # --without-newlib.
 278 if test x"${with_headers}" != x && test x"${with_headers}" != xno \
 279    && test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
 280   if test x"${with_newlib}" = x ; then
 281     with_newlib=no
 282   fi
 283 fi
 284
 285 # Recognize --with-newlib/--without-newlib.
 286 case ${with_newlib} in
 287   no) skipdirs="${skipdirs} target-newlib" ;;
 288   yes) skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'` ;;
 289 esac
 290
 291 AC_ARG_ENABLE(as-accelerator-for,
 292 [AS_HELP_STRING([--enable-as-accelerator-for=ARG],
 293                 [build as offload target compiler.
 294                 Specify offload host triple by ARG])])
 295
 296 AC_ARG_ENABLE(offload-targets,
 297 [AS_HELP_STRING([--enable-offload-targets=LIST],
 298                 [enable offloading to devices from comma-separated LIST of
 299                 TARGET[=DIR]. Use optional path to find offload target compiler
 300                 during the build])],
 301 [
 302   if test x"$enable_offload_targets" = x; then
 303     AC_MSG_ERROR([no offload targets specified])
 304   fi
 305 ], [enable_offload_targets=])
 306
 307 # Handle --enable-gold, --enable-ld.
 308 # --disable-gold [--enable-ld]
 309 #     Build only ld.  Default option.
 310 # --enable-gold [--enable-ld]
 311 #     Build both gold and ld.  Install gold as "ld.gold", install ld
 312 #     as "ld.bfd" and "ld".
 313 # --enable-gold=default [--enable-ld]
 314 #     Build both gold and ld.  Install gold as "ld.gold" and "ld",
 315 #     install ld as "ld.bfd".
 316 # --enable-gold[=default] --disable-ld
 317 #     Build only gold, which is then installed as both "ld.gold" and "ld".
 318 # --enable-gold --enable-ld=default
 319 #     Build both gold (installed as "ld.gold") and ld (installed as "ld"
 320 #     and ld.bfd).
 321 #     In other words, ld is default
 322 # --enable-gold=default --enable-ld=default
 323 #     Error.
 324
 325 default_ld=
 326 AC_ARG_ENABLE(gold,
 327 [AS_HELP_STRING([[--enable-gold[=ARG]]],
 328                 [build gold @<:@ARG={default,yes,no}@:>@])],
 329 ENABLE_GOLD=$enableval,
 330 ENABLE_GOLD=no)
 331 case "${ENABLE_GOLD}" in
 332   yes|default)
 333     # Check for ELF target.
 334     is_elf=no
 335     case "${target}" in
 336       *-*-elf* | *-*-sysv4* | *-*-unixware* | *-*-eabi* | hppa*64*-*-hpux* \
 337       | *-*-linux* | *-*-gnu* | frv-*-uclinux* | *-*-irix5* | *-*-irix6* \
 338       | *-*-netbsd* | *-*-openbsd* | *-*-freebsd* | *-*-dragonfly* \
 339       | *-*-solaris2* | *-*-nto* | *-*-nacl*)
 340         case "${target}" in
 341           *-*-linux*aout* | *-*-linux*oldld*)
 342             ;;
 343           *)
 344             is_elf=yes
 345             ;;
 346         esac
 347     esac
 348
 349     if test "$is_elf" = "yes"; then
 350       # Check for target supported by gold.
 351       case "${target}" in
 352         i?86-*-* | x86_64-*-* | sparc*-*-* | powerpc*-*-* | arm*-*-* \
 353         | aarch64*-*-* | tilegx*-*-* | mips*-*-* | s390*-*-*)
 354           configdirs="$configdirs gold"
 355           if test x${ENABLE_GOLD} = xdefault; then
 356             default_ld=gold
 357           fi
 358           ENABLE_GOLD=yes
 359           ;;
 360       esac
 361     fi
 362     ;;
 363   no)
 364     ;;
 365   *)
 366     AC_MSG_ERROR([invalid --enable-gold argument])
 367     ;;
 368 esac
 369
 370 AC_ARG_ENABLE(ld,
 371 [AS_HELP_STRING([[--enable-ld[=ARG]]],
 372                 [build ld @<:@ARG={default,yes,no}@:>@])],
 373 ENABLE_LD=$enableval,
 374 ENABLE_LD=yes)
 375
 376 case "${ENABLE_LD}" in
 377   default)
 378     if test x${default_ld} != x; then
 379       AC_MSG_ERROR([either gold or ld can be the default ld])
 380     fi
 381     ;;
 382   yes)
 383     ;;
 384   no)
 385     if test x${ENABLE_GOLD} != xyes; then
 386       AC_MSG_WARN([neither ld nor gold are enabled])
 387     fi
 388     configdirs=`echo " ${configdirs} " | sed -e 's/ ld / /'`
 389     ;;
 390   *)
 391     AC_MSG_ERROR([invalid --enable-ld argument])
 392     ;;
 393 esac
 394
 395 # PR gas/19109
 396 # Decide the default method for compressing debug sections.
 397 # Provide a configure time option to override our default.
 398 AC_ARG_ENABLE(compressed_debug_sections,
 399 [AS_HELP_STRING([--enable-compressed-debug-sections={all,gas,gold,ld,none}],
 400                 [Enable compressed debug sections for gas, gold or ld by
 401                  default])],
 402 [
 403   if test x"$enable_compressed_debug_sections" = xyes; then
 404     AC_MSG_ERROR([no program with compressed debug sections specified])
 405   fi
 406 ], [enable_compressed_debug_sections=])
 407
 408 # Configure extra directories which are host specific
 409
 410 case "${host}" in
 411   *-cygwin*)
 412     configdirs="$configdirs libtermcap" ;;
 413 esac
 414
 415 # A target can indicate whether a language isn't supported for some reason.
 416 # Only spaces may be used in this macro; not newlines or tabs.
 417 unsupported_languages=
 418
 419 # Remove more programs from consideration, based on the host or
 420 # target this usually means that a port of the program doesn't
 421 # exist yet.
 422
 423 case "${host}" in
 424   i[[3456789]]86-*-msdosdjgpp*)
 425     noconfigdirs="$noconfigdirs tcl tk itcl"
 426     ;;
 427 esac
 428
 429
 430 AC_ARG_ENABLE(libquadmath,
 431 AS_HELP_STRING([--disable-libquadmath],
 432   [do not build libquadmath directory]),
 433 ENABLE_LIBQUADMATH=$enableval,
 434 ENABLE_LIBQUADMATH=yes)
 435 if test "${ENABLE_LIBQUADMATH}" = "no" ; then
 436   noconfigdirs="$noconfigdirs target-libquadmath"
 437 fi
 438
 439
 440 AC_ARG_ENABLE(libquadmath-support,
 441 AS_HELP_STRING([--disable-libquadmath-support],
 442   [disable libquadmath support for Fortran]),
 443 ENABLE_LIBQUADMATH_SUPPORT=$enableval,
 444 ENABLE_LIBQUADMATH_SUPPORT=yes)
 445 enable_libquadmath_support=
 446 if test "${ENABLE_LIBQUADMATH_SUPPORT}" = "no" ; then
 447   enable_libquadmath_support=no
 448 fi
 449
 450
 451 AC_ARG_ENABLE(libada,
 452 [AS_HELP_STRING([--enable-libada], [build libada directory])],
 453 ENABLE_LIBADA=$enableval,
 454 ENABLE_LIBADA=yes)
 455 if test "${ENABLE_LIBADA}" != "yes" ; then
 456   noconfigdirs="$noconfigdirs gnattools"
 457 fi
 458
 459 AC_ARG_ENABLE(libssp,
 460 [AS_HELP_STRING([--enable-libssp], [build libssp directory])],
 461 ENABLE_LIBSSP=$enableval,
 462 ENABLE_LIBSSP=yes)
 463
 464 AC_ARG_ENABLE(libstdcxx,
 465 AS_HELP_STRING([--disable-libstdcxx],
 466   [do not build libstdc++-v3 directory]),
 467 ENABLE_LIBSTDCXX=$enableval,
 468 ENABLE_LIBSTDCXX=default)
 469 [if test "${ENABLE_LIBSTDCXX}" = "no" ; then
 470   noconfigdirs="$noconfigdirs target-libstdc++-v3"
 471 fi]
 472
 473 # If this is accelerator compiler and its target is intelmic we enable
 474 # target liboffloadmic by default.  If this is compiler with offloading
 475 # for intelmic we enable host liboffloadmic by default.  Otherwise
 476 # liboffloadmic is disabled by default.
 477 AC_ARG_ENABLE([liboffloadmic],
 478 AC_HELP_STRING([[--enable-liboffloadmic[=ARG]]],
 479                [build liboffloadmic @<:@ARG={no,host,target}@:>@]),
 480 [case "$enableval" in
 481   no | host | target)
 482     enable_liboffloadmic=$enableval ;;
 483   *)
 484     AC_MSG_ERROR([--enable-liboffloadmic=no/host/target]) ;;
 485 esac],
 486 [if test x"$enable_as_accelerator_for" != x; then
 487   case "${target}" in
 488     *-intelmic-* | *-intelmicemul-*)
 489       enable_liboffloadmic=target
 490       extra_liboffloadmic_configure_flags="--enable-liboffloadmic=target"
 491       ;;
 492     *)
 493       enable_liboffloadmic=no
 494       ;;
 495   esac
 496 else
 497   case "${enable_offload_targets}" in
 498     *-intelmic-* | *-intelmicemul-*)
 499       enable_liboffloadmic=host
 500       extra_liboffloadmic_configure_flags="--enable-liboffloadmic=host"
 501       ;;
 502     *)
 503       enable_liboffloadmic=no
 504       ;;
 505     esac
 506 fi])
 507 AC_SUBST(extra_liboffloadmic_configure_flags)
 508
 509 # Enable libgomp by default on hosted POSIX systems, and a few others.
 510 if test x$enable_libgomp = x ; then
 511     case "${target}" in
 512     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 513         ;;
 514     *-*-netbsd* | *-*-freebsd* | *-*-openbsd* | *-*-dragonfly*)
 515         ;;
 516     *-*-solaris2* | *-*-hpux11*)
 517         ;;
 518     *-*-darwin* | *-*-aix*)
 519         ;;
 520     nvptx*-*-*)
 521         ;;
 522     *)
 523         noconfigdirs="$noconfigdirs target-libgomp"
 524         ;;
 525     esac
 526 fi
 527
 528 # Disable libatomic on unsupported systems.
 529 if test -d ${srcdir}/libatomic; then
 530     if test x$enable_libatomic = x; then
 531         AC_MSG_CHECKING([for libatomic support])
 532         if (srcdir=${srcdir}/libatomic; \
 533                 . ${srcdir}/configure.tgt; \
 534                 test -n "$UNSUPPORTED")
 535         then
 536             AC_MSG_RESULT([no])
 537             noconfigdirs="$noconfigdirs target-libatomic"
 538         else
 539             AC_MSG_RESULT([yes])
 540         fi
 541     fi
 542 fi
 543
 544 # Disable liboffloadmic on unsupported systems.
 545 if test -d ${srcdir}/liboffloadmic; then
 546     if test x$enable_liboffloadmic != xno; then
 547         AC_MSG_CHECKING([for liboffloadmic support])
 548         if (srcdir=${srcdir}/liboffloadmic; \
 549                 . ${srcdir}/configure.tgt; \
 550                 test -n "$UNSUPPORTED")
 551         then
 552             AC_MSG_RESULT([no])
 553             noconfigdirs="$noconfigdirs target-liboffloadmic"
 554         else
 555             AC_MSG_RESULT([yes])
 556         fi
 557     fi
 558 fi
 559
 560 # Disable libitm on unsupported systems.
 561 if test -d ${srcdir}/libitm; then
 562     if test x$enable_libitm = x; then
 563         AC_MSG_CHECKING([for libitm support])
 564         if (srcdir=${srcdir}/libitm; \
 565                 . ${srcdir}/configure.tgt; \
 566                 test -n "$UNSUPPORTED")
 567         then
 568             AC_MSG_RESULT([no])
 569             noconfigdirs="$noconfigdirs target-libitm"
 570         else
 571             AC_MSG_RESULT([yes])
 572         fi
 573     fi
 574 fi
 575
 576 # Disable libsanitizer on unsupported systems.
 577 if test -d ${srcdir}/libsanitizer; then
 578     if test x$enable_libsanitizer = x; then
 579         AC_MSG_CHECKING([for libsanitizer support])
 580         if (srcdir=${srcdir}/libsanitizer; \
 581                 . ${srcdir}/configure.tgt; \
 582                 test -n "$UNSUPPORTED")
 583         then
 584             AC_MSG_RESULT([no])
 585             noconfigdirs="$noconfigdirs target-libsanitizer"
 586         else
 587             AC_MSG_RESULT([yes])
 588         fi
 589     fi
 590 fi
 591
 592 # Disable libvtv on unsupported systems.
 593 if test -d ${srcdir}/libvtv; then
 594     if test x$enable_libvtv = x; then
 595         AC_MSG_CHECKING([for libvtv support])
 596         if (srcdir=${srcdir}/libvtv; \
 597                 . ${srcdir}/configure.tgt; \
 598                 test "$VTV_SUPPORTED" != "yes")
 599         then
 600             AC_MSG_RESULT([no])
 601             noconfigdirs="$noconfigdirs target-libvtv"
 602         else
 603             AC_MSG_RESULT([yes])
 604         fi
 605     fi
 606 fi
 607
 608
 609 # Disable libhsail-rt on unsupported systems.
 610 if test -d ${srcdir}/libhsail-rt; then
 611     if test x$enable_libhsail_rt = x; then
 612         AC_MSG_CHECKING([for libhsail-rt support])
 613         if (srcdir=${srcdir}/libhsail-rt; \
 614                 . ${srcdir}/configure.tgt; \
 615                 test -n "$UNSUPPORTED")
 616         then
 617             AC_MSG_RESULT([no])
 618             unsupported_languages="$unsupported_languages brig"
 619             # This implicitly disables also target-libhsail-rt as it won't
 620             # get added to the build without BRIG FE.
 621         else
 622             AC_MSG_RESULT([yes])
 623         fi
 624     fi
 625 fi
 626
 627
 628 # Disable libquadmath for some systems.
 629 case "${target}" in
 630   avr-*-*)
 631     noconfigdirs="$noconfigdirs target-libquadmath"
 632     ;;
 633   # libquadmath is unused on AIX and libquadmath build process use of
 634   # LD_LIBRARY_PATH can break AIX bootstrap.
 635   powerpc-*-aix* | rs6000-*-aix*)
 636     noconfigdirs="$noconfigdirs target-libquadmath"
 637     ;;
 638 esac
 639
 640 # Disable libssp for some systems.
 641 case "${target}" in
 642   avr-*-*)
 643     # No hosted I/O support.
 644     noconfigdirs="$noconfigdirs target-libssp"
 645     ;;
 646   powerpc-*-aix* | rs6000-*-aix*)
 647     noconfigdirs="$noconfigdirs target-libssp"
 648     ;;
 649   rl78-*-*)
 650     # libssp uses a misaligned load to trigger a fault, but the RL78
 651     # doesn't fault for those - instead, it gives a build-time error
 652     # for explicit misaligned loads.
 653     noconfigdirs="$noconfigdirs target-libssp"
 654     ;;
 655   visium-*-*)
 656     # No hosted I/O support.
 657     noconfigdirs="$noconfigdirs target-libssp"
 658     ;;
 659 esac
 660
 661 # Disable libstdc++-v3 for some systems.
 662 # Allow user to override this if they pass --enable-libstdc++-v3
 663 if test "${ENABLE_LIBSTDCXX}" = "default" ; then
 664   case "${target}" in
 665     *-*-vxworks*)
 666       # VxWorks uses the Dinkumware C++ library.
 667       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 668       ;;
 669     arm*-wince-pe*)
 670       # the C++ libraries don't build on top of CE's C libraries
 671       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 672       ;;
 673     avr-*-*)
 674       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 675       ;;
 676     ft32-*-*)
 677       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 678       ;;
 679   esac
 680 fi
 681
 682 # Disable Fortran for some systems.
 683 case "${target}" in
 684   mmix-*-*)
 685     # See <http://gcc.gnu.org/ml/gcc-patches/2004-11/msg00572.html>.
 686     unsupported_languages="$unsupported_languages fortran"
 687     ;;
 688 esac
 689
 690 # Disable libffi for some systems.
 691 case "${target}" in
 692   powerpc-*-darwin*)
 693     ;;
 694   i[[3456789]]86-*-darwin*)
 695     ;;
 696   x86_64-*-darwin[[912]]*)
 697     ;;
 698   *-*-darwin*)
 699     noconfigdirs="$noconfigdirs target-libffi"
 700     ;;
 701   *-*-netware*)
 702     noconfigdirs="$noconfigdirs target-libffi"
 703     ;;
 704   *-*-phoenix*)
 705     noconfigdirs="$noconfigdirs target-libffi"
 706     ;;
 707   *-*-rtems*)
 708     noconfigdirs="$noconfigdirs target-libffi"
 709     ;;
 710   *-*-tpf*)
 711     noconfigdirs="$noconfigdirs target-libffi"
 712     ;;
 713   *-*-uclinux*)
 714     noconfigdirs="$noconfigdirs target-libffi"
 715     ;;
 716   *-*-vxworks*)
 717     noconfigdirs="$noconfigdirs target-libffi"
 718     ;;
 719   aarch64*-*-freebsd*)
 720     noconfigdirs="$noconfigdirs target-libffi"
 721     ;;
 722   alpha*-*-*vms*)
 723     noconfigdirs="$noconfigdirs target-libffi"
 724     ;;
 725   arm*-*-freebsd*)
 726     noconfigdirs="$noconfigdirs target-libffi"
 727     ;;
 728   arm-wince-pe)
 729     noconfigdirs="$noconfigdirs target-libffi"
 730     ;;
 731   cris-*-* | crisv32-*-*)
 732     case "${target}" in
 733       *-*-linux*)
 734         ;;
 735       *) # See PR46792 regarding target-libffi.
 736         noconfigdirs="$noconfigdirs target-libffi";;
 737     esac
 738     ;;
 739   hppa*64*-*-hpux*)
 740     noconfigdirs="$noconfigdirs target-libffi"
 741     ;;
 742   hppa*-hp-hpux11*)
 743     ;;
 744   hppa*-*-hpux*)
 745     noconfigdirs="$noconfigdirs target-libffi"
 746     ;;
 747   ia64*-*-*vms*)
 748     noconfigdirs="$noconfigdirs target-libffi"
 749     ;;
 750   i[[3456789]]86-w64-mingw*)
 751     noconfigdirs="$noconfigdirs target-libffi"
 752     ;;
 753   i[[3456789]]86-*-mingw*)
 754     noconfigdirs="$noconfigdirs target-libffi"
 755     ;;
 756   x86_64-*-mingw*)
 757     noconfigdirs="$noconfigdirs target-libffi"
 758     ;;
 759   mmix-*-*)
 760     noconfigdirs="$noconfigdirs target-libffi"
 761     ;;
 762   powerpc-*-aix*)
 763     ;;
 764   rs6000-*-aix*)
 765     ;;
 766   ft32-*-*)
 767     noconfigdirs="$noconfigdirs target-libffi"
 768     ;;
 769   *-*-lynxos*)
 770     noconfigdirs="$noconfigdirs target-libffi"
 771     ;;
 772 esac
 773
 774 # Disable the go frontend on systems where it is known to not work. Please keep
 775 # this in sync with contrib/config-list.mk.
 776 case "${target}" in
 777 *-*-darwin* | *-*-cygwin* | *-*-mingw*)
 778     unsupported_languages="$unsupported_languages go"
 779     ;;
 780 esac
 781
 782 # Only allow gdbserver on some systems.
 783 if test -d ${srcdir}/gdbserver; then
 784     if test x$enable_gdbserver = x; then
 785         AC_MSG_CHECKING([for gdbserver support])
 786         if (srcdir=${srcdir}/gdbserver; \
 787                 . ${srcdir}/configure.srv; \
 788                 test -n "$UNSUPPORTED")
 789         then
 790             AC_MSG_RESULT([no])
 791             noconfigdirs="$noconfigdirs gdbserver"
 792         else
 793             AC_MSG_RESULT([yes])
 794         fi
 795     fi
 796 fi
 797
 798 # Disable libgo for some systems where it is known to not work.
 799 # For testing, you can easily override this with --enable-libgo.
 800 if test x$enable_libgo = x; then
 801     case "${target}" in
 802     *-*-darwin*)
 803         # PR 46986
 804         noconfigdirs="$noconfigdirs target-libgo"
 805         ;;
 806     *-*-cygwin* | *-*-mingw*)
 807         noconfigdirs="$noconfigdirs target-libgo"
 808         ;;
 809     esac
 810 fi
 811
 812 # Default libgloss CPU subdirectory.
 813 libgloss_dir="$target_cpu"
 814
 815 case "${target}" in
 816   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 817     libgloss_dir=wince
 818     ;;
 819   aarch64*-*-* )
 820     libgloss_dir=aarch64
 821     ;;
 822   arm*-*-*)
 823     libgloss_dir=arm
 824     ;;
 825   cris-*-* | crisv32-*-*)
 826     libgloss_dir=cris
 827     ;;
 828   hppa*-*-*)
 829     libgloss_dir=pa
 830     ;;
 831   i[[3456789]]86-*-*)
 832     libgloss_dir=i386
 833     ;;
 834   m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)
 835     libgloss_dir=m68hc11
 836     ;;
 837   m68*-*-* | fido-*-*)
 838     libgloss_dir=m68k
 839     ;;
 840   mips*-*-*)
 841     libgloss_dir=mips
 842     ;;
 843   powerpc*-*-*)
 844     libgloss_dir=rs6000
 845     ;;
 846   sparc*-*-*)
 847     libgloss_dir=sparc
 848     ;;
 849 esac
 850
 851 # Disable newlib and libgloss for various target OSes.
 852 case "${target}" in
 853   alpha*-dec-osf*)
 854     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 855     ;;
 856   i[[3456789]]86-*-linux*)
 857     # This section makes it possible to build newlib natively on linux.
 858     # If we are using a cross compiler then don't configure newlib.
 859     if test x${is_cross_compiler} != xno ; then
 860       noconfigdirs="$noconfigdirs target-newlib"
 861     fi
 862     noconfigdirs="$noconfigdirs target-libgloss"
 863     # If we are not using a cross compiler, do configure newlib.
 864     # Note however, that newlib will only be configured in this situation
 865     # if the --with-newlib option has been given, because otherwise
 866     # 'target-newlib' will appear in skipdirs.
 867     ;;
 868   i[[3456789]]86-*-rdos*)
 869     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 870     ;;
 871   sh*-*-pe|mips*-*-pe|arm-wince-pe)
 872     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 873     ;;
 874   sparc-*-sunos4*)
 875     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 876     ;;
 877   *-*-aix*)
 878     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 879     ;;
 880   *-*-beos*)
 881     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 882     ;;
 883   *-*-chorusos)
 884     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 885     ;;
 886   *-*-dragonfly*)
 887     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 888     ;;
 889   *-*-freebsd*)
 890     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 891     ;;
 892   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 893     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 894     ;;
 895   *-*-lynxos*)
 896     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 897     ;;
 898   *-*-mingw*)
 899     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 900     ;;
 901   *-*-netbsd*)
 902     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 903     ;;
 904   *-*-netware*)
 905     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 906     ;;
 907   *-*-tpf*)
 908     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 909     ;;
 910   *-*-uclinux*)
 911     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 912     ;;
 913   *-*-vxworks*)
 914     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 915     ;;
 916 esac
 917
 918 case "${target}" in
 919   *-*-chorusos)
 920     ;;
 921   aarch64-*-darwin*)
 922     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 923     noconfigdirs="$noconfigdirs sim target-rda"
 924     ;;
 925   arm-*-darwin*)
 926     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 927     noconfigdirs="$noconfigdirs sim target-rda"
 928     ;;
 929   powerpc-*-darwin*)
 930     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 931     noconfigdirs="$noconfigdirs sim target-rda"
 932     ;;
 933   i[[3456789]]86-*-darwin*)
 934     noconfigdirs="$noconfigdirs ld gprof"
 935     noconfigdirs="$noconfigdirs sim target-rda"
 936     ;;
 937   x86_64-*-darwin[[912]]*)
 938     noconfigdirs="$noconfigdirs ld gas gprof"
 939     noconfigdirs="$noconfigdirs sim target-rda"
 940     ;;
 941   *-*-darwin*)
 942     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 943     noconfigdirs="$noconfigdirs sim target-rda"
 944     ;;
 945   *-*-dragonfly*)
 946     ;;
 947   *-*-freebsd*)
 948     if test "x$with_gmp" = x && test "x$with_gmp_dir" = x \
 949         && test -f /usr/local/include/gmp.h; then
 950       with_gmp=/usr/local
 951     fi
 952     ;;
 953   *-*-kaos*)
 954     # Remove unsupported stuff on all kaOS configurations.
 955     noconfigdirs="$noconfigdirs target-libgloss"
 956     ;;
 957   *-*-netbsd*)
 958     ;;
 959   *-*-netware*)
 960     ;;
 961   *-*-phoenix*)
 962     noconfigdirs="$noconfigdirs target-libgloss"
 963     ;;
 964   *-*-rtems*)
 965     noconfigdirs="$noconfigdirs target-libgloss"
 966     ;;
 967     # The tpf target doesn't support gdb yet.
 968   *-*-tpf*)
 969     noconfigdirs="$noconfigdirs gdb tcl tk libgui itcl"
 970     ;;
 971   *-*-uclinux*)
 972     noconfigdirs="$noconfigdirs target-rda"
 973     ;;
 974   *-*-vxworks*)
 975     ;;
 976   alpha*-dec-osf*)
 977     # ld works, but does not support shared libraries.
 978     # gas doesn't generate exception information.
 979     noconfigdirs="$noconfigdirs gas ld"
 980     ;;
 981   alpha*-*-*vms*)
 982     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss"
 983     ;;
 984   alpha*-*-*)
 985     # newlib is not 64 bit ready
 986     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 987     ;;
 988   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 989     noconfigdirs="$noconfigdirs tcl tk itcl libgui sim"
 990     ;;
 991   arc*-*-*)
 992     noconfigdirs="$noconfigdirs sim"
 993     ;;
 994   arm-*-pe*)
 995     noconfigdirs="$noconfigdirs target-libgloss"
 996     ;;
 997   arm-*-riscix*)
 998     noconfigdirs="$noconfigdirs ld target-libgloss"
 999     ;;
1000   avr-*-*)
1001     if test x${with_avrlibc} != xno; then
1002       noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1003     fi
1004     ;;
1005   c4x-*-* | tic4x-*-*)
1006     noconfigdirs="$noconfigdirs target-libgloss"
1007     ;;
1008   tic54x-*-*)
1009     noconfigdirs="$noconfigdirs target-libgloss gdb"
1010     ;;
1011   d10v-*-*)
1012     noconfigdirs="$noconfigdirs target-libgloss"
1013     ;;
1014   d30v-*-*)
1015     noconfigdirs="$noconfigdirs gdb"
1016     ;;
1017   fr30-*-elf*)
1018     noconfigdirs="$noconfigdirs gdb"
1019     ;;
1020   ft32-*-*)
1021     noconfigdirs="$noconfigdirs target-rda gprof"
1022     ;;
1023   moxie-*-*)
1024     noconfigdirs="$noconfigdirs"
1025     ;;
1026   h8300*-*-*)
1027     noconfigdirs="$noconfigdirs target-libgloss"
1028     ;;
1029   h8500-*-*)
1030     noconfigdirs="$noconfigdirs target-libgloss"
1031     ;;
1032   hppa1.1-*-osf* | hppa1.1-*-bsd* )
1033     ;;
1034   hppa*64*-*-hpux*)
1035     noconfigdirs="$noconfigdirs gdb"
1036     ;;
1037   hppa*-*-hpux11*)
1038     noconfigdirs="$noconfigdirs gdb ld"
1039     ;;
1040   hppa*64*-*-linux*)
1041     ;;
1042   hppa*-*-linux*)
1043     ;;
1044   hppa*-*-*elf* | \
1045   hppa*-*-lites* | \
1046   hppa*-*-openbsd* | \
1047   hppa*64*-*-*)
1048     ;;
1049   hppa*-*-pro*)
1050     ;;
1051   hppa*-*-*)
1052     noconfigdirs="$noconfigdirs ld"
1053     ;;
1054   i960-*-*)
1055     noconfigdirs="$noconfigdirs gdb"
1056     ;;
1057   ia64*-*-elf*)
1058     # No gdb support yet.
1059     noconfigdirs="$noconfigdirs readline libgui itcl gdb"
1060     ;;
1061   ia64*-**-hpux*)
1062     # No ld support yet.
1063     noconfigdirs="$noconfigdirs gdb libgui itcl ld"
1064     ;;
1065   ia64*-*-*vms*)
1066     # No ld support yet.
1067     noconfigdirs="$noconfigdirs libgui itcl ld"
1068     ;;
1069   i[[3456789]]86-w64-mingw*)
1070     ;;
1071   i[[3456789]]86-*-mingw*)
1072     target_configdirs="$target_configdirs target-winsup"
1073     ;;
1074   *-*-cygwin*)
1075     target_configdirs="$target_configdirs target-libtermcap target-winsup"
1076     noconfigdirs="$noconfigdirs target-libgloss"
1077     # always build newlib if winsup directory is present.
1078     if test -d "$srcdir/winsup/cygwin"; then
1079       skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1080     elif test -d "$srcdir/newlib"; then
1081       echo "Warning: winsup/cygwin is missing so newlib can't be built."
1082     fi
1083     ;;
1084   i[[3456789]]86-*-pe)
1085     noconfigdirs="$noconfigdirs target-libgloss"
1086     ;;
1087   i[[3456789]]86-*-sco3.2v5*)
1088     # The linker does not yet know about weak symbols in COFF,
1089     # and is not configured to handle mixed ELF and COFF.
1090     noconfigdirs="$noconfigdirs ld target-libgloss"
1091     ;;
1092   i[[3456789]]86-*-sco*)
1093     noconfigdirs="$noconfigdirs gprof target-libgloss"
1094     ;;
1095   i[[3456789]]86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*)
1096     noconfigdirs="$noconfigdirs target-libgloss"
1097     ;;
1098   i[[3456789]]86-*-sysv4*)
1099     noconfigdirs="$noconfigdirs target-libgloss"
1100     ;;
1101   i[[3456789]]86-*-beos*)
1102     noconfigdirs="$noconfigdirs gdb"
1103     ;;
1104   i[[3456789]]86-*-rdos*)
1105     noconfigdirs="$noconfigdirs gdb"
1106     ;;
1107   mmix-*-*)
1108     noconfigdirs="$noconfigdirs gdb"
1109     ;;
1110   mt-*-*)
1111     noconfigdirs="$noconfigdirs sim"
1112     ;;
1113   nfp-*-*)
1114     noconfigdirs="$noconfigdirs ld gas gdb gprof sim"
1115     noconfigdirs="$noconfigdirs $target_libraries"
1116     ;;
1117   pdp11-*-*)
1118     noconfigdirs="$noconfigdirs gdb gprof"
1119     ;;
1120   powerpc-*-aix*)
1121     # copied from rs6000-*-* entry
1122     noconfigdirs="$noconfigdirs gprof"
1123     ;;
1124   powerpc*-*-winnt* | powerpc*-*-pe*)
1125     target_configdirs="$target_configdirs target-winsup"
1126     noconfigdirs="$noconfigdirs gdb tcl tk target-libgloss itcl"
1127     # always build newlib.
1128     skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1129     ;;
1130     # This is temporary until we can link against shared libraries
1131   powerpcle-*-solaris*)
1132     noconfigdirs="$noconfigdirs gdb sim tcl tk itcl"
1133     ;;
1134   powerpc-*-beos*)
1135     noconfigdirs="$noconfigdirs gdb"
1136     ;;
1137   rs6000-*-lynxos*)
1138     noconfigdirs="$noconfigdirs gprof"
1139     ;;
1140   rs6000-*-aix*)
1141     noconfigdirs="$noconfigdirs gprof"
1142     ;;
1143   rs6000-*-*)
1144     noconfigdirs="$noconfigdirs gprof"
1145     ;;
1146   m68k-apollo-*)
1147     noconfigdirs="$noconfigdirs ld binutils gprof target-libgloss"
1148     ;;
1149   microblaze*)
1150     noconfigdirs="$noconfigdirs gprof"
1151     ;;
1152   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
1153     if test x$with_newlib = xyes; then
1154       noconfigdirs="$noconfigdirs gprof"
1155     fi
1156     ;;
1157   mips*-*-irix5*)
1158     noconfigdirs="$noconfigdirs gprof target-libgloss"
1159     ;;
1160   mips*-*-irix6*)
1161     noconfigdirs="$noconfigdirs gprof target-libgloss"
1162     ;;
1163   mips*-*-bsd*)
1164     noconfigdirs="$noconfigdirs ld gas gprof target-libgloss"
1165     ;;
1166   mips*-*-linux*)
1167     ;;
1168   mips*-*-ultrix* | mips*-*-osf* | mips*-*-ecoff* | mips*-*-pe* \
1169   | mips*-*-irix* | mips*-*-lnews* | mips*-*-riscos*)
1170     noconfigdirs="$noconfigdirs ld gas gprof"
1171     ;;
1172   mips*-*-*)
1173     noconfigdirs="$noconfigdirs gprof"
1174     ;;
1175   nvptx*-*-*)
1176     noconfigdirs="$noconfigdirs target-libssp target-libstdc++-v3 target-libobjc"
1177     ;;
1178   sh-*-*)
1179     case "${target}" in
1180       sh*-*-elf)
1181          ;;
1182       *)
1183          noconfigdirs="$noconfigdirs target-libgloss" ;;
1184     esac
1185     ;;
1186   sparc-*-sunos4*)
1187     if test x${is_cross_compiler} = xno ; then
1188            use_gnu_ld=no
1189     fi
1190     ;;
1191   tic6x-*-*)
1192     noconfigdirs="$noconfigdirs sim"
1193     ;;
1194   tilepro*-*-* | tilegx*-*-*)
1195     noconfigdirs="$noconfigdirs sim"
1196     ;;
1197   v810-*-*)
1198     noconfigdirs="$noconfigdirs bfd binutils gas gdb ld opcodes target-libgloss"
1199     ;;
1200   vax-*-*)
1201     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1202     ;;
1203   wasm32-*-*)
1204     noconfigdirs="$noconfigdirs ld"
1205     ;;
1206 esac
1207
1208 # If we aren't building newlib, then don't build libgloss, since libgloss
1209 # depends upon some newlib header files.
1210 case "${noconfigdirs}" in
1211   *target-libgloss*) ;;
1212   *target-newlib*) noconfigdirs="$noconfigdirs target-libgloss" ;;
1213 esac
1214
1215 # Work in distributions that contain no compiler tools, like Autoconf.
1216 host_makefile_frag=/dev/null
1217 if test -d ${srcdir}/config ; then
1218 case "${host}" in
1219   i[[3456789]]86-*-msdosdjgpp*)
1220     host_makefile_frag="config/mh-djgpp"
1221     ;;
1222   *-cygwin*)
1223     ACX_CHECK_CYGWIN_CAT_WORKS
1224     host_makefile_frag="config/mh-cygwin"
1225     ;;
1226   *-mingw*)
1227     host_makefile_frag="config/mh-mingw"
1228     ;;
1229   alpha*-linux*)
1230     host_makefile_frag="config/mh-alpha-linux"
1231     ;;
1232   hppa*-hp-hpux10*)
1233     host_makefile_frag="config/mh-pa-hpux10"
1234     ;;
1235   hppa*-hp-hpux*)
1236     host_makefile_frag="config/mh-pa"
1237     ;;
1238   hppa*-*)
1239     host_makefile_frag="config/mh-pa"
1240     ;;
1241   *-*-darwin*)
1242     host_makefile_frag="config/mh-darwin"
1243     ;;
1244   powerpc-*-aix*)
1245     host_makefile_frag="config/mh-ppc-aix"
1246     ;;
1247   rs6000-*-aix*)
1248     host_makefile_frag="config/mh-ppc-aix"
1249     ;;
1250 esac
1251 fi
1252
1253 if test "${build}" != "${host}" ; then
1254   AR_FOR_BUILD=${AR_FOR_BUILD-ar}
1255   AS_FOR_BUILD=${AS_FOR_BUILD-as}
1256   CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
1257   CXX_FOR_BUILD=${CXX_FOR_BUILD-g++}
1258   GFORTRAN_FOR_BUILD=${GFORTRAN_FOR_BUILD-gfortran}
1259   GOC_FOR_BUILD=${GOC_FOR_BUILD-gccgo}
1260   DLLTOOL_FOR_BUILD=${DLLTOOL_FOR_BUILD-dlltool}
1261   LD_FOR_BUILD=${LD_FOR_BUILD-ld}
1262   NM_FOR_BUILD=${NM_FOR_BUILD-nm}
1263   RANLIB_FOR_BUILD=${RANLIB_FOR_BUILD-ranlib}
1264   WINDRES_FOR_BUILD=${WINDRES_FOR_BUILD-windres}
1265   WINDMC_FOR_BUILD=${WINDMC_FOR_BUILD-windmc}
1266 else
1267   AR_FOR_BUILD="\$(AR)"
1268   AS_FOR_BUILD="\$(AS)"
1269   CC_FOR_BUILD="\$(CC)"
1270   CXX_FOR_BUILD="\$(CXX)"
1271   GFORTRAN_FOR_BUILD="\$(GFORTRAN)"
1272   GOC_FOR_BUILD="\$(GOC)"
1273   DLLTOOL_FOR_BUILD="\$(DLLTOOL)"
1274   LD_FOR_BUILD="\$(LD)"
1275   NM_FOR_BUILD="\$(NM)"
1276   RANLIB_FOR_BUILD="\$(RANLIB)"
1277   WINDRES_FOR_BUILD="\$(WINDRES)"
1278   WINDMC_FOR_BUILD="\$(WINDMC)"
1279 fi
1280
1281 AC_PROG_CC
1282 AC_PROG_CXX
1283
1284 # We must set the default linker to the linker used by gcc for the correct
1285 # operation of libtool.  If LD is not defined and we are using gcc, try to
1286 # set the LD default to the ld used by gcc.
1287 if test -z "$LD"; then
1288   if test "$GCC" = yes; then
1289     case $build in
1290     *-*-mingw*)
1291       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1 | tr -d '\015'` ;;
1292     *)
1293       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1` ;;
1294     esac
1295     case $gcc_prog_ld in
1296     # Accept absolute paths.
1297     [[\\/]* | [A-Za-z]:[\\/]*)]
1298       LD="$gcc_prog_ld" ;;
1299     esac
1300   fi
1301 fi
1302
1303 # Check whether -static-libstdc++ -static-libgcc is supported.
1304 have_static_libs=no
1305 if test "$GCC" = yes; then
1306   saved_LDFLAGS="$LDFLAGS"
1307
1308   LDFLAGS="$LDFLAGS -static-libstdc++ -static-libgcc"
1309   AC_MSG_CHECKING([whether g++ accepts -static-libstdc++ -static-libgcc])
1310   AC_LANG_PUSH(C++)
1311   AC_LINK_IFELSE([AC_LANG_SOURCE([
1312 #if (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 5)
1313 #error -static-libstdc++ not implemented
1314 #endif
1315 int main() {}])],
1316     [AC_MSG_RESULT([yes]); have_static_libs=yes],
1317     [AC_MSG_RESULT([no])])
1318   AC_LANG_POP(C++)
1319
1320   LDFLAGS="$saved_LDFLAGS"
1321 fi
1322
1323 ACX_PROG_GNAT
1324 ACX_PROG_CMP_IGNORE_INITIAL
1325
1326 AC_ARG_ENABLE([bootstrap],
1327 [AS_HELP_STRING([--enable-bootstrap],
1328                 [enable bootstrapping @<:@yes if native build@:>@])],,
1329 enable_bootstrap=default)
1330
1331 # Issue errors and warnings for invalid/strange bootstrap combinations.
1332 if test -r $srcdir/gcc/configure; then
1333   have_compiler=yes
1334 else
1335   have_compiler=no
1336 fi
1337
1338 case "$have_compiler:$host:$target:$enable_bootstrap" in
1339   *:*:*:no) ;;
1340
1341   # Default behavior.  Enable bootstrap if we have a compiler
1342   # and we are in a native configuration.
1343   yes:$build:$build:default)
1344     enable_bootstrap=yes ;;
1345
1346   *:*:*:default)
1347     enable_bootstrap=no ;;
1348
1349   # We have a compiler and we are in a native configuration, bootstrap is ok
1350   yes:$build:$build:yes)
1351     ;;
1352
1353   # Other configurations, but we have a compiler.  Assume the user knows
1354   # what he's doing.
1355   yes:*:*:yes)
1356     AC_MSG_WARN([trying to bootstrap a cross compiler])
1357     ;;
1358
1359   # No compiler: if they passed --enable-bootstrap explicitly, fail
1360   no:*:*:yes)
1361     AC_MSG_ERROR([cannot bootstrap without a compiler]) ;;
1362
1363   # Fail if wrong command line
1364   *)
1365     AC_MSG_ERROR([invalid option for --enable-bootstrap])
1366     ;;
1367 esac
1368
1369 # When bootstrapping with GCC, build stage 1 in C++98 mode to ensure that a
1370 # C++98 compiler can still start the bootstrap.
1371 if test "$enable_bootstrap:$GXX" = "yes:yes"; then
1372   CXX="$CXX -std=gnu++98"
1373 fi
1374
1375 AC_ARG_ENABLE([pgo-build],
1376 [AS_HELP_STRING([--enable-pgo-build[[=lto]]],
1377                 [enable the PGO build])],
1378 [enable_pgo_build=$enableval],
1379 [enable_pgo_build=no])
1380
1381 # Issue errors and warnings for invalid/strange PGO build combinations.
1382 case "$have_compiler:$host:$target:$enable_pgo_build" in
1383   *:*:*:no) ;;
1384
1385   # Allow the PGO build only if we aren't building a compiler and
1386   # we are in a native configuration.
1387   no:$build:$build:yes | no:$build:$build:lto) ;;
1388
1389   # Disallow the PGO bootstrap if we are building a compiler.
1390   yes:*:*:yes | yes:*:*:lto)
1391     AC_MSG_ERROR([cannot perform the PGO bootstrap when building a compiler]) ;;
1392
1393   *)
1394     AC_MSG_ERROR([invalid option for --enable-pgo-build])
1395     ;;
1396 esac
1397
1398 if test "$enable_pgo_build" != "no"; then
1399   AC_MSG_CHECKING([whether the compiler supports -fprofile-generate])
1400   old_CFLAGS="$CFLAGS"
1401   PGO_BUILD_GEN_CFLAGS="-fprofile-generate"
1402   CFLAGS="$CFLAGS $PGO_BUILD_CFLAGS"
1403   AC_COMPILE_IFELSE([AC_LANG_SOURCE([int foo;])],,
1404                     [PGO_BUILD_GEN_CFLAGS=])
1405   CFLAGS="$old_CFLAGS"
1406   if test -n "$PGO_BUILD_GEN_CFLAGS"; then
1407     AC_MSG_RESULT([yes])
1408     PGO_BUILD_USE_CFLAGS="-fprofile-use"
1409   else
1410     AC_MSG_RESULT([no])
1411     AC_MSG_ERROR([cannot perform the PGO build without -fprofile-generate])
1412   fi
1413
1414   if test "$enable_pgo_build" = "lto"; then
1415     AC_MSG_CHECKING([whether the compiler supports -flto=jobserver -ffat-lto-objects])
1416     old_CFLAGS="$CFLAGS"
1417     PGO_BUILD_LTO_CFLAGS="-flto=jobserver -ffat-lto-objects"
1418     CFLAGS="$CFLAGS $PGO_BUILD_LTO_CFLAGS"
1419     AC_COMPILE_IFELSE([AC_LANG_SOURCE([int foo;])],,
1420                       [PGO_BUILD_LTO_CFLAGS=])
1421     CFLAGS="$old_CFLAGS"
1422     if test -n "$PGO_BUILD_LTO_CFLAGS"; then
1423       AC_MSG_RESULT([yes])
1424     else
1425       AC_MSG_RESULT([no])
1426       AC_MSG_WARN([LTO is disabled for the PGO build])
1427     fi
1428   fi
1429 fi
1430 AC_SUBST(PGO_BUILD_GEN_CFLAGS)
1431 AC_SUBST(PGO_BUILD_USE_CFLAGS)
1432 AC_SUBST(PGO_BUILD_LTO_CFLAGS)
1433
1434 # Used for setting $lt_cv_objdir
1435 _LT_CHECK_OBJDIR
1436
1437 # Check for GMP, MPFR and MPC
1438 gmplibs="-lmpc -lmpfr -lgmp"
1439 gmpinc=
1440 have_gmp=no
1441
1442 # Specify a location for mpc
1443 # check for this first so it ends up on the link line before mpfr.
1444 AC_ARG_WITH(mpc,
1445 [AS_HELP_STRING([--with-mpc=PATH],
1446                 [specify prefix directory for installed MPC package.
1447                  Equivalent to --with-mpc-include=PATH/include
1448                  plus --with-mpc-lib=PATH/lib])])
1449 AC_ARG_WITH(mpc-include,
1450 [AS_HELP_STRING([--with-mpc-include=PATH],
1451                 [specify directory for installed MPC include files])])
1452 AC_ARG_WITH(mpc-lib,
1453 [AS_HELP_STRING([--with-mpc-lib=PATH],
1454                 [specify directory for the installed MPC library])])
1455
1456 if test "x$with_mpc" != x; then
1457   gmplibs="-L$with_mpc/lib $gmplibs"
1458   gmpinc="-I$with_mpc/include $gmpinc"
1459 fi
1460 if test "x$with_mpc_include" != x; then
1461   gmpinc="-I$with_mpc_include $gmpinc"
1462 fi
1463 if test "x$with_mpc_lib" != x; then
1464   gmplibs="-L$with_mpc_lib $gmplibs"
1465 fi
1466 if test "x$with_mpc$with_mpc_include$with_mpc_lib" = x && test -d ${srcdir}/mpc; then
1467   gmplibs='-L$$r/$(HOST_SUBDIR)/mpc/src/'"$lt_cv_objdir $gmplibs"
1468   gmpinc='-I$$s/mpc/src '"$gmpinc"
1469   # Do not test the mpc version.  Assume that it is sufficient, since
1470   # it is in the source tree, and the library has not been built yet
1471   # but it would be included on the link line in the version check below
1472   # hence making the test fail.
1473   have_gmp=yes
1474 fi
1475
1476 # Specify a location for mpfr
1477 # check for this first so it ends up on the link line before gmp.
1478 AC_ARG_WITH(mpfr-dir,
1479 [AS_HELP_STRING([--with-mpfr-dir=PATH], [this option has been REMOVED])],
1480 [AC_MSG_ERROR([The --with-mpfr-dir=PATH option has been removed.
1481 Use --with-mpfr=PATH or --with-mpfr-include=PATH plus --with-mpfr-lib=PATH])])
1482
1483 AC_ARG_WITH(mpfr,
1484 [AS_HELP_STRING([--with-mpfr=PATH],
1485                 [specify prefix directory for installed MPFR package.
1486                  Equivalent to --with-mpfr-include=PATH/include
1487                  plus --with-mpfr-lib=PATH/lib])])
1488 AC_ARG_WITH(mpfr-include,
1489 [AS_HELP_STRING([--with-mpfr-include=PATH],
1490                 [specify directory for installed MPFR include files])])
1491 AC_ARG_WITH(mpfr-lib,
1492 [AS_HELP_STRING([--with-mpfr-lib=PATH],
1493                 [specify directory for the installed MPFR library])])
1494
1495 if test "x$with_mpfr" != x; then
1496   gmplibs="-L$with_mpfr/lib $gmplibs"
1497   gmpinc="-I$with_mpfr/include $gmpinc"
1498 fi
1499 if test "x$with_mpfr_include" != x; then
1500   gmpinc="-I$with_mpfr_include $gmpinc"
1501 fi
1502 if test "x$with_mpfr_lib" != x; then
1503   gmplibs="-L$with_mpfr_lib $gmplibs"
1504 fi
1505 if test "x$with_mpfr$with_mpfr_include$with_mpfr_lib" = x && test -d ${srcdir}/mpfr; then
1506   # MPFR v3.1.0 moved the sources into a src sub-directory.
1507   if ! test -d ${srcdir}/mpfr/src; then
1508     AC_MSG_ERROR([dnl
1509 Building GCC with MPFR in the source tree is only handled for MPFR 3.1.0+.])
1510   fi
1511   gmplibs='-L$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir $gmplibs"
1512   gmpinc='-I$$r/$(HOST_SUBDIR)/mpfr/src -I$$s/mpfr/src '"$gmpinc"
1513   extra_mpc_mpfr_configure_flags='--with-mpfr-include=$$s/mpfr/src --with-mpfr-lib=$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir"
1514   # Do not test the mpfr version.  Assume that it is sufficient, since
1515   # it is in the source tree, and the library has not been built yet
1516   # but it would be included on the link line in the version check below
1517   # hence making the test fail.
1518   have_gmp=yes
1519 fi
1520
1521 # Specify a location for gmp
1522 AC_ARG_WITH(gmp-dir,
1523 [AS_HELP_STRING([--with-gmp-dir=PATH], [this option has been REMOVED])],
1524 [AC_MSG_ERROR([The --with-gmp-dir=PATH option has been removed.
1525 Use --with-gmp=PATH or --with-gmp-include=PATH plus --with-gmp-lib=PATH])])
1526
1527 AC_ARG_WITH(gmp,
1528 [AS_HELP_STRING([--with-gmp=PATH],
1529                 [specify prefix directory for the installed GMP package.
1530                  Equivalent to --with-gmp-include=PATH/include
1531                  plus --with-gmp-lib=PATH/lib])])
1532 AC_ARG_WITH(gmp-include,
1533 [AS_HELP_STRING([--with-gmp-include=PATH],
1534                 [specify directory for installed GMP include files])])
1535 AC_ARG_WITH(gmp-lib,
1536 [AS_HELP_STRING([--with-gmp-lib=PATH],
1537                 [specify directory for the installed GMP library])])
1538
1539
1540 if test "x$with_gmp" != x; then
1541   gmplibs="-L$with_gmp/lib $gmplibs"
1542   gmpinc="-I$with_gmp/include $gmpinc"
1543 fi
1544 if test "x$with_gmp_include" != x; then
1545   gmpinc="-I$with_gmp_include $gmpinc"
1546 fi
1547 if test "x$with_gmp_lib" != x; then
1548   gmplibs="-L$with_gmp_lib $gmplibs"
1549 fi
1550 if test "x$with_gmp$with_gmp_include$with_gmp_lib" = x && test -d ${srcdir}/gmp; then
1551   gmplibs='-L$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir $gmplibs"
1552   gmpinc='-I$$r/$(HOST_SUBDIR)/gmp -I$$s/gmp '"$gmpinc"
1553   extra_mpfr_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1554   extra_mpc_gmp_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1555   extra_isl_gmp_configure_flags='--with-gmp-builddir=$$r/$(HOST_SUBDIR)/gmp'
1556   # Do not test the gmp version.  Assume that it is sufficient, since
1557   # it is in the source tree, and the library has not been built yet
1558   # but it would be included on the link line in the version check below
1559   # hence making the test fail.
1560   have_gmp=yes
1561 fi
1562
1563 if test -d ${srcdir}/gcc && test "x$have_gmp" = xno; then
1564   have_gmp=yes
1565   saved_CFLAGS="$CFLAGS"
1566   CFLAGS="$CFLAGS $gmpinc"
1567   # Check for the recommended and required versions of GMP.
1568   AC_MSG_CHECKING([for the correct version of gmp.h])
1569   AC_TRY_COMPILE([#include "gmp.h"],[
1570   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1571   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1572   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,2,3)
1573   choke me
1574   #endif
1575   ], [AC_TRY_COMPILE([#include <gmp.h>],[
1576   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1577   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1578   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,3,2)
1579   choke me
1580   #endif
1581   ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1582    [AC_MSG_RESULT([no]); have_gmp=no])
1583
1584   # If we have GMP, check the MPFR version.
1585   if test x"$have_gmp" = xyes; then
1586     # Check for the recommended and required versions of MPFR.
1587     AC_MSG_CHECKING([for the correct version of mpfr.h])
1588     AC_TRY_COMPILE([#include <gmp.h>
1589     #include <mpfr.h>],[
1590     #if MPFR_VERSION < MPFR_VERSION_NUM(2,4,0)
1591     choke me
1592     #endif
1593     ], [AC_TRY_COMPILE([#include <gmp.h>
1594     #include <mpfr.h>],[
1595     #if MPFR_VERSION < MPFR_VERSION_NUM(2,4,2)
1596     choke me
1597     #endif
1598     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1599      [AC_MSG_RESULT([no]); have_gmp=no])
1600   fi
1601
1602   # Check for the MPC header version.
1603   if test x"$have_gmp" = xyes ; then
1604     # Check for the recommended and required versions of MPC.
1605     AC_MSG_CHECKING([for the correct version of mpc.h])
1606     AC_TRY_COMPILE([#include <mpc.h>],[
1607     #if MPC_VERSION < MPC_VERSION_NUM(0,8,0)
1608     choke me
1609     #endif
1610     ], [AC_TRY_COMPILE([#include <mpc.h>],[
1611     #if MPC_VERSION < MPC_VERSION_NUM(0,8,1)
1612     choke me
1613     #endif
1614     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1615      [AC_MSG_RESULT([no]); have_gmp=no])
1616   fi
1617
1618   # Now check the MPFR library.
1619   if test x"$have_gmp" = xyes; then
1620     saved_LIBS="$LIBS"
1621     LIBS="$LIBS $gmplibs"
1622     AC_MSG_CHECKING([for the correct version of the gmp/mpfr/mpc libraries])
1623     AC_TRY_LINK([#include <mpc.h>],[
1624     mpfr_t n;
1625     mpfr_t x;
1626     mpc_t c;
1627     int t;
1628     mpfr_init (n);
1629     mpfr_init (x);
1630     mpfr_atan2 (n, n, x, GMP_RNDN);
1631     mpfr_erfc (n, x, GMP_RNDN);
1632     mpfr_subnormalize (x, t, GMP_RNDN);
1633     mpfr_clear(n);
1634     mpfr_clear(x);
1635     mpc_init2 (c, 53);
1636     mpc_set_ui_ui (c, 1, 1, MPC_RNDNN);
1637     mpc_cosh (c, c, MPC_RNDNN);
1638     mpc_pow (c, c, c, MPC_RNDNN);
1639     mpc_acosh (c, c, MPC_RNDNN);
1640     mpc_clear (c);
1641     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1642     LIBS="$saved_LIBS"
1643   fi
1644
1645   CFLAGS="$saved_CFLAGS"
1646
1647 # The library versions listed in the error message below should match
1648 # the HARD-minimums enforced above.
1649   if test x$have_gmp != xyes; then
1650     AC_MSG_ERROR([Building GCC requires GMP 4.2+, MPFR 2.4.0+ and MPC 0.8.0+.
1651 Try the --with-gmp, --with-mpfr and/or --with-mpc options to specify
1652 their locations.  Source code for these libraries can be found at
1653 their respective hosting sites as well as at
1654 ftp://gcc.gnu.org/pub/gcc/infrastructure/.  See also
1655 http://gcc.gnu.org/install/prerequisites.html for additional info.  If
1656 you obtained GMP, MPFR and/or MPC from a vendor distribution package,
1657 make sure that you have installed both the libraries and the header
1658 files.  They may be located in separate packages.])
1659   fi
1660 fi
1661
1662 # Flags needed for both GMP, MPFR and/or MPC.
1663 AC_SUBST(gmplibs)
1664 AC_SUBST(gmpinc)
1665 AC_SUBST(extra_mpfr_configure_flags)
1666 AC_SUBST(extra_mpc_gmp_configure_flags)
1667 AC_SUBST(extra_mpc_mpfr_configure_flags)
1668 AC_SUBST(extra_isl_gmp_configure_flags)
1669
1670 # Libraries to use for stage1 or when not bootstrapping.
1671 AC_ARG_WITH(stage1-libs,
1672 [AS_HELP_STRING([--with-stage1-libs=LIBS], [libraries for stage1])],
1673 [if test "$withval" = "no" -o "$withval" = "yes"; then
1674    stage1_libs=
1675  else
1676    stage1_libs=$withval
1677  fi],
1678 [stage1_libs=])
1679 AC_SUBST(stage1_libs)
1680
1681 # Whether or not to use -static-libstdc++ and -static-libgcc.  The
1682 # default is yes if gcc is being built; no otherwise.  The reason for
1683 # this default is that gdb is sometimes linked against GNU Source
1684 # Highlight, which is a shared library that uses C++ exceptions.  In
1685 # this case, -static-libstdc++ will cause crashes.
1686 AC_ARG_WITH(static-standard-libraries,
1687 [AS_HELP_STRING([--with-static-standard-libraries],
1688                 [use -static-libstdc++ and -static-libgcc (default=auto)])],
1689 [], [with_static_standard_libraries=auto])
1690 if test "$with_static_standard_libraries" = auto; then
1691   with_static_standard_libraries=$have_compiler
1692 fi
1693
1694 # Linker flags to use for stage1 or when not bootstrapping.
1695 AC_ARG_WITH(stage1-ldflags,
1696 [AS_HELP_STRING([--with-stage1-ldflags=FLAGS], [linker flags for stage1])],
1697 [if test "$withval" = "no" -o "$withval" = "yes"; then
1698    stage1_ldflags=
1699  else
1700    stage1_ldflags=$withval
1701  fi],
1702 [stage1_ldflags=
1703  # In stage 1, default to linking libstdc++ and libgcc statically with GCC
1704  # if supported.  But if the user explicitly specified the libraries to use,
1705  # trust that they are doing what they want.
1706  if test "$with_static_standard_libraries" = yes -a "$stage1_libs" = "" \
1707      -a "$have_static_libs" = yes; then
1708    stage1_ldflags="-static-libstdc++ -static-libgcc"
1709  fi])
1710 AC_SUBST(stage1_ldflags)
1711
1712 # Libraries to use for stage2 and later builds.
1713 AC_ARG_WITH(boot-libs,
1714 [AS_HELP_STRING([--with-boot-libs=LIBS], [libraries for stage2 and later])],
1715 [if test "$withval" = "no" -o "$withval" = "yes"; then
1716    poststage1_libs=
1717  else
1718    poststage1_libs=$withval
1719  fi],
1720 [poststage1_libs=])
1721 AC_SUBST(poststage1_libs)
1722
1723 # Linker flags to use for stage2 and later builds.
1724 AC_ARG_WITH(boot-ldflags,
1725 [AS_HELP_STRING([--with-boot-ldflags=FLAGS],
1726                 [linker flags for stage2 and later])],
1727 [if test "$withval" = "no" -o "$withval" = "yes"; then
1728    poststage1_ldflags=
1729  else
1730    poststage1_ldflags=$withval
1731  fi],
1732 [poststage1_ldflags=
1733  # In stages 2 and 3, default to linking libstdc++ and libgcc
1734  # statically.  But if the user explicitly specified the libraries to
1735  # use, trust that they are doing what they want.
1736  if test "$poststage1_libs" = ""; then
1737    poststage1_ldflags="-static-libstdc++ -static-libgcc"
1738  fi])
1739 AC_SUBST(poststage1_ldflags)
1740
1741 # GCC GRAPHITE dependency isl.
1742 # Basic setup is inlined here, actual checks are in config/isl.m4
1743
1744 AC_ARG_WITH(isl,
1745   [AS_HELP_STRING(
1746    [--with-isl=PATH],
1747    [Specify prefix directory for the installed isl package.
1748     Equivalent to --with-isl-include=PATH/include
1749     plus --with-isl-lib=PATH/lib])])
1750
1751 # Treat --without-isl as a request to disable
1752 # GRAPHITE support and skip all following checks.
1753 if test "x$with_isl" != "xno"; then
1754   # Check for isl
1755   dnl Provide configure switches and initialize islinc & isllibs
1756   dnl with user input.
1757   ISL_INIT_FLAGS
1758   dnl The versions of isl that work for Graphite
1759   ISL_CHECK_VERSION()
1760   dnl Only execute fail-action, if isl has been requested.
1761   ISL_IF_FAILED([
1762     AC_MSG_ERROR([Unable to find a usable isl.  See config.log for details.])])
1763 fi
1764
1765 # If the isl check failed, disable builds of in-tree variant of isl
1766 if test "x$with_isl" = xno ||
1767    test "x$gcc_cv_isl" = xno; then
1768   noconfigdirs="$noconfigdirs isl"
1769   islinc=
1770 fi
1771
1772 AC_SUBST(isllibs)
1773 AC_SUBST(islinc)
1774
1775 # Check for LTO support.
1776 AC_ARG_ENABLE(lto,
1777 [AS_HELP_STRING([--enable-lto], [enable link time optimization support])],
1778 enable_lto=$enableval,
1779 enable_lto=yes; default_enable_lto=yes)
1780
1781 ACX_ELF_TARGET_IFELSE([# ELF platforms build the lto-plugin always.
1782   build_lto_plugin=yes
1783 ],[if test x"$default_enable_lto" = x"yes" ; then
1784     case $target in
1785       *-apple-darwin[[912]]* | *-cygwin* | *-mingw* | *djgpp*) ;;
1786       # On other non-ELF platforms, LTO has yet to be validated.
1787       *) enable_lto=no ;;
1788     esac
1789   else
1790   # Apart from ELF platforms, only Windows and Darwin support LTO so far.
1791   # It would also be nice to check the binutils support, but we don't
1792   # have gcc_GAS_CHECK_FEATURE available here.  For now, we'll just
1793   # warn during gcc/ subconfigure; unless you're bootstrapping with
1794   # -flto it won't be needed until after installation anyway.
1795     case $target in
1796       *-cygwin* | *-mingw* | *-apple-darwin* | *djgpp*) ;;
1797       *) if test x"$enable_lto" = x"yes"; then
1798         AC_MSG_ERROR([LTO support is not enabled for this target.])
1799         fi
1800       ;;
1801     esac
1802   fi
1803   # Among non-ELF, only Windows platforms support the lto-plugin so far.
1804   # Build it unless LTO was explicitly disabled.
1805   case $target in
1806     *-cygwin* | *-mingw*) build_lto_plugin=$enable_lto ;;
1807     *) ;;
1808   esac
1809 ])
1810
1811 AC_ARG_ENABLE(linker-plugin-configure-flags,
1812   [AS_HELP_STRING([[--enable-linker-plugin-configure-flags=FLAGS]],
1813     [additional flags for configuring linker plugins @<:@none@:>@])],
1814   extra_linker_plugin_configure_flags=$enableval,
1815   extra_linker_plugin_configure_flags=)
1816 AC_SUBST(extra_linker_plugin_configure_flags)
1817 AC_ARG_ENABLE(linker-plugin-flags,
1818   [AS_HELP_STRING([[--enable-linker-plugin-flags=FLAGS]],
1819     [additional flags for configuring and building linker plugins @<:@none@:>@])],
1820   extra_linker_plugin_flags=$enableval,
1821   extra_linker_plugin_flags=)
1822 AC_SUBST(extra_linker_plugin_flags)
1823
1824 # Enable --enable-host-shared.
1825 # Checked early to determine whether jit is an 'all' language
1826 AC_ARG_ENABLE(host-shared,
1827 [AS_HELP_STRING([--enable-host-shared],
1828                 [build host code as shared libraries])],
1829 [host_shared=$enableval], [host_shared=no])
1830 AC_SUBST(host_shared)
1831
1832 # By default, C and C++ are the only stage 1 languages.
1833 stage1_languages=,c,
1834
1835 # Target libraries that we bootstrap.
1836 bootstrap_target_libs=,target-libgcc,
1837
1838 # Figure out what language subdirectories are present.
1839 # Look if the user specified --enable-languages="..."; if not, use
1840 # the environment variable $LANGUAGES if defined. $LANGUAGES might
1841 # go away some day.
1842 # NB:  embedded tabs in this IF block -- do not untabify
1843 if test -d ${srcdir}/gcc; then
1844   if test x"${enable_languages+set}" != xset; then
1845     if test x"${LANGUAGES+set}" = xset; then
1846       enable_languages="${LANGUAGES}"
1847         echo configure.ac: warning: setting LANGUAGES is deprecated, use --enable-languages instead 1>&2
1848     else
1849       enable_languages=default
1850     fi
1851   else
1852     if test x"${enable_languages}" = x ||
1853        test x"${enable_languages}" = xyes;
1854        then
1855       echo configure.ac: --enable-languages needs at least one language argument 1>&2
1856       exit 1
1857     fi
1858   fi
1859   enable_languages=`echo "${enable_languages}" | sed -e 's/[[   ,]][[   ,]]*/,/g' -e 's/,$//'`
1860
1861   # 'f95' is the old name for the 'fortran' language. We issue a warning
1862   # and make the substitution.
1863   case ,${enable_languages}, in
1864     *,f95,*)
1865       echo configure.ac: warning: 'f95' as language name is deprecated, use 'fortran' instead 1>&2
1866       enable_languages=`echo "${enable_languages}" | sed -e 's/f95/fortran/g'`
1867       ;;
1868   esac
1869
1870   # If bootstrapping, C++ must be enabled.
1871   case ",$enable_languages,:$enable_bootstrap" in
1872     *,c++,*:*) ;;
1873     *:yes)
1874       if test -f ${srcdir}/gcc/cp/config-lang.in; then
1875         enable_languages="${enable_languages},c++"
1876       else
1877         AC_MSG_ERROR([bootstrapping requires c++ sources])
1878       fi
1879       ;;
1880   esac
1881
1882   # First scan to see if an enabled language requires some other language.
1883   # We assume that a given config-lang.in will list all the language
1884   # front ends it requires, even if some are required indirectly.
1885   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1886     case ${lang_frag} in
1887       ..) ;;
1888       # The odd quoting in the next line works around
1889       # an apparent bug in bash 1.12 on linux.
1890       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1891       *)
1892         # From the config-lang.in, get $language, $lang_requires, and
1893         # $lang_requires_boot_languages.
1894         language=
1895         lang_requires=
1896         lang_requires_boot_languages=
1897         # set srcdir during sourcing lang_frag to the gcc dir.
1898         # Sadly overriding srcdir on the . line doesn't work in plain sh as it
1899         # polutes this shell
1900         saved_srcdir=${srcdir}
1901         srcdir=${srcdir}/gcc . ${lang_frag}
1902         srcdir=${saved_srcdir}
1903         for other in ${lang_requires} ${lang_requires_boot_languages}; do
1904           case ,${enable_languages}, in
1905             *,$other,*) ;;
1906             *,default,*) ;;
1907             *,all,*) ;;
1908             *,$language,*)
1909               echo " \`$other' language required by \`$language'; enabling" 1>&2
1910               enable_languages="${enable_languages},${other}"
1911               ;;
1912           esac
1913         done
1914         for other in ${lang_requires_boot_languages} ; do
1915           if test "$other" != "c"; then
1916             case ,${enable_stage1_languages}, in
1917               *,$other,*) ;;
1918               *,default,*) ;;
1919               *,all,*) ;;
1920               *)
1921                 case ,${enable_languages}, in
1922                   *,$language,*)
1923                     echo " '$other' language required by '$language' in stage 1; enabling" 1>&2
1924                     enable_stage1_languages="$enable_stage1_languages,${other}"
1925                     ;;
1926                 esac
1927                 ;;
1928             esac
1929           fi
1930         done
1931         ;;
1932     esac
1933   done
1934
1935   new_enable_languages=,c,
1936
1937   # If LTO is enabled, add the LTO front end.
1938   if test "$enable_lto" = "yes" ; then
1939     case ,${enable_languages}, in
1940       *,lto,*) ;;
1941       *) enable_languages="${enable_languages},lto" ;;
1942     esac
1943     if test "${build_lto_plugin}" = "yes" ; then
1944       configdirs="$configdirs lto-plugin"
1945     fi
1946   fi
1947
1948   # If we're building an offloading compiler, add the LTO front end.
1949   if test x"$enable_as_accelerator_for" != x ; then
1950     case ,${enable_languages}, in
1951       *,lto,*) ;;
1952       *) enable_languages="${enable_languages},lto" ;;
1953     esac
1954   fi
1955
1956   missing_languages=`echo ",$enable_languages," | sed -e s/,default,/,/ -e s/,all,/,/ -e s/,c,/,/ `
1957   potential_languages=,c,
1958
1959   enabled_target_libs=
1960   disabled_target_libs=
1961
1962   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1963     case ${lang_frag} in
1964       ..) ;;
1965       # The odd quoting in the next line works around
1966       # an apparent bug in bash 1.12 on linux.
1967       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1968       *)
1969         # From the config-lang.in, get $language, $target_libs,
1970         # $lang_dirs, $boot_language, and $build_by_default
1971         language=
1972         target_libs=
1973         lang_dirs=
1974         subdir_requires=
1975         boot_language=no
1976         build_by_default=yes
1977         # set srcdir during sourcing.  See above about save & restore
1978         saved_srcdir=${srcdir}
1979         srcdir=${srcdir}/gcc . ${lang_frag}
1980         srcdir=${saved_srcdir}
1981         if test x${language} = x; then
1982           echo "${lang_frag} doesn't set \$language." 1>&2
1983           exit 1
1984         fi
1985
1986         if test "$language" = "c++"; then
1987           boot_language=yes
1988         fi
1989
1990         add_this_lang=no
1991         # C is always enabled, so no need to add it again
1992         if test "$language" != "c"; then
1993           case ,${enable_languages}, in
1994             *,${language},*)
1995               # Language was explicitly selected; include it
1996               add_this_lang=yes
1997               ;;
1998             *,all,*)
1999               # All languages are enabled
2000               add_this_lang=all
2001               ;;
2002             *,default,*)
2003               # 'default' was selected, select it if it is a default language
2004               add_this_lang=${build_by_default}
2005               ;;
2006           esac
2007         fi
2008
2009         # Disable languages that need other directories if these aren't available.
2010         for i in $subdir_requires; do
2011           test -f "$srcdir/gcc/$i/config-lang.in" && continue
2012           case ${add_this_lang} in
2013             yes)
2014               # Specifically requested language; tell them.
2015               AC_MSG_ERROR([The gcc/$i directory contains parts of $language but is missing])
2016               ;;
2017             all)
2018               AC_MSG_WARN([The gcc/$i directory contains parts of $language but is missing])
2019               add_this_lang=unsupported
2020               ;;
2021             *)
2022               # Silently disable.
2023               add_this_lang=unsupported
2024               ;;
2025           esac
2026         done
2027
2028         # Disable Ada if no preexisting GNAT is available.
2029         case ${add_this_lang}:${language}:${have_gnat} in
2030           yes:ada:no)
2031             # Specifically requested language; tell them.
2032             AC_MSG_ERROR([GNAT is required to build $language])
2033             ;;
2034           all:ada:no)
2035             AC_MSG_WARN([GNAT is required to build $language])
2036             add_this_lang=unsupported
2037             ;;
2038           *:ada:no)
2039             # Silently disable.
2040             add_this_lang=unsupported
2041             ;;
2042         esac
2043
2044         # Disable jit if -enable-host-shared not specified
2045         case ${add_this_lang}:${language}:${host_shared} in
2046           yes:jit:no)
2047             # PR jit/64780: explicitly specify --enable-host-shared
2048             AC_MSG_ERROR([
2049 Enabling language "jit" requires --enable-host-shared.
2050
2051 --enable-host-shared typically slows the rest of the compiler down by
2052 a few %, so you must explicitly enable it.
2053
2054 If you want to build both the jit and the regular compiler, it is often
2055 best to do this via two separate configure/builds, in separate
2056 directories, to avoid imposing the performance cost of
2057 --enable-host-shared on the regular compiler.])
2058             ;;
2059           all:jit:no)
2060             AC_MSG_WARN([--enable-host-shared required to build $language])
2061             add_this_lang=unsupported
2062             ;;
2063           *:jit:no)
2064             # Silently disable.
2065             add_this_lang=unsupported
2066             ;;
2067         esac
2068
2069         # Disable a language that is unsupported by the target.
2070         case "${add_this_lang}: $unsupported_languages " in
2071           no:*) ;;
2072           unsupported:*) ;;
2073           *:*" $language "*)
2074             AC_MSG_WARN([${language} not supported for this target])
2075             add_this_lang=unsupported
2076             ;;
2077         esac
2078
2079         case $add_this_lang in
2080           unsupported)
2081             # Remove language-dependent dirs.
2082             disabled_target_libs="$disabled_target_libs $target_libs"
2083             noconfigdirs="$noconfigdirs $lang_dirs"
2084             ;;
2085           no)
2086             # Remove language-dependent dirs; still show language as supported.
2087             disabled_target_libs="$disabled_target_libs $target_libs"
2088             noconfigdirs="$noconfigdirs $lang_dirs"
2089             potential_languages="${potential_languages}${language},"
2090             ;;
2091           all|yes)
2092             new_enable_languages="${new_enable_languages}${language},"
2093             potential_languages="${potential_languages}${language},"
2094             missing_languages=`echo "$missing_languages" | sed "s/,$language,/,/"`
2095             enabled_target_libs="$enabled_target_libs $target_libs"
2096             case "${boot_language}:,$enable_stage1_languages," in
2097               yes:* | *:*,$language,* | *:*,yes, | *:*,all,)
2098                 # Add to (comma-separated) list of stage 1 languages.
2099                 case ",$stage1_languages," in
2100                   *,$language,* | ,yes, | ,all,) ;;
2101                   *) stage1_languages="${stage1_languages}${language}," ;;
2102                 esac
2103                 # We need to bootstrap any supporting libraries.
2104                 bootstrap_target_libs="${bootstrap_target_libs}${target_libs},"
2105                 ;;
2106             esac
2107             ;;
2108         esac
2109         ;;
2110     esac
2111   done
2112
2113   # Add target libraries which are only needed for disabled languages
2114   # to noconfigdirs.
2115   if test -n "$disabled_target_libs"; then
2116     for dir in $disabled_target_libs; do
2117       case " $enabled_target_libs " in
2118       *" ${dir} "*) ;;
2119       *) noconfigdirs="$noconfigdirs $dir" ;;
2120       esac
2121     done
2122   fi
2123
2124   AC_ARG_ENABLE(stage1-languages,
2125   [AS_HELP_STRING([[--enable-stage1-languages[=all]]],
2126                   [choose additional languages to build during
2127                   stage1.  Mostly useful for compiler development])],
2128   [case ,${enable_stage1_languages}, in
2129     ,no,|,,)
2130       # Set it to something that will have no effect in the loop below
2131       enable_stage1_languages=c ;;
2132     ,yes,)
2133       enable_stage1_languages=`echo $new_enable_languages | \
2134         sed -e "s/^,//" -e "s/,$//" ` ;;
2135     *,all,*)
2136       enable_stage1_languages=`echo ,$enable_stage1_languages, | \
2137         sed -e "s/,all,/$new_enable_languages/" -e "s/^,//" -e "s/,$//" ` ;;
2138   esac
2139
2140   # Add "good" languages from enable_stage1_languages to stage1_languages,
2141   # while "bad" languages go in missing_languages.  Leave no duplicates.
2142   for i in `echo $enable_stage1_languages | sed 's/,/ /g' `; do
2143     case $potential_languages in
2144       *,$i,*)
2145         case $stage1_languages in
2146           *,$i,*) ;;
2147           *) stage1_languages="$stage1_languages$i," ;;
2148         esac ;;
2149       *)
2150         case $missing_languages in
2151           *,$i,*) ;;
2152           *) missing_languages="$missing_languages$i," ;;
2153         esac ;;
2154      esac
2155   done])
2156
2157   # Remove leading/trailing commas that were added for simplicity
2158   potential_languages=`echo "$potential_languages" | sed -e "s/^,//" -e "s/,$//"`
2159   missing_languages=`echo "$missing_languages" | sed -e "s/^,//" -e "s/,$//"`
2160   stage1_languages=`echo "$stage1_languages" | sed -e "s/^,//" -e "s/,$//"`
2161   new_enable_languages=`echo "$new_enable_languages" | sed -e "s/^,//" -e "s/,$//"`
2162
2163   if test "x$missing_languages" != x; then
2164     AC_MSG_ERROR([
2165 The following requested languages could not be built: ${missing_languages}
2166 Supported languages are: ${potential_languages}])
2167   fi
2168   if test "x$new_enable_languages" != "x$enable_languages"; then
2169     echo The following languages will be built: ${new_enable_languages}
2170     enable_languages="$new_enable_languages"
2171   fi
2172
2173   AC_SUBST(stage1_languages)
2174   ac_configure_args=`echo " $ac_configure_args" | sed -e "s/ '--enable-languages=[[^ ]]*'//g" -e "s/$/ '--enable-languages="$enable_languages"'/" `
2175 fi
2176
2177 # Handle --disable-<component> generically.
2178 for dir in $configdirs $build_configdirs $target_configdirs ; do
2179   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g -e s/-/_/g`
2180   varname=`echo $dirname | sed -e s/+/_/g`
2181   if eval test x\${enable_${varname}} "=" xno ; then
2182     noconfigdirs="$noconfigdirs $dir"
2183   fi
2184 done
2185
2186 # Check for Boehm's garbage collector
2187 AC_ARG_ENABLE(objc-gc,
2188 [AS_HELP_STRING([--enable-objc-gc],
2189                 [enable use of Boehm's garbage collector with the
2190                  GNU Objective-C runtime])])
2191 AC_ARG_WITH([target-bdw-gc],
2192 [AS_HELP_STRING([--with-target-bdw-gc=PATHLIST],
2193                 [specify prefix directory for installed bdw-gc package.
2194                  Equivalent to --with-target-bdw-gc-include=PATH/include
2195                  plus --with-target-bdw-gc-lib=PATH/lib])])
2196 AC_ARG_WITH([target-bdw-gc-include],
2197 [AS_HELP_STRING([--with-target-bdw-gc-include=PATHLIST],
2198                 [specify directories for installed bdw-gc include files])])
2199 AC_ARG_WITH([target-bdw-gc-lib],
2200 [AS_HELP_STRING([--with-target-bdw-gc-lib=PATHLIST],
2201                 [specify directories for installed bdw-gc library])])
2202
2203 case ,${enable_languages},:${enable_objc_gc} in *,objc,*:yes|*,objc,*:auto)
2204   AC_MSG_CHECKING([for bdw garbage collector])
2205   if test "x$with_target_bdw_gc$with_target_bdw_gc_include$with_target_bdw_gc_lib" = x; then
2206     dnl no bdw-gw options, assume default locations
2207     AC_MSG_RESULT([using bdw-gc in default locations])
2208   else
2209     dnl bdw-gw options, first error checking, complete checking in libobjc
2210     if test "x$with_target_bdw_gc_include" = x && test "x$with_target_bdw_gc_lib" != x; then
2211       AC_MSG_ERROR([found --with-target-bdw-gc-lib but --with-target-bdw-gc-include missing])
2212     elif test "x$with_target_bdw_gc_include" != x && test "x$with_target_bdw_gc_lib" = x; then
2213       AC_MSG_ERROR([found --with-target-bdw-gc-include but --with-target-bdw-gc-lib missing])
2214     else
2215       AC_MSG_RESULT([using paths configured with --with-target-bdw-gc options])
2216     fi
2217   fi
2218 esac
2219
2220 # Disable libitm, libsanitizer, libvtv, liboffloadmic if we're not building C++
2221 case ,${enable_languages}, in
2222   *,c++,*)
2223     # Disable libitm, libsanitizer if we're not building libstdc++
2224     case "${noconfigdirs}" in
2225       *target-libstdc++-v3*)
2226         noconfigdirs="$noconfigdirs target-libitm target-libsanitizer"
2227         ;;
2228       *) ;;
2229     esac
2230     ;;
2231   *)
2232     noconfigdirs="$noconfigdirs target-liboffloadmic target-libitm target-libsanitizer target-libvtv"
2233     ;;
2234 esac
2235
2236 # Remove the entries in $skipdirs and $noconfigdirs from $configdirs,
2237 # $build_configdirs and $target_configdirs.
2238 # If we have the source for $noconfigdirs entries, add them to $notsupp.
2239
2240 notsupp=""
2241 for dir in . $skipdirs $noconfigdirs ; do
2242   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g`
2243   if test $dir != .  && echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2244     configdirs=`echo " ${configdirs} " | sed -e "s/ ${dir} / /"`
2245     if test -r $srcdir/$dirname/configure ; then
2246       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2247         true
2248       else
2249         notsupp="$notsupp $dir"
2250       fi
2251     fi
2252   fi
2253   if test $dir != .  && echo " ${build_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2254     build_configdirs=`echo " ${build_configdirs} " | sed -e "s/ ${dir} / /"`
2255     if test -r $srcdir/$dirname/configure ; then
2256       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2257         true
2258       else
2259         notsupp="$notsupp $dir"
2260       fi
2261     fi
2262   fi
2263   if test $dir != . && echo " ${target_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2264     target_configdirs=`echo " ${target_configdirs} " | sed -e "s/ ${dir} / /"`
2265     if test -r $srcdir/$dirname/configure ; then
2266       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2267         true
2268       else
2269         notsupp="$notsupp $dir"
2270       fi
2271     fi
2272   fi
2273 done
2274
2275 # Quietly strip out all directories which aren't configurable in this tree.
2276 # This relies on all configurable subdirectories being autoconfiscated, which
2277 # is now the case.
2278 build_configdirs_all="$build_configdirs"
2279 build_configdirs=
2280 for i in ${build_configdirs_all} ; do
2281   j=`echo $i | sed -e s/build-//g`
2282   if test -f ${srcdir}/$j/configure ; then
2283     build_configdirs="${build_configdirs} $i"
2284   fi
2285 done
2286
2287 configdirs_all="$configdirs"
2288 configdirs=
2289 for i in ${configdirs_all} ; do
2290   if test -f ${srcdir}/$i/configure ; then
2291     configdirs="${configdirs} $i"
2292   fi
2293 done
2294
2295 target_configdirs_all="$target_configdirs"
2296 target_configdirs=
2297 for i in ${target_configdirs_all} ; do
2298   j=`echo $i | sed -e s/target-//g`
2299   if test -f ${srcdir}/$j/configure ; then
2300     target_configdirs="${target_configdirs} $i"
2301   fi
2302 done
2303
2304 # libiberty-linker-plugin is special: it doesn't have its own source directory,
2305 # so we have to add it after the preceding checks.
2306 if test x"$extra_linker_plugin_flags$extra_linker_plugin_configure_flags" != x
2307 then
2308   case " $configdirs " in
2309     *" libiberty "*)
2310       # If we can build libiberty, we can also build libiberty-linker-plugin.
2311       configdirs="$configdirs libiberty-linker-plugin"
2312       extra_linker_plugin_configure_flags="$extra_linker_plugin_configure_flags \
2313         --with-libiberty=../libiberty-linker-plugin";;
2314     *)
2315       AC_MSG_ERROR([libiberty missing]);;
2316   esac
2317 fi
2318
2319 # Sometimes we have special requirements for the host libiberty.
2320 extra_host_libiberty_configure_flags=
2321 extra_host_zlib_configure_flags=
2322 case " $configdirs " in
2323   *" lto-plugin "* | *" libcc1 "*)
2324     # When these are to be built as shared libraries, the same applies to
2325     # libiberty.
2326     extra_host_libiberty_configure_flags=--enable-shared
2327     ;;
2328   *" bfd "*)
2329     # When bfd is to be built as a shared library, the same applies to
2330     # zlib.
2331     if test "$enable_shared" = "yes"; then
2332       extra_host_zlib_configure_flags=--enable-host-shared
2333     fi
2334     ;;
2335 esac
2336 AC_SUBST(extra_host_libiberty_configure_flags)
2337 AC_SUBST(extra_host_zlib_configure_flags)
2338
2339 # Produce a warning message for the subdirs we can't configure.
2340 # This isn't especially interesting in the Cygnus tree, but in the individual
2341 # FSF releases, it's important to let people know when their machine isn't
2342 # supported by the one or two programs in a package.
2343
2344 if test -n "${notsupp}" && test -z "${norecursion}" ; then
2345   # If $appdirs is non-empty, at least one of those directories must still
2346   # be configured, or we error out.  (E.g., if the gas release supports a
2347   # specified target in some subdirs but not the gas subdir, we shouldn't
2348   # pretend that all is well.)
2349   if test -n "$appdirs" ; then
2350     for dir in $appdirs ; do
2351       if test -r $dir/Makefile.in ; then
2352         if echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2353           appdirs=""
2354           break
2355         fi
2356         if echo " ${target_configdirs} " | grep " target-${dir} " >/dev/null 2>&1; then
2357           appdirs=""
2358           break
2359         fi
2360       fi
2361     done
2362     if test -n "$appdirs" ; then
2363       echo "*** This configuration is not supported by this package." 1>&2
2364       exit 1
2365     fi
2366   fi
2367   # Okay, some application will build, or we don't care to check.  Still
2368   # notify of subdirs not getting built.
2369   echo "*** This configuration is not supported in the following subdirectories:" 1>&2
2370   echo "    ${notsupp}" 1>&2
2371   echo "    (Any other directories should still work fine.)" 1>&2
2372 fi
2373
2374 case "$host" in
2375   *msdosdjgpp*)
2376     enable_gdbtk=no ;;
2377 esac
2378
2379 # To find our prefix, in gcc_cv_tool_prefix.
2380 ACX_TOOL_DIRS
2381
2382 copy_dirs=
2383
2384 AC_ARG_WITH([build-sysroot],
2385   [AS_HELP_STRING([--with-build-sysroot=SYSROOT],
2386                   [use sysroot as the system root during the build])],
2387   [if test x"$withval" != x ; then
2388      SYSROOT_CFLAGS_FOR_TARGET="--sysroot=$withval"
2389    fi],
2390   [SYSROOT_CFLAGS_FOR_TARGET=])
2391 AC_SUBST(SYSROOT_CFLAGS_FOR_TARGET)
2392
2393 AC_ARG_WITH([debug-prefix-map],
2394   [AS_HELP_STRING([--with-debug-prefix-map='A=B C=D ...'],
2395                   [map A to B, C to D ... in debug information])],
2396   [if test x"$withval" != x; then
2397      DEBUG_PREFIX_CFLAGS_FOR_TARGET=
2398      for debug_map in $withval; do
2399        DEBUG_PREFIX_CFLAGS_FOR_TARGET="$DEBUG_PREFIX_CFLAGS_FOR_TARGET -fdebug-prefix-map=$debug_map"
2400      done
2401    fi],
2402   [DEBUG_PREFIX_CFLAGS_FOR_TARGET=])
2403 AC_SUBST(DEBUG_PREFIX_CFLAGS_FOR_TARGET)
2404
2405 # During gcc bootstrap, if we use some random cc for stage1 then CFLAGS
2406 # might be empty or "-g".  We don't require a C++ compiler, so CXXFLAGS
2407 # might also be empty (or "-g", if a non-GCC C++ compiler is in the path).
2408 # We want to ensure that TARGET libraries (which we know are built with
2409 # gcc) are built with "-O2 -g", so include those options when setting
2410 # CFLAGS_FOR_TARGET and CXXFLAGS_FOR_TARGET.
2411 if test "x$CFLAGS_FOR_TARGET" = x; then
2412   if test "x${is_cross_compiler}" = xyes; then
2413     CFLAGS_FOR_TARGET="-g -O2"
2414   else
2415     CFLAGS_FOR_TARGET=$CFLAGS
2416     case " $CFLAGS " in
2417       *" -O2 "*) ;;
2418       *) CFLAGS_FOR_TARGET="-O2 $CFLAGS_FOR_TARGET" ;;
2419     esac
2420     case " $CFLAGS " in
2421       *" -g "* | *" -g3 "*) ;;
2422       *) CFLAGS_FOR_TARGET="-g $CFLAGS_FOR_TARGET" ;;
2423     esac
2424   fi
2425 fi
2426 AC_SUBST(CFLAGS_FOR_TARGET)
2427
2428 if test "x$CXXFLAGS_FOR_TARGET" = x; then
2429   if test "x${is_cross_compiler}" = xyes; then
2430     CXXFLAGS_FOR_TARGET="-g -O2"
2431   else
2432     CXXFLAGS_FOR_TARGET=$CXXFLAGS
2433     case " $CXXFLAGS " in
2434       *" -O2 "*) ;;
2435       *) CXXFLAGS_FOR_TARGET="-O2 $CXXFLAGS_FOR_TARGET" ;;
2436     esac
2437     case " $CXXFLAGS " in
2438       *" -g "* | *" -g3 "*) ;;
2439       *) CXXFLAGS_FOR_TARGET="-g $CXXFLAGS_FOR_TARGET" ;;
2440     esac
2441   fi
2442 fi
2443 AC_SUBST(CXXFLAGS_FOR_TARGET)
2444
2445 AC_SUBST(LDFLAGS_FOR_TARGET)
2446
2447 # Handle --with-headers=XXX.  If the value is not "yes", the contents of
2448 # the named directory are copied to $(tooldir)/sys-include.
2449 if test x"${with_headers}" != x && test x"${with_headers}" != xno ; then
2450   if test x${is_cross_compiler} = xno ; then
2451     echo 1>&2 '***' --with-headers is only supported when cross compiling
2452     exit 1
2453   fi
2454   if test x"${with_headers}" != xyes ; then
2455     x=${gcc_cv_tool_prefix}
2456     copy_dirs="${copy_dirs} ${with_headers} $x/${target_noncanonical}/sys-include"
2457   fi
2458 fi
2459
2460 # Handle --with-libs=XXX.  If the value is not "yes", the contents of
2461 # the name directories are copied to $(tooldir)/lib.  Multiple directories
2462 # are permitted.
2463 if test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
2464   if test x${is_cross_compiler} = xno ; then
2465     echo 1>&2 '***' --with-libs is only supported when cross compiling
2466     exit 1
2467   fi
2468   if test x"${with_libs}" != xyes ; then
2469     # Copy the libraries in reverse order, so that files in the first named
2470     # library override files in subsequent libraries.
2471     x=${gcc_cv_tool_prefix}
2472     for l in ${with_libs}; do
2473       copy_dirs="$l $x/${target_noncanonical}/lib ${copy_dirs}"
2474     done
2475   fi
2476 fi
2477
2478 # Set with_gnu_as, with_gnu_ld, and with_system_zlib as appropriate.
2479 #
2480 # This is done by determining whether or not the appropriate directory
2481 # is available, and by checking whether or not specific configurations
2482 # have requested that this magic not happen.
2483 #
2484 # The command line options always override the explicit settings in
2485 # configure.ac, and the settings in configure.ac override this magic.
2486 #
2487 # If the default for a toolchain is to use GNU as and ld, and you don't
2488 # want to do that, then you should use the --without-gnu-as and
2489 # --without-gnu-ld options for the configure script.  Similarly, if
2490 # the default is to use the included zlib and you don't want to do that,
2491 # you should use the --with-system-zlib option for the configure script.
2492
2493 if test x${use_gnu_as} = x &&
2494    echo " ${configdirs} " | grep " gas " > /dev/null 2>&1 ; then
2495   with_gnu_as=yes
2496   extra_host_args="$extra_host_args --with-gnu-as"
2497 fi
2498
2499 if test x${use_gnu_ld} = x &&
2500    echo " ${configdirs} " | egrep " (go)?ld " > /dev/null 2>&1 ; then
2501   with_gnu_ld=yes
2502   extra_host_args="$extra_host_args --with-gnu-ld"
2503 fi
2504
2505 if test x${use_included_zlib} = x &&
2506    echo " ${configdirs} " | grep " zlib " > /dev/null 2>&1 ; then
2507   :
2508 else
2509   with_system_zlib=yes
2510   extra_host_args="$extra_host_args --with-system-zlib"
2511 fi
2512
2513 # If using newlib, add --with-newlib to the extra_host_args so that gcc/configure
2514 # can detect this case.
2515
2516 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " target-newlib " > /dev/null 2>&1 ; then
2517   with_newlib=yes
2518   extra_host_args="$extra_host_args --with-newlib"
2519 fi
2520
2521 # Handle ${copy_dirs}
2522 set fnord ${copy_dirs}
2523 shift
2524 while test $# != 0 ; do
2525   if test -f $2/COPIED && test x"`cat $2/COPIED`" = x"$1" ; then
2526     :
2527   else
2528     echo Copying $1 to $2
2529
2530     # Use the install script to create the directory and all required
2531     # parent directories.
2532     if test -d $2 ; then
2533       :
2534     else
2535       echo >config.temp
2536       ${srcdir}/install-sh -c -m 644 config.temp $2/COPIED
2537     fi
2538
2539     # Copy the directory, assuming we have tar.
2540     # FIXME: Should we use B in the second tar?  Not all systems support it.
2541     (cd $1; tar -cf - .) | (cd $2; tar -xpf -)
2542
2543     # It is the responsibility of the user to correctly adjust all
2544     # symlinks.  If somebody can figure out how to handle them correctly
2545     # here, feel free to add the code.
2546
2547     echo $1 > $2/COPIED
2548   fi
2549   shift; shift
2550 done
2551
2552 # Determine a target-dependent exec_prefix that the installed
2553 # gcc will search in.  Keep this list sorted by triplet, with
2554 # the *-*-osname triplets last.
2555 md_exec_prefix=
2556 case "${target}" in
2557   i[[34567]]86-pc-msdosdjgpp*)
2558     md_exec_prefix=/dev/env/DJDIR/bin
2559     ;;
2560   *-*-hpux* | \
2561   *-*-nto-qnx* | \
2562   *-*-solaris2*)
2563     md_exec_prefix=/usr/ccs/bin
2564     ;;
2565 esac
2566
2567 extra_arflags_for_target=
2568 extra_nmflags_for_target=
2569 extra_ranlibflags_for_target=
2570 target_makefile_frag=/dev/null
2571 case "${target}" in
2572   spu-*-*)
2573     target_makefile_frag="config/mt-spu"
2574     ;;
2575   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
2576     target_makefile_frag="config/mt-sde"
2577     ;;
2578   mipsisa*-*-elfoabi*)
2579     target_makefile_frag="config/mt-mips-elfoabi"
2580     ;;
2581   mips*-*-*linux* | mips*-*-gnu*)
2582     target_makefile_frag="config/mt-mips-gnu"
2583     ;;
2584   nios2-*-elf*)
2585     target_makefile_frag="config/mt-nios2-elf"
2586     ;;
2587   *-*-linux-android*)
2588     target_makefile_frag="config/mt-android"
2589     ;;
2590   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
2591     target_makefile_frag="config/mt-gnu"
2592     ;;
2593   *-*-aix4.[[3456789]]* | *-*-aix[[56789]].*)
2594     # nm and ar from AIX 4.3 and above require -X32_64 flag to all ar and nm
2595     # commands to handle both 32-bit and 64-bit objects.  These flags are
2596     # harmless if we're using GNU nm or ar.
2597     extra_arflags_for_target=" -X32_64"
2598     extra_nmflags_for_target=" -B -X32_64"
2599     ;;
2600 esac
2601
2602 alphaieee_frag=/dev/null
2603 case $target in
2604   alpha*-*-*)
2605     # This just makes sure to use the -mieee option to build target libs.
2606     # This should probably be set individually by each library.
2607     alphaieee_frag="config/mt-alphaieee"
2608     ;;
2609 esac
2610
2611 # If --enable-target-optspace always use -Os instead of -O2 to build
2612 # the target libraries, similarly if it is not specified, use -Os
2613 # on selected platforms.
2614 ospace_frag=/dev/null
2615 case "${enable_target_optspace}:${target}" in
2616   yes:*)
2617     ospace_frag="config/mt-ospace"
2618     ;;
2619   :d30v-*)
2620     ospace_frag="config/mt-d30v"
2621     ;;
2622   :m32r-* | :d10v-* | :fr30-* | :i?86*-*-elfiamcu)
2623     ospace_frag="config/mt-ospace"
2624     ;;
2625   no:* | :*)
2626     ;;
2627   *)
2628     echo "*** bad value \"${enable_target_optspace}\" for --enable-target-optspace flag; ignored" 1>&2
2629     ;;
2630 esac
2631
2632 # Some systems (e.g., one of the i386-aix systems the gas testers are
2633 # using) don't handle "\$" correctly, so don't use it here.
2634 tooldir='${exec_prefix}'/${target_noncanonical}
2635 build_tooldir=${tooldir}
2636
2637 # Create a .gdbinit file which runs the one in srcdir
2638 # and tells GDB to look there for source files.
2639
2640 if test -r ${srcdir}/.gdbinit ; then
2641   case ${srcdir} in
2642     .) ;;
2643     *) cat > ./.gdbinit <<EOF
2644 # ${NO_EDIT}
2645 dir ${srcdir}
2646 dir .
2647 source ${srcdir}/.gdbinit
2648 EOF
2649     ;;
2650   esac
2651 fi
2652
2653 # Make sure that the compiler is able to generate an executable.  If it
2654 # can't, we are probably in trouble.  We don't care whether we can run the
2655 # executable--we might be using a cross compiler--we only care whether it
2656 # can be created.  At this point the main configure script has set CC.
2657 we_are_ok=no
2658 echo "int main () { return 0; }" > conftest.c
2659 ${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
2660 if test $? = 0 ; then
2661   if test -s conftest || test -s conftest.exe ; then
2662     we_are_ok=yes
2663   fi
2664 fi
2665 case $we_are_ok in
2666   no)
2667     echo 1>&2 "*** The command '${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c' failed."
2668     echo 1>&2 "*** You must set the environment variable CC to a working compiler."
2669     rm -f conftest*
2670     exit 1
2671     ;;
2672 esac
2673 rm -f conftest*
2674
2675 # Decide which environment variable is used to find dynamic libraries.
2676 case "${host}" in
2677   *-*-hpux*) RPATH_ENVVAR=SHLIB_PATH ;;
2678   *-*-darwin*) RPATH_ENVVAR=DYLD_LIBRARY_PATH ;;
2679   *-*-mingw* | *-*-cygwin ) RPATH_ENVVAR=PATH ;;
2680   *) RPATH_ENVVAR=LD_LIBRARY_PATH ;;
2681 esac
2682
2683 # On systems where the dynamic library environment variable is PATH,
2684 # gcc/ will put dynamic libraries into a subdirectory to avoid adding
2685 # built executables to PATH.
2686 if test "$RPATH_ENVVAR" = PATH; then
2687   GCC_SHLIB_SUBDIR=/shlib
2688 else
2689   GCC_SHLIB_SUBDIR=
2690 fi
2691
2692 # Adjust the toplevel makefile according to whether bootstrap was selected.
2693 case $enable_bootstrap in
2694   yes)
2695     bootstrap_suffix=bootstrap
2696     BUILD_CONFIG=bootstrap-debug
2697     ;;
2698   no)
2699     bootstrap_suffix=no-bootstrap
2700     BUILD_CONFIG=
2701     ;;
2702 esac
2703
2704 AC_MSG_CHECKING(for default BUILD_CONFIG)
2705
2706 AC_ARG_WITH([build-config],
2707   [AS_HELP_STRING([--with-build-config='NAME NAME2...'],
2708                   [use config/NAME.mk build configuration])],
2709   [case $with_build_config in
2710    yes) with_build_config= ;;
2711    no) with_build_config= BUILD_CONFIG= ;;
2712    esac])
2713
2714 if test "x${with_build_config}" != x; then
2715   BUILD_CONFIG=$with_build_config
2716 else
2717   case $BUILD_CONFIG in
2718   bootstrap-debug)
2719     if echo "int f (void) { return 0; }" > conftest.c &&
2720        ${CC} -c conftest.c &&
2721        mv conftest.o conftest.o.g0 &&
2722        ${CC} -c -g conftest.c &&
2723        mv conftest.o conftest.o.g &&
2724        ${srcdir}/contrib/compare-debug conftest.o.g0 conftest.o.g > /dev/null 2>&1; then
2725       :
2726     else
2727       BUILD_CONFIG=
2728     fi
2729     rm -f conftest.c conftest.o conftest.o.g0 conftest.o.g
2730     ;;
2731   esac
2732 fi
2733 AC_MSG_RESULT($BUILD_CONFIG)
2734 AC_SUBST(BUILD_CONFIG)
2735
2736 # Use same top-level configure hooks in libgcc/libstdc++/libvtv.
2737 AC_MSG_CHECKING([for --enable-vtable-verify])
2738 AC_ARG_ENABLE(vtable-verify,
2739 [AS_HELP_STRING([--enable-vtable-verify],
2740                 [Enable vtable verification feature])],
2741 [case "$enableval" in
2742  yes) enable_vtable_verify=yes ;;
2743  no)  enable_vtable_verify=no ;;
2744  *)   enable_vtable_verify=no;;
2745  esac],
2746 [enable_vtable_verify=no])
2747 AC_MSG_RESULT($enable_vtable_verify)
2748
2749 # Record target_configdirs and the configure arguments for target and
2750 # build configuration in Makefile.
2751 target_configdirs=`echo "${target_configdirs}" | sed -e 's/target-//g'`
2752 build_configdirs=`echo "${build_configdirs}" | sed -e 's/build-//g'`
2753 bootstrap_fixincludes=no
2754
2755 # If we are building libgomp, bootstrap it.
2756 if echo " ${target_configdirs} " | grep " libgomp " > /dev/null 2>&1 ; then
2757   bootstrap_target_libs=${bootstrap_target_libs}target-libgomp,
2758 fi
2759
2760 # If we are building libsanitizer and $BUILD_CONFIG contains bootstrap-asan
2761 # or bootstrap-ubsan, bootstrap it.
2762 if echo " ${target_configdirs} " | grep " libsanitizer " > /dev/null 2>&1; then
2763   case "$BUILD_CONFIG" in
2764     *bootstrap-asan* | *bootstrap-ubsan* )
2765       bootstrap_target_libs=${bootstrap_target_libs}target-libsanitizer,
2766       bootstrap_fixincludes=yes
2767       ;;
2768   esac
2769 fi
2770
2771 # If we are building libvtv and --enable-vtable-verify, bootstrap it.
2772 if echo " ${target_configdirs} " | grep " libvtv " > /dev/null 2>&1 &&
2773    test "$enable_vtable_verify" != no; then
2774   bootstrap_target_libs=${bootstrap_target_libs}target-libvtv,
2775 fi
2776
2777 # Determine whether gdb needs tk/tcl or not.
2778 # Use 'maybe' since enable_gdbtk might be true even if tk isn't available
2779 # and in that case we want gdb to be built without tk.  Ugh!
2780 # In fact I believe gdb is the *only* package directly dependent on tk,
2781 # so we should be able to put the 'maybe's in unconditionally and
2782 # leave out the maybe dependencies when enable_gdbtk is false.  I'm not
2783 # 100% sure that that's safe though.
2784
2785 gdb_tk="maybe-all-tcl maybe-all-tk maybe-all-itcl maybe-all-libgui"
2786 case "$enable_gdbtk" in
2787   no)
2788     GDB_TK="" ;;
2789   yes)
2790     GDB_TK="${gdb_tk}" ;;
2791   *)
2792     # Only add the dependency on gdbtk when GDBtk is part of the gdb
2793     # distro.  Eventually someone will fix this and move Insight, nee
2794     # gdbtk to a separate directory.
2795     if test -d ${srcdir}/gdb/gdbtk ; then
2796       GDB_TK="${gdb_tk}"
2797     else
2798       GDB_TK=""
2799     fi
2800     ;;
2801 esac
2802 CONFIGURE_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-configure-/g`
2803 INSTALL_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-install-/g`
2804
2805 # gdb and gdbserver depend on gnulib and gdbsupport, but as nothing
2806 # else does, only include them if one of these is built.  The Makefile
2807 # provides the ordering, so it's enough here to add to the list.
2808 case " ${configdirs} " in
2809   *\ gdb\ *)
2810     configdirs="${configdirs} gnulib gdbsupport"
2811     ;;
2812   *\ gdbserver\ *)
2813     configdirs="${configdirs} gnulib gdbsupport"
2814     ;;
2815 esac
2816
2817 # Strip out unwanted targets.
2818
2819 # While at that, we remove Makefiles if we were started for recursive
2820 # configuration, so that the top-level Makefile reconfigures them,
2821 # like we used to do when configure itself was recursive.
2822
2823 # Loop over modules.  We used to use the "$extrasub" feature from Autoconf
2824 # but now we're fixing up the Makefile ourselves with the additional
2825 # commands passed to AC_CONFIG_FILES.  Use separate variables
2826 # extrasub-{build,host,target} not because there is any reason to split
2827 # the substitutions up that way, but only to remain below the limit of
2828 # 99 commands in a script, for HP-UX sed.
2829
2830 # Do not nest @if/@endif or @unless/@endunless pairs, because
2831 # configure will not warn you at all.
2832
2833 case "$enable_bootstrap:$ENABLE_GOLD: $configdirs :,$stage1_languages," in
2834   yes:yes:*\ gold\ *:*,c++,*) ;;
2835   yes:yes:*\ gold\ *:*)
2836     AC_MSG_ERROR([in a combined tree, bootstrapping with --enable-gold requires c++ in stage1_languages])
2837     ;;
2838 esac
2839
2840 extrasub_build=
2841 for module in ${build_configdirs} ; do
2842   if test -z "${no_recursion}" \
2843      && test -f ${build_subdir}/${module}/Makefile; then
2844     echo 1>&2 "*** removing ${build_subdir}/${module}/Makefile to force reconfigure"
2845     rm -f ${build_subdir}/${module}/Makefile
2846   fi
2847   extrasub_build="$extrasub_build
2848 /^@if build-$module\$/d
2849 /^@endif build-$module\$/d
2850 /^@unless build-$module\$/,/^@endunless build-$module\$/d
2851 /^@if build-$module-$bootstrap_suffix\$/d
2852 /^@endif build-$module-$bootstrap_suffix\$/d
2853 /^@unless build-$module-$bootstrap_suffix\$/,/^@endunless build-$module-$bootstrap_suffix\$/d"
2854 done
2855 extrasub_host=
2856 for module in ${configdirs} ; do
2857   if test -z "${no_recursion}"; then
2858     for file in stage*-${module}/Makefile prev-${module}/Makefile ${module}/Makefile; do
2859       if test -f ${file}; then
2860         echo 1>&2 "*** removing ${file} to force reconfigure"
2861         rm -f ${file}
2862       fi
2863     done
2864   fi
2865   case ${module},${bootstrap_fixincludes} in
2866     fixincludes,no) host_bootstrap_suffix=no-bootstrap ;;
2867     *) host_bootstrap_suffix=$bootstrap_suffix ;;
2868   esac
2869   extrasub_host="$extrasub_host
2870 /^@if $module\$/d
2871 /^@endif $module\$/d
2872 /^@unless $module\$/,/^@endunless $module\$/d
2873 /^@if $module-$host_bootstrap_suffix\$/d
2874 /^@endif $module-$host_bootstrap_suffix\$/d
2875 /^@unless $module-$host_bootstrap_suffix\$/,/^@endunless $module-$host_bootstrap_suffix\$/d"
2876 done
2877 extrasub_target=
2878 for module in ${target_configdirs} ; do
2879   if test -z "${no_recursion}" \
2880      && test -f ${target_subdir}/${module}/Makefile; then
2881     echo 1>&2 "*** removing ${target_subdir}/${module}/Makefile to force reconfigure"
2882     rm -f ${target_subdir}/${module}/Makefile
2883   fi
2884
2885   # We only bootstrap target libraries listed in bootstrap_target_libs.
2886   case $bootstrap_target_libs in
2887     *,target-$module,*) target_bootstrap_suffix=$bootstrap_suffix ;;
2888     *) target_bootstrap_suffix=no-bootstrap ;;
2889   esac
2890
2891   extrasub_target="$extrasub_target
2892 /^@if target-$module\$/d
2893 /^@endif target-$module\$/d
2894 /^@unless target-$module\$/,/^@endunless target-$module\$/d
2895 /^@if target-$module-$target_bootstrap_suffix\$/d
2896 /^@endif target-$module-$target_bootstrap_suffix\$/d
2897 /^@unless target-$module-$target_bootstrap_suffix\$/,/^@endunless target-$module-$target_bootstrap_suffix\$/d"
2898 done
2899
2900 # Do the final fixup along with target modules.
2901 extrasub_target="$extrasub_target
2902 /^@if /,/^@endif /d
2903 /^@unless /d
2904 /^@endunless /d"
2905
2906 if test "$enable_pgo_build" != "no"; then
2907   extrasub_build="$extrasub_build
2908 /^@if pgo-build\$/d
2909 /^@endif pgo-build\$/d"
2910 fi
2911
2912 # Create the serialization dependencies.  This uses a temporary file.
2913
2914 AC_ARG_ENABLE([serial-configure],
2915 [AS_HELP_STRING([[--enable-serial-[{host,target,build}-]configure]],
2916                 [force sequential configuration of
2917                  sub-packages for the host, target or build
2918                  machine, or all sub-packages])])
2919
2920 case ${enable_serial_configure} in
2921   yes)
2922     enable_serial_build_configure=yes
2923     enable_serial_host_configure=yes
2924     enable_serial_target_configure=yes
2925     ;;
2926 esac
2927
2928 # These force 'configure's to be done one at a time, to avoid problems
2929 # with contention over a shared config.cache.
2930 rm -f serdep.tmp
2931 echo '# serdep.tmp' > serdep.tmp
2932 olditem=
2933 test "x${enable_serial_build_configure}" = xyes &&
2934 for item in ${build_configdirs} ; do
2935   case ${olditem} in
2936     "") ;;
2937     *) echo "configure-build-${item}: configure-build-${olditem}" >> serdep.tmp ;;
2938   esac
2939   olditem=${item}
2940 done
2941 olditem=
2942 test "x${enable_serial_host_configure}" = xyes &&
2943 for item in ${configdirs} ; do
2944   case ${olditem} in
2945     "") ;;
2946     *) echo "configure-${item}: configure-${olditem}" >> serdep.tmp ;;
2947   esac
2948   olditem=${item}
2949 done
2950 olditem=
2951 test "x${enable_serial_target_configure}" = xyes &&
2952 for item in ${target_configdirs} ; do
2953   case ${olditem} in
2954     "") ;;
2955     *) echo "configure-target-${item}: configure-target-${olditem}" >> serdep.tmp ;;
2956   esac
2957   olditem=${item}
2958 done
2959 serialization_dependencies=serdep.tmp
2960 AC_SUBST_FILE(serialization_dependencies)
2961
2962 # Base args.  Strip norecursion, cache-file, srcdir, host, build,
2963 # target, nonopt, and variable assignments.  These are the ones we
2964 # might not want to pass down to subconfigures.  The exception being
2965 # --cache-file=/dev/null, which is used to turn off the use of cache
2966 # files altogether, and which should be passed on to subconfigures.
2967 # Also strip program-prefix, program-suffix, and program-transform-name,
2968 # so that we can pass down a consistent program-transform-name.
2969 baseargs=
2970 tbaseargs=
2971 keep_next=no
2972 skip_next=no
2973 eval "set -- $ac_configure_args"
2974 for ac_arg
2975 do
2976   if test X"$skip_next" = X"yes"; then
2977     skip_next=no
2978     continue
2979   fi
2980   if test X"$keep_next" = X"yes"; then
2981     case $ac_arg in
2982       *\'*)
2983         ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
2984     esac
2985     baseargs="$baseargs '$ac_arg'"
2986     tbaseargs="$tbaseargs '$ac_arg'"
2987     keep_next=no
2988     continue
2989   fi
2990
2991   # Handle separated arguments.  Based on the logic generated by
2992   # autoconf 2.59.
2993   case $ac_arg in
2994     *=* | --config-cache | -C | -disable-* | --disable-* \
2995       | -enable-* | --enable-* | -gas | --g* | -nfp | --nf* \
2996       | -q | -quiet | --q* | -silent | --sil* | -v | -verb* \
2997       | -with-* | --with-* | -without-* | --without-* | --x)
2998       separate_arg=no
2999       ;;
3000     -*)
3001       separate_arg=yes
3002       ;;
3003     *)
3004       separate_arg=no
3005       ;;
3006   esac
3007
3008   skip_targ=no
3009   case $ac_arg in
3010 changequote(,)
3011   --with-* | --without-*)
3012     libopt=`echo "$ac_arg" | sed -e 's,^--[^-_]*[-_],,' -e 's,=.*$,,'`
3013
3014     case $libopt in
3015     *[-_]include)
3016       lib=`echo "$libopt" | sed 's,[-_]include$,,'`
3017       ;;
3018     *[-_]lib)
3019       lib=`echo "$libopt" | sed 's,[-_]lib$,,'`
3020       ;;
3021     *)
3022       lib=$libopt
3023       ;;
3024     esac
3025 changequote([,])
3026
3027     case $lib in
3028     mpc | mpfr | gmp | isl)
3029       # If we're processing --with-$lib, --with-$lib-include or
3030       # --with-$lib-lib, for one of the libs above, and target is
3031       # different from host, don't pass the current argument to any
3032       # target library's configure.
3033       if test x$is_cross_compiler = xyes; then
3034         skip_targ=yes
3035       fi
3036       ;;
3037     esac
3038     ;;
3039   esac
3040
3041   case "$ac_arg" in
3042     --cache-file=/dev/null | \
3043     -cache-file=/dev/null )
3044       # Handled here to avoid the test to skip args below.
3045       baseargs="$baseargs '$ac_arg'"
3046       tbaseargs="$tbaseargs '$ac_arg'"
3047       # Assert: $separate_arg should always be no.
3048       keep_next=$separate_arg
3049       ;;
3050     --no*)
3051       continue
3052       ;;
3053     --c* | \
3054     --sr* | \
3055     --ho* | \
3056     --bu* | \
3057     --t* | \
3058     --program-* | \
3059     -cache_file* | \
3060     -srcdir* | \
3061     -host* | \
3062     -build* | \
3063     -target* | \
3064     -program-prefix* | \
3065     -program-suffix* | \
3066     -program-transform-name* )
3067       skip_next=$separate_arg
3068       continue
3069       ;;
3070     -*)
3071       # An option.  Add it.
3072       case $ac_arg in
3073         *\'*)
3074           ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
3075       esac
3076       baseargs="$baseargs '$ac_arg'"
3077       if test X"$skip_targ" = Xno; then
3078         tbaseargs="$tbaseargs '$ac_arg'"
3079       fi
3080       keep_next=$separate_arg
3081       ;;
3082     *)
3083       # Either a variable assignment, or a nonopt (triplet).  Don't
3084       # pass it down; let the Makefile handle this.
3085       continue
3086       ;;
3087   esac
3088 done
3089 # Remove the initial space we just introduced and, as these will be
3090 # expanded by make, quote '$'.
3091 baseargs=`echo "x$baseargs" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
3092
3093 # Add in --program-transform-name, after --program-prefix and
3094 # --program-suffix have been applied to it.  Autoconf has already
3095 # doubled dollar signs and backslashes in program_transform_name; we want
3096 # the backslashes un-doubled, and then the entire thing wrapped in single
3097 # quotes, because this will be expanded first by make and then by the shell.
3098 # Also, because we want to override the logic in subdir configure scripts to
3099 # choose program_transform_name, replace any s,x,x, with s,y,y,.
3100 sed -e "s,\\\\\\\\,\\\\,g; s,','\\\\'',g; s/s,x,x,/s,y,y,/" <<EOF_SED > conftestsed.out
3101 ${program_transform_name}
3102 EOF_SED
3103 gcc_transform_name=`cat conftestsed.out`
3104 rm -f conftestsed.out
3105 baseargs="$baseargs --program-transform-name='${gcc_transform_name}'"
3106 tbaseargs="$tbaseargs --program-transform-name='${gcc_transform_name}'"
3107 if test "$silent" = yes; then
3108   baseargs="$baseargs --silent"
3109   tbaseargs="$tbaseargs --silent"
3110 fi
3111 baseargs="$baseargs --disable-option-checking"
3112 tbaseargs="$tbaseargs --disable-option-checking"
3113
3114 # Record and document user additions to sub configure arguments.
3115 AC_ARG_VAR([build_configargs],
3116            [additional configure arguments for build directories])
3117 AC_ARG_VAR([host_configargs],
3118            [additional configure arguments for host directories])
3119 AC_ARG_VAR([target_configargs],
3120            [additional configure arguments for target directories])
3121
3122 # For the build-side libraries, we just need to pretend we're native,
3123 # and not use the same cache file.  Multilibs are neither needed nor
3124 # desired.  We can't even use the same cache file for all build-side
3125 # libraries, as they're compiled differently; some with C, some with
3126 # C++ or with different feature-enabling options.
3127 build_configargs="$build_configargs --cache-file=./config.cache ${baseargs}"
3128
3129 # For host modules, accept cache file option, or specification as blank.
3130 case "${cache_file}" in
3131 "") # empty
3132   cache_file_option="" ;;
3133 /* | [[A-Za-z]]:[[\\/]]* ) # absolute path
3134   cache_file_option="--cache-file=${cache_file}" ;;
3135 *) # relative path
3136   cache_file_option="--cache-file=../${cache_file}" ;;
3137 esac
3138
3139 # Host dirs don't like to share a cache file either, horribly enough.
3140 # This seems to be due to autoconf 2.5x stupidity.
3141 host_configargs="$host_configargs --cache-file=./config.cache ${extra_host_args} ${baseargs}"
3142
3143 target_configargs="$target_configargs ${tbaseargs}"
3144
3145 # Passing a --with-cross-host argument lets the target libraries know
3146 # whether they are being built with a cross-compiler or being built
3147 # native.  However, it would be better to use other mechanisms to make the
3148 # sorts of decisions they want to make on this basis.  Please consider
3149 # this option to be deprecated.  FIXME.
3150 if test x${is_cross_compiler} = xyes ; then
3151   target_configargs="--with-cross-host=${host_noncanonical} ${target_configargs}"
3152 fi
3153
3154 # Special user-friendly check for native x86_64-linux build, if
3155 # multilib is not explicitly enabled.
3156 case "$target:$have_compiler:$host:$target:$enable_multilib" in
3157   x86_64-*linux*:yes:$build:$build:)
3158     # Make sure we have a development environment that handles 32-bit
3159     dev64=no
3160     echo "int main () { return 0; }" > conftest.c
3161     ${CC} -m32 -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
3162     if test $? = 0 ; then
3163       if test -s conftest || test -s conftest.exe ; then
3164         dev64=yes
3165       fi
3166     fi
3167     rm -f conftest*
3168     if test x${dev64} != xyes ; then
3169       AC_MSG_ERROR([I suspect your system does not have 32-bit development libraries (libc and headers). If you have them, rerun configure with --enable-multilib. If you do not have them, and want to build a 64-bit-only compiler, rerun configure with --disable-multilib.])
3170     fi
3171     ;;
3172 esac
3173
3174 # Default to --enable-multilib.
3175 if test x${enable_multilib} = x ; then
3176   target_configargs="--enable-multilib ${target_configargs}"
3177 fi
3178
3179 # Pass --with-newlib if appropriate.  Note that target_configdirs has
3180 # changed from the earlier setting of with_newlib.
3181 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " newlib " > /dev/null 2>&1 && test -d ${srcdir}/newlib ; then
3182   target_configargs="--with-newlib ${target_configargs}"
3183 fi
3184
3185 # Different target subdirs use different values of certain variables
3186 # (notably CXX).  Worse, multilibs use *lots* of different values.
3187 # Worse yet, autoconf 2.5x makes some of these 'precious', meaning that
3188 # it doesn't automatically accept command-line overrides of them.
3189 # This means it's not safe for target subdirs to share a cache file,
3190 # which is disgusting, but there you have it.  Hopefully this can be
3191 # fixed in future.  It's still worthwhile to use a cache file for each
3192 # directory.  I think.
3193
3194 # Pass the appropriate --build, --host, --target and --cache-file arguments.
3195 # We need to pass --target, as newer autoconf's requires consistency
3196 # for target_alias and gcc doesn't manage it consistently.
3197 target_configargs="--cache-file=./config.cache ${target_configargs}"
3198
3199 FLAGS_FOR_TARGET=
3200 case " $target_configdirs " in
3201  *" newlib "*)
3202   case " $target_configargs " in
3203   *" --with-newlib "*)
3204    case "$target" in
3205     *-cygwin*)
3206       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/cygwin -isystem $$s/winsup/cygwin/include'
3207       ;;
3208    esac
3209
3210    # If we're not building GCC, don't discard standard headers.
3211    if test -d ${srcdir}/gcc; then
3212      FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -nostdinc'
3213
3214      if test "${build}" != "${host}"; then
3215        # On Canadian crosses, CC_FOR_TARGET will have already been set
3216        # by `configure', so we won't have an opportunity to add -Bgcc/
3217        # to it.  This is right: we don't want to search that directory
3218        # for binaries, but we want the header files in there, so add
3219        # them explicitly.
3220        FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -isystem $$r/$(HOST_SUBDIR)/gcc/include -isystem $$r/$(HOST_SUBDIR)/gcc/include-fixed'
3221
3222        # Someone might think of using the pre-installed headers on
3223        # Canadian crosses, in case the installed compiler is not fully
3224        # compatible with the compiler being built.  In this case, it
3225        # would be better to flag an error than risking having
3226        # incompatible object files being constructed.  We can't
3227        # guarantee that an error will be flagged, but let's hope the
3228        # compiler will do it, when presented with incompatible header
3229        # files.
3230      fi
3231    fi
3232
3233    case "${target}-${is_cross_compiler}" in
3234    i[[3456789]]86-*-linux*-no)
3235       # Here host == target, so we don't need to build gcc,
3236       # so we don't want to discard standard headers.
3237       FLAGS_FOR_TARGET=`echo " $FLAGS_FOR_TARGET " | sed -e 's/ -nostdinc / /'`
3238       ;;
3239    *)
3240       # If we're building newlib, use its generic headers last, but search
3241       # for any libc-related directories first (so make it the last -B
3242       # switch).
3243       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/newlib/ -isystem $$r/$(TARGET_SUBDIR)/newlib/targ-include -isystem $$s/newlib/libc/include'
3244
3245       # If we're building libgloss, find the startup file, simulator library
3246       # and linker script.
3247       case " $target_configdirs " in
3248         *" libgloss "*)
3249         # Look for startup file, simulator library and maybe linker script.
3250         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/libgloss/'"$libgloss_dir"
3251         # Look for libnosys.a in case the target needs it.
3252         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/libgloss/libnosys'
3253         # Most targets have the linker script in the source directory.
3254         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$s/libgloss/'"$libgloss_dir"
3255         ;;
3256       esac
3257       ;;
3258    esac
3259    ;;
3260   esac
3261   ;;
3262 esac
3263
3264 case "$target" in
3265   x86_64-*mingw* | *-w64-mingw*)
3266   # MinGW-w64 does not use newlib, nor does it use winsup. It may,
3267   # however, use a symlink named 'mingw' in ${prefix} .
3268     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L${prefix}/${target}/lib -L${prefix}/mingw/lib -isystem ${prefix}/${target}/include -isystem ${prefix}/mingw/include'
3269     ;;
3270   *-mingw*)
3271   # MinGW can't be handled as Cygwin above since it does not use newlib.
3272     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/mingw -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/mingw/include -isystem $$s/winsup/w32api/include'
3273     ;;
3274 esac
3275
3276 # Allow the user to override the flags for
3277 # our build compiler if desired.
3278 if test x"${build}" = x"${host}" ; then
3279   CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-${CFLAGS}}
3280   CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-${CXXFLAGS}}
3281   LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-${LDFLAGS}}
3282 fi
3283
3284 # On Canadian crosses, we'll be searching the right directories for
3285 # the previously-installed cross compiler, so don't bother to add
3286 # flags for directories within the install tree of the compiler
3287 # being built; programs in there won't even run.
3288 if test "${build}" = "${host}" && test -d ${srcdir}/gcc; then
3289   # Search for pre-installed headers if nothing else fits.
3290   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$(build_tooldir)/bin/ -B$(build_tooldir)/lib/ -isystem $(build_tooldir)/include -isystem $(build_tooldir)/sys-include'
3291 fi
3292
3293 if test "x${use_gnu_ld}" = x &&
3294    echo " ${configdirs} " | grep " ld " > /dev/null ; then
3295   # Arrange for us to find uninstalled linker scripts.
3296   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(HOST_SUBDIR)/ld'
3297 fi
3298
3299 # Search for other target-specific linker scripts and such.
3300 case "${target}" in
3301   mep*)
3302     FLAGS_FOR_TARGET="$FLAGS_FOR_TARGET -mlibrary"
3303     ;;
3304 esac
3305
3306 # Makefile fragments.
3307 for frag in host_makefile_frag target_makefile_frag alphaieee_frag ospace_frag;
3308 do
3309   eval fragval=\$$frag
3310   if test $fragval != /dev/null; then
3311     eval $frag=${srcdir}/$fragval
3312   fi
3313 done
3314 AC_SUBST_FILE(host_makefile_frag)
3315 AC_SUBST_FILE(target_makefile_frag)
3316 AC_SUBST_FILE(alphaieee_frag)
3317 AC_SUBST_FILE(ospace_frag)
3318
3319 # Miscellanea: directories, flags, etc.
3320 AC_SUBST(RPATH_ENVVAR)
3321 AC_SUBST(GCC_SHLIB_SUBDIR)
3322 AC_SUBST(tooldir)
3323 AC_SUBST(build_tooldir)
3324 AC_SUBST(CONFIGURE_GDB_TK)
3325 AC_SUBST(GDB_TK)
3326 AC_SUBST(INSTALL_GDB_TK)
3327
3328 # Build module lists & subconfigure args.
3329 AC_SUBST(build_configargs)
3330 AC_SUBST(build_configdirs)
3331
3332 # Host module lists & subconfigure args.
3333 AC_SUBST(host_configargs)
3334 AC_SUBST(configdirs)
3335 AC_SUBST(target_configdirs)
3336
3337 # Target module lists & subconfigure args.
3338 AC_SUBST(target_configargs)
3339
3340
3341 # Build tools.
3342 AC_SUBST(AR_FOR_BUILD)
3343 AC_SUBST(AS_FOR_BUILD)
3344 AC_SUBST(CC_FOR_BUILD)
3345 AC_SUBST(CFLAGS_FOR_BUILD)
3346 AC_SUBST(CXXFLAGS_FOR_BUILD)
3347 AC_SUBST(CXX_FOR_BUILD)
3348 AC_SUBST(DLLTOOL_FOR_BUILD)
3349 AC_SUBST(GFORTRAN_FOR_BUILD)
3350 AC_SUBST(GOC_FOR_BUILD)
3351 AC_SUBST(LDFLAGS_FOR_BUILD)
3352 AC_SUBST(LD_FOR_BUILD)
3353 AC_SUBST(NM_FOR_BUILD)
3354 AC_SUBST(RANLIB_FOR_BUILD)
3355 AC_SUBST(WINDMC_FOR_BUILD)
3356 AC_SUBST(WINDRES_FOR_BUILD)
3357
3358 # Generate default definitions for YACC, M4, LEX and other programs that run
3359 # on the build machine.  These are used if the Makefile can't locate these
3360 # programs in objdir.
3361 MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
3362
3363 AC_CHECK_PROGS([YACC], ['bison -y' byacc yacc], [$MISSING bison -y])
3364 case " $build_configdirs " in
3365   *" bison "*) YACC='$$r/$(BUILD_SUBDIR)/bison/tests/bison -y' ;;
3366 esac
3367
3368 AC_CHECK_PROGS([BISON], [bison], [$MISSING bison])
3369 case " $build_configdirs " in
3370   *" bison "*) BISON='$$r/$(BUILD_SUBDIR)/bison/tests/bison' ;;
3371 esac
3372
3373 AC_CHECK_PROGS([M4], [gm4 gnum4 m4], [$MISSING m4])
3374 case " $build_configdirs " in
3375   *" m4 "*) M4='$$r/$(BUILD_SUBDIR)/m4/m4' ;;
3376 esac
3377
3378 AC_CHECK_PROGS([LEX], [flex lex], [$MISSING flex])
3379 case " $build_configdirs " in
3380   *" flex "*) LEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3381   *" lex "*) LEX='$$r/$(BUILD_SUBDIR)/lex/lex' ;;
3382 esac
3383
3384 AC_CHECK_PROGS([FLEX], [flex], [$MISSING flex])
3385 case " $build_configdirs " in
3386   *" flex "*) FLEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3387 esac
3388
3389 AC_CHECK_PROGS([MAKEINFO], makeinfo, [$MISSING makeinfo])
3390 case " $build_configdirs " in
3391   *" texinfo "*) MAKEINFO='$$r/$(BUILD_SUBDIR)/texinfo/makeinfo/makeinfo' ;;
3392   *)
3393 changequote(,)
3394     # For an installed makeinfo, we require it to be from texinfo 4.7 or
3395     # higher, else we use the "missing" dummy.
3396     if ${MAKEINFO} --version \
3397        | egrep 'texinfo[^0-9]*(4\.([7-9]|[1-9][0-9])|[5-9]|[1-9][0-9])' >/dev/null 2>&1; then
3398       :
3399     else
3400       MAKEINFO="$MISSING makeinfo"
3401     fi
3402     ;;
3403 changequote([,])
3404 esac
3405
3406 # FIXME: expect and dejagnu may become build tools?
3407
3408 AC_CHECK_PROGS(EXPECT, expect, expect)
3409 case " $configdirs " in
3410   *" expect "*)
3411     test $host = $build && EXPECT='$$r/$(HOST_SUBDIR)/expect/expect'
3412     ;;
3413 esac
3414
3415 AC_CHECK_PROGS(RUNTEST, runtest, runtest)
3416 case " $configdirs " in
3417   *" dejagnu "*)
3418     test $host = $build && RUNTEST='$$s/$(HOST_SUBDIR)/dejagnu/runtest'
3419     ;;
3420 esac
3421
3422
3423 # Host tools.
3424 NCN_STRICT_CHECK_TOOLS(AR, ar)
3425 NCN_STRICT_CHECK_TOOLS(AS, as)
3426 NCN_STRICT_CHECK_TOOLS(DLLTOOL, dlltool)
3427 NCN_STRICT_CHECK_TOOLS(LD, ld)
3428 NCN_STRICT_CHECK_TOOLS(LIPO, lipo)
3429 NCN_STRICT_CHECK_TOOLS(NM, nm)
3430 NCN_STRICT_CHECK_TOOLS(RANLIB, ranlib, true)
3431 NCN_STRICT_CHECK_TOOLS(STRIP, strip, true)
3432 NCN_STRICT_CHECK_TOOLS(WINDRES, windres)
3433 NCN_STRICT_CHECK_TOOLS(WINDMC, windmc)
3434 NCN_STRICT_CHECK_TOOLS(OBJCOPY, objcopy)
3435 NCN_STRICT_CHECK_TOOLS(OBJDUMP, objdump)
3436 NCN_STRICT_CHECK_TOOLS(READELF, readelf)
3437 AC_SUBST(CC)
3438 AC_SUBST(CXX)
3439 AC_SUBST(CFLAGS)
3440 AC_SUBST(CXXFLAGS)
3441
3442 GCC_PLUGIN_OPTION(PLUGIN_OPTION)
3443 AR_PLUGIN_OPTION=
3444 RANLIB_PLUGIN_OPTION=
3445 if test -n "$PLUGIN_OPTION"; then
3446   if $AR --help 2>&1 | grep -q "\--plugin"; then
3447     AR_PLUGIN_OPTION="$PLUGIN_OPTION"
3448   fi
3449   if $RANLIB --help 2>&1 | grep -q "\--plugin"; then
3450     RANLIB_PLUGIN_OPTION="$PLUGIN_OPTION"
3451   fi
3452 else
3453   if test "$enable_pgo_build" != "no"; then
3454     AC_MSG_ERROR([AR with --plugin and rc is required for LTO build])
3455   fi
3456 fi
3457 AC_SUBST(AR_PLUGIN_OPTION)
3458 AC_SUBST(RANLIB_PLUGIN_OPTION)
3459
3460 # Target tools.
3461 AC_ARG_WITH([build-time-tools],
3462   [AS_HELP_STRING([--with-build-time-tools=PATH],
3463                   [use given path to find target tools during the build])],
3464   [case x"$withval" in
3465      x/*) ;;
3466      *)
3467        with_build_time_tools=
3468        AC_MSG_WARN([argument to --with-build-time-tools must be an absolute path])
3469        ;;
3470    esac],
3471   [with_build_time_tools=])
3472
3473 NCN_STRICT_CHECK_TARGET_TOOLS(CC_FOR_TARGET, cc gcc)
3474 NCN_STRICT_CHECK_TARGET_TOOLS(CXX_FOR_TARGET, c++ g++ cxx gxx)
3475 NCN_STRICT_CHECK_TARGET_TOOLS(GCC_FOR_TARGET, gcc, ${CC_FOR_TARGET})
3476 NCN_STRICT_CHECK_TARGET_TOOLS(GFORTRAN_FOR_TARGET, gfortran)
3477 NCN_STRICT_CHECK_TARGET_TOOLS(GOC_FOR_TARGET, gccgo)
3478
3479 ACX_CHECK_INSTALLED_TARGET_TOOL(AR_FOR_TARGET, ar)
3480 ACX_CHECK_INSTALLED_TARGET_TOOL(AS_FOR_TARGET, as)
3481 ACX_CHECK_INSTALLED_TARGET_TOOL(DLLTOOL_FOR_TARGET, dlltool)
3482 ACX_CHECK_INSTALLED_TARGET_TOOL(LD_FOR_TARGET, ld)
3483 ACX_CHECK_INSTALLED_TARGET_TOOL(LIPO_FOR_TARGET, lipo)
3484 ACX_CHECK_INSTALLED_TARGET_TOOL(NM_FOR_TARGET, nm)
3485 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJCOPY_FOR_TARGET, objcopy)
3486 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJDUMP_FOR_TARGET, objdump)
3487 ACX_CHECK_INSTALLED_TARGET_TOOL(RANLIB_FOR_TARGET, ranlib)
3488 ACX_CHECK_INSTALLED_TARGET_TOOL(READELF_FOR_TARGET, readelf)
3489 ACX_CHECK_INSTALLED_TARGET_TOOL(STRIP_FOR_TARGET, strip)
3490 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDRES_FOR_TARGET, windres)
3491 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDMC_FOR_TARGET, windmc)
3492
3493 RAW_CXX_FOR_TARGET="$CXX_FOR_TARGET"
3494
3495 GCC_TARGET_TOOL(ar, AR_FOR_TARGET, AR, [binutils/ar])
3496 GCC_TARGET_TOOL(as, AS_FOR_TARGET, AS, [gas/as-new])
3497 GCC_TARGET_TOOL(cc, CC_FOR_TARGET, CC, [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3498 dnl see comments for CXX_FOR_TARGET_FLAG_TO_PASS
3499 GCC_TARGET_TOOL(c++, CXX_FOR_TARGET, CXX,
3500                 [gcc/xg++ -B$$r/$(HOST_SUBDIR)/gcc/ -nostdinc++ `if test -f $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags; then $(SHELL) $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags --build-includes; else echo -funconfigured-libstdc++-v3 ; fi` -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3501                 c++)
3502 GCC_TARGET_TOOL(c++ for libstdc++, RAW_CXX_FOR_TARGET, CXX,
3503                 [gcc/xgcc -shared-libgcc -B$$r/$(HOST_SUBDIR)/gcc -nostdinc++ -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3504                 c++)
3505 GCC_TARGET_TOOL(dlltool, DLLTOOL_FOR_TARGET, DLLTOOL, [binutils/dlltool])
3506 GCC_TARGET_TOOL(gcc, GCC_FOR_TARGET, , [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3507 GCC_TARGET_TOOL(gfortran, GFORTRAN_FOR_TARGET, GFORTRAN,
3508                 [gcc/gfortran -B$$r/$(HOST_SUBDIR)/gcc/], fortran)
3509 GCC_TARGET_TOOL(gccgo, GOC_FOR_TARGET, GOC,
3510                 [gcc/gccgo -B$$r/$(HOST_SUBDIR)/gcc/], go)
3511 GCC_TARGET_TOOL(ld, LD_FOR_TARGET, LD, [ld/ld-new])
3512 GCC_TARGET_TOOL(lipo, LIPO_FOR_TARGET, LIPO)
3513 GCC_TARGET_TOOL(nm, NM_FOR_TARGET, NM, [binutils/nm-new])
3514 GCC_TARGET_TOOL(objcopy, OBJCOPY_FOR_TARGET, OBJCOPY, [binutils/objcopy])
3515 GCC_TARGET_TOOL(objdump, OBJDUMP_FOR_TARGET, OBJDUMP, [binutils/objdump])
3516 GCC_TARGET_TOOL(ranlib, RANLIB_FOR_TARGET, RANLIB, [binutils/ranlib])
3517 GCC_TARGET_TOOL(readelf, READELF_FOR_TARGET, READELF, [binutils/readelf])
3518 GCC_TARGET_TOOL(strip, STRIP_FOR_TARGET, STRIP, [binutils/strip-new])
3519 GCC_TARGET_TOOL(windres, WINDRES_FOR_TARGET, WINDRES, [binutils/windres])
3520 GCC_TARGET_TOOL(windmc, WINDMC_FOR_TARGET, WINDMC, [binutils/windmc])
3521
3522 AC_SUBST(FLAGS_FOR_TARGET)
3523 AC_SUBST(RAW_CXX_FOR_TARGET)
3524
3525 # Certain tools may need extra flags.
3526 AR_FOR_TARGET=${AR_FOR_TARGET}${extra_arflags_for_target}
3527 RANLIB_FOR_TARGET=${RANLIB_FOR_TARGET}${extra_ranlibflags_for_target}
3528 NM_FOR_TARGET=${NM_FOR_TARGET}${extra_nmflags_for_target}
3529
3530 # When building target libraries, except in a Canadian cross, we use
3531 # the same toolchain as the compiler we just built.
3532 COMPILER_AS_FOR_TARGET='$(AS_FOR_TARGET)'
3533 COMPILER_LD_FOR_TARGET='$(LD_FOR_TARGET)'
3534 COMPILER_NM_FOR_TARGET='$(NM_FOR_TARGET)'
3535 if test $host = $build; then
3536   case " $configdirs " in
3537     *" gcc "*)
3538       COMPILER_AS_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/as'
3539       COMPILER_LD_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/collect-ld'
3540       COMPILER_NM_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/nm'${extra_nmflags_for_target}
3541       ;;
3542   esac
3543 fi
3544
3545 AC_SUBST(COMPILER_AS_FOR_TARGET)
3546 AC_SUBST(COMPILER_LD_FOR_TARGET)
3547 AC_SUBST(COMPILER_NM_FOR_TARGET)
3548
3549 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3550 AC_ARG_ENABLE(maintainer-mode,
3551 [AS_HELP_STRING([--enable-maintainer-mode],
3552                 [enable make rules and dependencies not useful
3553                  (and sometimes confusing) to the casual installer])],
3554       USE_MAINTAINER_MODE=$enableval,
3555       USE_MAINTAINER_MODE=no)
3556 AC_MSG_RESULT($USE_MAINTAINER_MODE)
3557 AC_SUBST(MAINTAINER_MODE_TRUE)
3558 AC_SUBST(MAINTAINER_MODE_FALSE)
3559 if test "$USE_MAINTAINER_MODE" = yes; then
3560   MAINTAINER_MODE_TRUE=
3561   MAINTAINER_MODE_FALSE='#'
3562 else
3563   MAINTAINER_MODE_TRUE='#'
3564   MAINTAINER_MODE_FALSE=
3565 fi
3566 MAINT=$MAINTAINER_MODE_TRUE
3567 AC_SUBST(MAINT)dnl
3568
3569 # ---------------------
3570 # GCC bootstrap support
3571 # ---------------------
3572
3573 # Stage specific cflags for build.
3574 stage1_cflags="-g"
3575 case $build in
3576   vax-*-*)
3577     case ${GCC} in
3578       yes) stage1_cflags="-g -Wa,-J" ;;
3579       *) stage1_cflags="-g -J" ;;
3580     esac ;;
3581 esac
3582
3583 AC_SUBST(stage1_cflags)
3584
3585 # Enable --enable-checking in stage1 of the compiler.
3586 AC_ARG_ENABLE(stage1-checking,
3587 [AS_HELP_STRING([[--enable-stage1-checking[=all]]],
3588                 [choose additional checking for stage1 of the compiler])],
3589 [stage1_checking=--enable-checking=${enable_stage1_checking}],
3590 [if test "x$enable_checking" = xno || test "x$enable_checking" = x; then
3591   # For --disable-checking or implicit --enable-checking=release, avoid
3592   # setting --enable-checking=gc in the default stage1 checking for LTO
3593   # bootstraps.  See PR62077.
3594   case $BUILD_CONFIG in
3595     *lto*)
3596       stage1_checking=--enable-checking=release,misc,gimple,rtlflag,tree,types;;
3597     *)
3598       stage1_checking=--enable-checking=yes,types;;
3599   esac
3600   if test "x$enable_checking" = x && \
3601      test -d ${srcdir}/gcc && \
3602      test x"`cat ${srcdir}/gcc/DEV-PHASE`" = xexperimental; then
3603     stage1_checking=--enable-checking=yes,types,extra
3604   fi
3605 else
3606   stage1_checking=--enable-checking=$enable_checking,types
3607 fi])
3608 AC_SUBST(stage1_checking)
3609
3610 # Enable -Werror in bootstrap stage2 and later.
3611 AC_ARG_ENABLE(werror,
3612 [AS_HELP_STRING([--enable-werror],
3613                 [enable -Werror in bootstrap stage2 and later])],
3614 [
3615 case ${enable_werror} in
3616   yes) stage2_werror_flag="--enable-werror-always" ;;
3617   *) stage2_werror_flag="" ;;
3618 esac
3619 ],
3620 [
3621 if test -d ${srcdir}/gcc && test x"`cat $srcdir/gcc/DEV-PHASE`" = xexperimental; then
3622   case $BUILD_CONFIG in
3623   bootstrap-debug)
3624       stage2_werror_flag="--enable-werror-always" ;;
3625   "")
3626       stage2_werror_flag="--enable-werror-always" ;;
3627   esac
3628 fi
3629 ])
3630
3631 AC_SUBST(stage2_werror_flag)
3632
3633 # Specify what files to not compare during bootstrap.
3634
3635 compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/*"
3636 case "$target" in
3637   hppa*64*-*-hpux*) ;;
3638   hppa*-*-hpux*) compare_exclusions="gcc/cc*-checksum\$(objext) | */libgcc/lib2funcs* | gcc/ada/*tools/* | gcc/function-tests.o" ;;
3639   powerpc*-ibm-aix*) compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/* | *libgomp*\$(objext)" ;;
3640 esac
3641 AC_SUBST(compare_exclusions)
3642
3643 AC_CONFIG_FILES([Makefile],
3644   [sed "$extrasub_build" Makefile |
3645    sed "$extrasub_host" |
3646    sed "$extrasub_target" > mf$$
3647    mv -f mf$$ Makefile],
3648   [extrasub_build="$extrasub_build"
3649    extrasub_host="$extrasub_host"
3650    extrasub_target="$extrasub_target"])
3651 AC_OUTPUT