config-scripts/cups-common.m4

   1 dnl
   2 dnl Common configuration stuff for CUPS.
   3 dnl
   4 dnl Copyright © 2007-2018 by Apple Inc.
   5 dnl Copyright © 1997-2007 by Easy Software Products, all rights reserved.
   6 dnl
   7 dnl Licensed under Apache License v2.0.  See the file "LICENSE" for more
   8 dnl information.
   9 dnl
  10
  11 dnl Set the name of the config header file...
  12 AC_CONFIG_HEADER(config.h)
  13
  14 dnl Version number information...
  15 CUPS_VERSION="AC_PACKAGE_VERSION"
  16 CUPS_REVISION=""
  17 CUPS_BUILD="cups-$CUPS_VERSION"
  18
  19 AC_ARG_WITH(cups_build, [  --with-cups-build       set "cups-config --build" string ],
  20         CUPS_BUILD="$withval")
  21
  22 AC_SUBST(CUPS_VERSION)
  23 AC_SUBST(CUPS_REVISION)
  24 AC_SUBST(CUPS_BUILD)
  25 AC_DEFINE_UNQUOTED(CUPS_SVERSION, "AC_PACKAGE_NAME v$CUPS_VERSION$CUPS_REVISION")
  26 AC_DEFINE_UNQUOTED(CUPS_MINIMAL, "AC_PACKAGE_NAME/$CUPS_VERSION$CUPS_REVISION")
  27
  28 dnl Default compiler flags...
  29 CFLAGS="${CFLAGS:=}"
  30 CPPFLAGS="${CPPFLAGS:=}"
  31 CXXFLAGS="${CXXFLAGS:=}"
  32 LDFLAGS="${LDFLAGS:=}"
  33
  34 dnl Checks for programs...
  35 AC_PROG_AWK
  36 AC_PROG_CC(clang cc gcc)
  37 AC_PROG_CPP
  38 AC_PROG_CXX(clang++ c++ g++)
  39 AC_PROG_RANLIB
  40 AC_PATH_PROG(AR,ar)
  41 AC_PATH_PROG(CHMOD,chmod)
  42 AC_PATH_PROG(GZIP,gzip)
  43 AC_PATH_PROG(LD,ld)
  44 AC_PATH_PROG(LN,ln)
  45 AC_PATH_PROG(MKDIR,mkdir)
  46 AC_PATH_PROG(MV,mv)
  47 AC_PATH_PROG(RM,rm)
  48 AC_PATH_PROG(RMDIR,rmdir)
  49 AC_PATH_PROG(SED,sed)
  50 AC_PATH_PROG(XDGOPEN,xdg-open)
  51 if test "x$XDGOPEN" = x; then
  52         CUPS_HTMLVIEW="htmlview"
  53 else
  54         CUPS_HTMLVIEW="$XDGOPEN"
  55 fi
  56 AC_SUBST(CUPS_HTMLVIEW)
  57
  58 AC_MSG_CHECKING(for install-sh script)
  59 INSTALL="`pwd`/install-sh"
  60 AC_SUBST(INSTALL)
  61 AC_MSG_RESULT(using $INSTALL)
  62
  63 if test "x$AR" = x; then
  64         AC_MSG_ERROR([Unable to find required library archive command.])
  65 fi
  66 if test "x$CC" = x; then
  67         AC_MSG_ERROR([Unable to find required C compiler command.])
  68 fi
  69
  70 dnl Static library option...
  71 INSTALLSTATIC=""
  72 AC_ARG_ENABLE(static, [  --enable-static         install static libraries])
  73
  74 if test x$enable_static = xyes; then
  75         echo Installing static libraries...
  76         INSTALLSTATIC="installstatic"
  77 fi
  78
  79 AC_SUBST(INSTALLSTATIC)
  80
  81 dnl Check for pkg-config, which is used for some other tests later on...
  82 AC_PATH_TOOL(PKGCONFIG, pkg-config)
  83
  84 dnl Check for libraries...
  85 AC_SEARCH_LIBS(abs, m, AC_DEFINE(HAVE_ABS))
  86 AC_SEARCH_LIBS(crypt, crypt)
  87 AC_SEARCH_LIBS(fmod, m)
  88 AC_SEARCH_LIBS(getspent, sec gen)
  89
  90 LIBMALLOC=""
  91 AC_ARG_ENABLE(mallinfo, [  --enable-mallinfo       build with malloc debug logging])
  92
  93 if test x$enable_mallinfo = xyes; then
  94         SAVELIBS="$LIBS"
  95         LIBS=""
  96         AC_SEARCH_LIBS(mallinfo, malloc, AC_DEFINE(HAVE_MALLINFO))
  97         LIBMALLOC="$LIBS"
  98         LIBS="$SAVELIBS"
  99 fi
 100
 101 AC_SUBST(LIBMALLOC)
 102
 103 dnl Check for libpaper support...
 104 AC_ARG_ENABLE(libpaper, [  --enable-libpaper       build with libpaper support])
 105
 106 if test x$enable_libpaper = xyes; then
 107         AC_CHECK_LIB(paper,systempapername,
 108                 AC_DEFINE(HAVE_LIBPAPER)
 109                 LIBPAPER="-lpaper",
 110                 LIBPAPER="")
 111 else
 112         LIBPAPER=""
 113 fi
 114 AC_SUBST(LIBPAPER)
 115
 116 dnl Checks for header files.
 117 AC_HEADER_STDC
 118 AC_CHECK_HEADER(stdlib.h,AC_DEFINE(HAVE_STDLIB_H))
 119 AC_CHECK_HEADER(crypt.h,AC_DEFINE(HAVE_CRYPT_H))
 120 AC_CHECK_HEADER(langinfo.h,AC_DEFINE(HAVE_LANGINFO_H))
 121 AC_CHECK_HEADER(malloc.h,AC_DEFINE(HAVE_MALLOC_H))
 122 AC_CHECK_HEADER(shadow.h,AC_DEFINE(HAVE_SHADOW_H))
 123 AC_CHECK_HEADER(stdint.h,AC_DEFINE(HAVE_STDINT_H))
 124 AC_CHECK_HEADER(string.h,AC_DEFINE(HAVE_STRING_H))
 125 AC_CHECK_HEADER(strings.h,AC_DEFINE(HAVE_STRINGS_H))
 126 AC_CHECK_HEADER(bstring.h,AC_DEFINE(HAVE_BSTRING_H))
 127 AC_CHECK_HEADER(sys/ioctl.h,AC_DEFINE(HAVE_SYS_IOCTL_H))
 128 AC_CHECK_HEADER(sys/param.h,AC_DEFINE(HAVE_SYS_PARAM_H))
 129 AC_CHECK_HEADER(sys/ucred.h,AC_DEFINE(HAVE_SYS_UCRED_H))
 130
 131 dnl Checks for iconv.h and iconv_open
 132 AC_CHECK_HEADER(iconv.h,
 133         SAVELIBS="$LIBS"
 134         LIBS=""
 135         AC_SEARCH_LIBS(iconv_open,iconv,
 136                 AC_DEFINE(HAVE_ICONV_H)
 137                 SAVELIBS="$SAVELIBS $LIBS")
 138         AC_SEARCH_LIBS(libiconv_open,iconv,
 139                 AC_DEFINE(HAVE_ICONV_H)
 140                 SAVELIBS="$SAVELIBS $LIBS")
 141         LIBS="$SAVELIBS")
 142
 143 dnl Checks for Mini-XML (www.minixml.org)...
 144 LIBMXML=""
 145 AC_CHECK_HEADER(mxml.h,
 146         SAVELIBS="$LIBS"
 147         AC_SEARCH_LIBS(mmxlNewElement,mxml,
 148                 AC_DEFINE(HAVE_MXML_H)
 149                 LIBMXML="-lmxml")
 150         LIBS="$SAVELIBS")
 151 AC_SUBST(LIBMXML)
 152
 153 dnl Checks for statfs and its many headers...
 154 AC_CHECK_HEADER(sys/mount.h,AC_DEFINE(HAVE_SYS_MOUNT_H))
 155 AC_CHECK_HEADER(sys/statfs.h,AC_DEFINE(HAVE_SYS_STATFS_H))
 156 AC_CHECK_HEADER(sys/statvfs.h,AC_DEFINE(HAVE_SYS_STATVFS_H))
 157 AC_CHECK_HEADER(sys/vfs.h,AC_DEFINE(HAVE_SYS_VFS_H))
 158 AC_CHECK_FUNCS(statfs statvfs)
 159
 160 dnl Checks for string functions.
 161 AC_CHECK_FUNCS(strdup strlcat strlcpy)
 162 if test "$host_os_name" = "hp-ux" -a "$host_os_version" = "1020"; then
 163         echo Forcing snprintf emulation for HP-UX.
 164 else
 165         AC_CHECK_FUNCS(snprintf vsnprintf)
 166 fi
 167
 168 dnl Check for random number functions...
 169 AC_CHECK_FUNCS(random lrand48 arc4random)
 170
 171 dnl Check for geteuid function.
 172 AC_CHECK_FUNCS(geteuid)
 173
 174 dnl Check for setpgid function.
 175 AC_CHECK_FUNCS(setpgid)
 176
 177 dnl Check for vsyslog function.
 178 AC_CHECK_FUNCS(vsyslog)
 179
 180 dnl Checks for signal functions.
 181 case "$host_os_name" in
 182         linux* | gnu*)
 183                 # Do not use sigset on Linux or GNU HURD
 184                 ;;
 185         *)
 186                 # Use sigset on other platforms, if available
 187                 AC_CHECK_FUNCS(sigset)
 188                 ;;
 189 esac
 190
 191 AC_CHECK_FUNCS(sigaction)
 192
 193 dnl Checks for wait functions.
 194 AC_CHECK_FUNCS(waitpid wait3)
 195
 196 dnl Check for posix_spawn
 197 AC_CHECK_FUNCS(posix_spawn)
 198
 199 dnl Check for getgrouplist
 200 AC_CHECK_FUNCS(getgrouplist)
 201
 202 dnl See if the tm structure has the tm_gmtoff member...
 203 AC_MSG_CHECKING(for tm_gmtoff member in tm structure)
 204 AC_TRY_COMPILE([#include <time.h>],[struct tm t;
 205         int o = t.tm_gmtoff;],
 206         AC_MSG_RESULT(yes)
 207         AC_DEFINE(HAVE_TM_GMTOFF),
 208         AC_MSG_RESULT(no))
 209
 210 dnl See if the stat structure has the st_gen member...
 211 AC_MSG_CHECKING(for st_gen member in stat structure)
 212 AC_TRY_COMPILE([#include <sys/stat.h>],[struct stat t;
 213         int o = t.st_gen;],
 214         AC_MSG_RESULT(yes)
 215         AC_DEFINE(HAVE_ST_GEN),
 216         AC_MSG_RESULT(no))
 217
 218 dnl See if we have the removefile(3) function for securely removing files
 219 AC_CHECK_FUNCS(removefile)
 220
 221 dnl See if we have libusb...
 222 AC_ARG_ENABLE(libusb, [  --enable-libusb         use libusb for USB printing])
 223
 224 LIBUSB=""
 225 USBQUIRKS=""
 226 AC_SUBST(LIBUSB)
 227 AC_SUBST(USBQUIRKS)
 228
 229 if test "x$PKGCONFIG" != x; then
 230         if test x$enable_libusb != xno -a $host_os_name != darwin; then
 231                 AC_MSG_CHECKING(for libusb-1.0)
 232                 if $PKGCONFIG --exists libusb-1.0; then
 233                         AC_MSG_RESULT(yes)
 234                         AC_DEFINE(HAVE_LIBUSB)
 235                         CFLAGS="$CFLAGS `$PKGCONFIG --cflags libusb-1.0`"
 236                         LIBUSB="`$PKGCONFIG --libs libusb-1.0`"
 237                         USBQUIRKS="\$(DATADIR)/usb"
 238                 else
 239                         AC_MSG_RESULT(no)
 240                         if test x$enable_libusb = xyes; then
 241                                 AC_MSG_ERROR(libusb required for --enable-libusb.)
 242                         fi
 243                 fi
 244         fi
 245 elif test x$enable_libusb = xyes; then
 246         AC_MSG_ERROR(Need pkg-config to enable libusb support.)
 247 fi
 248
 249 dnl See if we have libwrap for TCP wrappers support...
 250 AC_ARG_ENABLE(tcp_wrappers, [  --enable-tcp-wrappers   use libwrap for TCP wrappers support])
 251
 252 LIBWRAP=""
 253 AC_SUBST(LIBWRAP)
 254
 255 if test x$enable_tcp_wrappers = xyes; then
 256         AC_CHECK_LIB(wrap, hosts_access,[
 257                 AC_CHECK_HEADER(tcpd.h,
 258                         AC_DEFINE(HAVE_TCPD_H)
 259                         LIBWRAP="-lwrap")])
 260 fi
 261
 262 dnl ZLIB
 263 INSTALL_GZIP=""
 264 LIBZ=""
 265 AC_CHECK_HEADER(zlib.h,
 266     AC_CHECK_LIB(z, gzgets,
 267         AC_DEFINE(HAVE_LIBZ)
 268         LIBZ="-lz"
 269         LIBS="$LIBS -lz"
 270         AC_CHECK_LIB(z, inflateCopy, AC_DEFINE(HAVE_INFLATECOPY))
 271         if test "x$GZIP" != z; then
 272                 INSTALL_GZIP="-z"
 273         fi))
 274 AC_SUBST(INSTALL_GZIP)
 275 AC_SUBST(LIBZ)
 276
 277 dnl Flags for "ar" command...
 278 case $host_os_name in
 279         darwin* | *bsd*)
 280                 ARFLAGS="-rcv"
 281                 ;;
 282         *)
 283                 ARFLAGS="crvs"
 284                 ;;
 285 esac
 286
 287 AC_SUBST(ARFLAGS)
 288
 289 dnl Prep libraries specifically for cupsd and backends...
 290 BACKLIBS=""
 291 SERVERLIBS=""
 292 AC_SUBST(BACKLIBS)
 293 AC_SUBST(SERVERLIBS)
 294
 295 dnl See if we have POSIX ACL support...
 296 SAVELIBS="$LIBS"
 297 LIBS=""
 298 AC_ARG_ENABLE(acl, [  --enable-acl            build with POSIX ACL support])
 299 if test "x$enable_acl" != xno; then
 300         AC_SEARCH_LIBS(acl_init, acl, AC_DEFINE(HAVE_ACL_INIT))
 301         SERVERLIBS="$SERVERLIBS $LIBS"
 302 fi
 303 LIBS="$SAVELIBS"
 304
 305 dnl Check for DBUS support
 306 AC_ARG_ENABLE(dbus, [  --disable-dbus          build without DBUS support])
 307 AC_ARG_WITH(dbusdir, [  --with-dbusdir          set DBUS configuration directory ],
 308         DBUSDIR="$withval")
 309
 310 DBUSDIR=""
 311 DBUS_NOTIFIER=""
 312 DBUS_NOTIFIERLIBS=""
 313
 314 if test "x$enable_dbus" != xno -a "x$PKGCONFIG" != x -a "x$host_os_name" != xdarwin; then
 315         AC_MSG_CHECKING(for DBUS)
 316         if $PKGCONFIG --exists dbus-1; then
 317                 AC_MSG_RESULT(yes)
 318                 AC_DEFINE(HAVE_DBUS)
 319                 CFLAGS="$CFLAGS `$PKGCONFIG --cflags dbus-1` -DDBUS_API_SUBJECT_TO_CHANGE"
 320                 SERVERLIBS="$SERVERLIBS `$PKGCONFIG --libs dbus-1`"
 321                 DBUS_NOTIFIER="dbus"
 322                 DBUS_NOTIFIERLIBS="`$PKGCONFIG --libs dbus-1`"
 323                 SAVELIBS="$LIBS"
 324                 LIBS="$LIBS $DBUS_NOTIFIERLIBS"
 325                 AC_CHECK_FUNC(dbus_message_iter_init_append,
 326                               AC_DEFINE(HAVE_DBUS_MESSAGE_ITER_INIT_APPEND))
 327                 AC_CHECK_FUNC(dbus_threads_init,
 328                               AC_DEFINE(HAVE_DBUS_THREADS_INIT))
 329                 LIBS="$SAVELIBS"
 330                 if test -d /etc/dbus-1; then
 331                         DBUSDIR="/etc/dbus-1"
 332                 fi
 333         else
 334                 AC_MSG_RESULT(no)
 335         fi
 336 fi
 337
 338 AC_SUBST(DBUSDIR)
 339 AC_SUBST(DBUS_NOTIFIER)
 340 AC_SUBST(DBUS_NOTIFIERLIBS)
 341
 342 dnl Extra platform-specific libraries...
 343 CUPS_DEFAULT_PRINTOPERATOR_AUTH="@SYSTEM"
 344 CUPS_DEFAULT_SYSTEM_AUTHKEY=""
 345 CUPS_SYSTEM_AUTHKEY=""
 346 INSTALLXPC=""
 347
 348 case $host_os_name in
 349         darwin*)
 350                 BACKLIBS="$BACKLIBS -framework IOKit"
 351                 SERVERLIBS="$SERVERLIBS -framework IOKit -weak_framework ApplicationServices"
 352                 LIBS="-framework SystemConfiguration -framework CoreFoundation -framework Security $LIBS"
 353
 354                 dnl Check for framework headers...
 355                 AC_CHECK_HEADER(ApplicationServices/ApplicationServices.h,AC_DEFINE(HAVE_APPLICATIONSERVICES_H))
 356                 AC_CHECK_HEADER(CoreFoundation/CoreFoundation.h,AC_DEFINE(HAVE_COREFOUNDATION_H))
 357                 AC_CHECK_HEADER(CoreFoundation/CFPriv.h,AC_DEFINE(HAVE_CFPRIV_H))
 358                 AC_CHECK_HEADER(CoreFoundation/CFBundlePriv.h,AC_DEFINE(HAVE_CFBUNDLEPRIV_H))
 359
 360                 dnl Check for dynamic store function...
 361                 AC_CHECK_FUNCS(SCDynamicStoreCopyComputerName)
 362
 363                 dnl Check for the new membership functions in MacOSX 10.4...
 364                 AC_CHECK_HEADER(membership.h,AC_DEFINE(HAVE_MEMBERSHIP_H))
 365                 AC_CHECK_HEADER(membershipPriv.h,AC_DEFINE(HAVE_MEMBERSHIPPRIV_H))
 366                 AC_CHECK_FUNCS(mbr_uid_to_uuid)
 367
 368                 dnl Need <dlfcn.h> header...
 369                 AC_CHECK_HEADER(dlfcn.h,AC_DEFINE(HAVE_DLFCN_H))
 370
 371                 dnl Check for notify_post support
 372                 AC_CHECK_HEADER(notify.h,AC_DEFINE(HAVE_NOTIFY_H))
 373                 AC_CHECK_FUNCS(notify_post)
 374
 375                 dnl Check for Authorization Services support
 376                 AC_ARG_WITH(adminkey, [  --with-adminkey         set the default SystemAuthKey value],
 377                         default_adminkey="$withval",
 378                         default_adminkey="default")
 379                 AC_ARG_WITH(operkey, [  --with-operkey          set the default operator @AUTHKEY value],
 380                         default_operkey="$withval",
 381                         default_operkey="default")
 382
 383                 AC_CHECK_HEADER(Security/Authorization.h, [
 384                         AC_DEFINE(HAVE_AUTHORIZATION_H)
 385
 386                         if test "x$default_adminkey" != xdefault; then
 387                                 CUPS_SYSTEM_AUTHKEY="SystemGroupAuthKey $default_adminkey"
 388                                 CUPS_DEFAULT_SYSTEM_AUTHKEY="$default_adminkey"
 389                         else
 390                                 CUPS_SYSTEM_AUTHKEY="SystemGroupAuthKey system.print.admin"
 391                                 CUPS_DEFAULT_SYSTEM_AUTHKEY="system.print.admin"
 392                         fi
 393
 394                         if test "x$default_operkey" != xdefault; then
 395                                 CUPS_DEFAULT_PRINTOPERATOR_AUTH="@AUTHKEY($default_operkey) @admin @lpadmin"
 396                         else
 397                                 CUPS_DEFAULT_PRINTOPERATOR_AUTH="@AUTHKEY(system.print.operator) @admin @lpadmin"
 398                         fi])
 399                 AC_CHECK_HEADER(Security/SecBasePriv.h,AC_DEFINE(HAVE_SECBASEPRIV_H))
 400
 401                 dnl Check for sandbox/Seatbelt support
 402                 if test $host_os_version -ge 100; then
 403                         AC_CHECK_HEADER(sandbox.h,AC_DEFINE(HAVE_SANDBOX_H))
 404                 fi
 405                 if test $host_os_version -ge 110 -a $host_os_version -lt 120; then
 406                         # Broken public headers in 10.7.x...
 407                         AC_MSG_CHECKING(for sandbox/private.h presence)
 408                         if test -f /usr/local/include/sandbox/private.h; then
 409                                 AC_MSG_RESULT(yes)
 410                         else
 411                                 AC_MSG_RESULT(no)
 412                                 AC_MSG_ERROR(Run 'sudo mkdir -p /usr/local/include/sandbox' and 'sudo touch /usr/local/include/sandbox/private.h' to build CUPS.)
 413                         fi
 414                 fi
 415
 416                 dnl Check for XPC support
 417                 AC_CHECK_HEADER(xpc/xpc.h,
 418                         AC_DEFINE(HAVE_XPC)
 419                         INSTALLXPC="install-xpc")
 420                 AC_CHECK_HEADER(xpc/private.h,
 421                         AC_DEFINE(HAVE_XPC_PRIVATE_H))
 422                 ;;
 423 esac
 424
 425 AC_SUBST(CUPS_DEFAULT_PRINTOPERATOR_AUTH)
 426 AC_DEFINE_UNQUOTED(CUPS_DEFAULT_PRINTOPERATOR_AUTH, "$CUPS_DEFAULT_PRINTOPERATOR_AUTH")
 427 AC_DEFINE_UNQUOTED(CUPS_DEFAULT_SYSTEM_AUTHKEY, "$CUPS_DEFAULT_SYSTEM_AUTHKEY")
 428 AC_SUBST(CUPS_SYSTEM_AUTHKEY)
 429 AC_SUBST(INSTALLXPC)
 430
 431 dnl Check for build components
 432 COMPONENTS="all"
 433
 434 AC_ARG_WITH(components, [  --with-components       set components to build:
 435                             - "all" (default) builds everything
 436                             - "core" builds libcups and ipptool
 437                             - "libcups" builds just libcups],
 438         COMPONENTS="$withval")
 439
 440 case "$COMPONENTS" in
 441         all)
 442                 BUILDDIRS="test filter backend berkeley cgi-bin monitor notifier ppdc scheduler systemv conf data desktop locale man doc examples templates"
 443                 ;;
 444
 445         core)
 446                 BUILDDIRS="test locale"
 447                 ;;
 448
 449         libcups)
 450                 BUILDDIRS="locale"
 451                 ;;
 452
 453         *)
 454                 AC_MSG_ERROR([Bad build component "$COMPONENT" specified!])
 455                 ;;
 456 esac
 457
 458 AC_SUBST(BUILDDIRS)