configure.ac

   1 #   Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000,
   2 #   2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011
   3 #   Free Software Foundation, Inc.
   4 #
   5 # This file is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; see the file COPYING3.  If not see
  17 # <http://www.gnu.org/licenses/>.
  18
  19 ##############################################################################
  20 ### WARNING: this file contains embedded tabs.  Do not run untabify on this file.
  21
  22 m4_include(config/acx.m4)
  23 m4_include(config/override.m4)
  24 m4_include(config/proginstall.m4)
  25 m4_include(config/elf.m4)
  26 m4_include([libtool.m4])
  27 m4_include([ltoptions.m4])
  28 m4_include([ltsugar.m4])
  29 m4_include([ltversion.m4])
  30 m4_include([lt~obsolete.m4])
  31 m4_include([config/cloog.m4])
  32
  33 AC_INIT(move-if-change)
  34 AC_PREREQ(2.64)
  35 AC_DISABLE_OPTION_CHECKING
  36
  37 progname=$0
  38 # if PWD already has a value, it is probably wrong.
  39 if test -n "$PWD" ; then PWD=`${PWDCMD-pwd}`; fi
  40
  41 # Export original configure arguments for use by sub-configures.
  42 # Quote arguments with shell meta charatcers.
  43 TOPLEVEL_CONFIGURE_ARGUMENTS=
  44 set -- "$progname" "$@"
  45 for ac_arg
  46 do
  47   case "$ac_arg" in
  48   *" "*|*"      "*|*[[\[\]\~\#\$\^\&\*\(\)\{\}\\\|\;\<\>\?\']]*)
  49     ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"`
  50     # if the argument is of the form -foo=baz, quote the baz part only
  51     ac_arg=`echo "'$ac_arg'" | sed "s/^'\([[-a-zA-Z0-9]]*=\)/\\1'/"` ;;
  52   *) ;;
  53   esac
  54   # Add the quoted argument to the list.
  55   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS $ac_arg"
  56 done
  57 if test "$silent" = yes; then
  58   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS --silent"
  59 fi
  60 # Remove the initial space we just introduced and, as these will be
  61 # expanded by make, quote '$'.
  62 TOPLEVEL_CONFIGURE_ARGUMENTS=`echo "x$TOPLEVEL_CONFIGURE_ARGUMENTS" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
  63 AC_SUBST(TOPLEVEL_CONFIGURE_ARGUMENTS)
  64
  65 # Find the build, host, and target systems.
  66 ACX_NONCANONICAL_BUILD
  67 ACX_NONCANONICAL_HOST
  68 ACX_NONCANONICAL_TARGET
  69
  70 dnl Autoconf 2.5x and later will set a default program prefix if
  71 dnl --target was used, even if it was the same as --host.  Disable
  72 dnl that behavior.  This must be done before AC_CANONICAL_SYSTEM
  73 dnl to take effect.
  74 test "$host_noncanonical" = "$target_noncanonical" &&
  75   test "$program_prefix$program_suffix$program_transform_name" = \
  76     NONENONEs,x,x, &&
  77   program_transform_name=s,y,y,
  78
  79 AC_CANONICAL_SYSTEM
  80 AC_ARG_PROGRAM
  81
  82 m4_pattern_allow([^AS_FOR_TARGET$])dnl
  83 m4_pattern_allow([^AS_FOR_BUILD$])dnl
  84
  85 # Get 'install' or 'install-sh' and its variants.
  86 AC_PROG_INSTALL
  87 ACX_PROG_LN
  88 AC_PROG_LN_S
  89 AC_PROG_SED
  90 AC_PROG_AWK
  91
  92 srcpwd=`cd ${srcdir} ; ${PWDCMD-pwd}`
  93
  94 # We pass INSTALL explicitly to sub-makes.  Make sure that it is not
  95 # a relative path.
  96 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
  97   INSTALL="${srcpwd}/install-sh -c"
  98 fi
  99
 100 # Set srcdir to "." if that's what it is.
 101 # This is important for multilib support.
 102 pwd=`${PWDCMD-pwd}`
 103 if test "${pwd}" = "${srcpwd}" ; then
 104   srcdir=.
 105 fi
 106
 107 topsrcdir=$srcpwd
 108
 109 extra_host_args=
 110
 111 ### To add a new directory to the tree, first choose whether it is a target
 112 ### or a host dependent tool.  Then put it into the appropriate list
 113 ### (library or tools, host or target), doing a dependency sort.
 114
 115 # Subdirs will be configured in the order listed in build_configdirs,
 116 # configdirs, or target_configdirs; see the serialization section below.
 117
 118 # Dependency sorting is only needed when *configuration* must be done in
 119 # a particular order.  In all cases a dependency should be specified in
 120 # the Makefile, whether or not it's implicitly specified here.
 121
 122 # Double entries in build_configdirs, configdirs, or target_configdirs may
 123 # cause circular dependencies and break everything horribly.
 124
 125 # these library is used by various programs built for the build
 126 # environment
 127 #
 128 build_libs="build-libiberty"
 129
 130 # these tools are built for the build environment
 131 build_tools="build-texinfo build-flex build-bison build-m4 build-fixincludes"
 132
 133 # these libraries are used by various programs built for the host environment
 134 #
 135 host_libs="intl libiberty opcodes bfd readline tcl tk itcl libgui zlib libcpp libdecnumber gmp mpfr mpc ppl cloog libelf libiconv"
 136
 137 # these tools are built for the host environment
 138 # Note, the powerpc-eabi build depends on sim occurring before gdb in order to
 139 # know that we are building the simulator.
 140 # binutils, gas and ld appear in that order because it makes sense to run
 141 # "make check" in that particular order.
 142 # If --enable-gold is used, "gold" may replace "ld".
 143 host_tools="texinfo flex bison binutils gas ld fixincludes gcc cgen sid sim gdb gprof etc expect dejagnu m4 utils guile fastjar gnattools"
 144
 145 # libgcj represents the runtime libraries only used by gcj.
 146 libgcj="target-libffi \
 147         target-zlib \
 148         target-libjava"
 149
 150 # these libraries are built for the target environment, and are built after
 151 # the host libraries and the host tools (which may be a cross compiler)
 152 #
 153 target_libraries="target-libgcc \
 154                 target-libiberty \
 155                 target-libgloss \
 156                 target-newlib \
 157                 target-libgomp \
 158                 target-libstdc++-v3 \
 159                 target-libmudflap \
 160                 target-libssp \
 161                 target-libquadmath \
 162                 target-libgfortran \
 163                 target-boehm-gc \
 164                 ${libgcj} \
 165                 target-libobjc \
 166                 target-libada \
 167                 target-libgo"
 168
 169 # these tools are built using the target libraries, and are intended to
 170 # run only in the target environment
 171 #
 172 # note: any program that *uses* libraries that are in the "target_libraries"
 173 # list belongs in this list.
 174 #
 175 target_tools="target-rda"
 176
 177 ################################################################################
 178
 179 ## All tools belong in one of the four categories, and are assigned above
 180 ## We assign ${configdirs} this way to remove all embedded newlines.  This
 181 ## is important because configure will choke if they ever get through.
 182 ## ${configdirs} is directories we build using the host tools.
 183 ## ${target_configdirs} is directories we build using the target tools.
 184 configdirs=`echo ${host_libs} ${host_tools}`
 185 target_configdirs=`echo ${target_libraries} ${target_tools}`
 186 build_configdirs=`echo ${build_libs} ${build_tools}`
 187
 188 m4_divert_text([PARSE_ARGS],
 189 [case $srcdir in
 190   *" "*)
 191 m4_pushdef([AS_MESSAGE_LOG_FD], [])dnl
 192     AC_MSG_ERROR([path to source, $srcdir, contains spaces])
 193 m4_popdef([AS_MESSAGE_LOG_FD])dnl
 194     ;;
 195 esac
 196 ac_subdirs_all=`cd $srcdir && echo */configure | sed 's,/configure,,g'`
 197 ])
 198
 199 ################################################################################
 200
 201 srcname="gnu development package"
 202
 203 # This gets set non-empty for some net releases of packages.
 204 appdirs=""
 205
 206 # Define is_cross_compiler to save on calls to 'test'.
 207 is_cross_compiler=
 208 if test x"${host}" = x"${target}" ; then
 209   is_cross_compiler=no
 210 else
 211   is_cross_compiler=yes
 212 fi
 213
 214 # Find the build and target subdir names.
 215 GCC_TOPLEV_SUBDIRS
 216 # Be sure to cover against remnants of an in-tree build.
 217 if test $srcdir != .  && test -d $srcdir/host-${host_noncanonical}; then
 218   AC_MSG_ERROR([building out of tree but $srcdir contains host-${host_noncanonical}.
 219 Use a pristine source tree when building in a separate tree])
 220 fi
 221
 222 # Skipdirs are removed silently.
 223 skipdirs=
 224 # Noconfigdirs are removed loudly.
 225 noconfigdirs=""
 226
 227 use_gnu_ld=
 228 # Make sure we don't let GNU ld be added if we didn't want it.
 229 if test x$with_gnu_ld = xno ; then
 230   use_gnu_ld=no
 231   noconfigdirs="$noconfigdirs ld gold"
 232 fi
 233
 234 use_gnu_as=
 235 # Make sure we don't let GNU as be added if we didn't want it.
 236 if test x$with_gnu_as = xno ; then
 237   use_gnu_as=no
 238   noconfigdirs="$noconfigdirs gas"
 239 fi
 240
 241 use_included_zlib=
 242 # Make sure we don't let ZLIB be added if we didn't want it.
 243 if test x$with_system_zlib = xyes ; then
 244   use_included_zlib=no
 245   noconfigdirs="$noconfigdirs zlib"
 246 fi
 247
 248 # some tools are so dependent upon X11 that if we're not building with X,
 249 # it's not even worth trying to configure, much less build, that tool.
 250
 251 case ${with_x} in
 252   yes | "") ;; # the default value for this tree is that X11 is available
 253   no)
 254     skipdirs="${skipdirs} tk itcl libgui"
 255     # We won't be able to build gdbtk without X.
 256     enable_gdbtk=no
 257     ;;
 258   *)  echo "*** bad value \"${with_x}\" for -with-x flag; ignored" 1>&2 ;;
 259 esac
 260
 261 # Some are only suitable for cross toolchains.
 262 # Remove these if host=target.
 263 cross_only="target-libgloss target-newlib target-opcodes"
 264
 265 case $is_cross_compiler in
 266   no) skipdirs="${skipdirs} ${cross_only}" ;;
 267 esac
 268
 269 # If both --with-headers and --with-libs are specified, default to
 270 # --without-newlib.
 271 if test x"${with_headers}" != x && test x"${with_headers}" != xno \
 272    && test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
 273   if test x"${with_newlib}" = x ; then
 274     with_newlib=no
 275   fi
 276 fi
 277
 278 # Recognize --with-newlib/--without-newlib.
 279 case ${with_newlib} in
 280   no) skipdirs="${skipdirs} target-newlib" ;;
 281   yes) skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'` ;;
 282 esac
 283
 284 # Handle --enable-gold, --enable-ld.
 285 # --disable-gold [--enable-ld]
 286 #     Build only ld.  Default option.
 287 # --enable-gold [--enable-ld]
 288 #     Build both gold and ld.  Install gold as "ld.gold", install ld
 289 #     as "ld.bfd" and "ld".
 290 # --enable-gold=default [--enable-ld]
 291 #     Build both gold and ld.  Install gold as "ld.gold" and "ld",
 292 #     install ld as "ld.bfd".
 293 # --enable-gold[=default] --disable-ld
 294 #     Build only gold, which is then installed as both "ld.gold" and "ld".
 295 # --enable-gold --enable-ld=default
 296 #     Build both gold (installed as "ld.gold") and ld (installed as "ld"
 297 #     and ld.bfd).
 298 #     In other words, ld is default
 299 # --enable-gold=default --enable-ld=default
 300 #     Error.
 301
 302 default_ld=
 303 AC_ARG_ENABLE(gold,
 304 [AS_HELP_STRING([[--enable-gold[=ARG]]],
 305                 [build gold @<:@ARG={default,yes,no}@:>@])],
 306 ENABLE_GOLD=$enableval,
 307 ENABLE_GOLD=no)
 308 case "${ENABLE_GOLD}" in
 309   yes|default)
 310     # Check for ELF target.
 311     is_elf=no
 312     case "${target}" in
 313       *-*-elf* | *-*-sysv4* | *-*-unixware* | *-*-eabi* | hppa*64*-*-hpux* \
 314       | *-*-linux* | frv-*-uclinux* | *-*-irix5* | *-*-irix6* \
 315       | *-*-netbsd* | *-*-openbsd* | *-*-freebsd* | *-*-dragonfly* \
 316       | *-*-solaris2* | *-*-nto*)
 317         case "${target}" in
 318           *-*-linux*aout* | *-*-linux*oldld*)
 319             ;;
 320           *)
 321             is_elf=yes
 322             ;;
 323         esac
 324     esac
 325
 326     if test "$is_elf" = "yes"; then
 327       # Check for target supported by gold.
 328       case "${target}" in
 329         i?86-*-* | x86_64-*-* | sparc*-*-* | powerpc*-*-* | arm*-*-*)
 330           configdirs="$configdirs gold"
 331           if test x${ENABLE_GOLD} = xdefault; then
 332             default_ld=gold
 333           fi
 334           ENABLE_GOLD=yes
 335           ;;
 336       esac
 337     fi
 338     ;;
 339   no)
 340     ;;
 341   *)
 342     AC_MSG_ERROR([invalid --enable-gold argument])
 343     ;;
 344 esac
 345
 346 AC_ARG_ENABLE(ld,
 347 [AS_HELP_STRING([[--enable-ld[=ARG]]],
 348                 [build ld @<:@ARG={default,yes,no}@:>@])],
 349 ENABLE_LD=$enableval,
 350 ENABLE_LD=yes)
 351
 352 case "${ENABLE_LD}" in
 353   default)
 354     if test x${default_ld} != x; then
 355       AC_MSG_ERROR([either gold or ld can be the default ld])
 356     fi
 357     ;;
 358   yes)
 359     ;;
 360   no)
 361     if test x${ENABLE_GOLD} != xyes; then
 362       AC_MSG_WARN([neither ld nor gold are enabled])
 363     fi
 364     configdirs=`echo " ${configdirs} " | sed -e 's/ ld / /'`
 365     ;;
 366   *)
 367     AC_MSG_ERROR([invalid --enable-ld argument])
 368     ;;
 369 esac
 370
 371 # Configure extra directories which are host specific
 372
 373 case "${host}" in
 374   *-cygwin*)
 375     configdirs="$configdirs libtermcap" ;;
 376 esac
 377
 378 # A target can indicate whether a language isn't supported for some reason.
 379 # Only spaces may be used in this macro; not newlines or tabs.
 380 unsupported_languages=
 381
 382 # Remove more programs from consideration, based on the host or
 383 # target this usually means that a port of the program doesn't
 384 # exist yet.
 385
 386 case "${host}" in
 387   i[[3456789]]86-*-msdosdjgpp*)
 388     noconfigdirs="$noconfigdirs tcl tk itcl"
 389     ;;
 390 esac
 391
 392
 393 AC_ARG_ENABLE(libquadmath,
 394 AS_HELP_STRING([--disable-libquadmath],
 395   [do not build libquadmath directory]),
 396 ENABLE_LIBQUADMATH=$enableval,
 397 ENABLE_LIBQUADMATH=yes)
 398 if test "${ENABLE_LIBQUADMATH}" = "no" ; then
 399   noconfigdirs="$noconfigdirs target-libquadmath"
 400 fi
 401
 402
 403 AC_ARG_ENABLE(libquadmath-support,
 404 AS_HELP_STRING([--disable-libquadmath-support],
 405   [disable libquadmath support for Fortran]),
 406 ENABLE_LIBQUADMATH_SUPPORT=$enableval,
 407 ENABLE_LIBQUADMATH_SUPPORT=yes)
 408 enable_libquadmath_support=
 409 if test "${ENABLE_LIBQUADMATH_SUPPORT}" = "no" ; then
 410   enable_libquadmath_support=no
 411 fi
 412
 413
 414 AC_ARG_ENABLE(libada,
 415 [AS_HELP_STRING([--enable-libada], [build libada directory])],
 416 ENABLE_LIBADA=$enableval,
 417 ENABLE_LIBADA=yes)
 418 if test "${ENABLE_LIBADA}" != "yes" ; then
 419   noconfigdirs="$noconfigdirs gnattools"
 420 fi
 421
 422 AC_ARG_ENABLE(libssp,
 423 [AS_HELP_STRING([--enable-libssp], [build libssp directory])],
 424 ENABLE_LIBSSP=$enableval,
 425 ENABLE_LIBSSP=yes)
 426
 427 # Save it here so that, even in case of --enable-libgcj, if the Java
 428 # front-end isn't enabled, we still get libgcj disabled.
 429 libgcj_saved=$libgcj
 430 case $enable_libgcj in
 431 yes)
 432   # If we reset it here, it won't get added to noconfigdirs in the
 433   # target-specific build rules, so it will be forcibly enabled
 434   # (unless the Java language itself isn't enabled).
 435   libgcj=
 436   ;;
 437 no)
 438   # Make sure we get it printed in the list of not supported target libs.
 439   # Don't disable libffi, though, other languages use it.
 440   noconfigdirs="$noconfigdirs `echo ${libgcj} | sed -e 's/target-libffi//'`"
 441   # Clear libgcj_saved so that even if java is enabled libffi won't be
 442   # built.
 443   libgcj_saved=
 444   ;;
 445 esac
 446
 447
 448 # Disable libmudflap on some systems.
 449 if test x$enable_libmudflap = x ; then
 450     case "${target}" in
 451     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | bfin*-*-uclinux* | *-*-kopensolaris*-gnu)
 452         # Enable libmudflap by default in GNU and friends.
 453         ;;
 454     *-*-freebsd*)
 455         # Enable libmudflap by default in FreeBSD.
 456         ;;
 457     *)
 458         # Disable it by default everywhere else.
 459         noconfigdirs="$noconfigdirs target-libmudflap"
 460         ;;
 461     esac
 462 fi
 463
 464 # Disable libgomp on non POSIX hosted systems.
 465 if test x$enable_libgomp = x ; then
 466     # Enable libgomp by default on hosted POSIX systems.
 467     case "${target}" in
 468     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 469         ;;
 470     *-*-netbsd* | *-*-freebsd* | *-*-openbsd* | *-*-dragonfly*)
 471         ;;
 472     *-*-solaris2* | *-*-irix6* | *-*-osf* | *-*-hpux11*)
 473         ;;
 474     *-*-darwin* | *-*-aix*)
 475         ;;
 476     *)
 477         noconfigdirs="$noconfigdirs target-libgomp"
 478         ;;
 479     esac
 480 fi
 481
 482 # Disable libssp for some systems.
 483 case "${target}" in
 484   avr-*-*)
 485     # No hosted I/O support.
 486     noconfigdirs="$noconfigdirs target-libssp"
 487     ;;
 488   powerpc-*-aix* | rs6000-*-aix*)
 489     noconfigdirs="$noconfigdirs target-libssp"
 490     ;;
 491 esac
 492
 493 # Disable target libiberty for some systems.
 494 case "${target}" in
 495   *-*-kaos*)
 496     # Remove unsupported stuff on all kaOS configurations.
 497     skipdirs="target-libiberty"
 498     ;;
 499   *-*-netbsd*)
 500     # Skip some stuff on all NetBSD configurations.
 501     noconfigdirs="$noconfigdirs target-libiberty"
 502     ;;
 503   *-*-netware*)
 504     noconfigdirs="$noconfigdirs target-libiberty"
 505     ;;
 506   *-*-rtems*)
 507     skipdirs="${skipdirs} target-libiberty"
 508     ;;
 509   *-*-tpf*)
 510     noconfigdirs="$noconfigdirs target-libiberty"
 511     ;;
 512   *-*-vxworks*)
 513     noconfigdirs="$noconfigdirs target-libiberty"
 514     ;;
 515   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 516     noconfigdirs="$noconfigdirs target-libiberty"
 517     ;;
 518   arm*-*-symbianelf*)
 519     noconfigdirs="$noconfigdirs target-libiberty"
 520     ;;
 521   avr-*-*)
 522     noconfigdirs="$noconfigdirs target-libiberty"
 523     ;;
 524   m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)
 525     noconfigdirs="$noconfigdirs target-libiberty"
 526     ;;
 527   picochip-*-*)
 528     noconfigdirs="$noconfigdirs target-libiberty"
 529     ;;
 530   mips*-sde-elf*)
 531     skipdirs="$skipdirs target-libiberty"
 532     ;;
 533   ip2k-*-*)
 534     noconfigdirs="$noconfigdirs target-libiberty"
 535     ;;
 536 esac
 537
 538 # Disable libstdc++-v3 for some systems.
 539 case "${target}" in
 540   *-*-vxworks*)
 541     # VxWorks uses the Dinkumware C++ library.
 542     noconfigdirs="$noconfigdirs target-libstdc++-v3"
 543     ;;
 544   arm*-wince-pe*)
 545     # the C++ libraries don't build on top of CE's C libraries
 546     noconfigdirs="$noconfigdirs target-libstdc++-v3"
 547     ;;
 548   avr-*-*)
 549     noconfigdirs="$noconfigdirs target-libstdc++-v3"
 550     ;;
 551 esac
 552
 553 # Disable Fortran for some systems.
 554 case "${target}" in
 555   mmix-*-*)
 556     # See <http://gcc.gnu.org/ml/gcc-patches/2004-11/msg00572.html>.
 557     unsupported_languages="$unsupported_languages fortran"
 558     ;;
 559 esac
 560
 561 # Disable Java if libffi is not supported.
 562 case "${target}" in
 563   alpha*-*-*)
 564     ;;
 565   arm*-*-*)
 566     ;;
 567   cris-*-*)
 568     ;;
 569   frv-*-*)
 570     ;;
 571   hppa*-*-linux*)
 572     ;;
 573   hppa*-*-hpux*)
 574     ;;
 575   i?86-*-*)
 576     ;;
 577   ia64*-*-*)
 578     ;;
 579   m32r*-*-*)
 580     ;;
 581   m68k-*-*)
 582     ;;
 583   mips-sgi-irix6.* | mips*-*-rtems*)
 584     ;;
 585   mips*-*-linux*)
 586     ;;
 587   powerpc*-*-linux*)
 588     ;;
 589   powerpc-*-darwin*)
 590     ;;
 591   powerpc-*-aix* | rs6000-*-aix*)
 592     ;;
 593   powerpc-*-freebsd*)
 594     ;;
 595   powerpc64-*-freebsd*)
 596     ;;
 597   powerpc*-*-rtems*)
 598     ;;
 599   s390-*-* | s390x-*-*)
 600     ;;
 601   sh-*-* | sh[[34]]*-*-*)
 602     ;;
 603   sh64-*-* | sh5*-*-*)
 604     ;;
 605   sparc*-*-*)
 606     ;;
 607   x86_64-*-*)
 608     ;;
 609   *-*-*)
 610     unsupported_languages="$unsupported_languages java"
 611     ;;
 612 esac
 613
 614 # Disable Java, libgcj or related libraries for some systems.
 615 case "${target}" in
 616   powerpc-*-darwin*)
 617     ;;
 618   i[[3456789]]86-*-darwin*)
 619     ;;
 620   x86_64-*-darwin[[912]]*)
 621     ;;
 622   *-*-darwin*)
 623     noconfigdirs="$noconfigdirs ${libgcj}"
 624     ;;
 625   *-*-netware*)
 626     noconfigdirs="$noconfigdirs ${libgcj}"
 627     ;;
 628   *-*-rtems*)
 629     noconfigdirs="$noconfigdirs ${libgcj}"
 630     ;;
 631   *-*-tpf*)
 632     noconfigdirs="$noconfigdirs ${libgcj}"
 633     ;;
 634   *-*-uclinux*)
 635     noconfigdirs="$noconfigdirs ${libgcj}"
 636     ;;
 637   *-*-vxworks*)
 638     noconfigdirs="$noconfigdirs ${libgcj}"
 639     ;;
 640   alpha*-*-*vms*)
 641     noconfigdirs="$noconfigdirs ${libgcj}"
 642     ;;
 643   arm-wince-pe)
 644     noconfigdirs="$noconfigdirs ${libgcj}"
 645     ;;
 646   arm*-*-symbianelf*)
 647     noconfigdirs="$noconfigdirs ${libgcj}"
 648     ;;
 649   bfin-*-*)
 650     noconfigdirs="$noconfigdirs target-boehm-gc"
 651     ;;
 652   cris-*-* | crisv32-*-*)
 653     unsupported_languages="$unsupported_languages java"
 654     case "${target}" in
 655       *-*-linux*)
 656         ;;
 657       *) # See PR46792 regarding target-libffi.
 658         noconfigdirs="$noconfigdirs target-libffi target-boehm-gc";;
 659     esac
 660     ;;
 661   hppa*64*-*-linux*)
 662     # In this case, it's because the hppa64-linux target is for
 663     # the kernel only at this point and has no libc, and thus no
 664     # headers, crt*.o, etc., all of which are needed by these.
 665     unsupported_languages="$unsupported_languages java"
 666     ;;
 667   hppa*64*-*-hpux*)
 668     noconfigdirs="$noconfigdirs ${libgcj}"
 669     ;;
 670   hppa*-hp-hpux11*)
 671     ;;
 672   hppa*-*-hpux*)
 673     # According to Alexandre Oliva <aoliva@redhat.com>, libjava won't
 674     # build on HP-UX 10.20.
 675     noconfigdirs="$noconfigdirs ${libgcj}"
 676     ;;
 677   ia64*-*-*vms*)
 678     noconfigdirs="$noconfigdirs ${libgcj}"
 679     ;;
 680   i[[3456789]]86-w64-mingw*)
 681     noconfigdirs="$noconfigdirs ${libgcj}"
 682     ;;
 683   i[[3456789]]86-*-mingw*)
 684     noconfigdirs="$noconfigdirs ${libgcj}"
 685     ;;
 686   x86_64-*-mingw*)
 687     noconfigdirs="$noconfigdirs ${libgcj}"
 688     ;;
 689   mmix-*-*)
 690     noconfigdirs="$noconfigdirs target-libffi target-boehm-gc"
 691     ;;
 692   powerpc-*-aix*)
 693     # copied from rs6000-*-* entry
 694     noconfigdirs="$noconfigdirs ${libgcj}"
 695     ;;
 696   rs6000-*-aix*)
 697     noconfigdirs="$noconfigdirs ${libgcj}"
 698     ;;
 699   mips*-*-irix6*)
 700     # Linking libjava exceeds command-line length limits on at least
 701     # IRIX 6.2, but not on IRIX 6.5.
 702     # Also, boehm-gc won't build on IRIX 6.5, according to Jeffrey Oldham
 703     # <oldham@codesourcery.com>
 704     noconfigdirs="$noconfigdirs ${libgcj}"
 705     ;;
 706   *-*-lynxos*)
 707     noconfigdirs="$noconfigdirs ${libgcj}"
 708     ;;
 709 esac
 710
 711 # Default libgloss CPU subdirectory.
 712 libgloss_dir="$target_cpu"
 713
 714 case "${target}" in
 715   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 716     libgloss_dir=wince
 717     ;;
 718   arm*-*-*)
 719     libgloss_dir=arm
 720     ;;
 721   cris-*-* | crisv32-*-*)
 722     libgloss_dir=cris
 723     ;;
 724   hppa*-*-*)
 725     libgloss_dir=pa
 726     ;;
 727   i[[3456789]]86-*-*)
 728     libgloss_dir=i386
 729     ;;
 730   m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)
 731     libgloss_dir=m68hc11
 732     ;;
 733   m68*-*-* | fido-*-*)
 734     libgloss_dir=m68k
 735     ;;
 736   mips*-*-*)
 737     libgloss_dir=mips
 738     ;;
 739   powerpc*-*-*)
 740     libgloss_dir=rs6000
 741     ;;
 742   sparc*-*-*)
 743     libgloss_dir=sparc
 744     ;;
 745 esac
 746
 747 # Disable newlib and libgloss for various target OSes.
 748 case "${target}" in
 749   alpha*-dec-osf*)
 750     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 751     ;;
 752   i[[3456789]]86-*-linux*)
 753     # This section makes it possible to build newlib natively on linux.
 754     # If we are using a cross compiler then don't configure newlib.
 755     if test x${is_cross_compiler} != xno ; then
 756       noconfigdirs="$noconfigdirs target-newlib"
 757     fi
 758     noconfigdirs="$noconfigdirs target-libgloss"
 759     # If we are not using a cross compiler, do configure newlib.
 760     # Note however, that newlib will only be configured in this situation
 761     # if the --with-newlib option has been given, because otherwise
 762     # 'target-newlib' will appear in skipdirs.
 763     ;;
 764   i[[3456789]]86-*-rdos*)
 765     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 766     ;;
 767   sh*-*-pe|mips*-*-pe|arm-wince-pe)
 768     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 769     ;;
 770   sparc-*-sunos4*)
 771     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 772     ;;
 773   *-*-aix*)
 774     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 775     ;;
 776   *-*-beos*)
 777     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 778     ;;
 779   *-*-chorusos)
 780     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 781     ;;
 782   *-*-dragonfly*)
 783     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 784     ;;
 785   *-*-freebsd*)
 786     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 787     ;;
 788   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 789     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 790     ;;
 791   *-*-lynxos*)
 792     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 793     ;;
 794   *-*-mingw*)
 795     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 796     ;;
 797   *-*-netbsd*)
 798     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 799     ;;
 800   *-*-netware*)
 801     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 802     ;;
 803   *-*-tpf*)
 804     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 805     ;;
 806   *-*-uclinux*)
 807     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 808     ;;
 809   *-*-vxworks*)
 810     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 811     ;;
 812 esac
 813
 814 case "${target}" in
 815   *-*-chorusos)
 816     ;;
 817   powerpc-*-darwin*)
 818     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 819     noconfigdirs="$noconfigdirs sim target-rda"
 820     ;;
 821   i[[3456789]]86-*-darwin*)
 822     noconfigdirs="$noconfigdirs ld gprof"
 823     noconfigdirs="$noconfigdirs sim target-rda"
 824     ;;
 825   x86_64-*-darwin[[912]]*)
 826     noconfigdirs="$noconfigdirs ld gas gprof"
 827     noconfigdirs="$noconfigdirs sim target-rda"
 828     ;;
 829   *-*-darwin*)
 830     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 831     noconfigdirs="$noconfigdirs sim target-rda"
 832     ;;
 833   *-*-dragonfly*)
 834     ;;
 835   *-*-freebsd*)
 836     if test "x$with_gmp" = x && test "x$with_gmp_dir" = x \
 837         && test -f /usr/local/include/gmp.h; then
 838       with_gmp=/usr/local
 839     fi
 840     ;;
 841   *-*-kaos*)
 842     # Remove unsupported stuff on all kaOS configurations.
 843     noconfigdirs="$noconfigdirs target-libgloss"
 844     ;;
 845   *-*-netbsd*)
 846     ;;
 847   *-*-netware*)
 848     ;;
 849   *-*-rtems*)
 850     noconfigdirs="$noconfigdirs target-libgloss"
 851     ;;
 852     # The tpf target doesn't support gdb yet.
 853   *-*-tpf*)
 854     noconfigdirs="$noconfigdirs gdb tcl tk libgui itcl"
 855     ;;
 856   *-*-uclinux*)
 857     noconfigdirs="$noconfigdirs target-rda"
 858     ;;
 859   *-*-vxworks*)
 860     ;;
 861   alpha*-dec-osf*)
 862     # ld works, but does not support shared libraries.
 863     # gas doesn't generate exception information.
 864     noconfigdirs="$noconfigdirs gas ld"
 865     ;;
 866   alpha*-*-*vms*)
 867     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss"
 868     ;;
 869   alpha*-*-*)
 870     # newlib is not 64 bit ready
 871     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 872     ;;
 873   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 874     noconfigdirs="$noconfigdirs tcl tk itcl libgui sim"
 875     ;;
 876   arc-*-*)
 877     noconfigdirs="$noconfigdirs target-libgloss"
 878     ;;
 879   arm-*-pe*)
 880     noconfigdirs="$noconfigdirs target-libgloss"
 881     ;;
 882   arm-*-riscix*)
 883     noconfigdirs="$noconfigdirs ld target-libgloss"
 884     ;;
 885   c4x-*-* | tic4x-*-*)
 886     noconfigdirs="$noconfigdirs target-libgloss"
 887     ;;
 888   tic54x-*-*)
 889     noconfigdirs="$noconfigdirs target-libgloss gdb"
 890     ;;
 891   cr16-*-*)
 892     noconfigdirs="$noconfigdirs gdb"
 893     ;;
 894   d10v-*-*)
 895     noconfigdirs="$noconfigdirs target-libgloss"
 896     ;;
 897   d30v-*-*)
 898     noconfigdirs="$noconfigdirs gdb"
 899     ;;
 900   fr30-*-elf*)
 901     noconfigdirs="$noconfigdirs gdb"
 902     ;;
 903   moxie-*-*)
 904     noconfigdirs="$noconfigdirs gprof"
 905     ;;
 906   h8300*-*-*)
 907     noconfigdirs="$noconfigdirs target-libgloss"
 908     ;;
 909   h8500-*-*)
 910     noconfigdirs="$noconfigdirs target-libgloss"
 911     ;;
 912   hppa1.1-*-osf* | hppa1.1-*-bsd* )
 913     ;;
 914   hppa*64*-*-linux*)
 915     ;;
 916   hppa*-*-linux*)
 917     ;;
 918   hppa*-*-*elf* | \
 919   hppa*-*-lites* | \
 920   hppa*-*-openbsd* | \
 921   hppa*64*-*-*)
 922     ;;
 923   hppa*-hp-hpux11*)
 924     noconfigdirs="$noconfigdirs ld"
 925     ;;
 926   hppa*-*-pro*)
 927     ;;
 928   hppa*-*-*)
 929     noconfigdirs="$noconfigdirs ld"
 930     ;;
 931   i960-*-*)
 932     noconfigdirs="$noconfigdirs gdb"
 933     ;;
 934   ia64*-*-elf*)
 935     # No gdb support yet.
 936     noconfigdirs="$noconfigdirs readline libgui itcl gdb"
 937     ;;
 938   ia64*-**-hpux*)
 939     # No ld support yet.
 940     noconfigdirs="$noconfigdirs libgui itcl ld"
 941     ;;
 942   ia64*-*-*vms*)
 943     # No gdb or ld support yet.
 944     noconfigdirs="$noconfigdirs readline libgui itcl gdb ld"
 945     ;;
 946   i[[3456789]]86-w64-mingw*)
 947     ;;
 948   i[[3456789]]86-*-mingw*)
 949     target_configdirs="$target_configdirs target-winsup"
 950     ;;
 951   *-*-cygwin*)
 952     target_configdirs="$target_configdirs target-libtermcap target-winsup"
 953     noconfigdirs="$noconfigdirs target-libgloss"
 954     # always build newlib if winsup directory is present.
 955     if test -d "$srcdir/winsup/cygwin"; then
 956       skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
 957     elif test -d "$srcdir/newlib"; then
 958       echo "Warning: winsup/cygwin is missing so newlib can't be built."
 959     fi
 960     ;;
 961   i[[3456789]]86-*-pe)
 962     noconfigdirs="$noconfigdirs target-libgloss"
 963     ;;
 964   i[[3456789]]86-*-sco3.2v5*)
 965     # The linker does not yet know about weak symbols in COFF,
 966     # and is not configured to handle mixed ELF and COFF.
 967     noconfigdirs="$noconfigdirs ld target-libgloss"
 968     ;;
 969   i[[3456789]]86-*-sco*)
 970     noconfigdirs="$noconfigdirs gprof target-libgloss"
 971     ;;
 972   i[[3456789]]86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*)
 973     noconfigdirs="$noconfigdirs target-libgloss"
 974     ;;
 975   i[[3456789]]86-*-sysv4*)
 976     noconfigdirs="$noconfigdirs target-libgloss"
 977     ;;
 978   i[[3456789]]86-*-beos*)
 979     noconfigdirs="$noconfigdirs gdb"
 980     ;;
 981   i[[3456789]]86-*-rdos*)
 982     noconfigdirs="$noconfigdirs gdb"
 983     ;;
 984   mmix-*-*)
 985     noconfigdirs="$noconfigdirs gdb"
 986     ;;
 987   mt-*-*)
 988     noconfigdirs="$noconfigdirs sim"
 989     ;;
 990   powerpc-*-aix*)
 991     # copied from rs6000-*-* entry
 992     noconfigdirs="$noconfigdirs gprof"
 993     ;;
 994   powerpc*-*-winnt* | powerpc*-*-pe*)
 995     target_configdirs="$target_configdirs target-winsup"
 996     noconfigdirs="$noconfigdirs gdb tcl tk target-libgloss itcl"
 997     # always build newlib.
 998     skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
 999     ;;
