gas/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl And be careful when changing it!  If you must add tests with square
   4 dnl brackets, be sure changequote invocations surround it.
   5 dnl
   6 dnl
   7 dnl v2.5 needed for --bindir et al
   8 AC_PREREQ(2.13)
   9 AC_INIT(as.h)
  10
  11 AC_CANONICAL_SYSTEM
  12 AC_ISC_POSIX
  13
  14 changequote(,)dnl
  15 BFD_VERSION=`sed -n -e 's/^.._INIT_AUTOMAKE.*,[         ]*\([^  ]*\)[   ]*).*/\1/p' < ${srcdir}/../bfd/configure.in`
  16 changequote([,])dnl
  17 AM_INIT_AUTOMAKE(gas, ${BFD_VERSION})
  18
  19 AM_PROG_LIBTOOL
  20
  21 user_bfd_gas=
  22 AC_ARG_ENABLE(bfd-assembler,
  23 [  --enable-bfd-assembler  use BFD back end for writing object files],
  24 [case "${enableval}" in
  25   yes) need_bfd=yes user_bfd_gas=yes ;;
  26   no)  user_bfd_gas=no ;;
  27   *)   AC_MSG_ERROR(bad value ${enableval} given for bfd-assembler option) ;;
  28 esac])dnl
  29 AC_ARG_ENABLE(targets,
  30 [    targets            alternative target configurations besides the primary],
  31 [case "${enableval}" in
  32   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  33             ;;
  34   no)       enable_targets= ;;
  35   *)        enable_targets=$enableval ;;
  36 esac])dnl
  37 AC_ARG_ENABLE(commonbfdlib,
  38 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  39 [case "${enableval}" in
  40   yes) commonbfdlib=true ;;
  41   no)  commonbfdlib=false ;;
  42   *)   AC_MSG_ERROR([bad value ${enableval} for BFD commonbfdlib option]) ;;
  43 esac])dnl
  44
  45 using_cgen=no
  46
  47 build_warnings="-W -Wall -Wstrict-prototypes -Wmissing-prototypes"
  48 AC_ARG_ENABLE(build-warnings,
  49 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
  50 [case "${enableval}" in
  51   yes)  ;;
  52   no)   build_warnings="-w";;
  53   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  54         build_warnings="${build_warnings} ${t}";;
  55   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  56         build_warnings="${t} ${build_warnings}";;
  57   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
  58 esac
  59 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
  60   echo "Setting warning flags = $build_warnings" 6>&1
  61 fi])dnl
  62 WARN_CFLAGS=""
  63 if test "x${build_warnings}" != x -a "x$GCC" = xyes ; then
  64     WARN_CFLAGS="${build_warnings}"
  65 fi
  66 AC_SUBST(WARN_CFLAGS)
  67
  68 # Generate a header file
  69 AM_CONFIG_HEADER(config.h:config.in)
  70
  71 # If we are on a DOS filesystem, we must use gdb.ini rather than
  72 # .gdbinit.
  73 GDBINIT=".gdbinit"
  74 case "${host}" in
  75   *-*-msdos* | *-*-go32* | *-*-mingw32* | *-*-cygwin* | *-*-windows*)
  76     GDBINIT="gdb.ini"
  77     ;;
  78 esac
  79 AC_SUBST(GDBINIT)
  80
  81 te_file=generic
  82
  83 # Makefile target for installing gas in $(tooldir)/bin.
  84 install_tooldir=install-exec-tooldir
  85
  86 canon_targets=""
  87 all_targets=no
  88 if test -n "$enable_targets" ; then
  89   for t in `echo $enable_targets | sed 's/,/ /g'`; do
  90     if test $t = "all"; then
  91       all_targets=yes
  92       continue
  93     fi
  94     result=`$ac_config_sub $t 2>/dev/null`
  95     if test -n "$result" ; then
  96       canon_targets="$canon_targets $result"
  97 #    else
  98 #      # Permit "all", etc.  We don't support it yet though.
  99 #      canon_targets="$canon_targets $t"
 100     fi
 101   done
 102   GAS_UNIQ(canon_targets)
 103 fi
 104
 105 emulations=""
 106
 107 for this_target in $target $canon_targets ; do
 108
 109 changequote(,)dnl
 110     eval `echo $this_target | sed 's/^\([^-]*\)-\([^-]*\)-\(.*\)$/cpu=\1 vendor=\2 os=\3/'`
 111 changequote([,])dnl
 112
 113     # check for architecture variants
 114     arch=
 115     endian=
 116     case ${cpu} in
 117       alpha*)           cpu_type=alpha ;;
 118       armeb)            cpu_type=arm endian=big ;;
 119       arm*)             cpu_type=arm endian=little ;;
 120       armb*)            cpu_type=arm endian=little ;;
 121       armv*l)           cpu_type=arm endian=little ;;
 122       armv*b)           cpu_type=arm endian=big ;;
 123       xscale*)          cpu_type=arm endian=little ;;
 124       strongarm*)       cpu_type=arm endian=little ;;
 125       thumb*)           cpu_type=arm endian=little ;;
 126       hppa*)            cpu_type=hppa ;;
 127 changequote(,)dnl
 128       i[3456]86)        cpu_type=i386 arch=i386;;
 129       x86_64)           cpu_type=i386 arch=x86_64;;
 130       ia64)             cpu_type=ia64 ;;
 131       m6811|m6812|m68hc12) cpu_type=m68hc11 ;;
 132       m680[012346]0)    cpu_type=m68k ;;
 133 changequote([,])dnl
 134       m68008)           cpu_type=m68k ;;
 135       m683??)           cpu_type=m68k ;;
 136       m5200)            cpu_type=m68k ;;
 137       m8*)              cpu_type=m88k ;;
 138       mips*el)          cpu_type=mips endian=little ;;
 139       mips*)            cpu_type=mips endian=big ;;
 140       or32*)            cpu_type=or32 endian=big ;;
 141       pjl*)             cpu_type=pj endian=little ;;
 142       pj*)              cpu_type=pj endian=big ;;
 143       powerpc*le*)      cpu_type=ppc endian=little ;;
 144       powerpc*)         cpu_type=ppc endian=big ;;
 145       rs6000*)          cpu_type=ppc ;;
 146       s390x*)           cpu_type=s390 arch=s390x ;;
 147       s390*)            cpu_type=s390 arch=s390 ;;
 148       sh64*)            cpu_type=sh64 endian=big;;
 149       sh*le)            cpu_type=sh endian=little ;;
 150       sh*)              cpu_type=sh endian=big ;;
 151       sparclite*)       cpu_type=sparc arch=sparclite ;;
 152       sparclet*)        cpu_type=sparc arch=sparclet ;;
 153       sparc64*)         cpu_type=sparc arch=v9-64 ;;
 154       sparc86x*)        cpu_type=sparc arch=sparc86x  ;;
 155       sparc*)           cpu_type=sparc arch=sparclite ;; # ??? See tc-sparc.c.
 156       v850*)            cpu_type=v850 ;;
 157       *)                cpu_type=${cpu} ;;
 158     esac
 159
 160     if test ${this_target} = $target ; then
 161       target_cpu_type=${cpu_type}
 162     elif test ${target_cpu_type} != ${cpu_type} ; then
 163       continue
 164     fi
 165
 166     generic_target=${cpu_type}-$vendor-$os
 167     dev=no
 168     bfd_gas=no
 169     em=generic
 170     mips_stabs_elf=
 171
 172     # assign object format
 173     case ${generic_target} in
 174       a29k-*-coff)          fmt=coff ;;
 175       a29k-amd-udi)         fmt=coff ;;
 176       a29k-amd-ebmon)       fmt=coff ;;
 177       a29k-nyu-sym1)        fmt=coff ;;
 178       a29k-*-rtems*)        fmt=coff ;;
 179       a29k-*-vxworks*)      fmt=coff ;;
 180
 181       alpha*-*-*vms*)       fmt=evax ;;
 182       alpha*-*-netware*)    fmt=ecoff ;;
 183       alpha*-*-openbsd*)    fmt=ecoff ;;
 184       alpha*-*-osf*)        fmt=ecoff ;;
 185       alpha*-*-linuxecoff*) fmt=ecoff ;;
 186       alpha*-*-linux-gnu*)  fmt=elf em=linux ;;
 187       alpha*-*-netbsd*)     fmt=elf em=nbsd ;;
 188
 189       arc-*-elf*)           fmt=elf bfd_gas=yes ;;
 190
 191       arm-*-aout)                       fmt=aout ;;
 192       arm-*-coff | thumb-*-coff)        fmt=coff ;;
 193       arm-*-rtems | thumb-*-rtems)      fmt=elf ;;
 194       arm-*-elf | thumb-*-elf)          fmt=elf ;;
 195       arm*-*-conix*)                    fmt=elf ;;
 196       arm-*-linux*aout*)                fmt=aout em=linux ;;
 197       arm*-*-linux-gnu* | arm*-*-uclinux*)
 198                                         fmt=elf  em=linux ;;
 199       arm-*-netbsdelf*)                 fmt=elf  em=nbsd ;;
 200       arm-*-netbsd* | arm-*-openbsd*)   fmt=aout em=nbsd ;;
 201       arm-*-oabi | thumb-*-oabi)        fmt=elf ;;
 202       arm-epoc-pe | thumb-epoc-pe)      fmt=coff em=epoc-pe ;;
 203       arm-*-wince)                      fmt=coff em=wince-pe ;;
 204       arm-*-pe | thumb-*-pe)            fmt=coff em=pe ;;
 205       arm-*-riscix*)                    fmt=aout em=riscix ;;
 206       arm-*-vxworks)                    fmt=coff ;;
 207
 208       avr-*-*)              fmt=elf bfd_gas=yes ;;
 209
 210       cris-*-*)             fmt=multi bfd_gas=yes ;;
 211
 212       d10v-*-*)             fmt=elf bfd_gas=yes ;;
 213       d30v-*-*)             fmt=elf bfd_gas=yes ;;
 214       dlx-*-*)              fmt=elf ;;
 215
 216
 217       fr30-*-*)             fmt=elf bfd_gas=yes ;;
 218
 219       hppa-*-linux-gnu*)    case ${cpu} in
 220                                 hppa*64*)
 221                                         fmt=elf em=hppalinux64;;
 222                                 hppa*)
 223                                         fmt=elf em=linux;;
 224                             esac ;;
 225       hppa-*-*elf*)         fmt=elf em=hppa ;;
 226       hppa-*-lites*)        fmt=elf em=hppa ;;
 227       hppa-*-netbsd*)       fmt=elf em=nbsd ;;
 228       hppa-*-osf*)          fmt=som em=hppa ;;
 229       hppa-*-rtems*)        fmt=elf em=hppa ;;
 230       hppa-*-hpux11*)       case ${cpu} in
 231                                 hppa*64*)
 232                                         fmt=elf em=hppa64 ;;
 233                                 hppa*)
 234                                         fmt=som em=hppa ;;
 235                             esac ;;
 236       hppa-*-hpux*)         fmt=som em=hppa ;;
 237       hppa-*-mpeix*)        fmt=som em=hppa ;;
 238       hppa-*-bsd*)          fmt=som em=hppa ;;
 239       hppa-*-hiux*)         fmt=som em=hppa ;;
 240
 241       h8300-*-rtems*)       fmt=coff ;;
 242       h8300-*-coff)         fmt=coff ;;
 243       h8300-*-elf)          fmt=elf ;;
 244       h8500-*-rtems*)       fmt=coff ;;
 245       h8500-*-coff)         fmt=coff ;;
 246
 247       i370-*-elf* | i370-*-linux*) fmt=elf ;;
 248       i386-ibm-aix*)        fmt=coff em=i386aix ;;
 249       i386-sequent-bsd*)    fmt=aout em=dynix bfd_gas=yes ;;
 250       i386-*-beospe*)       fmt=coff em=pe bfd_gas=yes ;;
 251       i386-*-beoself* | i386-*-beos*) fmt=elf bfd_gas=yes ;;
 252       i386-*-bsd*)          fmt=aout em=386bsd ;;
 253       i386-*-netbsd0.8)     fmt=aout em=386bsd ;;
 254       i386-*-netbsdpe*)       fmt=coff em=pe bfd_gas=yes ;;
 255       i386-*-netbsd*)       em=nbsd bfd_gas=yes
 256                             case ${cpu} in
 257                               x86_64)   fmt=elf ;;
 258                               *)        case ${os} in
 259                                           *elf*) fmt=elf ;;
 260                                           *)     fmt=aout ;;
 261                                         esac
 262                                         ;;
 263                             esac
 264                             ;;
 265       i386-*-openbsd*)      fmt=aout em=nbsd bfd_gas=yes;;
 266       i386-*-linux*aout* | i386-*-linux*oldld)   fmt=aout em=linux ;;
 267       i386-*-linux*coff*)   fmt=coff em=linux ;;
 268       i386-*-linux-gnu*)    fmt=elf em=linux bfd_gas=yes ;;
 269       x86_64-*-linux-gnu*)  fmt=elf em=linux bfd_gas=yes ;;
 270       i386-*-lynxos*)       fmt=coff em=lynx ;;
 271 changequote(,)dnl
 272       i386-*-sysv[45]* | i386-*-solaris* | i386-*-elf)
 273                             fmt=elf bfd_gas=yes ;;
 274       i386-*-freebsdaout* | i386-*-freebsd[12].* | i386-*-freebsd[12])
 275                             fmt=aout em=386bsd ;;
 276 changequote([,])dnl
 277       i386-*-coff | i386-*-sysv* | i386-*-sco3.2v5*coff | i386-*-isc*)
 278                           fmt=coff ;;
 279       i386-*-sco3.2v5*)      fmt=elf
 280                             if test ${this_target} = $target; then
 281                                 AC_DEFINE(SCO_ELF, 1,
 282                                     [Define if defaulting to ELF on SCO 5.])
 283                             fi
 284                             ;;
 285       i386-*-sco3.2*)       fmt=coff ;;
 286       i386-*-vsta)          fmt=aout ;;
 287       i386-*-msdosdjgpp* | i386-*-go32* | i386-go32-rtems*)
 288                             fmt=coff em=go32 bfd_gas=yes
 289                             AC_DEFINE(STRICTCOFF, 1, [Using strict COFF?])
 290                             ;;
 291       i386-*-rtemself*)     fmt=elf ;;
 292       i386-*-rtemscoff*)    fmt=coff ;;
 293       i386-*-rtems*)        fmt=elf ;;
 294       i386-*-gnu*)          fmt=elf ;;
 295       i386-*-mach*)
 296                             fmt=aout em=mach bfd_gas=yes ;;
 297       i386-*-msdos*)        fmt=aout ;;
 298       i386-*-moss*)         fmt=elf ;;
 299       i386-*-pe)            fmt=coff em=pe bfd_gas=yes ;;
 300       i386-*-cygwin*)       fmt=coff em=pe bfd_gas=yes ;;
 301       i386-*-interix*)      fmt=coff em=interix bfd_gas=yes ;;
 302       i386-*-mingw32*)      fmt=coff em=pe bfd_gas=yes ;;
 303       i386-*-*nt*)          fmt=coff em=pe bfd_gas=yes ;;
 304       i386-*-vxworks*)      fmt=aout ;;
 305       i386-*-chaos)         fmt=elf ;;
 306       i860-stardent-sysv4* | i860-stardent-elf*)
 307                             fmt=elf bfd_gas=yes endian=little
 308                             AC_MSG_WARN(GAS support for ${generic_target} is preliminary and a work in progress) ;;
 309       i960-*-bout)          fmt=bout ;;
 310       i960-*-coff)          fmt=coff em=ic960 ;;
 311       i960-*-rtems*)        fmt=coff em=ic960 ;;
 312       i960-*-nindy*)        fmt=bout ;;
 313       i960-*-vxworks4*)     fmt=bout ;;
 314       i960-*-vxworks5.0)    fmt=bout ;;
 315       i960-*-vxworks5.*)    fmt=coff em=ic960 ;;
 316       i960-*-vxworks*)      fmt=bout ;;
 317       i960-*-elf*)          fmt=elf ;;
 318
 319       ia64-*-elf*)          fmt=elf ;;
 320       ia64-*-aix*)          fmt=elf em=ia64aix ;;
 321       ia64-*-linux-gnu*)    fmt=elf em=linux ;;
 322       ia64-*-hpux*)         fmt=elf em=hpux ;;
 323       ia64-*-netbsd*)       fmt=elf em=nbsd ;;
 324
 325       m32r-*-*)             fmt=elf bfd_gas=yes ;;
 326
 327       m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)fmt=elf bfd_gas=yes ;;
 328
 329       m68k-*-vxworks* | m68k-ericsson-ose | m68k-*-sunos*)
 330                             fmt=aout em=sun3 ;;
 331       m68k-motorola-sysv*)  fmt=coff em=delta ;;
 332       m68k-bull-sysv3*)     fmt=coff em=dpx2 ;;
 333       m68k-apollo-*)        fmt=coff em=apollo ;;
 334       m68k-*-sysv4*) # must be before -sysv*
 335                             fmt=elf em=svr4 ;;
 336       m68k-*-elf*)          fmt=elf ;;
 337       m68k-*-coff | m68k-*-sysv* | m68k-*-rtemscoff*)
 338                             fmt=coff ;;
 339       m68k-*-rtems*)        fmt=elf ;;
 340       m68k-*-hpux*)         fmt=hp300 em=hp300 ;;
 341       m68k-*-linux*aout*)   fmt=aout em=linux ;;
 342       m68k-*-linux-gnu*)    fmt=elf em=linux ;;
 343       m68k-*-gnu*)          fmt=elf ;;
 344       m68k-*-lynxos*)       fmt=coff em=lynx ;;
 345       m68k-*-netbsdelf*)    fmt=elf em=nbsd bfd_gas=yes ;;
 346       m68k-*-netbsdaout* | m68k-*-netbsd*)
 347                             fmt=aout em=nbsd bfd_gas=yes ;;
 348       m68k-*-openbsd*)      fmt=aout em=nbsd bfd_gas=yes ;;
 349       m68k-apple-aux*)      fmt=coff em=aux ;;
 350       m68k-*-psos*)         fmt=elf em=psos;;
 351
 352       m88k-motorola-sysv3*) fmt=coff em=delt88 ;;
 353       m88k-*-coff*)         fmt=coff ;;
 354
 355       mcore-*-elf)          fmt=elf bfd_gas=yes ;;
 356       mcore-*-pe)           fmt=coff em=pe bfd_gas=yes ;;
 357
 358       # don't change em like *-*-bsd does
 359       mips-dec-openbsd*)    fmt=elf endian=little ;;
 360       mips-dec-bsd*)        fmt=aout endian=little ;;
 361       mips-sony-bsd*)       fmt=ecoff ;;
 362       mips-*-bsd*)          AC_MSG_ERROR(Unknown vendor for mips-bsd configuration.) ;;
 363       mips-*-ultrix*)       fmt=ecoff endian=little ;;
 364       mips-*-osf*)          fmt=ecoff endian=little ;;
 365       mips-*-ecoff*)        fmt=ecoff ;;
 366       mips-*-pe*)           fmt=coff endian=little em=pe ;;
 367       mips-*-irix6*)        fmt=elf ;;
 368       mips-*-irix5*)        fmt=elf ;;
 369       mips-*-irix*)         fmt=ecoff ;;
 370       mips-*-lnews*)        fmt=ecoff em=lnews ;;
 371       mips-*-riscos*)       fmt=ecoff ;;
 372       mips*-*-linux*)       fmt=elf em=tmips mips_stabs_elf=y ;;
 373       mips-*-sysv4*MP* | mips-*-gnu*)
 374                             fmt=elf em=tmips ;;
 375       mips-*-sysv*)         fmt=ecoff ;;
 376       mips-*-elf* | mips-*-rtems* | mips-*-netbsd* | mips-*-openbsd*)
 377                             fmt=elf ;;
 378       mips-*-vxworks*)      fmt=elf mips_stabs_elf=y ;;
 379       mmix-*-*)             fmt=elf bfd_gas=yes ;;
 380       mn10200-*-*)          fmt=elf bfd_gas=yes ;;
 381       mn10300-*-*)          fmt=elf bfd_gas=yes ;;
 382       openrisc-*-*)         fmt=elf bfd_gas=yes ;;
 383       or32-*-rtems*)        fmt=coff ;;
 384       or32-*-coff)          fmt=coff ;;
 385       or32-*-elf)           fmt=elf ;;
 386       pj*)                  fmt=elf ;;
 387       ppc-*-pe | ppc-*-cygwin* | ppc-*-winnt*)
 388                             fmt=coff em=pe ;;
 389       ppc-*-aix5*)          fmt=coff em=aix5 ;;
 390       ppc-*-aix*)           fmt=coff ;;
 391       ppc-*-beos*)          fmt=coff ;;
 392       ppc-*-*bsd* | ppc-*-elf* | ppc-*-eabi* | ppc-*-sysv4*)
 393                             fmt=elf ;;
 394       ppc-*-linux-gnu*)     fmt=elf
 395                             case "$endian" in
 396                             big)  ;;
 397                             *)    AC_MSG_ERROR(GNU/Linux must be configured big endian) ;;
 398                             esac
 399                             ;;
 400       ppc-*-solaris*)       fmt=elf
 401                             if test ${this_target} = $target; then
 402                                 AC_DEFINE(TARGET_SOLARIS_COMMENT, 1,
 403                                 [Define if default target is PowerPC Solaris.])
 404                             fi
 405                             if test x${endian} = xbig; then
 406                                 AC_MSG_ERROR(Solaris must be configured little endian)
 407                             fi
 408                             ;;
 409       ppc-*-rtems*)         fmt=elf ;;
 410       ppc-*-macos* | ppc-*-mpw*)
 411                             fmt=coff em=macos ;;
 412       ppc-*-netware*)       fmt=elf em=ppcnw ;;
 413       ppc-*-vxworks*)       fmt=elf ;;
 414       ppc-*-windiss*)       fmt=elf ;;
 415
 416       s390x-*-linux-gnu*)   fmt=elf em=linux ;;
 417       s390-*-linux-gnu*)    fmt=elf em=linux ;;
 418
 419       sh*-*-linux*)         fmt=elf em=linux
 420                             case ${cpu} in
 421                                 sh*eb)
 422                                         endian=big ;;
 423                                 sh*)
 424                                         endian=little ;;
 425                             esac ;;
 426       sh*-*-netbsdelf*)     fmt=elf em=nbsd ;;
 427       sh-*-elf*)            fmt=elf ;;
 428       sh-*-coff*)           fmt=coff ;;
 429       sh-*-pe*)             fmt=coff em=pe bfd_gas=yes endian=little ;;
 430       sh-*-rtemself*)       fmt=elf ;;
 431       sh-*-rtems*)          fmt=coff ;;
 432
 433       sh64-*-elf*)          fmt=elf ;;
 434       ns32k-pc532-mach* | ns32k-pc532-ux*)    fmt=aout em=pc532mach ;;
 435       ns32k-*-netbsd* | ns32k-pc532-lites*)  fmt=aout em=nbsd532 ;;
 436       ns32k-pc532-openbsd*) fmt=aout em=nbsd532 ;;
 437
 438       sparc-*-rtemsaout*)   fmt=aout ;;
 439       sparc-*-rtemself*)    fmt=elf ;;
 440       sparc-*-rtems*)       fmt=elf ;;
 441       sparc-*-sunos4*)      fmt=aout em=sun3 ;;
 442       sparc-*-aout | sparc*-*-vxworks*)
 443                             fmt=aout em=sparcaout ;;
 444       sparc-*-coff)         fmt=coff ;;
 445       sparc-*-linux*aout*)  fmt=aout em=linux ;;
 446       sparc-*-linux-gnu*)   fmt=elf em=linux ;;
 447       sparc-*-lynxos*)      fmt=coff em=lynx ;;
 448       sparc-fujitsu-none)   fmt=aout ;;
 449       sparc-*-elf | sparc-*-sysv4* | sparc-*-solaris*)
 450                             fmt=elf ;;
 451       sparc-*-netbsd*)      em=nbsd bfd_gas=yes
 452                             case ${cpu} in
 453                                 sparc) case ${os} in
 454                                            *elf*) fmt=elf ;;
 455                                            *)     fmt=aout ;;
 456                                        esac ;;
 457                                 sparc64) fmt=elf ;;
 458                             esac
 459                             ;;
 460       sparc-*-openbsd*)     fmt=aout em=nbsd ;;
 461
 462       strongarm-*-coff)     fmt=coff ;;
 463       strongarm-*-elf)      fmt=elf ;;
 464       xscale-*-coff)     fmt=coff ;;
 465       xscale-*-elf)      fmt=elf ;;
 466
 467       tic30-*-*aout*)       fmt=aout bfd_gas=yes ;;
 468       tic30-*-*coff*)       fmt=coff bfd_gas=yes ;;
 469       tic54x-*-* | c54x*-*-*)
 470                             fmt=coff bfd_gas=yes need_libm=yes;;
 471       tic80-*-*)            fmt=coff ;;
 472
 473       v850-*-*)             fmt=elf bfd_gas=yes ;;
 474       v850e-*-*)            fmt=elf bfd_gas=yes ;;
 475       v850ea-*-*)           fmt=elf bfd_gas=yes ;;
 476
 477       vax-*-bsd* | vax-*-ultrix*)
 478                             fmt=aout ;;
 479       vax-*-vms)            fmt=vms ;;
 480
 481       w65-*-*)              fmt=coff ;;
 482
 483       xstormy16-*-*)        fmt=elf bfd_gas=yes ;;
 484
 485       z8k-*-coff | z8k-*-sim)
 486                             fmt=coff ;;
 487
 488       *-*-aout | *-*-scout)
 489                             fmt=aout ;;
 490       *-*-freebsd*)         fmt=elf em=freebsd bfd_gas=yes ;;
 491       *-*-nindy*)
 492                             fmt=bout ;;
 493       *-*-bsd*)
 494                             fmt=aout em=sun3 ;;
 495       *-*-generic)          fmt=generic ;;
 496       *-*-xray | *-*-hms)   fmt=coff ;;
 497       *-*-sim)              fmt=coff ;;
 498       *-*-elf | *-*-sysv4* | *-*-solaris*)
 499                             AC_MSG_WARN(GAS support for ${generic_target} is incomplete.)
 500                             fmt=elf dev=yes ;;
 501       *-*-vxworks)          fmt=aout ;;
 502       *-*-netware)          fmt=elf ;;
 503     esac
 504
 505     if test ${this_target} = $target ; then
 506       endian_def=
 507       if test x${endian} = xbig; then
 508         endian_def=1
 509       elif test x${endian} = xlittle; then
 510         endian_def=0
 511       fi
 512       if test x${endian_def} != x; then
 513         AC_DEFINE_UNQUOTED(TARGET_BYTES_BIG_ENDIAN, $endian_def,
 514                            [Define as 1 if big endian.])
 515       fi
 516     fi
 517
 518     if test x${mips_stabs_elf} != x; then
 519       AC_DEFINE(MIPS_STABS_ELF, 1,
 520                 [Use ELF stabs for MIPS, not ECOFF stabs])
 521     fi
 522
 523     case ${cpu_type}-${fmt} in
 524       alpha*-*) bfd_gas=yes ;;
 525       arm-*)    bfd_gas=yes ;;
 526     # not yet
 527     # i386-aout)        bfd_gas=preferred ;;
 528       ia64*-*)  bfd_gas=yes ;;
 529       mips-*)   bfd_gas=yes ;;
 530       ns32k-*)  bfd_gas=yes ;;
 531       pdp11-*)  bfd_gas=yes ;;
 532       ppc-*)    bfd_gas=yes ;;
 533       sparc-*)  bfd_gas=yes ;;
 534       strongarm-*)      bfd_gas=yes ;;
 535       xscale-*) bfd_gas=yes ;;
 536       *-elf)    bfd_gas=yes ;;
 537       *-ecoff)  bfd_gas=yes ;;
 538       *-som)    bfd_gas=yes ;;
 539     #enable bfd for coff and aout to allow testing if a bfd target is
 540     #the primary target, but not for coff or aout as the primary target
 541       i386-coff)        if test x${primary_bfd_gas} = xyes; then bfd_gas=yes; fi ;;
 542       i386-aout)        if test x${primary_bfd_gas} = xyes; then bfd_gas=yes; fi ;;
 543       *)                ;;
 544     esac
 545
 546 # Other random stuff.
 547
 548     # Do we need the opcodes library?
 549     case ${cpu_type} in
 550       vax | i386 | tic30)
 551         ;;
 552
 553       *)
 554         need_opcodes=yes
 555
 556         case "${enable_shared}" in
 557         yes) shared_opcodes=true ;;
 558         *opcodes*) shared_opcodes=true ;;
 559         *) shared_opcodes=false ;;
 560         esac
 561         if test "${shared_opcodes}" = "true"; then
 562           # A shared libopcodes must be linked against libbfd.
 563           need_bfd=yes
 564         fi
 565         ;;
 566     esac
 567
 568     # Any other special object files needed ?
 569     case ${cpu_type} in
 570       fr30 | m32r | openrisc)
 571         using_cgen=yes
 572         ;;
 573
 574       m68k)
 575         case ${extra_objects} in
 576         *m68k-parse.o*) ;;
 577         *) extra_objects="$extra_objects m68k-parse.o" ;;
 578         esac
 579         ;;
 580
 581       mips)
 582         echo ${extra_objects} | grep -s "itbl-parse.o"
 583         if test $? -ne 0 ; then
 584           extra_objects="$extra_objects itbl-parse.o"
 585         fi
 586
 587         echo ${extra_objects} | grep -s "itbl-lex.o"
 588         if test $? -ne 0 ; then
 589           extra_objects="$extra_objects itbl-lex.o"
 590         fi
 591
 592         echo ${extra_objects} | grep -s "itbl-ops.o"
 593         if test $? -ne 0 ; then
 594           extra_objects="$extra_objects itbl-ops.o"
 595         fi
 596         ;;
 597
 598       i386 | s390 | sparc)
 599         if test $this_target = $target ; then
 600           AC_DEFINE_UNQUOTED(DEFAULT_ARCH, "${arch}", [Default architecture.])
 601         fi
 602         ;;
 603
 604       xstormy16)
 605         using_cgen=yes
 606         ;;
 607
 608       *)
 609         ;;
 610     esac
 611
 612     if test $using_cgen = yes ; then
 613         case "x${extra_objects}" in
 614         *cgen.o*) ;;
 615         *) extra_objects="$extra_objects cgen.o" ;;
 616         esac
 617     fi
 618
 619 # See if we really can support this configuration with the emulation code.
 620
 621     if test $this_target = $target ; then
 622       primary_bfd_gas=$bfd_gas
 623       obj_format=$fmt
 624       te_file=$em
 625
 626       if test $bfd_gas = no ; then
 627         # Can't support other configurations this way.
 628         break
 629       fi
 630     elif test $bfd_gas = no ; then
 631       # Can't support this configuration.
 632       break
 633     fi
 634
 635 # From target name and format, produce a list of supported emulations.
 636
 637     case ${generic_target}-${fmt} in
 638       mips-*-irix5*-*)  emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 639       mips*-*-linux*-*) case "$endian" in
 640                         big)    emulation="mipsbelf mipslelf mipself" ;;
 641                         *)      emulation="mipslelf mipsbelf mipself" ;;
 642                         esac ;;
 643       mips-*-lnews*-ecoff) ;;
 644       mips-*-*-ecoff)   case "$endian" in
 645                         big)    emulation="mipsbecoff mipslecoff mipsecoff" ;;
 646                         *)      emulation="mipslecoff mipsbecoff mipsecoff" ;;
 647                         esac ;;
 648       mips-*-*-elf)     case "$endian" in
 649                         big)    emulation="mipsbelf mipslelf mipself" ;;
 650                         *)      emulation="mipslelf mipsbelf mipself" ;;
 651                         esac ;;
 652       mips-*-sysv4*MP*-*) emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 653       # i386-pc-pe-coff != i386-pc-coff.
 654       i386-*-pe-coff)   ;;
 655       # Uncommenting the next line will turn on support for i386 AOUT
 656       # for the default linux configuration
 657       # i386-*-linux*-elf) emulation="i386elf i386aout" ;;
 658       #
 659       i386-*-aout)      emulation="i386aout" ;;
 660       i386-*-coff)      emulation="i386coff" ;;
 661       i386-*-elf)       emulation="i386elf" ;;
 662
 663       # Always all formats.  The first stated emulation becomes the default.
 664       cris-*-*aout*)    emulation="crisaout criself" ;;
 665       cris-*-*)         emulation="criself crisaout" ;;
 666     esac
 667
 668     emulations="$emulations $emulation"
 669
 670 done
 671
 672 # Turn on all targets if possible
 673 if test ${all_targets} = "yes"; then
 674   case ${target_cpu_type} in
 675   i386)
 676     case ${obj_format} in
 677     aout)
 678       emulations="$emulations i386coff i386elf"
 679       ;;
 680     coff)
 681       emulations="$emulations i386aout i386elf"
 682     ;;
 683     elf)
 684       emulations="$emulations i386aout i386coff"
 685       ;;
 686     esac
 687   ;;
 688   esac
 689 fi
 690
 691 # Assign floating point type.  Most processors with FP support
 692 # IEEE FP.  On those that don't support FP at all, usually IEEE
 693 # is emulated.
 694 case ${target_cpu} in
 695   vax | tahoe ) atof=${target_cpu} ;;
 696   pdp11)        atof=vax ;;
 697   *)            atof=ieee ;;
 698 esac
 699
 700 case "${obj_format}" in
 701   "") AC_MSG_ERROR(GAS does not know what format to use for target ${target}) ;;
 702 esac
 703
 704 # Unfortunately the cpu in cpu-opc.h file isn't always $(TARGET_CPU).
 705 cgen_cpu_prefix=""
 706 if test $using_cgen = yes ; then
 707   case ${target_cpu} in
 708     *) cgen_cpu_prefix=${target_cpu} ;;
 709   esac
 710   AC_SUBST(cgen_cpu_prefix)
 711   AC_DEFINE(USING_CGEN, 1, [Using cgen code?])
 712 fi
 713
 714 dnl
 715 dnl Make sure the desired support files exist.
 716 dnl
 717
 718 if test ! -r ${srcdir}/config/tc-${target_cpu_type}.c; then
 719   AC_MSG_ERROR(GAS does not support target CPU ${target_cpu_type})
 720 fi
 721
 722 if test ! -r ${srcdir}/config/obj-${obj_format}.c; then
 723   AC_MSG_ERROR(GAS does not have support for object file format ${obj_format})
 724 fi
 725
 726 case ${user_bfd_gas}-${primary_bfd_gas} in
 727   yes-yes | no-no)
 728     # We didn't override user's choice.
 729     ;;
 730   no-yes)
 731     AC_MSG_WARN(Use of BFD is required for ${target}; overriding config options.)
 732     ;;
 733   no-preferred)
 734     primary_bfd_gas=no
 735     ;;
 736   *-preferred)
 737     primary_bfd_gas=yes
 738     ;;
 739   yes-*)
 740     primary_bfd_gas=yes
 741     ;;
 742   -*)
 743     # User specified nothing.
 744     ;;
 745 esac
 746
 747 # Some COFF configurations want these random other flags set.
 748 case ${obj_format} in
 749   coff)
 750     case ${target_cpu_type} in
 751       i386) AC_DEFINE(I386COFF, 1, [Using i386 COFF?]) ;;
 752       m68k) AC_DEFINE(M68KCOFF, 1, [Using m68k COFF?]) ;;
 753       m88k) AC_DEFINE(M88KCOFF, 1, [Using m88k COFF?]) ;;
 754     esac
 755     ;;
 756 esac
 757
 758 # Getting this done right is going to be a bitch.  Each configuration specified
 759 # with --enable-targets=... should be checked for environment, format, cpu, and
 760 # bfd_gas setting.
 761 #
 762 # For each configuration, the necessary object file support code must be linked
 763 # in.  This might be only one, it might be up to four.  The necessary emulation
 764 # code needs to be provided, too.
 765 #
 766 # And then there's "--enable-targets=all"....
 767 #
 768 # For now, just always do it for MIPS ELF or ECOFF configurations.  Sigh.
 769
 770 formats="${obj_format}"
 771 emfiles=""
 772 EMULATIONS=""
 773 GAS_UNIQ(emulations)
 774 for em in . $emulations ; do
 775   case $em in
 776     .)  continue ;;
 777     mipsbelf | mipslelf | mipself)
 778         fmt=elf   file=mipself ;;
 779     mipsbecoff | mipslecoff | mipsecoff)
 780         fmt=ecoff file=mipsecoff ;;
 781     *coff)
 782         fmt=coff  file=$em ;;
 783     *aout)
 784         fmt=aout file=$em ;;
 785     *elf)
 786         fmt=elf file=$em ;;
 787   esac
 788   formats="$formats $fmt"
 789   emfiles="$emfiles e-$file.o"
 790   EMULATIONS="$EMULATIONS &$em,"
 791 done
 792 GAS_UNIQ(formats)
 793 GAS_UNIQ(emfiles)
 794 if test `set . $formats ; shift ; echo $#` -gt 1 ; then
 795   for fmt in $formats ; do
 796     case $fmt in
 797       aout)     AC_DEFINE(OBJ_MAYBE_AOUT, 1,    [a.out support?])   ;;
 798       bout)     AC_DEFINE(OBJ_MAYBE_BOUT, 1,    [b.out support?])   ;;
 799       coff)     AC_DEFINE(OBJ_MAYBE_COFF, 1,    [COFF support?])    ;;
 800       ecoff)    AC_DEFINE(OBJ_MAYBE_ECOFF, 1,   [ECOFF support?])   ;;
 801       elf)      AC_DEFINE(OBJ_MAYBE_ELF, 1,     [ELF support?])     ;;
 802       generic)  AC_DEFINE(OBJ_MAYBE_GENERIC, 1, [generic support?]) ;;
 803       hp300)    AC_DEFINE(OBJ_MAYBE_HP300, 1,   [HP300 support?])   ;;
 804       ieee)     AC_DEFINE(OBJ_MAYBE_IEEE, 1,    [IEEE support?])    ;;
 805       som)      AC_DEFINE(OBJ_MAYBE_SOM, 1,     [SOM support?])     ;;
 806       vms)      AC_DEFINE(OBJ_MAYBE_VMS, 1,     [VMS support?])     ;;
 807     esac
 808     extra_objects="$extra_objects obj-$fmt.o"
 809   done
 810   obj_format=multi
 811 fi
 812 if test `set . $emfiles ; shift ; echo $#` -gt 0 ; then
 813   DEFAULT_EMULATION=`set . $emulations ; echo $2`
 814   # e-mips* has more than one emulation per file, e-i386* has just one at the
 815   # moment.  If only one emulation is specified, then don't define
 816   # USE_EMULATIONS or include any of the e-files as they will only be bloat.
 817   case "${obj_format}${emfiles}" in
 818     multi* | *mips*)
 819       extra_objects="$extra_objects $emfiles"
 820       AC_DEFINE(USE_EMULATIONS, 1, [Use emulation support?]) ;;
 821   esac
 822 fi
 823 AC_SUBST(extra_objects)
 824 AC_DEFINE_UNQUOTED(EMULATIONS, $EMULATIONS, [Supported emulations.])
 825 AC_DEFINE_UNQUOTED(DEFAULT_EMULATION, "$DEFAULT_EMULATION",
 826                    [Default emulation.])
 827
 828 case ${primary_bfd_gas}-${target_cpu_type}-${obj_format} in
 829   yes-*-coff)   need_bfd=yes ;;
 830   no-*-coff)    need_bfd=yes
 831                 AC_DEFINE(MANY_SEGMENTS, 1, [old COFF support?]) ;;
 832 esac
 833
 834 reject_dev_configs=yes
 835
 836 case ${reject_dev_configs}-${dev} in
 837   yes-yes) # Oops.
 838     AC_MSG_ERROR(GAS does not support the ${generic_target} configuration.)
 839     ;;
 840 esac
 841
 842 AC_SUBST(target_cpu_type)
 843 AC_SUBST(obj_format)
 844 AC_SUBST(te_file)
 845 AC_SUBST(install_tooldir)
 846 AC_SUBST(atof)
 847 dnl AC_SUBST(emulation)
 848
 849 case "${primary_bfd_gas}" in
 850   yes)  AC_DEFINE(BFD_ASSEMBLER, 1, [Use BFD interface?])
 851         need_bfd=yes ;;
 852 esac
 853
 854 # do we need the opcodes library?
 855 case "${need_opcodes}" in
 856 yes)
 857   OPCODES_LIB=../opcodes/libopcodes.la
 858   ;;
 859 esac
 860
 861 case "${need_bfd}" in
 862 yes)
 863   BFDLIB=../bfd/libbfd.la
 864   ALL_OBJ_DEPS="$ALL_OBJ_DEPS"' ../bfd/bfd.h $(INCDIR)/symcat.h'
 865   ;;
 866 esac
 867
 868 AC_SUBST(BFDLIB)
 869 AC_SUBST(OPCODES_LIB)
 870
 871 AC_SUBST(ALL_OBJ_DEPS)
 872
 873 AC_DEFINE_UNQUOTED(TARGET_ALIAS,        "${target_alias}", [Target alias.])
 874 AC_DEFINE_UNQUOTED(TARGET_CANONICAL,    "${target}",       [Canonical target.])
 875 AC_DEFINE_UNQUOTED(TARGET_CPU,          "${target_cpu}",   [Target CPU.])
 876 AC_DEFINE_UNQUOTED(TARGET_VENDOR,       "${target_vendor}", [Target vendor.])
 877 AC_DEFINE_UNQUOTED(TARGET_OS,           "${target_os}",    [Target OS.])
 878
 879 AC_PROG_CC
 880
 881 AC_PROG_YACC
 882 AM_PROG_LEX
 883
 884 ALL_LINGUAS="fr tr es"
 885 CY_GNU_GETTEXT
 886
 887 AM_MAINTAINER_MODE
 888 AC_EXEEXT
 889
 890 AC_CHECK_HEADERS(string.h stdlib.h memory.h strings.h unistd.h stdarg.h varargs.h errno.h sys/types.h)
 891
 892 # Put this here so that autoconf's "cross-compiling" message doesn't confuse
 893 # people who are not cross-compiling but are compiling cross-assemblers.
 894 AC_MSG_CHECKING(whether compiling a cross-assembler)
 895 if test "${host}" = "${target}"; then
 896   cross_gas=no
 897 else
 898   cross_gas=yes
 899   AC_DEFINE(CROSS_COMPILE, 1, [Compiling cross-assembler?])
 900 fi
 901 AC_MSG_RESULT($cross_gas)
 902
 903 dnl ansidecl.h will deal with const
 904 dnl AC_CONST
 905 AC_FUNC_ALLOCA
 906 AC_C_INLINE
 907
 908 # VMS doesn't have unlink.
 909 AC_CHECK_FUNCS(unlink remove, break)
 910
 911 # Some systems don't have sbrk().
 912 AC_CHECK_FUNCS(sbrk)
 913
 914 # do we need the math library?
 915 case "${need_libm}" in
 916 yes)
 917   AC_CHECK_LIBM
 918   AC_SUBST(LIBM)
 919   ;;
 920 esac
 921
 922 # Some non-ANSI preprocessors botch requoting inside strings.  That's bad
 923 # enough, but on some of those systems, the assert macro relies on requoting
 924 # working properly!
 925 GAS_WORKING_ASSERT
 926
 927 # On some systems, the system header files may not declare malloc, realloc,
 928 # and free.  There are places where gas needs these functions to have been
 929 # declared -- such as when taking their addresses.
 930 gas_test_headers="
 931 #ifdef HAVE_MEMORY_H
 932 #include <memory.h>
 933 #endif
 934 #ifdef HAVE_STRING_H
 935 #include <string.h>
 936 #else
 937 #ifdef HAVE_STRINGS_H
 938 #include <strings.h>
 939 #endif
 940 #endif
 941 #ifdef HAVE_STDLIB_H
 942 #include <stdlib.h>
 943 #endif
 944 #ifdef HAVE_UNISTD_H
 945 #include <unistd.h>
 946 #endif
 947 "
 948 GAS_CHECK_DECL_NEEDED(strstr, f, char *(*f)(), $gas_test_headers)
 949 GAS_CHECK_DECL_NEEDED(malloc, f, char *(*f)(), $gas_test_headers)
 950 GAS_CHECK_DECL_NEEDED(free, f, void (*f)(), $gas_test_headers)
 951 GAS_CHECK_DECL_NEEDED(sbrk, f, char *(*f)(), $gas_test_headers)
 952 GAS_CHECK_DECL_NEEDED(environ, f, char **f, $gas_test_headers)
 953
 954 # Does errno.h declare errno, or do we have to add a separate declaration
 955 # for it?
 956 GAS_CHECK_DECL_NEEDED(errno, f, int f, [
 957 #ifdef HAVE_ERRNO_H
 958 #include <errno.h>
 959 #endif
 960 ])
 961
 962 dnl This must come last.
 963
 964 dnl We used to make symlinks to files in the source directory, but now
 965 dnl we just use the right name for .c files, and create .h files in
 966 dnl the build directory which include the right .h file.  Make sure
 967 dnl the old symlinks don't exist, so that a reconfigure in an existing
 968 dnl directory behaves reasonably.
 969
 970 AC_OUTPUT(Makefile doc/Makefile ${GDBINIT}:gdbinit.in po/Makefile.in:po/Make-in,
 971 [rm -f targ-cpu.c targ-cpu.h obj-format.h obj-format.c targ-env.h atof-targ.c itbl-cpu.h
 972  echo '#include "tc-'"${target_cpu_type}"'.h"' > targ-cpu.h
 973  echo '#include "obj-'"${obj_format}"'.h"' > obj-format.h
 974  echo '#include "te-'"${te_file}"'.h"' > targ-env.h
 975  echo '#include "itbl-'"${target_cpu_type}"'.h"' > itbl-cpu.h
 976  if test "x$cgen_cpu_prefix" != x ; then
 977    echo '#include "opcodes/'"${cgen_cpu_prefix}"'-desc.h"' > cgen-desc.h
 978  fi
 979
 980  sed -e '/POTFILES =/r po/POTFILES' po/Makefile.in > po/Makefile],
 981 [target_cpu_type=${target_cpu_type}
 982  cgen_cpu_prefix=${cgen_cpu_prefix}
 983  obj_format=${obj_format}
 984  te_file=${te_file}])