config-scripts/cups-defaults.m4

   1 dnl
   2 dnl "$Id: cups-defaults.m4 6720 2007-07-25 00:40:03Z mike $"
   3 dnl
   4 dnl   Default cupsd configuration settings for the Common UNIX Printing System
   5 dnl   (CUPS).
   6 dnl
   7 dnl   Copyright 2007 by Apple Inc.
   8 dnl   Copyright 2006-2007 by Easy Software Products, all rights reserved.
   9 dnl
  10 dnl   These coded instructions, statements, and computer programs are the
  11 dnl   property of Apple Inc. and are protected by Federal copyright
  12 dnl   law.  Distribution and use rights are outlined in the file "LICENSE.txt"
  13 dnl   which should have been included with this file.  If this file is
  14 dnl   file is missing or damaged, see the license at "http://www.cups.org/".
  15 dnl
  16
  17 dnl Default languages...
  18 LANGUAGES="`ls -1 locale/*.po | sed -e '1,$s/locale\/cups_//' -e '1,$s/\.po//' | tr '\n' ' '`"
  19
  20 AC_ARG_WITH(languages, [  --with-languages        set installed languages, default=all ],[
  21         case "$withval" in
  22                 none | no) LANGUAGES="" ;;
  23                 all) ;;
  24                 *) LANGUAGES="$withval" ;;
  25         esac])
  26 AC_SUBST(LANGUAGES)
  27
  28 dnl Default ConfigFilePerm
  29 AC_ARG_WITH(config_file_perm, [  --with-config-file-perm set default ConfigFilePerm value, default=0640],
  30         CUPS_CONFIG_FILE_PERM="$withval",
  31         if test "x$uname" = xDarwin; then
  32                 CUPS_CONFIG_FILE_PERM="644"
  33         else
  34                 CUPS_CONFIG_FILE_PERM="640"
  35         fi)
  36 AC_SUBST(CUPS_CONFIG_FILE_PERM)
  37 AC_DEFINE_UNQUOTED(CUPS_DEFAULT_CONFIG_FILE_PERM, 0$CUPS_CONFIG_FILE_PERM)
  38
  39 dnl Default LogFilePerm
  40 AC_ARG_WITH(log_file_perm, [  --with-log-file-perm    set default LogFilePerm value, default=0644],
  41         CUPS_LOG_FILE_PERM="$withval",
  42         CUPS_LOG_FILE_PERM="644")
  43 AC_SUBST(CUPS_LOG_FILE_PERM)
  44 AC_DEFINE_UNQUOTED(CUPS_DEFAULT_LOG_FILE_PERM, 0$CUPS_LOG_FILE_PERM)
  45
  46 dnl Default Browsing
  47 AC_ARG_ENABLE(browsing, [  --enable-browsing       enable Browsing by default, default=yes])
  48 if test "x$enable_browsing" = xno; then
  49         CUPS_BROWSING="No"
  50         AC_DEFINE_UNQUOTED(CUPS_DEFAULT_BROWSING, 0)
  51 else
  52         CUPS_BROWSING="Yes"
  53         AC_DEFINE_UNQUOTED(CUPS_DEFAULT_BROWSING, 1)
  54 fi
  55 AC_SUBST(CUPS_BROWSING)
  56
  57 dnl Default BrowseLocalProtocols
  58 AC_ARG_WITH(local_protocols, [  --with-local-protocols  set default BrowseLocalProtocols, default="CUPS"],
  59         default_local_protocols="$withval",
  60         default_local_protocols="default")
  61
  62 if test x$with_local_protocols != xno; then
  63         if test "x$default_local_protocols" = "xdefault"; then
  64                 if test "x$DNSSDLIBS" != "x"; then
  65                 CUPS_BROWSE_LOCAL_PROTOCOLS="CUPS dnssd"
  66         else
  67                 CUPS_BROWSE_LOCAL_PROTOCOLS="CUPS"
  68                 fi
  69         else
  70                 CUPS_BROWSE_LOCAL_PROTOCOLS="$default_local_protocols"
  71         fi
  72 else
  73         CUPS_BROWSE_LOCAL_PROTOCOLS=""
  74 fi
  75
  76 AC_SUBST(CUPS_BROWSE_LOCAL_PROTOCOLS)
  77 AC_DEFINE_UNQUOTED(CUPS_DEFAULT_BROWSE_LOCAL_PROTOCOLS,
  78         "$CUPS_BROWSE_LOCAL_PROTOCOLS")
  79
  80 dnl Default BrowseRemoteProtocols
  81 AC_ARG_WITH(remote_protocols, [  --with-remote-protocols set default BrowseRemoteProtocols, default="CUPS"],
  82         default_remote_protocols="$withval",
  83         default_remote_protocols="default")
  84
  85 if test x$with_remote_protocols != xno; then
  86         if test "x$default_remote_protocols" = "xdefault"; then
  87                 if test "$uname" = "Darwin" -a $uversion -ge 90; then
  88                         CUPS_BROWSE_REMOTE_PROTOCOLS=""
  89                 else
  90                         CUPS_BROWSE_REMOTE_PROTOCOLS="CUPS"
  91                 fi
  92         else
  93                 CUPS_BROWSE_REMOTE_PROTOCOLS="$default_remote_protocols"
  94         fi
  95 else
  96         CUPS_BROWSE_REMOTE_PROTOCOLS=""
  97 fi
  98
  99 AC_SUBST(CUPS_BROWSE_REMOTE_PROTOCOLS)
 100 AC_DEFINE_UNQUOTED(CUPS_DEFAULT_BROWSE_REMOTE_PROTOCOLS,
 101         "$CUPS_BROWSE_REMOTE_PROTOCOLS")
 102
 103 dnl Default BrowseShortNames
 104 AC_ARG_ENABLE(browse_short, [  --enable-browse-short-names
 105                           enable BrowseShortNames by default, default=yes])
 106 if test "x$enable_browse_short" = xno; then
 107         CUPS_BROWSE_SHORT_NAMES="No"
 108         AC_DEFINE_UNQUOTED(CUPS_DEFAULT_BROWSE_SHORT_NAMES, 0)
 109 else
 110         CUPS_BROWSE_SHORT_NAMES="Yes"
 111         AC_DEFINE_UNQUOTED(CUPS_DEFAULT_BROWSE_SHORT_NAMES, 1)
 112 fi
 113 AC_SUBST(CUPS_BROWSE_SHORT_NAMES)
 114
 115 dnl Default DefaultShared
 116 AC_ARG_ENABLE(default_shared, [  --enable-default-shared enable DefaultShared by default, default=yes])
 117 if test "x$enable_default_shared" = xno; then
 118         CUPS_DEFAULT_SHARED="No"
 119         AC_DEFINE_UNQUOTED(CUPS_DEFAULT_DEFAULT_SHARED, 0)
 120 else
 121         CUPS_DEFAULT_SHARED="Yes"
 122         AC_DEFINE_UNQUOTED(CUPS_DEFAULT_DEFAULT_SHARED, 1)
 123 fi
 124 AC_SUBST(CUPS_DEFAULT_SHARED)
 125
 126 dnl Default ImplicitClasses
 127 AC_ARG_ENABLE(implicit, [  --enable-implicit-classes
 128                           enable ImplicitClasses by default, default=yes])
 129 if test "x$enable_implicit" = xno; then
 130         CUPS_IMPLICIT_CLASSES="No"
 131         AC_DEFINE_UNQUOTED(CUPS_DEFAULT_IMPLICIT_CLASSES, 0)
 132 else
 133         CUPS_IMPLICIT_CLASSES="Yes"
 134         AC_DEFINE_UNQUOTED(CUPS_DEFAULT_IMPLICIT_CLASSES, 1)
 135 fi
 136 AC_SUBST(CUPS_IMPLICIT_CLASSES)
 137
 138 dnl Default UseNetworkDefault
 139 AC_ARG_ENABLE(use_network_default, [  --enable-use-network-default
 140                           enable UseNetworkDefault by default, default=auto])
 141 if test "x$enable_use_network_default" != xno; then
 142         AC_MSG_CHECKING(whether to use network default printers)
 143         if test "x$enable_use_network_default" = xyes -o $uname != Darwin; then
 144                 CUPS_USE_NETWORK_DEFAULT="Yes"
 145                 AC_DEFINE_UNQUOTED(CUPS_DEFAULT_USE_NETWORK_DEFAULT, 1)
 146                 AC_MSG_RESULT(yes)
 147         else
 148                 CUPS_USE_NETWORK_DEFAULT="No"
 149                 AC_DEFINE_UNQUOTED(CUPS_DEFAULT_USE_NETWORK_DEFAULT, 0)
 150                 AC_MSG_RESULT(no)
 151         fi
 152 else
 153         CUPS_USE_NETWORK_DEFAULT="No"
 154         AC_DEFINE_UNQUOTED(CUPS_DEFAULT_USE_NETWORK_DEFAULT, 0)
 155 fi
 156 AC_SUBST(CUPS_USE_NETWORK_DEFAULT)
 157
 158 dnl Determine the correct username and group for this OS...
 159 AC_ARG_WITH(cups_user, [  --with-cups-user        set default user for CUPS],
 160         CUPS_USER="$withval",
 161         AC_MSG_CHECKING(for default print user)
 162         if test x$uname = xDarwin; then
 163                 if x`id -u _lp 2>/dev/null` = x; then
 164                         CUPS_USER="lp";
 165                 else
 166                         CUPS_USER="_lp";
 167                 fi
 168         elif test -f /etc/passwd; then
 169                 CUPS_USER=""
 170                 for user in lp lpd guest daemon nobody; do
 171                         if test "`grep \^${user}: /etc/passwd`" != ""; then
 172                                 CUPS_USER="$user"
 173                                 AC_MSG_RESULT($user)
 174                                 break;
 175                         fi
 176                 done
 177
 178                 if test x$CUPS_USER = x; then
 179                         CUPS_USER="nobody"
 180                         AC_MSG_RESULT(not found, using "$CUPS_USER")
 181                 fi
 182         else
 183                 CUPS_USER="nobody"
 184                 AC_MSG_RESULT(no password file, using "$CUPS_USER")
 185         fi)
 186
 187 AC_ARG_WITH(cups_group, [  --with-cups-group       set default group for CUPS],
 188         CUPS_GROUP="$withval",
 189         AC_MSG_CHECKING(for default print group)
 190         if test x$uname = xDarwin; then
 191                 if x`id -g _lp 2>/dev/null` = x; then
 192                         CUPS_GROUP="lp";
 193                 else
 194                         CUPS_GROUP="_lp";
 195                 fi
 196         elif test -f /etc/group; then
 197                 GROUP_LIST="_lp lp nobody"
 198                 CUPS_GROUP=""
 199                 for group in $GROUP_LIST; do
 200                         if test "`grep \^${group}: /etc/group`" != ""; then
 201                                 CUPS_GROUP="$group"
 202                                 AC_MSG_RESULT($group)
 203                                 break;
 204                         fi
 205                 done
 206
 207                 if test x$CUPS_GROUP = x; then
 208                         CUPS_GROUP="nobody"
 209                         AC_MSG_RESULT(not found, using "$CUPS_GROUP")
 210                 fi
 211         else
 212                 CUPS_GROUP="nobody"
 213                 AC_MSG_RESULT(no group file, using "$CUPS_GROUP")
 214         fi)
 215
 216 AC_ARG_WITH(system_groups, [  --with-system-groups    set default system groups for CUPS],
 217         CUPS_SYSTEM_GROUPS="$withval",
 218         if test x$uname = xDarwin; then
 219                 CUPS_SYSTEM_GROUPS="admin"
 220         else
 221                 AC_MSG_CHECKING(for default system groups)
 222                 if test -f /etc/group; then
 223                         CUPS_SYSTEM_GROUPS=""
 224                         GROUP_LIST="lpadmin sys system root"
 225                         for group in $GROUP_LIST; do
 226                                 if test "`grep \^${group}: /etc/group`" != ""; then
 227                                         if test "x$CUPS_SYSTEM_GROUPS" = x; then
 228                                                 CUPS_SYSTEM_GROUPS="$group"
 229                                         else
 230                                                 CUPS_SYSTEM_GROUPS="$CUPS_SYSTEM_GROUPS $group"
 231                                         fi
 232                                 fi
 233                         done
 234
 235                         if test "x$CUPS_SYSTEM_GROUPS" = x; then
 236                                 CUPS_SYSTEM_GROUPS="$GROUP_LIST"
 237                                 AC_MSG_RESULT(no groups found, using "$CUPS_SYSTEM_GROUPS")
 238                         else
 239                                 AC_MSG_RESULT("$CUPS_SYSTEM_GROUPS")
 240                         fi
 241                 else
 242                         CUPS_SYSTEM_GROUPS="$GROUP_LIST"
 243                         AC_MSG_RESULT(no group file, using "$CUPS_SYSTEM_GROUPS")
 244                 fi
 245         fi)
 246
 247
 248 CUPS_PRIMARY_SYSTEM_GROUP="`echo $CUPS_SYSTEM_GROUPS | awk '{print $1}'`"
 249
 250 AC_SUBST(CUPS_USER)
 251 AC_SUBST(CUPS_GROUP)
 252 AC_SUBST(CUPS_SYSTEM_GROUPS)
 253 AC_SUBST(CUPS_PRIMARY_SYSTEM_GROUP)
 254
 255 AC_DEFINE_UNQUOTED(CUPS_DEFAULT_USER, "$CUPS_USER")
 256 AC_DEFINE_UNQUOTED(CUPS_DEFAULT_GROUP, "$CUPS_GROUP")
 257 AC_DEFINE_UNQUOTED(CUPS_DEFAULT_SYSTEM_GROUPS, "$CUPS_SYSTEM_GROUPS")
 258
 259 dnl Default printcap file...
 260 AC_ARG_WITH(printcap, [  --with-printcap         set default printcap file],
 261         default_printcap="$withval",
 262         default_printcap="default")
 263
 264 if test x$default_printcap != xno; then
 265         if test "x$default_printcap" = "xdefault"; then
 266                 case $uname in
 267                         Darwin*)
 268                                 if test $uversion -ge 90; then
 269                                         CUPS_DEFAULT_PRINTCAP=""
 270                                 else
 271                                         CUPS_DEFAULT_PRINTCAP="/etc/printcap"
 272                                 fi
 273                                 ;;
 274                         SunOS*)
 275                                 CUPS_DEFAULT_PRINTCAP="/etc/printers.conf"
 276                                 ;;
 277                         *)
 278                                 CUPS_DEFAULT_PRINTCAP="/etc/printcap"
 279                                 ;;
 280                 esac
 281         else
 282                 CUPS_DEFAULT_PRINTCAP="$default_printcap"
 283         fi
 284 else
 285         CUPS_DEFAULT_PRINTCAP=""
 286 fi
 287
 288 AC_DEFINE_UNQUOTED(CUPS_DEFAULT_PRINTCAP, "$CUPS_DEFAULT_PRINTCAP")
 289
 290 dnl Default MaxCopies value...
 291 AC_ARG_WITH(max-copies, [  --with-max-copies       set max copies value, default=100 ],
 292         CUPS_MAX_COPIES="$withval",
 293         if test "x$uname" = xDarwin; then
 294                 CUPS_MAX_COPIES="999"
 295         else
 296                 CUPS_MAX_COPIES="100"
 297         fi)
 298
 299 AC_SUBST(CUPS_MAX_COPIES)
 300 AC_DEFINE_UNQUOTED(CUPS_DEFAULT_MAX_COPIES, $CUPS_MAX_COPIES)
 301
 302 dnl Default raw printing state
 303 AC_ARG_ENABLE(raw_printing, [  --enable-raw-printing   enable raw printing by default, default=auto])
 304 if test "x$enable_raw_printing" != xno; then
 305         AC_MSG_CHECKING(whether to enable raw printing)
 306         if test "x$enable_raw_printing" = xyes -o $uname = Darwin; then
 307                 DEFAULT_RAW_PRINTING=""
 308                 AC_MSG_RESULT(yes)
 309         else
 310                 DEFAULT_RAW_PRINTING="#"
 311                 AC_MSG_RESULT(no)
 312         fi
 313 else
 314         DEFAULT_RAW_PRINTING="#"
 315 fi
 316 AC_SUBST(DEFAULT_RAW_PRINTING)
 317
 318 dnl Default SNMP options...
 319 AC_ARG_WITH(snmp-address, [  --with-snmp-address     set SNMP query address, default=auto ],
 320         if test "x$withval" = x; then
 321                 CUPS_SNMP_ADDRESS=""
 322         else
 323                 CUPS_SNMP_ADDRESS="Address $withval"
 324         fi,
 325         if test "x$uname" = xDarwin; then
 326                 CUPS_SNMP_ADDRESS=""
 327         else
 328                 CUPS_SNMP_ADDRESS="Address @LOCAL"
 329         fi)
 330
 331 AC_ARG_WITH(snmp-community, [  --with-snmp-community   set SNMP community, default=public ],
 332         CUPS_SNMP_COMMUNITY="Community $withval",
 333         CUPS_SNMP_COMMUNITY="Community public")
 334
 335 AC_SUBST(CUPS_SNMP_ADDRESS)
 336 AC_SUBST(CUPS_SNMP_COMMUNITY)
 337
 338 dnl
 339 dnl End of "$Id: cups-defaults.m4 6720 2007-07-25 00:40:03Z mike $".
 340 dnl