configure.ac

   1 #   Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000,
   2 #   2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011, 2012,
   3 #   2014, 2015, 2016, 2019, 2022 Free Software Foundation, Inc.
   4 #
   5 # This file is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; see the file COPYING3.  If not see
  17 # <http://www.gnu.org/licenses/>.
  18
  19 ##############################################################################
  20 ### WARNING: this file contains embedded tabs.  Do not run untabify on this file.
  21
  22 m4_include(config/acx.m4)
  23 m4_include(config/override.m4)
  24 m4_include(config/proginstall.m4)
  25 m4_include(config/elf.m4)
  26 m4_include(config/gcc-plugin.m4)
  27 m4_include(config/ax_cxx_compile_stdcxx.m4)
  28 m4_include([libtool.m4])
  29 m4_include([ltoptions.m4])
  30 m4_include([ltsugar.m4])
  31 m4_include([ltversion.m4])
  32 m4_include([lt~obsolete.m4])
  33 m4_include([config/isl.m4])
  34
  35 AC_INIT(move-if-change)
  36 AC_DISABLE_OPTION_CHECKING
  37
  38 progname=$0
  39 # if PWD already has a value, it is probably wrong.
  40 if test -n "$PWD" ; then PWD=`${PWDCMD-pwd}`; fi
  41
  42 # Export original configure arguments for use by sub-configures.
  43 # Quote arguments with shell meta charatcers.
  44 TOPLEVEL_CONFIGURE_ARGUMENTS=
  45 set -- "$progname" "$@"
  46 for ac_arg
  47 do
  48   case "$ac_arg" in
  49   *" "*|*"      "*|*[[\[\]\~\#\$\^\&\*\(\)\{\}\\\|\;\<\>\?\']]*)
  50     ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"`
  51     # if the argument is of the form -foo=baz, quote the baz part only
  52     ac_arg=`echo "'$ac_arg'" | sed "s/^'\([[-a-zA-Z0-9]]*=\)/\\1'/"` ;;
  53   *) ;;
  54   esac
  55   # Add the quoted argument to the list.
  56   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS $ac_arg"
  57 done
  58 if test "$silent" = yes; then
  59   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS --silent"
  60 fi
  61 # Remove the initial space we just introduced and, as these will be
  62 # expanded by make, quote '$'.
  63 TOPLEVEL_CONFIGURE_ARGUMENTS=`echo "x$TOPLEVEL_CONFIGURE_ARGUMENTS" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
  64 AC_SUBST(TOPLEVEL_CONFIGURE_ARGUMENTS)
  65
  66 # Find the build, host, and target systems.
  67 ACX_NONCANONICAL_BUILD
  68 ACX_NONCANONICAL_HOST
  69 ACX_NONCANONICAL_TARGET
  70
  71 dnl Autoconf 2.5x and later will set a default program prefix if
  72 dnl --target was used, even if it was the same as --host.  Disable
  73 dnl that behavior.  This must be done before AC_CANONICAL_SYSTEM
  74 dnl to take effect.
  75 test "$host_noncanonical" = "$target_noncanonical" &&
  76   test "$program_prefix$program_suffix$program_transform_name" = \
  77     NONENONEs,x,x, &&
  78   program_transform_name=s,y,y,
  79
  80 AC_CANONICAL_SYSTEM
  81 AC_ARG_PROGRAM
  82
  83 m4_pattern_allow([^AS_FOR_TARGET$])dnl
  84 m4_pattern_allow([^AS_FOR_BUILD$])dnl
  85
  86 # Get 'install' or 'install-sh' and its variants.
  87 AC_PROG_INSTALL
  88 ACX_PROG_LN
  89 AC_PROG_LN_S
  90 AC_PROG_SED
  91 AC_PROG_AWK
  92
  93 srcpwd=`cd ${srcdir} ; ${PWDCMD-pwd}`
  94
  95 # We pass INSTALL explicitly to sub-makes.  Make sure that it is not
  96 # a relative path.
  97 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
  98   INSTALL="${srcpwd}/install-sh -c"
  99 fi
 100
 101 # Set srcdir to "." if that's what it is.
 102 # This is important for multilib support.
 103 pwd=`${PWDCMD-pwd}`
 104 if test "${pwd}" = "${srcpwd}" ; then
 105   srcdir=.
 106 fi
 107
 108 topsrcdir=$srcpwd
 109
 110 extra_host_args=
 111
 112 ### To add a new directory to the tree, first choose whether it is a target
 113 ### or a host dependent tool.  Then put it into the appropriate list
 114 ### (library or tools, host or target), doing a dependency sort.
 115
 116 # Subdirs will be configured in the order listed in build_configdirs,
 117 # configdirs, or target_configdirs; see the serialization section below.
 118
 119 # Dependency sorting is only needed when *configuration* must be done in
 120 # a particular order.  In all cases a dependency should be specified in
 121 # the Makefile, whether or not it's implicitly specified here.
 122
 123 # Double entries in build_configdirs, configdirs, or target_configdirs may
 124 # cause circular dependencies and break everything horribly.
 125
 126 # these library is used by various programs built for the build
 127 # environment
 128 #
 129 build_libs="build-libiberty build-libcpp"
 130
 131 # these tools are built for the build environment
 132 build_tools="build-texinfo build-flex build-bison build-m4 build-fixincludes"
 133
 134 # these libraries are used by various programs built for the host environment
 135 #f
 136 host_libs="intl libiberty opcodes bfd readline tcl tk itcl libgui zlib libbacktrace libcpp libcody libdecnumber gmp mpfr mpc isl libiconv libctf libsframe"
 137
 138 # these tools are built for the host environment
 139 # Note, the powerpc-eabi build depends on sim occurring before gdb in order to
 140 # know that we are building the simulator.
 141 # binutils, gas and ld appear in that order because it makes sense to run
 142 # "make check" in that particular order.
 143 # If --enable-gold is used, "gold" may replace "ld".
 144 host_tools="texinfo flex bison binutils gas ld fixincludes gcc cgen sid sim gdb gdbserver gprof etc expect dejagnu m4 utils guile fastjar gnattools libcc1 gotools c++tools"
 145
 146 # these libraries are built for the target environment, and are built after
 147 # the host libraries and the host tools (which may be a cross compiler)
 148 # Note that libiberty is not a target library.
 149 target_libraries="target-libgcc \
 150                 target-libbacktrace \
 151                 target-libgloss \
 152                 target-newlib \
 153                 target-libgomp \
 154                 target-liboffloadmic \
 155                 target-libatomic \
 156                 target-libitm \
 157                 target-libstdc++-v3 \
 158                 target-libsanitizer \
 159                 target-libvtv \
 160                 target-libssp \
 161                 target-libquadmath \
 162                 target-libgfortran \
 163                 target-libffi \
 164                 target-libobjc \
 165                 target-libada \
 166                 target-libgo \
 167                 target-libphobos \
 168                 target-zlib"
 169
 170 # these tools are built using the target libraries, and are intended to
 171 # run only in the target environment
 172 #
 173 # note: any program that *uses* libraries that are in the "target_libraries"
 174 # list belongs in this list.
 175 #
 176 target_tools="target-rda"
 177
 178 ################################################################################
 179
 180 ## All tools belong in one of the four categories, and are assigned above
 181 ## We assign ${configdirs} this way to remove all embedded newlines.  This
 182 ## is important because configure will choke if they ever get through.
 183 ## ${configdirs} is directories we build using the host tools.
 184 ## ${target_configdirs} is directories we build using the target tools.
 185 configdirs=`echo ${host_libs} ${host_tools}`
 186 target_configdirs=`echo ${target_libraries} ${target_tools}`
 187 build_configdirs=`echo ${build_libs} ${build_tools}`
 188
 189 m4_divert_text([PARSE_ARGS],
 190 [case $srcdir in
 191   *" "*)
 192 m4_pushdef([AS_MESSAGE_LOG_FD], [])dnl
 193     AC_MSG_ERROR([path to source, $srcdir, contains spaces])
 194 m4_popdef([AS_MESSAGE_LOG_FD])dnl
 195     ;;
 196 esac
 197 ac_subdirs_all=`cd $srcdir && echo */configure | sed 's,/configure,,g'`
 198 ])
 199
 200 ################################################################################
 201
 202 srcname="gnu development package"
 203
 204 # This gets set non-empty for some net releases of packages.
 205 appdirs=""
 206
 207 # Define is_cross_compiler to save on calls to 'test'.
 208 is_cross_compiler=
 209 if test x"${host}" = x"${target}" ; then
 210   is_cross_compiler=no
 211 else
 212   is_cross_compiler=yes
 213 fi
 214
 215 # Find the build and target subdir names.
 216 GCC_TOPLEV_SUBDIRS
 217 # Be sure to cover against remnants of an in-tree build.
 218 if test $srcdir != .  && test -d $srcdir/host-${host_noncanonical}; then
 219   AC_MSG_ERROR([building out of tree but $srcdir contains host-${host_noncanonical}.
 220 Use a pristine source tree when building in a separate tree])
 221 fi
 222
 223 # Skipdirs are removed silently.
 224 skipdirs=
 225 # Noconfigdirs are removed loudly.
 226 noconfigdirs=""
 227
 228 use_gnu_ld=
 229 # Make sure we don't let GNU ld be added if we didn't want it.
 230 if test x$with_gnu_ld = xno ; then
 231   use_gnu_ld=no
 232   noconfigdirs="$noconfigdirs ld gold"
 233 fi
 234
 235 use_gnu_as=
 236 # Make sure we don't let GNU as be added if we didn't want it.
 237 if test x$with_gnu_as = xno ; then
 238   use_gnu_as=no
 239   noconfigdirs="$noconfigdirs gas"
 240 fi
 241
 242 use_included_zlib=
 243 AC_ARG_WITH(system-zlib,
 244 [AS_HELP_STRING([--with-system-zlib], [use installed libz])])
 245 # Make sure we don't let ZLIB be added if we didn't want it.
 246 if test x$with_system_zlib = xyes ; then
 247   use_included_zlib=no
 248   noconfigdirs="$noconfigdirs zlib"
 249 fi
 250
 251 # Don't compile the bundled readline/libreadline.a if --with-system-readline
 252 # is provided.
 253 if test x$with_system_readline = xyes ; then
 254   noconfigdirs="$noconfigdirs readline"
 255 fi
 256
 257 AC_ARG_WITH(zstd,
 258 [AS_HELP_STRING([--with-zstd], [Support zstd compressed debug sections (default=auto)])])
 259
 260 # some tools are so dependent upon X11 that if we're not building with X,
 261 # it's not even worth trying to configure, much less build, that tool.
 262
 263 case ${with_x} in
 264   yes | "") ;; # the default value for this tree is that X11 is available
 265   no)
 266     skipdirs="${skipdirs} tk itcl libgui"
 267     # We won't be able to build gdbtk without X.
 268     enable_gdbtk=no
 269     ;;
 270   *)  echo "*** bad value \"${with_x}\" for -with-x flag; ignored" 1>&2 ;;
 271 esac
 272
 273 # Some are only suitable for cross toolchains.
 274 # Remove these if host=target.
 275 cross_only="target-libgloss target-newlib target-opcodes"
 276
 277 case $is_cross_compiler in
 278   no) skipdirs="${skipdirs} ${cross_only}" ;;
 279 esac
 280
 281 # If both --with-headers and --with-libs are specified, default to
 282 # --without-newlib.
 283 if test x"${with_headers}" != x && test x"${with_headers}" != xno \
 284    && test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
 285   if test x"${with_newlib}" = x ; then
 286     with_newlib=no
 287   fi
 288 fi
 289
 290 # Recognize --with-newlib/--without-newlib.
 291 case ${with_newlib} in
 292   no) skipdirs="${skipdirs} target-newlib" ;;
 293   yes) skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'` ;;
 294 esac
 295
 296 AC_ARG_ENABLE(as-accelerator-for,
 297 [AS_HELP_STRING([--enable-as-accelerator-for=ARG],
 298                 [build as offload target compiler.
 299                 Specify offload host triple by ARG])])
 300
 301 AC_ARG_ENABLE(offload-targets,
 302 [AS_HELP_STRING([--enable-offload-targets=LIST],
 303                 [enable offloading to devices from comma-separated LIST of
 304                 TARGET[=DIR]. Use optional path to find offload target compiler
 305                 during the build])],
 306 [
 307   if test x"$enable_offload_targets" = x; then
 308     AC_MSG_ERROR([no offload targets specified])
 309   fi
 310 ], [enable_offload_targets=])
 311
 312 AC_ARG_ENABLE(offload-defaulted,
 313 [AS_HELP_STRING([--enable-offload-defaulted]
 314                 [If enabled, configured but not installed offload compilers and
 315                 libgomp plugins are silently ignored.  Useful for distribution
 316                 compilers where those are in separate optional packages.])],
 317 [enable_offload_defaulted=$enableval],
 318 [enable_offload_defaulted=])
 319
 320 # Handle --enable-gold, --enable-ld.
 321 # --disable-gold [--enable-ld]
 322 #     Build only ld.  Default option.
 323 # --enable-gold [--enable-ld]
 324 #     Build both gold and ld.  Install gold as "ld.gold", install ld
 325 #     as "ld.bfd" and "ld".
 326 # --enable-gold=default [--enable-ld]
 327 #     Build both gold and ld.  Install gold as "ld.gold" and "ld",
 328 #     install ld as "ld.bfd".
 329 # --enable-gold[=default] --disable-ld
 330 #     Build only gold, which is then installed as both "ld.gold" and "ld".
 331 # --enable-gold --enable-ld=default
 332 #     Build both gold (installed as "ld.gold") and ld (installed as "ld"
 333 #     and ld.bfd).
 334 #     In other words, ld is default
 335 # --enable-gold=default --enable-ld=default
 336 #     Error.
 337
 338 default_ld=
 339 AC_ARG_ENABLE(gold,
 340 [AS_HELP_STRING([[--enable-gold[=ARG]]],
 341                 [build gold @<:@ARG={default,yes,no}@:>@])],
 342 ENABLE_GOLD=$enableval,
 343 ENABLE_GOLD=no)
 344 case "${ENABLE_GOLD}" in
 345   yes|default)
 346     # Check for ELF target.
 347     is_elf=no
 348     case "${target}" in
 349       *-*-elf* | *-*-sysv4* | *-*-unixware* | *-*-eabi* | hppa*64*-*-hpux* \
 350       | *-*-linux* | *-*-gnu* | frv-*-uclinux* | *-*-irix5* | *-*-irix6* \
 351       | *-*-netbsd* | *-*-openbsd* | *-*-freebsd* | *-*-dragonfly* \
 352       | *-*-solaris2* | *-*-nto* | *-*-nacl*)
 353         case "${target}" in
 354           *-*-linux*aout* | *-*-linux*oldld*)
 355             ;;
 356           *)
 357             is_elf=yes
 358             ;;
 359         esac
 360     esac
 361
 362     if test "$is_elf" = "yes"; then
 363       # Check for target supported by gold.
 364       case "${target}" in
 365         i?86-*-* | x86_64-*-* | sparc*-*-* | powerpc*-*-* | arm*-*-* \
 366         | aarch64*-*-* | tilegx*-*-* | mips*-*-* | s390*-*-* | loongarch*-*-*)
 367           configdirs="$configdirs gold"
 368           if test x${ENABLE_GOLD} = xdefault; then
 369             default_ld=gold
 370           fi
 371           ENABLE_GOLD=yes
 372           ;;
 373       esac
 374     fi
 375     ;;
 376   no)
 377     ;;
 378   *)
 379     AC_MSG_ERROR([invalid --enable-gold argument])
 380     ;;
 381 esac
 382
 383 AC_ARG_ENABLE(ld,
 384 [AS_HELP_STRING([[--enable-ld[=ARG]]],
 385                 [build ld @<:@ARG={default,yes,no}@:>@])],
 386 ENABLE_LD=$enableval,
 387 ENABLE_LD=yes)
 388
 389 case "${ENABLE_LD}" in
 390   default)
 391     if test x${default_ld} != x; then
 392       AC_MSG_ERROR([either gold or ld can be the default ld])
 393     fi
 394     ;;
 395   yes)
 396     ;;
 397   no)
 398     if test x${ENABLE_GOLD} != xyes; then
 399       AC_MSG_WARN([neither ld nor gold are enabled])
 400     fi
 401     configdirs=`echo " ${configdirs} " | sed -e 's/ ld / /'`
 402     ;;
 403   *)
 404     AC_MSG_ERROR([invalid --enable-ld argument])
 405     ;;
 406 esac
 407
 408 AC_ARG_ENABLE(gprofng,
 409 [AS_HELP_STRING([[--enable-gprofng[=ARG]]],
 410                 [build gprofng @<:@ARG={yes,no}@:>@])],
 411 enable_gprofng=$enableval,
 412 enable_gprofng=yes)
 413 if test "$enable_gprofng" = "yes"; then
 414   case "${target}" in
 415     x86_64-*-linux* | i?86-*-linux* | aarch64-*-linux*)
 416     configdirs="$configdirs gprofng"
 417     ;;
 418   esac
 419 fi
 420
 421
 422 # PR gas/19109
 423 # Decide the default method for compressing debug sections.
 424 # Provide a configure time option to override our default.
 425 AC_ARG_ENABLE(compressed_debug_sections,
 426 [AS_HELP_STRING([--enable-compressed-debug-sections={all,gas,gold,ld,none}],
 427                 [Enable compressed debug sections for gas, gold or ld by
 428                  default])],
 429 [
 430   if test x"$enable_compressed_debug_sections" = xyes; then
 431     AC_MSG_ERROR([no program with compressed debug sections specified])
 432   fi
 433 ], [enable_compressed_debug_sections=])
 434
 435 # Select default compression algorithm.
 436 AC_ARG_ENABLE(default_compressed_debug_sections_algorithm,
 437 [AS_HELP_STRING([--enable-default-compressed-debug-sections-algorithm={zlib,zstd}],
 438                 [Default compression algorithm for --enable-compressed-debug-sections.])],
 439 [], [default_compressed_debug_sections_algorithm=])
 440
 441 # Configure extra directories which are host specific
 442
 443 case "${host}" in
 444   *-cygwin*)
 445     configdirs="$configdirs libtermcap" ;;
 446 esac
 447
 448 # A target can indicate whether a language isn't supported for some reason.
 449 # Only spaces may be used in this macro; not newlines or tabs.
 450 unsupported_languages=
 451
 452 # Remove more programs from consideration, based on the host or
 453 # target this usually means that a port of the program doesn't
 454 # exist yet.
 455
 456 case "${host}" in
 457   i[[3456789]]86-*-msdosdjgpp*)
 458     noconfigdirs="$noconfigdirs tcl tk itcl"
 459     ;;
 460 esac
 461
 462 # Default to --disable-year2038 until we can handle differences between
 463 # projects that use gnulib (which understands year 2038) and projects that
 464 # do not (like BFD).
 465 AC_ARG_ENABLE(year2038,
 466 AS_HELP_STRING([--enable-year2038],
 467   [enable support for timestamps past the year 2038]),
 468 ENABLE_YEAR2038=$enableval,
 469 ENABLE_YEAR2038=no)
 470 enable_year2038=
 471 if test "${ENABLE_YEAR2038}" = "no" ; then
 472   enable_year2038=no
 473 fi
 474
 475 AC_ARG_ENABLE(libquadmath,
 476 AS_HELP_STRING([--disable-libquadmath],
 477   [do not build libquadmath directory]),
 478 ENABLE_LIBQUADMATH=$enableval,
 479 ENABLE_LIBQUADMATH=yes)
 480 if test "${ENABLE_LIBQUADMATH}" = "no" ; then
 481   noconfigdirs="$noconfigdirs target-libquadmath"
 482 fi
 483
 484
 485 AC_ARG_ENABLE(libquadmath-support,
 486 AS_HELP_STRING([--disable-libquadmath-support],
 487   [disable libquadmath support for Fortran]),
 488 ENABLE_LIBQUADMATH_SUPPORT=$enableval,
 489 ENABLE_LIBQUADMATH_SUPPORT=yes)
 490 enable_libquadmath_support=
 491 if test "${ENABLE_LIBQUADMATH_SUPPORT}" = "no" ; then
 492   enable_libquadmath_support=no
 493 fi
 494
 495
 496 AC_ARG_ENABLE(libada,
 497 [AS_HELP_STRING([--enable-libada], [build libada directory])],
 498 ENABLE_LIBADA=$enableval,
 499 ENABLE_LIBADA=yes)
 500 if test "${ENABLE_LIBADA}" != "yes" ; then
 501   noconfigdirs="$noconfigdirs gnattools"
 502 fi
 503
 504 AC_ARG_ENABLE(libssp,
 505 [AS_HELP_STRING([--enable-libssp], [build libssp directory])],
 506 ENABLE_LIBSSP=$enableval,
 507 ENABLE_LIBSSP=yes)
 508
 509 AC_ARG_ENABLE(libstdcxx,
 510 AS_HELP_STRING([--disable-libstdcxx],
 511   [do not build libstdc++-v3 directory]),
 512 ENABLE_LIBSTDCXX=$enableval,
 513 ENABLE_LIBSTDCXX=default)
 514 [if test "${ENABLE_LIBSTDCXX}" = "no" ; then
 515   noconfigdirs="$noconfigdirs target-libstdc++-v3"
 516 fi]
 517
 518 # If this is accelerator compiler and its target is intelmic we enable
 519 # target liboffloadmic by default.  If this is compiler with offloading
 520 # for intelmic we enable host liboffloadmic by default.  Otherwise
 521 # liboffloadmic is disabled by default.
 522 AC_ARG_ENABLE([liboffloadmic],
 523 AC_HELP_STRING([[--enable-liboffloadmic[=ARG]]],
 524                [build liboffloadmic @<:@ARG={no,host,target}@:>@]),
 525 [case "$enableval" in
 526   no | host | target)
 527     enable_liboffloadmic=$enableval ;;
 528   *)
 529     AC_MSG_ERROR([--enable-liboffloadmic=no/host/target]) ;;
 530 esac],
 531 [if test x"$enable_as_accelerator_for" != x; then
 532   case "${target}" in
 533     *-intelmic-* | *-intelmicemul-*)
 534       enable_liboffloadmic=target
 535       extra_liboffloadmic_configure_flags="--enable-liboffloadmic=target"
 536       ;;
 537     *)
 538       enable_liboffloadmic=no
 539       ;;
 540   esac
 541 else
 542   case "${enable_offload_targets}" in
 543     *-intelmic-* | *-intelmicemul-*)
 544       enable_liboffloadmic=host
 545       extra_liboffloadmic_configure_flags="--enable-liboffloadmic=host"
 546       ;;
 547     *)
 548       enable_liboffloadmic=no
 549       ;;
 550     esac
 551 fi])
 552 AC_SUBST(extra_liboffloadmic_configure_flags)
 553
 554 # Enable libgomp by default on hosted POSIX systems, and a few others.
 555 if test x$enable_libgomp = x ; then
 556     case "${target}" in
 557     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 558         ;;
 559     *-*-netbsd* | *-*-freebsd* | *-*-openbsd* | *-*-dragonfly*)
 560         ;;
 561     *-*-solaris2* | *-*-hpux11*)
 562         ;;
 563     *-*-darwin* | *-*-aix*)
 564         ;;
 565     nvptx*-*-* | amdgcn*-*-*)
 566         ;;
 567     *)
 568         noconfigdirs="$noconfigdirs target-libgomp"
 569         ;;
 570     esac
 571 fi
 572
 573 # Disable libatomic on unsupported systems.
 574 if test -d ${srcdir}/libatomic; then
 575     if test x$enable_libatomic = x; then
 576         AC_MSG_CHECKING([for libatomic support])
 577         if (srcdir=${srcdir}/libatomic; \
 578                 . ${srcdir}/configure.tgt; \
 579                 test -n "$UNSUPPORTED")
 580         then
 581             AC_MSG_RESULT([no])
 582             noconfigdirs="$noconfigdirs target-libatomic"
 583         else
 584             AC_MSG_RESULT([yes])
 585         fi
 586     fi
 587 fi
 588
 589 # Disable liboffloadmic on unsupported systems.
 590 if test -d ${srcdir}/liboffloadmic; then
 591     if test x$enable_liboffloadmic != xno; then
 592         AC_MSG_CHECKING([for liboffloadmic support])
 593         if (srcdir=${srcdir}/liboffloadmic; \
 594                 . ${srcdir}/configure.tgt; \
 595                 test -n "$UNSUPPORTED")
 596         then
 597             AC_MSG_RESULT([no])
 598             noconfigdirs="$noconfigdirs target-liboffloadmic"
 599         else
 600             AC_MSG_RESULT([yes])
 601         fi
 602     fi
 603 fi
 604
 605 # Disable libitm on unsupported systems.
 606 if test -d ${srcdir}/libitm; then
 607     if test x$enable_libitm = x; then
 608         AC_MSG_CHECKING([for libitm support])
 609         if (srcdir=${srcdir}/libitm; \
 610                 . ${srcdir}/configure.tgt; \
 611                 test -n "$UNSUPPORTED")
 612         then
 613             AC_MSG_RESULT([no])
 614             noconfigdirs="$noconfigdirs target-libitm"
 615         else
 616             AC_MSG_RESULT([yes])
 617         fi
 618     fi
 619 fi
 620
 621 # Disable libsanitizer on unsupported systems.
 622 if test -d ${srcdir}/libsanitizer; then
 623     if test x$enable_libsanitizer = x; then
 624         AC_MSG_CHECKING([for libsanitizer support])
 625         if (srcdir=${srcdir}/libsanitizer; \
 626                 . ${srcdir}/configure.tgt; \
 627                 test -n "$UNSUPPORTED")
 628         then
 629             AC_MSG_RESULT([no])
 630             noconfigdirs="$noconfigdirs target-libsanitizer"
 631         else
 632             AC_MSG_RESULT([yes])
 633         fi
 634     fi
 635 fi
 636
 637 # Disable libvtv on unsupported systems.
 638 if test -d ${srcdir}/libvtv; then
 639     if test x$enable_libvtv = x; then
 640         AC_MSG_CHECKING([for libvtv support])
 641         if (srcdir=${srcdir}/libvtv; \
 642                 . ${srcdir}/configure.tgt; \
 643                 test "$VTV_SUPPORTED" != "yes")
 644         then
 645             AC_MSG_RESULT([no])
 646             noconfigdirs="$noconfigdirs target-libvtv"
 647         else
 648             AC_MSG_RESULT([yes])
 649         fi
 650     fi
 651 fi
 652
 653 # Disable libquadmath for some systems.
 654 case "${target}" in
 655   avr-*-*)
 656     noconfigdirs="$noconfigdirs target-libquadmath"
 657     ;;
 658   # libquadmath is unused on AIX and libquadmath build process use of
 659   # LD_LIBRARY_PATH can break AIX bootstrap.
 660   powerpc-*-aix* | rs6000-*-aix*)
 661     noconfigdirs="$noconfigdirs target-libquadmath"
 662     ;;
 663 esac
 664
 665 # Disable libssp for some systems.
 666 case "${target}" in
 667   avr-*-*)
 668     # No hosted I/O support.
 669     noconfigdirs="$noconfigdirs target-libssp"
 670     ;;
 671   bpf-*-*)
 672     noconfigdirs="$noconfigdirs target-libssp"
 673     ;;
 674   powerpc-*-aix* | rs6000-*-aix*)
 675     noconfigdirs="$noconfigdirs target-libssp"
 676     ;;
 677   pru-*-*)
 678     # No hosted I/O support.
 679     noconfigdirs="$noconfigdirs target-libssp"
 680     ;;
 681   rl78-*-*)
 682     # libssp uses a misaligned load to trigger a fault, but the RL78
 683     # doesn't fault for those - instead, it gives a build-time error
 684     # for explicit misaligned loads.
 685     noconfigdirs="$noconfigdirs target-libssp"
 686     ;;
 687   visium-*-*)
 688     # No hosted I/O support.
 689     noconfigdirs="$noconfigdirs target-libssp"
 690     ;;
 691 esac
 692
 693 # Disable libstdc++-v3 for some systems.
 694 # Allow user to override this if they pass --enable-libstdcxx
 695 if test "${ENABLE_LIBSTDCXX}" = "default" ; then
 696   case "${target}" in
 697     *-*-vxworks*)
 698       # VxWorks uses the Dinkumware C++ library.
 699       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 700       ;;
 701     amdgcn*-*-*)
 702       # Not ported/fails to build when using newlib.
 703       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 704       ;;
 705     arm*-wince-pe*)
 706       # the C++ libraries don't build on top of CE's C libraries
 707       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 708       ;;
 709     avr-*-*)
 710       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 711       ;;
 712     bpf-*-*)
 713       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 714       ;;
 715     ft32-*-*)
 716       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 717       ;;
 718   esac
 719 fi
 720
 721 # Disable C++ on systems where it is known to not work.
 722 # For testing, you can override this with --enable-languages=c++.
 723 case ,${enable_languages}, in
 724   *,c++,*)
 725     ;;
 726   *)
 727       case "${target}" in
 728         bpf-*-*)
 729           unsupported_languages="$unsupported_languages c++"
 730           ;;
 731       esac
 732       ;;
 733 esac
 734
 735 # Disable Objc on systems where it is known to not work.
 736 # For testing, you can override this with --enable-languages=objc.
 737 case ,${enable_languages}, in
 738   *,objc,*)
 739     ;;
 740   *)
 741       case "${target}" in
 742         bpf-*-*)
 743           unsupported_languages="$unsupported_languages objc"
 744           ;;
 745       esac
 746       ;;
 747 esac
 748
 749 # Disable D on systems where it is known to not work.
 750 # For testing, you can override this with --enable-languages=d.
 751 case ,${enable_languages}, in
 752   *,d,*)
 753     ;;
 754   *)
 755     case "${target}" in
 756       bpf-*-*)
 757         unsupported_languages="$unsupported_languages d"
 758         ;;
 759     esac
 760     ;;
 761 esac
 762
 763 # Disable libphobos on unsupported systems.
 764 # For testing, you can override this with --enable-libphobos.
 765 if test -d ${srcdir}/libphobos; then
 766     if test x$enable_libphobos = x; then
 767         AC_MSG_CHECKING([for libphobos support])
 768         if (srcdir=${srcdir}/libphobos; \
 769                 . ${srcdir}/configure.tgt; \
 770                 test "$LIBPHOBOS_SUPPORTED" != "yes")
 771         then
 772             AC_MSG_RESULT([no])
 773             noconfigdirs="$noconfigdirs target-libphobos"
 774         else
 775             AC_MSG_RESULT([yes])
 776         fi
 777     fi
 778 fi
 779
 780 # Disable Fortran for some systems.
 781 case "${target}" in
 782   mmix-*-*)
 783     # See <http://gcc.gnu.org/ml/gcc-patches/2004-11/msg00572.html>.
 784     unsupported_languages="$unsupported_languages fortran"
 785     ;;
 786   bpf-*-*)
 787     unsupported_languages="$unsupported_languages fortran"
 788     ;;
 789 esac
 790
 791 # Disable libffi for some systems.
 792 case "${target}" in
 793   powerpc-*-darwin*)
 794     ;;
 795   i[[3456789]]86-*-darwin*)
 796     ;;
 797   x86_64-*-darwin[[912]]*)
 798     ;;
 799   *-*-darwin*)
 800     noconfigdirs="$noconfigdirs target-libffi"
 801     ;;
 802   *-*-netware*)
 803     noconfigdirs="$noconfigdirs target-libffi"
 804     ;;
 805   *-*-phoenix*)
 806     noconfigdirs="$noconfigdirs target-libffi"
 807     ;;
 808   *-*-rtems*)
 809     noconfigdirs="$noconfigdirs target-libffi"
 810     ;;
 811   *-*-tpf*)
 812     noconfigdirs="$noconfigdirs target-libffi"
 813     ;;
 814   *-*-uclinux*)
 815     noconfigdirs="$noconfigdirs target-libffi"
 816     ;;
 817   *-*-vxworks*)
 818     noconfigdirs="$noconfigdirs target-libffi"
 819     ;;
 820   aarch64*-*-freebsd*)
 821     noconfigdirs="$noconfigdirs target-libffi"
 822     ;;
 823   alpha*-*-*vms*)
 824     noconfigdirs="$noconfigdirs target-libffi"
 825     ;;
 826   arm*-*-freebsd*)
 827     noconfigdirs="$noconfigdirs target-libffi"
 828     ;;
 829   arm-wince-pe)
 830     noconfigdirs="$noconfigdirs target-libffi"
 831     ;;
 832   arm*-*-symbianelf*)
 833     noconfigdirs="$noconfigdirs target-libffi"
 834     ;;
 835   bpf-*-*)
 836     noconfigdirs="$noconfigdirs target-libffi"
 837     ;;
 838   cris-*-* | crisv32-*-*)
 839     case "${target}" in
 840       *-*-linux*)
 841         ;;
 842       *) # See PR46792 regarding target-libffi.
 843         noconfigdirs="$noconfigdirs target-libffi";;
 844     esac
 845     ;;
 846   hppa*64*-*-hpux*)
 847     noconfigdirs="$noconfigdirs target-libffi"
 848     ;;
 849   hppa*-hp-hpux11*)
 850     ;;
 851   hppa*-*-hpux*)
 852     noconfigdirs="$noconfigdirs target-libffi"
 853     ;;
 854   ia64*-*-*vms*)
 855     noconfigdirs="$noconfigdirs target-libffi"
 856     ;;
 857   i[[3456789]]86-w64-mingw*)
 858     noconfigdirs="$noconfigdirs target-libffi"
 859     ;;
 860   i[[3456789]]86-*-mingw*)
 861     noconfigdirs="$noconfigdirs target-libffi"
 862     ;;
 863   x86_64-*-mingw*)
 864     noconfigdirs="$noconfigdirs target-libffi"
 865     ;;
 866   mmix-*-*)
 867     noconfigdirs="$noconfigdirs target-libffi"
 868     ;;
 869   powerpc-*-aix*)
 870     ;;
 871   rs6000-*-aix*)
 872     ;;
 873   ft32-*-*)
 874     noconfigdirs="$noconfigdirs target-libffi"
 875     ;;
 876   *-*-lynxos*)
 877     noconfigdirs="$noconfigdirs target-libffi"
 878     ;;
 879 esac
 880
 881 # Disable the go frontend on systems where it is known to not work. Please keep
 882 # this in sync with contrib/config-list.mk.
 883 case "${target}" in
 884 *-*-darwin* | *-*-cygwin* | *-*-mingw* | bpf-* )
 885     unsupported_languages="$unsupported_languages go"
 886     ;;
 887 esac
 888
 889 # Only allow gdbserver on some systems.
 890 if test -d ${srcdir}/gdbserver; then
 891     if test x$enable_gdbserver = x; then
 892         AC_MSG_CHECKING([for gdbserver support])
 893         if (srcdir=${srcdir}/gdbserver; \
 894                 . ${srcdir}/configure.srv; \
 895                 test -n "$UNSUPPORTED")
 896         then
 897             AC_MSG_RESULT([no])
 898             noconfigdirs="$noconfigdirs gdbserver"
 899         else
 900             AC_MSG_RESULT([yes])
 901         fi
 902     fi
 903 fi
 904
 905 # Disable libgo for some systems where it is known to not work.
 906 # For testing, you can easily override this with --enable-libgo.
 907 if test x$enable_libgo = x; then
 908     case "${target}" in
 909     *-*-darwin*)
 910         # PR 46986
 911         noconfigdirs="$noconfigdirs target-libgo"
 912         ;;
 913     *-*-cygwin* | *-*-mingw*)
 914         noconfigdirs="$noconfigdirs target-libgo"
 915         ;;
 916     bpf-*-*)
 917         noconfigdirs="$noconfigdirs target-libgo"
 918         ;;
 919     esac
 920 fi
 921
 922 # Default libgloss CPU subdirectory.
 923 libgloss_dir="$target_cpu"
 924
 925 case "${target}" in
 926   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 927     libgloss_dir=wince
 928     ;;
 929   aarch64*-*-* )
 930     libgloss_dir=aarch64
 931     ;;
 932   arm*-*-*)
 933     libgloss_dir=arm
 934     ;;
 935   cris-*-* | crisv32-*-*)
 936     libgloss_dir=cris
 937     ;;
 938   hppa*-*-*)
 939     libgloss_dir=pa
 940     ;;
 941   i[[3456789]]86-*-*)
 942     libgloss_dir=i386
 943     ;;
 944   loongarch*-*-*)
 945     libgloss_dir=loongarch
 946     ;;
 947   m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)
 948     libgloss_dir=m68hc11
 949     ;;
 950   m68*-*-* | fido-*-*)
 951     libgloss_dir=m68k
 952     ;;
 953   mips*-*-*)
 954     libgloss_dir=mips
 955     ;;
 956   powerpc*-*-*)
 957     libgloss_dir=rs6000
 958     ;;
 959   pru-*-*)
 960     libgloss_dir=pru
 961     ;;
 962   sparc*-*-*)
 963     libgloss_dir=sparc
 964     ;;
 965 esac
 966
 967 # Disable newlib and libgloss for various target OSes.
 968 case "${target}" in
 969   alpha*-dec-osf*)
 970     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 971     ;;
 972   i[[3456789]]86-*-linux*)
 973     # This section makes it possible to build newlib natively on linux.
 974     # If we are using a cross compiler then don't configure newlib.
 975     if test x${is_cross_compiler} != xno ; then
 976       noconfigdirs="$noconfigdirs target-newlib"
 977     fi
 978     noconfigdirs="$noconfigdirs target-libgloss"
 979     # If we are not using a cross compiler, do configure newlib.
 980     # Note however, that newlib will only be configured in this situation
 981     # if the --with-newlib option has been given, because otherwise
 982     # 'target-newlib' will appear in skipdirs.
 983     ;;
 984   i[[3456789]]86-*-rdos*)
 985     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 986     ;;
 987   sh*-*-pe|mips*-*-pe|arm-wince-pe)
 988     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 989     ;;
 990   sparc-*-sunos4*)
 991     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 992     ;;
 993   bpf-*-*)
 994     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 995     ;;
 996   *-*-aix*)
 997     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 998     ;;
 999   *-*-beos*)