1000     # This is temporary until we can link against shared libraries
1001   powerpcle-*-solaris*)
1002     noconfigdirs="$noconfigdirs gdb sim tcl tk itcl"
1003     ;;
1004   powerpc-*-beos*)
1005     noconfigdirs="$noconfigdirs gdb"
1006     ;;
1007   rs6000-*-lynxos*)
1008     noconfigdirs="$noconfigdirs gprof"
1009     ;;
1010   rs6000-*-aix*)
1011     noconfigdirs="$noconfigdirs gprof"
1012     ;;
1013   rs6000-*-*)
1014     noconfigdirs="$noconfigdirs gprof"
1015     ;;
1016   m68k-apollo-*)
1017     noconfigdirs="$noconfigdirs ld binutils gprof target-libgloss"
1018     ;;
1019   microblaze*)
1020     noconfigdirs="$noconfigdirs gprof"
1021     ;;
1022   mips*-sde-elf*)
1023     if test x$with_newlib = xyes; then
1024       noconfigdirs="$noconfigdirs gprof"
1025     fi
1026     ;;
1027   mips*-*-irix5*)
1028     noconfigdirs="$noconfigdirs gprof target-libgloss"
1029     ;;
1030   mips*-*-irix6*)
1031     noconfigdirs="$noconfigdirs gprof target-libgloss"
1032     ;;
1033   mips*-*-bsd*)
1034     noconfigdirs="$noconfigdirs gprof target-libgloss"
1035     ;;
1036   mips*-*-linux*)
1037     ;;
1038   mips*-*-*)
1039     noconfigdirs="$noconfigdirs gprof"
1040     ;;
1041   sh-*-* | sh64-*-*)
1042     case "${target}" in
1043       sh*-*-elf)
1044          ;;
1045       *)
1046          noconfigdirs="$noconfigdirs target-libgloss" ;;
1047     esac
1048     ;;
1049   sparc-*-sunos4*)
1050     if test x${is_cross_compiler} = xno ; then
1051            use_gnu_ld=no
1052     fi
1053     ;;
1054   tic6x-*-*)
1055     noconfigdirs="$noconfigdirs gdb sim"
1056     ;;
1057   tilepro-*-* | tilegx-*-*)
1058     noconfigdirs="$noconfigdirs sim"
1059     ;;
1060   v810-*-*)
1061     noconfigdirs="$noconfigdirs bfd binutils gas gdb ld opcodes target-libgloss"
1062     ;;
1063   vax-*-*)
1064     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1065     ;;
1066 esac
1067
1068 # If we aren't building newlib, then don't build libgloss, since libgloss
1069 # depends upon some newlib header files.
1070 case "${noconfigdirs}" in
1071   *target-libgloss*) ;;
1072   *target-newlib*) noconfigdirs="$noconfigdirs target-libgloss" ;;
1073 esac
1074
1075 # Work in distributions that contain no compiler tools, like Autoconf.
1076 host_makefile_frag=/dev/null
1077 if test -d ${srcdir}/config ; then
1078 case "${host}" in
1079   i[[3456789]]86-*-msdosdjgpp*)
1080     host_makefile_frag="config/mh-djgpp"
1081     ;;
1082   *-cygwin*)
1083     ACX_CHECK_CYGWIN_CAT_WORKS
1084     host_makefile_frag="config/mh-cygwin"
1085     ;;
1086   *-mingw*)
1087     host_makefile_frag="config/mh-mingw"
1088     ;;
1089   *-interix*)
1090     host_makefile_frag="config/mh-interix"
1091     ;;
1092   hppa*-hp-hpux10*)
1093     host_makefile_frag="config/mh-pa-hpux10"
1094     ;;
1095   hppa*-hp-hpux*)
1096     host_makefile_frag="config/mh-pa"
1097     ;;
1098   hppa*-*)
1099     host_makefile_frag="config/mh-pa"
1100     ;;
1101   *-*-darwin*)
1102     host_makefile_frag="config/mh-darwin"
1103     ;;
1104   powerpc-*-aix*)
1105     host_makefile_frag="config/mh-ppc-aix"
1106     ;;
1107   rs6000-*-aix*)
1108     host_makefile_frag="config/mh-ppc-aix"
1109     ;;
1110 esac
1111 fi
1112
1113 if test "${build}" != "${host}" ; then
1114   AR_FOR_BUILD=${AR_FOR_BUILD-ar}
1115   AS_FOR_BUILD=${AS_FOR_BUILD-as}
1116   CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
1117   CXX_FOR_BUILD=${CXX_FOR_BUILD-g++}
1118   GCJ_FOR_BUILD=${GCJ_FOR_BUILD-gcj}
1119   GFORTRAN_FOR_BUILD=${GFORTRAN_FOR_BUILD-gfortran}
1120   GOC_FOR_BUILD=${GOC_FOR_BUILD-gccgo}
1121   DLLTOOL_FOR_BUILD=${DLLTOOL_FOR_BUILD-dlltool}
1122   LD_FOR_BUILD=${LD_FOR_BUILD-ld}
1123   NM_FOR_BUILD=${NM_FOR_BUILD-nm}
1124   RANLIB_FOR_BUILD=${RANLIB_FOR_BUILD-ranlib}
1125   WINDRES_FOR_BUILD=${WINDRES_FOR_BUILD-windres}
1126   WINDMC_FOR_BUILD=${WINDMC_FOR_BUILD-windmc}
1127 else
1128   AR_FOR_BUILD="\$(AR)"
1129   AS_FOR_BUILD="\$(AS)"
1130   CC_FOR_BUILD="\$(CC)"
1131   CXX_FOR_BUILD="\$(CXX)"
1132   GCJ_FOR_BUILD="\$(GCJ)"
1133   GFORTRAN_FOR_BUILD="\$(GFORTRAN)"
1134   GOC_FOR_BUILD="\$(GOC)"
1135   DLLTOOL_FOR_BUILD="\$(DLLTOOL)"
1136   LD_FOR_BUILD="\$(LD)"
1137   NM_FOR_BUILD="\$(NM)"
1138   RANLIB_FOR_BUILD="\$(RANLIB)"
1139   WINDRES_FOR_BUILD="\$(WINDRES)"
1140   WINDMC_FOR_BUILD="\$(WINDMC)"
1141 fi
1142
1143 AC_PROG_CC
1144 AC_PROG_CXX
1145
1146 # We must set the default linker to the linker used by gcc for the correct
1147 # operation of libtool.  If LD is not defined and we are using gcc, try to
1148 # set the LD default to the ld used by gcc.
1149 if test -z "$LD"; then
1150   if test "$GCC" = yes; then
1151     case $build in
1152     *-*-mingw*)
1153       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1 | tr -d '\015'` ;;
1154     *)
1155       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1` ;;
1156     esac
1157     case $gcc_prog_ld in
1158     # Accept absolute paths.
1159     [[\\/]* | [A-Za-z]:[\\/]*)]
1160       LD="$gcc_prog_ld" ;;
1161     esac
1162   fi
1163 fi
1164
1165 ACX_PROG_GNAT
1166 ACX_PROG_CMP_IGNORE_INITIAL
1167
1168 # See if we are building gcc with C++.
1169 AC_ARG_ENABLE(build-with-cxx,
1170 [AS_HELP_STRING([--enable-build-with-cxx],
1171                 [build with C++ compiler instead of C compiler])],
1172 ENABLE_BUILD_WITH_CXX=$enableval,
1173 ENABLE_BUILD_WITH_CXX=no)
1174
1175 # Used for setting $lt_cv_objdir
1176 _LT_CHECK_OBJDIR
1177
1178 # Check for GMP, MPFR and MPC
1179 gmplibs="-lmpc -lmpfr -lgmp"
1180 gmpinc=
1181 have_gmp=no
1182
1183 # Specify a location for mpc
1184 # check for this first so it ends up on the link line before mpfr.
1185 AC_ARG_WITH(mpc,
1186 [AS_HELP_STRING([--with-mpc=PATH],
1187                 [specify prefix directory for installed MPC package.
1188                  Equivalent to --with-mpc-include=PATH/include
1189                  plus --with-mpc-lib=PATH/lib])])
1190 AC_ARG_WITH(mpc-include,
1191 [AS_HELP_STRING([--with-mpc-include=PATH],
1192                 [specify directory for installed MPC include files])])
1193 AC_ARG_WITH(mpc-lib,
1194 [AS_HELP_STRING([--with-mpc-lib=PATH],
1195                 [specify directory for the installed MPC library])])
1196
1197 if test "x$with_mpc" != x; then
1198   gmplibs="-L$with_mpc/lib $gmplibs"
1199   gmpinc="-I$with_mpc/include $gmpinc"
1200 fi
1201 if test "x$with_mpc_include" != x; then
1202   gmpinc="-I$with_mpc_include $gmpinc"
1203 fi
1204 if test "x$with_mpc_lib" != x; then
1205   gmplibs="-L$with_mpc_lib $gmplibs"
1206 fi
1207 if test "x$with_mpc$with_mpc_include$with_mpc_lib" = x && test -d ${srcdir}/mpc; then
1208   gmplibs='-L$$r/$(HOST_SUBDIR)/mpc/src/'"$lt_cv_objdir $gmplibs"
1209   gmpinc='-I$$s/mpc/src '"$gmpinc"
1210   # Do not test the mpc version.  Assume that it is sufficient, since
1211   # it is in the source tree, and the library has not been built yet
1212   # but it would be included on the link line in the version check below
1213   # hence making the test fail.
1214   have_gmp=yes
1215 fi
1216
1217 # Specify a location for mpfr
1218 # check for this first so it ends up on the link line before gmp.
1219 AC_ARG_WITH(mpfr-dir,
1220 [AS_HELP_STRING([--with-mpfr-dir=PATH], [this option has been REMOVED])],
1221 [AC_MSG_ERROR([The --with-mpfr-dir=PATH option has been removed.
1222 Use --with-mpfr=PATH or --with-mpfr-include=PATH plus --with-mpfr-lib=PATH])])
1223
1224 AC_ARG_WITH(mpfr,
1225 [AS_HELP_STRING([--with-mpfr=PATH],
1226                 [specify prefix directory for installed MPFR package.
1227                  Equivalent to --with-mpfr-include=PATH/include
1228                  plus --with-mpfr-lib=PATH/lib])])
1229 AC_ARG_WITH(mpfr-include,
1230 [AS_HELP_STRING([--with-mpfr-include=PATH],
1231                 [specify directory for installed MPFR include files])])
1232 AC_ARG_WITH(mpfr-lib,
1233 [AS_HELP_STRING([--with-mpfr-lib=PATH],
1234                 [specify directory for the installed MPFR library])])
1235
1236 if test "x$with_mpfr" != x; then
1237   gmplibs="-L$with_mpfr/lib $gmplibs"
1238   gmpinc="-I$with_mpfr/include $gmpinc"
1239 fi
1240 if test "x$with_mpfr_include" != x; then
1241   gmpinc="-I$with_mpfr_include $gmpinc"
1242 fi
1243 if test "x$with_mpfr_lib" != x; then
1244   gmplibs="-L$with_mpfr_lib $gmplibs"
1245 fi
1246 if test "x$with_mpfr$with_mpfr_include$with_mpfr_lib" = x && test -d ${srcdir}/mpfr; then
1247   gmplibs='-L$$r/$(HOST_SUBDIR)/mpfr/'"$lt_cv_objdir $gmplibs"
1248   gmpinc='-I$$r/$(HOST_SUBDIR)/mpfr -I$$s/mpfr '"$gmpinc"
1249   extra_mpc_mpfr_configure_flags='--with-mpfr-include=$$s/mpfr --with-mpfr-lib=$$r/$(HOST_SUBDIR)/mpfr/'"$lt_cv_objdir"
1250   # Do not test the mpfr version.  Assume that it is sufficient, since
1251   # it is in the source tree, and the library has not been built yet
1252   # but it would be included on the link line in the version check below
1253   # hence making the test fail.
1254   have_gmp=yes
1255 fi
1256
1257 # Specify a location for gmp
1258 AC_ARG_WITH(gmp-dir,
1259 [AS_HELP_STRING([--with-gmp-dir=PATH], [this option has been REMOVED])],
1260 [AC_MSG_ERROR([The --with-gmp-dir=PATH option has been removed.
1261 Use --with-gmp=PATH or --with-gmp-include=PATH plus --with-gmp-lib=PATH])])
1262
1263 AC_ARG_WITH(gmp,
1264 [AS_HELP_STRING([--with-gmp=PATH],
1265                 [specify prefix directory for the installed GMP package.
1266                  Equivalent to --with-gmp-include=PATH/include
1267                  plus --with-gmp-lib=PATH/lib])])
1268 AC_ARG_WITH(gmp-include,
1269 [AS_HELP_STRING([--with-gmp-include=PATH],
1270                 [specify directory for installed GMP include files])])
1271 AC_ARG_WITH(gmp-lib,
1272 [AS_HELP_STRING([--with-gmp-lib=PATH],
1273                 [specify directory for the installed GMP library])])
1274
1275
1276 if test "x$with_gmp" != x; then
1277   gmplibs="-L$with_gmp/lib $gmplibs"
1278   gmpinc="-I$with_gmp/include $gmpinc"
1279 fi
1280 if test "x$with_gmp_include" != x; then
1281   gmpinc="-I$with_gmp_include $gmpinc"
1282 fi
1283 if test "x$with_gmp_lib" != x; then
1284   gmplibs="-L$with_gmp_lib $gmplibs"
1285 fi
1286 if test "x$with_gmp$with_gmp_include$with_gmp_lib" = x && test -d ${srcdir}/gmp; then
1287   gmplibs='-L$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir $gmplibs"
1288   gmpinc='-I$$r/$(HOST_SUBDIR)/gmp -I$$s/gmp '"$gmpinc"
1289   extra_mpfr_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1290   extra_mpc_gmp_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1291   # Do not test the gmp version.  Assume that it is sufficient, since
1292   # it is in the source tree, and the library has not been built yet
1293   # but it would be included on the link line in the version check below
1294   # hence making the test fail.
1295   have_gmp=yes
1296 fi
1297
1298 if test -d ${srcdir}/gcc && test "x$have_gmp" = xno; then
1299   have_gmp=yes
1300   saved_CFLAGS="$CFLAGS"
1301   CFLAGS="$CFLAGS $gmpinc"
1302   # Check for the recommended and required versions of GMP.
1303   AC_MSG_CHECKING([for the correct version of gmp.h])
1304   AC_TRY_COMPILE([#include "gmp.h"],[
1305   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1306   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1307   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,2,0)
1308   choke me
1309   #endif
1310   ], [AC_TRY_COMPILE([#include <gmp.h>],[
1311   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1312   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1313   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,3,2)
1314   choke me
1315   #endif
1316   ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1317    [AC_MSG_RESULT([no]); have_gmp=no])
1318
1319   # If we have GMP, check the MPFR version.
1320   if test x"$have_gmp" = xyes; then
1321     # Check for the recommended and required versions of MPFR.
1322     AC_MSG_CHECKING([for the correct version of mpfr.h])
1323     AC_TRY_COMPILE([#include <gmp.h>
1324     #include <mpfr.h>],[
1325     #if MPFR_VERSION < MPFR_VERSION_NUM(2,3,1)
1326     choke me
1327     #endif
1328     ], [AC_TRY_COMPILE([#include <gmp.h>
1329     #include <mpfr.h>],[
1330     #if MPFR_VERSION < MPFR_VERSION_NUM(2,4,2)
1331     choke me
1332     #endif
1333     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1334      [AC_MSG_RESULT([no]); have_gmp=no])
1335   fi
1336
1337   # Check for the MPC header version.
1338   if test x"$have_gmp" = xyes ; then
1339     # Check for the recommended and required versions of MPC.
1340     AC_MSG_CHECKING([for the correct version of mpc.h])
1341     AC_TRY_COMPILE([#include <mpc.h>],[
1342     #if MPC_VERSION < MPC_VERSION_NUM(0,8,0)
1343     choke me
1344     #endif
1345     ], [AC_TRY_COMPILE([#include <mpc.h>],[
1346     #if MPC_VERSION < MPC_VERSION_NUM(0,8,1)
1347     choke me
1348     #endif
1349     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1350      [AC_MSG_RESULT([no]); have_gmp=no])
1351   fi
1352
1353   # Now check the MPFR library.
1354   if test x"$have_gmp" = xyes; then
1355     saved_LIBS="$LIBS"
1356     LIBS="$LIBS $gmplibs"
1357     AC_MSG_CHECKING([for the correct version of the gmp/mpfr/mpc libraries])
1358     AC_TRY_LINK([#include <mpc.h>],[
1359     mpfr_t n;
1360     mpfr_t x;
1361     mpc_t c;
1362     int t;
1363     mpfr_init (n);
1364     mpfr_init (x);
1365     mpfr_atan2 (n, n, x, GMP_RNDN);
1366     mpfr_erfc (n, x, GMP_RNDN);
1367     mpfr_subnormalize (x, t, GMP_RNDN);
1368     mpfr_clear(n);
1369     mpfr_clear(x);
1370     mpc_init2 (c, 53);
1371     mpc_set_ui_ui (c, 1, 1, MPC_RNDNN);
1372     mpc_cosh (c, c, MPC_RNDNN);
1373     mpc_pow (c, c, c, MPC_RNDNN);
1374     mpc_acosh (c, c, MPC_RNDNN);
1375     mpc_clear (c);
1376     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1377     LIBS="$saved_LIBS"
1378   fi
1379
1380   CFLAGS="$saved_CFLAGS"
1381
1382 # The library versions listed in the error message below should match
1383 # the HARD-minimums enforced above.
1384   if test x$have_gmp != xyes; then
1385     AC_MSG_ERROR([Building GCC requires GMP 4.2+, MPFR 2.3.1+ and MPC 0.8.0+.
1386 Try the --with-gmp, --with-mpfr and/or --with-mpc options to specify
1387 their locations.  Source code for these libraries can be found at
1388 their respective hosting sites as well as at
1389 ftp://gcc.gnu.org/pub/gcc/infrastructure/.  See also
1390 http://gcc.gnu.org/install/prerequisites.html for additional info.  If
1391 you obtained GMP, MPFR and/or MPC from a vendor distribution package,
1392 make sure that you have installed both the libraries and the header
1393 files.  They may be located in separate packages.])
1394   fi
1395 fi
1396
1397 # Flags needed for both GMP, MPFR and/or MPC.
1398 AC_SUBST(gmplibs)
1399 AC_SUBST(gmpinc)
1400 AC_SUBST(extra_mpfr_configure_flags)
1401 AC_SUBST(extra_mpc_gmp_configure_flags)
1402 AC_SUBST(extra_mpc_mpfr_configure_flags)
1403
1404 # Allow host libstdc++ to be specified for static linking with PPL.
1405 AC_ARG_WITH(host-libstdcxx,
1406 [AS_HELP_STRING([--with-host-libstdcxx=L],
1407                 [use linker arguments L to link with libstdc++
1408                  when linking with PPL])])
1409
1410 case $with_host_libstdcxx in
1411   no|yes)
1412     AC_MSG_ERROR([-with-host-libstdcxx needs an argument])
1413     ;;
1414 esac
1415
1416 # Linker flags to use for stage1 or when not boostrapping.
1417 AC_ARG_WITH(stage1-ldflags,
1418 [AS_HELP_STRING([--with-stage1-ldflags=FLAGS], [linker flags for stage1])],
1419 [if test "$withval" = "no" -o "$withval" = "yes"; then
1420    stage1_ldflags=
1421  else
1422    stage1_ldflags=$withval
1423  fi],
1424 [stage1_ldflags=])
1425 AC_SUBST(stage1_ldflags)
1426
1427 # Libraries to use for stage1 or when not bootstrapping.
1428 AC_ARG_WITH(stage1-libs,
1429 [AS_HELP_STRING([--with-stage1-libs=LIBS], [libraries for stage1])],
1430 [if test "$withval" = "no" -o "$withval" = "yes"; then
1431    stage1_libs=
1432  else
1433    stage1_libs=$withval
1434  fi],
1435 [stage1_libs=$with_host_libstdcxx])
1436 AC_SUBST(stage1_libs)
1437
1438 # Libraries to use for stage2 and later builds.  This defaults to the
1439 # argument passed to --with-host-libstdcxx.
1440 AC_ARG_WITH(boot-libs,
1441 [AS_HELP_STRING([--with-boot-libs=LIBS], [libraries for stage2 and later])],
1442 [if test "$withval" = "no" -o "$withval" = "yes"; then
1443    poststage1_libs=
1444  else
1445    poststage1_libs=$withval
1446  fi],
1447 [poststage1_libs=$with_host_libstdcxx])
1448 AC_SUBST(poststage1_libs)
1449
1450 # Linker flags to use for stage2 and later builds.
1451 AC_ARG_WITH(boot-ldflags,
1452 [AS_HELP_STRING([--with-boot-ldflags=FLAGS],
1453                 [linker flags for stage2 and later])],
1454 [if test "$withval" = "no" -o "$withval" = "yes"; then
1455    poststage1_ldflags=
1456  else
1457    poststage1_ldflags=$withval
1458  fi],
1459 [poststage1_ldflags=
1460  # In stages 2 and 3, default to linking libstdc++ and libgcc
1461  # statically.  But if the user explicitly specified the libraries to
1462  # use, trust that they are doing what they want.
1463  if test "$poststage1_libs" = ""; then
1464    poststage1_ldflags="-static-libstdc++ -static-libgcc"
1465  fi])
1466 AC_SUBST(poststage1_ldflags)
1467
1468 # Check for PPL
1469 ppllibs=
1470 pplinc=
1471 pwllib=
1472
1473 AC_ARG_WITH(ppl,
1474 [AS_HELP_STRING([--with-ppl=PATH],
1475                 [specify prefix directory for the installed PPL package.
1476                  Equivalent to --with-ppl-include=PATH/include
1477                  plus --with-ppl-lib=PATH/lib])])
1478 AC_ARG_WITH(ppl-include,
1479 [AS_HELP_STRING([--with-ppl-include=PATH],
1480                 [specify directory for installed PPL include files])])
1481 AC_ARG_WITH(ppl-lib,
1482 [AS_HELP_STRING([--with-ppl-lib=PATH],
1483                 [specify directory for the installed PPL library])])
1484
1485 AC_ARG_ENABLE(ppl-version-check,
1486 [AS_HELP_STRING([--disable-ppl-version-check],
1487                 [disable check for PPL version])])
1488
1489 case $with_ppl in
1490   yes | no | "")
1491     ;;
1492   *)
1493     ppllibs="-L$with_ppl/lib"
1494     pplinc="-I$with_ppl/include $pplinc"
1495     if test -d "$with_ppl/lib" && test -d "$with_ppl/include"; then
1496       with_ppl=yes
1497     else
1498       AC_MSG_ERROR([cannot find directories "$with_ppl/lib" or "$with_ppl/include"])
1499     fi
1500     ;;
1501 esac
1502
1503 if test x"$with_ppl_include" != x; then
1504   pplinc="-I$with_ppl_include $pplinc"
1505   with_ppl=yes
1506 fi
1507
1508 if test "x$with_ppl_lib" != x; then
1509   ppllibs="-L$with_ppl_lib"
1510   with_ppl=yes
1511 fi
1512
1513 if test x"$with_ppl$with_ppl_include$with_ppl_lib" = x && test -d ${srcdir}/ppl; then
1514   if test x"$enable_watchdog" = xyes; then
1515     pwllib="-lpwl"
1516   fi
1517   ppllibs='-L$$r/$(HOST_SUBDIR)/ppl/interfaces/C/'"$lt_cv_objdir"' -L$$r/$(HOST_SUBDIR)/ppl/src/'"$lt_cv_objdir"
1518   pplinc='-I$$r/$(HOST_SUBDIR)/ppl/src -I$$r/$(HOST_SUBDIR)/ppl/interfaces/C '
1519   enable_ppl_version_check=no
1520   with_ppl=yes
1521 fi
1522
1523 if test "x$with_ppl" != xno; then
1524   if test "x$pwllib" = x; then
1525     saved_LIBS="$LIBS"
1526     LIBS="$LIBS $ppllibs -lstdc++ -lm"
1527     AC_CHECK_LIB(pwl, PWL_handle_timeout, [pwllib="-lpwl"])
1528     LIBS="$saved_LIBS"
1529   fi
1530
1531   ppllibs="$ppllibs -lppl_c -lppl $pwllib -lgmpxx"
1532
1533   if test "$enable_ppl_version_check" != no; then
1534     saved_CFLAGS="$CFLAGS"
1535     CFLAGS="$CFLAGS $pplinc $gmpinc"
1536     AC_MSG_CHECKING([for version 0.11 (revision 0 or later) of PPL])
1537     AC_TRY_COMPILE([#include "ppl_c.h"],[
1538     #if PPL_VERSION_MAJOR != 0 || PPL_VERSION_MINOR < 11
1539     choke me
1540     #endif
1541     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); ppllibs= ; pplinc= ; with_ppl=no ])
1542     CFLAGS="$saved_CFLAGS"
1543   fi
1544 fi
1545
1546 # Flags needed for PPL
1547 AC_SUBST(ppllibs)
1548 AC_SUBST(pplinc)
1549
1550
1551 # Check for CLOOG
1552
1553 dnl Provide configure switches and initialize clooginc & clooglibs
1554 dnl with user input.
1555 CLOOG_INIT_FLAGS
1556 if test "x$with_ppl" = "xno"; then
1557   dnl Only execute fail-action, if CLooG has been requested.
1558   CLOOG_REQUESTED([graphite_requested=yes], [graphite_requested=no])
1559   if test "${graphite_requested}" = yes; then
1560     AC_MSG_ERROR([Unable to find a usable PPL.  See config.log for details.])
1561   fi
1562   with_cloog=no
1563 fi
1564 if test "x${with_cloog}" = x && test "x${with_cloog_include}" = x \
1565   && test "x${with_cloog_lib}" = x && test -d ${srcdir}/cloog; then
1566   clooglibs='-L$$r/$(HOST_SUBDIR)/cloog/'"$lt_cv_objdir"' '
1567   clooginc='-I$$r/$(HOST_SUBDIR)/cloog/include -I$$s/cloog/include '
1568 fi
1569 if test "x$with_cloog" != "xno"; then
1570   dnl The minimal version of CLooG required for Graphite.
1571   dnl
1572   dnl If we use CLooG-Legacy, the provided version information is
1573   dnl ignored.
1574   CLOOG_CHECK_VERSION(0,16,1)
1575
1576   dnl Only execute fail-action, if CLooG has been requested.
1577   CLOOG_IF_FAILED([
1578     AC_MSG_ERROR([Unable to find a usable CLooG.  See config.log for details.])])
1579 fi
1580
1581 # Check for LTO support.
1582 AC_ARG_ENABLE(lto,
1583 [AS_HELP_STRING([--enable-lto], [enable link time optimization support])],
1584 enable_lto=$enableval,
1585 enable_lto=yes; default_enable_lto=yes)
1586
1587 ACX_ELF_TARGET_IFELSE([# ELF platforms build the lto-plugin always.
1588   build_lto_plugin=yes
1589 ],[if test x"$default_enable_lto" = x"yes" ; then
1590     case $target in
1591       *-apple-darwin9* | *-cygwin* | *-mingw*) ;;
1592       # On other non-ELF platforms, LTO has yet to be validated.
1593       *) enable_lto=no ;;
1594     esac
1595   else
1596   # Apart from ELF platforms, only Windows and Darwin support LTO so far.
1597   # It would also be nice to check the binutils support, but we don't
1598   # have gcc_GAS_CHECK_FEATURE available here.  For now, we'll just
1599   # warn during gcc/ subconfigure; unless you're bootstrapping with
1600   # -flto it won't be needed until after installation anyway.
1601     case $target in
1602       *-cygwin* | *-mingw* | *-apple-darwin*) ;;
1603       *) if test x"$enable_lto" = x"yes"; then
1604         AC_MSG_ERROR([LTO support is not enabled for this target.])
1605         fi
1606       ;;
1607     esac
1608   fi
1609   # Among non-ELF, only Windows platforms support the lto-plugin so far.
1610   # Build it unless LTO was explicitly disabled.
1611   case $target in
1612     *-cygwin* | *-mingw*) build_lto_plugin=$enable_lto ;;
1613     *) ;;
1614   esac
1615 ])
1616
1617
1618 # By default, C is the only stage 1 language.
1619 stage1_languages=,c,
1620
1621 # Target libraries that we bootstrap.
1622 bootstrap_target_libs=,target-libgcc,
1623
1624 # Figure out what language subdirectories are present.
1625 # Look if the user specified --enable-languages="..."; if not, use
1626 # the environment variable $LANGUAGES if defined. $LANGUAGES might
1627 # go away some day.
1628 # NB:  embedded tabs in this IF block -- do not untabify
1629 if test -d ${srcdir}/gcc; then
1630   if test x"${enable_languages+set}" != xset; then
1631     if test x"${LANGUAGES+set}" = xset; then
1632       enable_languages="${LANGUAGES}"
1633         echo configure.in: warning: setting LANGUAGES is deprecated, use --enable-languages instead 1>&2
1634     else
1635       enable_languages=all
1636     fi
1637   else
1638     if test x"${enable_languages}" = x ||
1639        test x"${enable_languages}" = xyes;
1640        then
1641       echo configure.in: --enable-languages needs at least one language argument 1>&2
1642       exit 1
1643     fi
1644   fi
1645   enable_languages=`echo "${enable_languages}" | sed -e 's/[[   ,]][[   ,]]*/,/g' -e 's/,$//'`
1646
1647   # 'f95' is the old name for the 'fortran' language. We issue a warning
1648   # and make the substitution.
1649   case ,${enable_languages}, in
1650     *,f95,*)
1651       echo configure.in: warning: 'f95' as language name is deprecated, use 'fortran' instead 1>&2
1652       enable_languages=`echo "${enable_languages}" | sed -e 's/f95/fortran/g'`
1653       ;;
1654   esac
1655
1656   # First scan to see if an enabled language requires some other language.
1657   # We assume that a given config-lang.in will list all the language
1658   # front ends it requires, even if some are required indirectly.
1659   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1660     case ${lang_frag} in
1661       ..) ;;
1662       # The odd quoting in the next line works around
1663       # an apparent bug in bash 1.12 on linux.
1664       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1665       *)
1666         # From the config-lang.in, get $language, $lang_requires, and
1667         # $lang_requires_boot_languages.
1668         language=
1669         lang_requires=
1670         lang_requires_boot_languages=
1671         . ${lang_frag}
1672         for other in ${lang_requires} ${lang_requires_boot_languages}; do
1673           case ,${enable_languages}, in
1674             *,$other,*) ;;
1675             *,all,*) ;;
1676             *,$language,*)
1677               echo " \`$other' language required by \`$language'; enabling" 1>&2
1678               enable_languages="${enable_languages},${other}"
1679               ;;
1680           esac
1681         done
1682         for other in ${lang_requires_boot_languages} ; do
1683           if test "$other" != "c"; then
1684             case ,${enable_stage1_languages}, in
1685               *,$other,*) ;;
1686               *,all,*) ;;
1687               *)
1688                 case ,${enable_languages}, in
1689                   *,$language,*)
1690                     echo " '$other' language required by '$language' in stage 1; enabling" 1>&2
1691                     enable_stage1_languages="$enable_stage1_languages,${other}"
1692                     ;;
1693                 esac
1694                 ;;
1695             esac
1696           fi
1697         done
1698         ;;
1699     esac
1700   done
1701
1702   new_enable_languages=,c,
1703
1704   # If LTO is enabled, add the LTO front end.
1705   extra_host_libiberty_configure_flags=
1706   if test "$enable_lto" = "yes" ; then
1707     case ,${enable_languages}, in
1708       *,lto,*) ;;
1709       *) enable_languages="${enable_languages},lto" ;;
1710     esac
1711     if test "${build_lto_plugin}" = "yes" ; then
1712       configdirs="$configdirs lto-plugin"
1713       extra_host_libiberty_configure_flags=--enable-shared
1714     fi
1715   fi
1716   AC_SUBST(extra_host_libiberty_configure_flags)
1717
1718   missing_languages=`echo ",$enable_languages," | sed -e s/,all,/,/ -e s/,c,/,/ `
1719   potential_languages=,c,
1720
1721   enabled_target_libs=
1722   disabled_target_libs=
1723
1724   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1725     case ${lang_frag} in
1726       ..) ;;
1727       # The odd quoting in the next line works around
1728       # an apparent bug in bash 1.12 on linux.
1729       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1730       *)
1731         # From the config-lang.in, get $language, $target_libs,
1732         # $lang_dirs, $boot_language, and $build_by_default
1733         language=
1734         target_libs=
1735         lang_dirs=
1736         subdir_requires=
1737         boot_language=no
1738         build_by_default=yes
1739         . ${lang_frag}
1740         if test x${language} = x; then
1741           echo "${lang_frag} doesn't set \$language." 1>&2
1742           exit 1
1743         fi
1744
1745         if test "$language" = "c++" \
1746            && test "$ENABLE_BUILD_WITH_CXX" = "yes"; then
1747           boot_language=yes
1748         fi
1749
1750         case ,${enable_languages}, in
1751           *,${language},*)
1752             # Language was explicitly selected; include it.
1753             add_this_lang=yes
1754             ;;
1755           *,all,*)
1756             # 'all' was selected, select it if it is a default language
1757             add_this_lang=${build_by_default}
1758             ;;
1759           *)
1760             add_this_lang=no
1761             ;;
1762         esac
1763
1764         # Disable languages that need other directories if these aren't available.
1765         for i in $subdir_requires; do
1766           test -f "$srcdir/gcc/$i/config-lang.in" && continue
1767           case ,${enable_languages}, in
1768             *,${language},*)
1769               # Specifically requested language; tell them.
1770               AC_MSG_ERROR([The gcc/$i directory contains parts of $language but is missing])
1771               ;;
1772             *)
1773               # Silently disable.
1774               add_this_lang=unsupported
1775               ;;
1776           esac
1777         done
1778
1779         # Disable Ada if no preexisting GNAT is available.
1780         case ,${enable_languages},:${language}:${have_gnat} in
1781           *,${language},*:ada:no)
1782             # Specifically requested language; tell them.
1783             AC_MSG_ERROR([GNAT is required to build $language])
1784             ;;
1785           *:ada:no)
1786             # Silently disable.
1787             add_this_lang=unsupported
1788             ;;
1789         esac
1790
1791         # Disable a language that is unsupported by the target.
1792         case " $unsupported_languages " in
1793           *" $language "*)
1794             add_this_lang=unsupported
1795             ;;
1796         esac
1797
1798         case $add_this_lang in
1799           unsupported)
1800             # Remove language-dependent dirs.
1801             disabled_target_libs="$disabled_target_libs $target_libs"
1802             noconfigdirs="$noconfigdirs $lang_dirs"
1803             ;;
1804           no)
1805             # Remove language-dependent dirs; still show language as supported.
1806             disabled_target_libs="$disabled_target_libs $target_libs"
1807             noconfigdirs="$noconfigdirs $lang_dirs"
1808             potential_languages="${potential_languages}${language},"
1809             ;;
1810           yes)
1811             new_enable_languages="${new_enable_languages}${language},"
1812             potential_languages="${potential_languages}${language},"
1813             missing_languages=`echo "$missing_languages" | sed "s/,$language,/,/"`
1814             enabled_target_libs="$enabled_target_libs $target_libs"
1815             case "${boot_language}:,$enable_stage1_languages," in
1816               yes:* | *:*,$language,* | *:*,yes, | *:*,all,)
1817                 # Add to (comma-separated) list of stage 1 languages.
1818                 case ",$stage1_languages," in
1819                   *,$language,* | ,yes, | ,all,) ;;
1820                   *) stage1_languages="${stage1_languages}${language}," ;;
1821                 esac
1822                 # We need to bootstrap any supporting libraries.
1823                 bootstrap_target_libs="${bootstrap_target_libs}${target_libs},"
1824                 ;;
1825             esac
1826             ;;
1827         esac
1828         ;;
1829     esac
1830   done
1831
1832   # Add target libraries which are only needed for disabled languages
1833   # to noconfigdirs.
1834   if test -n "$disabled_target_libs"; then
1835     for dir in $disabled_target_libs; do
1836       case " $enabled_target_libs " in
1837       *" ${dir} "*) ;;
1838       *) noconfigdirs="$noconfigdirs $dir" ;;
1839       esac
1840     done
1841   fi
1842
1843   AC_ARG_ENABLE(stage1-languages,
1844   [AS_HELP_STRING([[--enable-stage1-languages[=all]]],
1845                   [choose additional languages to build during
1846                   stage1.  Mostly useful for compiler development])],
1847   [case ,${enable_stage1_languages}, in
1848     ,no,|,,)
1849       # Set it to something that will have no effect in the loop below
1850       enable_stage1_languages=c ;;
1851     ,yes,)
1852       enable_stage1_languages=`echo $new_enable_languages | \
1853         sed -e "s/^,//" -e "s/,$//" ` ;;
1854     *,all,*)
1855       enable_stage1_languages=`echo ,$enable_stage1_languages, | \
1856         sed -e "s/,all,/$new_enable_languages/" -e "s/^,//" -e "s/,$//" ` ;;
1857   esac
1858
1859   # Add "good" languages from enable_stage1_languages to stage1_languages,
1860   # while "bad" languages go in missing_languages.  Leave no duplicates.
1861   for i in `echo $enable_stage1_languages | sed 's/,/ /g' `; do
1862     case $potential_languages in
1863       *,$i,*)
1864         case $stage1_languages in
1865           *,$i,*) ;;
1866           *) stage1_languages="$stage1_languages$i," ;;
1867         esac ;;
1868       *)
1869         case $missing_languages in
1870           *,$i,*) ;;
1871           *) missing_languages="$missing_languages$i," ;;
1872         esac ;;
1873      esac
1874   done])
1875
1876   # Remove leading/trailing commas that were added for simplicity
1877   potential_languages=`echo "$potential_languages" | sed -e "s/^,//" -e "s/,$//"`
1878   missing_languages=`echo "$missing_languages" | sed -e "s/^,//" -e "s/,$//"`
1879   stage1_languages=`echo "$stage1_languages" | sed -e "s/^,//" -e "s/,$//"`
1880   new_enable_languages=`echo "$new_enable_languages" | sed -e "s/^,//" -e "s/,$//"`
1881
1882   if test "x$missing_languages" != x; then
1883     AC_MSG_ERROR([
1884 The following requested languages could not be built: ${missing_languages}
1885 Supported languages are: ${potential_languages}])
1886   fi
1887   if test "x$new_enable_languages" != "x$enable_languages"; then
1888     echo The following languages will be built: ${new_enable_languages}
1889     enable_languages="$new_enable_languages"
1890   fi
1891
1892   AC_SUBST(stage1_languages)
1893   ac_configure_args=`echo " $ac_configure_args" | sed -e "s/ '--enable-languages=[[^ ]]*'//g" -e "s/$/ '--enable-languages="$enable_languages"'/" `
1894 fi
1895
1896 # Handle --disable-<component> generically.
1897 for dir in $configdirs $build_configdirs $target_configdirs ; do
1898   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g -e s/-/_/g`
1899   varname=`echo $dirname | sed -e s/+/_/g`
1900   if eval test x\${enable_${varname}} "=" xno ; then
1901     noconfigdirs="$noconfigdirs $dir"
1902   fi
1903 done
1904
1905 # Check for Boehm's garbage collector
1906 AC_ARG_ENABLE(objc-gc,
1907 [AS_HELP_STRING([--enable-objc-gc],
1908                 [enable use of Boehm's garbage collector with the
1909                  GNU Objective-C runtime])],
1910 [case ,${enable_languages},:${enable_objc_gc}:${noconfigdirs} in
1911   *,objc,*:*:yes:*target-boehm-gc*)
1912     AC_MSG_ERROR([Boehm's garbage collector was requested yet not supported in this configuration])
1913     ;;
1914 esac])
1915
1916 # Make sure we only build Boehm's garbage collector if required.
1917 case ,${enable_languages},:${enable_objc_gc} in
1918   *,objc,*:yes)
1919     # Keep target-boehm-gc if requested for Objective-C.
1920     ;;
1921   *)
1922     # Otherwise remove target-boehm-gc depending on target-libjava.
1923     if echo " ${noconfigdirs} " | grep "target-libjava" >/dev/null 2>&1; then
1924       noconfigdirs="$noconfigdirs target-boehm-gc"
1925     fi
1926     ;;
1927 esac
1928
1929 # Remove the entries in $skipdirs and $noconfigdirs from $configdirs,
1930 # $build_configdirs and $target_configdirs.
1931 # If we have the source for $noconfigdirs entries, add them to $notsupp.
1932
1933 notsupp=""
1934 for dir in . $skipdirs $noconfigdirs ; do
1935   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g`
1936   if test $dir != .  && echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1937     configdirs=`echo " ${configdirs} " | sed -e "s/ ${dir} / /"`
1938     if test -r $srcdir/$dirname/configure ; then
1939       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1940         true
1941       else
1942         notsupp="$notsupp $dir"
1943       fi
1944     fi
1945   fi
1946   if test $dir != .  && echo " ${build_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1947     build_configdirs=`echo " ${build_configdirs} " | sed -e "s/ ${dir} / /"`
1948     if test -r $srcdir/$dirname/configure ; then
1949       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1950         true
1951       else
1952         notsupp="$notsupp $dir"
1953       fi
1954     fi
1955   fi
1956   if test $dir != . && echo " ${target_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1957     target_configdirs=`echo " ${target_configdirs} " | sed -e "s/ ${dir} / /"`
1958     if test -r $srcdir/$dirname/configure ; then
1959       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1960         true
1961       else
1962         notsupp="$notsupp $dir"
1963       fi
1964     fi
1965   fi
1966 done
1967
1968 # Sometimes the tools are distributed with libiberty but with no other
1969 # libraries.  In that case, we don't want to build target-libiberty.
1970 # Don't let libgcc imply libiberty either.
1971 if test -n "${target_configdirs}" ; then
1972   libgcc=
1973   others=
1974   for i in `echo ${target_configdirs} | sed -e s/target-//g` ; do
1975     if test "$i" = "libgcc"; then
1976       libgcc=target-libgcc
1977     elif test "$i" != "libiberty" ; then
1978       if test -r $srcdir/$i/configure ; then
1979         others=yes;
1980         break;
1981       fi
1982     fi
1983   done
1984   if test -z "${others}" ; then
1985     target_configdirs=$libgcc
1986   fi
1987 fi
1988
1989 # Quietly strip out all directories which aren't configurable in this tree.
1990 # This relies on all configurable subdirectories being autoconfiscated, which
1991 # is now the case.
1992 build_configdirs_all="$build_configdirs"
1993 build_configdirs=
1994 for i in ${build_configdirs_all} ; do
1995   j=`echo $i | sed -e s/build-//g`
1996   if test -f ${srcdir}/$j/configure ; then
1997     build_configdirs="${build_configdirs} $i"
1998   fi
1999 done
2000
2001 configdirs_all="$configdirs"
2002 configdirs=
2003 for i in ${configdirs_all} ; do
2004   if test -f ${srcdir}/$i/configure ; then
2005     configdirs="${configdirs} $i"
2006   fi
2007 done
2008
2009 target_configdirs_all="$target_configdirs"
2010 target_configdirs=
2011 for i in ${target_configdirs_all} ; do
2012   j=`echo $i | sed -e s/target-//g`
2013   if test -f ${srcdir}/$j/configure ; then
2014     target_configdirs="${target_configdirs} $i"
2015   fi
2016 done
2017
2018 # Produce a warning message for the subdirs we can't configure.
2019 # This isn't especially interesting in the Cygnus tree, but in the individual
2020 # FSF releases, it's important to let people know when their machine isn't
2021 # supported by the one or two programs in a package.
2022
2023 if test -n "${notsupp}" && test -z "${norecursion}" ; then
2024   # If $appdirs is non-empty, at least one of those directories must still
2025   # be configured, or we error out.  (E.g., if the gas release supports a
2026   # specified target in some subdirs but not the gas subdir, we shouldn't
2027   # pretend that all is well.)
2028   if test -n "$appdirs" ; then
2029     for dir in $appdirs ; do
2030       if test -r $dir/Makefile.in ; then
2031         if echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2032           appdirs=""
2033           break
2034         fi
2035         if echo " ${target_configdirs} " | grep " target-${dir} " >/dev/null 2>&1; then
2036           appdirs=""
2037           break
2038         fi
2039       fi
2040     done
2041     if test -n "$appdirs" ; then
2042       echo "*** This configuration is not supported by this package." 1>&2
2043       exit 1
2044     fi
2045   fi
2046   # Okay, some application will build, or we don't care to check.  Still
2047   # notify of subdirs not getting built.
2048   echo "*** This configuration is not supported in the following subdirectories:" 1>&2
2049   echo "    ${notsupp}" 1>&2
2050   echo "    (Any other directories should still work fine.)" 1>&2
2051 fi
2052
2053 case "$host" in
2054   *msdosdjgpp*)
2055     enable_gdbtk=no ;;
2056 esac
2057
2058 # To find our prefix, in gcc_cv_tool_prefix.
2059 ACX_TOOL_DIRS
2060
2061 copy_dirs=
2062
2063 AC_ARG_WITH([build-sysroot],
2064   [AS_HELP_STRING([--with-build-sysroot=SYSROOT],
2065                   [use sysroot as the system root during the build])],
2066   [if test x"$withval" != x ; then
2067      SYSROOT_CFLAGS_FOR_TARGET="--sysroot=$withval"
2068    fi],
2069   [SYSROOT_CFLAGS_FOR_TARGET=])
2070 AC_SUBST(SYSROOT_CFLAGS_FOR_TARGET)
2071
2072 AC_ARG_WITH([debug-prefix-map],
2073   [AS_HELP_STRING([--with-debug-prefix-map='A=B C=D ...'],
2074                   [map A to B, C to D ... in debug information])],
2075   [if test x"$withval" != x; then
2076      DEBUG_PREFIX_CFLAGS_FOR_TARGET=
2077      for debug_map in $withval; do
2078        DEBUG_PREFIX_CFLAGS_FOR_TARGET="$DEBUG_PREFIX_CFLAGS_FOR_TARGET -fdebug-prefix-map=$debug_map"
2079      done
2080    fi],
2081   [DEBUG_PREFIX_CFLAGS_FOR_TARGET=])
2082 AC_SUBST(DEBUG_PREFIX_CFLAGS_FOR_TARGET)
2083
2084 # During gcc bootstrap, if we use some random cc for stage1 then CFLAGS
2085 # might be empty or "-g".  We don't require a C++ compiler, so CXXFLAGS
2086 # might also be empty (or "-g", if a non-GCC C++ compiler is in the path).
2087 # We want to ensure that TARGET libraries (which we know are built with
2088 # gcc) are built with "-O2 -g", so include those options when setting
2089 # CFLAGS_FOR_TARGET and CXXFLAGS_FOR_TARGET.
2090 if test "x$CFLAGS_FOR_TARGET" = x; then
2091   CFLAGS_FOR_TARGET=$CFLAGS
2092   case " $CFLAGS " in
2093     *" -O2 "*) ;;
2094     *) CFLAGS_FOR_TARGET="-O2 $CFLAGS" ;;
2095   esac
2096   case " $CFLAGS " in
2097     *" -g "* | *" -g3 "*) ;;
2098     *) CFLAGS_FOR_TARGET="-g $CFLAGS" ;;
2099   esac
2100 fi
2101 AC_SUBST(CFLAGS_FOR_TARGET)
2102
2103 if test "x$CXXFLAGS_FOR_TARGET" = x; then
2104   CXXFLAGS_FOR_TARGET=$CXXFLAGS
2105   case " $CXXFLAGS " in
2106     *" -O2 "*) ;;
2107     *) CXXFLAGS_FOR_TARGET="-O2 $CXXFLAGS" ;;
2108   esac
2109   case " $CXXFLAGS " in
2110     *" -g "* | *" -g3 "*) ;;
2111     *) CXXFLAGS_FOR_TARGET="-g $CXXFLAGS" ;;
2112   esac
2113 fi
2114 AC_SUBST(CXXFLAGS_FOR_TARGET)
2115
2116 AC_SUBST(LDFLAGS_FOR_TARGET)
2117
2118 # Handle --with-headers=XXX.  If the value is not "yes", the contents of
2119 # the named directory are copied to $(tooldir)/sys-include.
2120 if test x"${with_headers}" != x && test x"${with_headers}" != xno ; then
2121   if test x${is_cross_compiler} = xno ; then
2122     echo 1>&2 '***' --with-headers is only supported when cross compiling
2123     exit 1
2124   fi
2125   if test x"${with_headers}" != xyes ; then
2126     x=${gcc_cv_tool_prefix}
2127     copy_dirs="${copy_dirs} ${with_headers} $x/${target_noncanonical}/sys-include"
2128   fi
2129 fi
2130
2131 # Handle --with-libs=XXX.  If the value is not "yes", the contents of
2132 # the name directories are copied to $(tooldir)/lib.  Multiple directories
2133 # are permitted.
2134 if test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
2135   if test x${is_cross_compiler} = xno ; then
2136     echo 1>&2 '***' --with-libs is only supported when cross compiling
2137     exit 1
2138   fi
2139   if test x"${with_libs}" != xyes ; then
2140     # Copy the libraries in reverse order, so that files in the first named
2141     # library override files in subsequent libraries.
2142     x=${gcc_cv_tool_prefix}
2143     for l in ${with_libs}; do
2144       copy_dirs="$l $x/${target_noncanonical}/lib ${copy_dirs}"
2145     done
2146   fi
2147 fi
2148
2149 # Set with_gnu_as, with_gnu_ld, and with_system_zlib as appropriate.
2150 #
2151 # This is done by determining whether or not the appropriate directory
2152 # is available, and by checking whether or not specific configurations
2153 # have requested that this magic not happen.
2154 #
2155 # The command line options always override the explicit settings in
2156 # configure.in, and the settings in configure.in override this magic.
2157 #
2158 # If the default for a toolchain is to use GNU as and ld, and you don't
2159 # want to do that, then you should use the --without-gnu-as and
2160 # --without-gnu-ld options for the configure script.  Similarly, if
2161 # the default is to use the included zlib and you don't want to do that,
2162 # you should use the --with-system-zlib option for the configure script.
2163
2164 if test x${use_gnu_as} = x &&
2165    echo " ${configdirs} " | grep " gas " > /dev/null 2>&1 ; then
2166   with_gnu_as=yes
2167   extra_host_args="$extra_host_args --with-gnu-as"
2168 fi
2169
2170 if test x${use_gnu_ld} = x &&
2171    echo " ${configdirs} " | egrep " (go)?ld " > /dev/null 2>&1 ; then
2172   with_gnu_ld=yes
2173   extra_host_args="$extra_host_args --with-gnu-ld"
2174 fi
2175
2176 if test x${use_included_zlib} = x &&
2177    echo " ${configdirs} " | grep " zlib " > /dev/null 2>&1 ; then
2178   :
2179 else
2180   with_system_zlib=yes
2181   extra_host_args="$extra_host_args --with-system-zlib"
2182 fi
2183
2184 # If using newlib, add --with-newlib to the extra_host_args so that gcc/configure
2185 # can detect this case.
2186
2187 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " target-newlib " > /dev/null 2>&1 ; then
2188   with_newlib=yes
2189   extra_host_args="$extra_host_args --with-newlib"
2190 fi
2191
2192 # Handle ${copy_dirs}
2193 set fnord ${copy_dirs}
2194 shift
2195 while test $# != 0 ; do
2196   if test -f $2/COPIED && test x"`cat $2/COPIED`" = x"$1" ; then
2197     :
2198   else
2199     echo Copying $1 to $2
2200
2201     # Use the install script to create the directory and all required
2202     # parent directories.
2203     if test -d $2 ; then
2204       :
2205     else
2206       echo >config.temp
2207       ${srcdir}/install-sh -c -m 644 config.temp $2/COPIED
2208     fi
2209
2210     # Copy the directory, assuming we have tar.
2211     # FIXME: Should we use B in the second tar?  Not all systems support it.
2212     (cd $1; tar -cf - .) | (cd $2; tar -xpf -)
2213
2214     # It is the responsibility of the user to correctly adjust all
2215     # symlinks.  If somebody can figure out how to handle them correctly
2216     # here, feel free to add the code.
2217
2218     echo $1 > $2/COPIED
2219   fi
2220   shift; shift
2221 done
2222
2223 # Determine a target-dependent exec_prefix that the installed
2224 # gcc will search in.  Keep this list sorted by triplet, with
2225 # the *-*-osname triplets last.
2226 md_exec_prefix=
2227 case "${target}" in
2228   i[[34567]]86-pc-msdosdjgpp*)
2229     md_exec_prefix=/dev/env/DJDIR/bin
2230     ;;
2231   *-*-hpux* | \
2232   *-*-nto-qnx* | \
2233   *-*-solaris2*)
2234     md_exec_prefix=/usr/ccs/bin
2235     ;;
2236 esac
2237
2238 extra_arflags_for_target=
2239 extra_nmflags_for_target=
2240 extra_ranlibflags_for_target=
2241 target_makefile_frag=/dev/null
2242 case "${target}" in
2243   spu-*-*)
2244     target_makefile_frag="config/mt-spu"
2245     ;;
2246   mips*-sde-elf*)
2247     target_makefile_frag="config/mt-sde"
2248     ;;
2249   mipsisa*-*-elfoabi*)
2250     target_makefile_frag="config/mt-mips-elfoabi"
2251     ;;
2252   mips*-*-*linux* | mips*-*-gnu*)
2253     target_makefile_frag="config/mt-mips-gnu"
2254     ;;
2255   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
2256     target_makefile_frag="config/mt-gnu"
2257     ;;
2258   *-*-aix4.[[3456789]]* | *-*-aix[[56789]].*)
2259     # nm and ar from AIX 4.3 and above require -X32_64 flag to all ar and nm
2260     # commands to handle both 32-bit and 64-bit objects.  These flags are
2261     # harmless if we're using GNU nm or ar.
2262     extra_arflags_for_target=" -X32_64"
2263     extra_nmflags_for_target=" -B -X32_64"
2264     ;;
2265   *-*-darwin[[3-9]]*)
2266     # ranlib before Darwin10 requires the -c flag to look at common symbols.
2267     extra_ranlibflags_for_target=" -c"
2268     ;;
2269 esac
2270
2271 alphaieee_frag=/dev/null
2272 case $target in
2273   alpha*-*-*)
2274     # This just makes sure to use the -mieee option to build target libs.
2275     # This should probably be set individually by each library.
2276     alphaieee_frag="config/mt-alphaieee"
2277     ;;
2278 esac
2279
2280 # If --enable-target-optspace always use -Os instead of -O2 to build
2281 # the target libraries, similarly if it is not specified, use -Os
2282 # on selected platforms.
2283 ospace_frag=/dev/null
2284 case "${enable_target_optspace}:${target}" in
2285   yes:*)
2286     ospace_frag="config/mt-ospace"
2287     ;;
2288   :d30v-*)
2289     ospace_frag="config/mt-d30v"
2290     ;;
2291   :m32r-* | :d10v-* | :fr30-*)
2292     ospace_frag="config/mt-ospace"
2293     ;;
2294   no:* | :*)
2295     ;;
2296   *)
2297     echo "*** bad value \"${enable_target_optspace}\" for --enable-target-optspace flag; ignored" 1>&2
2298     ;;
2299 esac
2300
2301 # Default to using --with-stabs for certain targets.
2302 if test x${with_stabs} = x ; then
2303   case "${target}" in
2304   mips*-*-irix[[56]]*)
2305     ;;
2306   mips*-*-* | alpha*-*-osf*)
2307     with_stabs=yes;
2308     extra_host_args="${extra_host_args} --with-stabs"
2309     ;;
2310   esac
2311 fi
2312
2313 # Some systems (e.g., one of the i386-aix systems the gas testers are
2314 # using) don't handle "\$" correctly, so don't use it here.
2315 tooldir='${exec_prefix}'/${target_noncanonical}
2316 build_tooldir=${tooldir}
2317
2318 # Create a .gdbinit file which runs the one in srcdir
2319 # and tells GDB to look there for source files.
2320
2321 if test -r ${srcdir}/.gdbinit ; then
2322   case ${srcdir} in
2323     .) ;;
2324     *) cat > ./.gdbinit <<EOF
2325 # ${NO_EDIT}
2326 dir ${srcdir}
2327 dir .
2328 source ${srcdir}/.gdbinit
2329 EOF
2330     ;;
2331   esac
2332 fi
2333
2334 # Make sure that the compiler is able to generate an executable.  If it
2335 # can't, we are probably in trouble.  We don't care whether we can run the
2336 # executable--we might be using a cross compiler--we only care whether it
2337 # can be created.  At this point the main configure script has set CC.
2338 we_are_ok=no
2339 echo "int main () { return 0; }" > conftest.c
2340 ${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
2341 if test $? = 0 ; then
2342   if test -s conftest || test -s conftest.exe ; then
2343     we_are_ok=yes
2344   fi
2345 fi
2346 case $we_are_ok in
2347   no)
2348     echo 1>&2 "*** The command '${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c' failed."
2349     echo 1>&2 "*** You must set the environment variable CC to a working compiler."
2350     rm -f conftest*
2351     exit 1
2352     ;;
2353 esac
2354 rm -f conftest*
2355
2356 # Decide which environment variable is used to find dynamic libraries.
2357 case "${host}" in
2358   *-*-hpux*) RPATH_ENVVAR=SHLIB_PATH ;;
2359   *-*-darwin*) RPATH_ENVVAR=DYLD_LIBRARY_PATH ;;
2360   *-*-mingw* | *-*-cygwin ) RPATH_ENVVAR=PATH ;;
2361   *) RPATH_ENVVAR=LD_LIBRARY_PATH ;;
2362 esac
2363
2364 # On systems where the dynamic library environment variable is PATH,
2365 # gcc/ will put dynamic libraries into a subdirectory to avoid adding
2366 # built executables to PATH.
2367 if test "$RPATH_ENVVAR" = PATH; then
2368   GCC_SHLIB_SUBDIR=/shlib
2369 else
2370   GCC_SHLIB_SUBDIR=
2371 fi
2372
2373 # Record target_configdirs and the configure arguments for target and
2374 # build configuration in Makefile.
2375 target_configdirs=`echo "${target_configdirs}" | sed -e 's/target-//g'`
2376 build_configdirs=`echo "${build_configdirs}" | sed -e 's/build-//g'`
2377
2378 # If we are building libgomp, bootstrap it.
2379 if echo " ${target_configdirs} " | grep " libgomp " > /dev/null 2>&1 ; then
2380   bootstrap_target_libs=${bootstrap_target_libs}target-libgomp,
2381 fi
2382
2383 # Determine whether gdb needs tk/tcl or not.
2384 # Use 'maybe' since enable_gdbtk might be true even if tk isn't available
2385 # and in that case we want gdb to be built without tk.  Ugh!
2386 # In fact I believe gdb is the *only* package directly dependent on tk,
2387 # so we should be able to put the 'maybe's in unconditionally and
2388 # leave out the maybe dependencies when enable_gdbtk is false.  I'm not
2389 # 100% sure that that's safe though.
2390
2391 gdb_tk="maybe-all-tcl maybe-all-tk maybe-all-itcl maybe-all-libgui"
2392 case "$enable_gdbtk" in
2393   no)
2394     GDB_TK="" ;;
2395   yes)
2396     GDB_TK="${gdb_tk}" ;;
2397   *)
2398     # Only add the dependency on gdbtk when GDBtk is part of the gdb
2399     # distro.  Eventually someone will fix this and move Insight, nee
2400     # gdbtk to a separate directory.
2401     if test -d ${srcdir}/gdb/gdbtk ; then
2402       GDB_TK="${gdb_tk}"
2403     else
2404       GDB_TK=""
2405     fi
2406     ;;
2407 esac
2408 CONFIGURE_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-configure-/g`
2409 INSTALL_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-install-/g`
2410
2411 # Strip out unwanted targets.
2412
2413 # While at that, we remove Makefiles if we were started for recursive
2414 # configuration, so that the top-level Makefile reconfigures them,
2415 # like we used to do when configure itself was recursive.
2416
2417 # Loop over modules.  We used to use the "$extrasub" feature from Autoconf
2418 # but now we're fixing up the Makefile ourselves with the additional
2419 # commands passed to AC_CONFIG_FILES.  Use separate variables
2420 # extrasub-{build,host,target} not because there is any reason to split
2421 # the substitutions up that way, but only to remain below the limit of
2422 # 99 commands in a script, for HP-UX sed.
2423 # Do not nest @if/@endif pairs, because configure will not warn you at all.
2424
2425 AC_ARG_ENABLE([bootstrap],
2426 [AS_HELP_STRING([--enable-bootstrap],
2427                 [enable bootstrapping @<:@yes if native build@:>@])],,
2428 enable_bootstrap=default)
2429
2430 # Issue errors and warnings for invalid/strange bootstrap combinations.
2431 case "$configdirs" in
2432   *gcc*) have_compiler=yes ;;
2433   *) have_compiler=no ;;
2434 esac
2435
2436 case "$have_compiler:$host:$target:$enable_bootstrap" in
2437   *:*:*:no) ;;
2438
2439   # Default behavior.  Enable bootstrap if we have a compiler
2440   # and we are in a native configuration.
2441   yes:$build:$build:default)
2442     enable_bootstrap=yes ;;
2443
2444   *:*:*:default)
2445     enable_bootstrap=no ;;
2446
2447   # We have a compiler and we are in a native configuration, bootstrap is ok
2448   yes:$build:$build:yes)
2449     ;;
2450
2451   # Other configurations, but we have a compiler.  Assume the user knows
2452   # what he's doing.
2453   yes:*:*:yes)
2454     AC_MSG_WARN([trying to bootstrap a cross compiler])
2455     ;;
2456
2457   # No compiler: if they passed --enable-bootstrap explicitly, fail
2458   no:*:*:yes)
2459     AC_MSG_ERROR([cannot bootstrap without a compiler]) ;;
2460
2461   # Fail if wrong command line
2462   *)
2463     AC_MSG_ERROR([invalid option for --enable-bootstrap])
2464     ;;
2465 esac
2466
2467 case ",$enable_languages,:$ENABLE_BUILD_WITH_CXX:$enable_bootstrap" in
2468   *,c++,*:yes:yes) ;;
2469   *:yes:yes)
2470     AC_MSG_ERROR([bootstrapping with --enable-build-with-cxx requires c++ in --enable-languages])
2471     ;;
2472 esac
2473
2474 case "$enable_bootstrap:$ENABLE_GOLD: $configdirs :,$stage1_languages," in
2475   yes:yes:*\ gold\ *:*,c++,*) ;;
2476   yes:yes:*\ gold\ *:*)
2477     AC_MSG_ERROR([in a combined tree, bootstrapping with --enable-gold requires c++ in stage1_languages])
2478     ;;
2479 esac
2480
2481 # Adjust the toplevel makefile according to whether bootstrap was selected.
2482 case $enable_bootstrap in
2483   yes)
2484     bootstrap_suffix=bootstrap
2485     BUILD_CONFIG=bootstrap-debug
2486     ;;
2487   no)
2488     bootstrap_suffix=no-bootstrap
2489     BUILD_CONFIG=
2490     ;;
2491 esac
2492
2493 AC_MSG_CHECKING(for default BUILD_CONFIG)
2494
2495 AC_ARG_WITH([build-config],
2496   [AS_HELP_STRING([--with-build-config='NAME NAME2...'],
2497                   [use config/NAME.mk build configuration])],
2498   [case $with_build_config in
2499    yes) with_build_config= ;;
2500    no) with_build_config= BUILD_CONFIG= ;;
2501    esac])
2502
2503 if test "x${with_build_config}" != x; then
2504   BUILD_CONFIG=$with_build_config
2505 else
2506   case $BUILD_CONFIG in
2507   bootstrap-debug)
2508     if echo "int f (void) { return 0; }" > conftest.c &&
2509        ${CC} -c conftest.c &&
2510        mv conftest.o conftest.o.g0 &&
2511        ${CC} -c -g conftest.c &&
2512        mv conftest.o conftest.o.g &&
2513        ${srcdir}/contrib/compare-debug conftest.o.g0 conftest.o.g > /dev/null 2>&1; then
2514       :
2515     else
2516       BUILD_CONFIG=
2517     fi
2518     rm -f conftest.c conftest.o conftest.o.g0 conftest.o.g
2519     ;;
2520   esac
2521 fi
2522 AC_MSG_RESULT($BUILD_CONFIG)
2523 AC_SUBST(BUILD_CONFIG)
2524
2525 extrasub_build=
2526 for module in ${build_configdirs} ; do
2527   if test -z "${no_recursion}" \
2528      && test -f ${build_subdir}/${module}/Makefile; then
2529     echo 1>&2 "*** removing ${build_subdir}/${module}/Makefile to force reconfigure"
2530     rm -f ${build_subdir}/${module}/Makefile
2531   fi
2532   extrasub_build="$extrasub_build
2533 /^@if build-$module\$/d
2534 /^@endif build-$module\$/d
2535 /^@if build-$module-$bootstrap_suffix\$/d
2536 /^@endif build-$module-$bootstrap_suffix\$/d"
2537 done
2538 extrasub_host=
2539 for module in ${configdirs} ; do
2540   if test -z "${no_recursion}"; then
2541     for file in stage*-${module}/Makefile prev-${module}/Makefile ${module}/Makefile; do
2542       if test -f ${file}; then
2543         echo 1>&2 "*** removing ${file} to force reconfigure"
2544         rm -f ${file}
2545       fi
2546     done
2547   fi
2548   extrasub_host="$extrasub_host
2549 /^@if $module\$/d
2550 /^@endif $module\$/d
2551 /^@if $module-$bootstrap_suffix\$/d
2552 /^@endif $module-$bootstrap_suffix\$/d"
2553 done
2554 extrasub_target=
2555 for module in ${target_configdirs} ; do
2556   if test -z "${no_recursion}" \
2557      && test -f ${target_subdir}/${module}/Makefile; then
2558     echo 1>&2 "*** removing ${target_subdir}/${module}/Makefile to force reconfigure"
2559     rm -f ${target_subdir}/${module}/Makefile
2560   fi
2561
2562   # We only bootstrap target libraries listed in bootstrap_target_libs.
2563   case $bootstrap_target_libs in
2564     *,target-$module,*) target_bootstrap_suffix=$bootstrap_suffix ;;
2565     *) target_bootstrap_suffix=no-bootstrap ;;
2566   esac
2567
2568   extrasub_target="$extrasub_target
2569 /^@if target-$module\$/d
2570 /^@endif target-$module\$/d
2571 /^@if target-$module-$target_bootstrap_suffix\$/d
2572 /^@endif target-$module-$target_bootstrap_suffix\$/d"
2573 done
2574
2575 # Do the final fixup along with target modules.
2576 extrasub_target="$extrasub_target
2577 /^@if /,/^@endif /d"
2578
2579 # Create the serialization dependencies.  This uses a temporary file.
2580
2581 AC_ARG_ENABLE([serial-configure],
2582 [AS_HELP_STRING([[--enable-serial-[{host,target,build}-]configure]],
2583                 [force sequential configuration of
2584                  sub-packages for the host, target or build
2585                  machine, or all sub-packages])])
2586
2587 case ${enable_serial_configure} in
2588   yes)
2589     enable_serial_build_configure=yes
2590     enable_serial_host_configure=yes
2591     enable_serial_target_configure=yes
2592     ;;
2593 esac
2594
2595 # These force 'configure's to be done one at a time, to avoid problems
2596 # with contention over a shared config.cache.
2597 rm -f serdep.tmp
2598 echo '# serdep.tmp' > serdep.tmp
2599 olditem=
2600 test "x${enable_serial_build_configure}" = xyes &&
2601 for item in ${build_configdirs} ; do
2602   case ${olditem} in
2603     "") ;;
2604     *) echo "configure-build-${item}: configure-build-${olditem}" >> serdep.tmp ;;
2605   esac
2606   olditem=${item}
2607 done
2608 olditem=
2609 test "x${enable_serial_host_configure}" = xyes &&
2610 for item in ${configdirs} ; do
2611   case ${olditem} in
2612     "") ;;
2613     *) echo "configure-${item}: configure-${olditem}" >> serdep.tmp ;;
2614   esac
2615   olditem=${item}
2616 done
2617 olditem=
2618 test "x${enable_serial_target_configure}" = xyes &&
2619 for item in ${target_configdirs} ; do
2620   case ${olditem} in
2621     "") ;;
2622     *) echo "configure-target-${item}: configure-target-${olditem}" >> serdep.tmp ;;
2623   esac
2624   olditem=${item}
2625 done
2626 serialization_dependencies=serdep.tmp
2627 AC_SUBST_FILE(serialization_dependencies)
2628
2629 # Base args.  Strip norecursion, cache-file, srcdir, host, build,
2630 # target, nonopt, and variable assignments.  These are the ones we
2631 # might not want to pass down to subconfigures.  The exception being
2632 # --cache-file=/dev/null, which is used to turn off the use of cache
2633 # files altogether, and which should be passed on to subconfigures.
2634 # Also strip program-prefix, program-suffix, and program-transform-name,
2635 # so that we can pass down a consistent program-transform-name.
2636 baseargs=
2637 tbaseargs=
2638 keep_next=no
2639 skip_next=no
2640 eval "set -- $ac_configure_args"
2641 for ac_arg
2642 do
2643   if test X"$skip_next" = X"yes"; then
2644     skip_next=no
2645     continue
2646   fi
2647   if test X"$keep_next" = X"yes"; then
2648     case $ac_arg in
2649       *\'*)
2650         ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
2651     esac
2652     baseargs="$baseargs '$ac_arg'"
2653     tbaseargs="$tbaseargs '$ac_arg'"
2654     keep_next=no
2655     continue
2656   fi
2657
2658   # Handle separated arguments.  Based on the logic generated by
2659   # autoconf 2.59.
2660   case $ac_arg in
2661     *=* | --config-cache | -C | -disable-* | --disable-* \
2662       | -enable-* | --enable-* | -gas | --g* | -nfp | --nf* \
2663       | -q | -quiet | --q* | -silent | --sil* | -v | -verb* \
2664       | -with-* | --with-* | -without-* | --without-* | --x)
2665       separate_arg=no
2666       ;;
2667     -*)
2668       separate_arg=yes
2669       ;;
2670     *)
2671       separate_arg=no
2672       ;;
2673   esac
2674
2675   skip_targ=no
2676   case $ac_arg in
2677 changequote(,)
2678   --with-* | --without-*)
2679     libopt=`echo "$ac_arg" | sed -e 's,^--[^-_]*[-_],,' -e 's,=.*$,,'`
2680
2681     case $libopt in
2682     *[-_]include)
2683       lib=`echo "$libopt" | sed 's,[-_]include$,,'`
2684       ;;
2685     *[-_]lib)
2686       lib=`echo "$libopt" | sed 's,[-_]lib$,,'`
2687       ;;
2688     *)
2689       lib=$libopt
2690       ;;
2691     esac
2692 changequote([,])
2693
2694     case $lib in
2695     mpc | mpfr | gmp | ppl | cloog)
2696       # If we're processing --with-$lib, --with-$lib-include or
2697       # --with-$lib-lib, for one of the libs above, and target is
2698       # different from host, don't pass the current argument to any
2699       # target library's configure.
2700       if test x$is_cross_compiler = xyes; then
2701         skip_targ=yes
2702       fi
2703       ;;
2704     esac
2705     ;;
2706   esac
2707
2708   case "$ac_arg" in
2709     --cache-file=/dev/null | \
2710     -cache-file=/dev/null )
2711       # Handled here to avoid the test to skip args below.
2712       baseargs="$baseargs '$ac_arg'"
2713       tbaseargs="$tbaseargs '$ac_arg'"
2714       # Assert: $separate_arg should always be no.
2715       keep_next=$separate_arg
2716       ;;
2717     --no*)
2718       continue
2719       ;;
2720     --c* | \
2721     --sr* | \
2722     --ho* | \
2723     --bu* | \
2724     --t* | \
2725     --program-* | \
2726     -cache_file* | \
2727     -srcdir* | \
2728     -host* | \
2729     -build* | \
2730     -target* | \
2731     -program-prefix* | \
2732     -program-suffix* | \
2733     -program-transform-name* )
2734       skip_next=$separate_arg
2735       continue
2736       ;;
2737     -*)
2738       # An option.  Add it.
2739       case $ac_arg in
2740         *\'*)
2741           ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
2742       esac
2743       baseargs="$baseargs '$ac_arg'"
2744       if test X"$skip_targ" = Xno; then
2745         tbaseargs="$tbaseargs '$ac_arg'"
2746       fi
2747       keep_next=$separate_arg
2748       ;;
2749     *)
2750       # Either a variable assignment, or a nonopt (triplet).  Don't
2751       # pass it down; let the Makefile handle this.
2752       continue
2753       ;;
2754   esac
2755 done
2756 # Remove the initial space we just introduced and, as these will be
2757 # expanded by make, quote '$'.
2758 baseargs=`echo "x$baseargs" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
2759
2760 # Add in --program-transform-name, after --program-prefix and
2761 # --program-suffix have been applied to it.  Autoconf has already
2762 # doubled dollar signs and backslashes in program_transform_name; we want
2763 # the backslashes un-doubled, and then the entire thing wrapped in single
2764 # quotes, because this will be expanded first by make and then by the shell.
2765 # Also, because we want to override the logic in subdir configure scripts to
2766 # choose program_transform_name, replace any s,x,x, with s,y,y,.
2767 sed -e "s,\\\\\\\\,\\\\,g; s,','\\\\'',g; s/s,x,x,/s,y,y,/" <<EOF_SED > conftestsed.out
2768 ${program_transform_name}
2769 EOF_SED
2770 gcc_transform_name=`cat conftestsed.out`
2771 rm -f conftestsed.out
2772 baseargs="$baseargs --program-transform-name='${gcc_transform_name}'"
2773 tbaseargs="$tbaseargs --program-transform-name='${gcc_transform_name}'"
2774 if test "$silent" = yes; then
2775   baseargs="$baseargs --silent"
2776   tbaseargs="$tbaseargs --silent"
2777 fi
2778 baseargs="$baseargs --disable-option-checking"
2779 tbaseargs="$tbaseargs --disable-option-checking"
2780
2781 # Record and document user additions to sub configure arguments.
2782 AC_ARG_VAR([build_configargs],
2783            [additional configure arguments for build directories])
2784 AC_ARG_VAR([host_configargs],
2785            [additional configure arguments for host directories])
2786 AC_ARG_VAR([target_configargs],
2787            [additional configure arguments for target directories])
2788
2789 # For the build-side libraries, we just need to pretend we're native,
2790 # and not use the same cache file.  Multilibs are neither needed nor
2791 # desired.
2792 build_configargs="$build_configargs --cache-file=../config.cache ${baseargs}"
2793
2794 # For host modules, accept cache file option, or specification as blank.
2795 case "${cache_file}" in
2796 "") # empty
2797   cache_file_option="" ;;
2798 /* | [[A-Za-z]]:[[\\/]]* ) # absolute path
2799   cache_file_option="--cache-file=${cache_file}" ;;
2800 *) # relative path
2801   cache_file_option="--cache-file=../${cache_file}" ;;
2802 esac
2803
2804 # Host dirs don't like to share a cache file either, horribly enough.
2805 # This seems to be due to autoconf 2.5x stupidity.
2806 host_configargs="$host_configargs --cache-file=./config.cache ${extra_host_args} ${baseargs}"
2807
2808 target_configargs="$target_configargs ${tbaseargs}"
2809
2810 # Passing a --with-cross-host argument lets the target libraries know
2811 # whether they are being built with a cross-compiler or being built
2812 # native.  However, it would be better to use other mechanisms to make the
2813 # sorts of decisions they want to make on this basis.  Please consider
2814 # this option to be deprecated.  FIXME.
2815 if test x${is_cross_compiler} = xyes ; then
2816   target_configargs="--with-cross-host=${host_noncanonical} ${target_configargs}"
2817 fi
2818
2819 # Default to --enable-multilib.
2820 if test x${enable_multilib} = x ; then
2821   target_configargs="--enable-multilib ${target_configargs}"
2822 fi
2823
2824 # Pass --with-newlib if appropriate.  Note that target_configdirs has
2825 # changed from the earlier setting of with_newlib.
2826 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " newlib " > /dev/null 2>&1 && test -d ${srcdir}/newlib ; then
2827   target_configargs="--with-newlib ${target_configargs}"
2828 fi
2829
2830 # Different target subdirs use different values of certain variables
2831 # (notably CXX).  Worse, multilibs use *lots* of different values.
2832 # Worse yet, autoconf 2.5x makes some of these 'precious', meaning that
2833 # it doesn't automatically accept command-line overrides of them.
2834 # This means it's not safe for target subdirs to share a cache file,
2835 # which is disgusting, but there you have it.  Hopefully this can be
2836 # fixed in future.  It's still worthwhile to use a cache file for each
2837 # directory.  I think.
2838
2839 # Pass the appropriate --build, --host, --target and --cache-file arguments.
2840 # We need to pass --target, as newer autoconf's requires consistency
2841 # for target_alias and gcc doesn't manage it consistently.
2842 target_configargs="--cache-file=./config.cache ${target_configargs}"
2843
2844 FLAGS_FOR_TARGET=
2845 case " $target_configdirs " in
2846  *" newlib "*)
2847   case " $target_configargs " in
2848   *" --with-newlib "*)
2849    case "$target" in
2850     *-cygwin*)
2851       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup -L$$r/$(TARGET_SUBDIR)/winsup/cygwin -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/include -isystem $$s/winsup/cygwin/include -isystem $$s/winsup/w32api/include'
2852       ;;
2853    esac
2854
2855    # If we're not building GCC, don't discard standard headers.
2856    if test -d ${srcdir}/gcc; then
2857      FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -nostdinc'
2858
2859      if test "${build}" != "${host}"; then
2860        # On Canadian crosses, CC_FOR_TARGET will have already been set
2861        # by `configure', so we won't have an opportunity to add -Bgcc/
2862        # to it.  This is right: we don't want to search that directory
2863        # for binaries, but we want the header files in there, so add
2864        # them explicitly.
2865        FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -isystem $$r/$(HOST_SUBDIR)/gcc/include -isystem $$r/$(HOST_SUBDIR)/gcc/include-fixed'
2866
2867        # Someone might think of using the pre-installed headers on
2868        # Canadian crosses, in case the installed compiler is not fully
2869        # compatible with the compiler being built.  In this case, it
2870        # would be better to flag an error than risking having
2871        # incompatible object files being constructed.  We can't
2872        # guarantee that an error will be flagged, but let's hope the
2873        # compiler will do it, when presented with incompatible header
2874        # files.
2875      fi
2876    fi
2877
2878    case "${target}-${is_cross_compiler}" in
2879    i[[3456789]]86-*-linux*-no)
2880       # Here host == target, so we don't need to build gcc,
2881       # so we don't want to discard standard headers.
2882       FLAGS_FOR_TARGET=`echo " $FLAGS_FOR_TARGET " | sed -e 's/ -nostdinc / /'`
2883       ;;
2884    *)
2885       # If we're building newlib, use its generic headers last, but search
2886       # for any libc-related directories first (so make it the last -B
2887       # switch).
2888       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/newlib/ -isystem $$r/$(TARGET_SUBDIR)/newlib/targ-include -isystem $$s/newlib/libc/include'
2889
2890       # If we're building libgloss, find the startup file, simulator library
2891       # and linker script.
2892       case " $target_configdirs " in
2893         *" libgloss "*)
2894         # Look for startup file, simulator library and maybe linker script.
2895         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/libgloss/'"$libgloss_dir"
2896         # Look for libnosys.a in case the target needs it.
2897         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/libgloss/libnosys'
2898         # Most targets have the linker script in the source directory.
2899         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$s/libgloss/'"$libgloss_dir"
2900         ;;
2901       esac
2902       ;;
2903    esac
2904    ;;
2905   esac
2906   ;;
2907 esac
2908
2909 case "$target" in
2910   x86_64-*mingw* | *-w64-mingw*)
2911   # MinGW-w64 does not use newlib, nor does it use winsup. It may,
2912   # however, use a symlink named 'mingw' in ${prefix} .
2913     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L${prefix}/${target}/lib -L${prefix}/mingw/lib -isystem ${prefix}/${target}/include -isystem ${prefix}/mingw/include'
2914     ;;
2915   *-mingw*)
2916   # MinGW can't be handled as Cygwin above since it does not use newlib.
2917     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/mingw -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/mingw/include -isystem $$s/winsup/w32api/include'
2918     ;;
2919 esac
2920
2921 # Allow the user to override the flags for
2922 # our build compiler if desired.
2923 if test x"${build}" = x"${host}" ; then
2924   CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-${CFLAGS}}
2925   CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-${CXXFLAGS}}
2926   LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-${LDFLAGS}}
2927 fi
2928
2929 # On Canadian crosses, we'll be searching the right directories for
2930 # the previously-installed cross compiler, so don't bother to add
2931 # flags for directories within the install tree of the compiler
2932 # being built; programs in there won't even run.
2933 if test "${build}" = "${host}" && test -d ${srcdir}/gcc; then
2934   # Search for pre-installed headers if nothing else fits.
2935   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$(build_tooldir)/bin/ -B$(build_tooldir)/lib/ -isystem $(build_tooldir)/include -isystem $(build_tooldir)/sys-include'
2936 fi
2937
2938 if test "x${use_gnu_ld}" = x &&
2939    echo " ${configdirs} " | grep " ld " > /dev/null ; then
2940   # Arrange for us to find uninstalled linker scripts.
2941   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(HOST_SUBDIR)/ld'
2942 fi
2943
2944 # Search for other target-specific linker scripts and such.
2945 case "${target}" in
2946   mep*)
2947     FLAGS_FOR_TARGET="$FLAGS_FOR_TARGET -mlibrary"
2948     ;;
2949 esac
2950
2951 # Makefile fragments.
2952 for frag in host_makefile_frag target_makefile_frag alphaieee_frag ospace_frag;
2953 do
2954   eval fragval=\$$frag
2955   if test $fragval != /dev/null; then
2956     eval $frag=${srcdir}/$fragval
2957   fi
2958 done
2959 AC_SUBST_FILE(host_makefile_frag)
2960 AC_SUBST_FILE(target_makefile_frag)
2961 AC_SUBST_FILE(alphaieee_frag)
2962 AC_SUBST_FILE(ospace_frag)
2963
2964 # Miscellanea: directories, flags, etc.
2965 AC_SUBST(RPATH_ENVVAR)
2966 AC_SUBST(GCC_SHLIB_SUBDIR)
2967 AC_SUBST(tooldir)
2968 AC_SUBST(build_tooldir)
2969 AC_SUBST(CONFIGURE_GDB_TK)
2970 AC_SUBST(GDB_TK)
2971 AC_SUBST(INSTALL_GDB_TK)
2972
2973 # Build module lists & subconfigure args.
2974 AC_SUBST(build_configargs)
2975 AC_SUBST(build_configdirs)
2976
2977 # Host module lists & subconfigure args.
2978 AC_SUBST(host_configargs)
2979 AC_SUBST(configdirs)
2980 AC_SUBST(target_configdirs)
2981
2982 # Target module lists & subconfigure args.
2983 AC_SUBST(target_configargs)
2984
2985
2986 # Build tools.
2987 AC_SUBST(AR_FOR_BUILD)
2988 AC_SUBST(AS_FOR_BUILD)
2989 AC_SUBST(CC_FOR_BUILD)
2990 AC_SUBST(CFLAGS_FOR_BUILD)
2991 AC_SUBST(CXXFLAGS_FOR_BUILD)
2992 AC_SUBST(CXX_FOR_BUILD)
2993 AC_SUBST(DLLTOOL_FOR_BUILD)
2994 AC_SUBST(GCJ_FOR_BUILD)
2995 AC_SUBST(GFORTRAN_FOR_BUILD)
2996 AC_SUBST(GOC_FOR_BUILD)
2997 AC_SUBST(LDFLAGS_FOR_BUILD)
2998 AC_SUBST(LD_FOR_BUILD)
2999 AC_SUBST(NM_FOR_BUILD)
3000 AC_SUBST(RANLIB_FOR_BUILD)
3001 AC_SUBST(WINDMC_FOR_BUILD)
3002 AC_SUBST(WINDRES_FOR_BUILD)
3003
3004 # Generate default definitions for YACC, M4, LEX and other programs that run
3005 # on the build machine.  These are used if the Makefile can't locate these
3006 # programs in objdir.
3007 MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
3008
3009 AC_CHECK_PROGS([YACC], ['bison -y' byacc yacc], [$MISSING bison -y])
3010 case " $build_configdirs " in
3011   *" bison "*) YACC='$$r/$(BUILD_SUBDIR)/bison/tests/bison -y' ;;
3012 esac
3013
3014 AC_CHECK_PROGS([BISON], [bison], [$MISSING bison])
3015 case " $build_configdirs " in
3016   *" bison "*) BISON='$$r/$(BUILD_SUBDIR)/bison/tests/bison' ;;
3017 esac
3018
3019 AC_CHECK_PROGS([M4], [gm4 gnum4 m4], [$MISSING m4])
3020 case " $build_configdirs " in
3021   *" m4 "*) M4='$$r/$(BUILD_SUBDIR)/m4/m4' ;;
3022 esac
3023
3024 AC_CHECK_PROGS([LEX], [flex lex], [$MISSING flex])
3025 case " $build_configdirs " in
3026   *" flex "*) LEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3027   *" lex "*) LEX='$$r/$(BUILD_SUBDIR)/lex/lex' ;;
3028 esac
3029
3030 AC_CHECK_PROGS([FLEX], [flex], [$MISSING flex])
3031 case " $build_configdirs " in
3032   *" flex "*) FLEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3033 esac
3034
3035 AC_CHECK_PROGS([MAKEINFO], makeinfo, [$MISSING makeinfo])
3036 case " $build_configdirs " in
3037   *" texinfo "*) MAKEINFO='$$r/$(BUILD_SUBDIR)/texinfo/makeinfo/makeinfo' ;;
3038   *)
3039 changequote(,)
3040     # For an installed makeinfo, we require it to be from texinfo 4.7 or
3041     # higher, else we use the "missing" dummy.
3042     if ${MAKEINFO} --version \
3043        | egrep 'texinfo[^0-9]*(4\.([7-9]|[1-9][0-9])|[5-9]|[1-9][0-9])' >/dev/null 2>&1; then
3044       :
3045     else
3046       MAKEINFO="$MISSING makeinfo"
3047     fi
3048     ;;
3049 changequote([,])
3050 esac
3051
3052 # FIXME: expect and dejagnu may become build tools?
3053
3054 AC_CHECK_PROGS(EXPECT, expect, expect)
3055 case " $configdirs " in
3056   *" expect "*)
3057     test $host = $build && EXPECT='$$r/$(HOST_SUBDIR)/expect/expect'
3058     ;;
3059 esac
3060
3061 AC_CHECK_PROGS(RUNTEST, runtest, runtest)
3062 case " $configdirs " in
3063   *" dejagnu "*)
3064     test $host = $build && RUNTEST='$$s/$(HOST_SUBDIR)/dejagnu/runtest'
3065     ;;
3066 esac
3067
3068
3069 # Host tools.
3070 NCN_STRICT_CHECK_TOOLS(AR, ar)
3071 NCN_STRICT_CHECK_TOOLS(AS, as)
3072 NCN_STRICT_CHECK_TOOLS(DLLTOOL, dlltool)
3073 NCN_STRICT_CHECK_TOOLS(LD, ld)
3074 NCN_STRICT_CHECK_TOOLS(LIPO, lipo)
3075 NCN_STRICT_CHECK_TOOLS(NM, nm)
3076 NCN_STRICT_CHECK_TOOLS(RANLIB, ranlib, true)
3077 NCN_STRICT_CHECK_TOOLS(STRIP, strip, true)
3078 NCN_STRICT_CHECK_TOOLS(WINDRES, windres)
3079 NCN_STRICT_CHECK_TOOLS(WINDMC, windmc)
3080 NCN_STRICT_CHECK_TOOLS(OBJCOPY, objcopy)
3081 NCN_STRICT_CHECK_TOOLS(OBJDUMP, objdump)
3082 AC_SUBST(CC)
3083 AC_SUBST(CXX)
3084 AC_SUBST(CFLAGS)
3085 AC_SUBST(CXXFLAGS)
3086
3087 # Target tools.
3088 AC_ARG_WITH([build-time-tools],
3089   [AS_HELP_STRING([--with-build-time-tools=PATH],
3090                   [use given path to find target tools during the build])],
3091   [case x"$withval" in
3092      x/*) ;;
3093      *)
3094        with_build_time_tools=
3095        AC_MSG_WARN([argument to --with-build-time-tools must be an absolute path])
3096        ;;
3097    esac],
3098   [with_build_time_tools=])
3099
3100 NCN_STRICT_CHECK_TARGET_TOOLS(CC_FOR_TARGET, cc gcc)
3101 NCN_STRICT_CHECK_TARGET_TOOLS(CXX_FOR_TARGET, c++ g++ cxx gxx)
3102 NCN_STRICT_CHECK_TARGET_TOOLS(GCC_FOR_TARGET, gcc, ${CC_FOR_TARGET})
3103 NCN_STRICT_CHECK_TARGET_TOOLS(GCJ_FOR_TARGET, gcj)
3104 NCN_STRICT_CHECK_TARGET_TOOLS(GFORTRAN_FOR_TARGET, gfortran)
3105 NCN_STRICT_CHECK_TARGET_TOOLS(GOC_FOR_TARGET, gccgo)
3106
3107 ACX_CHECK_INSTALLED_TARGET_TOOL(AR_FOR_TARGET, ar)
3108 ACX_CHECK_INSTALLED_TARGET_TOOL(AS_FOR_TARGET, as)
3109 ACX_CHECK_INSTALLED_TARGET_TOOL(DLLTOOL_FOR_TARGET, dlltool)
3110 ACX_CHECK_INSTALLED_TARGET_TOOL(LD_FOR_TARGET, ld)
3111 ACX_CHECK_INSTALLED_TARGET_TOOL(LIPO_FOR_TARGET, lipo)
3112 ACX_CHECK_INSTALLED_TARGET_TOOL(NM_FOR_TARGET, nm)
3113 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJDUMP_FOR_TARGET, objdump)
3114 ACX_CHECK_INSTALLED_TARGET_TOOL(RANLIB_FOR_TARGET, ranlib)
3115 ACX_CHECK_INSTALLED_TARGET_TOOL(STRIP_FOR_TARGET, strip)
3116 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDRES_FOR_TARGET, windres)
3117 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDMC_FOR_TARGET, windmc)
3118
3119 RAW_CXX_FOR_TARGET="$CXX_FOR_TARGET"
3120
3121 GCC_TARGET_TOOL(ar, AR_FOR_TARGET, AR, [binutils/ar])
3122 GCC_TARGET_TOOL(as, AS_FOR_TARGET, AS, [gas/as-new])
3123 GCC_TARGET_TOOL(cc, CC_FOR_TARGET, CC, [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3124 dnl see comments for CXX_FOR_TARGET_FLAG_TO_PASS
3125 GCC_TARGET_TOOL(c++, CXX_FOR_TARGET, CXX,
3126                 [gcc/g++ -B$$r/$(HOST_SUBDIR)/gcc/ -nostdinc++ `if test -f $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags; then $(SHELL) $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags --build-includes; else echo -funconfigured-libstdc++-v3 ; fi` -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs],
3127                 c++)
3128 GCC_TARGET_TOOL(c++ for libstdc++, RAW_CXX_FOR_TARGET, CXX,
3129                 [gcc/xgcc -shared-libgcc -B$$r/$(HOST_SUBDIR)/gcc -nostdinc++ -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs],
3130                 c++)
3131 GCC_TARGET_TOOL(dlltool, DLLTOOL_FOR_TARGET, DLLTOOL, [binutils/dlltool])
3132 GCC_TARGET_TOOL(gcc, GCC_FOR_TARGET, , [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3133 GCC_TARGET_TOOL(gcj, GCJ_FOR_TARGET, GCJ,
3134                 [gcc/gcj -B$$r/$(HOST_SUBDIR)/gcc/], java)
3135 GCC_TARGET_TOOL(gfortran, GFORTRAN_FOR_TARGET, GFORTRAN,
3136                 [gcc/gfortran -B$$r/$(HOST_SUBDIR)/gcc/], fortran)
3137 GCC_TARGET_TOOL(gccgo, GOC_FOR_TARGET, GOC,
3138                 [gcc/gccgo -B$$r/$(HOST_SUBDIR)/gcc/], go)
3139 GCC_TARGET_TOOL(ld, LD_FOR_TARGET, LD, [ld/ld-new])
3140 GCC_TARGET_TOOL(lipo, LIPO_FOR_TARGET, LIPO)
3141 GCC_TARGET_TOOL(nm, NM_FOR_TARGET, NM, [binutils/nm-new])
3142 GCC_TARGET_TOOL(objdump, OBJDUMP_FOR_TARGET, OBJDUMP, [binutils/objdump])
3143 GCC_TARGET_TOOL(ranlib, RANLIB_FOR_TARGET, RANLIB, [binutils/ranlib])
3144 GCC_TARGET_TOOL(strip, STRIP_FOR_TARGET, STRIP, [binutils/strip-new])
3145 GCC_TARGET_TOOL(windres, WINDRES_FOR_TARGET, WINDRES, [binutils/windres])
3146 GCC_TARGET_TOOL(windmc, WINDMC_FOR_TARGET, WINDMC, [binutils/windmc])
3147
3148 AC_SUBST(FLAGS_FOR_TARGET)
3149 AC_SUBST(RAW_CXX_FOR_TARGET)
3150
3151 # Certain tools may need extra flags.
3152 AR_FOR_TARGET=${AR_FOR_TARGET}${extra_arflags_for_target}
3153 RANLIB_FOR_TARGET=${RANLIB_FOR_TARGET}${extra_ranlibflags_for_target}
3154 NM_FOR_TARGET=${NM_FOR_TARGET}${extra_nmflags_for_target}
3155
3156 # When building target libraries, except in a Canadian cross, we use
3157 # the same toolchain as the compiler we just built.
3158 COMPILER_AS_FOR_TARGET='$(AS_FOR_TARGET)'
3159 COMPILER_LD_FOR_TARGET='$(LD_FOR_TARGET)'
3160 COMPILER_NM_FOR_TARGET='$(NM_FOR_TARGET)'
3161 if test $host = $build; then
3162   case " $configdirs " in
3163     *" gcc "*)
3164       COMPILER_AS_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/as'
3165       COMPILER_LD_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/collect-ld'
3166       COMPILER_NM_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/nm'${extra_nmflags_for_target}
3167       ;;
3168   esac
3169 fi
3170
3171 AC_SUBST(COMPILER_AS_FOR_TARGET)
3172 AC_SUBST(COMPILER_LD_FOR_TARGET)
3173 AC_SUBST(COMPILER_NM_FOR_TARGET)
3174
3175 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3176 AC_ARG_ENABLE(maintainer-mode,
3177 [AS_HELP_STRING([--enable-maintainer-mode],
3178                 [enable make rules and dependencies not useful
3179                  (and sometimes confusing) to the casual installer])],
3180       USE_MAINTAINER_MODE=$enableval,
3181       USE_MAINTAINER_MODE=no)
3182 AC_MSG_RESULT($USE_MAINTAINER_MODE)
3183 AC_SUBST(MAINTAINER_MODE_TRUE)
3184 AC_SUBST(MAINTAINER_MODE_FALSE)
3185 if test "$USE_MAINTAINER_MODE" = yes; then
3186   MAINTAINER_MODE_TRUE=
3187   MAINTAINER_MODE_FALSE='#'
3188 else
3189   MAINTAINER_MODE_TRUE='#'
3190   MAINTAINER_MODE_FALSE=
3191 fi
3192 MAINT=$MAINTAINER_MODE_TRUE
3193 AC_SUBST(MAINT)dnl
3194
3195 # ---------------------
3196 # GCC bootstrap support
3197 # ---------------------
3198
3199 # Stage specific cflags for build.
3200 stage1_cflags="-g"
3201 case $build in
3202   vax-*-*)
3203     case ${GCC} in
3204       yes) stage1_cflags="-g -Wa,-J" ;;
3205       *) stage1_cflags="-g -J" ;;
3206     esac ;;
3207 esac
3208
3209 # This is aimed to mimic bootstrap with a non-GCC compiler to catch problems.
3210 if test "$GCC" = yes -a "$ENABLE_BUILD_WITH_CXX" != yes; then
3211   saved_CFLAGS="$CFLAGS"
3212
3213   # Pass -fkeep-inline-functions for stage 1 if the GCC version supports it.
3214   CFLAGS="$CFLAGS -fkeep-inline-functions"
3215   AC_MSG_CHECKING([whether -fkeep-inline-functions is supported])
3216   AC_TRY_COMPILE([
3217 #if (__GNUC__ < 3) \
3218     || (__GNUC__ == 3 && (__GNUC_MINOR__ < 3 \
3219                           || (__GNUC_MINOR__ == 3 && __GNUC_PATCHLEVEL__ < 1)))
3220 #error http://gcc.gnu.org/PR29382
3221 #endif
3222     ],,
3223     [AC_MSG_RESULT([yes]); stage1_cflags="$stage1_cflags -fkeep-inline-functions"],
3224     [AC_MSG_RESULT([no])])
3225
3226   CFLAGS="$saved_CFLAGS"
3227 fi
3228
3229 AC_SUBST(stage1_cflags)
3230
3231 # Enable --enable-checking in stage1 of the compiler.
3232 AC_ARG_ENABLE(stage1-checking,
3233 [AS_HELP_STRING([[--enable-stage1-checking[=all]]],
3234                 [choose additional checking for stage1 of the compiler])],
3235 [stage1_checking=--enable-checking=${enable_stage1_checking}],
3236 [if test "x$enable_checking" = xno || test "x$enable_checking" = x; then
3237   stage1_checking=--enable-checking=yes,types
3238 else
3239   stage1_checking=--enable-checking=$enable_checking,types
3240 fi])
3241 AC_SUBST(stage1_checking)
3242
3243 # Enable -Werror in bootstrap stage2 and later.
3244 AC_ARG_ENABLE(werror,
3245 [AS_HELP_STRING([--enable-werror],
3246                 [enable -Werror in bootstrap stage2 and later])], [],
3247 [if test -d ${srcdir}/gcc && test x"`cat $srcdir/gcc/DEV-PHASE`" = xexperimental; then
3248   enable_werror=yes
3249 else
3250   enable_werror=no
3251 fi])
3252 case ${enable_werror} in
3253   yes) stage2_werror_flag="--enable-werror-always" ;;
3254   *) stage2_werror_flag="" ;;
3255 esac
3256 AC_SUBST(stage2_werror_flag)
3257
3258 # Specify what files to not compare during bootstrap.
3259
3260 compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/*"
3261 case "$target" in
3262   hppa*64*-*-hpux*) ;;
3263   hppa*-*-hpux*) compare_exclusions="gcc/cc*-checksum\$(objext) | */libgcc/lib2funcs* | gcc/ada/*tools/*" ;;
3264 esac
3265 case " $configdirs " in
3266 *" ppl "*) compare_exclusions="$compare_exclusions | ppl/src/ppl-config.o" ;;
3267 esac
3268 AC_SUBST(compare_exclusions)
3269
3270 AC_CONFIG_FILES([Makefile],
3271   [sed "$extrasub_build" Makefile |
3272    sed "$extrasub_host" |
3273    sed "$extrasub_target" > mf$$
3274    mv -f mf$$ Makefile],
3275   [extrasub_build="$extrasub_build"
3276    extrasub_host="$extrasub_host"
3277    extrasub_target="$extrasub_target"])
3278 AC_OUTPUT