ld/configure.in

   1 dnl Process this file with autoconf to produce a configure script
   2 dnl
   3 AC_PREREQ(2.57)
   4 AC_INIT(ldmain.c)
   5
   6 AC_CANONICAL_SYSTEM
   7 AC_ISC_POSIX
   8
   9 changequote(,)dnl
  10 BFD_VERSION=`sed -n -e 's/^.._INIT_AUTOMAKE.*,[         ]*\([^  ]*\)[   ]*).*/\1/p' < ${srcdir}/../bfd/configure.in`
  11 changequote([,])dnl
  12 AM_INIT_AUTOMAKE(ld, ${BFD_VERSION})
  13
  14 AM_PROG_LIBTOOL
  15
  16 AC_ARG_WITH(lib-path, [  --with-lib-path=dir1:dir2...  set default LIB_PATH],LIB_PATH=$withval)
  17 AC_ARG_ENABLE(targets,
  18 [  --enable-targets        alternative target configurations],
  19 [case "${enableval}" in
  20   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  21             ;;
  22   no)       enable_targets= ;;
  23   *)        enable_targets=$enableval ;;
  24 esac])dnl
  25 AC_ARG_ENABLE(64-bit-bfd,
  26 [  --enable-64-bit-bfd     64-bit support (on hosts with narrower word sizes)],
  27 [case "${enableval}" in
  28   yes)  want64=true  ;;
  29   no)   want64=false ;;
  30   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
  31 esac],[want64=false])dnl
  32
  33 AC_ARG_WITH(sysroot,
  34 [  --with-sysroot[=DIR] Search for usr/lib et al within DIR.],
  35 [
  36  case ${with_sysroot} in
  37  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
  38  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
  39  esac
  40
  41  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
  42  use_sysroot=yes
  43
  44  if test "x$exec_prefix" = xNONE; then
  45   if test "x$prefix" = xNONE; then
  46    test_prefix=/usr/local
  47   else
  48    test_prefix=$prefix
  49   fi
  50  else
  51   test_prefix=$exec_prefix
  52  fi
  53  case ${TARGET_SYSTEM_ROOT} in
  54  "${test_prefix}"|"${test_prefix}/"*|\
  55  '${exec_prefix}'|'${exec_prefix}/'*)
  56    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
  57    TARGET_SYSTEM_ROOT_DEFINE="$t"
  58    ;;
  59  esac
  60 ], [
  61  use_sysroot=no
  62  TARGET_SYSTEM_ROOT=
  63  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"'
  64 ])
  65 AC_SUBST(use_sysroot)
  66 AC_SUBST(TARGET_SYSTEM_ROOT)
  67 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
  68
  69 # The location to which bugs should be reported.
  70 AC_ARG_WITH(bugurl,
  71   AS_HELP_STRING([--with-bugurl=URL],
  72                  [Direct users to URL to report a bug]),
  73   [case "$withval" in
  74     yes) AC_MSG_ERROR([bug URL not specified]) ;;
  75     no)  REPORT_BUGS_TO="" ;;
  76     *)   REPORT_BUGS_TO="<URL:$withval>" ;;
  77    esac],
  78    REPORT_BUGS_TO="<URL:http://www.sourceware.org/bugzilla/>"
  79 )
  80 AC_SUBST(REPORT_BUGS_TO)
  81
  82 AM_BINUTILS_WARNINGS
  83
  84 AM_CONFIG_HEADER(config.h:config.in)
  85
  86 if test -z "$target" ; then
  87     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
  88 fi
  89 if test -z "$host" ; then
  90     AC_MSG_ERROR(Unrecognized host system type; please check config.sub.)
  91 fi
  92
  93 # host-specific stuff:
  94
  95 AC_PROG_CC
  96 AC_PROG_INSTALL
  97
  98 ALL_LINGUAS="fr sv tr es da vi zh_CN zh_TW ga"
  99 ZW_GNU_GETTEXT_SISTER_DIR
 100 AM_PO_SUBDIRS
 101
 102 AC_EXEEXT
 103
 104 AC_PROG_YACC
 105 AM_PROG_LEX
 106
 107 AM_MAINTAINER_MODE
 108 AM_CONDITIONAL(GENINSRC_NEVER, false)
 109
 110 . ${srcdir}/configure.host
 111
 112 AC_SUBST(HDEFINES)
 113 AC_SUBST(HOSTING_CRT0)
 114 AC_SUBST(HOSTING_LIBS)
 115 AC_SUBST(NATIVE_LIB_DIRS)
 116
 117 AC_CHECK_HEADERS(string.h strings.h stdlib.h unistd.h elf-hints.h limits.h sys/param.h)
 118 AC_CHECK_FUNCS(sbrk realpath glob)
 119 AC_HEADER_DIRENT
 120
 121 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
 122 AC_CACHE_VAL(ld_cv_decl_getopt_unistd_h,
 123 [AC_TRY_COMPILE([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);],
 124 ld_cv_decl_getopt_unistd_h=yes, ld_cv_decl_getopt_unistd_h=no)])
 125 AC_MSG_RESULT($ld_cv_decl_getopt_unistd_h)
 126 if test $ld_cv_decl_getopt_unistd_h = yes; then
 127   AC_DEFINE([HAVE_DECL_GETOPT], 1,
 128             [Is the prototype for getopt in <unistd.h> in the expected format?])
 129 fi
 130
 131 BFD_BINARY_FOPEN
 132
 133 AC_CHECK_DECLS([strstr, free, sbrk, getenv, environ])
 134
 135 # When converting linker scripts into strings for use in emulation
 136 # files, use astring.sed if the compiler supports ANSI string
 137 # concatenation, or ostring.sed otherwise.  This is to support the
 138 # broken Microsoft MSVC compiler, which limits the length of string
 139 # constants, while still supporting pre-ANSI compilers which do not
 140 # support string concatenation.
 141 AC_MSG_CHECKING([whether ANSI C string concatenation works])
 142 AC_CACHE_VAL(ld_cv_string_concatenation,
 143 [AC_TRY_COMPILE(,[char *a = "a" "a";],
 144   [ld_cv_string_concatenation=yes],
 145   [ld_cv_string_concatenation=no])])
 146 AC_MSG_RESULT($ld_cv_string_concatenation)
 147 if test "$ld_cv_string_concatenation" = "yes"; then
 148   STRINGIFY=astring.sed
 149 else
 150   STRINGIFY=ostring.sed
 151 fi
 152 AC_SUBST(STRINGIFY)
 153
 154 # target-specific stuff:
 155
 156 all_targets=
 157 EMUL=
 158 all_emuls=
 159 all_emul_extras=
 160 all_libpath=
 161
 162 dnl We need to get an arbitrary number of tdir definitions into
 163 dnl Makefile.  We can't do it using AC_SUBST, because autoconf does
 164 dnl not permit literal newlines in an AC_SUBST variables.  So we use a
 165 dnl file.
 166 rm -f tdirs
 167
 168 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 169 do
 170   if test "$targ_alias" = "all"; then
 171     all_targets=true
 172   else
 173     # Canonicalize the secondary target names.
 174     result=`$ac_config_sub $targ_alias 2>/dev/null`
 175     if test -n "$result"; then
 176         targ=$result
 177     else
 178         targ=$targ_alias
 179     fi
 180
 181     . ${srcdir}/configure.tgt
 182
 183     if test "$targ" = "$target"; then
 184       EMUL=$targ_emul
 185     fi
 186
 187     if test x${want64} = xfalse; then
 188       . ${srcdir}/../bfd/config.bfd
 189     fi
 190
 191     if test x${want64} = xtrue; then
 192       targ_extra_emuls="$targ_extra_emuls $targ64_extra_emuls"
 193       targ_extra_libpath="$targ_extra_libpath $targ64_extra_libpath"
 194     fi
 195
 196     for i in $targ_emul $targ_extra_emuls $targ_extra_libpath; do
 197         case " $all_emuls " in
 198         *" e${i}.o "*) ;;
 199         *)
 200           all_emuls="$all_emuls e${i}.o"
 201           eval result=\$tdir_$i
 202           test -z "$result" && result=$targ_alias
 203           echo tdir_$i=$result >> tdirs
 204           ;;
 205         esac
 206     done
 207
 208     for i in $targ_emul $targ_extra_libpath; do
 209         case " $all_libpath " in
 210         *" ${i} "*) ;;
 211         *)
 212           if test -z "$all_libpath"; then
 213             all_libpath=${i}
 214           else
 215             all_libpath="$all_libpath ${i}"
 216           fi
 217           ;;
 218         esac
 219     done
 220
 221     for i in $targ_extra_ofiles; do
 222         case " $all_emul_extras " in
 223         *" ${i} "*) ;;
 224         *)
 225           all_emul_extras="$all_emul_extras ${i}"
 226           ;;
 227         esac
 228     done
 229   fi
 230 done
 231
 232 AC_SUBST(EMUL)
 233
 234 TDIRS=tdirs
 235 AC_SUBST_FILE(TDIRS)
 236
 237 if test x${all_targets} = xtrue; then
 238   if test x${want64} = xfalse; then
 239     AC_CHECK_SIZEOF(long)
 240     if test "x${ac_cv_sizeof_long}" = "x8"; then
 241       want64=true
 242     fi
 243   fi
 244   if test x${want64} = xtrue; then
 245     EMULATION_OFILES='$(ALL_EMULATIONS) $(ALL_64_EMULATIONS)'
 246   else
 247     EMULATION_OFILES='$(ALL_EMULATIONS)'
 248   fi
 249   EMUL_EXTRA_OFILES='$(ALL_EMUL_EXTRA_OFILES)'
 250 else
 251   EMULATION_OFILES=$all_emuls
 252   EMUL_EXTRA_OFILES=$all_emul_extras
 253 fi
 254 AC_SUBST(EMULATION_OFILES)
 255 AC_SUBST(EMUL_EXTRA_OFILES)
 256 AC_SUBST(LIB_PATH)
 257
 258 EMULATION_LIBPATH=$all_libpath
 259 AC_SUBST(EMULATION_LIBPATH)
 260
 261 if test x${enable_static} = xno; then
 262   TESTBFDLIB="--rpath ../bfd/.libs ../bfd/.libs/libbfd.so"
 263 else
 264   TESTBFDLIB="../bfd/.libs/libbfd.a"
 265 fi
 266 AC_SUBST(TESTBFDLIB)
 267
 268 target_vendor=${target_vendor=$host_vendor}
 269 case "$target_vendor" in
 270   hp) EXTRA_SHLIB_EXTENSION=".sl" ;;
 271   *)  EXTRA_SHLIB_EXTENSION= ;;
 272 esac
 273
 274 case "$target_os" in
 275   lynxos) EXTRA_SHLIB_EXTENSION=".a" ;;
 276 esac
 277
 278 if test x${EXTRA_SHLIB_EXTENSION} != x ; then
 279   AC_DEFINE_UNQUOTED(EXTRA_SHLIB_EXTENSION, "$EXTRA_SHLIB_EXTENSION",
 280    [Additional extension a shared object might have.])
 281 fi
 282
 283 dnl Required by html and install-html
 284 AC_SUBST(datarootdir)
 285 AC_SUBST(docdir)
 286 AC_SUBST(htmldir)
 287
 288 AC_OUTPUT(Makefile po/Makefile.in:po/Make-in)