1000     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1001     ;;
1002   *-*-chorusos)
1003     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1004     ;;
1005   *-*-dragonfly*)
1006     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1007     ;;
1008   *-*-freebsd*)
1009     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1010     ;;
1011   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
1012     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1013     ;;
1014   *-*-lynxos*)
1015     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1016     ;;
1017   *-*-mingw*)
1018     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1019     ;;
1020   *-*-netbsd*)
1021     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1022     ;;
1023   *-*-netware*)
1024     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1025     ;;
1026   *-*-tpf*)
1027     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1028     ;;
1029   *-*-uclinux*)
1030     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1031     ;;
1032   *-*-vxworks*)
1033     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1034     ;;
1035 esac
1036
1037 case "${target}" in
1038   *-*-chorusos)
1039     ;;
1040   aarch64-*-darwin*)
1041     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1042     noconfigdirs="$noconfigdirs sim target-rda"
1043     ;;
1044   amdgcn*-*-*)
1045     ;;
1046   arm-*-darwin*)
1047     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1048     noconfigdirs="$noconfigdirs sim target-rda"
1049     ;;
1050   powerpc-*-darwin*)
1051     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1052     noconfigdirs="$noconfigdirs sim target-rda"
1053     ;;
1054   i[[3456789]]86-*-darwin*)
1055     noconfigdirs="$noconfigdirs ld gprof"
1056     noconfigdirs="$noconfigdirs sim target-rda"
1057     ;;
1058   x86_64-*-darwin[[912]]*)
1059     noconfigdirs="$noconfigdirs ld gas gprof"
1060     noconfigdirs="$noconfigdirs sim target-rda"
1061     ;;
1062   *-*-darwin*)
1063     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1064     noconfigdirs="$noconfigdirs sim target-rda"
1065     ;;
1066   *-*-dragonfly*)
1067     ;;
1068   *-*-freebsd*)
1069     if test "x$with_gmp" = x \
1070         && ! test -d ${srcdir}/gmp \
1071         && test -f /usr/local/include/gmp.h; then
1072       with_gmp=/usr/local
1073     fi
1074     ;;
1075   *-*-kaos*)
1076     # Remove unsupported stuff on all kaOS configurations.
1077     noconfigdirs="$noconfigdirs target-libgloss"
1078     ;;
1079   *-*-netbsd*)
1080     ;;
1081   *-*-netware*)
1082     ;;
1083   *-*-phoenix*)
1084     noconfigdirs="$noconfigdirs target-libgloss"
1085     ;;
1086   *-*-rtems*)
1087     noconfigdirs="$noconfigdirs target-libgloss"
1088     ;;
1089     # The tpf target doesn't support gdb yet.
1090   *-*-tpf*)
1091     noconfigdirs="$noconfigdirs gdb tcl tk libgui itcl"
1092     ;;
1093   *-*-uclinux*)
1094     noconfigdirs="$noconfigdirs target-rda"
1095     ;;
1096   *-*-vxworks*)
1097     ;;
1098   alpha*-dec-osf*)
1099     # ld works, but does not support shared libraries.
1100     # gas doesn't generate exception information.
1101     noconfigdirs="$noconfigdirs gas ld"
1102     ;;
1103   alpha*-*-*vms*)
1104     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss"
1105     ;;
1106   alpha*-*-*)
1107     # newlib is not 64 bit ready
1108     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1109     ;;
1110   bpf-*-*)
1111     noconfigdirs="$noconfigdirs target-libobjc target-libbacktrace"
1112     ;;
1113   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
1114     noconfigdirs="$noconfigdirs tcl tk itcl libgui sim"
1115     ;;
1116   arc*-*-*)
1117     noconfigdirs="$noconfigdirs sim"
1118     ;;
1119   arm-*-pe*)
1120     noconfigdirs="$noconfigdirs target-libgloss"
1121     ;;
1122   arm-*-riscix*)
1123     noconfigdirs="$noconfigdirs ld target-libgloss"
1124     ;;
1125   avr-*-*)
1126     if test x${with_avrlibc} != xno; then
1127       noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1128     fi
1129     ;;
1130   c4x-*-* | tic4x-*-*)
1131     noconfigdirs="$noconfigdirs target-libgloss"
1132     ;;
1133   tic54x-*-*)
1134     noconfigdirs="$noconfigdirs target-libgloss gdb"
1135     ;;
1136   d10v-*-*)
1137     noconfigdirs="$noconfigdirs target-libgloss"
1138     ;;
1139   d30v-*-*)
1140     noconfigdirs="$noconfigdirs gdb"
1141     ;;
1142   fr30-*-elf*)
1143     noconfigdirs="$noconfigdirs gdb"
1144     ;;
1145   ft32-*-*)
1146     noconfigdirs="$noconfigdirs target-rda gprof"
1147     ;;
1148   moxie-*-*)
1149     noconfigdirs="$noconfigdirs"
1150     ;;
1151   h8300*-*-*)
1152     noconfigdirs="$noconfigdirs target-libgloss"
1153     ;;
1154   h8500-*-*)
1155     noconfigdirs="$noconfigdirs target-libgloss"
1156     ;;
1157   hppa1.1-*-osf* | hppa1.1-*-bsd* )
1158     ;;
1159   hppa*64*-*-hpux*)
1160     noconfigdirs="$noconfigdirs gdb"
1161     ;;
1162   hppa*-*-hpux11*)
1163     noconfigdirs="$noconfigdirs gdb ld"
1164     ;;
1165   hppa*64*-*-linux*)
1166     ;;
1167   hppa*-*-linux*)
1168     ;;
1169   hppa*-*-*elf* | \
1170   hppa*-*-lites* | \
1171   hppa*-*-openbsd* | \
1172   hppa*64*-*-*)
1173     ;;
1174   hppa*-*-pro*)
1175     ;;
1176   hppa*-*-*)
1177     noconfigdirs="$noconfigdirs ld"
1178     ;;
1179   i960-*-*)
1180     noconfigdirs="$noconfigdirs gdb"
1181     ;;
1182   ia64*-*-elf*)
1183     # No gdb support yet.
1184     noconfigdirs="$noconfigdirs readline libgui itcl gdb"
1185     ;;
1186   ia64*-**-hpux*)
1187     # No ld support yet.
1188     noconfigdirs="$noconfigdirs gdb libgui itcl ld"
1189     ;;
1190   ia64*-*-*vms*)
1191     # No ld support yet.
1192     noconfigdirs="$noconfigdirs libgui itcl ld"
1193     ;;
1194   i[[3456789]]86-w64-mingw*)
1195     ;;
1196   i[[3456789]]86-*-mingw*)
1197     target_configdirs="$target_configdirs target-winsup"
1198     ;;
1199   *-*-cygwin*)
1200     target_configdirs="$target_configdirs target-libtermcap target-winsup"
1201     noconfigdirs="$noconfigdirs target-libgloss"
1202     # always build newlib if winsup directory is present.
1203     if test -d "$srcdir/winsup/cygwin"; then
1204       skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1205     elif test -d "$srcdir/newlib"; then
1206       echo "Warning: winsup/cygwin is missing so newlib can't be built."
1207     fi
1208     ;;
1209   i[[3456789]]86-*-pe)
1210     noconfigdirs="$noconfigdirs target-libgloss"
1211     ;;
1212   i[[3456789]]86-*-sco3.2v5*)
1213     # The linker does not yet know about weak symbols in COFF,
1214     # and is not configured to handle mixed ELF and COFF.
1215     noconfigdirs="$noconfigdirs ld target-libgloss"
1216     ;;
1217   i[[3456789]]86-*-sco*)
1218     noconfigdirs="$noconfigdirs gprof target-libgloss"
1219     ;;
1220   i[[3456789]]86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*)
1221     noconfigdirs="$noconfigdirs target-libgloss"
1222     ;;
1223   i[[3456789]]86-*-sysv4*)
1224     noconfigdirs="$noconfigdirs target-libgloss"
1225     ;;
1226   i[[3456789]]86-*-beos*)
1227     noconfigdirs="$noconfigdirs gdb"
1228     ;;
1229   i[[3456789]]86-*-rdos*)
1230     noconfigdirs="$noconfigdirs gdb"
1231     ;;
1232   mmix-*-*)
1233     noconfigdirs="$noconfigdirs gdb"
1234     ;;
1235   mt-*-*)
1236     noconfigdirs="$noconfigdirs sim"
1237     ;;
1238   nfp-*-*)
1239     noconfigdirs="$noconfigdirs ld gas gdb gprof sim"
1240     noconfigdirs="$noconfigdirs $target_libraries"
1241     ;;
1242   pdp11-*-*)
1243     noconfigdirs="$noconfigdirs gdb gprof"
1244     ;;
1245   powerpc-*-aix*)
1246     # copied from rs6000-*-* entry
1247     noconfigdirs="$noconfigdirs gprof"
1248     ;;
1249   powerpc*-*-winnt* | powerpc*-*-pe*)
1250     target_configdirs="$target_configdirs target-winsup"
1251     noconfigdirs="$noconfigdirs gdb tcl tk target-libgloss itcl"
1252     # always build newlib.
1253     skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1254     ;;
1255     # This is temporary until we can link against shared libraries
1256   powerpcle-*-solaris*)
1257     noconfigdirs="$noconfigdirs gdb sim tcl tk itcl"
1258     ;;
1259   powerpc-*-beos*)
1260     noconfigdirs="$noconfigdirs gdb"
1261     ;;
1262   rs6000-*-lynxos*)
1263     noconfigdirs="$noconfigdirs gprof"
1264     ;;
1265   rs6000-*-aix*)
1266     noconfigdirs="$noconfigdirs gprof"
1267     ;;
1268   rs6000-*-*)
1269     noconfigdirs="$noconfigdirs gprof"
1270     ;;
1271   m68k-apollo-*)
1272     noconfigdirs="$noconfigdirs ld binutils gprof target-libgloss"
1273     ;;
1274   microblaze*)
1275     noconfigdirs="$noconfigdirs gprof"
1276     ;;
1277   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
1278     if test x$with_newlib = xyes; then
1279       noconfigdirs="$noconfigdirs gprof"
1280     fi
1281     ;;
1282   mips*-*-irix5*)
1283     noconfigdirs="$noconfigdirs gprof target-libgloss"
1284     ;;
1285   mips*-*-irix6*)
1286     noconfigdirs="$noconfigdirs gprof target-libgloss"
1287     ;;
1288   mips*-*-bsd*)
1289     noconfigdirs="$noconfigdirs ld gas gprof target-libgloss"
1290     ;;
1291   mips*-*-linux*)
1292     ;;
1293   mips*-*-ultrix* | mips*-*-osf* | mips*-*-ecoff* | mips*-*-pe* \
1294   | mips*-*-irix* | mips*-*-lnews* | mips*-*-riscos*)
1295     noconfigdirs="$noconfigdirs ld gas gprof"
1296     ;;
1297   mips*-*-*)
1298     noconfigdirs="$noconfigdirs gprof"
1299     ;;
1300   nvptx*-*-*)
1301     noconfigdirs="$noconfigdirs target-libssp target-libstdc++-v3 target-libobjc"
1302     ;;
1303   sh-*-*)
1304     case "${target}" in
1305       sh*-*-elf)
1306          ;;
1307       *)
1308          noconfigdirs="$noconfigdirs target-libgloss" ;;
1309     esac
1310     ;;
1311   sparc-*-sunos4*)
1312     if test x${is_cross_compiler} = xno ; then
1313            use_gnu_ld=no
1314     fi
1315     ;;
1316   tic6x-*-*)
1317     noconfigdirs="$noconfigdirs sim"
1318     ;;
1319   tilepro*-*-* | tilegx*-*-*)
1320     noconfigdirs="$noconfigdirs sim"
1321     ;;
1322   v810-*-*)
1323     noconfigdirs="$noconfigdirs bfd binutils gas gdb ld opcodes target-libgloss"
1324     ;;
1325   vax-*-*)
1326     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1327     ;;
1328   wasm32-*-*)
1329     noconfigdirs="$noconfigdirs ld"
1330     ;;
1331   loongarch*-*-linux*)
1332     ;;
1333   loongarch*-*-*)
1334     noconfigdirs="$noconfigdirs gprof"
1335     ;;
1336 esac
1337
1338 # If we aren't building newlib, then don't build libgloss, since libgloss
1339 # depends upon some newlib header files.
1340 case "${noconfigdirs}" in
1341   *target-libgloss*) ;;
1342   *target-newlib*) noconfigdirs="$noconfigdirs target-libgloss" ;;
1343 esac
1344
1345 # Work in distributions that contain no compiler tools, like Autoconf.
1346 host_makefile_frag=/dev/null
1347 if test -d ${srcdir}/config ; then
1348 case "${host}" in
1349   i[[3456789]]86-*-msdosdjgpp*)
1350     host_makefile_frag="config/mh-djgpp"
1351     ;;
1352   *-cygwin*)
1353     ACX_CHECK_CYGWIN_CAT_WORKS
1354     host_makefile_frag="config/mh-cygwin"
1355     ;;
1356   *-mingw*)
1357     host_makefile_frag="config/mh-mingw"
1358     ;;
1359   alpha*-linux*)
1360     host_makefile_frag="config/mh-alpha-linux"
1361     ;;
1362   hppa*-hp-hpux10*)
1363     host_makefile_frag="config/mh-pa-hpux10"
1364     ;;
1365   hppa*-hp-hpux*)
1366     host_makefile_frag="config/mh-pa"
1367     ;;
1368   hppa*-*)
1369     host_makefile_frag="config/mh-pa"
1370     ;;
1371   i?86-*-darwin[[89]]* | i?86-*-darwin1[[0-7]]* | powerpc*-*-darwin*)
1372     host_makefile_frag="config/mh-darwin"
1373     ;;
1374   powerpc-*-aix*)
1375     host_makefile_frag="config/mh-ppc-aix"
1376     ;;
1377   rs6000-*-aix*)
1378     host_makefile_frag="config/mh-ppc-aix"
1379     ;;
1380 esac
1381 fi
1382
1383 if test "${build}" != "${host}" ; then
1384   AR_FOR_BUILD=${AR_FOR_BUILD-ar}
1385   AS_FOR_BUILD=${AS_FOR_BUILD-as}
1386   CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
1387   CPP_FOR_BUILD="${CPP_FOR_BUILD-\$(CC_FOR_BUILD) -E}"
1388   CXX_FOR_BUILD=${CXX_FOR_BUILD-g++}
1389   DSYMUTIL_FOR_BUILD=${DSYMUTIL_FOR_BUILD-dsymutil}
1390   GFORTRAN_FOR_BUILD=${GFORTRAN_FOR_BUILD-gfortran}
1391   GOC_FOR_BUILD=${GOC_FOR_BUILD-gccgo}
1392   GDC_FOR_BUILD=${GDC_FOR_BUILD-gdc}
1393   DLLTOOL_FOR_BUILD=${DLLTOOL_FOR_BUILD-dlltool}
1394   LD_FOR_BUILD=${LD_FOR_BUILD-ld}
1395   NM_FOR_BUILD=${NM_FOR_BUILD-nm}
1396   RANLIB_FOR_BUILD=${RANLIB_FOR_BUILD-ranlib}
1397   WINDRES_FOR_BUILD=${WINDRES_FOR_BUILD-windres}
1398   WINDMC_FOR_BUILD=${WINDMC_FOR_BUILD-windmc}
1399 else
1400   AR_FOR_BUILD="\$(AR)"
1401   AS_FOR_BUILD="\$(AS)"
1402   CC_FOR_BUILD="\$(CC)"
1403   CXX_FOR_BUILD="\$(CXX)"
1404   DSYMUTIL_FOR_BUILD="\$(DSYMUTIL)"
1405   GFORTRAN_FOR_BUILD="\$(GFORTRAN)"
1406   GOC_FOR_BUILD="\$(GOC)"
1407   GDC_FOR_BUILD="\$(GDC)"
1408   DLLTOOL_FOR_BUILD="\$(DLLTOOL)"
1409   LD_FOR_BUILD="\$(LD)"
1410   NM_FOR_BUILD="\$(NM)"
1411   RANLIB_FOR_BUILD="\$(RANLIB)"
1412   WINDRES_FOR_BUILD="\$(WINDRES)"
1413   WINDMC_FOR_BUILD="\$(WINDMC)"
1414 fi
1415
1416 AC_PROG_CC_C99
1417 AC_PROG_CXX
1418
1419 # We must set the default linker to the linker used by gcc for the correct
1420 # operation of libtool.  If LD is not defined and we are using gcc, try to
1421 # set the LD default to the ld used by gcc.
1422 if test -z "$LD"; then
1423   if test "$GCC" = yes; then
1424     case $build in
1425     *-*-mingw*)
1426       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1 | tr -d '\015'` ;;
1427     *)
1428       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1` ;;
1429     esac
1430     case $gcc_prog_ld in
1431     # Accept absolute paths.
1432     [[\\/]* | [A-Za-z]:[\\/]*)]
1433       LD="$gcc_prog_ld" ;;
1434     esac
1435   fi
1436 fi
1437
1438 # Check whether -static-libstdc++ -static-libgcc is supported.
1439 have_static_libs=no
1440 if test "$GCC" = yes; then
1441   saved_LDFLAGS="$LDFLAGS"
1442
1443   LDFLAGS="$LDFLAGS -static-libstdc++ -static-libgcc"
1444   AC_MSG_CHECKING([whether g++ accepts -static-libstdc++ -static-libgcc])
1445   AC_LANG_PUSH(C++)
1446   AC_LINK_IFELSE([AC_LANG_SOURCE([
1447 #if (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 5)
1448 #error -static-libstdc++ not implemented
1449 #endif
1450 int main() {}])],
1451     [AC_MSG_RESULT([yes]); have_static_libs=yes],
1452     [AC_MSG_RESULT([no])])
1453   AC_LANG_POP(C++)
1454
1455   LDFLAGS="$saved_LDFLAGS"
1456 fi
1457
1458 ACX_PROG_GNAT
1459 ACX_PROG_GDC
1460 ACX_PROG_CMP_IGNORE_INITIAL
1461
1462 AC_ARG_ENABLE([bootstrap],
1463 [AS_HELP_STRING([--enable-bootstrap],
1464                 [enable bootstrapping @<:@yes if native build@:>@])],,
1465 enable_bootstrap=default)
1466
1467 # Issue errors and warnings for invalid/strange bootstrap combinations.
1468 if test -r $srcdir/gcc/configure; then
1469   have_compiler=yes
1470 else
1471   have_compiler=no
1472 fi
1473
1474 case "$have_compiler:$host:$target:$enable_bootstrap" in
1475   *:*:*:no) ;;
1476
1477   # Default behavior.  Enable bootstrap if we have a compiler
1478   # and we are in a native configuration.
1479   yes:$build:$build:default)
1480     enable_bootstrap=yes ;;
1481
1482   *:*:*:default)
1483     enable_bootstrap=no ;;
1484
1485   # We have a compiler and we are in a native configuration, bootstrap is ok
1486   yes:$build:$build:yes)
1487     ;;
1488
1489   # Other configurations, but we have a compiler.  Assume the user knows
1490   # what he's doing.
1491   yes:*:*:yes)
1492     AC_MSG_WARN([trying to bootstrap a cross compiler])
1493     ;;
1494
1495   # No compiler: if they passed --enable-bootstrap explicitly, fail
1496   no:*:*:yes)
1497     AC_MSG_ERROR([cannot bootstrap without a compiler]) ;;
1498
1499   # Fail if wrong command line
1500   *)
1501     AC_MSG_ERROR([invalid option for --enable-bootstrap])
1502     ;;
1503 esac
1504
1505 # When bootstrapping with GCC, build stage 1 in C++11 mode to ensure that a
1506 # C++11 compiler can still start the bootstrap.  Otherwise, if building GCC,
1507 # require C++11 (or higher).
1508 if test "$enable_bootstrap:$GXX" = "yes:yes"; then
1509   CXX="$CXX -std=c++11"
1510 elif test "$have_compiler" = yes; then
1511   AX_CXX_COMPILE_STDCXX(11)
1512
1513   if test "${build}" != "${host}"; then
1514     AX_CXX_COMPILE_STDCXX(11, [], [], [_FOR_BUILD])
1515   fi
1516 fi
1517
1518 AC_ARG_ENABLE([pgo-build],
1519 [AS_HELP_STRING([--enable-pgo-build[[=lto]]],
1520                 [enable the PGO build])],
1521 [enable_pgo_build=$enableval],
1522 [enable_pgo_build=no])
1523
1524 # Issue errors and warnings for invalid/strange PGO build combinations.
1525 case "$have_compiler:$host:$target:$enable_pgo_build" in
1526   *:*:*:no) ;;
1527
1528   # Allow the PGO build only if we aren't building a compiler and
1529   # we are in a native configuration.
1530   no:$build:$build:yes | no:$build:$build:lto) ;;
1531
1532   # Disallow the PGO bootstrap if we are building a compiler.
1533   yes:*:*:yes | yes:*:*:lto)
1534     AC_MSG_ERROR([cannot perform the PGO bootstrap when building a compiler]) ;;
1535
1536   *)
1537     AC_MSG_ERROR([invalid option for --enable-pgo-build])
1538     ;;
1539 esac
1540
1541 if test "$enable_pgo_build" != "no"; then
1542   AC_MSG_CHECKING([whether the compiler supports -fprofile-generate])
1543   old_CFLAGS="$CFLAGS"
1544   PGO_BUILD_GEN_CFLAGS="-fprofile-generate"
1545   CFLAGS="$CFLAGS $PGO_BUILD_CFLAGS"
1546   AC_COMPILE_IFELSE([AC_LANG_SOURCE([int foo;])],,
1547                     [PGO_BUILD_GEN_CFLAGS=])
1548   CFLAGS="$old_CFLAGS"
1549   if test -n "$PGO_BUILD_GEN_CFLAGS"; then
1550     AC_MSG_RESULT([yes])
1551     PGO_BUILD_USE_CFLAGS="-fprofile-use"
1552   else
1553     AC_MSG_RESULT([no])
1554     AC_MSG_ERROR([cannot perform the PGO build without -fprofile-generate])
1555   fi
1556
1557   if test "$enable_pgo_build" = "lto"; then
1558     AC_MSG_CHECKING([whether the compiler supports -flto=jobserver -ffat-lto-objects])
1559     old_CFLAGS="$CFLAGS"
1560     PGO_BUILD_LTO_CFLAGS="-flto=jobserver -ffat-lto-objects"
1561     CFLAGS="$CFLAGS $PGO_BUILD_LTO_CFLAGS"
1562     AC_COMPILE_IFELSE([AC_LANG_SOURCE([int foo;])],,
1563                       [PGO_BUILD_LTO_CFLAGS=])
1564     CFLAGS="$old_CFLAGS"
1565     if test -n "$PGO_BUILD_LTO_CFLAGS"; then
1566       AC_MSG_RESULT([yes])
1567     else
1568       AC_MSG_RESULT([no])
1569       AC_MSG_WARN([LTO is disabled for the PGO build])
1570     fi
1571   fi
1572 fi
1573 AC_SUBST(PGO_BUILD_GEN_CFLAGS)
1574 AC_SUBST(PGO_BUILD_USE_CFLAGS)
1575 AC_SUBST(PGO_BUILD_LTO_CFLAGS)
1576
1577 # Used for setting $lt_cv_objdir
1578 _LT_CHECK_OBJDIR
1579
1580 # Check for GMP, MPFR and MPC
1581 require_gmp=no
1582 require_mpc=no
1583 if test -d ${srcdir}/gcc ; then
1584   require_gmp=yes
1585   require_mpc=yes
1586 fi
1587 if test -d ${srcdir}/gdb ; then
1588   if test "x$enable_gdb" != xno; then
1589    require_gmp=yes
1590   fi
1591 fi
1592
1593 gmplibs="-lmpfr -lgmp"
1594 if test x"$require_mpc" = "xyes" ; then
1595   gmplibs="-lmpc $gmplibs"
1596 fi
1597 gmpinc=
1598 have_gmp=no
1599
1600 # Specify a location for mpc
1601 # check for this first so it ends up on the link line before mpfr.
1602 AC_ARG_WITH(mpc,
1603 [AS_HELP_STRING([--with-mpc=PATH],
1604                 [specify prefix directory for installed MPC package.
1605                  Equivalent to --with-mpc-include=PATH/include
1606                  plus --with-mpc-lib=PATH/lib])])
1607 AC_ARG_WITH(mpc-include,
1608 [AS_HELP_STRING([--with-mpc-include=PATH],
1609                 [specify directory for installed MPC include files])])
1610 AC_ARG_WITH(mpc-lib,
1611 [AS_HELP_STRING([--with-mpc-lib=PATH],
1612                 [specify directory for the installed MPC library])])
1613
1614 if test "x$with_mpc" != x; then
1615   gmplibs="-L$with_mpc/lib $gmplibs"
1616   gmpinc="-I$with_mpc/include $gmpinc"
1617 fi
1618 if test "x$with_mpc_include" != x; then
1619   gmpinc="-I$with_mpc_include $gmpinc"
1620 fi
1621 if test "x$with_mpc_lib" != x; then
1622   gmplibs="-L$with_mpc_lib $gmplibs"
1623 fi
1624 if test "x$with_mpc$with_mpc_include$with_mpc_lib" = x && test -d ${srcdir}/mpc; then
1625   gmplibs='-L$$r/$(HOST_SUBDIR)/mpc/src/'"$lt_cv_objdir $gmplibs"
1626   gmpinc='-I$$s/mpc/src '"$gmpinc"
1627   # Do not test the mpc version.  Assume that it is sufficient, since
1628   # it is in the source tree, and the library has not been built yet
1629   # but it would be included on the link line in the version check below
1630   # hence making the test fail.
1631   have_gmp=yes
1632 fi
1633
1634 # Specify a location for mpfr
1635 # check for this first so it ends up on the link line before gmp.
1636 AC_ARG_WITH(mpfr,
1637 [AS_HELP_STRING([--with-mpfr=PATH],
1638                 [specify prefix directory for installed MPFR package.
1639                  Equivalent to --with-mpfr-include=PATH/include
1640                  plus --with-mpfr-lib=PATH/lib])])
1641 AC_ARG_WITH(mpfr-include,
1642 [AS_HELP_STRING([--with-mpfr-include=PATH],
1643                 [specify directory for installed MPFR include files])])
1644 AC_ARG_WITH(mpfr-lib,
1645 [AS_HELP_STRING([--with-mpfr-lib=PATH],
1646                 [specify directory for the installed MPFR library])])
1647
1648 if test "x$with_mpfr" != x; then
1649   gmplibs="-L$with_mpfr/lib $gmplibs"
1650   gmpinc="-I$with_mpfr/include $gmpinc"
1651 fi
1652 if test "x$with_mpfr_include" != x; then
1653   gmpinc="-I$with_mpfr_include $gmpinc"
1654 fi
1655 if test "x$with_mpfr_lib" != x; then
1656   gmplibs="-L$with_mpfr_lib $gmplibs"
1657 fi
1658 if test "x$with_mpfr$with_mpfr_include$with_mpfr_lib" = x && test -d ${srcdir}/mpfr; then
1659   # MPFR v3.1.0 moved the sources into a src sub-directory.
1660   if ! test -d ${srcdir}/mpfr/src; then
1661     AC_MSG_ERROR([dnl
1662 Building GCC with MPFR in the source tree is only handled for MPFR 3.1.0+.])
1663   fi
1664   gmplibs='-L$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir $gmplibs"
1665   gmpinc='-I$$r/$(HOST_SUBDIR)/mpfr/src -I$$s/mpfr/src '"$gmpinc"
1666   extra_mpc_mpfr_configure_flags='--with-mpfr-include=$$s/mpfr/src --with-mpfr-lib=$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir"
1667   # Do not test the mpfr version.  Assume that it is sufficient, since
1668   # it is in the source tree, and the library has not been built yet
1669   # but it would be included on the link line in the version check below
1670   # hence making the test fail.
1671   have_gmp=yes
1672 fi
1673
1674 # Specify a location for gmp
1675 AC_ARG_WITH(gmp,
1676 [AS_HELP_STRING([--with-gmp=PATH],
1677                 [specify prefix directory for the installed GMP package.
1678                  Equivalent to --with-gmp-include=PATH/include
1679                  plus --with-gmp-lib=PATH/lib])])
1680 AC_ARG_WITH(gmp-include,
1681 [AS_HELP_STRING([--with-gmp-include=PATH],
1682                 [specify directory for installed GMP include files])])
1683 AC_ARG_WITH(gmp-lib,
1684 [AS_HELP_STRING([--with-gmp-lib=PATH],
1685                 [specify directory for the installed GMP library])])
1686
1687
1688 if test "x$with_gmp" != x; then
1689   gmplibs="-L$with_gmp/lib $gmplibs"
1690   gmpinc="-I$with_gmp/include $gmpinc"
1691 fi
1692 if test "x$with_gmp_include" != x; then
1693   gmpinc="-I$with_gmp_include $gmpinc"
1694 fi
1695 if test "x$with_gmp_lib" != x; then
1696   gmplibs="-L$with_gmp_lib $gmplibs"
1697 fi
1698 if test "x$with_gmp$with_gmp_include$with_gmp_lib" = x && test -d ${srcdir}/gmp; then
1699   gmplibs='-L$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir $gmplibs"
1700   gmpinc='-I$$r/$(HOST_SUBDIR)/gmp -I$$s/gmp '"$gmpinc"
1701   extra_mpfr_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1702   extra_mpc_gmp_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1703   extra_isl_gmp_configure_flags='--with-gmp-builddir=$$r/$(HOST_SUBDIR)/gmp'
1704   # Do not test the gmp version.  Assume that it is sufficient, since
1705   # it is in the source tree, and the library has not been built yet
1706   # but it would be included on the link line in the version check below
1707   # hence making the test fail.
1708   have_gmp=yes
1709 fi
1710
1711 if test "x$require_gmp" = xyes && test "x$have_gmp" = xno; then
1712   have_gmp=yes
1713   saved_CFLAGS="$CFLAGS"
1714   CFLAGS="$CFLAGS $gmpinc"
1715   # Check for the recommended and required versions of GMP.
1716   AC_MSG_CHECKING([for the correct version of gmp.h])
1717   AC_TRY_COMPILE([#include "gmp.h"],[
1718   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1719   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1720   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,2,3)
1721   choke me
1722   #endif
1723   ], [AC_TRY_COMPILE([#include <gmp.h>],[
1724   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1725   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1726   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,3,2)
1727   choke me
1728   #endif
1729   ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1730    [AC_MSG_RESULT([no]); have_gmp=no])
1731
1732   # If we have GMP, check the MPFR version.
1733   if test x"$have_gmp" = xyes; then
1734     # Check for the recommended and required versions of MPFR.
1735     AC_MSG_CHECKING([for the correct version of mpfr.h])
1736     AC_TRY_COMPILE([#include <gmp.h>
1737     #include <mpfr.h>],[
1738     #if MPFR_VERSION < MPFR_VERSION_NUM(3,1,0)
1739     choke me
1740     #endif
1741     ], [AC_TRY_COMPILE([#include <gmp.h>
1742     #include <mpfr.h>],[
1743     #if MPFR_VERSION < MPFR_VERSION_NUM(3,1,6)
1744     choke me
1745     #endif
1746     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1747      [AC_MSG_RESULT([no]); have_gmp=no])
1748   fi
1749
1750   # Check for the MPC header version.
1751   if test "x$require_mpc" = xyes && test x"$have_gmp" = xyes ; then
1752     # Check for the recommended and required versions of MPC.
1753     AC_MSG_CHECKING([for the correct version of mpc.h])
1754     AC_TRY_COMPILE([#include <mpc.h>],[
1755     #if MPC_VERSION < MPC_VERSION_NUM(0,8,0)
1756     choke me
1757     #endif
1758     ], [AC_TRY_COMPILE([#include <mpc.h>],[
1759     #if MPC_VERSION < MPC_VERSION_NUM(0,8,1)
1760     choke me
1761     #endif
1762     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1763      [AC_MSG_RESULT([no]); have_gmp=no])
1764   fi
1765
1766   # Now check the MPFR library.
1767   if test x"$have_gmp" = xyes; then
1768     saved_LIBS="$LIBS"
1769     LIBS="$LIBS $gmplibs"
1770     AC_MSG_CHECKING([for the correct version of the gmp/mpfr libraries])
1771     AC_TRY_LINK([#include <mpfr.h>],[
1772     mpfr_t n;
1773     mpfr_t x;
1774     int t;
1775     mpfr_init (n);
1776     mpfr_init (x);
1777     mpfr_atan2 (n, n, x, MPFR_RNDN);
1778     mpfr_erfc (n, x, MPFR_RNDN);
1779     mpfr_subnormalize (x, t, MPFR_RNDN);
1780     mpfr_clear(n);
1781     mpfr_clear(x);
1782     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1783     LIBS="$saved_LIBS"
1784   fi
1785
1786   # Now check the MPC library
1787   if test "x$require_mpc" = xyes && test x"$have_gmp" = xyes; then
1788     saved_LIBS="$LIBS"
1789     LIBS="$LIBS $gmplibs"
1790     AC_MSG_CHECKING([for the correct version of the mpc libraries])
1791     AC_TRY_LINK([#include <mpc.h>],[
1792     mpc_t c;
1793     mpc_init2 (c, 53);
1794     mpc_set_ui_ui (c, 1, 1, MPC_RNDNN);
1795     mpc_cosh (c, c, MPC_RNDNN);
1796     mpc_pow (c, c, c, MPC_RNDNN);
1797     mpc_acosh (c, c, MPC_RNDNN);
1798     mpc_clear (c);
1799     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1800     LIBS="$saved_LIBS"
1801   fi
1802
1803   CFLAGS="$saved_CFLAGS"
1804
1805 # The library versions listed in the error message below should match
1806 # the HARD-minimums enforced above.
1807   if test x$have_gmp != xyes; then
1808     if test -d ${srcdir}/gcc ; then
1809       AC_MSG_ERROR([Building GCC requires GMP 4.2+, MPFR 3.1.0+ and MPC 0.8.0+.
1810 Try the --with-gmp, --with-mpfr and/or --with-mpc options to specify
1811 their locations.  Source code for these libraries can be found at
1812 their respective hosting sites as well as at
1813 https://gcc.gnu.org/pub/gcc/infrastructure/.  See also
1814 http://gcc.gnu.org/install/prerequisites.html for additional info.  If
1815 you obtained GMP, MPFR and/or MPC from a vendor distribution package,
1816 make sure that you have installed both the libraries and the header
1817 files.  They may be located in separate packages.])
1818     else
1819       AC_MSG_ERROR([Building GDB requires GMP 4.2+, and MPFR 3.1.0+.
1820 Try the --with-gmp and/or --with-mpfr options to specify
1821 their locations.  If you obtained GMP and/or MPFR from a vendor
1822 distribution package, make sure that you have installed both the libraries
1823 and the header files.  They may be located in separate packages.])
1824     fi
1825   fi
1826 fi
1827
1828 # Flags needed for both GMP, MPFR and/or MPC.
1829 AC_SUBST(gmplibs)
1830 AC_SUBST(gmpinc)
1831 AC_SUBST(extra_mpfr_configure_flags)
1832 AC_SUBST(extra_mpc_gmp_configure_flags)
1833 AC_SUBST(extra_mpc_mpfr_configure_flags)
1834 AC_SUBST(extra_isl_gmp_configure_flags)
1835
1836 # Libraries to use for stage1 or when not bootstrapping.
1837 AC_ARG_WITH(stage1-libs,
1838 [AS_HELP_STRING([--with-stage1-libs=LIBS], [libraries for stage1])],
1839 [if test "$withval" = "no" -o "$withval" = "yes"; then
1840    stage1_libs=
1841  else
1842    stage1_libs=$withval
1843  fi],
1844 [stage1_libs=])
1845 AC_SUBST(stage1_libs)
1846
1847 # Whether or not to use -static-libstdc++ and -static-libgcc.  The
1848 # default is yes if gcc is being built; no otherwise.  The reason for
1849 # this default is that gdb is sometimes linked against GNU Source
1850 # Highlight, which is a shared library that uses C++ exceptions.  In
1851 # this case, -static-libstdc++ will cause crashes.
1852 AC_ARG_WITH(static-standard-libraries,
1853 [AS_HELP_STRING([--with-static-standard-libraries],
1854                 [use -static-libstdc++ and -static-libgcc (default=auto)])],
1855 [], [with_static_standard_libraries=auto])
1856 if test "$with_static_standard_libraries" = auto; then
1857   with_static_standard_libraries=$have_compiler
1858 fi
1859
1860 # Linker flags to use for stage1 or when not bootstrapping.
1861 AC_ARG_WITH(stage1-ldflags,
1862 [AS_HELP_STRING([--with-stage1-ldflags=FLAGS], [linker flags for stage1])],
1863 [if test "$withval" = "no" -o "$withval" = "yes"; then
1864    stage1_ldflags=
1865  else
1866    stage1_ldflags=$withval
1867  fi],
1868 [stage1_ldflags=
1869  # In stage 1, default to linking libstdc++ and libgcc statically with GCC
1870  # if supported.  But if the user explicitly specified the libraries to use,
1871  # trust that they are doing what they want.
1872  if test "$with_static_standard_libraries" = yes -a "$stage1_libs" = "" \
1873      -a "$have_static_libs" = yes; then
1874    stage1_ldflags="-static-libstdc++ -static-libgcc"
1875  fi])
1876 AC_SUBST(stage1_ldflags)
1877
1878 # Libraries to use for stage2 and later builds.
1879 AC_ARG_WITH(boot-libs,
1880 [AS_HELP_STRING([--with-boot-libs=LIBS], [libraries for stage2 and later])],
1881 [if test "$withval" = "no" -o "$withval" = "yes"; then
1882    poststage1_libs=
1883  else
1884    poststage1_libs=$withval
1885  fi],
1886 [poststage1_libs=])
1887 AC_SUBST(poststage1_libs)
1888
1889 # Linker flags to use for stage2 and later builds.
1890 AC_ARG_WITH(boot-ldflags,
1891 [AS_HELP_STRING([--with-boot-ldflags=FLAGS],
1892                 [linker flags for stage2 and later])],
1893 [if test "$withval" = "no" -o "$withval" = "yes"; then
1894    poststage1_ldflags=
1895  else
1896    poststage1_ldflags=$withval
1897  fi],
1898 [poststage1_ldflags=
1899  # In stages 2 and 3, default to linking libstdc++ and libgcc
1900  # statically.  But if the user explicitly specified the libraries to
1901  # use, trust that they are doing what they want.
1902  if test "$poststage1_libs" = ""; then
1903    poststage1_ldflags="-static-libstdc++ -static-libgcc"
1904  fi])
1905 AC_SUBST(poststage1_ldflags)
1906
1907 # GCC GRAPHITE dependency isl.
1908 # Basic setup is inlined here, actual checks are in config/isl.m4
1909
1910 AC_ARG_WITH(isl,
1911   [AS_HELP_STRING(
1912    [--with-isl=PATH],
1913    [Specify prefix directory for the installed isl package.
1914     Equivalent to --with-isl-include=PATH/include
1915     plus --with-isl-lib=PATH/lib])])
1916
1917 # Treat --without-isl as a request to disable
1918 # GRAPHITE support and skip all following checks.
1919 if test "x$with_isl" != "xno"; then
1920   # Check for isl
1921   dnl Provide configure switches and initialize islinc & isllibs
1922   dnl with user input.
1923   ISL_INIT_FLAGS
1924   dnl The versions of isl that work for Graphite
1925   ISL_CHECK_VERSION()
1926   dnl Only execute fail-action, if isl has been requested.
1927   ISL_IF_FAILED([
1928     AC_MSG_ERROR([Unable to find a usable isl.  See config.log for details.])])
1929 fi
1930
1931 # If the isl check failed, disable builds of in-tree variant of isl
1932 if test "x$with_isl" = xno ||
1933    test "x$gcc_cv_isl" = xno; then
1934   noconfigdirs="$noconfigdirs isl"
1935   islinc=
1936 fi
1937
1938 AC_SUBST(isllibs)
1939 AC_SUBST(islinc)
1940
1941 # Check for LTO support.
1942 AC_ARG_ENABLE(lto,
1943 [AS_HELP_STRING([--enable-lto], [enable link time optimization support])],
1944 enable_lto=$enableval,
1945 enable_lto=yes; default_enable_lto=yes)
1946
1947 ACX_ELF_TARGET_IFELSE([# ELF platforms build the lto-plugin always.
1948   build_lto_plugin=yes
1949 ],[if test x"$default_enable_lto" = x"yes" ; then
1950     case $target in
1951       *-apple-darwin[[912]]* | *-cygwin* | *-mingw* | *djgpp*) ;;
1952       # On other non-ELF platforms, LTO has yet to be validated.
1953       *) enable_lto=no ;;
1954     esac
1955   else
1956   # Apart from ELF platforms, only Windows and Darwin support LTO so far.
1957   # It would also be nice to check the binutils support, but we don't
1958   # have gcc_GAS_CHECK_FEATURE available here.  For now, we'll just
1959   # warn during gcc/ subconfigure; unless you're bootstrapping with
1960   # -flto it won't be needed until after installation anyway.
1961     case $target in
1962       *-cygwin* | *-mingw* | *-apple-darwin* | *djgpp*) ;;
1963       *) if test x"$enable_lto" = x"yes"; then
1964         AC_MSG_ERROR([LTO support is not enabled for this target.])
1965         fi
1966       ;;
1967     esac
1968   fi
1969   # Among non-ELF, only Windows platforms support the lto-plugin so far.
1970   # Build it unless LTO was explicitly disabled.
1971   case $target in
1972     *-cygwin* | *-mingw*) build_lto_plugin=$enable_lto ;;
1973     *) ;;
1974   esac
1975 ])
1976
1977 AC_ARG_ENABLE(linker-plugin-configure-flags,
1978   [AS_HELP_STRING([[--enable-linker-plugin-configure-flags=FLAGS]],
1979     [additional flags for configuring linker plugins @<:@none@:>@])],
1980   extra_linker_plugin_configure_flags=$enableval,
1981   extra_linker_plugin_configure_flags=)
1982 AC_SUBST(extra_linker_plugin_configure_flags)
1983 AC_ARG_ENABLE(linker-plugin-flags,
1984   [AS_HELP_STRING([[--enable-linker-plugin-flags=FLAGS]],
1985     [additional flags for configuring and building linker plugins @<:@none@:>@])],
1986   extra_linker_plugin_flags=$enableval,
1987   extra_linker_plugin_flags=)
1988 AC_SUBST(extra_linker_plugin_flags)
1989
1990 # Enable --enable-host-pie.
1991 # Checked early to determine whether jit is an 'all' language
1992 AC_ARG_ENABLE(host-pie,
1993 [AS_HELP_STRING([--enable-host-pie],
1994                 [build position independent host executables])],
1995 [host_pie=$enableval
1996  case $host in
1997    x86_64-*-darwin* | aarch64-*-darwin*)
1998      if test x$host_pie != xyes ; then
1999        # PIC is the default, and actually cannot be switched off.
2000        echo configure.ac: warning: PIC code is required for the configured target, host-shared setting ignored. 1>&2
2001        host_pie=yes
2002      fi ;;
2003   *) ;;
2004  esac],
2005 [case $host in
2006   *-*-darwin2*) host_pie=yes ;;
2007   *) host_pie=no ;;
2008  esac])
2009
2010 AC_SUBST(host_pie)
2011
2012 # Enable --enable-host-shared.
2013 # Checked early to determine whether jit is an 'all' language
2014 AC_ARG_ENABLE(host-shared,
2015 [AS_HELP_STRING([--enable-host-shared],
2016                 [build host code as shared libraries])],
2017 [host_shared=$enableval
2018  case $host in
2019    x86_64-*-darwin* | aarch64-*-darwin*)
2020      if test x$host_shared != xyes ; then
2021        # PIC is the default, and actually cannot be switched off.
2022        echo configure.ac: warning: PIC code is required for the configured target, host-shared setting ignored. 1>&2
2023        host_shared=yes
2024      fi ;;
2025    *-*-darwin*)
2026      if test x$host_pie == xyes ; then
2027        echo configure.ac: warning: PIC code is required for PIE executables. 1>&2
2028        host_shared=yes
2029      fi ;;
2030   *) ;;
2031  esac],
2032 [case $host in
2033   x86_64-*-darwin* | aarch64-*-darwin*) host_shared=yes ;;
2034   # Darwin needs PIC objects to link PIE executables.
2035   *-*-darwin*) host_shared=host_pie ;;
2036   *) host_shared=no;;
2037  esac])
2038
2039 AC_SUBST(host_shared)
2040
2041 if test x$host_shared = xyes; then
2042   PICFLAG=-fPIC
2043 elif test x$host_pie = xyes; then
2044   PICFLAG=-fPIE
2045 else
2046   PICFLAG=
2047 fi
2048
2049 AC_SUBST(PICFLAG)
2050
2051 # If we are building PIC/PIE host executables, and we are building dependent
2052 # libs (e.g. GMP) in-tree those libs need to be configured to generate PIC
2053 # code.
2054 host_libs_picflag=
2055 if test "$host_shared" = "yes" -o "$host_pie" = "yes"; then
2056 host_libs_picflag='--with-pic'
2057 fi
2058 AC_SUBST(host_libs_picflag)
2059
2060 # By default, C and C++ are the only stage 1 languages.
2061 stage1_languages=,c,
2062
2063 # Target libraries that we bootstrap.
2064 bootstrap_target_libs=,target-libgcc,
2065
2066 # Figure out what language subdirectories are present.
2067 # Look if the user specified --enable-languages="..."; if not, use
2068 # the environment variable $LANGUAGES if defined. $LANGUAGES might
2069 # go away some day.
2070 # NB:  embedded tabs in this IF block -- do not untabify
2071 if test -d ${srcdir}/gcc; then
2072   if test x"${enable_languages+set}" != xset; then
2073     if test x"${LANGUAGES+set}" = xset; then
2074       enable_languages="${LANGUAGES}"
2075         echo configure.ac: warning: setting LANGUAGES is deprecated, use --enable-languages instead 1>&2
2076     else
2077       enable_languages=default
2078     fi
2079   else
2080     if test x"${enable_languages}" = x ||
2081        test x"${enable_languages}" = xyes;
2082        then
2083       echo configure.ac: --enable-languages needs at least one language argument 1>&2
2084       exit 1
2085     fi
2086   fi
2087   enable_languages=`echo "${enable_languages}" | sed -e 's/[[   ,]][[   ,]]*/,/g' -e 's/,$//'`
2088
2089   # 'f95' is the old name for the 'fortran' language. We issue a warning
2090   # and make the substitution.
2091   case ,${enable_languages}, in
2092     *,f95,*)
2093       echo configure.ac: warning: 'f95' as language name is deprecated, use 'fortran' instead 1>&2
2094       enable_languages=`echo "${enable_languages}" | sed -e 's/f95/fortran/g'`
2095       ;;
2096   esac
2097
2098   # If bootstrapping, C++ must be enabled.
2099   case ",$enable_languages,:$enable_bootstrap" in
2100     *,c++,*:*) ;;
2101     *:yes)
2102       if test -f ${srcdir}/gcc/cp/config-lang.in; then
2103         enable_languages="${enable_languages},c++"
2104       else
2105         AC_MSG_ERROR([bootstrapping requires c++ sources])
2106       fi
2107       ;;
2108   esac
2109
2110   # First scan to see if an enabled language requires some other language.
2111   # We assume that a given config-lang.in will list all the language
2112   # front ends it requires, even if some are required indirectly.
2113   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
2114     case ${lang_frag} in
2115       ..) ;;
2116       # The odd quoting in the next line works around
2117       # an apparent bug in bash 1.12 on linux.
2118       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
2119       *)
2120         # From the config-lang.in, get $language, $lang_requires, and
2121         # $lang_requires_boot_languages.
2122         language=
2123         lang_requires=
2124         lang_requires_boot_languages=
2125         # set srcdir during sourcing lang_frag to the gcc dir.
2126         # Sadly overriding srcdir on the . line doesn't work in plain sh as it
2127         # polutes this shell
2128         saved_srcdir=${srcdir}
2129         srcdir=${srcdir}/gcc . ${lang_frag}
2130         srcdir=${saved_srcdir}
2131         for other in ${lang_requires} ${lang_requires_boot_languages}; do
2132           case ,${enable_languages}, in
2133             *,$other,*) ;;
2134             *,default,*) ;;
2135             *,all,*) ;;
2136             *,$language,*)
2137               echo " \`$other' language required by \`$language'; enabling" 1>&2
2138               enable_languages="${enable_languages},${other}"
2139               ;;
2140           esac
2141         done
2142         for other in ${lang_requires_boot_languages} ; do
2143           if test "$other" != "c"; then
2144             case ,${enable_stage1_languages}, in
2145               *,$other,*) ;;
2146               *,default,*) ;;
2147               *,all,*) ;;
2148               *)
2149                 case ,${enable_languages}, in
2150                   *,$language,*)
2151                     echo " '$other' language required by '$language' in stage 1; enabling" 1>&2
2152                     enable_stage1_languages="$enable_stage1_languages,${other}"
2153                     ;;
2154                 esac
2155                 ;;
2156             esac
2157           fi
2158         done
2159         ;;
2160     esac
2161   done
2162
2163   new_enable_languages=,c,
2164
2165   # If LTO is enabled, add the LTO front end.
2166   if test "$enable_lto" = "yes" ; then
2167     case ,${enable_languages}, in
2168       *,lto,*) ;;
2169       *) enable_languages="${enable_languages},lto" ;;
2170     esac
2171     if test "${build_lto_plugin}" = "yes" ; then
2172       configdirs="$configdirs lto-plugin"
2173     fi
2174   fi
2175
2176   # If we're building an offloading compiler, add the LTO front end.
2177   if test x"$enable_as_accelerator_for" != x ; then
2178     case ,${enable_languages}, in
2179       *,lto,*) ;;
2180       *) enable_languages="${enable_languages},lto" ;;
2181     esac
2182   fi
2183
2184   missing_languages=`echo ",$enable_languages," | sed -e s/,default,/,/ -e s/,all,/,/ -e s/,c,/,/ `
2185   potential_languages=,c,
2186
2187   enabled_target_libs=
2188   disabled_target_libs=
2189
2190   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
2191     case ${lang_frag} in
2192       ..) ;;
2193       # The odd quoting in the next line works around
2194       # an apparent bug in bash 1.12 on linux.
2195       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
2196       *)
2197         # From the config-lang.in, get $language, $target_libs,
2198         # $lang_dirs, $boot_language, and $build_by_default
2199         language=
2200         target_libs=
2201         lang_dirs=
2202         subdir_requires=
2203         boot_language=no
2204         build_by_default=yes
2205         # set srcdir during sourcing.  See above about save & restore
2206         saved_srcdir=${srcdir}
2207         srcdir=${srcdir}/gcc . ${lang_frag}
2208         srcdir=${saved_srcdir}
2209         if test x${language} = x; then
2210           echo "${lang_frag} doesn't set \$language." 1>&2
2211           exit 1
2212         fi
2213
2214         if test "$language" = "c++"; then
2215           boot_language=yes
2216         fi
2217
2218         add_this_lang=no
2219         # C is always enabled, so no need to add it again
2220         if test "$language" != "c"; then
2221           case ,${enable_languages}, in
2222             *,${language},*)
2223               # Language was explicitly selected; include it
2224               add_this_lang=yes
2225               ;;
2226             *,all,*)
2227               # All languages are enabled
2228               add_this_lang=all
2229               ;;
2230             *,default,*)
2231               # 'default' was selected, select it if it is a default language
2232               add_this_lang=${build_by_default}
2233               ;;
2234           esac
2235         fi
2236
2237         # Disable languages that need other directories if these aren't available.
2238         for i in $subdir_requires; do
2239           test -f "$srcdir/gcc/$i/config-lang.in" && continue
2240           case ${add_this_lang} in
2241             yes)
2242               # Specifically requested language; tell them.
2243               AC_MSG_ERROR([The gcc/$i directory contains parts of $language but is missing])
2244               ;;
2245             all)
2246               AC_MSG_WARN([The gcc/$i directory contains parts of $language but is missing])
2247               add_this_lang=unsupported
2248               ;;
2249             *)
2250               # Silently disable.
2251               add_this_lang=unsupported
2252               ;;
2253           esac
2254         done
2255
2256         # Disable Ada if no preexisting GNAT is available.
2257         case ${add_this_lang}:${language}:${have_gnat} in
2258           yes:ada:no)
2259             # Specifically requested language; tell them.
2260             AC_MSG_ERROR([GNAT is required to build $language])
2261             ;;
2262           all:ada:no)
2263             AC_MSG_WARN([GNAT is required to build $language])
2264             add_this_lang=unsupported
2265             ;;
2266           *:ada:no)
2267             # Silently disable.
2268             add_this_lang=unsupported
2269             ;;
2270         esac
2271
2272         # Disable D if no preexisting GDC is available.
2273         case ${add_this_lang}:${language}:${have_gdc} in
2274           yes:d:no)
2275             # Specifically requested language; tell them.
2276             AC_MSG_ERROR([GDC is required to build $language])
2277            ;;
2278           all:d:no)
2279             AC_MSG_WARN([GDC is required to build $language])
2280             add_this_lang=unsupported
2281             ;;
2282           *:d:no)
2283             # Silently disable.
2284             add_this_lang=unsupported
2285             ;;
2286         esac
2287
2288         # Disable jit if -enable-host-shared not specified
2289         # but not if building for Mingw. All code in Windows
2290         # is position independent code (PIC).
2291         case $target in
2292           *mingw*) ;;
2293           *)
2294           case ${add_this_lang}:${language}:${host_shared} in
2295             yes:jit:no)
2296                    # PR jit/64780: explicitly specify --enable-host-shared
2297             AC_MSG_ERROR([
2298 Enabling language "jit" requires --enable-host-shared.
2299
2300 --enable-host-shared typically slows the rest of the compiler down by
2301 a few %, so you must explicitly enable it.
2302
2303 If you want to build both the jit and the regular compiler, it is often
2304 best to do this via two separate configure/builds, in separate
2305 directories, to avoid imposing the performance cost of
2306 --enable-host-shared on the regular compiler.])
2307                     ;;
2308             all:jit:no)
2309               AC_MSG_WARN([--enable-host-shared required to build $language])
2310               add_this_lang=unsupported
2311               ;;
2312             *:jit:no)
2313               # Silently disable.
2314               add_this_lang=unsupported
2315               ;;
2316                 esac
2317           ;;
2318         esac
2319
2320         # Disable a language that is unsupported by the target.
2321         case "${add_this_lang}: $unsupported_languages " in
2322           no:*) ;;
2323           unsupported:*) ;;
2324           *:*" $language "*)
2325             AC_MSG_WARN([${language} not supported for this target])
2326             add_this_lang=unsupported
2327             ;;
2328         esac
2329
2330         case $add_this_lang in
2331           unsupported)
2332             # Remove language-dependent dirs.
2333             disabled_target_libs="$disabled_target_libs $target_libs"
2334             noconfigdirs="$noconfigdirs $lang_dirs"
2335             ;;
2336           no)
2337             # Remove language-dependent dirs; still show language as supported.
2338             disabled_target_libs="$disabled_target_libs $target_libs"
2339             noconfigdirs="$noconfigdirs $lang_dirs"
2340             potential_languages="${potential_languages}${language},"
2341             ;;
2342           all|yes)
2343             new_enable_languages="${new_enable_languages}${language},"
2344             potential_languages="${potential_languages}${language},"
2345             missing_languages=`echo "$missing_languages" | sed "s/,$language,/,/"`
2346             enabled_target_libs="$enabled_target_libs $target_libs"
2347             case "${boot_language}:,$enable_stage1_languages," in
2348               yes:* | *:*,$language,* | *:*,yes, | *:*,all,)
2349                 # Add to (comma-separated) list of stage 1 languages.
2350                 case ",$stage1_languages," in
2351                   *,$language,* | ,yes, | ,all,) ;;
2352                   *) stage1_languages="${stage1_languages}${language}," ;;
2353                 esac
2354                 # We need to bootstrap any supporting libraries.
2355                 bootstrap_target_libs=`echo "${bootstrap_target_libs}${target_libs}," | sed "s/ /,/g"`
2356                 ;;
2357             esac
2358             ;;
2359         esac
2360         ;;
2361     esac
2362   done
2363
2364   # Add target libraries which are only needed for disabled languages
2365   # to noconfigdirs.
2366   if test -n "$disabled_target_libs"; then
2367     for dir in $disabled_target_libs; do
2368       case " $enabled_target_libs " in
2369       *" ${dir} "*) ;;
2370       *) noconfigdirs="$noconfigdirs $dir" ;;
2371       esac
2372     done
2373   fi
2374
2375   AC_ARG_ENABLE(stage1-languages,
2376   [AS_HELP_STRING([[--enable-stage1-languages[=all]]],
2377                   [choose additional languages to build during
2378                   stage1.  Mostly useful for compiler development])],
2379   [case ,${enable_stage1_languages}, in
2380     ,no,|,,)
2381       # Set it to something that will have no effect in the loop below
2382       enable_stage1_languages=c ;;
2383     ,yes,)
2384       enable_stage1_languages=`echo $new_enable_languages | \
2385         sed -e "s/^,//" -e "s/,$//" ` ;;
2386     *,all,*)
2387       enable_stage1_languages=`echo ,$enable_stage1_languages, | \
2388         sed -e "s/,all,/$new_enable_languages/" -e "s/^,//" -e "s/,$//" ` ;;
2389   esac
2390
2391   # Add "good" languages from enable_stage1_languages to stage1_languages,
2392   # while "bad" languages go in missing_languages.  Leave no duplicates.
2393   for i in `echo $enable_stage1_languages | sed 's/,/ /g' `; do
2394     case $potential_languages in
2395       *,$i,*)
2396         case $stage1_languages in
2397           *,$i,*) ;;
2398           *) stage1_languages="$stage1_languages$i," ;;
2399         esac ;;
2400       *)
2401         case $missing_languages in
2402           *,$i,*) ;;
2403           *) missing_languages="$missing_languages$i," ;;
2404         esac ;;
2405      esac
2406   done])
2407
2408   # Remove leading/trailing commas that were added for simplicity
2409   potential_languages=`echo "$potential_languages" | sed -e "s/^,//" -e "s/,$//"`
2410   missing_languages=`echo "$missing_languages" | sed -e "s/^,//" -e "s/,$//"`
2411   stage1_languages=`echo "$stage1_languages" | sed -e "s/^,//" -e "s/,$//"`
2412   new_enable_languages=`echo "$new_enable_languages" | sed -e "s/^,//" -e "s/,$//"`
2413
2414   if test "x$missing_languages" != x; then
2415     AC_MSG_ERROR([
2416 The following requested languages could not be built: ${missing_languages}
2417 Supported languages are: ${potential_languages}])
2418   fi
2419   if test "x$new_enable_languages" != "x$enable_languages"; then
2420     echo The following languages will be built: ${new_enable_languages}
2421     enable_languages="$new_enable_languages"
2422   fi
2423
2424   AC_SUBST(stage1_languages)
2425   ac_configure_args=`echo " $ac_configure_args" | sed -e "s/ '--enable-languages=[[^ ]]*'//g" -e "s/$/ '--enable-languages="$enable_languages"'/" `
2426 fi
2427
2428 # Handle --disable-<component> generically.
2429 for dir in $configdirs $build_configdirs $target_configdirs ; do
2430   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g -e s/-/_/g`
2431   varname=`echo $dirname | sed -e s/+/_/g`
2432   if eval test x\${enable_${varname}} "=" xno ; then
2433     noconfigdirs="$noconfigdirs $dir"
2434   fi
2435 done
2436
2437 # Check for Boehm's garbage collector
2438 AC_ARG_ENABLE(objc-gc,
2439 [AS_HELP_STRING([--enable-objc-gc],
2440                 [enable use of Boehm's garbage collector with the
2441                  GNU Objective-C runtime])])
2442 AC_ARG_WITH([target-bdw-gc],
2443 [AS_HELP_STRING([--with-target-bdw-gc=PATHLIST],
2444                 [specify prefix directory for installed bdw-gc package.
2445                  Equivalent to --with-target-bdw-gc-include=PATH/include
2446                  plus --with-target-bdw-gc-lib=PATH/lib])])
2447 AC_ARG_WITH([target-bdw-gc-include],
2448 [AS_HELP_STRING([--with-target-bdw-gc-include=PATHLIST],
2449                 [specify directories for installed bdw-gc include files])])
2450 AC_ARG_WITH([target-bdw-gc-lib],
2451 [AS_HELP_STRING([--with-target-bdw-gc-lib=PATHLIST],
2452                 [specify directories for installed bdw-gc library])])
2453
2454 case ,${enable_languages},:${enable_objc_gc} in *,objc,*:yes|*,objc,*:auto)
2455   AC_MSG_CHECKING([for bdw garbage collector])
2456   if test "x$with_target_bdw_gc$with_target_bdw_gc_include$with_target_bdw_gc_lib" = x; then
2457     dnl no bdw-gw options, assume default locations
2458     AC_MSG_RESULT([using bdw-gc in default locations])
2459   else
2460     dnl bdw-gw options, first error checking, complete checking in libobjc
2461     if test "x$with_target_bdw_gc_include" = x && test "x$with_target_bdw_gc_lib" != x; then
2462       AC_MSG_ERROR([found --with-target-bdw-gc-lib but --with-target-bdw-gc-include missing])
2463     elif test "x$with_target_bdw_gc_include" != x && test "x$with_target_bdw_gc_lib" = x; then
2464       AC_MSG_ERROR([found --with-target-bdw-gc-include but --with-target-bdw-gc-lib missing])
2465     else
2466       AC_MSG_RESULT([using paths configured with --with-target-bdw-gc options])
2467     fi
2468   fi
2469 esac
2470
2471 # Disable libitm, libsanitizer, libvtv, liboffloadmic if we're not building C++
2472 case ,${enable_languages}, in
2473   *,c++,*)
2474     # Disable libitm, libsanitizer if we're not building libstdc++
2475     case "${noconfigdirs}" in
2476       *target-libstdc++-v3*)
2477         noconfigdirs="$noconfigdirs target-libitm target-libsanitizer"
2478         ;;
2479       *) ;;
2480     esac
2481     ;;
2482   *)
2483     noconfigdirs="$noconfigdirs target-liboffloadmic target-libitm target-libsanitizer target-libvtv"
2484     ;;
2485 esac
2486
2487 # If gcc/ is not in the source tree then we'll not be building a
2488 # target compiler, assume in that case we don't want to build any
2489 # target libraries or tools.
2490 #
2491 # This was added primarily for the benefit for binutils-gdb who reuse
2492 # this configure script, but don't always have target tools available.
2493 if test ! -d ${srcdir}/gcc; then
2494    skipdirs="${skipdirs} ${target_configdirs}"
2495 fi
2496
2497 # Remove the entries in $skipdirs and $noconfigdirs from $configdirs,
2498 # $build_configdirs and $target_configdirs.
2499 # If we have the source for $noconfigdirs entries, add them to $notsupp.
2500
2501 notsupp=""
2502 for dir in . $skipdirs $noconfigdirs ; do
2503   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g`
2504   if test $dir != .  && echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2505     configdirs=`echo " ${configdirs} " | sed -e "s/ ${dir} / /"`
2506     if test -r $srcdir/$dirname/configure ; then
2507       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2508         true
2509       else
2510         notsupp="$notsupp $dir"
2511       fi
2512     fi
2513   fi
2514   if test $dir != .  && echo " ${build_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2515     build_configdirs=`echo " ${build_configdirs} " | sed -e "s/ ${dir} / /"`
2516     if test -r $srcdir/$dirname/configure ; then
2517       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2518         true
2519       else
2520         notsupp="$notsupp $dir"
2521       fi
2522     fi
2523   fi
2524   if test $dir != . && echo " ${target_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2525     target_configdirs=`echo " ${target_configdirs} " | sed -e "s/ ${dir} / /"`
2526     if test -r $srcdir/$dirname/configure ; then
2527       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2528         true
2529       else
2530         notsupp="$notsupp $dir"
2531       fi
2532     fi
2533   fi
2534 done
2535
2536 # Quietly strip out all directories which aren't configurable in this tree.
2537 # This relies on all configurable subdirectories being autoconfiscated, which
2538 # is now the case.
2539 build_configdirs_all="$build_configdirs"
2540 build_configdirs=
2541 for i in ${build_configdirs_all} ; do
2542   j=`echo $i | sed -e s/build-//g`
2543   if test -f ${srcdir}/$j/configure ; then
2544     build_configdirs="${build_configdirs} $i"
2545   fi
2546 done
2547
2548 configdirs_all="$configdirs"
2549 configdirs=
2550 for i in ${configdirs_all} ; do
2551   if test -f ${srcdir}/$i/configure ; then
2552     configdirs="${configdirs} $i"
2553   fi
2554 done
2555
2556 target_configdirs_all="$target_configdirs"
2557 target_configdirs=
2558 for i in ${target_configdirs_all} ; do
2559   j=`echo $i | sed -e s/target-//g`
2560   if test -f ${srcdir}/$j/configure ; then
2561     target_configdirs="${target_configdirs} $i"
2562   fi
2563 done
2564
2565 # libiberty-linker-plugin is special: it doesn't have its own source directory,
2566 # so we have to add it after the preceding checks.
2567 if test x"$extra_linker_plugin_flags$extra_linker_plugin_configure_flags" != x
2568 then
2569   case " $configdirs " in
2570     *" libiberty "*)
2571       # If we can build libiberty, we can also build libiberty-linker-plugin.
2572       configdirs="$configdirs libiberty-linker-plugin"
2573       extra_linker_plugin_configure_flags="$extra_linker_plugin_configure_flags \
2574         --with-libiberty=../libiberty-linker-plugin";;
2575     *)
2576       AC_MSG_ERROR([libiberty missing]);;
2577   esac
2578 fi
2579
2580 # Sometimes we have special requirements for the host libiberty.
2581 extra_host_libiberty_configure_flags=
2582 case " $configdirs " in
2583   *" lto-plugin "* | *" libcc1 "* | *" gdbserver "*)
2584     # When these are to be built as shared libraries, the same applies to
2585     # libiberty.
2586     extra_host_libiberty_configure_flags=--enable-shared
2587     ;;
2588 esac
2589 AC_SUBST(extra_host_libiberty_configure_flags)
2590
2591 # Sometimes we have special requirements for the host zlib.
2592 extra_host_zlib_configure_flags=
2593 case " $configdirs " in
2594   *" bfd "*)
2595     # When bfd is to be built as a shared library, the same applies to
2596     # zlib.
2597     if test "$enable_shared" = "yes"; then
2598       extra_host_zlib_configure_flags=--enable-host-shared
2599     fi
2600     ;;
2601 esac
2602 AC_SUBST(extra_host_zlib_configure_flags)
2603
2604 # Produce a warning message for the subdirs we can't configure.
2605 # This isn't especially interesting in the Cygnus tree, but in the individual
2606 # FSF releases, it's important to let people know when their machine isn't
2607 # supported by the one or two programs in a package.
2608
2609 if test -n "${notsupp}" && test -z "${norecursion}" ; then
2610   # If $appdirs is non-empty, at least one of those directories must still
2611   # be configured, or we error out.  (E.g., if the gas release supports a
2612   # specified target in some subdirs but not the gas subdir, we shouldn't
2613   # pretend that all is well.)
2614   if test -n "$appdirs" ; then
2615     for dir in $appdirs ; do
2616       if test -r $dir/Makefile.in ; then
2617         if echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2618           appdirs=""
2619           break
2620         fi
2621         if echo " ${target_configdirs} " | grep " target-${dir} " >/dev/null 2>&1; then
2622           appdirs=""
2623           break
2624         fi
2625       fi
2626     done
2627     if test -n "$appdirs" ; then
2628       echo "*** This configuration is not supported by this package." 1>&2
2629       exit 1
2630     fi
2631   fi
2632   # Okay, some application will build, or we don't care to check.  Still
2633   # notify of subdirs not getting built.
2634   echo "*** This configuration is not supported in the following subdirectories:" 1>&2
2635   echo "    ${notsupp}" 1>&2
2636   echo "    (Any other directories should still work fine.)" 1>&2
2637 fi
2638
2639 case "$host" in
2640   *msdosdjgpp*)
2641     enable_gdbtk=no ;;
2642 esac
2643
2644 # To find our prefix, in gcc_cv_tool_prefix.
2645 ACX_TOOL_DIRS
2646
2647 copy_dirs=
2648
2649 AC_ARG_WITH([build-sysroot],
2650   [AS_HELP_STRING([--with-build-sysroot=SYSROOT],
2651                   [use sysroot as the system root during the build])],
2652   [if test x"$withval" != x ; then
2653      SYSROOT_CFLAGS_FOR_TARGET="--sysroot=$withval"
2654    fi],
2655   [SYSROOT_CFLAGS_FOR_TARGET=])
2656 AC_SUBST(SYSROOT_CFLAGS_FOR_TARGET)
2657
2658 AC_ARG_WITH([debug-prefix-map],
2659   [AS_HELP_STRING([--with-debug-prefix-map='A=B C=D ...'],
2660                   [map A to B, C to D ... in debug information])],
2661   [if test x"$withval" != x; then
2662      DEBUG_PREFIX_CFLAGS_FOR_TARGET=
2663      for debug_map in $withval; do
2664        DEBUG_PREFIX_CFLAGS_FOR_TARGET="$DEBUG_PREFIX_CFLAGS_FOR_TARGET -fdebug-prefix-map=$debug_map"
2665      done
2666    fi],
2667   [DEBUG_PREFIX_CFLAGS_FOR_TARGET=])
2668 AC_SUBST(DEBUG_PREFIX_CFLAGS_FOR_TARGET)
2669
2670 # During gcc bootstrap, if we use some random cc for stage1 then CFLAGS
2671 # might be empty or "-g".  We don't require a C++ compiler, so CXXFLAGS
2672 # might also be empty (or "-g", if a non-GCC C++ compiler is in the path).
2673 # We want to ensure that TARGET libraries (which we know are built with
2674 # gcc) are built with "-O2 -g", so include those options when setting
2675 # CFLAGS_FOR_TARGET and CXXFLAGS_FOR_TARGET.
2676 if test "x$CFLAGS_FOR_TARGET" = x; then
2677   if test "x${is_cross_compiler}" = xyes; then
2678     CFLAGS_FOR_TARGET="-g -O2"
2679   else
2680     CFLAGS_FOR_TARGET=$CFLAGS
2681     case " $CFLAGS " in
2682       *" -O2 "*) ;;
2683       *) CFLAGS_FOR_TARGET="-O2 $CFLAGS_FOR_TARGET" ;;
2684     esac
2685     case " $CFLAGS " in
2686       *" -g "* | *" -g3 "*) ;;
2687       *) CFLAGS_FOR_TARGET="-g $CFLAGS_FOR_TARGET" ;;
2688     esac
2689   fi
2690 fi
2691 AC_SUBST(CFLAGS_FOR_TARGET)
2692
2693 if test "x$CXXFLAGS_FOR_TARGET" = x; then
2694   if test "x${is_cross_compiler}" = xyes; then
2695     CXXFLAGS_FOR_TARGET="-g -O2"
2696   else
2697     CXXFLAGS_FOR_TARGET=$CXXFLAGS
2698     case " $CXXFLAGS " in
2699       *" -O2 "*) ;;
2700       *) CXXFLAGS_FOR_TARGET="-O2 $CXXFLAGS_FOR_TARGET" ;;
2701     esac
2702     case " $CXXFLAGS " in
2703       *" -g "* | *" -g3 "*) ;;
2704       *) CXXFLAGS_FOR_TARGET="-g $CXXFLAGS_FOR_TARGET" ;;
2705     esac
2706   fi
2707 fi
2708 AC_SUBST(CXXFLAGS_FOR_TARGET)
2709
2710 AC_SUBST(LDFLAGS_FOR_TARGET)
2711
2712 # Handle --with-headers=XXX.  If the value is not "yes", the contents of
2713 # the named directory are copied to $(tooldir)/sys-include.
2714 if test x"${with_headers}" != x && test x"${with_headers}" != xno ; then
2715   if test x${is_cross_compiler} = xno ; then
2716     echo 1>&2 '***' --with-headers is only supported when cross compiling
2717     exit 1
2718   fi
2719   if test x"${with_headers}" != xyes ; then
2720     x=${gcc_cv_tool_prefix}
2721     copy_dirs="${copy_dirs} ${with_headers} $x/${target_noncanonical}/sys-include"
2722   fi
2723 fi
2724
2725 # Handle --with-libs=XXX.  If the value is not "yes", the contents of
2726 # the name directories are copied to $(tooldir)/lib.  Multiple directories
2727 # are permitted.
2728 if test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
2729   if test x${is_cross_compiler} = xno ; then
2730     echo 1>&2 '***' --with-libs is only supported when cross compiling
2731     exit 1
2732   fi
2733   if test x"${with_libs}" != xyes ; then
2734     # Copy the libraries in reverse order, so that files in the first named
2735     # library override files in subsequent libraries.
2736     x=${gcc_cv_tool_prefix}
2737     for l in ${with_libs}; do
2738       copy_dirs="$l $x/${target_noncanonical}/lib ${copy_dirs}"
2739     done
2740   fi
2741 fi
2742
2743 # Set with_gnu_as, with_gnu_ld, and with_system_zlib as appropriate.
2744 #
2745 # This is done by determining whether or not the appropriate directory
2746 # is available, and by checking whether or not specific configurations
2747 # have requested that this magic not happen.
2748 #
2749 # The command line options always override the explicit settings in
2750 # configure.ac, and the settings in configure.ac override this magic.
2751 #
2752 # If the default for a toolchain is to use GNU as and ld, and you don't
2753 # want to do that, then you should use the --without-gnu-as and
2754 # --without-gnu-ld options for the configure script.  Similarly, if
2755 # the default is to use the included zlib and you don't want to do that,
2756 # you should use the --with-system-zlib option for the configure script.
2757
2758 if test x${use_gnu_as} = x &&
2759    echo " ${configdirs} " | grep " gas " > /dev/null 2>&1 ; then
2760   with_gnu_as=yes
2761   extra_host_args="$extra_host_args --with-gnu-as"
2762 fi
2763
2764 if test x${use_gnu_ld} = x &&
2765    echo " ${configdirs} " | egrep " (go)?ld " > /dev/null 2>&1 ; then
2766   with_gnu_ld=yes
2767   extra_host_args="$extra_host_args --with-gnu-ld"
2768 fi
2769
2770 if test x${use_included_zlib} = x &&
2771    echo " ${configdirs} " | grep " zlib " > /dev/null 2>&1 ; then
2772   :
2773 else
2774   with_system_zlib=yes
2775   extra_host_args="$extra_host_args --with-system-zlib"
2776 fi
2777
2778 # If using newlib, add --with-newlib to the extra_host_args so that gcc/configure
2779 # can detect this case.
2780
2781 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " target-newlib " > /dev/null 2>&1 ; then
2782   with_newlib=yes
2783   extra_host_args="$extra_host_args --with-newlib"
2784 fi
2785
2786 # Handle ${copy_dirs}
2787 set fnord ${copy_dirs}
2788 shift
2789 while test $# != 0 ; do
2790   if test -f $2/COPIED && test x"`cat $2/COPIED`" = x"$1" ; then
2791     :
2792   else
2793     echo Copying $1 to $2
2794
2795     # Use the install script to create the directory and all required
2796     # parent directories.
2797     if test -d $2 ; then
2798       :
2799     else
2800       echo >config.temp
2801       ${srcdir}/install-sh -c -m 644 config.temp $2/COPIED
2802     fi
2803
2804     # Copy the directory, assuming we have tar.
2805     # FIXME: Should we use B in the second tar?  Not all systems support it.
2806     (cd $1; tar -cf - .) | (cd $2; tar -xpf -)
2807
2808     # It is the responsibility of the user to correctly adjust all
2809     # symlinks.  If somebody can figure out how to handle them correctly
2810     # here, feel free to add the code.
2811
2812     echo $1 > $2/COPIED
2813   fi
2814   shift; shift
2815 done
2816
2817 # Determine a target-dependent exec_prefix that the installed
2818 # gcc will search in.  Keep this list sorted by triplet, with
2819 # the *-*-osname triplets last.
2820 md_exec_prefix=
2821 case "${target}" in
2822   i[[34567]]86-pc-msdosdjgpp*)
2823     md_exec_prefix=/dev/env/DJDIR/bin
2824     ;;
2825   *-*-hpux* | \
2826   *-*-nto-qnx* | \
2827   *-*-solaris2*)
2828     md_exec_prefix=/usr/ccs/bin
2829     ;;
2830 esac
2831
2832 extra_arflags_for_target=
2833 extra_nmflags_for_target=
2834 extra_ranlibflags_for_target=
2835 target_makefile_frag=/dev/null
2836 case "${target}" in
2837   spu-*-*)
2838     target_makefile_frag="config/mt-spu"
2839     ;;
2840   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
2841     target_makefile_frag="config/mt-sde"
2842     ;;
2843   mipsisa*-*-elfoabi*)
2844     target_makefile_frag="config/mt-mips-elfoabi"
2845     ;;
2846   mips*-*-*linux* | mips*-*-gnu*)
2847     target_makefile_frag="config/mt-mips-gnu"
2848     ;;
2849   nios2-*-elf*)
2850     target_makefile_frag="config/mt-nios2-elf"
2851     ;;
2852   *-*-linux-android*)
2853     target_makefile_frag="config/mt-android"
2854     ;;
2855   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
2856     target_makefile_frag="config/mt-gnu"
2857     ;;
2858   *-*-aix4.[[3456789]]* | *-*-aix[[56789]].*)
2859     # nm and ar from AIX 4.3 and above require -X32_64 flag to all ar and nm
2860     # commands to handle both 32-bit and 64-bit objects.  These flags are
2861     # harmless if we're using GNU nm or ar.
2862     extra_arflags_for_target=" -X32_64"
2863     extra_nmflags_for_target=" -B -X32_64"
2864     ;;
2865 esac
2866
2867 alphaieee_frag=/dev/null
2868 case $target in
2869   alpha*-*-*)
2870     # This just makes sure to use the -mieee option to build target libs.
2871     # This should probably be set individually by each library.
2872     alphaieee_frag="config/mt-alphaieee"
2873     ;;
2874 esac
2875
2876 # If --enable-target-optspace always use -Os instead of -O2 to build
2877 # the target libraries, similarly if it is not specified, use -Os
2878 # on selected platforms.
2879 ospace_frag=/dev/null
2880 case "${enable_target_optspace}:${target}" in
2881   yes:*)
2882     ospace_frag="config/mt-ospace"
2883     ;;
2884   :d30v-*)
2885     ospace_frag="config/mt-d30v"
2886     ;;
2887   :m32r-* | :d10v-* | :fr30-* | :i?86*-*-elfiamcu)
2888     ospace_frag="config/mt-ospace"
2889     ;;
2890   no:* | :*)
2891     ;;
2892   *)
2893     echo "*** bad value \"${enable_target_optspace}\" for --enable-target-optspace flag; ignored" 1>&2
2894     ;;
2895 esac
2896
2897 # Some systems (e.g., one of the i386-aix systems the gas testers are
2898 # using) don't handle "\$" correctly, so don't use it here.
2899 tooldir='${exec_prefix}'/${target_noncanonical}
2900 build_tooldir=${tooldir}
2901
2902 # Create a .gdbinit file which runs the one in srcdir
2903 # and tells GDB to look there for source files.
2904
2905 if test -r ${srcdir}/.gdbinit ; then
2906   case ${srcdir} in
2907     .) ;;
2908     *) cat > ./.gdbinit <<EOF
2909 # ${NO_EDIT}
2910 dir ${srcdir}
2911 dir .
2912 source ${srcdir}/.gdbinit
2913 EOF
2914     ;;
2915   esac
2916 fi
2917
2918 # Make sure that the compiler is able to generate an executable.  If it
2919 # can't, we are probably in trouble.  We don't care whether we can run the
2920 # executable--we might be using a cross compiler--we only care whether it
2921 # can be created.  At this point the main configure script has set CC.
2922 we_are_ok=no
2923 echo "int main () { return 0; }" > conftest.c
2924 ${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
2925 if test $? = 0 ; then
2926   if test -s conftest || test -s conftest.exe ; then
2927     we_are_ok=yes
2928   fi
2929 fi
2930 case $we_are_ok in
2931   no)
2932     echo 1>&2 "*** The command '${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c' failed."
2933     echo 1>&2 "*** You must set the environment variable CC to a working compiler."
2934     rm -f conftest*
2935     exit 1
2936     ;;
2937 esac
2938 rm -f conftest*
2939
2940 # Decide which environment variable is used to find dynamic libraries.
2941 case "${host}" in
2942   *-*-hpux*) RPATH_ENVVAR=SHLIB_PATH ;;
2943   *-*-darwin*) RPATH_ENVVAR=DYLD_LIBRARY_PATH ;;
2944   *-*-mingw* | *-*-cygwin ) RPATH_ENVVAR=PATH ;;
2945   *) RPATH_ENVVAR=LD_LIBRARY_PATH ;;
2946 esac
2947
2948 # On systems where the dynamic library environment variable is PATH,
2949 # gcc/ will put dynamic libraries into a subdirectory to avoid adding
2950 # built executables to PATH.
2951 if test "$RPATH_ENVVAR" = PATH; then
2952   GCC_SHLIB_SUBDIR=/shlib
2953 else
2954   GCC_SHLIB_SUBDIR=
2955 fi
2956
2957 # Adjust the toplevel makefile according to whether bootstrap was selected.
2958 case $enable_bootstrap in
2959   yes)
2960     bootstrap_suffix=bootstrap
2961     BUILD_CONFIG=bootstrap-debug
2962     ;;
2963   no)
2964     bootstrap_suffix=no-bootstrap
2965     BUILD_CONFIG=
2966     ;;
2967 esac
2968
2969 AC_MSG_CHECKING(for default BUILD_CONFIG)
2970
2971 AC_ARG_WITH([build-config],
2972   [AS_HELP_STRING([--with-build-config='NAME NAME2...'],
2973                   [use config/NAME.mk build configuration])],
2974   [case $with_build_config in
2975    yes) with_build_config= ;;
2976    no) with_build_config= BUILD_CONFIG= ;;
2977    esac])
2978
2979 if test "x${with_build_config}" != x; then
2980   BUILD_CONFIG=$with_build_config
2981 else
2982   case $BUILD_CONFIG in
2983   bootstrap-debug)
2984     if echo "int f (void) { return 0; }" > conftest.c &&
2985        ${CC} -c conftest.c &&
2986        mv conftest.o conftest.o.g0 &&
2987        ${CC} -c -g conftest.c &&
2988        mv conftest.o conftest.o.g &&
2989        ${srcdir}/contrib/compare-debug conftest.o.g0 conftest.o.g > /dev/null 2>&1; then
2990       :
2991     else
2992       BUILD_CONFIG=
2993     fi
2994     rm -f conftest.c conftest.o conftest.o.g0 conftest.o.g
2995     ;;
2996   esac
2997 fi
2998 AC_MSG_RESULT($BUILD_CONFIG)
2999 AC_SUBST(BUILD_CONFIG)
3000
3001 # Use same top-level configure hooks in libgcc/libstdc++/libvtv.
3002 AC_MSG_CHECKING([for --enable-vtable-verify])
3003 AC_ARG_ENABLE(vtable-verify,
3004 [AS_HELP_STRING([--enable-vtable-verify],
3005                 [Enable vtable verification feature])],
3006 [case "$enableval" in
3007  yes) enable_vtable_verify=yes ;;
3008  no)  enable_vtable_verify=no ;;
3009  *)   enable_vtable_verify=no;;
3010  esac],
3011 [enable_vtable_verify=no])
3012 AC_MSG_RESULT($enable_vtable_verify)
3013
3014 # Record target_configdirs and the configure arguments for target and
3015 # build configuration in Makefile.
3016 target_configdirs=`echo "${target_configdirs}" | sed -e 's/target-//g'`
3017 build_configdirs=`echo "${build_configdirs}" | sed -e 's/build-//g'`
3018 bootstrap_fixincludes=no
3019
3020 # If we are building libgomp, bootstrap it.
3021 if echo " ${target_configdirs} " | grep " libgomp " > /dev/null 2>&1 ; then
3022   bootstrap_target_libs=${bootstrap_target_libs}target-libgomp,
3023 fi
3024
3025 # If we are building libsanitizer and $BUILD_CONFIG contains bootstrap-asan
3026 # or bootstrap-ubsan, bootstrap it.
3027 if echo " ${target_configdirs} " | grep " libsanitizer " > /dev/null 2>&1; then
3028   case "$BUILD_CONFIG" in
3029     *bootstrap-hwasan* | *bootstrap-asan* | *bootstrap-ubsan* )
3030       bootstrap_target_libs=${bootstrap_target_libs}target-libsanitizer,
3031       bootstrap_fixincludes=yes
3032       ;;
3033   esac
3034 fi
3035
3036 # If we are building libvtv and --enable-vtable-verify, bootstrap it.
3037 if echo " ${target_configdirs} " | grep " libvtv " > /dev/null 2>&1 &&
3038    test "$enable_vtable_verify" != no; then
3039   bootstrap_target_libs=${bootstrap_target_libs}target-libvtv,
3040 fi
3041
3042 # If we are building libatomic and the list of enabled languages includes the
3043 # D frontend, bootstrap it.
3044 if echo " ${target_configdirs} " | grep " libatomic " > /dev/null 2>&1; then
3045   case ,${enable_languages}, in
3046     *,d,*)
3047       bootstrap_target_libs=${bootstrap_target_libs}target-libatomic,
3048       ;;
3049   esac
3050 fi
3051
3052 # Determine whether gdb needs tk/tcl or not.
3053 # Use 'maybe' since enable_gdbtk might be true even if tk isn't available
3054 # and in that case we want gdb to be built without tk.  Ugh!
3055 # In fact I believe gdb is the *only* package directly dependent on tk,
3056 # so we should be able to put the 'maybe's in unconditionally and
3057 # leave out the maybe dependencies when enable_gdbtk is false.  I'm not
3058 # 100% sure that that's safe though.
3059
3060 gdb_tk="maybe-all-tcl maybe-all-tk maybe-all-itcl maybe-all-libgui"
3061 case "$enable_gdbtk" in
3062   no)
3063     GDB_TK="" ;;
3064   yes)
3065     GDB_TK="${gdb_tk}" ;;
3066   *)
3067     # Only add the dependency on gdbtk when GDBtk is part of the gdb
3068     # distro.  Eventually someone will fix this and move Insight, nee
3069     # gdbtk to a separate directory.
3070     if test -d ${srcdir}/gdb/gdbtk ; then
3071       GDB_TK="${gdb_tk}"
3072     else
3073       GDB_TK=""
3074     fi
3075     ;;
3076 esac
3077 CONFIGURE_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-configure-/g`
3078 INSTALL_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-install-/g`
3079
3080 # gdb and gdbserver depend on gnulib and gdbsupport, but as nothing
3081 # else does, only include them if one of these is built.  The Makefile
3082 # provides the ordering, so it's enough here to add to the list.
3083 case " ${configdirs} " in
3084   *\ gdb\ *)
3085     configdirs="${configdirs} gnulib gdbsupport"
3086     ;;
3087   *\ gdbserver\ *)
3088     configdirs="${configdirs} gnulib gdbsupport"
3089     ;;
3090   *\ sim\ *)
3091     configdirs="${configdirs} gnulib"
3092     ;;
3093 esac
3094
3095 # Strip out unwanted targets.
3096
3097 # While at that, we remove Makefiles if we were started for recursive
3098 # configuration, so that the top-level Makefile reconfigures them,
3099 # like we used to do when configure itself was recursive.
3100
3101 # Loop over modules.  We used to use the "$extrasub" feature from Autoconf
3102 # but now we're fixing up the Makefile ourselves with the additional
3103 # commands passed to AC_CONFIG_FILES.  Use separate variables
3104 # extrasub-{build,host,target} not because there is any reason to split
3105 # the substitutions up that way, but only to remain below the limit of
3106 # 99 commands in a script, for HP-UX sed.
3107
3108 # Do not nest @if/@endif or @unless/@endunless pairs, because
3109 # configure will not warn you at all.
3110
3111 case "$enable_bootstrap:$ENABLE_GOLD: $configdirs :,$stage1_languages," in
3112   yes:yes:*\ gold\ *:*,c++,*) ;;
3113   yes:yes:*\ gold\ *:*)
3114     AC_MSG_ERROR([in a combined tree, bootstrapping with --enable-gold requires c++ in stage1_languages])
3115     ;;
3116 esac
3117
3118 extrasub_build=
3119 for module in ${build_configdirs} ; do
3120   if test -z "${no_recursion}" \
3121      && test -f ${build_subdir}/${module}/Makefile; then
3122     echo 1>&2 "*** removing ${build_subdir}/${module}/Makefile to force reconfigure"
3123     rm -f ${build_subdir}/${module}/Makefile
3124   fi
3125   extrasub_build="$extrasub_build
3126 /^@if build-$module\$/d
3127 /^@endif build-$module\$/d
3128 /^@unless build-$module\$/,/^@endunless build-$module\$/d
3129 /^@if build-$module-$bootstrap_suffix\$/d
3130 /^@endif build-$module-$bootstrap_suffix\$/d
3131 /^@unless build-$module-$bootstrap_suffix\$/,/^@endunless build-$module-$bootstrap_suffix\$/d"
3132 done
3133 extrasub_host=
3134 for module in ${configdirs} ; do
3135   if test -z "${no_recursion}"; then
3136     for file in stage*-${module}/Makefile prev-${module}/Makefile ${module}/Makefile; do
3137       if test -f ${file}; then
3138         echo 1>&2 "*** removing ${file} to force reconfigure"
3139         rm -f ${file}
3140       fi
3141     done
3142   fi
3143   case ${module},${bootstrap_fixincludes} in
3144     fixincludes,no) host_bootstrap_suffix=no-bootstrap ;;
3145     *) host_bootstrap_suffix=$bootstrap_suffix ;;
3146   esac
3147   extrasub_host="$extrasub_host
3148 /^@if $module\$/d
3149 /^@endif $module\$/d
3150 /^@unless $module\$/,/^@endunless $module\$/d
3151 /^@if $module-$host_bootstrap_suffix\$/d
3152 /^@endif $module-$host_bootstrap_suffix\$/d
3153 /^@unless $module-$host_bootstrap_suffix\$/,/^@endunless $module-$host_bootstrap_suffix\$/d"
3154 done
3155 extrasub_target=
3156 for module in ${target_configdirs} ; do
3157   if test -z "${no_recursion}" \
3158      && test -f ${target_subdir}/${module}/Makefile; then
3159     echo 1>&2 "*** removing ${target_subdir}/${module}/Makefile to force reconfigure"
3160     rm -f ${target_subdir}/${module}/Makefile
3161   fi
3162
3163   # We only bootstrap target libraries listed in bootstrap_target_libs.
3164   case $bootstrap_target_libs in
3165     *,target-$module,*) target_bootstrap_suffix=$bootstrap_suffix ;;
3166     *) target_bootstrap_suffix=no-bootstrap ;;
3167   esac
3168
3169   extrasub_target="$extrasub_target
3170 /^@if target-$module\$/d
3171 /^@endif target-$module\$/d
3172 /^@unless target-$module\$/,/^@endunless target-$module\$/d
3173 /^@if target-$module-$target_bootstrap_suffix\$/d
3174 /^@endif target-$module-$target_bootstrap_suffix\$/d
3175 /^@unless target-$module-$target_bootstrap_suffix\$/,/^@endunless target-$module-$target_bootstrap_suffix\$/d"
3176 done
3177
3178 # Do the final fixup along with target modules.
3179 extrasub_target="$extrasub_target
3180 /^@if /,/^@endif /d
3181 /^@unless /d
3182 /^@endunless /d"
3183
3184 if test "$enable_pgo_build" != "no"; then
3185   extrasub_build="$extrasub_build
3186 /^@if pgo-build\$/d
3187 /^@endif pgo-build\$/d"
3188 fi
3189
3190 # Create the serialization dependencies.  This uses a temporary file.
3191
3192 AC_ARG_ENABLE([serial-configure],
3193 [AS_HELP_STRING([[--enable-serial-[{host,target,build}-]configure]],
3194                 [force sequential configuration of
3195                  sub-packages for the host, target or build
3196                  machine, or all sub-packages])])
3197
3198 case ${enable_serial_configure} in
3199   yes)
3200     enable_serial_build_configure=yes
3201     enable_serial_host_configure=yes
3202     enable_serial_target_configure=yes
3203     ;;
3204 esac
3205
3206 # These force 'configure's to be done one at a time, to avoid problems
3207 # with contention over a shared config.cache.
3208 rm -f serdep.tmp
3209 if test "x${enable_serial_build_configure}" = xyes || test "x${enable_serial_host_configure}" = xyes || test "x${enable_serial_target_configure}" = xyes; then
3210 echo '# serdep.tmp' > serdep.tmp
3211 fi
3212 olditem=
3213 test "x${enable_serial_build_configure}" = xyes &&
3214 for item in ${build_configdirs} ; do
3215   case ${olditem} in
3216     "") ;;
3217     *) echo "configure-build-${item}: configure-build-${olditem}" >> serdep.tmp ;;
3218   esac
3219   olditem=${item}
3220 done
3221 olditem=
3222 test "x${enable_serial_host_configure}" = xyes &&
3223 for item in ${configdirs} ; do
3224   case ${olditem} in
3225     "") ;;
3226     *) echo "configure-${item}: configure-${olditem}" >> serdep.tmp ;;
3227   esac
3228   olditem=${item}
3229 done
3230 olditem=
3231 test "x${enable_serial_target_configure}" = xyes &&
3232 for item in ${target_configdirs} ; do
3233   case ${olditem} in
3234     "") ;;
3235     *) echo "configure-target-${item}: configure-target-${olditem}" >> serdep.tmp ;;
3236   esac
3237   olditem=${item}
3238 done
3239 serialization_dependencies=serdep.tmp
3240 AC_SUBST_FILE(serialization_dependencies)
3241
3242 # Base args.  Strip norecursion, cache-file, srcdir, host, build,
3243 # target, nonopt, and variable assignments.  These are the ones we
3244 # might not want to pass down to subconfigures.  The exception being
3245 # --cache-file=/dev/null, which is used to turn off the use of cache
3246 # files altogether, and which should be passed on to subconfigures.
3247 # Also strip program-prefix, program-suffix, and program-transform-name,
3248 # so that we can pass down a consistent program-transform-name.
3249 baseargs=
3250 tbaseargs=
3251 keep_next=no
3252 skip_next=no
3253 eval "set -- $ac_configure_args"
3254 for ac_arg
3255 do
3256   if test X"$skip_next" = X"yes"; then
3257     skip_next=no
3258     continue
3259   fi
3260   if test X"$keep_next" = X"yes"; then
3261     case $ac_arg in
3262       *\'*)
3263         ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
3264     esac
3265     baseargs="$baseargs '$ac_arg'"
3266     tbaseargs="$tbaseargs '$ac_arg'"
3267     keep_next=no
3268     continue
3269   fi
3270
3271   # Handle separated arguments.  Based on the logic generated by
3272   # autoconf 2.59.
3273   case $ac_arg in
3274     *=* | --config-cache | -C | -disable-* | --disable-* \
3275       | -enable-* | --enable-* | -gas | --g* | -nfp | --nf* \
3276       | -q | -quiet | --q* | -silent | --sil* | -v | -verb* \
3277       | -with-* | --with-* | -without-* | --without-* | --x)
3278       separate_arg=no
3279       ;;
3280     -*)
3281       separate_arg=yes
3282       ;;
3283     *)
3284       separate_arg=no
3285       ;;
3286   esac
3287
3288   skip_targ=no
3289   case $ac_arg in
3290 changequote(,)
3291   --with-* | --without-*)
3292     libopt=`echo "$ac_arg" | sed -e 's,^--[^-_]*[-_],,' -e 's,=.*$,,'`
3293
3294     case $libopt in
3295     *[-_]include)
3296       lib=`echo "$libopt" | sed 's,[-_]include$,,'`
3297       ;;
3298     *[-_]lib)
3299       lib=`echo "$libopt" | sed 's,[-_]lib$,,'`
3300       ;;
3301     *)
3302       lib=$libopt
3303       ;;
3304     esac
3305 changequote([,])
3306
3307     case $lib in
3308     mpc | mpfr | gmp | isl)
3309       # If we're processing --with-$lib, --with-$lib-include or
3310       # --with-$lib-lib, for one of the libs above, and target is
3311       # different from host, don't pass the current argument to any
3312       # target library's configure.
3313       if test x$is_cross_compiler = xyes; then
3314         skip_targ=yes
3315       fi
3316       ;;
3317     esac
3318     ;;
3319   esac
3320
3321   case "$ac_arg" in
3322     --cache-file=/dev/null | \
3323     -cache-file=/dev/null )
3324       # Handled here to avoid the test to skip args below.
3325       baseargs="$baseargs '$ac_arg'"
3326       tbaseargs="$tbaseargs '$ac_arg'"
3327       # Assert: $separate_arg should always be no.
3328       keep_next=$separate_arg
3329       ;;
3330     --no*)
3331       continue
3332       ;;
3333     --c* | \
3334     --sr* | \
3335     --ho* | \
3336     --bu* | \
3337     --t* | \
3338     --program-* | \
3339     -cache_file* | \
3340     -srcdir* | \
3341     -host* | \
3342     -build* | \
3343     -target* | \
3344     -program-prefix* | \
3345     -program-suffix* | \
3346     -program-transform-name* )
3347       skip_next=$separate_arg
3348       continue
3349       ;;
3350     -*)
3351       # An option.  Add it.
3352       case $ac_arg in
3353         *\'*)
3354           ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
3355       esac
3356       baseargs="$baseargs '$ac_arg'"
3357       if test X"$skip_targ" = Xno; then
3358         tbaseargs="$tbaseargs '$ac_arg'"
3359       fi
3360       keep_next=$separate_arg
3361       ;;
3362     *)
3363       # Either a variable assignment, or a nonopt (triplet).  Don't
3364       # pass it down; let the Makefile handle this.
3365       continue
3366       ;;
3367   esac
3368 done
3369 # Remove the initial space we just introduced and, as these will be
3370 # expanded by make, quote '$'.
3371 baseargs=`echo "x$baseargs" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
3372
3373 # Add in --program-transform-name, after --program-prefix and
3374 # --program-suffix have been applied to it.  Autoconf has already
3375 # doubled dollar signs and backslashes in program_transform_name; we want
3376 # the backslashes un-doubled, and then the entire thing wrapped in single
3377 # quotes, because this will be expanded first by make and then by the shell.
3378 # Also, because we want to override the logic in subdir configure scripts to
3379 # choose program_transform_name, replace any s,x,x, with s,y,y,.
3380 sed -e "s,\\\\\\\\,\\\\,g; s,','\\\\'',g; s/s,x,x,/s,y,y,/" <<EOF_SED > conftestsed.out
3381 ${program_transform_name}
3382 EOF_SED
3383 gcc_transform_name=`cat conftestsed.out`
3384 rm -f conftestsed.out
3385 baseargs="$baseargs --program-transform-name='${gcc_transform_name}'"
3386 tbaseargs="$tbaseargs --program-transform-name='${gcc_transform_name}'"
3387 if test "$silent" = yes; then
3388   baseargs="$baseargs --silent"
3389   tbaseargs="$tbaseargs --silent"
3390 fi
3391
3392 baseargs="$baseargs --disable-option-checking"
3393 tbaseargs="$tbaseargs --disable-option-checking"
3394
3395 if test "$enable_year2038" = no; then
3396   baseargs="$baseargs --disable-year2038"
3397   tbaseargs="$tbaseargs --disable-year2038"
3398 fi
3399
3400 # Record and document user additions to sub configure arguments.
3401 AC_ARG_VAR([build_configargs],
3402            [additional configure arguments for build directories])
3403 AC_ARG_VAR([host_configargs],
3404            [additional configure arguments for host directories])
3405 AC_ARG_VAR([target_configargs],
3406            [additional configure arguments for target directories])
3407
3408 # For the build-side libraries, we just need to pretend we're native,
3409 # and not use the same cache file.  Multilibs are neither needed nor
3410 # desired.  We can't even use the same cache file for all build-side
3411 # libraries, as they're compiled differently; some with C, some with
3412 # C++ or with different feature-enabling options.
3413 build_configargs="$build_configargs --cache-file=./config.cache ${baseargs}"
3414
3415 # For host modules, accept cache file option, or specification as blank.
3416 case "${cache_file}" in
3417 "") # empty
3418   cache_file_option="" ;;
3419 /* | [[A-Za-z]]:[[\\/]]* ) # absolute path
3420   cache_file_option="--cache-file=${cache_file}" ;;
3421 *) # relative path
3422   cache_file_option="--cache-file=../${cache_file}" ;;
3423 esac
3424
3425 # Host dirs don't like to share a cache file either, horribly enough.
3426 # This seems to be due to autoconf 2.5x stupidity.
3427 host_configargs="$host_configargs --cache-file=./config.cache ${extra_host_args} ${baseargs}"
3428
3429 target_configargs="$target_configargs ${tbaseargs}"
3430
3431 # Passing a --with-cross-host argument lets the target libraries know
3432 # whether they are being built with a cross-compiler or being built
3433 # native.  However, it would be better to use other mechanisms to make the
3434 # sorts of decisions they want to make on this basis.  Please consider
3435 # this option to be deprecated.  FIXME.
3436 if test x${is_cross_compiler} = xyes ; then
3437   target_configargs="--with-cross-host=${host_noncanonical} ${target_configargs}"
3438 fi
3439
3440 # Special user-friendly check for native x86_64-linux build, if
3441 # multilib is not explicitly enabled.
3442 case "$target:$have_compiler:$host:$target:$enable_multilib" in
3443   x86_64-*linux*:yes:$build:$build:)
3444     # Make sure we have a development environment that handles 32-bit
3445     dev64=no
3446     echo "int main () { return 0; }" > conftest.c
3447     ${CC} -m32 -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
3448     if test $? = 0 ; then
3449       if test -s conftest || test -s conftest.exe ; then
3450         dev64=yes
3451       fi
3452     fi
3453     rm -f conftest*
3454     if test x${dev64} != xyes ; then
3455       AC_MSG_ERROR([I suspect your system does not have 32-bit development libraries (libc and headers). If you have them, rerun configure with --enable-multilib. If you do not have them, and want to build a 64-bit-only compiler, rerun configure with --disable-multilib.])
3456     fi
3457     ;;
3458 esac
3459
3460 # Default to --enable-multilib.
3461 if test x${enable_multilib} = x ; then
3462   target_configargs="--enable-multilib ${target_configargs}"
3463 fi
3464
3465 # Pass --with-newlib if appropriate.  Note that target_configdirs has
3466 # changed from the earlier setting of with_newlib.
3467 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " newlib " > /dev/null 2>&1 && test -d ${srcdir}/newlib ; then
3468   target_configargs="--with-newlib ${target_configargs}"
3469 fi
3470
3471 # Different target subdirs use different values of certain variables
3472 # (notably CXX).  Worse, multilibs use *lots* of different values.
3473 # Worse yet, autoconf 2.5x makes some of these 'precious', meaning that
3474 # it doesn't automatically accept command-line overrides of them.
3475 # This means it's not safe for target subdirs to share a cache file,
3476 # which is disgusting, but there you have it.  Hopefully this can be
3477 # fixed in future.  It's still worthwhile to use a cache file for each
3478 # directory.  I think.
3479
3480 # Pass the appropriate --build, --host, --target and --cache-file arguments.
3481 # We need to pass --target, as newer autoconf's requires consistency
3482 # for target_alias and gcc doesn't manage it consistently.
3483 target_configargs="--cache-file=./config.cache ${target_configargs}"
3484
3485 FLAGS_FOR_TARGET=
3486 case " $target_configdirs " in
3487  *" newlib "*)
3488   case " $target_configargs " in
3489   *" --with-newlib "*)
3490    case "$target" in
3491     *-cygwin*)
3492       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/cygwin -isystem $$s/winsup/cygwin/include'
3493       ;;
3494    esac
3495
3496    # If we're not building GCC, don't discard standard headers.
3497    if test -d ${srcdir}/gcc; then
3498      FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -nostdinc'
3499
3500      if test "${build}" != "${host}"; then
3501        # On Canadian crosses, CC_FOR_TARGET will have already been set
3502        # by `configure', so we won't have an opportunity to add -Bgcc/
3503        # to it.  This is right: we don't want to search that directory
3504        # for binaries, but we want the header files in there, so add
3505        # them explicitly.
3506        FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -isystem $$r/$(HOST_SUBDIR)/gcc/include -isystem $$r/$(HOST_SUBDIR)/gcc/include-fixed'
3507
3508        # Someone might think of using the pre-installed headers on
3509        # Canadian crosses, in case the installed compiler is not fully
3510        # compatible with the compiler being built.  In this case, it
3511        # would be better to flag an error than risking having
3512        # incompatible object files being constructed.  We can't
3513        # guarantee that an error will be flagged, but let's hope the
3514        # compiler will do it, when presented with incompatible header
3515        # files.
3516      fi
3517    fi
3518
3519    case "${target}-${is_cross_compiler}" in
3520    i[[3456789]]86-*-linux*-no)
3521       # Here host == target, so we don't need to build gcc,
3522       # so we don't want to discard standard headers.
3523       FLAGS_FOR_TARGET=`echo " $FLAGS_FOR_TARGET " | sed -e 's/ -nostdinc / /'`
3524       ;;
3525    *)
3526       # If we're building newlib, use its generic headers last, but search
3527       # for any libc-related directories first (so make it the last -B
3528       # switch).
3529       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/newlib/ -isystem $$r/$(TARGET_SUBDIR)/newlib/targ-include -isystem $$s/newlib/libc/include'
3530
3531       # If we're building libgloss, find the startup file, simulator library
3532       # and linker script.
3533       case " $target_configdirs " in
3534         *" libgloss "*)
3535         # Look for startup file, simulator library and maybe linker script.
3536         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/libgloss/'"$libgloss_dir"
3537         # Look for libnosys.a in case the target needs it.
3538         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/libgloss/libnosys'
3539         # Most targets have the linker script in the source directory.
3540         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$s/libgloss/'"$libgloss_dir"
3541         ;;
3542       esac
3543       ;;
3544    esac
3545    ;;
3546   esac
3547   ;;
3548 esac
3549
3550 case "$target" in
3551   x86_64-*mingw* | *-w64-mingw*)
3552   # MinGW-w64 does not use newlib, nor does it use winsup. It may,
3553   # however, use a symlink named 'mingw' in ${prefix} .
3554     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L${prefix}/${target}/lib -L${prefix}/mingw/lib -isystem ${prefix}/${target}/include -isystem ${prefix}/mingw/include'
3555     ;;
3556   *-mingw*)
3557   # MinGW can't be handled as Cygwin above since it does not use newlib.
3558     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/mingw -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/mingw/include -isystem $$s/winsup/w32api/include'
3559     ;;
3560 esac
3561
3562 # Allow the user to override the flags for
3563 # our build compiler if desired.
3564 if test x"${build}" = x"${host}" ; then
3565   CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-${CFLAGS}}
3566   CPPFLAGS_FOR_BUILD=${CPPFLAGS_FOR_BUILD-${CPPFLAGS}}
3567   CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-${CXXFLAGS}}
3568   LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-${LDFLAGS}}
3569 fi
3570
3571 # On Canadian crosses, we'll be searching the right directories for
3572 # the previously-installed cross compiler, so don't bother to add
3573 # flags for directories within the install tree of the compiler
3574 # being built; programs in there won't even run.
3575 if test "${build}" = "${host}" && test -d ${srcdir}/gcc; then
3576   # Search for pre-installed headers if nothing else fits.
3577   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$(build_tooldir)/bin/ -B$(build_tooldir)/lib/ -isystem $(build_tooldir)/include -isystem $(build_tooldir)/sys-include'
3578 fi
3579
3580 if test "x${use_gnu_ld}" = x &&
3581    echo " ${configdirs} " | grep " ld " > /dev/null ; then
3582   # Arrange for us to find uninstalled linker scripts.
3583   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(HOST_SUBDIR)/ld'
3584 fi
3585
3586 # Search for other target-specific linker scripts and such.
3587 case "${target}" in
3588   mep*)
3589     FLAGS_FOR_TARGET="$FLAGS_FOR_TARGET -mlibrary"
3590     ;;
3591   # The VxWorks support for shared libraries is getting in
3592   # incrementally.  Make sure it doesn't get activated implicitly:
3593   *vxworks*)
3594     if test "${enable_shared-unset}" = unset ; then
3595       enable_shared=no
3596       # So the build of libraries knows ...
3597       target_configargs="${target_configargs} --disable-shared"
3598       # So gcc knows ...
3599       host_configargs="${host_configargs} --disable-shared"
3600     fi
3601     ;;
3602 esac
3603
3604 # Makefile fragments.
3605 for frag in host_makefile_frag target_makefile_frag alphaieee_frag ospace_frag;
3606 do
3607   eval fragval=\$$frag
3608   if test $fragval != /dev/null; then
3609     eval $frag=${srcdir}/$fragval
3610   fi
3611 done
3612 AC_SUBST_FILE(host_makefile_frag)
3613 AC_SUBST_FILE(target_makefile_frag)
3614 AC_SUBST_FILE(alphaieee_frag)
3615 AC_SUBST_FILE(ospace_frag)
3616
3617 # Miscellanea: directories, flags, etc.
3618 AC_SUBST(RPATH_ENVVAR)
3619 AC_SUBST(GCC_SHLIB_SUBDIR)
3620 AC_SUBST(tooldir)
3621 AC_SUBST(build_tooldir)
3622 AC_SUBST(CONFIGURE_GDB_TK)
3623 AC_SUBST(GDB_TK)
3624 AC_SUBST(INSTALL_GDB_TK)
3625
3626 # Build module lists & subconfigure args.
3627 AC_SUBST(build_configargs)
3628 AC_SUBST(build_configdirs)
3629
3630 # Host module lists & subconfigure args.
3631 AC_SUBST(host_configargs)
3632 AC_SUBST(configdirs)
3633 AC_SUBST(target_configdirs)
3634
3635 # Target module lists & subconfigure args.
3636 AC_SUBST(target_configargs)
3637
3638
3639 # Build tools.
3640 AC_SUBST(AR_FOR_BUILD)
3641 AC_SUBST(AS_FOR_BUILD)
3642 AC_SUBST(CC_FOR_BUILD)
3643 AC_SUBST(CFLAGS_FOR_BUILD)
3644 AC_SUBST(CPP_FOR_BUILD)
3645 AC_SUBST(CPPFLAGS_FOR_BUILD)
3646 AC_SUBST(CXXFLAGS_FOR_BUILD)
3647 AC_SUBST(CXX_FOR_BUILD)
3648 AC_SUBST(DLLTOOL_FOR_BUILD)
3649 AC_SUBST(DSYMUTIL_FOR_BUILD)
3650 AC_SUBST(GFORTRAN_FOR_BUILD)
3651 AC_SUBST(GOC_FOR_BUILD)
3652 AC_SUBST(GDC_FOR_BUILD)
3653 AC_SUBST(LDFLAGS_FOR_BUILD)
3654 AC_SUBST(LD_FOR_BUILD)
3655 AC_SUBST(NM_FOR_BUILD)
3656 AC_SUBST(RANLIB_FOR_BUILD)
3657 AC_SUBST(WINDMC_FOR_BUILD)
3658 AC_SUBST(WINDRES_FOR_BUILD)
3659
3660 # Generate default definitions for YACC, M4, LEX and other programs that run
3661 # on the build machine.  These are used if the Makefile can't locate these
3662 # programs in objdir.
3663 MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
3664
3665 AC_CHECK_PROGS([YACC], ['bison -y' byacc yacc], [$MISSING bison -y])
3666 case " $build_configdirs " in
3667   *" bison "*) YACC='$$r/$(BUILD_SUBDIR)/bison/tests/bison -y' ;;
3668 esac
3669
3670 AC_CHECK_PROGS([BISON], [bison], [$MISSING bison])
3671 case " $build_configdirs " in
3672   *" bison "*) BISON='$$r/$(BUILD_SUBDIR)/bison/tests/bison' ;;
3673 esac
3674
3675 AC_CHECK_PROGS([M4], [gm4 gnum4 m4], [$MISSING m4])
3676 case " $build_configdirs " in
3677   *" m4 "*) M4='$$r/$(BUILD_SUBDIR)/m4/m4' ;;
3678 esac
3679
3680 AC_CHECK_PROGS([LEX], [flex lex], [$MISSING flex])
3681 case " $build_configdirs " in
3682   *" flex "*) LEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3683   *" lex "*) LEX='$$r/$(BUILD_SUBDIR)/lex/lex' ;;
3684 esac
3685
3686 AC_CHECK_PROGS([FLEX], [flex], [$MISSING flex])
3687 case " $build_configdirs " in
3688   *" flex "*) FLEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3689 esac
3690
3691 AC_CHECK_PROGS([MAKEINFO], makeinfo, [$MISSING makeinfo])
3692 case " $build_configdirs " in
3693   *" texinfo "*) MAKEINFO='$$r/$(BUILD_SUBDIR)/texinfo/makeinfo/makeinfo' ;;
3694   *)
3695 changequote(,)
3696     # For an installed makeinfo, we require it to be from texinfo 4.7 or
3697     # higher, else we use the "missing" dummy.
3698     if ${MAKEINFO} --version \
3699        | egrep 'texinfo[^0-9]*(4\.([7-9]|[1-9][0-9])|[5-9]|[1-9][0-9])' >/dev/null 2>&1; then
3700       :
3701     else
3702       MAKEINFO="$MISSING makeinfo"
3703     fi
3704     ;;
3705 changequote([,])
3706 esac
3707
3708 # FIXME: expect and dejagnu may become build tools?
3709
3710 AC_CHECK_PROGS(EXPECT, expect, expect)
3711 case " $configdirs " in
3712   *" expect "*)
3713     test $host = $build && EXPECT='$$r/$(HOST_SUBDIR)/expect/expect'
3714     ;;
3715 esac
3716
3717 AC_CHECK_PROGS(RUNTEST, runtest, runtest)
3718 case " $configdirs " in
3719   *" dejagnu "*)
3720     test $host = $build && RUNTEST='$$s/$(HOST_SUBDIR)/dejagnu/runtest'
3721     ;;
3722 esac
3723
3724
3725 # Host tools.
3726 NCN_STRICT_CHECK_TOOLS(AR, ar)
3727 NCN_STRICT_CHECK_TOOLS(AS, as)
3728 NCN_STRICT_CHECK_TOOLS(DLLTOOL, dlltool)
3729 NCN_STRICT_CHECK_TOOLS(DSYMUTIL, dsymutil)
3730 NCN_STRICT_CHECK_TOOLS(LD, ld)
3731 NCN_STRICT_CHECK_TOOLS(LIPO, lipo)
3732 NCN_STRICT_CHECK_TOOLS(NM, nm)
3733 NCN_STRICT_CHECK_TOOLS(RANLIB, ranlib, true)
3734 NCN_STRICT_CHECK_TOOLS(STRIP, strip, true)
3735 NCN_STRICT_CHECK_TOOLS(WINDRES, windres)
3736 NCN_STRICT_CHECK_TOOLS(WINDMC, windmc)
3737 NCN_STRICT_CHECK_TOOLS(OBJCOPY, objcopy)
3738 NCN_STRICT_CHECK_TOOLS(OBJDUMP, objdump)
3739 NCN_STRICT_CHECK_TOOLS(OTOOL, otool)
3740 NCN_STRICT_CHECK_TOOLS(READELF, readelf)
3741 AC_SUBST(CC)
3742 AC_SUBST(CXX)
3743 AC_SUBST(CFLAGS)
3744 AC_SUBST(CXXFLAGS)
3745 AC_SUBST(GDC)
3746 AC_SUBST(GDCFLAGS)
3747 AC_SUBST(PKG_CONFIG_PATH)
3748
3749 GCC_PLUGIN_OPTION(PLUGIN_OPTION)
3750 AR_PLUGIN_OPTION=
3751 RANLIB_PLUGIN_OPTION=
3752 if test -n "$PLUGIN_OPTION"; then
3753   if $AR --help 2>&1 | grep -q "\--plugin"; then
3754     AR_PLUGIN_OPTION="$PLUGIN_OPTION"
3755   fi
3756   if $RANLIB --help 2>&1 | grep -q "\--plugin"; then
3757     RANLIB_PLUGIN_OPTION="$PLUGIN_OPTION"
3758   fi
3759 fi
3760 AC_SUBST(AR_PLUGIN_OPTION)
3761 AC_SUBST(RANLIB_PLUGIN_OPTION)
3762
3763 # Target tools.
3764 AC_ARG_WITH([build-time-tools],
3765   [AS_HELP_STRING([--with-build-time-tools=PATH],
3766                   [use given path to find target tools during the build])],
3767   [case x"$withval" in
3768      x/*) ;;
3769      *)
3770        with_build_time_tools=
3771        AC_MSG_WARN([argument to --with-build-time-tools must be an absolute path])
3772        ;;
3773    esac],
3774   [with_build_time_tools=])
3775
3776 NCN_STRICT_CHECK_TARGET_TOOLS(CC_FOR_TARGET, cc gcc)
3777 NCN_STRICT_CHECK_TARGET_TOOLS(CXX_FOR_TARGET, c++ g++ cxx gxx)
3778 NCN_STRICT_CHECK_TARGET_TOOLS(GCC_FOR_TARGET, gcc, ${CC_FOR_TARGET})
3779 NCN_STRICT_CHECK_TARGET_TOOLS(GFORTRAN_FOR_TARGET, gfortran)
3780 NCN_STRICT_CHECK_TARGET_TOOLS(GOC_FOR_TARGET, gccgo)
3781 NCN_STRICT_CHECK_TARGET_TOOLS(GDC_FOR_TARGET, gdc)
3782
3783 ACX_CHECK_INSTALLED_TARGET_TOOL(AR_FOR_TARGET, ar)
3784 ACX_CHECK_INSTALLED_TARGET_TOOL(AS_FOR_TARGET, as)
3785 ACX_CHECK_INSTALLED_TARGET_TOOL(DLLTOOL_FOR_TARGET, dlltool)
3786 ACX_CHECK_INSTALLED_TARGET_TOOL(DSYMUTIL_FOR_TARGET, dsymutil)
3787 ACX_CHECK_INSTALLED_TARGET_TOOL(LD_FOR_TARGET, ld)
3788 ACX_CHECK_INSTALLED_TARGET_TOOL(LIPO_FOR_TARGET, lipo)
3789 ACX_CHECK_INSTALLED_TARGET_TOOL(NM_FOR_TARGET, nm)
3790 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJCOPY_FOR_TARGET, objcopy)
3791 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJDUMP_FOR_TARGET, objdump)
3792 ACX_CHECK_INSTALLED_TARGET_TOOL(OTOOL_FOR_TARGET, otool)
3793 ACX_CHECK_INSTALLED_TARGET_TOOL(RANLIB_FOR_TARGET, ranlib)
3794 ACX_CHECK_INSTALLED_TARGET_TOOL(READELF_FOR_TARGET, readelf)
3795 ACX_CHECK_INSTALLED_TARGET_TOOL(STRIP_FOR_TARGET, strip)
3796 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDRES_FOR_TARGET, windres)
3797 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDMC_FOR_TARGET, windmc)
3798
3799 RAW_CXX_FOR_TARGET="$CXX_FOR_TARGET"
3800
3801 GCC_TARGET_TOOL(ar, AR_FOR_TARGET, AR, [binutils/ar])
3802 GCC_TARGET_TOOL(as, AS_FOR_TARGET, AS, [gas/as-new])
3803 GCC_TARGET_TOOL(cc, CC_FOR_TARGET, CC, [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3804 dnl see comments for CXX_FOR_TARGET_FLAG_TO_PASS
3805 GCC_TARGET_TOOL(c++, CXX_FOR_TARGET, CXX,
3806                 [gcc/xg++ -B$$r/$(HOST_SUBDIR)/gcc/ -nostdinc++ `if test -f $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags; then $(SHELL) $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags --build-includes; else echo -funconfigured-libstdc++-v3 ; fi` -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3807                 c++)
3808 GCC_TARGET_TOOL(c++ for libstdc++, RAW_CXX_FOR_TARGET, CXX,
3809                 [gcc/xgcc -shared-libgcc -B$$r/$(HOST_SUBDIR)/gcc -nostdinc++ -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3810                 c++)
3811 GCC_TARGET_TOOL(dlltool, DLLTOOL_FOR_TARGET, DLLTOOL, [binutils/dlltool])
3812 GCC_TARGET_TOOL(dsymutil, DSYMUTIL_FOR_TARGET, DSYMUTIL)
3813 GCC_TARGET_TOOL(gcc, GCC_FOR_TARGET, , [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3814 GCC_TARGET_TOOL(gfortran, GFORTRAN_FOR_TARGET, GFORTRAN,
3815                 [gcc/gfortran -B$$r/$(HOST_SUBDIR)/gcc/], fortran)
3816 GCC_TARGET_TOOL(gccgo, GOC_FOR_TARGET, GOC,
3817                 [gcc/gccgo -B$$r/$(HOST_SUBDIR)/gcc/], go)
3818 GCC_TARGET_TOOL(gdc, GDC_FOR_TARGET, GDC,
3819                 [gcc/gdc -B$$r/$(HOST_SUBDIR)/gcc/], d)
3820 GCC_TARGET_TOOL(ld, LD_FOR_TARGET, LD, [ld/ld-new])
3821 GCC_TARGET_TOOL(lipo, LIPO_FOR_TARGET, LIPO)
3822 GCC_TARGET_TOOL(nm, NM_FOR_TARGET, NM, [binutils/nm-new])
3823 GCC_TARGET_TOOL(objcopy, OBJCOPY_FOR_TARGET, OBJCOPY, [binutils/objcopy])
3824 GCC_TARGET_TOOL(objdump, OBJDUMP_FOR_TARGET, OBJDUMP, [binutils/objdump])
3825 GCC_TARGET_TOOL(otool, OTOOL_FOR_TARGET, OTOOL)
3826 GCC_TARGET_TOOL(ranlib, RANLIB_FOR_TARGET, RANLIB, [binutils/ranlib])
3827 GCC_TARGET_TOOL(readelf, READELF_FOR_TARGET, READELF, [binutils/readelf])
3828 GCC_TARGET_TOOL(strip, STRIP_FOR_TARGET, STRIP, [binutils/strip-new])
3829 GCC_TARGET_TOOL(windres, WINDRES_FOR_TARGET, WINDRES, [binutils/windres])
3830 GCC_TARGET_TOOL(windmc, WINDMC_FOR_TARGET, WINDMC, [binutils/windmc])
3831
3832 AC_SUBST(FLAGS_FOR_TARGET)
3833 AC_SUBST(RAW_CXX_FOR_TARGET)
3834
3835 # Certain tools may need extra flags.
3836 AR_FOR_TARGET=${AR_FOR_TARGET}${extra_arflags_for_target}
3837 RANLIB_FOR_TARGET=${RANLIB_FOR_TARGET}${extra_ranlibflags_for_target}
3838 NM_FOR_TARGET=${NM_FOR_TARGET}${extra_nmflags_for_target}
3839
3840 # When building target libraries, except in a Canadian cross, we use
3841 # the same toolchain as the compiler we just built.
3842 COMPILER_AS_FOR_TARGET='$(AS_FOR_TARGET)'
3843 COMPILER_LD_FOR_TARGET='$(LD_FOR_TARGET)'
3844 COMPILER_NM_FOR_TARGET='$(NM_FOR_TARGET)'
3845 if test $host = $build; then
3846   case " $configdirs " in
3847     *" gcc "*)
3848       COMPILER_AS_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/as'
3849       COMPILER_LD_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/collect-ld'
3850       COMPILER_NM_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/nm'${extra_nmflags_for_target}
3851       ;;
3852   esac
3853 fi
3854
3855 AC_SUBST(COMPILER_AS_FOR_TARGET)
3856 AC_SUBST(COMPILER_LD_FOR_TARGET)
3857 AC_SUBST(COMPILER_NM_FOR_TARGET)
3858
3859 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3860 AC_ARG_ENABLE(maintainer-mode,
3861 [AS_HELP_STRING([--enable-maintainer-mode],
3862                 [enable make rules and dependencies not useful
3863                  (and sometimes confusing) to the casual installer])],
3864       USE_MAINTAINER_MODE=$enableval,
3865       USE_MAINTAINER_MODE=no)
3866 AC_MSG_RESULT($USE_MAINTAINER_MODE)
3867 AC_SUBST(MAINTAINER_MODE_TRUE)
3868 AC_SUBST(MAINTAINER_MODE_FALSE)
3869 if test "$USE_MAINTAINER_MODE" = yes; then
3870   MAINTAINER_MODE_TRUE=
3871   MAINTAINER_MODE_FALSE='#'
3872 else
3873   MAINTAINER_MODE_TRUE='#'
3874   MAINTAINER_MODE_FALSE=
3875 fi
3876 MAINT=$MAINTAINER_MODE_TRUE
3877 AC_SUBST(MAINT)dnl
3878
3879 # ---------------------
3880 # GCC bootstrap support
3881 # ---------------------
3882
3883 # Stage specific cflags for build.
3884 stage1_cflags="-g"
3885 case $build in
3886   vax-*-*)
3887     case ${GCC} in
3888       yes) stage1_cflags="-g -Wa,-J" ;;
3889       *) stage1_cflags="-g -J" ;;
3890     esac ;;
3891 esac
3892
3893 AC_SUBST(stage1_cflags)
3894
3895 # Enable --enable-checking in stage1 of the compiler.
3896 AC_ARG_ENABLE(stage1-checking,
3897 [AS_HELP_STRING([[--enable-stage1-checking[=all]]],
3898                 [choose additional checking for stage1 of the compiler])],
3899 [stage1_checking=--enable-checking=${enable_stage1_checking}],
3900 [if test "x$enable_checking" = xno || test "x$enable_checking" = x; then
3901   # For --disable-checking or implicit --enable-checking=release, avoid
3902   # setting --enable-checking=gc in the default stage1 checking for LTO
3903   # bootstraps.  See PR62077.
3904   case $BUILD_CONFIG in
3905     *lto*)
3906       stage1_checking=--enable-checking=release,misc,gimple,rtlflag,tree,types;;
3907     *)
3908       stage1_checking=--enable-checking=yes,types;;
3909   esac
3910   if test "x$enable_checking" = x && \
3911      test -d ${srcdir}/gcc && \
3912      test x"`cat ${srcdir}/gcc/DEV-PHASE`" = xexperimental; then
3913     stage1_checking=--enable-checking=yes,types,extra
3914   fi
3915 else
3916   stage1_checking=--enable-checking=$enable_checking,types
3917 fi])
3918 AC_SUBST(stage1_checking)
3919
3920 # Enable -Werror in bootstrap stage2 and later.
3921 AC_ARG_ENABLE(werror,
3922 [AS_HELP_STRING([--enable-werror],
3923                 [enable -Werror in bootstrap stage2 and later])],
3924 [
3925 case ${enable_werror} in
3926   yes) stage2_werror_flag="--enable-werror-always" ;;
3927   *) stage2_werror_flag="" ;;
3928 esac
3929 ],
3930 [
3931 if test -d ${srcdir}/gcc && test x"`cat $srcdir/gcc/DEV-PHASE`" = xexperimental; then
3932   case $BUILD_CONFIG in
3933   bootstrap-debug)
3934       stage2_werror_flag="--enable-werror-always" ;;
3935   "")
3936       stage2_werror_flag="--enable-werror-always" ;;
3937   esac
3938 fi
3939 ])
3940
3941 AC_SUBST(stage2_werror_flag)
3942
3943 # Specify what files to not compare during bootstrap.
3944
3945 compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/*"
3946 case "$target" in
3947   hppa*64*-*-hpux*) ;;
3948   hppa*-*-hpux*) compare_exclusions="$compare_exclusions | */libgcc/lib2funcs* | gcc/function-tests.o" ;;
3949   powerpc*-ibm-aix*) compare_exclusions="$compare_exclusions | *libgomp*\$(objext)" ;;
3950 esac
3951 AC_SUBST(compare_exclusions)
3952
3953 AC_CONFIG_FILES([Makefile],
3954   [sed "$extrasub_build" Makefile |
3955    sed "$extrasub_host" |
3956    sed "$extrasub_target" > mf$$
3957    mv -f mf$$ Makefile],
3958   [extrasub_build="$extrasub_build"
3959    extrasub_host="$extrasub_host"
3960    extrasub_target="$extrasub_target"])
3961 AC_OUTPUT